         TITLE 'IHKCCSGN-SRCHGEN'                                       00300015
IHKCCSGN CSECT                                                          00600015
*********************************************************************** 00900015
*                                                                     * 01200015
*STATUS                                                               * 01500015
*   CHANGE LEVEL 0                                                    * 01800015
*                                                                     * 02100015
*FUNCTION/OPERATION                                                   * 02400015
*   GIVEN A 3 CHARACTER USER PREFIX AND THE ADDRESS OF A SEARCH START-* 02700015
*   ING POINT IN THE FAST TABLE(THE ADDRESS OF THE FIRST BYTE OF A JOB* 03000015
*   ENTRY), THIS ROUTINE SEARCHES THE FAST TABLE FOR THE FIRST JOB FOR* 03300015
*   WHICH THIS USER IS A VALID RECIPIENT OF JOB OUTPUT.  FURTHER      * 03600015
*   AVAILABLE OPTIONS WHICH CONCERN THE ORIGINATOR OF THE JOB AND THE * 03900015
*   JOB STATUS ARE INDICATED BELOW.                                   * 04200015
*                                                                     * 04500015
*ENTRY POINTS                                                         * 04800015
*        IHKCCSGN-SEARCH FAST TABLE FOR THE FIRST JOB MEETING CERTAIN * 05100015
*   CONDITIONS SPECIFIED BY MEANS OF AN INPUT PARAMETER LIST PASSED BY* 05400015
*   THE CALLING ROUTINE. STANDARD SUBROUTINE LINKAGES PREVAIL. IN     * 05700015
*   PARTICULAR, REGISTER 1 CONTAINS THE ADDRESS OF AN INPUT PARAMETER * 06000015
*   LIST, DESCRIBED BELOW. THE CALLING SEQUENCE MIGHT BE:             * 06300015
*                        LA   1,PARAMETER LIST                        * 06600015
*                        CALL IHKCCSGN                                * 06900015
*                                                                     * 07200015
*INPUT                                                                * 07500015
*   THE ONLY INPUT IS THE PARAMETER LIST PASSED BY THE CALLING ROUTINE* 07800015
*   THIS PARAMETER LIST MUST BE ALIGNED ON A FULLWORD BOUNDARY. ITS   * 08100015
*   CONTENTS ARE DEFINED AS-                                          * 08400015
*   1.START LOCATION-THE FIRST FULL WORD CONTAINS THE ADDRESS OF AN   * 08700015
*     ENTRY IN THE FAST TABLE AT WHICH THE SEARCH IS TO START. IF THIS* 09000015
*     WORD CONTAINS BINARY ZERO, THE SEARCH BEGINS AT THE FIRST ENTRY * 09300015
*     IN THE FAST TABLE. THE SEARCH IS A SERIAL SEARCH.               * 09600015
*   2.SOURCE PREFIX-THE NEXT 3 BYTES CONTAIN THE PREFIX OF THE USER   * 09900015
*     WHO SUBMITTED THE JOB BEING SEARCHED FOR BY THIS ROUTINE. IF THE* 10200015
*     SOURCE PREFIX CONTAINS BINARY ZERO, A SEARCH IS MADE FOR A JOB  * 10500015
*     FOR WHICH THE DESTINATION PREFIX IS A VALID RECEIVER, REGARDLESS* 10800015
*     OF BY WHOM THE JOB WAS SUBMITTED.                               * 11100015
*   3.DESTINATION PREFIX-THE NEXT 3 BYTES CONTAIN THE PREFIX OF A USER* 11400015
*     WHO IS A VALID RECEIVER OF THE JOB FOR WHICH A SEARCH IS BEING  * 11700015
*    MADE.  THIIS PREFIX MAY BE IDENTICAL TO THE ORIGINATOR PREFIX,   * 12000015
*     PROVIDED THE ORIGINATOR PROFIX IS NOT ZERO, EXCEPT IN THOSE     * 12300015
*     CASES SPECIFIED BELOW.                                          * 12600015
*   4.THE LAST BYTE CONTAINS A CHARACTER DESIGNATING THE JOB STATUS   * 12900015
*     OPTION-STATE OF COMPLETION-CHOSEN BY THE CALLING ROUTINE-       * 13200015
*     C-SEARCH FOR THE FIRST JOB FOR WHICH THE DESTINATION PREFIX IS  * 13500015
*       A VALID RECEIVER OF JOB OUTPUT. THE JOB MAY BE IN ANY STAGE   * 13800015
*       OF COMPLETION OR DELIVERY.                                    * 14100015
*     O-SEARCH FOR THE FIRST COMPLETED JOB FOR WHICH THE DESTINATION  * 14400015
*       PREFIX IS A VALID RECEIVER, BUT WHICH IS NOT ALREADY ENQUEUED * 14700015
*       FOR DELIVERY. SUCH A JOB WILL BE REFERRED TO AS A TYPE N JOB. * 15000015
*     A-SEARCH FOR THE FIRST TYPE N JOB FOR WHICH THE DESTINATION     * 15300015
*       PREFIX IS NOT ALREADY NOTIFIED OR ALERTED.                    * 15600015
*     T-SEARCH FOR THE FIRST TYPE N JOB FOR WHICH THE NOTIFY PENDING  * 15900015
*       RJSTART BIT IS SET TO ONE AND FOR WHICH THE SOURCE HAS NOT    * 16200015
*       BEEN NOTIFIED. IN THIS CASE THE SOURCE AND DESTINATION  PRE-  * 16500015
*       FIXES MUST BE IDENTICAL.                                      * 16800015
*     L-SEARCH FOR THE FIRST TYPE N JOB FOR WHICH ONE OF THE NOTIFY   * 17100015
*       PENDING LOGON OR NOTIFY PENDING RJSTART BITS IS SET AND THE   * 17400015
*       DESTINATION PREFIX HAS NOT BEEN NOTIFIED. IN THIS CASE THE    * 17700015
*       SOURCE PREFIX MUST CONTAIN BINARY ZERO.                       * 18000015
*     I-SEARCH FOR THE FIRST TYPE N JOB FOR WHICH THE BYPASSED OUTPUT * 18300015
*       BIT FOR THE DESTINATION PREFIX IS SET TO ONE.                 * 18600015
*                                                                     * 18900015
*OUTPUT                                                               * 19200015
*   THE RESULTS OF THE SEARCH ARE INDICATED UNDER EXITS.              * 19500015
*                                                                     * 19800015
*EXTERNAL ROUTINES                                                    * 20100015
*   NONE                                                              * 20400015
*                                                                     * 20700015
*EXITS-NORMAL                                                         * 21000015
*   RETURN CODES OF ZERO AND FOUR IN REGISTER 15 RESPECTIVELY INDICATE* 21300015
*   WHETHER A JOB OF THE TYPE SOUGHT WAS FOUND OR NOT FOUND. REGISTER * 21600015
*   1 CONTAINS THE ADDRESS OF THE FIRST BYTE OF THE FAST TABLE ENTRY, * 21900015
*   IF A JOB WAS FOUND. OTHERWISE IT CONTAINS ZERO.                   * 22200015
*                                                                     * 22500015
*EXITS-ERROR                                                          * 22800015
*   NONE.                                                             * 23100015
*                                                                     * 23400015
*TABLES1WORK AREAS                                                    * 23700015
*   NONE.                                                             * 24000015
*                                                                     * 24300015
*ATTRIBUTES                                                           * 24600015
*   SERIALLY REUSABLE.                                                * 24900015
*                                                                     * 25200015
*NOTES                                                                * 25500015
*   THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL             * 25800015
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET EQUIVALENT TO THE    * 26100015
*   ONE USED AT ASSEMBLY TIME.  THE CODING IS ARRANGED SO THAT        * 26400015
*   REDEFINITION OF CHARACTER CONSTANTS, BY REASSEMBLY, WILL RESULT   * 26700015
*   IN A CORRECT MODULE FOR THE NEW DEFINITIONS. FURTHER DEPENDENCIES * 27000015
*   ARE- THIS ROUTINE EXPECTS A HEX 40 BIT REPRESENTATION IN THE FIRST* 27300015
*   BYTE OF A FAST TABLE ENTRY    IF     THE ENTRY IS INACTIVE. THIS  * 27600015
*   BIT COMBINATION IS CURRENTLY SET BY THE RJE INITIALIZE ROUTINES.  * 27900015
*   -ANY CHANGES IN THE BIT REPRESENTATION OF FAST TABLE INFORMATION  * 28200015
*   REQUIRE CHANGES IN THIS ROUTINE.                                  * 28500015
*                                                                     * 28800015
*                                                                     * 29100015
*********************************************************************** 29400015
*                                                                       29700015
*                                                                       30000015
*  GENERAL REGISTER USAGES                                              30300015
R0       EQU   0                                                        30600015
R1       EQU   1                   POINTER TO PARAMETER LIST RECEIVED   30900015
R2       EQU   2                                                        31200015
R3       EQU   3                                                        31500015
R4       EQU   4                                                        31800015
R5       EQU   5                                                        32100015
R6       EQU   6                                                        32400015
R7       EQU   7                                                        32700015
R8       EQU   8                   ADDRESS OF FAST TABLE END OF STORAGE 33000015
R9       EQU   9                   LENGTH OF A FAST TABLE ENTRY         33300015
R10      EQU   10                                                       33600015
R11      EQU   11                  BASE REGISTER FOR FASTABLE DSECT     33900015
R12      EQU   12                  BASE REGISTER FOR PROGRAM            34200015
R13      EQU   13                  SAVE AREA ADDRESS REGISTER           34500015
R14      EQU   14                  RETURN POINT REGISTER                34800015
R15      EQU   15                  ENTRY POINT REGISTER                 35100015
*                                                                       35400015
*  PRELIMINARY MANIPULATIONS                                            35700015
*                                                                       36000015
         SAVE  (14,12),,7-12-67/SRCHGEN-ROUTINE-ENTRY/RJE               36300015
         BALR  R12,0               ESTABLISH ADDRESSIBILITY USING R12   36600015
