 TITLE  'IHKCBSTD'                                                      00700015
IHKCBSTD CSECT                                                          01400015
*STATUS:                                                              * 02100015
*   CHANGE LEVEL 0                                                    * 02800015
*FUNCTION/OPERATION:                                                  * 03500015
*   THIS ROUTINE PERFORMS A SERIAL SEARCH OF THETERMINAL DIRECTORY,   * 04200015
*   LOOKING FOR THE ENTRY OF A SPECIFIED TERMINAL IDENTIFICATION.     * 04900015
*                                                                     * 05600015
*ENTRY POINTS:                                                        * 06300015
*        IHKCBSTD IS THE ONLY ENTRY POINT.                            * 07000015
*        IHKCBSTD - FIND TERMINAL DIRECTORY ENTRY                     * 07700015
*                   LA   1,TERMINAL IDENTIFICATION                    * 08400015
*                   CALL SRCHTID                                      * 09100015
*                                                                     * 09800015
*   DATA IS PASSED TO THIS ROUTINE BY ITS LOCATION                    * 10500015
*                                                                     * 11200015
*INPUT:                                                               * 11900015
*   STANDARD SUBROUTINE LINKAGE PREVAILS.REGISTER ONE POINTS TO       * 12600015
*   AN EIGHT BYTE TERMINAL IDENTIFICATION, FOR WHICH THE USER WANTS   * 13300015
*   THE CORRESPONDING ENTRY IN THE TERMINAL DIRECTORY. IF THE         * 14000015
*   TERMINAL ID IS NOT EIGHT BYTES LONG, IT SHOULD BE LEFT ADJUSTED   * 14700015
*   AND PADDED WITH BLANKS, HEX 40'S, TO THE RIGHT.                   * 15400015
*                                                                     * 16100015
*OUTPUT:                                                              * 16800015
*   NO OUTPUT EXCEPT THAT LISTED UNDER 'EXITS'.                       * 17500015
*                                                                     * 18200015
*EXTERNAL ROUTINES:                                                   * 18900015
*   N/A                                                               * 19600015
*                                                                     * 20300015
*EXITS-NORMAL:                                                        * 21000015
*   REGISTER ONE POINTS TO THE FIRST BYTE OF THE FOUND TERMINAL       * 21700015
*   DIRECTORY ENTRY. REGISTER FIFTEEN CONTAINS A RETURN CODE OF ZERO.*  22400015
*                                                                     * 23100015
*EXITS-ERROR:                                                         * 23800015
*   REGISTER ONE REMAINS UNCHANGED. REGISTER FIFTEEN HAS A RETURN     * 24500015
*   CODE OF FOUR.                                                     * 25200015
*                                                                     * 25900015
*TABLES/WORK AREAS:                                                   * 26600015
*   THE TERMINAL DIRECTORY CONSISTS OF AN ENTRY FOR                   * 27300015
*   EACH POTENIAL REMOTE TERMINAL AVAILABLE TO THE SYSTEM. WITHIN     * 28000015
*   EACH 13 BYTE ENTRY IS AN EIGHT BYTE TERMINAL ID, A THREE BYTE     * 28700015
*   USER ID, A STATUS BYTE, AND A RETAIN PERIOD BYTE.                 * 29400015
*                                                                     * 30100015
*ATTRIBUTES:                                                          * 30800015
*   SERIALLY REUSABLE.                                                  31500015
*                                                                     * 32200015
*NOTES:                                                               * 32900015
*   N/A                                                               * 33600015
*                                                                     * 34300015
*                                                                       35000015
*********************************************************************** 35700015
*                                                                       36400015
*        GENERAL REGISTERS                                              37100015
TERMID   EQU   1                   ADDRESS OF TERMINAL ID               37800015
TLENT    EQU   7                   LENGTH OF TDIR ENTRY                 38500015
TNUMB    EQU   8                   NUMBER OF ENTRIES IN TABLE           39200015
BUMP     EQU   9                   INCREMENT IN BXLE INSTRUCTION        39900015
SRCHBASE EQU   11                  BASE REGISTER FOR DSECT              40600015
BASE     EQU   12                  BASE REGISTER FOR SRCHTID            41300015
RTRNCODE EQU   15                  RETURN CODE                          42000015
*                                                                       42700015
**************                                              *********** 43400015
*                                                                       44100015
         STM   14,12,12(13)        SAVE REGISTERS                       44800015
         BALR  BASE,0              SET UP ADDRESSABILITY USIING         45500015
         USING *,BASE              REGISTER 12 (BASE)                   46200015
         LA    10,SAVE                                                  46900015
         ST    10,8(13)            STORE MY SAVE ADDRESS IN HIS SAVE    47600015
         ST    13,4(10)            STORE HIS SAVE ADDRESS IN MY AREA    48300015
