         TITLE 'IHKCCPLM-FREEPOOL MANAGER'                              00200016
IHKCCPLM CSECT                                                          00230021
*D 648000-660000                                                 A37764 00260021
*A 223000,647000-658000                                          A37764 00290021
*D 200000-201200                                                 A37779 00320021
*C 488000-490000                                                 A37779 00350021
*C649000                                                         A55181 00370021
*D651000-659000                                                  A58978 00377021
*A651000                                                         A58978 00384021
*C649000                                                         A58978 00391021
*ROUTINE NAME                                                         * 00400016
*   FREEPOOL MANAGER                                                  * 00600016
*                                                                     * 00800016
* STATUS: CHANGE LEVEL 2, RELEASE 21.7                                * 01100021
*                                                                     * 01400016
*FUNCTION/OPERATION                                                   * 01600016
*   THIS ROUTINE SUPPLIES QUEUE ENTRY BLOCKS (QEB) TO THE VARIOUS     * 01800016
*   MODULES WHICH BUILD QUEUE ENTRYS FOR THE RJE INPUT AND OUTPUT     * 02000016
*   STREAMS. THESE QEB ARE MAINTAINED IN THE RJE FREEPOOL, A BUFFER   * 02200016
*   POOL CONSISTING OF TWO SUBPOOLS. THE CORE FOR THE BUFFER POOL AND * 02400016
*   POOL CONTROL LISTS FOR EACH SUBPOOL IS SEPARATELY ASSEMBLED IN THE* 02600016
*   FREEPOOL MODULE. THIS MODULE IS CONTROLLED AND ACCESSED ONLY BY   * 02800016
*   THE FREEPOOL MANAGER.                                             * 03000016
*                                                                     * 03200016
*ENTRY POINTS                                                         * 03400016
*        IHKCCPLM-THIS LABEL IS THE ONLY ENTRY POINT. ENTRY IS MADE   * 03600016
*   FOR THE PURPOSE OF RETURNING A QEB TO A SUBPOOL (A RELEASE        * 03800016
*   REQUEST), OR FOR OBTAINING A QEB FROM A SUBPOOL (RETRIEVE REQUEST)* 04000016
*   THE CALLING SEQUENCE IN EITHER CASE MIGHT BE-                     * 04200016
*              L    2,ADDRESS SPECIFYING WHICH POOL.                  * 04400016
*              L    3,ADDRESS SPECIFYING RETRIEVE OR RELEASE.         * 04600016
*              CALL IHKCCPLM,((2),(3))                                * 04800016
*                                                                     * 05000016
*   AS ILLUSTRATED BY THE CALLING SEQUENCE, PARAMETERS ARE PASSED TO  * 05200016
*   THIS ROUTINE BY MEANS OF A TWO FULL WORD PARAMETER LIST POINTED   * 05400016
*   TO BY REGISTER 1. THE FIRST FULL WORD CONTAINS AN ADDRESS SPECIFY-* 05600016
*   ING WHICH POOL - BINARY ZERO FOR MESSAGE BLOCKS - AND ANY OTHER   * 05800016
*   NONZERO ADDRESS FOR JOB BLOCKS. THE SECOND FULL WORD CONTAINS AN  * 06000016
*   ADDRESS SPECIFYING THE OPERATION - BINARY ZERO IF A BLOCK IS TO BE  06200016
*   RETRIEVED AND - THE ADDRESS OF THE BLOCK, IF IT IS BEING RETURNED.* 06400016
*INPUT                                                                * 06600016
*   NO INPUT OTHER THAN THE PARAMETERS DESCRIBED ABOVE.               * 06800016
*                                                                     * 07000016
*OUTPUT                                                               * 07200016
*   A RETRIEVE REQUEST OR A RELEASE REQUEST HAS BEEN SERVICED.        * 07400016
*                                                                     * 07600016
*EXTERNAL ROUTINES                                                    * 07800016
*        IHKCAOSR-OVERLOAD SAFETY ROUTINE. THIS ROUTINE IS ENTERED TO * 08000016
*   CLEAR THE TERMINAL QUEUE OF A TERMINAL IN A STATE OF MALFUNCTION  * 08200016
*   AT THE SAME TIM E A BLOCK REQUEST FINDS AN EMPTY SUBPOOL.         * 08400016
*        IHKCCFP1-RJE FREEPOOL-THIS IS NOT AN EXECUTABLE MODULE.      * 08600016
*   HOWEVER, THE ACTUAL CORE SPACE USED AS A BUFFER POOL FROM WHICH   * 08800016
*   TO OBTAIN QUEUE ENTRY BLOCKS IS ASSEMBLED WITHIN THE EXTERNAL     * 09000016
*   FREEPOOL MODULE. THIS MODULE MUST BE LINKAGE EDITED WITH THE      * 09200016
*   FREEPOOL MANAGER. THIS SUPPLIES THE FREEPOOL MANAGER WITH THE     * 09400016
*   ADDRESSES OF THE LABELS IHKCCFP1,IHKCCFP2 FOUND IN THE FREEPOOL   * 09600016
*   MODULE. THESE LABELS IDENTIFY THE FIRST BYTE OF THE POOL CONTROL  * 09800016
*   LISTS (PCL) FOR EACH OF SUBPOOLS 1 AND 2, ALLOWING THE FREEPOOL   * 10000016
*   MANAGER TO ACCESS THESE CORE POOLS.                               * 10200016
*                                                                     * 10400016
*        IHKAADSP-RJE DISPATCHER. THIS ROUTINE IS ENTERED TO WAIT FOR * 10600016
*   REPLENISHMENT OF BLOCKS WHEN A SUBPOOL IS EMPTY. IT IS ALSO       * 10800016
*   ENTERED IF A REQUEST FOR BLOCKS FROM A PARTICULAR SUBPOOL IS MADE * 11000016
*   BY ONE SUBTASK FOLLOWING A REQUEST FOR THE SAME KIND OF BLOCKS BY * 11200016
*   ANOTHER SUBTASK WHICH REQUIRES A WAIT EXIT TO THE DISPATCHER.THIS * 11400016
*   SECOND TYPE OF ENTRY TO THE DISPATCHER IS A WAIT FOR THE GATE TO  * 11600016
*   THIS ROUTINE TO BE OPENED, AS OPPOSED TO A WAIT FOR BLOCKS. IT IS * 11800016
*   TO BE NOTED THAT A CLOSED GATE TO ONE SUBPOOL DOES NOT PREVENT    * 12000016
*   THE SERVICING OF A REQUEST FOR BLOCKS FROM ANOTHER SUBPOOL, PRO-  * 12200016
*   VIDED THIS SUBPOOL IS NOT ALSO EMPTY.                             * 12400016
*                                                                     * 12600016
*EXITS-NORMAL                                                         * 12800016
*   AFTER A RETRIEVE REQUEST-UPON EXIT REGISTER 1 CONTAINS THE ADDRESS* 13000016
*   OF THE QEB BEING SUPPLIED TO THE CALLING ROUTINE.                 * 13200016
*   IN ANY EVENT REGISTER 15 CONTAINS A ZERO RETURN CODE. REGISTER 1  * 13400016
*   IS CHANGED.                                                       * 13600016
*EXITS-ABNORMAL                                                       * 13800016
*   WAIT FOR BLOCKS EXIT-EXIT TO THE DISPATCHER TO WAIT FOR BLOCKS    * 14000016
*   FROM A PARTICULAR SUBPOOL TO BE RETURNED. THE ECBS FOR SUCH AN    * 14200016
*   ENTRY TO THE DISPATCHER ARE CONTAINED IN AND POSTED BY THIS       * 14400016
*   ROUTINE.                                                          * 14600016
*   WAIT FOR GATE EXIT-EXIT TO THE DISPATCHER TO WAIT FOR THE RELEASE * 14800016
*   OF THIS ROUTINE BY ANOTHER SUBTASK.                               * 15000016
*                                                                     * 15200016
*                                                                     * 15400016
*TABLES/WORK AREAS                                                    * 15600016
*   A SEPARATE SAVE AREA IS REQUIRED FOR WAITING ON BLOCKS FOR EACH   * 15800016
*   SUBPOOL. A 4 WORD DUMMY SAVE AREA IS REQUIRED FOR SAVE AREA       * 16000016
*   CHAINING ON ENQUEUE REQUESTS.  THE THREE SAVE AREAS ARE           * 16200016
*   REQUIRED BECAUSE THIS ROUTINE MUST  HAVE THE ABILITY TO           * 16400016
*   SIMULTANEOUSLY PERFORM THREE SEPARATE FUNCTIONS FOR AS MANY       * 16600016
*   SUBTASKS.                                                         * 16800016
*                                                                     * 17000016
*ATTRIBUTES                                                           * 17200016
*   THIS ROUTINE IS SERIALLY REUSABLE. THE NUMBER OF QEB IN A         * 17400016
*   IN A SUBPOOL MUST BE DETERMINED BY REASSEMBLY OF THIS MODULE      * 17600016
*   PRIOR TO SYSTEM STARTUP.  A WAIT OCCURS                           * 17800016
*   IN THIS ROUTINE WHEN A RETRIEVE REQUEST COINCIDES WITH AN         * 18000016
*   EMPTY SUBPOOL OR A CLOSED GATE TO A SUBPOOL. EITHER WAIT CONSISTS * 18200016
*   OF AN EXIT TO THE DISPATCHER, AND IS NOT A HARD WAIT.             * 18400016
*                                                                     * 18600016
*NOTES                                                                * 18800016
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR    * 19000016
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 19200016
*                                                                     * 19400016
*   THE ECB'S IN THE ECBLIST ARE EXPECTED TO BE CONSECUTIVE.          * 19600016
*                                                                     * 19800016
         SPACE                                                          20200016
         ENTRY IHKCCECB                                                 20400016
         EXTRN IHKCCFP1,IHKCCFP2                                        20600016
         EXTRN IHKCACOM                                                 20800016
         SPACE                                                          21000016
