IHKBBRII CSECT                                                          00500017
         TITLE 'IHKBBRII - READER/INTERPRETER INTERFACE -MVT'           01000017
*********************************************************************** 01500017
*STATUS-                                                                02000017
*   CHANGE LEVEL 0                                                      02500017
*                                                                       03000017
*FUNCTION/OPERATION-                                                    03500017
*   THIS MODULE IS A LOGICAL MEMBER OF THE ATTACHED R/I TASK BUT EXISTS 04000017
*   PHYSICALLY IN THE RJE LOAD MODULE. THE ADDRESS OF IHKBBRII (RII) IS 04500017
*   PASSED TO R/I BY IHKRJBGN WHEN THE R/I TASK IS ATTACHED. RII GAINS  05000017
*   CONTROL WHEN R/I ISSUES A 'GET' FOR A RECORD. RII PROVIDES TWO      05500017
*   SERVICES TO THE MAIN RJE TASK- (1) AN INTERFACE BETWEEN THE RJE     06000017
*   READER AND THE READER/INTERPRETER, AND (2) LOADS AND DELETES NON-   06500017
*   RESIDENT MODULES FOR THE RJE READER AND COMMAND INTERPRETER.        07000017
*                                                                       07500017
*   WHEN RII GETS CONTROL, IT POSTS THE ECB FOR THE RJE READER TO       08000017
*   INDICATE THAT THE R/I HAS ISSUED A 'GET' FOR A RECORD. IT THEN      08500017
*   WAITS ON AN ECB LIST (CURRENTLY ECBS FOR RJE READER AND FOR COMMAND 09000017
*   INTERPRETER).                                                       09500017
*                                                                       10000017
*   WHEN ONE OF THE ECBS IS POSTED RII DETERMINES WHO POSTED HIM, TURNS 10500017
*   OFF THE POST BIT, DETERMINES WHICH ECB TO POST WHEN THIS REQUEST IS 11000017
*   SATISFIED, AND INITIALIZES FOR A LOAD OR DELETE. RII THEN           11500017
*   DETERMINES THE TYPE OF REQUEST AND PERFORMS ONE OF THE FOLLOWING-   12000017
*        1. RECORD TO R/I - THE ADDRESS OF THE RECORD IS PLACED IN THE  12500017
*           R/I SAVE AREA AND CONTROL IS RETURNED TO R/I.               13000017
*        2. LOAD - MODULE IS LOADED, ECB OF REQUESTOR IS POSTED (POST   13500017
*           CODE IS ENTRY POINT OF MODULE), AND A WAIT IS ISSUED FOR    14000017
*           NEXT REQUEST.                                               14500017
*        3. DELETE - MODULE IS DELETED, ECB OF REQUESTOR IS POSTED, AND 15000017
*           A WAIT IS ISSUED FOR NEXT REQUEST.                          15500017
*        4. EODAD - EODAD ADDRESS IS MOVED INTO R/I SAVE AREA AND       16000017
*           CONTROL IS RETURNED TO R/I.                                 16500017
*                                                                       17000017
*ENTRY POINT-                                                           17500017
*        IHKBBRII IS THE ONLY ENTRY POINT. THE CALLING SEQUENCE FOR     18000017
*   RJE MODULES IS-                                                     18500017
*        LA    0,PARM                                                   19000017
*        LA    1,RIECB                                                  19500017
*        POST  (1),(0)                                                  20000017
*WHERE PARM IS A FULL WORD. THE HIGH ORDER BYTE IS THE OPERATION CODE-  20500017
*        X'00' - RECORD FOR R/I                                         21000017
*        X'04' - LOAD                                                   21500017
*        X'08' - DELETE                                                 22000017
*        X'0C' - EODAD                                                  22500017
*   THE LOW ORDER THREE BYTES ARE USED IN THE FOLLOWING MANNER-         23000017
*        OP. CODE   LOW ORDER BYTES                                     23500017
*           0       ADDRESS OF RECORD                                   24000017
*           4       SECOND BYTE IS LAST CHARACTER OF NAME FOR SHOWS     24500017
*                   (OTHERWISE NOT USED), THE TWO LOW ORDER BYTES ARE   25000017
*                   THE OFFSET TO THE MODULE NAME.                      25500017
*           8       SAME AS FOR LOAD                                    26000017
*          12       NOT USED                                            26500017
*                                                                       27000017
*INPUT-                                                                 27500017
*   AS DESCRIBED ABOVE.                                                 28000017
*                                                                       28500017
*OUTPUT-                                                                29000017
*   THE REQUESTED FUNCTION IS PERFORMED AND THE REQUESTOR IS POSTED.    29500017
*   FOR A LOAD REQUEST, THE POST CODE IS THE ADDRESS OF THE ENTRY POINT 30000017
*   OF THE LOADED ROUTINE, FOR EODAD, THE READER IS POSTED BY IHKBBNIT  30500017
*   WITH A CODE OF 1, AND FOR THE OTHER REQUESTS THE POST CODE IS ZERO. 31000017
*                                                                       31500017
*EXTERNAL ROUTINES-                                                     32000017
*        WAIT - WAIT ON ECBLIST.                                        32500017
*        POST - INFORM REQUESTOR OF COMPLETION OF REQUEST.              33000017
*        LOAD - LOAD NON-RESIDENT MODULE                                33500017
*        DELETE- DELETE NON-RESIDENT MODULE                             34000017
*                                                                       34500017
*EXITS-NORMAL-                                                          35000017
*   IHKBBRII RETURNS TO R/I.                                            35500017
*                                                                       36000017
*EXITS-ERROR-                                                           36500017
*   N/A                                                                 37000017
*                                                                       37500017
*TABLES/WORK AREAS-                                                     38000017
*   AN 84 BYTE TABLE OF MODULE NAMES, AN 8 BYTE ECB LIST, AND 16 BYTES  38500017
*   OF ASSOCIATED ECBS ARE MAINTAINED.                                  39000017
*                                                                       39500017
*ATTRIBUTES-                                                            40000017
*   SERIALLY REUSABLE.                                                  40500017
*                                                                       41000017
*NOTES-                                                                 41500017
*   N/A                                                                 42000017
*                                                                       42500017
*********************************************************************** 43000017
         EJECT                                                          43500017
