INI     TITLE 'IHKCDINI, INITIALIZE 4 DISC TABLES'                      00200015
IHKCDINI CSECT                                                          00400015
*                                                                     * 00600015
* 516000                                                         A29520 00700020
*D100000,108000-110000,680000-692000,770000-772000               A32878 00720021
*A084500-085000,100000,108000-110000,679000-691000               A32878 00740021
*A768800-772800,512600,513200                                    A32878 00760021
*C516000                                                         A32878 00780021
*C 482000-486000                                                 A48981 00830021
*                                                                     * 00880021
* STATUS - CHANGE LEVEL 2, RELEASE 21.6                               * 00930021
*                                                                     * 01000015
*FUNCTION/OPERATION -                                                 * 01200015
*                                                                     * 01400015
*   THIS ROUTINE FORMATS THE SPACE ON DISC ALLOCATED TO EACH OF THE 4 * 01600015
*   DATA SETS TO CONTAIN THE RJE INTERNAL CONTROL TABLES SO THAT THE  * 01800015
*   VARIOUS TABLE MANAGERS CAN USE 'BDAM' TO REFERENCE THESE DISC     * 02000015
*   DATA SETS.  THIS IS DONE BY WRITING BLANK (DUMMY) RECORDS ON THE  * 02200015
*   DISC AND RECORDING THE RELATIVE TRACK AND RECORD (TTR) ADDRESS    * 02400015
*   WITHIN EACH RECORD.                                               * 02600015
*                                                                     * 02800015
*ENTRY POINT                                                          * 03000015
*                                                                     * 03200015
*        'IHKCDINI' - PREPARE DISC FOR TABLE MANAGERS.                * 03400015
*                                                                     * 03600015
*   CALLING SEQUENCE - L    15,=V(IHKCDINI)                           * 03800015
*                      BALR 14,15                                       04000015
*                                                                     * 04200015
*INPUT - N/A                                                          * 04400015
*                                                                     * 04600015
*OUTPUT -                                                             * 04800015
*                                                                     * 05000015
*   ON DISC WILL BE 4 DATA SETS, ONE FOR EACH OF THE 4 RJE SYSTEM     * 05200015
*   CONTROL TABLES.                                                   * 05400015
*                                                                     * 05600015
*              TABLE NAME               DDNAME                        * 05800015
*                                                                     * 06000015
*              FAST TABLE              'IHKFSTDD'                     * 06200015
*              JED TABLE               'IHKJEDDD'                     * 06400015
*              USER DIRECTORY          'IHKUDRDD'                     * 06600015
*              TERMINAL DIRECTORY      'IHKTDRDD'                     * 06800015
*                                                                     * 07000015
*   THE NO. OF BYTES PER RECORD IS THE SAME AS THE NO. OF BYTES PER   * 07200015
*   ENTRY AS DEFINED IN 'IHKCDTAB CSECT'.  ALL RECORDS, EXCEPT THOSE  * 07400015
*   IN THE 'JEDTABLE' HAVE A 3 BYTE FIELD CONTAINING A TTR POINTER    * 07600015
*   TO THAT SAME RECORD.  TTR POINTERS FOR THE 'JEDTABLE' ARE IN THE  * 07800015
*   CORRESPONDING RECORD OF THE 'FASTABLE'.  THE REMAINING FIELDS     * 08000015
*   REMAIN DEFINED AS THEY WERE WHEN 'IHKCDTAB' WAS ASSEMBLED.        * 08200015
*                                                                     * 08400015
*   AN ERROR MESSAGE IS DISPLAYED IF THE DCB FOR A TABLE IS NOT  A32878 08450021
*   OPENED OR IF THERE IS A DISK WRITE ERROR.                    A32878 08500021
*                                                                     * 08550021
*EXTERNAL ROUTINES -                                                  * 08600015
*                                                                     * 08800015
*        'BSAM' - (OS BASIC SEQUENTIAL ACCESS METHOD).  STANDARD USE  * 09000015
*   IS MADE OF MACROS 'OPEN', 'CLOSE', 'WRITE', 'NOTE', AND 'CHECK'.  * 09200015
*                                                                     * 09400015
*EXITS-NORMAL                                                         * 09600015
*                                                                     * 09800015
*   A CODE OF ZERO IN REGISTER 15 INDICATES NORMAL COMPLETION.   A32878 10000021
*                                                                       10200021
*   EXITS - ERROR                                                       10400021
*                                                                     * 10600021
*   REGISTER 15 = 4 INDICATES THAT A DCB FAILED TO OPEN.         A32878 10800021
*   REGISTER 15 = 8 INDICATES A WRITE OPERATION ERROR.           A32878 11000021
*                                                                     * 11200015
*TABLES,WORK AREAS    N/A                                             * 11400015
*                                                                     * 11600015
*ATTRIBUTES - REUSABLE                                                * 11800015
*                                                                     * 12000015
*NOTES -                                                              * 12200015
*                                                                     * 12400015
*   STANDARD LINKAGE CONVENTIONS ARE FOLLOWED.                        * 12600015
*                                                                     * 12800015
*   EXTERNAL REFERENCES ARE MADE TO A SERIES OF CONSTANTS AND AREAS   * 13000015
*   DEFINED IN 'IHKCDTAB CSECT.'  THESE HALFWORDS DEFINE THE SIZE     * 13200015
*   OF ALL 4 TABLES.  THESE ARE INDIVIDUALLY DEFINED UNDER 'CONSTANTS'* 13400015
*   IN THIS LISTING.  (SEE EXTRN STATEMENTS.)                         * 13600015
*                                                                     * 13800015
*   THE OPERATION OF THIS SUBROUTINE DEPENDS UPON AN INTERNAL         * 14000015
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 14200015
*   TO THE ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED    * 14400015
*   SO THAT REDEFINITION OF THE CHARACTER CONSTANTS, BY REASSEMBLY,   * 14600015
*   WILL RESULT IN A CORRECT SUBROUTINE FOR THE NEW DEFINITIONS.      * 14800015
*                                                                     * 15000015
*                                                                     * 15200015
*********************************************************************** 15400015
*                                                                       15600015
*              ESTABLISH ADDRESSABILIYTY OF DSECT                       15800015
*                                                                       16000015
         USING IHADCB,DCB                                               16200015
         USING CVT,R15                                                  16400015