*                                                                       21200016
*  GENERAL REGISTER USAGES                                              21400016
*                                                                       21600016
R15      EQU   15                  ENTRY POINT AND RETURN CODE REGISTER 21800016
R14      EQU   14                  RETURN POINT REGISTER                22000016
R13      EQU   13                  SAVE AREA REGISTER                   22200016
R12      EQU   12                  NOT USED                      A37764 22300021
BASE     EQU   12                  BASE REGISTER FOR PROGRAM            22400016
R10      EQU   10                  UTILITY REGISTER                     22600016
TEMP     EQU   9                   UTILITY REGISTER                     22800016
BUSYREG  EQU   8                   REGISTER FOR ADDRESSING BUSY FLAG    23000016
ECBREG   EQU   7                   REGISTER FOR POSTING ECB OF A        23200016
*                                  SUBTASK WAITING FOR BLOCKS FROM A    23400016
*                                  PARTICULAR SUBPOOL AT THE TIME SOME  23600016
*                                  OTHERSUBTASK FREES SUCH A BLOCK.     23800016
R6       EQU   6                   UTILITY REGISTER                     24000016
R5       EQU   5                   UTILITY REGISTER                     24200016
R4       EQU   4                   UTILITY REGISTER                     24400016
R3       EQU   3                        ADDRESS OF IHKCACOM             24600016
LIST     EQU   2                   SUBPOOL LIST ADDRESS REGISTER        24800016
R1       EQU   1                   PARAMETER REGISTER AT ENTRY AND EXIT 25000016
R0       EQU   0                   PARAMETER REGISTER AT ENTRY          25200016
STPRJE   EQU   B'10000000'                                              25400016
OFF      EQU   0                                                        25600016
STPRJEND EQU   X'08'               RJENDSWITCH-DEQ MSGS ONLY            25800016
CNTU     EQU   B'01100000'         USED TO CHECK FOR CONTINUE           26000016
         SPACE 3                                                        26200016
