BDC TITLE '''IHKCDBDC'' - CENTRAL BRDCST INTERPRETER'                   00200016
IHKCDBDC CSECT                                                          00400016
*3230002000-038000,294000-300000,310000,328000,342000,348000,358000000A 00600016
*3230372000,382000,386000-388000,392000-394000,402000,406000-408000000A 00800016
*3230418000,428000,452000,480000,498000,508000-512000,528000,536000000A 01000016
*3230544000,552000,564000,600000,694000-700000                     000A 01200016
*                                                                     * 01400016
*   TITLE 'IHKCDBDC' - CENTRAL BRDCST INTERPRETER                     * 01600016
*                                                                     * 01800016
*   STATUS - CHANGE LEVEL 0                                           * 02000016
*                                                                     * 02200016
*   FUNCTION/OPERATION - THERE ARE SEVERAL TYPES OF SERVICES WHICH    * 02400016
*   THE CENTRAL OPERATOR CAN REQUEST BY USING VARIOUS FORMS OF THE    * 02600016
*   BRDCST COMMAND.  THIS ROUTINE IS TO DETERMINE WHICH SERVICE IS    * 02800016
*   REQUESTED, THEN CALL THE APPROPRIATE SUBROUTINE TO PEFORM THE     * 03000016
*   DESIRED SERVICE.                                                  * 03200016
*                                                                     * 03400016
*   ENTRY POINTS - THERE IS ONLY ONE ENTRY POINT FOR THIS ROUTINE.    * 03600016
*        'IHKCDBDC' - CENTRAL BRDCST INTERPRETER                      * 03800016
*                                                                     * 04000016
*   CALLING SEQUENCE  -  LA   1,PARALIST                              * 04200016
*                        LINK EP=IHKCDBDC                             * 04400016
*                                                                     * 04600016
*   INPUT - THE PARAMETER PASSED IN REGISTER 1 IS THE ADDRESS OF A    * 04800016
*   PARAMETER LIST OF 4 BYTE ADDRESSES AS FOLLOWS -                   * 05000016
*                                                                     * 05200016
*   1. UNUSED                                                         * 05400016
*   2. ADDRESS OF 95 BYTE CARD IMAGE.                                 * 05600016
*   3. ADDRESS OF 'IHKAADSP' (DISPATCHER)                             * 05800016
*   4.-5. NOT USED                                                    * 06000016
*                                                                     * 06200016
*   6. ADDRESS OF 'IHKCBLDM' (BUILD MSG)                              * 06400016
*   7.-25. NOT USED                                                   * 06600016
*   26. ADDRESS OF LIST OF DCB ADDRESSES                              * 06800016
*                                                                     * 07000016
*   THE FORMAT OF THE 95 BYTE CARD IS DEFINED AS FOLLOWS -            * 07200016
*   COLUMN 1-72     CENTRAL OPERATOR'S COMMAND.  DOUBLE QUOTES HAVE   * 07400016
*                   BEEN REDUCED TO ONE QUOTE.                        * 07600016
*   COLUMN 73-80    SEQUENCE NUMBER AS GIVEN BY CENTRAL OPERATOR.     * 07800016
*                   THESE 8 ALPHANUMERIC CHARACTERS ARE USED TO       * 08000016
*                   IDENTIFY THE COMMAND IN ERROR DIAGNOSTIC TYPEOUTS.* 08200016
*   COLUMN 81       CHARACTER 'T'                                     * 08400016
*   COLUMN 88       SPECIAL FUNCTION INDICATOR                        * 08600016
*     VALUE - CHARACTER 'A' - INSERT TEXT INTO INDICATED SLOT, PUSH   * 08800016
*                   UP ALL TEXTS TO MAKE ROOM.                        * 09000016
*     VALUE - CHARACTER 'K' - PACK ALL ACTIVE TEXTS INTO LOW NUMBERED * 09200016
*                   SLOTS.  PACK INACTIVE SLOTS AT HIGH NUMBERED SLOTS* 09400016
*     VALUE - CHARACTER 'D' - MARK ALL SLOTS INACTIVE TO LOGICALLY    * 09600016
*                   DELETE ALL BRDCST MESSAGE TEXTS.                  * 09800016
*     VALUE - BINARY ZERO - NONE OF THE ABOVE SPECIAL FUNCTIONS ARE   * 10000016
*                   REQUESTED.                                        * 10200016
*   COLUMN 83-84    SLOT NUMBER (ZONED FORMAT).  IF NO SLOT NUMBER    * 10400016
*                   WAS SPECIFIED, COLUMN 83 HAS CHARACTER 'X'        * 10600016
*   COLUMN 85       DISPLACEMENT FROM BEGINNING OF CARD OF FIRST      * 10800016
*                   QUOTE. IF THERE ARE NO QUOTES, VALUE IS BINARY 0. * 11000016
*   COLUMN 86       DISPLACEMENT FROM BEGINNING OF CARD OF LAST       * 11200016
*                   QUOTE.                                            * 11400016
*   COLUMN 87-95    IGNORED                                           * 11600016
*                                                                     * 11800016
*                                                                     * 12000016
*   OUTPUT - THE DISC DATA SET (DDNAME=IHKTXTDD) HAS BEEN MODIFIED TO * 12200016
*   CONFORM TO THE CENTRAL OPERATOR'S REQUEST.                        * 12400016
*                                                                     * 12600016
*   EXTERNAL ROUTINES -                                               * 12800016
*                                                                     * 13000016
*        'IHKCDBIN' - IF THE BRDCST SLOT DIRECTORY IS NOT CURRENTLY   * 13200016
*        IN CORE, THIS ROUTINE READS IT IN FROM THE DISC DATA SET     * 13400016
*        DDNAME=IHKBRDDD                                              * 13600016
*                                                                     * 13800016
*        'IHKCDBOT' - IF CHANGES HAVE BEEN MADE TO THE CORE SLOT      * 14000016
*        DIRECTORY, THESE CHANGES ARE RECORED ON DISC.                * 14200016
*                                                                     * 14400016
*        'IHKCDBPK' - PERFORMS THE PACK SPECIAL FUNCTION.             * 14600016
*                                                                     * 14800016
*        'IHKCDBIS' - PERFORMS THE INSERT SPECIAL FUNCTION.           * 15000016
*                                                                     * 15200016
*        'IHKCDBSH' - SEARCHES BRDCST SLOT DIRECTORY IN CORE FOR      * 15400016
*        AN INACTIVE ENTRY.                                           * 15600016
*                                                                     * 15800016
*        'IHKCDBTW' - WRITES THE TEXT OF A NEW MESSAGE TO DISC, AND   * 16000016
*        MARKS THE SLOT IN THE DIRECTORY 'ACTIVE'.                    * 16200016
*                                                                     * 16400016
*        'IHKCBLDM' - SENDS SYSTEM ERROR MESSAGES.                    * 16600016
*                                                                     * 16800016
*   EXITS-NORMAL - THE REQUIRED FUNCTION HAS BEEN PERFORMED.  ALL I/O * 17000016
*   OPERATIONS ARE COMPLETE.  REGISTER 15 = 0.                        * 17200016
*                                                                     * 17400016
*   EXITS-ERROR - AN APPROPRIATE DIAGNOSTIC TYPED ON THE CENTRAL      * 17600016
*   CONSOLE DESCRIBES THE ERROR.  REGISTER 15 = 4.                    * 17800016
*                                                                     * 18000016
*   TABLES/WORK AREAS - AN 18 WORD SAVE AREA AND A 60 BYTE I/O BUFFER * 18200016
*   ARE PROVIDED.                                                     * 18400016
*                                                                     * 18600016
*   ATTRIBUTES - REUSABLE, NON-RESIDENT                               * 18800016
*                                                                     * 19000016
*   NOTES -                                                           * 19200016
*                                                                     * 19400016
*   PROPER FUNCTIONING OF THIS SUBROUTINE IS DEPENDENT UPON AN        * 19600016
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    * 19800016
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  IF THE CHARACTER    * 20000016
*   CONSTANTS ARE REDEFINED, A REASSEMBLY WITHOUT ANY CODING CHANGES  * 20200016
*   STILL RESULT IN A CORRECT SUBROUTINE FOR THE NEW DEFINITIONS.     * 20400016
*                                                                     * 20600016
*   STANDARD LINKAGE CONVENTIONS ARE FOLLOWED.                        * 20800016
*                                                                     * 21000016
*                                                                     * 21200016
*                                                                     * 21400016
*                                                                       21600016
*                   REGISTER ASSIGNMENTS                                21800016
*                                                                       22000016
R15      EQU   15                                                       22200016
R14      EQU   14                                                       22400016
R13      EQU   13                                                       22600016
R12      EQU   12                                                       22800016
BASE     EQU   12                       PROGRAM BASE                    23000016
TEMP     EQU   11                       TEMPORARY STORAGE               23200016
PARM     EQU   10                       HOLDS INPUT PARAM FORM REG 1    23400016
BTB      EQU   9                        ADDR OF SLOT DIRECTORY          23600016
X        EQU   8                        RETURN ADDR FROM INTERNAL SUBR  23800016
FIRST    EQU   7                        POINTER TO FIRST QUOTE MARK     24000016
SECOND   EQU   6                        POINTER TO SECOND QUOTE MARK    24200016
RC       EQU   5                        HOLDS RETURN CODE               24400016
TAB      EQU   4                        INDEX OF CORE SLOT DIRECTORY    24600016
CNT      EQU   3                        LOOP COUNTER                    24800016
CARD     EQU   2                        DSECT BASE OF 95 BYTE CARD      25000016
R1       EQU   1                                                        25200016
R0       EQU   0                                                        25400016
*                                                                       25600016
         USING PARLIST,PARM             DSECT BASE OF INPUT PARAMETERS  25800016
         USING CARDLIST,CARD            DSECT OF CARD IMAGE             26000016
*                                                                       26200016
         SAVE  (14,12),,*                                          000A 26400016
         BALR  BASE,R0                                             000A 26600016
         USING *,BASE                                              000A 26800016
         ST    R13,SAVE+4                                          000A 27000016
         LA    TEMP,SAVE                                           000A 27200016
         ST    TEMP,8(R13)                                         000A 27400016
         LR    R13,TEMP                                            000A 27600016
*                                                                  000A 27800016
*                        END OF STANDARD ENTRY LINKAGE             000A 28000016
*                                                                  000A 28200016
         LR    PARM,R1                  SAVE INPUT PARAMETER            28400016
         L     CARD,ADCARD              GET ADDR OF 95 BYTE CARD        28600016
         MVC   ADDCB(4),ADDCBS          MOVE PARAMETER TO LIST AREA     28800016
         MVC   ADDISPAC(4),ADDISP       PASS DISPATCHER ADDRESS,TOO     29000016
         LOAD  EPLOC=ADCDBIN            GET SLOT DIRECTORY         000A 29200016
         LR    R15,R0                   SAVE ENTRY POINT ADDRESS        29400016
         LA    R1,ADDCB                 PASS PARAMS TO ROLLIN           29600016
         BALR  R14,R15                  CALL ROLLIN                     29800016
         LR    BTB,R1                   KEEP LOCATION OF DIRECTORY      30000016
         ST    BTB,ADBTB                PASS ADDRESS OF SLOT DIRECTORY  30200016
         ST    BTB,ADBTBA                 ON TO SUBROUTINES             30400016
         ST    R15,ADBOT                SAVE ROLLOUT ROUTINE ADDRESS    30600016
*                                                                       30800016
         SRL   R15,SHIFT                SHIFT OUT ALL BUT OFFSET   000A 31000016
         LTR   R15,R15                  WAS THERE AN I/O ERROR          31200016
         BNZ   IOERROR                  IF SO, PROCESS AND EXIT         31400016
TOK      CLI   C82,NOTSPEC              ARE SPECIAL FUNCTIONS REQD 000A 31600016
         BE    NOSPEC                   IF NO, BRANCH                   31800016
*                                                                       32000016
*                                       CHECK FOR WHICH SPECIAL REQUEST 32200016
         CLI   C82,A                    IS INSERT WANTED           000A 32400016
         BE    INSERT                                                   32600016
*                                                                       32800016
         CLI   C82,D                    IS DELETE WANTED           000A 33000016
         BE    DELETE                                                   33200016
*                                                                       33400016
*                        SPECIAL SERVICES                               33600016
PACK     LR    R1,BTB                   PASS ADDR OF SLOT DIRECTORY     33800016
         LINK  EPLOC=ADCDBPK            GET PACK ROUTINE           000A 34000016
         B     GOOD                     GO TO NORMAL EXIT               34200016
*                                                                       34400016
INSERT   BAL   X,GETSLOT                GO PUT ADDRESS OF SPECIFIED     34600016
*                                         SLOT IN REG 'TEMP' AND INTO   34800016
*                                         PARAMETER LIST 'ADSLOT'       35000016
         BAL   X,QUOTES                 MOVE TEST TO 'BIN'              35200016
         LOAD  EPLOC=ADCDBIS            GET INSERT ROUTINE         000A 35400016
        LR    R15,R0                                                    35600016
         LA    R1,OUTPAR                PASS PARAMETER'S ADDRESS        35800016
        BALR  R14,R15                                                   36000016
         LR    TEMP,R15                                                 36200016
         DELETE EPLOC=ADCDBIS                                      000A 36400016
*                                                                       36600016
         LTR   R15,TEMP                 CHECK RETURN CODE          000A 36800016
         BZ    GOOD                     IF 0, OK                        37000016
         LA    TEMP,CODE4               WAS MSG NOT INSERTED FOR   000A 37200016
         CLR   TEMP,R15                   LACK OF ROOM             000A 37400016
         BE    CALLBLDM                 IF SO, SEND MSG                 37600016
         B     IOERROR                  IF IO ERROR, PROCESS AND EXIT   37800016
*                                                                       38000016
DELETE   LA    CNT,NUMBRD               SET LOOP COUNTER           000A 38200016
         LR    TAB,BTB                  PRESET INDEX OF DIRECTORY       38400016
DELOOP   MVI   3(TAB),INACTIVE          SET SLOTS TO INACTIVE      000A 38600016
         LA    TAB,BRDLN(TAB)           POINT TO NEXT SLOT,        000A 38800016
         BCT   CNT,DELOOP                 IF ANY                        39000016
         B     GOOD                     NORMAL EXIT                     39200016
*                                                                       39400016
*                        END OF SPECIAL SERVICES                        39600016
NOSPEC   CLI   NUMBER,XX                IS SLOT NUMBER SPECIFIED   000A 39800016
         BC    7,SPECSLOT               IF YES, BRANCH                  40000016
*                                       IF NO, TEXT IS TO GO TO 1ST     40200016
*                                         AVAILABLE SLOT                40400016
         LA    R1,ADBTB                 SEARCH FOR AN INACTIVE SLOT     40600016
         LINK  EPLOC=ADCDBSH            CALL FOR SEARCH            000A 40800016
*                                                                       41000016
         LTR   R15,R15                  CHECK RETURN CODE (WAS AN       41200016
*                                         INACTIVE SLOT FOUND)          41400016
         BC    8,FOUND                  IF YES, BRANCH                  41600016
*                                       IF NO, ERROR-REFUSE TO PROCESS  41800016
*                                         COMMAND                       42000016
CALLBLDM LA    R1,BLDMPARM              SET PARAMS FOR 'IHKCBLDM'       42200016
ERRORMSG L     R15,ADBLDM               GET ADDRESS OF RESIDENT         42400016
*                                         'BUILD MSG' ROUTINE FROM      42600016
*                                         INPUT PARAMETER LIST          42800016
         BALR  R14,R15                  TYPE ERROR MESSAGE TO OPERATOR  43000016
BAD      LA    RC,CODE4                 SET RETURN CODE FOR ERROR  000A 43200016
*                                         WILL UNLOCK ONLY              43400016
         B     ROLLOUT                  GO UNLOCK DIRECTORY DCB         43600016
*                                                                       43800016
GOOD     SR    RC,RC                    NORMAL EXIT-SET RETURN CODE     44000016
*                                         TO ZERO                       44200016
*                                         COPY MODIFIED DIRECTORY BACK  44400016
*                                         TO DISC AND THEN UNLOCK       44600016
*                                         DIRECTORY DCB                 44800016
ROLLOUT  LR    R1,RC                    PASS CODE TO ROLLOUT            45000016
         L     R15,ADBOT                RESTORE ROLLOUT ADDRESS         45200016
         BALR  R14,R15                  CALL ROLLOUT ROUTINE            45400016
         LTR   R15,R15                  WAS THERE AN IO ERROR           45600016
         BNZ   MSGONLY                  IF SO, SEND ERROR MSG ONLY      45800016
OUT      DELETE EPLOC=ADCDBIN           FORGET SLOT DIRECTORY      000A 46000016
         LR    R15,RC                   GET PRESET RETURN CODE          46200016
         L     R13,SAVE+4                                               46400016
         RETURN (14,12),T,RC=(15)       EXIT                            46600016
*                                                                       46800016
FOUND    ST    R1,ADSLOT                STORE ADDRESS OF INACTIVE ENTRY 47000016
*                                         LOCATED BY 'SEARCH' IN PARAM  47200016
*                                         LIST FOR 'WRITE' SUBROUTINE   47400016
WRITE    BAL   X,QUOTES                 MOVE TEXT TO 'BIN'              47600016
         LOAD  EPLOC=ADCDBTW                                       000A 47800016
        LR    R15,R0                                                    48000016
         LA    R1,OUTPAR                PASS PARAMS TO WRITE ROUTINE    48200016
        BALR  R14,R15                                                   48400016
         LR    TEMP,R15                                                 48600016
         DELETE EPLOC=ADCDBTW                                      000A 48800016
         LTR   R15,TEMP                 WAS THERE AN ERROR         000A 49000016
         BNZ   IOERROR                  IF SO, SEND MSG AND EXIT        49200016
         B     GOOD                     NORMAL EXIT                     49400016
*                                                                       49600016
*                                       A SLOT HAS BEEN SPECIFIED       49800016
SPECSLOT BAL   X,GETSLOT                GO PUT ADDRESS OF SPECIFIED     50000016
*                                         SLOT IN REG 'TEMP' AND INTO   50200016
*                                         PARAMETER LIST 'ADSLOT'       50400016
         CLI   QUOTE1,ZERO              IS THERE TEXT FOR          000A 50600016
*                                         SPECIFIED SLOT, OR IS THE     50800016
*                                         SLOT TO BE MARKED 'INACTIVE'  51000016
         BC    7,WRITE                  IF TEXT, BRANCH                 51200016
         MVI   3(TEMP),INACTIVE         NO TEXT,INACTIVATE SLOT    000A 51400016
         B     GOOD                     NORMAL EXIT                     51600016
*                                                                       51800016
*                        INTERNAL SUBROUTINES                           52000016
GETSLOT  NI    NUMBER+1,CF              PUT LEGIT PLUS ON SLOT     000A 52200016
*                                         NUMBER                        52400016
         PACK  DOUBLE(8),NUMBER(2)      CONVERT CHARACTERS TO PACKED    52600016
         CVB   TEMP,DOUBLE              SLOT NO. IS NOW BINARY IN'TEMP' 52800016
         SLL   TEMP,TWO                 MULT BY 4 TO CONVERT       000A 53000016
*                                         NO. TO SLOT DIRECTORY INDEX   53200016
         LA    TEMP,0(TEMP,BTB)         REG 'TEMP' HAS ADDR OF SLOT     53400016
         ST    TEMP,ADSLOT              ADDR OF SLOT IS PASSED IN PARAM 53600016
         BR    X                                                        53800016
*                                                                       54000016
QUOTES   MVI   BIN,BLANK                CLEAR ENTIRE 60 BYTE I/O   000A 54200016
         MVC   BIN+1(59),BIN              BIN TO BLANKS                 54400016
         MVC   MARKB(1),QUOTE1          GET DISPLACEMENT FROM START OF  54600016
         LH    FIRST,MARKA                CARD OF FIRST QUOTE MARK      54800016
         MVC   MARKB(1),QUOTE2          GET DISPLACEMENT OF             55000016
         LH    SECOND,MARKA               SECOND QUOTE                  55200016
         LA    TEMP,2(FIRST)            CALCULATE LENGTH OF TEXT,BUT    55400016
         SR    SECOND,TEMP                ADJUST IT FOR 'EX' INSTR.     55600016
         LA    TEMP,1(CARD,FIRST)       POINT TO 1ST CHARACTER OF TEXT  55800016
         EX    SECOND,MOVE              MOVE TEXT TO I/O BIN            56000016
         BR    X                        EXIT                            56200016
MOVE     MVC   BIN(0),0(TEMP)           EXECUTED BY ABOVE 'EX' INSTR    56400016
*                                                                       56600016
IOERROR  STH   R15,OFFSET               INSERT OFFSET PASSED BACK BY    56800016
*                                         I/O ROUTINES                  57000016
         LA    R1,BLDMPAR2              SET UP PARAMETERS FOR BUILDMSG  57200016
         B     ERRORMSG                   AND SEND                      57400016
*                                                                       57600016
MSGONLY  SRL   R15,SHIFT                SHIFT OUT ALL BUT OFFSET   000A 57800016
         STH   R15,OFFSET               PASS ERROR OFFSET               58000016
         LA    R1,BLDMPAR2              SET UP PARAMETER LIST           58200016
         L     R15,ADBLDM                                               58400016
         BALR  R14,R15                  GO TO BUILD AND SEND MESSAGE    58600016
         B     OUT                      EXIT                            58800016
*                                                                       59000016
*********************************************************************** 59200016
*                                                                       59400016
*                        CONSTANTS                                      59600016
*                                                                       59800016
*********************************************************************** 60000016
SHIFT    EQU   24                       SHIFT COUNT OF 3 BYTES     000A 60200016
NOTSPEC  EQU   0                        NO SPEC FUNCTIONS REQD     000A 60400016
CODE4    EQU   4                                                   000A 60600016
NUMBRD   EQU   100                                                 000A 60800016
BRDLN    EQU   4                                                   000A 61000016
ZERO     EQU   0                        NO QUOTE FLAG              000A 61200016
TWO      EQU   2                        SHIFT TO MULT BY 4         000A 61400016
A        EQU   C'A'                     INSERT FLAG                000A 61600016
D        EQU   C'D'                     DELETE FLAG                000A 61800016
XX       EQU   C'X'                     NO SLOT SPECIFIED FLAG     000A 62000016
BLANK    EQU   C' '                     BLANK CHARACTER            000A 62200016
CF       EQU   X'CF'                    PLUS SIGN                  000A 62400016
INACTIVE EQU   X'FF'                    INACTIVE SLOT FLAG         000A 62600016
*                                                                       62800016
         DS    0D                                                       63000016
DOUBLE   DC    2F'0'                    DOUBLE WORD USID IN CVB INSTR   63200016
SAVE     DC    18F'0'                   SAVE AREA                       63400016
*                                                                       63600016
ADCDBIN  DC    CL8'IHKCDBIN'            ROLL IN-OUT SLOT DIRECTORY 000A 63800016
ADCDBPK  DC    CL8'IHKCDBPK'            PACK ROUTINE               000A 64000016
ADCDBIS  DC    CL8'IHKCDBIS'            INSERT ROUTINE             000A 64200016
ADCDBSH  DC    CL8'IHKCDBSH'            SEARCH ROUTINE             000A 64400016
ADCDBTW  DC    CL8'IHKCDBTW'            BDAM WRITE DRIVER          000A 64600016
*                                                                  000A 64800016
*                                       PARAMETER LIST FOR SUBROUTINES  65000016
*                                         'IHKCDBIS' (5 WORDS)          65200016
*                                         'IHKCDBTW' (4 WORDS)          65400016
OUTPAR   DS    0F                                                       65600016
ADDCB    DC    F'0'                     ADDRESS OF LIST OF DCB ADDRESSE 65800016
ADDISPAC DC    F'0'                     ADDRESS OF DISPATCHER (RECEIVED 66000016
*                                         FROM 'IHKCAINT')              66200016
ADSLOT   DC    F'0'                     SET BY LOCAL SUBROUTINE (SEE    66400016
*                                         TAG 'GETSLOT')                66600016
ADBIN    DC    A(BIN)                   ADDRESS OF 60 BYTE I/O AREA.    66800016
*                                         TEXT IS MOVED FROM CARD TO    67000016
*                                         THIS AREA. ALTHOUGH TEXT IS   67200016
*                                         ONLY UP THRU 40 BYTES, THE    67400016
*                                         ENTIRE 60 BYTES OF 'BIN' ARE  67600016
*                                         STORED ON DISC.               67800016
ADBTB    DC    F'0'                     ADDRESS OF BRDCST CORE SLOT     68000016
*                                         DIRECTORY. (RECEIVED FROM     68200016
*                                         'IHKCDBIN', ROLLIN)           68400016
*                                        THIS IS ALSO THE START OF THE  68600016
*                                         PARAMETER LIST OF 2 WORDS TO  68800016
*                                         SUBROUTINE 'IHKCDBSH'(SEARCH) 69000016
ADBTBA   DC    F'0'                     TELLS 'SEARCH' WHICH SLOT TO    69200016
*                                         START SEARCHING AT. AS USED   69400016
*                                         HERE, THIS IS THE SAME VALUE  69600016
*                                         AS 'ADBTB' ABOVE, SINCE       69800016
*                                         ENTIRE TABLE IS SEARCHED.     70000016
ADBOT    DS    F                        ADDRESS OF ROLLOUT ROUTINE      70200016
*                                         RECEIVED FROM ROLLIN          70400016
BIN      DC    60C' '                   I/O AREA                        70600016
*                                                                       70800016
*                                       PARAMETER LIST TO 'BUILD MSG'   71000016
BLDMPARM DC    F'0'                     MESSAGE IS TO GO TO CONSOLE     71200016
*                                         TYPEWRITER                    71400016
         DC    H'15'                    MESSAGE SELECTOR. ERROR MESSAGE 71600016
*                                         TEXT IS -                     71800016
*                   'IHK034I MSG CANNOT BE ADDED BRDCST'                72000016
         DC    X'06'                    6 CHARACTERS ARE ADDED TO MSG   72200016
         DC    C'BRDCST'                                                72400016
*                                                                  000A 72600016
         DS    0H                                                  000A 72800016
MARKA    DC    X'00'                    USED IN INTERPRETING LOCA- 000A 73000016
MARKB    DC    X'00'                      TION OF BOTH QUOTE MARKS 000A 73200016
*                                                                  000A 73400016
BLDMPAR2 DC    F'0'                                                     73600016
OFFSET   DS    H                                                        73800016
         DC    X'00'                                                    74000016
PLUS     DC    X'C0'                    PLUS SIGN TO 'PACK'             74200016
*                                                                       74400016
*********************************************************************** 74600016
*                                                                       74800016
*                        DSECT OF INPUT PARAMS FROM 'IHKCAINT'          75000016
*                                                                       75200016
*********************************************************************** 75400016
*                                                                       75600016
CARDLIST DSECT                                                          75800016
*                                                                       76000016
         DS    72C                      USER'S INSTRUCTION              76200016
SEQ      DS    CL8                      LAST 8 CHARACTERS OF CARD       76400016
C81      DS    C                        MUST BE C'T'                    76600016
C82      DS    C                        INDICATOR OF SPECIAL SERVICES   76800016
*                                         'A'-INSERT                    77000016
*                                         'K'-PACK                      77200016
*                                         'D'-DELETE                    77400016
*                                         BINARY ZERO-NONE OF ABOVE     77600016
NUMBER   DS    2C                       ZONED SLOT NUMBER, OR,          77800016
*                                         C'X ' IF NO NUMBER SPECIFIED  78000016
QUOTE1   DS    C                        DISPLACEMENT FROM START OF      78200016
*                                         CARD OF 1ST QUOTE. IF NO      78400016
*                                         QUOTES, VALUE=BINARY ZERO     78600016
QUOTE2   DS    C                        DISPLACEMENT FROM START OF      78800016
*                                         CARD OF LAST QUOTE            79000016
         DS    CL9                      UNUSED                          79200016
*                                                                       79400016
PARLIST  DSECT                                                          79600016
         DS    CL4                      UNUSED                          79800016
ADCARD   DS    CL4                      ADDR OF 95 BYTE CARD            80000016
ADDISP   DS    CL4                      ADDRESS OF RESIDENT DISPATCHER  80200016
         DS    CL4                      UNUSED                          80400016
         DS    CL4                      UNUSED                          80600016
ADBLDM   DS    CL4                      ADDRESS OF RESIDENT BUILD MSG.  80800016
         DS    CL76                     UNUSED                          81000016
ADDCBS   DS    CL4                      ADDRESS OF DCB LIST             81200016
         END                                                            81400016
