MDQ TITLE '''IHKCDMDQ'' - BROADCAST AND MESSAGE DATA SET DEQUEUER'      00300017
IHKCDMDQ CSECT                                                          00600017
*3200THE ENTIRE ROUTINE HAS BEEN REWRITTEN TO ALTER ITS FUNCTION.  000A 00900017
*3200FORMERLY, WHEN A DELAYED MESSAGE WAS RETRIEVED FOR TRANS-     000A 01200017
*3200MISSION TO A REMOTE TERMINAL, ITS SLOT WAS MARKED INACTIVE    000A 01500017
*3200BEFORE THE ACTUAL TRANSMISSION WAS ATTEMPTED.  IF THIS        000A 01800017
*3200TRANSMISSION FAILED DUE TO LINE ERROR OR REQUESTED DISCONTINUE000A 02100017
*3200THE MSG TEXT WAS LOST.  IN THIS VERSION, THE MESSAGE SLOT     000A 02400017
*3200BEING MARKED INACTIVE IS NOT THE ONE FOR THE MESSAGE BEING    000A 02700017
*3200READ IN, BUT THE SLOT FOR THE MESSAGE THAT WAS READ IN ON THE 000A 03000017
*3200PREVIOUS CALL.  BY THIS TIME, THE PREVIOUS MESSAGE HAS BEEN   000A 03300017
*3200SUCCESSFULLY TRANSMITTED.                                     000A 03600017
*0793042000                                                        000B 03900017
*                                                                     * 04200017
*STATUS - CHANGE LEVEL 2                                           000B 04500017
*                                                                     * 04800017
*FUNCTION/OPERATION-                                                  * 05100017
*   THIS ROUTINE READS INTO A CALLER'S AREA A 60 BYTE TEXT OF EITHER  * 05400017
*   A DELAYED MSG FOR A PARTICULAR TERMINAL OR A BROADCAST MESSAGE.   * 05700017
*   OPTIONALLY, THE DELAYED MSG READ IN ON A PREVIOUS CALL MAY BE     * 06000017
*   DELETED.                                                          * 06300017
*                                                                     * 06600017
*ENTRY POINT-                                                         * 06900017
*        'IHKCDMDQ'-READ MESSAGE FROM DISC                            * 07200017
*   CALLING SEQUENCE-                                                 * 07500017
*        LOAD  EP=IHKCDMDQ                                            * 07800017
*        LR    15,0                                                   * 08100017
*        LA    1,PARALIST                                             * 08400017
*        BALR  14,15                                                  * 08700017
*        LR    X,15      SAVE RETURN CODE                             * 09000017
*        LR    Y,1       SAVE NEXT SLOT RELATIVE ADDRESS              * 09300017
*        DELETE EP=IHKCDMDQ                                           * 09600017
*                                                                     * 09900017
*INPUT-                                                               * 10200017
*   THE ADDRESS OF THE PARAMETER LIST IS PASSED IN REGISTER 1.        * 10500017
*   CONTENTS OF PARAMETER LIST (ON WORD BOUNDARY)                     * 10800017
*   WORD 1 - ADDR OF LIST OF RESIDENT DCB'S. (IHKCDCBS)               * 11100017
*   WORD 2 - ADDR OF DISPATCHER.                                      * 11400017
*              HIGH ORDER BYTE -                                      * 11700017
*              X'00'-BROADCAST                                        * 12000017
*              X'80' -DELAYED MSG                                     * 12300017
*   WORD 3 - RELATIVE ADDR OF FIRST SLOT IN DIRECTORY TO BE SEARCHED. * 12600017
*            ZERO VALUE CAUSES SEARCH TO START AT BEGINNING OF SLOT   * 12900017
*            DIRECTORY.  IF THE OPTION OF DELETING A MSG IS REQUESTED,* 13200017
*            THE SLOT MARKED INACTIVE IS THE ONE JUST BEFORE THE ONE  * 13500017
*            INDICATED BY THIS PARAMETER.  IF THIS VALUE IS ZERO, NO  * 13800017
*            SLOT IS MARKED INACTIVE.                                 * 14100017
*   WORD 4 - ADDR OF 60 BYTE I/O AREA TO RECEIVE TEXT.                * 14400017
*   WORD 5 - (USED ONLY WHEN REQUESTING A DELAYED MESSAGE.)           * 14700017
*            RELATIVE ADDR OF TDIR ENTRY                              * 15000017
*              HIGH ORDER BYTE -                                      * 15300017
*              X'00'-DELETE MSG                                       * 15600017
*              X'80'-DO NOT DELETE MSG                                * 15900017
*OUTPUT -                                                             * 16200017
*   IF A SPECIFIED MESSAGE IS FOUND, IT IS MOVED FROM DISC TO THE 60  * 16500017
*   BYTE I/O AREA INDICATED BY THE CALLER.  THE MESSAGE TEXT THAT     * 16800017
*   WAS PASSED BACK ON THE PREVIOUS CALL IS SCRATCHED IF MESSAGE      * 17100017
*   DELETION WAS REQUESTED.  REGISTER 1 HAS THE RELATIVE ADDR IN THE  * 17400017
*   SLOT DIRECTORY OF THE SLOT FOLLOWING THAT OF THE MESSAGE BEING    * 17700017
*   PASSED.                                                           * 18000017
*                                                                     * 18300017
*EXTERNAL ROUTINES-                                                   * 18600017
*        IHKCDBIN-ROLLIN DESIGNATED SLOT DIRECTORY                    * 18900017
*        IHKCDBTX-READ SPECIFIED MESSAGE TO CALLERS I/O AREA          * 19200017
*        IHKAADSP- DUMMY PASS THROUGH DISPATCHER                   000B 19500017
*EXITS-NORMAL -                                                       * 19800017
*   REGISTER 15=0.  MESSAGE IS IN I/O AREA.  REGISTER 1 POINTS TO     * 20100017
*   NEXT SLOT.                                                        * 20400017
*   REGISTER 15=4.  NO MESSAGE AVAILABLE.  IF REQUESTED, PREVIOUS     * 20700017
*   MESSAGE IS SCRATCHED.                                             * 21000017
*                                                                     * 21300017
*EXITS-ERROR -                                                        * 21600017
*   REGISTER 15 HAS A VALUE OTHER THAN 0 OR 4.  IT IS THE OFFSET      * 21900017
*   FOR AN APPROPRIATE DISC ERROR MESSAGE PASSED FROM IHKCDBIN        * 22200017
*   OR IHKCDBTX.                                                      * 22500017
*                                                                     * 22800017
*TABLES/WORKAREAS-                                                    * 23100017
*   THE 60 BYTE I/O AREA IS PROVIDED BY THE CALLER.                   * 23400017
*   ALL DCB'S ARE RESIDENT WITHIN THE TABLE MANAGERS, IHKCDFMR.       * 23700017
*                                                                     * 24000017
*ATTRIBUTES-                                                          * 24300017
*   REENTRANT (USES LOCKED DOOR FUNCTION OF DISPATCHER.)              * 24600017
*   NON-RESIDENT                                                      * 24900017
*NOTES-                                                               * 25200017
*   ALTHOUGH REENTRANT, ONLY ONE CALLER IS PROCESSED AT A TIME BECAUSE* 25500017
*   OTHER CALLERS WAIT AT THE LOCKED DOOR.                            * 25800017
*                                                                     * 26100017
*   THIS ROUTINE DOES NOT DEPEND UPON ANY PARTICULAR INTERNAL         * 26400017
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET.                     * 26700017
*                                                                       27000017
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 27300017
*                                                                       27600017
R15      EQU   15                       ADDR OF SUBROUTINE              27900017
*                                                                       28200017
R14      EQU   14                       RETURN ADDR FROM SUBROUTINE     28500017
*                                                                       28800017
R13      EQU   13                       ADDR OF LINKAGE SAVEAREA        29100017
*                                                                       29400017
R12      EQU   12                       PROGRAM BASE                    29700017
*                                                                       30000017
R11      EQU   11                       ADDR OF SLOT TO BE SCRATCHED    30300017
*                                                                       30600017
R10      EQU   10                       '0'-ROLLOUT AND UNLOCK          30900017
*                                       'NON-ZERO'-UNLOCK ONLY          31200017
*                                                                       31500017
R9       EQU   9                        LOOP STOPPER,ADDR OF LAST BYTE  31800017
*                                         OF SLOT DIRECTORY             32100017
R8       EQU   8                        INDEX INCREMENTOR,VALUE IS      32400017
*                                         EITHER 'MSGLN' OR 'BRDLN'     32700017
R7       EQU   7                        INDEX OF SLOT DIRECTORY         33000017
*                                                                       33300017
R6       EQU   6                        SAVES RETURN CODE FROM          33600017
*                                         SUBROUTINES UNTIL RETURN      33900017
R5       EQU   5                        TEMPORARILY HAS SAVEAREA ADDR   34200017
*                                                                       34500017
R4       EQU   4                        ADDR OF DIRECTORY ROLLOUT       34800017
*                                         ROUTINE, IHKCDBOT.            35100017
R3       EQU   3                        ADDR OF SLOT DIRECTORY          35400017
*                                                                       35700017
R2       EQU   2                        BASE OF INPUT PARAMETERS DSECT  36000017
*                                                                       36300017
R1       EQU   1                        PARAMETER PASSER                36600017
*                                                                       36900017
R0       EQU   0                        ADDR OF SUBROUTINE FROM 'LOAD'  37200017
*                                                                       37500017
         USING IHKCDMDQ,R12             ESTABLISH PROGRAM BASE          37800017
         USING PARAM,R2                 ESTABLISH PARAMETER DSECT BASE  38100017
*                                                                       38400017
         EJECT                                                          38700017
*********************************************************************** 39000017
*                                                                       39300017
*                   ENTRY POINT   IHKCDMDQ                              39600017
*                                                                       39900017
*********************************************************************** 40200017
         SAVE  (14,12),,*                                               40500017
         LR    R12,R15                  SET PRAGRAM BASE                40800017
*                        LOCK DOOR                                      41100017
         SR    R14,R14                  REQUEST LOCK DOOR FUNCTION      41400017
         L     R15,4(R1)                GET ADDR OF DISPATCHER FROM     41700017
*                                         INPUT PARAM LIST.             42000017
         TS    BIT                      IS DOOR LOCKED                  42300017
         BCR   7,R15                    IF LOCKED, WAIT IN DISPATCHER   42600017
*                        CHAIN SAVEAREAS                                42900017
         ST    R13,SAVE+4                                               43200017
         LA    R5,SAVE                                                  43500017
         ST    R5,8(R13)                                                43800017
         LR    R13,R5                                                   44100017
*                        END OF STANDARD ENTRY LINKAGE                  44400017
         LR    R2,R1                    SAVE INPUT PARAMETER            44700017
         LR    R10,R12                  SET TO 'UNLOCK ONLY'            45000017
         LA    R1,DUMWAIT              ADDRESS OF POSTED ECB       000B 45300017
         BALR  R14,R15                 DUMMY PASS THRU DISPATCHER  000B 45600017
*                                                                       45900017
*                                       MODULE HAS THREE PARTS,ROUTINE  46200017
*                                         TO ROLL IN SLOT DIRECTORY,    46500017
         LOAD  EPLOC=ADCDBIN              TO ROLL OUT SLOT DIRECTORY,  *46800017
                                          THE SLOT DIRECTORY ITSELF     47100017
         LR    R15,R0                   SAVE ENTRY POINT ADDR           47400017
         LR    R1,R2                    PASS PARAM LIST TO IHKCDBIN     47700017
         BALR  R14,R15                  ROLL IN SLOT DIRECTORY TO CORE  48000017
*                                  R1 WILL HAVE ADDR OF SLOT DIRECTORY  48300017
*                                  R15 WILL HAVE ADDR OF ROLLOUT        48600017
*                                    ROUTINE, IHKCDBOT.                 48900017
         LR    R3,R1               SAVE ADDR OF SLOT DIRECTORY          49200017
         LR    R4,R15              SAVE ADDR OF ROLLOUT ROUTINE         49500017
         SRL   R15,SHIFT           MOVE OUT ALL BUT ERROR MSG OFFSET    49800017
         LTR   R6,R15              SAVE RETURN CODE. WAS THERE ERROR    50100017
         BNZ   BOT                      IF ERROR, CLOSE AND RETURN      50400017
         TM    DISP,HIGHBIT             MSG OR BRDCST                   50700017
         BZ    AROUND                     BRDCST,DO NOT SCRATCH         51000017
*                                         MSG, CONTINUE                 51300017
*                        SCRATCH SLOT OF MSG RETURNED                   51600017
*                        ON PREVIOUS CALL BY IHKABLWR                   51900017
         TM    TDIRDISP,HIGHBIT    IS MSG TO BE SCRATCHED               52200017
         BO    AROUND                '1'-DO NOT DELETE (GO TO AROUND)   52500017
*                                    '0'-DELETE (CONTINUE)              52800017
         CLC   SLOT+2(2),BIT+2          IS SLOT DISPLACEMENT ZERO       53100017
         BE    AROUND                   IF SO, DO NOT SCRATCH           53400017
         L     R11,SLOT            RELATIVE ADDR OF FIRST SLOT BEYOND   53700017
*                                    SLOT TO BE SCRATCHED               54000017
         LA    R1,MSGLN                 NUMBER BYTES PER MSG SLOT       54300017
*                                         (BRDCST SLOTS NEVER DELETED)  54600017
         SR    R11,R1                   BACK UP ONE SLOT TO RELATIVE    54900017
*                                         ADDR OF SLOT TO BE SCRATCHED  55200017
         AR    R11,R3                   ADD ADDR OF DIRECTORY TO GET    55500017
*                                         ABSOLUTE SLOT ADDRESS         55800017
         MVI   3(R11),INACTIVE          SCRATCH IT                      56100017
         SR    R10,R10                  SET TO 'ROLLOUT AND UNLOCK'     56400017
*                        END OF SCRATCH ROUTINE                         56700017
AROUND   DS    0H                                                       57000017
*                        SET REGS FOR SEARCH                            57300017
         LR    R7,R3                    SET INDEX TO SLOT DIRECTORY     57600017
         LR    R9,R3                    INITIALIZE LOOP STOPPER         57900017
         BCTR  R9,R0                    BACK UP ONE, LOOP STOPPER       58200017
         A     R7,SLOT                  POINT TO SLOT TO BEGIN SEARCH   58500017
*                        MSG OR BRDCST                                  58800017
         TM    DISP,HIGHBIT                                             59100017
         BZ    BRDCST                                                   59400017
*                        MSG IS REQUESTED                               59700017
         LA    R8,MSGLN                 SET INDEX INCREMENTOR TO SIZE   60000017
*                                         OF EACH MSG SLOT              60300017
         LA    R1,MSGLEN                GET SIZE OF MSG DIRECTORY       60600017
         AR    R9,R1                    SET LOOP STOPPER TO ADDR OF     60900017
*                                         LAST BYTE OF MSG DIRECTORY    61200017
         SR    R7,R8                    BACK UP ONE SLOT (FOR BXLE)     61500017
         B     MSGTEST                  WAS THAT END OF DIRECTORY       61800017
*                                                                       62100017
MSGLOOP  CLC   3(2,R7),TDIRDISP+2       IS MSG FOR THIS TERMINAL        62400017
         BE    FOUNDMSG                   YES, GO GET MSG TEXT          62700017
MSGTEST  BXLE  R7,R8,MSGLOOP              NO, INCREMENT INDEX TO        63000017
*                                           NEXT SLOT, IF ANY           63300017
         B     NOMORE                   NO MORE SLOTS, NO MSG FOUND     63600017
*                        BRDCST IS REQUESTED                            63900017
BRDCST   LA    R8,BRDLN                 SET INCREMENTOR TO SIZE OF      64200017
*                                         BRDCST SLOT                   64500017
         LA    R1,BRDLEN                GET SIZE OF BRDCST DIRECTORY    64800017
         AR    R9,R1                    SET LOOP STOPPER TO ADDR OF     65100017
*                                         LAST BYTE OF BRDCST DIRECTORY 65400017
         SR    R7,R8                    BACK UP ONE SLOT (FOR BXLE)     65700017
         B     BRDTEST                  WAS THAT END OF DIRECTORY       66000017
*                                                                       66300017
BRDLOOP  CLI   3(R7),INACTIVE           IS THIS BRDCST SLOT INACTIVE    66600017
         BNE   FOUNDBRD                   NO, ACTIVE, GO GET TEXT       66900017
BRDTEST  BXLE  R7,R8,BRDLOOP              YES,INCREMENT INDEX TO        67200017
*                                           NEXT SLOT, IF ANY           67500017
NOMORE   DS    0H                       CONTINUE IF NO MORE SLOTS, AND  67800017
*                                         NO BRDCST NOR MSG FOUND       68100017
         LA    R6,CODE4                 INDICATE 'NO TEXT' TO CALLER    68400017
BOT      LR    R1,R10                   TELL BOT TO ROLLOUT OR NOT      68700017
         LR    R15,R4                   GET ADDR OF ROLLOUT ROUTINE     69000017
         BALR  R14,R15                  CALL IHKCDBOT                   69300017
*                                                                       69600017
         LTR   R6,R6                    HAS A NON-ZERO RETURN CODE      69900017
*                                         ALREADY BEEN FOUND            70200017
         BNZ   GOTCODE                  YES, FORGET BOT RETURN CODE     70500017
         SRL   R15,SHIFT                SHIFT OUT ALL BUT ERROR MSG     70800017
*                                         OFFSET FROM BOT RETURN        71100017
         LR    R6,R15                   PASS OFFSET AS RETURN CODE      71400017
*                                                                       71700017
GOTCODE  DELETE EPLOC=ADCDBIN           THROW AWAY CORE OF ROLLIN-OUT  *72000017
                                          ROUTINES, SLOT DIRECTORY      72300017
         LR    R15,R6                   GET RETURN CODE                 72600017
         MVI   BIT,UNLOCK               UNLOCK DOOR                     72900017
         L     R13,SAVE+4                                               73200017
*                                  R7 HAS ADDR OF SLOT OF TEXT          73500017
*                                  R3 HAS ADDR OF SLOT DIRECTORY        73800017
         SR    R7,R3                    GET RELATIVE ADDR OF SLOT       74100017
         AR    R7,R8                    BUMP TO NEXT SLOT TO WHERE      74400017
*                                         SEARCH STARTS NEXT TIME       74700017
         ST    R7,HISREG1(R13)          PASS BACK IN REG 1 THE RELATIVE 75000017
*                                         ADDR OF FIRST SLOT TO BE      75300017
*                                         SEARCHED NEXT TIME AROUND     75600017
         RETURN (14,12),T,RC=(15)                                       75900017
*                                                                       76200017
*                                                                       76500017
FOUNDMSG DS    0H                                                       76800017
FOUNDBRD EQU   FOUNDMSG                 R7 HAS ADDR OF SLOT OF TEXT     77100017
         ST    R7,SLOT                  PASS SLOT ADDR IN PARALIST      77400017
*                                                                       77700017
         LOAD  EPLOC=ADCDBTX            GET TEXT READ ROUTINE           78000017
*                                                                       78300017
         LR    R15,R0                   SAVE ENTRY POINT ADDR           78600017
         LR    R1,R2                    PASS INPUT PARAMS               78900017
         BALR  R14,R15                  READ TEXT TO USER'S AREA        79200017
*                                                                       79500017
         LR    R6,R15                   SAVE RETURN CODE                79800017
*                                                                       80100017
         DELETE EPLOC=ADCDBTX           FREE CORE OF READ ROUTINE       80400017
*                                                                       80700017
         B     BOT                      PREPARE TO EXIT                 81000017
*                                                                       81300017
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 81600017
*                                                                       81900017
*                       CONSTANTS                                       82200017
*                                                                       82500017
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 82800017
*                                                                       83100017
SAVE     DC    18F'0'                   SAVEAREA                        83400017
DUMWAIT  DC    X'40000000'             DUMMY POSTED ECB            000B 83700017
ADCDBIN  DC    CL8'IHKCDBIN'                                            84000017
ADCDBTX  DC    CL8'IHKCDBTX'                                            84300017
BIT      DC    X'00'                    LOCK OF DOOR                    84600017
         DC    3X'00'                   ZERO BYTES                      84900017
*                                                                       85200017
NUMMSG   EQU   150                      NO. DELAYED MSG SLOTS           85500017
NUMBRD   EQU   100                      NO. BRDCST SLOTS                85800017
MSGLN    EQU   5                        BYTES PER MSG SLOT              86100017
BRDLN    EQU   4                        BYTES PER BRDCST SLOT           86400017
MSGLEN   EQU   NUMMSG*MSGLN             BYTES IN MSG DIRECTORY          86700017
BRDLEN   EQU   NUMBRD*BRDLN             BYTES IN BRDCST DIRECTORY       87000017
SHIFT    EQU   24                       SHIFT COUNT FOR 3 BYTES         87300017
HISREG1  EQU   24                       DISP OF REG 1 PLACE IN SAVEAREA 87600017
CODE4    EQU   4                        RETURN CODE MEANS 'NO TEXT'     87900017
UNLOCK   EQU   0                        CLEARS LOCKED DOOR AT EXIT      88200017
HIGHBIT  EQU   X'80'                    SIGN BIT MASK                   88500017
INACTIVE EQU   X'FF'                    INACTIVE SLOT INDICATOR         88800017
*                                                                       89100017
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 89400017
*                                                                       89700017
*                       INPUT PARAMETER DSECT                           90000017
*                                                                       90300017
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 90600017
*                                                                       90900017
PARAM    DSECT                                                          91200017
LIST     DS    F                        ADDR OF IHKCDCBS, WHICH IS A    91500017
*                                         3 WORD LIST OF ADDRESSES OF   91800017
*                                         RESIDENT DCB'S. SEE IHKCDJMR  92100017
DISP     DS    F                        ADDR OF DISPATCHER              92400017
*                                         HIGH ORDER BYTE -             92700017
*                                         X'80'- DELAYED MSG REQUESTED  93000017
*                                         X'00'- BRDCST REQUESTED       93300017
SLOT     DS    F                        RELATIVE ADDR OF FIRST SLOT     93600017
*                                         TO BE SEARCHED.               93900017
*                                         INITIAL VALUE IS ZERO.        94200017
*                                         SUBSEQUENT VALUES RETURNED    94500017
*                                         IN REG 1 TO CALLER            94800017
IOAREA   DS    F                        ADDR OF 60 BYTE I/O AREA        95100017
*                                         PROVIDED BY CALLER TO         95400017
*                                         RECEIVE TEXT FROM DISC        95700017
TDIRDISP DS    F                        RELATIVE ADDR OF TERMINAL       96000017
*                                         DIRECTORY ENTRY DEFINING      96300017
*                                         TERMINAL TO RECEIVE A         96600017
*                                         DELAYED MSG.                  96900017
*                                       HIGH ORDER BYTE -               97200017
*                                         X'00'-DELETE MSG              97500017
*                                         X'80'-DO NOT DELETE MSG       97800017
         END                                                            98100017