*                                                                       16600015
*********************************************************************** 16800015
*                                                                       17000015
*                  R E G I S T E R    A S S I G N M E N T S             17200015
*                                                                       17400015
R15      EQU   15                                                       17600015
R14      EQU   14                                                       17800015
R13      EQU   13                                                       18000015
R12      EQU   12                                                       18200015
BASE     EQU   12                       PROGRAM BASE                    18400015
LENTJEDT EQU   11                       NO. BYTES PER JEDTABLE ENTRY    18600015
TEMP     EQU   10                       TEMPORARY STORAGE               18800015
AREA     EQU   9                        OUTPUT BIN ADDRESS              19000015
LENTFAST EQU   8                        NO. BYTES PER ENTRY             19200015
R8       EQU   8                                                        19400015
NUMBFAST EQU   7                        NO. ENTRIES IN TABLE            19600015
XX       EQU   6                        RETURN ADDRESS                  19800015
CNT      EQU   5                        NO. ENTRIES IN FASTABLE         20000015
X        EQU   4                        RETURN ADDRESS                  20200015
DCB      EQU   3                        ADDRESS OF PROPER DCB           20400015
FASTBASE EQU   2                        ADDRESS OF TABLE                20600015
R2       EQU   2                                                        20800015
R1       EQU   1                                                        21000015
R0       EQU   0                                                        21200015
*                                                                       21400015
TDIRBASE EQU   FASTBASE                                                 21600015
UDIRBASE EQU   TDIRBASE                                                 21800015
*                                                                       22000015
LENTTDIR EQU   LENTFAST                                                 22200015
LENTUDIR EQU   LENTTDIR                                                 22400015
*                                                                       22600015
NUMBTDIR EQU   NUMBFAST                                                 22800015
NUMBUDIR EQU   NUMBTDIR                                                 23000015
*                                                                       23200015
*********************************************************************** 23400015
*                                                                       23600015
*                       ENTRY  IHKCDINI (INITIALIZE)                    23800015
*                                                                       24000015
*********************************************************************** 24200015
*                                                                       24400015
         SAVE (14,12),,*                                                24600015
         BALR  R12,R0                   ESTABLISH MY                    24800015
         USING *,R12                      BASE REGISTER                 25000015
