BIS TITLE '''IHKCDBIS'' - INSERT BRDCST MSG INTO SPECIFIED SLOT'        00400016
IHKCDBIS CSECT                                                        * 00800016
*3200004000-076000,492000-504000,516000,528000-532000,580000,708000000A 01200016
*3200732000                                                        000A 01600016
*   TITLE 'IHKCDBIS' - INSERT BRDCST MESSAGE                          * 02000016
*                                                                     * 02400016
*   STATUS - CHANGE LEVEL 0                                           * 02800016
*                                                                     * 03200016
*   FUNCTION/OPERATION - THIS ROUTINE IS TO INSERT A NEW MESSAGE INTO * 03600016
*   A PARTICULAR ONE OF THE 100 MESSAGE SLOTS OF THE BRDCST DATA SET. * 04000016
*   THE ORIGINAL CONTENTS OF THIS SLOT AND ALL HIGHER CONSECUTIVE     * 04400016
*   ACTIVE SLOTS ARE TO BE PUSHED UP TO MAKE ROOM.  THIS REQUIRES THAT* 04800016
*   THERE EXISTS AN INACTIVE SLOT AT THIS NUMBER OR A HIGHER NUMBER.  * 05200016
*                                                                     * 05600016
*   ENTRY POINTS -                                                    * 06000016
*                                                                     * 06400016
*        'IHKCDBIS' - INSERT BRDCST MESSAGE                           * 06800016
*                                                                     * 07200016
*   CALLING SEQUENCE -   LA   1,PARLIST                               * 07600016
*                        LINK EP=IHKCDBIS                             * 08000016
*                                                                     * 08400016
*        WHERE 'PARLIST' IS A LIST OF ADDRESS PARAMETERS AS FOLLOWS - * 08800016
*        1ST WORD - ADDRESS OF LIST OF RESIDENT DCB'S                 * 09200016
*        2ND WORD - ADDRESS OF 'IHKAADSP' (DISPATCHER)                * 09600016
*        3RD WORD - ADDRESS OF THE SLOT TO RECEIVE NEW TEXT           * 10000016
*        4TH WORD - ADDRESS OF 60 BYTE AREA CONTAINING TEXT           * 10400016
*        5TH WORD - ADDRESS OF THE SLOT DIRECTORY                     * 10800016
*                                                                     * 11200016
*   INPUT -                                                           * 11600016
*                                                                     * 12000016
*   NONE, OTHER THAN PARAMETERS DESCRIBED ABOVE.                      * 12400016
*                                                                     * 12800016
*   OUTPUT -                                                          * 13200016
*                                                                     * 13600016
*   THE CORE DIRECTORY HAS BEEN REARRANGED TO MAKE ROOM FOR THE NEW   * 14000016
*   MESSAGE.  THE DISC DATA SET CONTAINS THE NEW MESSAGE TEXT.  NO    * 14400016
*   OLD TEXTS HAVE BEEN LOST.                                         * 14800016
*                                                                     * 15200016
*   EXTERNAL ROUTINES -                                               * 15600016
*                                                                     * 16000016
*        'IHKCDBSH' - SEARCH CORE SLOT DIRECTORY FOR INACTIVE SLOT.   * 16400016
*                                                                     * 16800016
*        'IHKCDBTW' - PUT BRDCST MESSAGE TEXT ONTO DISC               * 17200016
*                                                                     * 17600016
*   EXITS-NORMAL -                                                    * 18000016
*                                                                     * 18400016
*   REGISTER 15=0,  MESSAGE HAS BEEN INSERTED AS REQUESTED.           * 18800016
*                                                                     * 19200016
*   EXITS-ERROR -                                                     * 19600016
*                                                                     * 20000016
*   REGISTER 15=4 MESSAGE CANNOT BE INSERTED.  DISC DATA SET          * 20400016
*   UNCHANGED.  CORE SLOT DIRECTORY UNCHANGED.  NEITHER SPECIFIED     * 20800016
*   SLOT NOR ANY HIGHER SLOT WAS FOUND INACTIVE.                      * 21200016
*                                                                     * 21600016
*   REGISTER 15 NOT EQUAL 0 OR 4, DISC ERROR FROM IHKCDBTW. RETURN    * 22000016
*   CODE IS THE OFFSET OF AN ERROR MESSAGE TO BE SENT TO THE CENTRAL  * 22400016
*   OPERATOR.                                                         * 22800016
*                                                                     * 23200016
*   TABLES/WORK AREAS -                                               * 23600016
*                                                                     * 24000016
*   AN 18 WORD SAVE AREA IS PROVIDED.                                 * 24400016
*                                                                     * 24800016
*   AN EXTERNAL CORE SLOT DIRECTORY IS USED.  ITS LOCATION IS PASSED  * 25200016
*   AS THE 5TH WORD OF THE PARAMETER LIST.                            * 25600016
*                                                                     * 26000016
*   ATTRIBUTES - REUSABLE, NON-RESIDENT                               * 26400016
*                                                                     * 26800016
*   NOTES -                                                           * 27200016
*                                                                     * 27600016
*   STANDARD LINKAGE CONVENTIONS ARE FOLLOWED.                        * 28000016
*                                                                     * 28400016
*   PROPER FUNCTIONING OF THIS SUBROUTINE IS DEPENDENT UPON AN        * 28800016
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    * 29200016
*   EQUIVALENT TO THE ONE USED AS ASSEMBLY TIME.  IF THE CHARACTER    * 29600016
*   CONSTANTS ARE REDEFINED, A REASSEMBLY WITHOUT ANY CODING CHANGES  * 30000016
*   SILL RESULT IN A CORRECT SUBROUTINE FOR THE NEW DEFINITIONS.      * 30400016
*                                                                     * 30800016
*********************************************************************** 31200016
*                                                                     * 31600016
*                        REGISTER ASSIGNMENTS                           32000016
*                                                                       32400016
R15      EQU   15                                                       32800016
R14      EQU   14                                                       33200016
R13      EQU   13                                                       33600016
R12      EQU   12                                                       34000016
BASE     EQU   12                       PROGRAM BASE                    34400016
TEMP     EQU   11                       TEMPORARY STORAGE               34800016
SLOT     EQU   10                       ADDRESS OF SLOT IN CORE SLOT    35200016
*                                         DIRECTORY TO CONTAIN NEW      35600016
*                                         MESSAGE                       36000016
LIMIT    EQU   9                        ADDRESS OF END OF SLOT DIRECTOR 36400016
BUMP     EQU   8                        VALUE 4.  USED TO MODIFY        36800016
*                                         POINTERS TO SLOTS             37200016
INACTIVE EQU   7                        ADDRESS OF HIGHER INACTIVE SLOT 37600016
H        EQU   6                        TEMPORARY STORAGE,USED IN       38000016
L        EQU   5                        SWAPPING SLOTS                  38400016
LOW      EQU   4                        ADDRESS OF LOWER SLOT TO BE     38800016
*                                         MOVED UP TO MAKE ROOM         39200016
BIN      EQU   3                        ADDRESS OF TEXT                 39600016
PARM     EQU   2                        HOLDS INPUT PARAM FROM REG 1    40000016
R1       EQU   1                        PARAMETER PASSER                40400016
R0       EQU   0                                                        40800016
*                                                                       41200016
         USING PARLIST,PARM                                             41600016
*                                                                       42000016
         SAVE  (14,12),,*                                          000A 42400016
         BALR  BASE,R0                                             000A 42800016
         USING *,BASE                                              000A 43200016
         ST    R13,SAVE+4                                          000A 43600016
         LA    TEMP,SAVE                                           000A 44000016
         ST    TEMP,8(R13)                                         000A 44400016
         LR    R13,TEMP                                            000A 44800016
*                                                                  000A 45200016
*                       END OF STANDARD ENTRY LINKAGE              000A 45600016
*                                                                  000A 46000016
         LR    PARM,R1                  SAVE INPUT PARAMETER            46400016
         L     SLOT,ADSLOT              SAVE SPECIFIED SLOT ADDRESS     46800016
         CLI   3(SLOT),INAC                                        000A 47200016
         BC    8,RIGHT                                                  47600016
         L     TEMP,ADBTB               GET ADDRESS OF START OF DIRECTR 48000016
         LA    LIMIT,BRDLEN-1(TEMP)     LET LOOP STOPPER           000A 48400016
         LA    BUMP,BRDLN               SET INCREMENTOR            000A 48800016
         LR    TEMP,SLOT                                                49200016
         BXH   TEMP,BUMP,REFUSE         PREPARE ADDRESSES FOR           49600016
*                                         SEARCH TO BEGIN AT NEXT SLOT  50000016
*                                         BEYOND SPECIFIED SLOT.  IF    50400016
*                                         THERE IS NOT NEXT SLOT,ERROR. 50800016
*                                                                       51200016
         MVC   MSHBTB(4),ADBTB          SET PARAMS FOR                  51600016
         ST    TEMP,MSHSLOT               SEARCH ROUTINE                52000016
         LA    R1,MSHBTB                PASS PARAMETER LIST ADDRESS     52400016
*                                       LOOK FOR AN INACTIVE SLOT WITH  52800016
*                                         A HIGHER NUMBER THAN THE ONE  53200016
         LINK  EPLOC=ADCDBSH              SPECIFIED                000A 53600016
         LTR   R15,R15                  WAS AN INACTIVE SLOT FOUND      54000016
         BC    8,FOUND                  YES                             54400016
REFUSE   LR    R15,BUMP                 NO. REFUSE TO INSERT MESSAGE    54800016
EXIT     L     R13,SAVE+4                                               55200016
         RETURN (14,12),T,RC=(15)       EXIT                            55600016
*                                                                       56000016
FOUND    LR    INACTIVE,R1              SAVE ADDRESS OF INACTIVE SLOT   56400016
*                                         FOUND BY SEARCH               56800016
         LR    LOW,R1                   PREPARE TO START MOVING SLOTS   57200016
*                                         UP BY SWAPPING WITH INACTIVE  57600016
*                                         SLOT. WORK FROM HIGH NUMBERED 58000016
*                                         SLOT BACK TO LOWER NUMBERED   58400016
*                                         SPECIFIED SLOT.               58800016
*                                                                       59200016
LOOP     SR    LOW,BUMP                 GET ADDRESS OF ACTIVE SLOT      59600016
*                                         BELOW INACTIVE SLOT           60000016
         L     H,0(INACTIVE)            GET INACTIVE SLOT CONTENTS      60400016
*                                         TO A TEMPORARY REGISTER       60800016
         L     L,0(LOW)                 DO SAME THING WITH ACTIVE SLOT  61200016
         ST    H,0(LOW)                 MOVE DOWN INACTIVE SLOT         61600016
         ST    L,0(INACTIVE)            MOVE UP ACTIVE SLOT             62000016
*                                                                       62400016
*                                       SLOTS HAVE BEEN SWAPPED.        62800016
*                                       HAS THE INACTIVE SLOT BEEN      63200016
*                                         MOVED INTO THE SPECIFIED      63600016
         CR    LOW,SLOT                   SLOT YET                      64000016
         BC    13,RIGHT                 BRANCH IF YES                   64400016
*                                       NO. ADJUST POINTERS TO PREPARE  64800016
         SR    INACTIVE,BUMP              TO SWAP NEXT PAIR             65200016
         B     LOOP                                                     65600016
*                                                                       66000016
RIGHT    LOAD  EPLOC=ADCDBTW                                       000A 66400016
         LR    R15,R0                   SAVE ENTRY POINT ADDRESS        66800016
         LR    R1,PARM                  PASS PARAMETERS TO 'IHKCDBTW'   67200016
         BALR  R14,R15                  CALL IHKCDBTX-PUT TEXT TO DISC  67600016
*                                                                       68000016
         LR    H,R15                                                    68400016
         DELETE EPLOC=ADCDBTW                                      000A 68800016
         LR    R15,H                                                    69200016
         B     EXIT                     QUIT                            69600016
*                                                                       70000016
*********************************************************************** 70400016
*                                                                       70800016
*                        CONSTANTS                                      71200016
*                                                                       71600016
*********************************************************************** 72000016
*                                                                       72400016
INAC     EQU   X'FF'                    INACTIVE SLOT FLAG         000A 72800016
BRDLN    EQU   4                        BYTES/BRDCST SLOT          000A 73200016
NUMBRD   EQU   100                      NO. BRDCST SLOTS           000A 73600016
BRDLEN   EQU   BRDLN*NUMBRD             NO. BYTES IN BRDCST DIRECTR000A 74000016
*                                                                  000A 74400016
SAVE     DC    18F'0'                   LINKAGE SAVE AREA               74800016
*                                                                       75200016
*                                       PARAMETER LIST FOR 'IHKCDBSH'   75600016
MSHBTB   DC    F'0'                     ADDRESS OF SLOT DIRECTORY       76000016
MSHSLOT  DC    F'0'                     ADDRESS OF SLOT TO RECEIVE      76400016
*                                         NEW TEXT                      76800016
*                                                                       77200016
ADCDBSH  DC    CL8'IHKCDBSH'            SEARCH ROUTINE             000A 77600016
ADCDBTW  DC    CL8'IHKCDBTW'            BDAM WRITE DRIVER          000A 78000016
*********************************************************************** 78400016
*                                                                       78800016
*                  DSECT FOR INPUT PARAMETER LIST                       79200016
*                                                                       79600016
*********************************************************************** 80000016
*                                                                       80400016
PARLIST DSECT                                                           80800016
ADDCBS   DS    CL4                      ADDRESS OF RESIDENT DCB'S LIST  81200016
ADDISP   DS    CL4                      ADDRESS OF DISPATCHER           81600016
ADSLOT   DS    CL4                      ADDRESS OF SLOT IN DIRECTORY    82000016
ADBIN    DS    CL4                      ADDRESS OF 60 BYTE I/O AREA     82400016
ADBTB    DS    CL4                      ADDRESS OF CORE SLOT DIRECTORY  82800016
         END                                                            83200016