*                                                                       49000015
*                                                                       49700015
*        INITIALIZE COUNTERS FOR LOOP CONTROL                           50400015
*                                                                       51100015
*                                                                       51800015
         LA    BUMP,1              SET VALUE OF INCREMENT FOR BXLE      52500015
         LNR   BUMP,BUMP           INSTRUCTION                          53200015
         L     TLENT,ADTLENT       FIND LENGTH OF EACH ENTRY            53900015
         LH    TLENT,0(TLENT)                                           54600015
         L     TNUMB,ADTNUMB       FIND NUMBER FO ENTRIES IN TERMINAL   55300015
         LH    TNUMB,0(TNUMB)      TABLE                                56000015
*                                                                       56700015
*                                                                       57400015
*        SET UP ADDRESSABILITY WITHIN DSECT                             58100015
*                                                                       58800015
*                                                                       59500015
         L     SRCHBASE,ADTDIR          USE ADDRESS OF FIRST BYTE IN    60200015
         USING TDIREC,SRCHBASE          THE TERMINAL DIRECTORY          60900015
*                                                                       61600015
*                                                                       62300015
*        LOOP FOR SERIAL SEARCH OF TERMINAL DIRECTORY. SEEKING          63000015
* TERMINAL NAME EQUAL TO NAME POINTED TO BY REGISTER ONE (TERMID).      63700015
*                                                                       64400015
*                                                                       65100015
LOOP     BXLE  TNUMB,BUMP,NOTFOUND      LOOP CONTROL,BRANCH IF END TDIR 65800015
         CLC   TDIRTERM(8),0(TERMID)    COMPARE TERMINAL IDS            66500015
         BE    FOUND                    IF EQUAL GO TO ROUTINE TO       67200015
*                                       RETURN RESULTS TO CALLER        67900015
         AR    SRCHBASE,TLENT           INCREMENT TO NEXT ENTRY         68600015
         B     LOOP                                                     69300015
*                                                                       70000015
*                                                                       70700015
*        LOAD  RETURN CODE INDICATIONG UNSUCCESSFUL SEARCH AND BRANCH   71400015
* TO ENDUP ROUTINE.                                                     72100015
*                                                                       72800015
*                                                                       73500015
NOTFOUND LA    RTRNCODE,4                                               74200015
         B     RETURN                                                   74900015
*                                                                       75600015
*                                                                       76300015
*        LOAD  SUCCESSFUL RETURN CODE AND ADDRESS OF TERMINAL           77000015
* IDENTIFICATION                                                        77700015
*                                                                       78400015
*                                                                       79100015
FOUND    LA    RTRNCODE,0                                               79800015
         LR    TERMID,SRCHBASE          PUT ADDRESS OF FOUND ENTRY      80500015
         ST    TERMID,24(13)              IN REGISTER 1 AND RETURN IT   81200015
RETURN   ST    RTRNCODE,16(13)     RETURN TO CALLING ROUTINE            81900015
         RETURN (14,12)                                                 82600015
*                                                                       83300015
**************                                              *********** 84000015
*                                                                       84700015
*        CONSTANTS                                                      85400015
*                                                                       86100015
SAVE     DC    3F'0'               SAVE AREA                            86800015
*                                                                       87500015
*        ADCONS                                                         88200015
*                                                                       88900015
ADTLENT  DC    A(IHKCDTLN)         ADDRESS OF TABLE LENGTH              89600015
ADTNUMB  DC    A(IHKCDTNB)         ADDRESS OF NUMBER OF ENTRIES         90300015
ADTDIR   DC    A(IHKCDTDR)         ADDRESS OF TERMINAL DIRECTORY        91000015
*                                                                       91700015
**************                                              *********** 92400015
*        DSECT DEFINING TERMINAL DIRECTORY                              93100015
**************                                              *********** 93800015
TDIREC   DSECT                                                          94500015
TDIRTERM DS    CL8                 TERMINAL IDENTIFICATION              95200015
TDIRUSID DS    CL3                 USER IDENTIFICATION                  95900015
TDIRSTAT DS    C                   STATUS BYTE                          96600015
TDIRRB   DS    C                   RETAIN PERIOD BYTE                   97300015
         EXTRN IHKCDTDR,IHKCDTNB,IHKCDTLN                               98000015
         END                                                            98700015