*                                  AS BASE REGISTER                     36900015
         USING *,R12                                                    37200015
         ST    R13,SAVE+4          STORE HIS SAVE ADDRESS IN MY SAVE    37500015
*                                  AREA                                 37800015
         LA    R4,SAVE             STORE MY SAVE ADDRESS IN HIS         38100015
         ST    R4,8(R13)           SAVE AREA                            38400015
*                                                                       38700015
*  PRE-SEARCH PRELIMINARIES AND SEARCH LOOP INITIALIZATION              39000015
*                                                                       39300015
         L     R11,0(R1)           GET FASTABLE STARTING POINT ADDRESS  39600015
*                                  PASSED BY CALLING ROUTINE IN R11     39900015
         LTR   R11,R11             IS START ADDRESS ZERO                40200015
         BNZ   NONZERO             BRANCH IF NOT ZERO                   40500015
         L     R11,ADFTAB          START ADDRESS PASSED WAS ZERO SO     40800015
*                                  GET ADDRESS OF FIRST FASTABLE ENTRY  41100015
*                                  IN R11, THE DSECT BASE REGISTER      41400015
         USING FASTAB,R11          PROMISE ASSEMBLER GOOD INTENTIONS    41700015
*                                  WHEN REFERRING TO FASTAB DSECT       42000015
NONZERO  L     R9,ADFLENT          GET THE LENGTH OF A FAST TABLE       42300015
         LH    R9,0(R9)            ENTRY IN GEGISTER 9                  42600015
         L     R8,ADFEOS           GET THE FAST TABLE END OF STORAGE    42900015
         L     R8,0(R8)            ADDRESS IN REGISTER 8                43200015
         LA    R8,0(R8)                                                 43500015
         LA    R11,0(R11)                                               43800015
         CR    R11,R8              TEST FOR VALID SEARCH START POINT    44100015
         BNL   NOTFOUND            BRANCH IF NOT VALID START POINT      44400015