IHKCCPLM CSECT                                                          26400016
*                                                                       26600016
*  PRELIMINARY MANIPULATIONS                                            26800016
*                                                                       27000016
         SAVE  (14,12),,11/8/IHKCCPLM                                   27200016
         BALR  BASE,0              ESTABLISH ADDRESSIBILITY  USING      27400016
         USING *,BASE              REGISTER 12 AS BASE                  27600016
         SPACE 3                                                        27800016
         USING IHKZZCVT,R3              COMMUNICATIONS REGION           28000016
         L     R3,PARMLIST              ADDRESS OF COMMUNICATION REGION 28200016
***                                                                **** 28400016
*  THE TYPE OF QUEUE ENTRY BLOCK TO CHANGE HANDS WILL NOW BE DETERMINED 28600016
***                                                                **** 28800016
         SPACE                                                          29000016
         L     R4,0(R1)                                                 29200016
         LTR   R4,R4               TEST TO DETERMINE WHICH POOL.        29400016
         BNZ   SMALL               BRANCH IF JOB BLOCK DESIRED.         29600016
*                                  IF THE BRANCH IS NOT TAKEN, A        29800016
*                                  QUEUE ENTRY BLOCK FOR A SYSTEM       30000016
*                                  MESSAGE IS DESIRED.                  30200016
         SPACE                                                          30400016
         L     LIST,SUBPOOL1       LOAD LIST REGISTER WITH THE ADDRESS  30600016