R0       EQU   0                                                        44000017
R1       EQU   1                   PARAMETER REGISTER                   44500017
R2       EQU   2                   WORK REGISTER                        45000017
R3       EQU   3                                                        45500017
R4       EQU   4                                                        46000017
R5       EQU   5                                                        46500017
R6       EQU   6                                                        47000017
R7       EQU   7                                                        47500017
R8       EQU   8                                                        48000017
R9       EQU   9                                                        48500017
R10      EQU   10                                                       49000017
R11      EQU   11                  TEMPORARY WORK REGISTER              49500017
R12      EQU   12                  BASE REGISTER                        50000017
R13      EQU   13                  SAVE AREA POINTER                    50500017
R14      EQU   14                                                       51000017
R15      EQU   15                                                       51500017
         SAVE  (14,12),,*          SAVE READER/INTERPRETER'S REGISTERS  52000017
         BALR  R12,R0              ESTABLISH ADDRESSABILITY             52500017
         USING *,R12               REGISTER 12 IS BASE REGISTER         53000017
         LA    R11,SAVE            ADDRESS OF MY SAVE AREA              53500017
         ST    R11,8(R13)          ESTABLISH BACK CHAIN                 54000017
         ST    R13,SAVE+4          ADDRESS OF CALLER'S SAVE AREA        54500017
         LR    R2,R1               SAVE POINTER TO DCB USED BY R/I      55000017
         SR    R3,R3               CLEAR INDEX REGISTER                 55500017
         LR    R0,R3               CLEAR REGISTER ZERO                  56000017
         LA    R6,ECBLIST                                               56500017
         LA    R7,IHKCBRDP         ADDRESS OF RJE READER'S ECB          57000017
POST     LR    R1,R7                                                    57500017
         POST  (1),(0)             POST RJE READER'S ECB                58000017
         LR    R1,R6               ADDRESS OF ECB LIST                  58500017
         WAIT  ECBLIST=(1)                                              59000017
         LR    R1,R6                                                    59500017
AGAIN    L     R4,0(R1)            GET POINTER TO ECB                   60000017
         TM    0(R4),POSTR         IS ECB POSTED                        60500017
         BO    PROS                YES, PROCESS REQUEST                 61000017
         LA    R1,4(R1)            NO, INCREMENT TO NEXT ECB            61500017
         B     AGAIN               CHECK ECB                            62000017