*                                                                       44700015
*  THIS IS THE SEARCH LOOP START POINT                                  45000015
*                                                                       45300015
SRCHLOOP CLI   FASTNAME,C' '       CHECK FOR ACTIVE FASTAB ENTRY        45600015
         BE    EOTCHECK            BRANCH IF INACTIVE ENTRY TO CHECK    45900015
*                                  IF END OF TABLE REACHED              46200015
         CLI   FASTNAME,0          CHECK FOR UNUSABLE FASTAB ENTRY      46500015
         BE    EOTCHECK            BRANCH IF UNUSED                     46800015
         SPACE                                                          47100015
         CLC   4(3,R1),ZERO        DOES THE PARAMETER LIST RECEIVED     47400015
*                                  CONTAIN A SOURCE PREFIX              47700015
         BE    DESTCHEK            BRANCH IF NO SOURCE PREFIX           48000015
         CLC   4(3,R1),FASTSUID    COMPARE SOURCE AND JOB USER          48300015
*                                  PREFIX                               48600015
         BNE   EOTCHECK            BRANCH IF PREFIXES NOT IDENTICAL SO  48900015
*                                  AS TO PASS OVER THIS ENTRY           49200015
*                                                                       49500015
DESTCHEK CLC   7(3,R1),FASTSUID    COMPARE DESTINATION PREFIX WITH THE  49800015
*                                  JOBS SOURCE USER IDENTIFICATION.     50100015
         BNE   ALTCHECK            BRANCH IF PREFIXES DO NOT AGREE TO   50400015
