MDE TITLE '''IHKCDMDE'' - DELETE ALL DELAYED MESSAGES FOR ONE TERMINAL' 00400016
IHKCDMDE CSECT                                                          00800016
*2782348000,420000,460000-468000,484000,512000-520000,528000-532000000A 01200016
*2782556000,568000,580000-584000,628000,636000,800000-816000       000A 01600016
*                                                                     * 02000016
*   TITLE - 'IHKCDMDE' - DELETE ALL DELAYED MESSAGES FOR ONE TERMINAL.* 02400016
*                                                                     * 02800016
*   STATUS - CHANGE LEVEL 0                                           * 03200016
*                                                                     * 03600016
*   FUNCTION/OPERATION - THIS ROUTINE IS TO SEARCH THE MSG SLOT       * 04000016
*   DIRECTORY FOR ALL SLOTS ASSOCIATED WITH A PARTICULAR TERMINAL,    * 04400016
*   AND TO DELETE ALL TEXTS DIRECTED TO THIS TERMINAL BY MARKING ALL  * 04800016
*   CORRESPONDING SLOTS 'INACTIVE'.                                   * 05200016
*                                                                     * 05600016
*   ENTRY POINT -                                                     * 06000016
*                                                                     * 06400016
*        'IHKCDMDE' - DELETE MESSAGES FOR ONE TERMINAL.               * 06800016
*                                                                     * 07200016
*   CALLING SEQUENCE -   LA   R1,PARLIST                              * 07600016
*                        LINK EP=IHKCDMDE                             * 08000016
*         WHERE 'PARLIST' IS DEFINED AS -                             * 08400016
*                PARLIST  DC  A(IHKCDCBS)  LIST OF RESIDENT DCB'S     * 08800016
*                         DC  V(IHKAADSP)  ADDR OF DISPATCHER         * 09200016
*                         DC  F'0'        ADDR OF TERMINAL DIRECTORY  * 09600016
*                                          ENTRY OF TERMINAL WHOSE    * 10000016
*                                          MESSAGES ARE TO BE DELETED * 10400016
*                        DC  F'0'         ADDR OF TERMINAL DIRECTORY  * 10800016
*                         DC  V'IHKCDTMR' ADDR OF TDIR MANAGER        * 11200016
*                                                                     * 11600016
*   INPUT - THE PARAMETER IN REGISTER 1 IS THE ADDRESS OF A PARAMETER * 12000016
*   LIST WHICH CONTAINS THE FIVE FULL WORD ADDRESSES DESCRIBED ABOVE. * 12400016
*                                                                     * 12800016
*   OUTPUT - THE MSG SLOT DIRECTORY WILL BE ALTERED AS REQUESTED.     * 13200016
*                                                                     * 13600016
*   EXTERNAL ROUTINES -                                               * 14000016
*        'IHKCDBIN' - ROLLIN MSG SLOT DIRECTORY FROM DISC             * 14400016
*                                                                     * 14800016
*        'IHKCDBOT' - ROLLOUT SLOT DIRECTORY TO DISK AND UNLOCK.      * 15200016
*                                                                     * 15600016
*        'IHKCDTMR' - RECORDS TERMINAL DIRECTORY ONTO DISC            * 16000016
*                                                                     * 16400016
*   EXITS-NORMAL -                                                    * 16800016
*                                                                     * 17200016
*   REGISTER 15=0. ANY MESSAGES FOR THE TERMINAL WERE DELETED.        * 17600016
*                                                                     * 18000016
*   AN X'FF' IS IN THE FIRST BYTE OF THE FOURTH WORD OF THE CALLER'S  * 18400016
*   SAVE AREA TO INDICATE THE COMPLETION OF THIS ROUTINE.             * 18800016
*                                                                     * 19200016
*   EXITS-ERROR -                                                     * 19600016
*                                                                     * 20000016
*   REGISTER 15 NON-ZERO. THIS IS AN OFFSET FOR AN APPROPRIATE DISC   * 20400016
*   ERROR MESSAGE PASSED BY IHKCDBIN OR IHKCDBOT UPON DETECTION OF    * 20800016
*   AN I/O ERROR.                                                     * 21200016
*                                                                     * 21600016
*   TABLES/WORK AREAS - AN 18 WORD SAVE AREA IS PROVIDED.             * 22000016
*                                                                     * 22400016
*   ATTRIBUTES - REUSABLE, NON-RESIDENT                               * 22800016
*                                                                     * 23200016
*   NOTES -                                                           * 23600016
*                                                                     * 24000016
*   PROPER FUNCTIONING OF THIS SUBROUTINE IS DEPENDENT UPON AN        * 24400016
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    * 24800016
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  IF THE CHARACTER    * 25200016
*   CONSTANTS ARE REDEFINED, A REASSEMBLY WITHOUT ANY CODING CHANGES  * 25600016
*   STILL RESULT IN A CORRECT SUBROUTINE FOR THE NEW DEFINITIONS.     * 26000016
*                                                                     * 26400016
*   STANDARD LINKAGE CONVENTIONS ARE FOLLOWED.                        * 26800016
*                                                                       27200016
**********************************************************************  27600016
*                                                                       28000016
*                        REGISTER ASSIGNMENTS                           28400016
*                                                                       28800016
**********************************************************************  29200016
*                                                                       29600016
R15      EQU   15                                                       30000016
R14      EQU   14                                                       30400016
R13      EQU   13                                                       30800016
R12      EQU   12                                                       31200016
BASE     EQU   12                       PROGRAM BASE                    31600016
TEMP     EQU   11                       TEMPORARY STORAGE               32000016
PARM     EQU   10                       HOLDS INPUT FROM REG1           32400016
MTB      EQU   9                        ADDRESS OF SLOT DIRECTORY       32800016
ADBOT    EQU   8                        ADDRESS OF ROLLOUT              33200016
LIMIT    EQU   7                        LOOP STOPPER                    33600016
BUMP     EQU   6                        INCREMENTOR                000A 34000016
RENT     EQU   5                        ADDRESS TO TDIR ENTRY           34400016
NOTUSED4 EQU   4                                                        34800016
NOTUSED3 EQU   3                                                        35200016
NOTUSED2 EQU   2                                                        35600016
R1       EQU   1                                                        36000016
R0       EQU   0                                                        36400016
*                                                                       36800016
         USING PARLIST,PARM             BASE OF PARAMETER LIST DSECT    37200016
         USING TDIREC,RENT              BASE OF TERMINAL DIRECTORY      37600016
*                                         DSECT                         38000016
*                                                                       38400016
*********************************************************************** 38800016
*                                                                       39200016
*                        ENTRY IHKCDMDE                                 39600016
*                                                                       40000016
*********************************************************************** 40400016
*                                                                       40800016
         SAVE  (14,12),,*                                          000A 41200016
         BALR  BASE,R0                  ESTABLISH PROGRAM BASE          41600016
         USING *,BASE                                                   42000016
         ST    R13,SAVE+4               KEEP HIS SAVE AREA ADDRESS      42400016
         LA    TEMP,SAVE                GET MY SAVE AREA ADDRESS        42800016
         ST    TEMP,8(R13)              GIVE IT TO CALLER               43200016
         LR    R13,TEMP                 PASS IT ON TO NEXT PROG         43600016
*                                                                       44000016
*                        END OF STANDARD ENTRY                          44400016
*                                                                       44800016
         LR    PARM,R1                  SAVE INPUT PARAMETER            45200016
         MVC   DISPATCH,ADDISP          PASS DISPATCHER ADDR TO ROLLIN  45600016
         MVC   ADDCBS,ADDCB             SAVE PARAMETER                  46000016
         LOAD  EPLOC=ADCDBIN                                       000A 46400016
         LR    R15,R0                   SAVE ENTRY POINT ADDRESS        46800016
         LA    R1,ADDCBS                PASS PARAM LIST TO ROLLIN       47200016
         BALR  R14,R15                  CALL ROLLIN                     47600016
         LR    MTB,R1                   SAVE ADDR OF SLOT DIRECTORY     48000016
         LR    ADBOT,R15                SAVE ADDR OF ROLLOUT ROUTINE    48400016
*                                                                       48800016
         SRL   R15,SHIFT                SHIFT OUT ALL BUT OFFSET   000A 49200016
         LTR   TEMP,R15                 SAVE RETURN CODE           000A 49600016
*                                         IS DISC ERROR IN BIN     000A 50000016
         BNZ   OUT                      IF SO, CLEAN HOUSE AND RETURN   50400016
         LA    BUMP,MSGLN               SET INCREMENTOR            000A 50800016
         LA    LIMIT,MSGLEN-1(MTB)      SET LOOP STOPPER           000A 51200016
         L     TEMP,ADENT               GET ADDRESS OF ENTRY            51600016
         LR    RENT,TEMP                SAVE ADDR FOR DSECT BASE        52000016
         S     TEMP,ADTDIR              FIND DIRECTORY DISPLACEMENT     52400016
         ST    TEMP,DISPLACE                                            52800016
*                                                                       53200016
LOOP     CLC   3(2,MTB),DISPLACE+2      IS THIS SLOT FOR SPECIFIED 000A 53600016
*                                         TERMINAL                      54000016
         BC    7,NO                     SKIP ALL OTHER SLOTS            54400016
         MVI   3(MTB),INACTIVE          MARK SLOT INACTIVE         000A 54800016
NO       BXLE  MTB,BUMP,LOOP            POINT TO NEXT SLOT, IF ANY      55200016
*                                                                       55600016
         NI    TDIRSTAT,TDIRDLMF        FLIP BIT IN TDIRSTAT TO    000A 56000016
*                                         SAY NO DELAYED MSGS      000A 56400016
         LR    R1,RENT                  PASS ADDR OF DIRECTORY ENTRY    56800016
*                                         TO BE UPDATED ON DISC         57200016
         L     R15,ADTMR                CALL TERMINAL DIRECTORY TABLE   57600016
         BALR  R14,R15                    MANAGER TO RECORD ENTRY       58000016
         SR    TEMP,TEMP                SET 0 RETURN CODE               58400016
         SR    R1,R1                    REQUEST 'ROLLOUT AND UNLOCK'    58800016
OUT      LR    R15,ADBOT                GET ADDRESS OF ROLLOUT          59200016
         BALR  R14,R15                  CALL ROLLOUT                    59600016
         LTR   TEMP,TEMP                WAS RETURN CODE ZERO            60000016
         BNE   OUT1                                                     60400016
         SRL   R15,SHIFT                                           000A 60800016
         LR    TEMP,R15                                                 61200016
OUT1     DELETE EPLOC=ADCDBIN           FORGET DIRECTORY           000A 61600016
         LR    R15,TEMP                 INSERT RETURN CODE              62000016
         L     R13,SAVE+4                                               62400016
         RETURN (14,12),T,RC=(15)       EXIT                            62800016
*                                                                       63200016
*********************************************************************** 63600016
*                                                                       64000016
*                        CONSTANTS                                      64400016
*                                                                       64800016
*********************************************************************** 65200016
MSGLN    EQU   5                        BYTES/ENTRY MSG SLOT DIREC 000A 65600016
NUMMSG   EQU   150                      NO. SLOTS IN MSG DIRECTORY 000A 66000016
MSGLEN   EQU   MSGLN*NUMMSG             NO. BYTES IN MSG SLOT DIR  000A 66400016
INACTIVE EQU   X'FF'                    INACTIVE SLOT INDICATOR    000A 66800016
SHIFT    EQU   24                       SHIFT COUNT OF 3 BYTES     000A 67200016
*                                                                       67600016
SAVE     DC    18F'0'                   LINKAGE SAVE AREA               68000016
ADCDBIN  DC    CL8'IHKCDBIN'            ROLL IN-OUT MSG SLOT DIREC 000A 68400016
*                                                                       68800016
*                                       PARAMETER TO ROLLIN             69200016
ADDCBS   DS    F                        ADDRESS OF RESIDENT DBC'S       69600016
BINPARM  DC    X'80'                      REQUESTS 'MSG'                70000016
DISPATCH DC    XL3'000000'                ADDR OF DISPATCHER            70400016
*                                                                       70800016
DISPLACE DC    F'0'                     DISPLACEMENT OF TDIR ENTRY      71200016
*                                         RELATIVE TO START OF ENTIRE   71600016
*                                         TERMINAL DIRECTORY            72000016
*                                                                       72400016
*********************************************************************** 72800016
*                                                                       73200016
*                        DSECT OF INPUT PARAMETER LIST                  73600016
*                                                                       74000016
*********************************************************************** 74400016
*                                                                       74800016
PARLIST  DSECT                                                          75200016
ADDCB    DS    CL4                      ADDR OF LIST OF RESIDENT DCS'S  75600016
         DS    C                                                        76000016
ADDISP   DS    CL3                      ADDR OF DISPATCHER              76400016
*                                                                       76800016
ADENT    DS    CL4                      ADDRESS OF THE TERMINAL         77200016
*                                         DIRECTORY ENTRY               77600016
ADTDIR   DS    CL4                      ADDRESS OF TERMINAL DIRECTORY   78000016
*                                                                       78400016
ADTMR    DS    CL4                      ADDR OF 'IHKCDTMR',TERMINAL     78800016
*                                         DIRECTORY TABLE MANAGER       79200016
*                                                                       79600016
*                                                                       80000016
         IHKDSECT TDIR                                             000A 80400016
         END                                                            80800016
