         TITLE ' IHKCCSCN-SCAN1'                                      * 00500015
*STATUS                                                               * 01000015
*   CHANGE LEVEL 0.                                                   * 01500015
*                                                                     * 02000015
*FUNCTION/OPERATION                                                   * 02500015
*   GIVEN A CHARACTER STRING AND A STARTING LOCATION, THIS ROUTINE    * 03000015
*   SCANS IN THE DIRECTION OF HIGH CORE STORAGE, THE SCAN TERMINATING * 03500015
*   WITH THE FIRST CHARACTER OBSERVED WHICH BELONGS TO THE CHARACTER  * 04000015
*   STRING. ALTERNATIVELY, A SCAN MAY BE MADE FOR THE FIRST NON-BLANK * 04500015
*   CHARACTER. THE USER MUST SPECIFY EITHER A MAXIMUM NUMBER OF       * 05000015
*   CHARACTERS OVER WHICH TO SCAN, OR ELSE THE ADDRESS OF A STOPPING  * 05500015
*   LOCATION PAST WHICH NO SCANNING IS TO BE DONE.                    * 06000015
*                                                                     * 06500015
*ENTRY POINTS                                                         * 07000015
*        IHKCCSCN-SCAN FOR FIRST NONBLANK OR FIRST OBSERVED CHARACTER * 07500015
*   OF A CHARACTER STRING.  THIS IS THE ONLY ENTRY POINT.  THE CALLING* 08000015
*   SEQUENCE MIGHT BE    LA   1,PARAMETER LIST                        * 08500015
*                        CALL IHKCCSCN.                               * 09000015
*   UPON ENTRY TO THIS ROUTINE STANDARD SUBROUTINE LINKAGES PREVAIL.  * 09500015
*   INPUT PARAMETERS ARE PASSED VIA A PARAMETER LIST WHOSE ADDRESS IS * 10000015
*   IN REGISTER 1. THE LIST MUST BE ALIGNED ON A FULL WORD BOUNDARY.  * 10500015
*   THE CONTENTS OF THE PARAMETER LIST ARE DEFINED AS FOLLOWS-        * 11000015
*   1.THE FIRST HALFWORD CONTAINS THE MAXIMUM SCAN LENGTH. IF A       * 11500015
*     STOPPING ADDRESS IS SPECIFIED IN THE THIRD FULL WORD, THIS HALF * 12000015
*     WORD MUST CONTAIN BINARY ZEROES.                                * 12500015
*   2.THE SECOND HALF WORD CONTAINS THE NUMBER OF CHARACTERS TO WHICH * 13000015
*     SCAN1 IS SENSITIVE. IF THIS NUMBER IS BINARY ZERO, SCAN1        * 13500015
*     SEARCHES FOR THE FIRST NONBLANK CHARACTER.                      * 14000015
*   3.THE NEXT FULLWORD CONTAINS THE STARTING ADDRESS FOR THE SCAN.   * 14500015
*   4.THE THIRD FULLWORD IS TO CONTAIN THE ADDRESS OF A STOPPING POINT* 15000015
*     FOR THE SCAN. IF A MAXIMUN SCAN LENGTH IS SPECIFIED, THE CONTENT* 15500015
*     OF THIS WORD IS ARBRITRARY.                                     * 16000015
*   5.A CHARACTER STRING C1C2C3...CN CONTAINING THE CHARACTERS TO     * 16500015
*     WHICH SCAN1 IS SENSITIVE BEGINS IN THE FIRST BYTE OF THE FOURTH * 17000015
*     FULLWORD. THE MAXIMUN LENGTH OF THIS CHARACTER STRING IS 12.    * 17500015
*                                                                     * 18000015
*INPUT                                                                * 18500015
*   THE PARAMETER LIST DESCRIBED ABOVE.                               * 19000015
*                                                                     * 19500015
*OUTPUT                                                               * 20000015
*    THE RESULTS OF THE SCAN, DESCRIBED UNDER EXITS.                  * 20500015
*                                                                     * 21000015
*EXITS-NORMAL                                                         * 21500015
*   REGISTER 15 CONTAINS ONE OF THE FOLLOWING INDICATORS-             * 22000015
*   1.ZERO IF NO SENSITIVE CHARACTER OR NON-BLANK WAS FOUND.          * 22500015
*   2.FOUR IF A FIND WAS MADE ON A REQUEST TO SCAN FOR THE FIRST NON- * 23000015
*     BLANK CHARACTER.                                                * 23500015
*   3.4J IF A HIT WAS MADE ON THE J-TH CHARACTER OF THE CHARACTER     * 24000015
*     STRING C1C2C3...CJ...CN.                                        * 24500015
*   REGISTER 1, IN ALL CASES OF A FIND, CONTAINS THE ADDRESS OF THE   * 25000015
*   CHARACTER FOUND. IT CONTAINS ZERO IF NO FIND WAS MADE.            * 25500015
*                                                                     * 26000015
*EXITS-ERROR                                                          * 26500015
*   N/A                                                               * 27000015
*                                                                     * 27500015
*TABLES/WORK AREAS                                                    * 28000015
*   A 256 BYTE WORK AREA LABELLED TRTTAB IS USED TO BUILD A TRANSLATE * 28500015
*   TABLE SENSITIVE TO THE PROPER NUMBER OF CHARACTERS.               * 29000015
*                                                                     * 29500015
*ATTRIBUTES                                                           * 30000015
*   SERIALLY REUSABLE.                                                * 30500015
*                                                                     * 31000015
*NOTES                                                                * 31500015
*   THE OPERATION OF THIS MODULE DEPENDS UPON THE INTERNAL            * 32000015
*   REPRESENTATION OF THE EXISTING EXTERNAL  CHARACTER SET. NAMELY,   * 32500015
*   IF THIS CHARACTER SET WERE ENLARGED, THE TRANSLATE TABLE BUILT    * 33000015
*   UPON ENTRY TO THIS ROUTINE WOULD HAVE TO BE ENLARGED BY CHANGING  * 33500015
*   THE INSTRUCTION                                                   * 34000015
*                   TRTTAB  DS  CL256                                 * 34500015
*   WHICH OCCURS IN THIS PROGRAM.  THIS INSTRUCTION ASSUMES A         * 35000015
*   CHARACTER SET OF 256 CHARACTERS. FURTHER, IF THE POSITION OF THE  * 35500015
*   BLANK CHARACTER WITHIN THE CHARACTER CODE TABLE, WHICH IS ARRANGED* 36000015
*   IN ORDER ACCORDING TO THE DECIMAL EQUIVALENT OF THE HEXADECIMAL   * 36500015
*   REPRESENTATION OF EACH CHARACTER, WERE CHANGED FROM THE SIXTY     * 37000015
*   FOURTH TO SOME OTHER POSITION, THEN THE INSTRUCTION               * 37500015
*        MVI   TRTTAB+64,X'0'                                         * 38000015
*   WOULD HAVE TO BE MODIFIED TO REFLECT THIS NEW POSITION OF THE     * 38500015
*   BLANK CHARACTER. THIS IS THE THIRD INSTRUCTION PRECEDING THE      * 39000015
*   LABEL  -RETURN-.                                                  * 39500015
*                                                                     * 40000015
*                                                                     * 40500015
IHKCCSCN CSECT                                                          41000015
R0       EQU   0                                                        41500015
R1       EQU   1                                                        42000015
R2       EQU   2                                                        42500015
R3       EQU   3                                                        43000015
R4       EQU   4                                                        43500015
R5       EQU   5                                                        44000015
R6       EQU   6                                                        44500015
R7       EQU   7                                                        45000015
R8       EQU   8                                                        45500015
R9       EQU   9                                                        46000015
R10      EQU   10                                                       46500015
R11      EQU   11                                                       47000015
R12      EQU   12                  BASE REG                             47500015
R13      EQU   13                                                       48000015
R14      EQU   14                                                       48500015
R15      EQU   15                                                       49000015
         SAVE  (14,12),,IHKCCSCN                                        49500015
         BALR  R12,0               ESTABLISH ADDRESSIBILITY             50000015
         USING *,R12                                                    50500015
         ST    R13,SAVE+4          STORE ADDRESS OF HIS SAVE IN MY      51000015