*                                  CHECK IF ANY ALTERNATE DESTINATIONS  50700015
*                                                                       51000015
*  A JOB SUBMITTED BY THE DESTINATION PREFIX HAS BEEN FOUND. FURTHER    51300015
*  ANALYSIS WILL NOW BE MADE TO SEE IF IT QUALIFIES IN ALL OTHER        51600015
*  DESIRED RESPECTS INDICATED BY THE PARAMETER LIST                     51900015
*                                                                       52200015
         CLI   10(R1),C'C'         DOES THE PARM LIST INDICATE A C TYPE 52500015
*                                  JOB STATUS IE A JOB WHOSE COMPLETION 52800015
*                                  STATUS IS OF NO CONCERN              53100015
         BE    FOUND               BRANCH IF C TYPE TO INDICATE JOB     53400015
*                                  FOUND                                53700015
*                                                                       54000015
*  SINCE THE JOB IS NOT C TYPE OTHER STATUS INDICATORS MUST BE CHECKED  54300015
*                                                                       54600015
         TM    FASTDSB,X'80'       TEST JOB COMPLETION BIT IN FASTABLE  54900015
         BZ    EOTCHECK            BRANCH IF JOB NOT COMPLETE           55200015
*                                                                       55500015
*                                  JOB IS COMPLETE                      55800015
         TM    FASTDSB,X'60'       TEST ENQUEUED FOR DELIVERY BITS      56100015
         BC    7,EOTCHECK          BRANCH IF JOB ALREADY ENQUEUED       56400015
*                                                                       56700015
*  THE JOB IS COMPLETE AND NOT ALREADY ENQUEUED FOR DELIVERY TO         57000015
*  EITHER THE SUBMITTER OR HIS ALTERNATE DESIGNEE.                      57300015
*                                                                       57600015
         CLI   10(R1),C'O'         DOES PARM LIST INDICATE AN O TYPE    57900015
*                                  JOB DESIRED                          58200015
         BE    FOUND               BRANCH IF O TYPE TO INDICATE FOUND   58500015
         CLI   10(R1),C'A'         IS AN A TYPE JOB DESIRED             58800015
         BE    ATYPE               BRANCH IF A TYPE JOB DESIRED         59100015