*                                  OF THE LIST FOR SUBPOOL 1 OF THE     30800016
*                                  FREEPOOL.                            31000016
         LA    TEMP,MYSAVE1        SET UP SAVE AREA REGISTER.           31200016
         LA    ECBREG,MSGECB       ESTABLISH ADDRESSIBILITY FOR THE     31400016
         LA    BUSYREG,BUSYBYTM    MESSAGE POOL EVENT CONTROL BLOCK     31600016
*                                  AND BUSY FLAG.                       31800016
         SPACE                                                          32000016
***                                                                **** 32200016
*  IT WILL NOW BE DETERMINED WHETHER A BLOCK IS BEING REQUESTED FROM A  32400016
*  SUBPOOL, OR BEING RETURNED TO A SUBPOOL.                             32600016
***                                                                **** 32800016
         SPACE                                                          33000016
TEST     L     R1,4(R1)            GET OPERATION INDICATOR              33200016
         LTR   R1,R1               TEST OPERATION INDICATOR             33400016
         BNZ   ADDEL               BRANCH IF REGISTER  1 IS NOT         33600016
*                                  ZERO TO ADD A BLOCK TO A SUBPOOL.    33800016
         SPACE                                                          34000016
***                                                                 *** 34200016
*  A BLOCK IS TO BE REMOVED FROM A SUBPOOL, IF ONE IS AVAILABLE.        34400016
*  THE BUSY FLAG FOR THIS SUBPOOL MUST BE TESTED TO SEE IF ANOTHER    * 34600016
*  SUBTASK IS ALREADY WAITING FOR BLOCKS FROM THIS SUBPOOL.           * 34800016
***                                                                 *** 35000016
         SPACE                                                          35200016
         TS    0(BUSYREG)          TEST BUSY FLAG AND SET IF NOT SET.   35400016
         BC    7,GATE              BRANCH IF GATE IS CLOSED.            35600016
         ST    R13,4(TEMP)         CHAIN THE SAVE AREAS AND             35800016
         ST    TEMP,8(R13)         SET POINTER TO MY SAVE AREA IN       36000016
         LR    R13,TEMP            REGISTER 13.                         36200016
WAITRET  LH    R5,4(LIST)                                          000A 36400016
         LTR   R5,R5               TEST SUBPOOL LIST BLOCK COUNT   000A 36600016
         BZ    WAIT                BRANCH TO WAIT IF SUBPOOL IS EMPTY.  36800016
         SPACE                                                          37000016
***                                                                **** 37200016
*  A BLOCK IS NOW AVAILABLE IN THE SUBPOOL AND CAN BE REMOVED.          37400016
***                                                                **** 37600016
         SPACE                                                          37800016
