         TITLE 'IHKCCSUD-SEARCH USER DIRECTORY ROUTINE'                 00700015
IHKCCSUD CSECT                                                          01400015
*********************************************************************** 02100015
*                                                                     * 02800015
*STATUS:                                                              * 03500015
*   CHANGE LEVEL 0.                                                   * 04200015
*                                                                     * 04900015
*FUNCTION/OPERATION:                                                  * 05600015
*   THIS ROUTINE PERFORMS A SERIAL SEARCH OF THE USER DIRECTORY FOR   * 06300015
*   AN ENTRY HAVING ASSOCIATED WITH IT A SPECIFIED USER PREFIX.       * 07000015
*                                                                     * 07700015
*ENTRY POINTS:                                                        * 08400015
*        IHKCCSUD-SEARCH USER DIRECTORY FOR A SPECIFIED USER PREFIX.  * 09100015
*   THE CALLING SEQUENCE IS:  L    1,USER PREFIX                      * 09800015
*                             CALL IHKCCSUD                           * 10500015
*                                                                     * 11200015
*   UPON ENTRY TO THIS ROUTINE                                        * 11900015
*   STANDARD SUBROUTINE LINKAGES PREVAIL. IN PARTICULAR,REGISTER 1    * 12600015
*   CONTAINS A THREE CHARACTER USER PREFIX,LEFT ADJUSTED,PASSED BY    * 13300015
*   THE CALLING ROUTINE. THIS PREFIX IS USED AS SEARCH ARGUMENT IN    * 14000015
*   A SEARCH OF THE USER DIRECTORY.                                   * 14700015
*                                                                     * 15400015
*INPUT:                                                               * 16100015
*   NO INPUT OTHER THAN THE PARAMETER PASSED BY VALUE IN REGISTER 1.  * 16800015
*                                                                     * 17500015
*OUTPUT:                                                              * 18200015
*   NO OUTPUT, OTHER THAN THAT EXPLAINED UNDER ' EXITS'.              * 18900015
*                                                                     * 19600015
*                                                                     * 20300015
*EXTERNAL ROUTINES:                                                   * 21000015
*        IHKCDTAB-CONTROL SECTION CONTAINING THE RJE SYSTEM TABLES    * 21700015
*   SUCH AS THE FAST TABLE, USER DIRECTORY, ETC. THE EXTERNAL LABELS  * 22400015
*   IHKCDUDR,IHKCDUNB,AND IHKCDULN APPEARING IN THIS CONTROL SECTION  * 23100015
*   ARE REFERENCED BY THIS ROUTINE. HOWEVER, NO EXTERNAL ROUTINES ARE * 23800015
*   USED AS SUBROUTINES BY THIS MODULE.                               * 24500015
*                                                                     * 25200015
*EXITS-NORMAL:                                                        * 25900015
*   REGISTER 1 CONTAINS THE ADDRESS OF THE USER DIRECTORY ENTRY       * 26600015
*   FOR WHICH THE CORRESPONDING USER PREFIX MATCHES THE INPUT         * 27300015
*   SEARCH ARGUMENT. IF NO MATCHING PREFIX IS FOUND, REGISTER 1       * 28000015
*   CONTAINS ZERO.                                                    * 28700015
*                                                                     * 29400015
*EXITS-ERROR:                                                         * 30100015
*   N/A                                                               * 30800015
*                                                                     * 31500015
*TABLES/WORK AREAS:                                                   * 32200015
*   N/A                                                               * 32900015
*                                                                     * 33600015
*ATTRIBUTES:                                                          * 34300015
*   SERIALLY RE-USEABLE.                                              * 35000015
*                                                                     * 35700015
*NOTES                                                                * 36400015
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR    * 37100015
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHCRACTER SET.            * 37800015
*                                                                     * 38500015
*                                                                     * 39200015
*********************************************************************** 39900015
*                                                                       40600015
*  GENERAL REGISTER USAGES                                              41300015
*                                                                       42000015
R15      EQU   15                  ENTRY POINT REGISTER                 42700015
R14      EQU   14                  RETURN POINT REGISTER                43400015
R13      EQU   13                  ADDRESS OF CALLING ROUTINE SAVE AREA 44100015
R12      EQU   12                  BASE REGISTER FOR THIS PROGRAM       44800015
R11      EQU   11                  BASE REGISTER FOR USER DIRECTORY     45500015
*                                  DSECT                                46200015
R10      EQU   10                  LENGTH OF EACH ENTRY IN USER DIRECT  46900015
R9       EQU   9                   DECREMENT FOR SEARCH LOOP            47600015
R8       EQU   8                  NUMBER OF USER DIRECTORY ENTRIES      48300015
R4       EQU   4                                                        49000015
R1       EQU   1                   PARAMETER REGISTER WHICH UPON ENTRY  49700015
*                                  TO THIS ROUTINE CONTAINS A 3 CHARAC- 50400015
*                                  ER USER PREFIX LEFT ADJUSTED.        51100015
*                                                                       51800015
*  PRELIMINARY MANIPULATIONS                                            52500015
*                                                                       53200015
         SAVE  (14,12),,3-31-67/RJE-SRCHUDIR  SAVE REGISTERS            53900015
         BALR  R12,0               ESTABLISH ADDRESSIBILITY USING R12   54600015
         USING *,R12               AS BASE REGISTER                     55300015
         ST    R13,SAVE+4          STORE HIS SAVE ADDRESS IN MY DUMMY   56000015
         LA    R4,SAVE             SAVE AREA FOR TRACING PURPOSES       56700015
         ST    R4,8(R13)           STORE MY SAVE ADDRESS IN HIS SAVE    57400015