*                                                                       59400015
         CLI   10(R1),C'L'         IS AN L TYPE JOB DESIRED             59700015
         BE    TTYPE               BRANCH IF YES                        60000015
         CLI   10(R1),C'T'         T TYPE JOB DESIRED?                  60300015
         BE    TTYPE               BRANCH IF T TYPE JOB DESIRED         60600015
*                                                                       60900015
         TM    FASTDSBE,X'80'      TEST SOUECE BYPASSED OUTPUT BIT.     61200015
         BZ    EOTCHECK            BRANCH IF BIT NOT SET TO ONE         61500015
         B     FOUND               OTHERWISE, RECORD FIND               61800015
ATYPE    TM    FASTDSB,X'08'       TEST SOURCE NOTIFIED BIT IN FAST     62100015
*                                  TABLE ENTRY.                         62400015
         BO    EOTCHECK            BRANCH IF SOURCE IS NOTIFIED         62700015
         B     FOUND               NOT NOTIFIED SO BRANCH TO FOUND      63000015
TTYPE    TM    FASTDSB,X'02'       TEST NOTIFY PENDING RJSTART BIT      63300015
         BZ    EOTCHECK            BRANCH IF BIT NOT SET                63600015
         B     ATYPE               BRANCH IF BIT IS SET                 63900015
         SPACE                                                          64200015
ALTCHECK CLC   7(3,R1),FASTALT     TEST IF ALTERNATE DESTINATION AND    64500015
*                                  DESTINATION PREFIX PASSED IN         64800015
*                                  PARAMETER LIST AGREE.                65100015
         BNE   EOTCHECK            BRANCH IF NO AGREEMENT               65400015
*  A JOB SUBMITTED BY THE ORIGINATOR PREFIX AND DIRECTED TO THE         65700015
*  DESTINATION PREFIX HAS BEEN FOUND. FURTHER ANALYSIS IS NECESSARY     66000015
*  IN ORDER TO DETERMINE IF IT QUALIFIES IN OTHER DESIRED RESPECTS.     66300015
*                                                                       66600015
         CLI   10(R1),C'C'         DOES PARM LIST INDICATE A C TYPE JOB 66900015
*                                  DESIRED                              67200015
         BE    FOUND               BRANCH IF C TYPE JOB DESIRED.        67500015
         TM    FASTDSB,X'80'       TEST JOB COMPLETION BIT              67800015
         BZ    EOTCHECK            BRANCH IF JOB NOT COMPLETE.          68100015
         TM    FASTDSB,X'60'       TEST ENQUEUED FOR DELIVERY BITS      68400015
         BC    7,EOTCHECK          BRANCH IF JOB ALREADY ENQUEUED.      68700015
*                                                                       69000015
         CLI   10(R1),C'O'         IS A O TYPE JOB DESIRED              69300015
         BE    FOUND               BRANCH IF YES TO INDICATE FOUND      69600015
         CLI   10(R1),C'A'         IS AN A TYPE JOB DESIRED             69900015
         BE    TYPEA               BRANCH IF A TYPE JOB DESIRED.        70200015
         CLI   10(R1),C'L'         IS AN L TYPE JOB DESIRED?            70500015
         BE    TYPEL               BRANCH IF TYPE L JOB DESIRED.        70800015
         TM    FASTDSBE,X'40'      TEST BYPASSED BIT FOR                71100015
*                                  THE ALTERNATE.                       71400015
         BO    FOUND               BRANCH IF SET.                       71700015
         B     EOTCHECK             BRANCH TO TEST FOR END OF TABLE.    72000015
TYPEA    TM    FASTDSB,X'04'       TEST ALTERNATE NOTIFIED BIT          72300015
         BO    EOTCHECK            BRANCH IF ALTERNATE ALREADY NOTIFIED 72600015
         B     FOUND               NOT NOTIFIED SO INDICATE FOUND       72900015