*                                  SAVE AREA.                           51500015
         LA    R4,SAVE                                                  52000015
         ST    R4,8(R13)           STORE ADDRESS OF MY SAVE AREA IN     52500015
*                                  HIS SAVE AREA.                       53000015
         LH    R7,2(R1)            GET NUMBER OF SENSITIVE CHARACTERS   53500015
         LTR   R7,R7                                                    54000015
         BNZ   SEVERAL             BRANCH IF NOT SENSITIVE TO ALL       54500015
*                                  EXCEPT BLANK                         55000015
         LA    R6,A                SET SWITCH FOR SCAN LOOP             55500015
         MVI   TRTTAB,X'4'         BUILD TRANSLATE TABLE SENSITIVE TO   56000015
*                                   ALL CHARACTERS EXCEPT BLANK         56500015
         MVC   TRTTAB+1(255),TRTTAB                                     57000015
         MVI   TRTTAB+64,X'0'                                           57500015
         B     SCAN                ENTER SCAN LOOP                      58000015
A        LA    R15,4               SET RETURN CODE FOR HIT ON NON-      58500015
*                                  BLANK                                59000015
RETURN   STM   R15,R1,16(R13)      SET UP RETURN LINKAGE                59500015
         RETURN (14,12),T                                               60000015
SEVERAL  LA    R8,TRTTAB           R8 HAS ADDRESS OF TRT TABLE          60500015
         MVI   0(R8),X'0'                                               61000015
         MVC   1(255,R8),0(R8)    ZERO TRT TABLE                        61500015
         LA    R9,12(R1)          RREGISTER 9 HAS ADDRESS OF FIRST      62000015