REMFEL   L     R1,0(LIST)          PLACE ADDRESS OF BLOCK TO BE REMOVED 38000016
*                                  IN REGISTER 1.                       38200016
         MVC   0(4,LIST),0(R1)     CHANGE THE POINTERS                  38400016
         LH    R10,4(LIST)         GET BLOCK COUNT                 8207 38600000
         BCTR  R10,R0              DECREMENT THE COUNT OF THE      8207 38800000
         STH   R10,4(LIST)         BLOCKS KEPT IN THE SUBPOOL LIST 8207 39000000
         TM    STPSW,STPRJE             CHECK TO SEE IF THIS BLOCK IS   39400016
*                                       BEING REMOVED TO BE USED AS A   39600016
*                                       DUMMY QEB                       39800016
         BO    ENQDUM                   BRANCH IF THIS IS THE CASE      40000016
         SPACE                                                          40200016
         NI    0(BUSYREG),X'0'     TURN OFF BUSY FLAG FOR THIS SUBPOOL. 40400016
         SPACE                                                          40600016
         SPACE                                                          40800016
RETURN   L     R13,4(R13)          MAKE SURE CONTENTS OF REGISTER 1   * 41000016
         ST    R1,24(R13)          GO BACK TO CALLER                    41200016
         RETURN (14,12),T,RC=0      SET ZERO RETURN CODE.               41400016
         SPACE                                                          41600016
SMALL    L     LIST,SUBPOOL2       LOAD LIST REGISTER WITH THE ADDRESS  41800016
*                                  OF THE LIST OF SUBPOOL 2 OF THE      42000016
*                                  FREEPOOL.                            42200016
         LA    TEMP,MYSAVE2        SET UP SAVE AREA REGISTER.           42400016
         LA    ECBREG,JOBECB       ESTABLISH ADDRESSIBILITY FOR THE     42600016
         LA    BUSYREG,BUSYBYTJ    JOB POOL EVENT CONTROL BLOCK AND     42800016
*                                  BUSY FLAG.                           43000016
         B     TEST                BRANCH TO TEST                       43200016
         SPACE                                                          43400016
***                                                                **** 43600016
*  A BLOCK IS TO BE ADDED TO A SUBPOOL.                                 43800016
***                                                                **** 44000016
         SPACE                                                          44200016
ADDEL    ST    R13,MYSAVE+4        CHAIN THE SAVE AREAS OF              44400016
         LA    TEMP,MYSAVE         CALLING AND CALLED ROUTINE           44600016
         ST    TEMP,8(R13)         TOGETHER.                            44800016
         LR    R13,TEMP                                                 45000016
         L     LIST,SUBPOOL1       LOAD MSG SUBPOOL              A29512 45030020
         TM    0(R1),X'80'         TEST IF MSG QEB              A29512  45060020
         BO    USEIT               YES USE MSG SUBPOOL           A29512 45090020
         L     LIST,SUBPOOL2       LOAD JOB SUBPOOL              A29512 45120020
USEIT    EQU   *                                                 A29512 45150020
         MVC   0(4,R1),0(LIST)     ADD THE BLOCK POINTED TO BY REGISTER 45200016
         MVI   0(R1),OFF          SET INDICATOR FLAG OFF         A32860 45300020
         ST    R1,0(LIST)          1 TO THE SUBPOOL BY CHANGING THE     45400016
*                                  LIST AND BLOCK LINK POINTERS         45600016
         LA    LIST,4(LIST)                                             45800016
         LH    R6,0(LIST)          INCREMENT THE COUNT OF               46000016
         LA    R5,1                THE NUMBER OF BLOCKS IN THE          46200016
         AR    R6,R5               SUBPOOL KEPT IN                      46400016
         STH   R6,0(LIST)          THE SUBPOOL LIST                     46600016
         OI    0(ECBREG),X'40'     POST THE ECB OF ANY SUBTASK WAITING  46800016
*                                  FOR THE BLOCK JUST RELEASED.         47000016
         B     RETURN              BRANCH TO RETURN                     47200016