BIN      DS    0H                       DUMMY I/O AREA.  JED IS         25200015
*                                         INITIALIZED TO UNDEFINED      25400015
*                                         DATA WHICH IS ACTUALLY THE    25600015
*                                         FOLLOWING CODE                25800015
         ST    R13,SAVE+4               KEEP HIS SAVE AREA ADDRESS      26000015
         LA    TEMP,SAVE                GET MY SAVEAREA ADDRESS         26200015
         ST    TEMP,8(R13)              PASS IT TO CALLER               26400015
         LR    R13,TEMP                 PASS IT TO NEXT PROGRAM         26600015
*                                                                       26800015
*                   END OF STANDARD ENTRY LINKAGE                       27000015
*                                                                       27200015
         L     TEMP,ADJEDLEN            GET NO. BYTES PER ENTRY         27400015
         LH    LENTJEDT,0(TEMP)           IN JEDTABLE                   27600015
         L     TEMP,ADFSTNUM            GDT NO. ENTRIES                 27800015
         LH    CNT,0(TEMP)                IN FASTABLE                   28000015
         BAL   X,SETFAST                SET CONSTANTS FOR FASTABLE      28200015
*                                                                       28400015
         MR    NUMBFAST-1,LENTFAST      SET ADDRESS OF 1ST BYTE BEYOND  28600015
         AR    NUMBFAST,FASTBASE        USABLE FASTABLE INTO EXTERNAL   28800015
         L     TEMP,ADEOS                 CONSTANT 'FASTEOS'            29000015
         ST    NUMBFAST,0(TEMP)                                         29200015
         MVI   1(NUMBFAST),XFF          SET TO 'ROLLED OUT' - CHECKED   29400015
*                                         BY ROLLIN ROUTINE             29600015
         LR    NUMBFAST,CNT             RESTORE COUNT                   29800015
*                                                                       30000015
* SET ALL 4 WRITE DCB'S TO LOAD MODE. SET LRECL + BLKSIZE               30200015
*                                                                       30400015
         BAL   X,STH                    FOR FASTABLE,                   30600015
*                                                                       30800015
         LA    DCB,WRITJED                JEDTABLE,                     31000015
         LR    R8,LENTJEDT                                              31200015
         BAL   X,STH                                                    31400015
*                                                                       31600015
         BAL   X,SETUDIR                  USER DIRECTORY,               31800015
         BAL   X,STH                                                    32000015
*                                                                       32200015
         BAL   X,SETTDIR                  AND TERMINAL DIRECTORY        32400015
         BAL   X,STH                                                    32600015
*                                                                       32800015
         BAL   X,OPEN                   OPEN ALL 4 DCB'S                33000015
*                                                                       33200015
* WRITE OUT BLANK ENTRIES ONTO ALL 4 DISC DATA SETS TO FORMAT THE DISC  33400015
* AREA.  PAD OUT UNUSED PORTIONS OF THE LAST TRACK OF EACH DATA SET.    33600015
*                                                                       33800015
         LA    AREA,BIN                 GET OUTPUT BIN OF BLANKS        34000015
         LA    DCB,WRITJED                                              34200015
         LR    NUMBFAST,CNT             SET NO. JED ENTRIES             34400015
         BAL   X,LOOPDUM                FORMAT DISC JED AREA            34600015
*                                                                       34800015
         LA    DCB,WRITFAST                                             35000015
         LA    NUMBFAST,1(CNT)          INCLUDE EXTRA FAST ENTRY        35200015
         BAL   X,LOOPDUM                FORMAT DISC FAST AREA           35400015
*                                                                       35600015
         BAL   X,SETUDIR                SET UDIR CONSTANTS              35800015
         BAL   X,LOOPDUM                FORMAT DISC UDIR AREA           36000015
*                                                                       36200015
         BAL   X,SETTDIR                SET TDIR CONSTANTS              36400015
         BAL   X,LOOPDUM                FORMAT DISC TDIR AREA           36600015
*                                                                       36800015
         CLOSE (WRITFAST,,WRITJED,,WRITUDIR,,WRITTDIR)                  37000015
*                                                                       37200015
* SET ALL 4 DCB'S TO NOTE MODE, SO TTR'S CAN BE NOTED                   37400015
*                                                                       37600015
         LA    DCB,WRITFAST                                             37800015
         MVC   DCBMACR,NOTEMODE                                         38000015
         LA    DCB,WRITJED                                              38200015
         MVC   DCBMACR,NOTEMODE                                         38400015
         LA    DCB,WRITUDIR                                             38600015
         MVC   DCBMACR,NOTEMODE                                         38800015
         LA    DCB,WRITTDIR                                             39000015
         MVC   DCBMACR,NOTEMODE                                         39200015