*                                  AREA FOR TRACING PURPOSES            58100015
*                                                                       58800015
*  PRE-SEARCH PRELIMINARIES AND SEARCH LOOP INITIALIZATION              59500015
*                                                                       60200015
         L     R11,ADUDIR          GET ADDRESS OF THE FIRST BYTE IN THE 60900015
*                                  USER DIRECTORY IN REGISTER 11        61600015
         USING UDIREC,R11          NOTIFY ASSEMBLER OF INTENT TO USE    62300015
*                                  R11 AS BASE FOR UDIREC DSECT         63000015
         L     R8,ADUNUMB          REGISTER 8 HAS THE NUMBER OF ENTRYS  63700015
         LH    R8,0(R8)            IN THE USER DIRECTORY                64400015
         L     R10,ADULENT         REGISTER 10 HAS THE LENGTH OF EACH   65100015
         LH    R10,0(R10)          ENTRY IN USER DIRECTORY              65800015
         LA    R9,1                                                     66500015
         ST    R1,HOLD             STORE USER PREFIX FOR COMPARISON     67200015
         LNR   R9,R9               REGISTER 9 CONTAINS THE DECREMENT    67900015
*                                                                       68600015
*  SEARCH LOOP STARTS HERE                                              69300015
*                                                                       70000015
START    BXLE  R8,R9,NOTFOUND      BRANCH IF END OF USER DIRECTORY      70700015
         CLC   UDIRUSID(3),HOLD    COMPARE USER PREFIXES                71400015
         BE    FOUND               BRANCH IF DESIRED PREFIX FOUND       72100015
         AR    R11,R10             UPDATE BASE REGISTER TO NEXT ENTRY   72800015
         B     START               REPEAT CYCLE                         73500015
*                                                                       74200015
FOUND    LR    R1,R11              PUT ADDRESS OF FIND IN REGISTER 1    74900015
RETURN   ST    R1,24(R13)          AND RETURN IT TO CALLING ROUTINE     75600015
         RETURN (14,12),T          RETURN TO CALLING ROUTINE            76300015
*                                                                       77000015
NOTFOUND LA    R1,0                PREFIX NOT FOUND.  THIS IS TO BE     77700015
         B     RETURN              INDICATED BY ZERO IN REGISTER 1      78400015
*                                  UPON RETURN                          79100015
*                                                                       79800015
*  PROGRAM SECTION FOR SAVE AREAS, TEMPORARY STORAGE, ADDRESS CONSTANTS 80500015
*                                                                       81200015
SAVE     DS    3F                  DUMMY SAVE AREA CONSISTING OF THE    81900015
*                                  FIRST THREE WORDS OF USUAL SAVE AREA 82600015
HOLD     DC    F'0'                TEMPORARY STORAGE FOR USER PREFIX    83300015
*                                  PASSED BY CALLING ROUTINE            84000015
ADUDIR   DC    A(IHKCDUDR)         ADDRESS OF FIRST BYTE IN USER        84700015
*                                  DIRECTORY                            85400015
ADUNUMB  DC    A(IHKCDUNB)         ADDRESS OF A HALFWORD CONTAINING THE 86100015
*                                  NUMBER OF ENTRYS IN USER DIRECTORY   86800015
ADULENT  DC    A(IHKCDULN)         ADDRESS OF A HALFWORD CONTAINING THE 87500015
*                                  LENGTH OF EACH ENTRY                 88200015
*                                                                       88900015
         ENTRY IHKCCSUD                                                 89600015
         EXTRN IHKCDUDR,IHKCDUNB,IHKCDULN                               90300015
         LTORG                                                          91000015
*                                                                       91700015
*  USER DIRECTORY DUMMY SECTION                                         92400015
*                                                                       93100015
UDIREC   DSECT                                                          93800015
UDIRTERM DS    CL8                 TERMINAL ID                          94500015
UDIRSTAT DS    C                   STATUS BYTE                          95200015
UDIRUSID DS    CL3                 USER ID                              95900015
UDIRUKEY DS    CL3                 USER PROTECTION KEY                  96600015
         LTORG                                                          97300015
*                                                                       98000015
         END                                                            98700015