WAIT     L     R4,TDIRBGN          GET ADDRESS OF TERMINAL DIRECTORY    47400016
         USING TDIREC,R4           ESTABLISH ADDRESSIBILITY OF DUMY     47600016
*                                  CONTROL SECTION MAP                  47800016
         L     R5,TDIRLGTH         GET LENGTH OF A TERMINAL             48000016
         LH    R5,0(R5)            DIRECTORY ENTRY.                     48200016
         L     R6,TDIRNUMB         GET NUMBER OF ENTRIES IN THE         48400016
         LH    R6,0(R6)            TERMINAL DIRECTORY.                  48600016
         SR    TEMP,TEMP               ZERO OUT TEMP             A37779 48800021
         BCTR  TEMP,R0                 SET TEMP TO -1            A37779 49000021
         SPACE                                                          49200016
***                                                                 *** 49400016
*  A SEARCH FOR TERMINALS HAVING A MECHANICAL FAILURE IS TO BE MADE.  * 49600016
***                                                                 *** 49800016
         SPACE                                                          50000016
LOOP     BXLE  R6,TEMP,OUT         SEARCH LOOP-BRANCH IF DIRECTORY END. 50200016
         MVI   STPSW,OFF                INITIALIZE INTERNAL STOP SWITCH 50400016
MORE     TM    TDIRSTAT,X'04'      TEST FOR MECHANICAL FAILURE.         50600016
         BO    SAFETY              BRANCH IF DEQUEUE NOTHING BIT SET.   50800016
         TM    TDIRSTAT,STPRJEND   CHECK FOR RJEND RECEIVED BY C/E      51000016
         BO    STOP                BRANCH IF RECEIVED                   51200016
         TM    TDIRSWCH+1,X'80'         CHECK FOR DISCONTINUE           51400016
         BO    DISCONTU            CHECK FOR  CONTINUE                  51600016
         L     R1,IHKZZRCS              ADDRESS OF STOP SWITCH          51800016
         TM    0(R1),X'08'             TEST READER WARMSTART SWITCH     52000016
         BO    SAFETY                  BRANCH IF ON                     52200016
         TM    0(R1),STPRJE             CHECK FOR STOP RJE SITUATION    52400016
         BZ    INACTIVE                 BRANCH IF NOT STOP SITUATION    52600016
STOP     EQU   *                                                        52800016
         OI    STPSW,STPRJE             TURN ON INTERNAL STOP SWITCH    53000016
         B     SAFETY                                                   53200016
         SPACE                                                          53400016
INACTIVE AR    R4,R5               UPDATE TO NEXT ENTRY.                53600016
         B     LOOP                LOOP BACK.                           53800016
         SPACE 3                                                        54000016
*TERMINAL IS DISCONTINUED, CHECK FOR CONTINUE RECEIVED. IF RECEIVED,    54200016
*IGNORE THE DISCONTINUE AND CONTINUE SEARCH THROUGH TERMINAL DIRECTORY. 54400016
         SPACE                                                          54600016
DISCONTU EQU   *                                                        54800016
         TM    TDIRSWCH+1,CNTU     CHECK FOR CONTINUE                   55000016
        BNZ   INACTIVE            BRANCH IF CONTINUE RECEIVED           55200016
         SPACE                                                          55400016
SAFETY  EQU   *                                                         55600016
         CLC   TDIRFQEB+1(3),ZERO  TEST FOR EMPTY QUEUE.                55800016
         BE    INACTIVE            BRANCH IF EMPTY QUEUE.               56000016
         SPACE                                                          56200016
***                                                                 *** 56400016
*  A MALFUNCTIONING TERMINAL WITH A NONEMPTY QUEUE HAS BEEN FOUND. THE* 56600016
*  OVERLOAD SAFETY ROUTINE IS CALLED TO CLEAR THIS QUEUE.             * 56800016
***                                                                 *** 57000016
         LOAD  EP=IHKCAOSR                                              57200016
         L     R1,PARMLIST         ADDRESS OF PARAMETER LIST-IHKCACOM   57400016
         ST    R4,0(R1)            SET UP PARM LIST.                    57600016
         LR    R15,R0                   LOAD ENTRY POINT                57800016
         BALR  R14,R15                  BRANCH TO ROUTINE               58000016
         DELETE EP=IHKCAOSR                                             58200016
         SPACE 3                                                        58400016