PROS     NI    0(R4),ZERO          CLEAR POST BIT                       62500017
         L     R5,0(R4)            CONTENTS OF ECB IN R5                63000017
         LA    R7,0(R4)            SAVE ECB ADDRESS                     63500017
         S     R7,0(R6)            GET OFFSET FOR ECB TO BE POSTED      64000017
         LA    R7,IHKCAINP(R7)     GET ADDRESS OF ECB TO BE POSTED      64500017
DOIT     LA    R1,ROUTNAME         TABLE OF ROUTINE NAMES               65000017
         AH    R1,2(R5)            GET POINTER TO ROUTINE NAME          65500017
         MVC   NAME(4),0(R1)       MOVE NAME INTO PARM LIST             66000017
         CLI   3(R5),SHOW          IS THIS A SHOW REQUEST               66500017
         BNE   INSERT              NO                                   67000017
         MVC   NAME+3(1),1(R5)     YES INSERT LAST CHARACTER OF NAME    67500017
INSERT   IC    R3,0(R5)            INSERT OPERATION CODE                68000017
         B     *+4(R3)             BRANCH TABLE TO OPERATION            68500017
         B     PROCREC             GIVE R/I RECORD                      69000017
         B     LOADR               LOAD NON-RESIDENT ROUTINE            69500017
         B     DELETER             DELETE NON-RESIDENT ROUTINE          70000017
EODAD    MVC   13(3,R13),33(R2)    EODAD ADDRESS FROM DCB               70500017
RETURN   RETURN (14,12),T,RC=0     RETURN CONTROL TO R/I                71000017
PROCREC  L     R5,0(R5)                                                 71500017
         ST    R5,24(R13)          PUT POINTER IN R/I SAVEAREA          72000017
         B     RETURN              GO SET UP FOR NORMAL RETURN TO R/I   72500017
LOADR    LOAD  EPLOC=REPLOC                                             73000017
         B     POST                RETURN CONTROL TO RJE                73500017
DELETER DELETE EPLOC=REPLOC                                             74000017
         SR    R0,R0                                                    74500017
         B     POST                RETURN CONTROL TO RJE                75000017
SAVE     DC    3F'0'               REGISTER SAVE AREA                   75500017
ECBLIST  DC    A(IHKCAINE)         ECB LIST                             76000017
         DC    X'80'                                                    76500017
         DC    AL3(IHKCBRDE)                                            77000017
IHKCAINE DC    F'0'                ECB INDICATING IHKCXINT REQUEST      77500017
IHKCBRDE DC    F'0'                ECB INDICATING IHKCXRDR REQUEST      78000017
IHKCAINP DC    F'0'                ECB SHOWING IHKCXINT REQUEST DONE    78500017
IHKCBRDP DC    F'0'                ECB SHOWING READER REQUEST DONE      79000017
POSTR    EQU   X'40'                                                    79500017
ZERO     EQU   0                                                        80000017
SHOW     EQU   X'30'               SHOW ROUTINES OFFSET                 80500017
REPLOC   DC    C'IHKC'                                                  81000017
NAME DC CL4' '                                                          81500017
         SPACE 3                                                        82000017
ROUTNAME DC    F'0'                                                     82500017
         DC    C'BLGN'                                             000A 83000017
         DC    C'BRJS'                                             000A 83500017
         DC    C'GDLT'                                             000A 84000017
         DC    C'BLGF'                                             000A 84500017
         DC    C'FBDR'                                             000A 85000017
         DC    C'FOUT'                                             000A 85500017
         DC    C'FSTA'                                             000A 86000017
         DC    C'ARJN'                                             000A 86500017
         DC    C'HCNT'                  CENOUT                     000B 87000017
         DC    C'DBDC'                  BRDCST                          87500017
         DC    C'BUID'                  USERID                          88000017
         DC    C'ASHO'                  SHOW                            88500017
         DC    C'FMSG'                                             000A 89000017
         DC    C'FMSG'                                             000A 89500017
         DC    C'GALT'                                             000A 90000017
         DC    C'BRJS'                                             000A 90500017
         DC    C'ARJN'                                             000A 91000017
         DC    C'ARJN'                                             000A 91500017
         DC    C'HJPR'                                                  92000017
         DC    C'FSTB'                                                  92500017
         ENTRY IHKCAINE,IHKCBRDE,IHKCAINP,IHKCBRDP                      93000017
         END                                                            93500017