*                                                                       39400015
         BAL   X,OPEN                   OPEN IN NOTE MODE               39600015
*                                                                       39800015
* AGAIN WRITE OUT BLANK RECORDS ONTO ALL 4 DISC DATA SETS WHICH HAVE    40000015
* NOW BEEN PRE-FORMATTED AND NOTE 'TTR' LOCATIONS OF EACH RECORD. SAVE  40200015
* THIS 'TTR' INFORMATION IN THE CORRESPONDING ENTRY OF THE CORE TABLE.  40400015
*                                                                       40600015
         USING FASTAB,FASTBASE                                          40800015
         BAL   X,SETFAST                SET CONSTANTS                   41000015
         LA    DCB,WRITJED                FOR JED                       41200015
LOOPJ    BAL   X,WRITNOTE               GET TTR'S FOR EACH JED RECORD   41400015
         MVC   FASTJEDT,WORD            SAVE JED TTR IN CORE FASTABLE   41600015
         AR    FASTBASE,LENTFAST        BUMP INDEX TO NEXT FAST ENTRY   41800015
         BCT   NUMBFAST,LOOPJ                                           42000015
*                                                                       42200015
         BAL   X,SETFAST                SET CONSTANTS FOR FASTABLE      42400015
         LA    NUMBFAST,1(NUMBFAST)     COUNT EXTRA FAST ENTRY          42600015
LOOPF    BAL   X,WRITNOTE               GET TTR'S OF EACH FAST RECORD   42800015
         MVC   FASTTTR,WORD             SAVE TTR IN CORE FASTABLE       43000015
         AR    FASTBASE,LENTFAST        BUMP INDEX TO NEXT FAST ENTRY   43200015
         BCT   NUMBFAST,LOOPF                                           43400015
*                                                                       43600015
         DROP  FASTBASE                                                 43800015
         USING UDIREC,UDIRBASE                                          44000015
*                                                                       44200015
         BAL   X,SETUDIR                SET CONSTANTS FOR UDIR          44400015
LOOPU    BAL   X,WRITNOTE               GET TTR'S FOR EACH UDIR RECORD  44600015
         MVC   UDIRTTR,WORD             SAVE TTR IN CORE UDIR           44800015
         AR    UDIRBASE,LENTUDIR        BUMP INDEX TO NEXT UDIR ENTRY   45000015
         BCT   NUMBUDIR,LOOPU                                           45200015
*                                                                       45400015
         DROP  UDIRBASE                                                 45600015
         USING TDIREC,TDIRBASE                                          45800015
*                                                                       46000015
         BAL   X,SETTDIR                SET CONSTANTS FOR TDIR          46200015
LOOPT    BAL   X,WRITNOTE               GET TTR'S OF EACH TDIR RECORD   46400015
         MVC   TDIRTTR,WORD             SAVE TTR IN CORE TDIR           46600015
         AR    TDIRBASE,LENTTDIR        BUMP INDEX TO NEXT TDIR ENTRY   46800015
         BCT   NUMBTDIR,LOOPT                                           47000015
*                                                                       47200015
* CORE TABLES EACH CONTAIN TTR POINTERS TO ITS CORRESPONDING DISC       47400015
* RECORD.  MOVE CORE ENTRIES TO THIS PROPER DISC RECORD, SO DISC WILL   47600015
* HAVE TTR POINTERS ALSO.                                               47800015
*                                                                       48000015
*                                                                     * 48100021
* CLOSE AND OPEN TO START WRITING AT START OF DATA SETS               * 48200021
*                                                                     * 48300021
         CLOSE (WRITFAST,,WRITUDIR,,WRITTDIR)                    A48981 48400021
*                                                                A48981 48500021
         OPEN  (WRITFAST,(OUTPUT),WRITUDIR,(OUTPUT),WRITTDIR,(OUTPUT))  48600021
*                                                                       48800015
         BAL   X,SETFAST                SET CONSTANTS FOR FASTABLE      49000015
         LA    NUMBFAST,1(NUMBFAST)     COUNT EXTRA FAST ENTRY          49200015
         BAL   X,DISCTTR                RECORD FASTABLE ENTRIES WITH    49400015