*CHECK TO MAKE SURE THERE ARE QEBS AVAILABLE NOW                        58600016
         SPACE                                                          58800016
RETEST   EQU   *                                                        59000016
         LH    R10,4(LIST)                                              59200016
         LTR   R10,R10             TEST FOR EMPTY SUBPOOL.              59400016
         BNZ   REMFEL              BRANCH IF NOT EMPTY.                 59600016
         B     INACTIVE            TRY NEXT ENTRY IN THE TDIR      8207 59800000
         SPACE 3                                                        60000016
*THE QEBS WERE DEPLETED WHILE THE C/E WAS WAITING FOR A STOP COMMAND TO 60200016
*BE PROCESSED. THE QEBS HAVE BEEN CLEARED FROM THE FIRST TERMINAL       60400016
*HAVING ANYTHING ENQUEUED. NOW A DUMMY QEB WILL BE ENQUEUED SO THAT     60600016
*LINE ANALYSIS WRITE WILL SEND ALL MESSAGES TO THE TERMINAL BEFORE      60800016
*CLOSING DOWN.                                                          61000016
         SPACE                                                          61200016
ENQDUM   EQU   *                                                        61400016
         MVI   STPSW,OFF           TURN OFF INTERNAL STOP SWITCH        61600016
         MVI   0(R1),DUMQEB        INDICATE TYPE OF QEB                 61800016
         ST    R4,QMGTDIR          TERMINAL WHERE QEB IS TO BE ENQUEUED 62000016
         ST    R1,QMGQEB           ADDRESS OF QEB                       62200016
         LA    R1,QMGPARM          ADDRESS OF PARAMETER LIST            62400016
         L     R15,IHKZZQMG        ADDRESS OF Q-MGR                     62600016
         BALR  R14,R15             ENQUEUE DUMMY QEB                    62800016
         B     RETEST              GO CHECK TO SEE IF THERE ARE STILL   63000016
*                                  QEBS AVAILABLE                       63200016
         SPACE                                                          63400016
***                                                                 *** 63600016
*  THE POOL IS EMPTY AND NO TERMINAL HAVING A MECHANICAL FAILURE HAS  * 63800016
*  BLOCKS FROM THIS POOL ON ITS QUEUE. THE DISPATCHER MUST BE ENTERED * 64000016
*  TO WAIT FOR BLOCKS TO BE RETURNED TO THIS SUBPOOL.                 * 64200016
***                                                                 *** 64400016
         SPACE                                                          64600016
OUT      EQU   *                                                 A37764 64700021
         MVI   STPSW,OFF           TURN OFF STOP SWITCH          A37779 64800021
         LA    R15,WAITRET             SET RETURN ADDRESS        A58978 64900021
         STM   R14,R12,12(R13)     STORE REGS FOR RETURN TO      A37764 65000021
*                                      WAITRET                   A58978 65100021
*                                                                       66200016
         SPACE                                                          66400016
***                                                                 *** 66600016
*  THE DISPATCHER IS TO BE ENTERED BECAUSE THE BUSY FLAG WAS SET.     * 66800016
***                                                                 *** 67000016
         SPACE                                                          67200016
GATE     SR    R14,R14             SET REGISTERS FOR SPECIAL ENTRY      67400016
         L     R15,AADSP           TO THE DISPATCHER                    67600016
         BR    R15                 AND EXIT.                            67800016
*  PROGRAM SECTION FOR SAVE AREA,WORKING STORAGE, AND CONSTANTS .       68000016
*                                                                       68200016
         SPACE                                                          68400016
SUBPOOL1 DC    A(IHKCCFP1)         ADDRESSES OF THE SUBPOOL LISTS FOR   68600016
SUBPOOL2 DC    A(IHKCCFP2)         SUBPOOLS 1 AND 2 OF THE FREEPOOL.    68800016
         SPACE 3                                                        69000016