TYPEL    TM    FASTDSB,X'01'       TEST NOTIFY PENDING LOGON BIT.       73200015
         BZ    EOTCHECK            BRANCH IF NOT SET TO ONE             73500015
         B     TYPEA               BRANCH IF SET                        73800015
*                                                                       74100015
*  AT THIS POINT THE JOB UNDER CONSIDERATION HAS BEEN ELIMINATED AS A   74400015
*  DESIRABLE CANDIDATE. FURTHER SEARCH MUST BE INITIATED IF END OF      74700015
*  TABLE HAS NOT BEEN REACHED.                                          75000015
*                                                                       75300015
EOTCHECK AR    R11,R9              UPDATE SEARCH POINTER TO NEXT ENTRY  75600015
*                                  IN FAST TABLE                        75900015
         CR    R11,R8              IS ADDRESS OF NEXT ENTRY IDENTICAL   76200015
*                                  TO THE FAST TABLE END OF STORAGE     76500015
         BL    SRCHLOOP            BRANCH IF NOT END OF STORAGE         76800015
*                                                                       77100015
*  AT THIS POINT END OF STORAGE HAS BEEN REACHED AND NO JOB HAS BEEN    77400015
*  FOUND OR ELSE THE JOB TYPE PARAMETER RECEIVED WAS INACCURATE         77700015
*                                                                       78000015
NOTFOUND LA    R15,4               SET NOT FOUND RETURN CODE            78300015
         LA    R1,0                ZERO REGISTER 1                      78600015
RETURN   STM   R15,R1,16(R13)      SET UP RETURN CODES AND PARAMETERS   78900015
         RETURN (14,12),T                                               79200015
FOUND    LA    R15,0               SET FOUND RETURN CODE                79500015
         LR    R1,R11              ADDRESS OF FAST TABLE ENTRY FOR JOB  79800015
*                                  THAT WAS FOUND GOES IN REGISTER 1.   80100015
         B     RETURN              RETURN                               80400015
*                                                                       80700015
*  PROGRAM SECTION FOR CONSTANTS, SAVE AREAS,EXTERNALLY DEFINED SYMBOLS 81000015
*                                                                       81300015
SAVE     DS    3F                  3 WORD DUMMY SAVE AREA               81600015
ADFTAB   DC    A(IHKCDFTB)         FAST TABLE ADDRESS                   81900015
ADFLENT  DC    A(IHKCDFLN)         ADDRESS OF HALFWORD CONTAINING       82200015
*                                  LENGTH OF EACH FAST TABLE ENTRY.     82500015
ADFEOS   DC    A(IHKCDFES)         ADRESS OF FAST TABLE END OF          82800015
*                                  STORAGE                              83100015
ZERO     DC    3X'00'              3 BYTES OF ZERO                      83400015
         LTORG                                                          83700015
*                                                                       84000015
*  DUMMY SECTIONS                                                       84300015
*                                  FAST TABLE DUMMY SECTION             84600015
*                                                                       84900015
FASTAB   DSECT                                                          85200015
FASTNAME DS    CL8                 JOBNAME                              85500015
FASTJIB  DS    C                   JOB INFORMATION BYTE                 85800015
FASTJEDT DS    CL3                 JEDT ADDRESS                         86100015
FASTDSB  DS    C                   DELIVERY STATUS BYTE                 86400015
FASTDSBE DS    C                   DELIVERY STATUS BYTE EXTENDED.       86700015
FASTTTR  DS    CL3                                                      87000015
FASTALT  DS    CL3                 ALTERNATE DESTINATION USER           87300015
*                                  PREFIX                               87600015
FASTCNT  DS    C                   NUMBER OF CLOSEDOWNS SINCE LAST IPL. 87900015
FASTSUID DS    CL3                 USER IDENTIFICATION OF SOURCE.       88200015
         ENTRY IHKCCSGN                                                 88500015
         EXTRN IHKCDFTB,IHKCDFLN,IHKCDFES                               88800015
*                                                                       89100015
         END                                                            89400015