*                                         TTR'S ON DISC                 49600015
         BAL   X,SETUDIR                SET CONSTANTS FOR UDIR          49800015
         BAL   X,DISCTTR                RECORD UDIR ENTRIES WITH        50000015
*                                         TTR'S ON DISC                 50200015
         BAL   X,SETTDIR                SET CONSTANTS FOR TDIR          50400015
         BAL   X,DISCTTR                RECORD TDIR ENTRIES WITH        50600015
*                                         TTR'S ON DISC                 50800015
         CLOSE (WRITFAST,,WRITJED,,WRITUDIR,,WRITTDIR)                  51000015
*                                                                       51200015
         SR    R15,R15                 SET RETURN CODE           A32878 51260021
ABNMEXIT EQU   *                     ENTRY TO EXIT IF I/O ERROR  A32878 51320021
         L     R13,SAVE+4                                               51400015
         RETURN (14,12),T,RC=(15)    RETURN TO CALLER            A32878 51600021
*                                                                       51800015
*********************************************************************** 52000015
*                                                                       52200015
*                       INTERNAL  SUBROUTINES                           52400015
*                                                                       52600015
*********************************************************************** 52800015
*                                                                       53000015
DISCTTR  WRITE DECB2,SF,(3),(2)                                         53200015
*                                                                       53400015
         CHECK DECB2                                                    53600015
*                                                                       53800015
         AR    R2,R8                                                    54000015
         BCT   7,DISCTTR                                                54200015
         BR    X                                                        54400015
*                                                                       54600015
*********************************************************************** 54800015
*                                                                       55000015
SETFAST  L     TEMP,ADFSTLEN            GET NO.BYTES PER ENTRY          55200015
         LH    LENTFAST,0(TEMP)           IN FASTABLE                   55400015
         LR    NUMBFAST,CNT             GET NO. ENTRIES                 55600015
         L     FASTBASE,ADFSTABL        GET START OF FASTABLE           55800015
         LA    DCB,WRITFAST                                             56000015
         BR    X                                                        56200015
*                                                                       56400015
*********************************************************************** 56600015
*                                                                       56800015
SETUDIR  L     TEMP,ADUDRLEN            GET NO. BYTES PER ENTRY         57000015
         LH    LENTUDIR,0(TEMP)           OF USER DIRECTORY             57200015
         L     TEMP,ADUDRNUM            GET NO. ENTRIES                 57400015
         LH    NUMBUDIR,0(TEMP)           IN USER DIRECTORY             57600015
         L     UDIRBASE,ADUDIR          GET START OF UDIR               57800015
         LA    DCB,WRITUDIR                                             58000015
         BR    X                                                        58200015
*                                                                       58400015
*********************************************************************** 58600015
*                                                                       58800015
SETTDIR  L     TEMP,ADTDRLEN            GET NO. BYTES PER ENTRY         59000015
         LH    LENTTDIR,0(TEMP)           INTERMINAL DIRECTORY          59200015
         L     TEMP,ADTDRNUM            GET NO. ENTRIES                 59400015
         LH    NUMBTDIR,0(TEMP)           IN TERMINAL DIRECTORY         59600015
         L     TDIRBASE,ADTDIR          GET START OF TDIR               59800015
         LA    DCB,WRITTDIR                                             60000015
         BR    X                                                        60200015
*                                                                       60400015
*********************************************************************** 60600015
*                                                                       60800015
STH      MVC   DCBMACR,LOADMODE                                         61000015
         STH   R8,DCBLRECL                                              61200015
         STH   R8,DCBBLKSI                                              61400015
         BR    X                                                        61600015
*                                                                       61800015
*********************************************************************** 62000015
*                                                                       62200015
OPEN OPEN (WRITFAST,(OUTPUT),WRITJED,(OUTPUT),WRITUDIR,(OUTPUT),       *62400015
               WRITTDIR,(OUTPUT))                                       62600015
*                                                                       62800015
         BR    X                                                        63000015
*                                                                       63200015
*********************************************************************** 63400015
*                                                                       63600015
WRITE    WRITE DECBWRIT,SF,(3),(9)      WRITE DUMMY RECORD TO DISC      63800015
*                                                                       64000015
         LR    TEMP,R15                 SAVE TRACK FULL INDICATOR       64200015