*ECB LIST-BOTH ECB'S ARE POSTED COMPLETE EVERY TIME THERE IS A LINE     69200016
*FAILURE OR A DISCONTINUE. IF THE POOL MGR IS WAITING IN THE DISPATCHER 69400016
*FOR A QEB TO FREED UP, IT WILL RECEIVE CONTROL,CHECK THE BITS          69600016
*(TDIRSTAT,X'04' AND TDIRSWCH+1,X'80'),FREE THE QEB'S AND CONTINUE      69800016
*PROCESSING. IF THE POOL MGR IS NOT WAITING,THE POSTING WILL HAVE NO    70000016
*EFFECT.                                                                70200016
         SPACE                                                          70400016
IHKCCECB DS    0F                                                       70600016
MSGECB   DC    F'0'                ECB FOR SUBTASKS WAITING FOR         70800016
*                                  MESSAGE BLOCKS.                      71000016
JOBECB   DC    F'0'                ECB FOR JOB BLOCKS SUBPOOL.          71200016
BUSYBYTM DC    X'00'               BUSY FLAG FOR MESSAGE SUBPOOL.       71400016
BUSYBYTJ DC    X'00'               BUSYFLAG FOR JOB BLOCKS. A HEX 80    71600016
DUMQEB   EQU   X'84'                                                    71800016
*                                  IS MOVED INTO A BUSY FLAG TO         72000016
*                                  INDICATE A WAIT CONDITION. OTHERWISE 72200016
*                                  IT IS BINARY ZERO.                   72400016
         SPACE                                                          72600016
STPSW    DC    X'0'                INTERNAL STOP SWITCH                 72800016
         SPACE                                                          73000016
MYSAVE1  DS    18F                 SAVE AREA FOR SUBPOOL1.              73200016
MYSAVE2  DS    18F                 SAVE AREA FOR SUBPOOL2.              73400016
MYSAVE   DS    4F                  DUMMY SAVE AREA FOR CHAININF ON      73600016
*                                  ENQUEUE REQUESTS.                    73800016
         SPACE                                                          74000016
         SPACE                                                          74200016
PARMLIST DC    A(IHKCACOM)         ADDRESS OF PARAMETER LIST            74400016
ZERO     DC    F'0'                BINARY ZERO                          74600016
         SPACE 3                                                        74800016
*PARAMETER LIST FOR Q-MGR TO ENQUEUE DUMMY QEB                          75000016
         SPACE                                                          75200016
QMGPARM  DS    0F                                                       75400016
QMGTDIR  DC    F'0'                ADDRESS OF TDIR ENTRY                75600016
QMGQEB   DC    F'0'                ADDRESS OF QEB                       75800016
         SPACE 3                                                        76000016
*DSECT FOR COMMUNICATIONS REGION                                        76200016
         SPACE                                                          76400016
IHKZZCVT DSECT                                                          76600016
         DS    2F                                                       76800016
AADSP    DS    V                   DISPATCHER ENTRY POINT               77000016
         DS    18F                                                      77200016
TDIRBGN  DS    A                   BEGINNING OF TERMINAL DIRECTORY      77400016
TDIRLGTH DS    A                   LENGTH OF TDIR ENTRY                 77600016
TDIRNUMB DS    A                   NUMBER OF TDIR ENTRIES               77800016
         DS    16F                                                      78000016
IHKZZRCS DS    F                                                        78200016
IHKZZQMG DS    F                                                        78400016
         SPACE                                                          78600016
TDIREC   DSECT                                                          78800016
TDIRTERM DS    CL8                 TERMINAL IDENTIFICATION.             79000016
         DS    CL3                                                      79200016
TDIRSTAT DS    C                   TERMINAL STATUS BYTE.                79400016
         DS    C                                                        79600016
         DS    CL3                                                      79800016
TDIRFQEB DS    CL4                 FIRST QUEUE ENTRY BLOCK ADDRESS.     80000016
         DS    CL8                                                      80200016
         DS    CL7                                                      80400016
         DS    C                                                        80600016
TDIRSWCH DS    CL3                                                      80800016
         END                                                            81000016