*                                  CHARACTER.                           62500015
         LA    R10,1               R10 HAS INCREMENT                    63000015
         LR    R11,R9                                                   63500015
         AR    R11,R7                                                   64000015
         SR    R11,R10             REGISTER 11 HAS ADDRESS OF LAST      64500015
*                                  CHARACTER.                           65000015
         SR    R9,R10              REGISTER 9 HAS ADDRESS OF FIRST      65500015
*                                  CHARACTER MINUS ONE.                 66000015
         SR    R6,R6                                                    66500015
BUILDTAB BXH   R9,R10,BUILT        BRANCH IF TRT TABLE IS BUILT         67000015
         AH    R6,FOUR             SET RETURN CODE                      67500015
         SR    R7,R7                                                    68000015
         IC    R7,0(R9)            GET CHARACTER                        68500015
         AR    R7,R8               GET CHARACTER POSITION IN TRT TABLE  69000015
         STC   R6,0(R7)            PUT RETURN CODE IN TRT TABLE         69500015
         B     BUILDTAB            GO BACK FOR MORE                     70000015
BUILT    LA    R6,B                SET SWITCH FOR SCAN LOOP             70500015
         B     SCAN                ENTER SCAN LOOP                      71000015
B        LR    R15,R2              PUT RETURN CODE IN REGISTER 15       71500015
         B     RETURN              RETURN TO CALLER                     72000015
SCAN     L     R5,4(R1)           SSCAN STARTING ADDRESS REGISTER NOW   72500015
*                                  HAS STARTING POINT.                  73000015
         LA    R4,255              LENGTH REGISTER FOR TRT INSTRUCTION  73500015
*                                  NOW HAS 255                          74000015
         LH    R3,0(R1)            GET MAXIMUN SCAN LENGTH              74500015
         LTR   R3,R3              IIS MAXIMUN SCAN LENGTH SPECIFIED     75000015
         BNZ   ALTER               BRANCH IF SPECIFIED                  75500015
       L       R3,8(R1)           GET STOP SCAN ADDRESS                 76000015
       SR      R3,R5              SUBTRACT START SCAN ADDRESS           76500015
         LTR   R3,R3               CHECK FOR NEGATIVE DIFFERENCE        77000015
         BM    SET                 BRANCH IF NEGATIVE                   77500015
GET      LA    R7,256              GET INTERNAL SCAN DISPLACEMENT       78000015
         SR    R2,R2                                                    78500015
         SR    R1,R1               CLEAR REGISTERS 1 AND 2              79000015
COMPARE  CR    R3,R7                                                    79500015
         BL    LT256               BRANCH IF LESS THAN 256              80000015
*                                  CHARACTERS TO SCAN.                  80500015
         SR    R3,R7               DECREMENT MAXIMUN SCAN LENGTH BY 256 81000015
EXEC     EX    R4,LOOK             SCAN FOR SENSITIVE CHARACTERS.       81500015
         BC    8,MORE              BRANCH IF NO HIT                     82000015
         BR    R6                  BRANCH TO A OR B AS INDICATED BY     82500015
*                                  REGISTER 6                           83000015
LOOK     TRT   0(0,R5),TRTTAB      SCAN INSTRUCTION                     83500015
ALTER    LA    R2,1                MAXIMIM SCAN LENGTH MUST BE          84000015
         SR    R3,R2               DECREMENTED BY ONE                   84500015
         B     GET                                                      85000015
LT256    LR    R4,R3               ALTER SCAN LENGTH                    85500015
         LA    R3,0                SET MORE SWITCH OFF IE MO EQ ZERO    86000015
         B     EXEC                                                     86500015
MORE     LTR   R3,R3                                                    87000015
         BZ    SET                 BRANCH IF NO MORE TO SCAN            87500015
         AR    R5,R7               UPDATE SCAN START ADDRESS            88000015
         B     COMPARE                                                  88500015
SET      EQU   *                                                        89000015
         SR    R15,R15             SET NO HIT RETURN CODE               89500015
         B     RETURN                                                   90000015
*                                                                       90500015
*  PROGRAM SECTION FOR TABLES, SAVE AREAS, CONSTANTS                    91000015
*                                                                       91500015
SAVE     DS    3F                  SAVE AREA                            92000015
TRTTAB   DS    CL256               TRANSLATE AND TEST TABLE             92500015
FOUR     DC    H'4'                                                     93000015
         LTORG                                                          93500015
         ENTRY IHKCCSCN                                                 94000015
         END                                                            94500015