*                                                                       64400015
         CHECK DECBWRIT                 WAIT FOR COMPLETED WRITE        64600015
*                                                                       64800015
         BR    XX                                                       65000015
*                                                                       65200015
*********************************************************************** 65400015
*                                                                       65600015
WRITNOTE BAL   XX,WRITE                 WRITE A DUMMY RECORD            65800015
*                                                                       66000015
         NOTE  (3)                      GET TTR                         66200015
*                                                                       66400015
         ST    R1,WORD                  SAVE TTR                        66600015
         BR    X                                                        66800015
*                                                                       67000015
*********************************************************************** 67200015
*                                                                       67400015
LOOPDUM  TM    DCBOFLGS,DCBOP           IS THIS DCB OPEN                67600015
         BC    7,YES                      YES, BRANCH TO WRITE ROUTINE  67800015
*                                      NO, ISSUE ERROR MESSAGE   A32878 67850021
         MVC   WTOPARM1+58(8),DCBDDNAM MOVE DDNAME INTO MESSAGE  A32878 67900021
         LA    R1,WTOPARM1             IN PARAMETER LIST         A32878 67950021
         WTO   MF=(E,(1))              ISSUE DISK OPEN ERROR     A32878 68000021
*                                      TO CONSOLE AND USER       A32878 68050021
         LA    R15,X                   SET RETURN CODE           A32878 68100021
         B     ABNMEXIT                RETURN                    A32878 68150021
         SPACE 1                                                        68200021
SYNAD    EQU   *                   COME HERE IF I/O ERR WRITTING A32878 68250021
*                                                                A32878 68300021
*  GET DDNAME FROM TIOT TO PUT INTO ERROR MSG TO CONSLE AND USER A32878 68350021
*                                                                A32878 68400021
         L     TEMP,CVTAD          GET CVT ADDRESS               A32878 68450021
         L     TEMP,0(TEMP)        GET PTR TO TCBWORDS           A32878 68500021
         L     TEMP,TCBAD(TEMP)    GET TCB ADDRESS               A32878 68550021
         L     TEMP,TIOTAD(TEMP)   GET TIOT ADDRESS              A32878 68600021
         ST    TEMP,WORD           SAVE PTR TO TIOT              A32878 68650021
         LH    TEMP,DCBTIOT        GET OFFSET INTO TIOT OF THE   A32878 68700021
*                                  ASSOCIATED DDENTRY            A32878 68750021
         A     TEMP,WORD           ADD DD OFFSET TO TIOT ORIGIN  A32878 68800021
*                                                                A32878 68850021
         MVC   WTOPARM2+56(8),4(TEMP) PUT DDNAME INTO ERR MESSGE A32878 68900021
         LA    R1,WTOPARM2             IN PARAMETER LIST         A32878 68950021
         WTO   MF=(E,(1))              ISSUE DISK I/O ERROR      A32878 69000021
*                                      TO CONSOLE AND USER       A32878 69050021
         LA    R15,LENTFAST            SET RETURN CODE           A32878 69100021
         B     ABNMEXIT                RETURN                    A32878 69150021
*                                                                       69400015
YES      BAL   XX,WRITE                 FORMAT DISC AREA                69600015
         BCT   NUMBFAST,YES             ONE DISC RECORD PER CORE ENTRY  69800015
PAD      LTR   TEMP,TEMP                WAS THAT THE END OF TRACK       70000015
         BCR   7,X                      IF SO, AREA FORMATTED           70200015
         BAL   XX,WRITE                 CONTINUE WRITING TO END OF TRK  70400015
         B     PAD                                                      70600015
*                                                                       70800015
*********************************************************************** 71000015
*                                                                       71200015
*                       C O N S T A N T S                               71400015
*                                                                       71600015
*********************************************************************** 71800015
*                                                                       72000015
XFF      EQU   X'FF'                    'ROLLED OUT' INDICATOR          72200015
DCBOP    EQU   X'10'                    CHECKS OPEN FLAG IN DCB         72400015
*                                                                       72600015
SAVE     DC    18F'0'                   LINKAGE SAVE AREA               72800015
WORD     DC    F'0'                     TEMPORARY STORAGE OF TTR        73000015
*                                                                       73200015
* THE FOLLOWING ADCONS REFER TO EXTERNAL DESCRIPTIONS OF THE 4          73400015
* TABLES AS DEFINED IN 'IHKCDTAB CSECT'.                                73600015
*                                                                       73800015
ADEOS    DC    A(IHKCDFES)              CORE LIMIT OF FASTABLE          74000015
ADFSTABL DC    A(IHKCDFTB)              CORE FASTABLE                   74200015
ADFSTLEN DC    A(IHKCDFLN)              NO. BYTES PER FAST ENTRY        74400015
ADFSTNUM DC    A(IHKCDFNB)              NO. ENTRIES IN FASTABLE         74600015
ADUDIR   DC    A(IHKCDUDR)              CORE USER DIRECTORY             74800015
ADUDRLEN DC    A(IHKCDULN)              NO. BYTES PER USER ENTRY        75000015
ADUDRNUM DC    A(IHKCDUNB)              NO. ENTRIES IN UDIR             75200015
ADTDIR   DC    A(IHKCDTDR)              CORE TERMINAL DIRECTORY         75400015
ADTDRLEN DC    A(IHKCDTLN)              NO. BYTES PER TDIR ENTRY        75600015
ADTDRNUM DC    A(IHKCDTNB)              NO. ENTRIES IN TDIR             75800015
ADJEDLEN DC    A(IHKCDJLN)              NO. BYTES PER JED ENTRY         76000015
         EXTRN IHKCDFES,IHKCDFTB,IHKCDFLN,IHKCDFNB                      76200015
         EXTRN IHKCDUDR,IHKCDULN,IHKCDUNB                               76400015
         EXTRN IHKCDTDR,IHKCDTLN,IHKCDTNB,IHKCDJLN                      76600015
*                                                                       76800015
WTOPARM1 DS    0F                                                A32878 76860021
         WTO   ' IHK063I  DISK ERROR - INITIALIZATION UNABLE TO OPEN  *X76920021
               *******',MF=L,ROUTCDE=(4,11),DESC=4               A32878 76980021
WTOPARM2 DS    0F                                                A32878 77040021
         WTO   ' IHK063I  DISK ERROR - INITIALIZATION I/O ERROR ON  ***X77100021
               *****',MF=L,ROUTCDE=(4,11),DESC=4                 A32878 77160021
CVTAD    EQU   X'10'               PERMANENT CORE LOC OF CVT PTR A32878 77220021
TCBAD    EQU   X'04'               DISP INTO TCBWORDS OF CURRENT A32878 77280021
TIOTAD   EQU   X'0C'               DISP INTO TCB OF TIOTPTR      A32878 77340021
*                                                                       77400015
LOADMODE DC    X'0028'                  MACRF=WL                        77600015
NOTEMODE DC    X'0024'                  MACRF=WP                        77800015
*                                                                       78000015
WRITFAST DCB   DSORG=PS,                                               *78200015
               MACRF=WL,                                               *78400015
               DDNAME=IHKFSTDD,                                        *78600015
               RECFM=F,                                                *78800015
               SYNAD=SYNAD,                                            *79000015
               BUFNO=1                                                  79200015
*                                                                       79400015
WRITJED  DCB   DSORG=PS,                                               *79600015
               MACRF=WL,                                               *79800015
               DDNAME=IHKJEDDD,                                        *80000015
               RECFM=F,                                                *80200015
               SYNAD=SYNAD,                                            *80400015
               BUFNO=1                                                  80600015
*                                                                       80800015
WRITUDIR DCB   DSORG=PS,                                               *81000015
               MACRF=WL,                                               *81200015
               DDNAME=IHKUDRDD,                                        *81400015
               RECFM=F,                                                *81600015
               SYNAD=SYNAD,                                            *81800015
               BUFNO=1                                                  82000015
*                                                                       82200015
WRITTDIR DCB   DSORG=PS,                                               *82400015
               MACRF=WL,                                               *82600015
               DDNAME=IHKTDRDD,                                        *82800015
               RECFM=F,                                                *83000015
               SYNAD=SYNAD,                                            *83200015
               BUFNO=1                                                  83400015
*                                                                       83600015
         DCBD  DSORG=BS,DEVD=DA                                         83800015
*                                                                       84000015
CVT      DSECT                                                          84200015
         CVT                                                            84400015
         IHKDSECT TDIR,UDIR,FASTAB                                      84600015
         END                                                            84800015
