SCH      TITLE 'IHKCDSCH - SEARCH FOR MATCHING JOBNAME IN FASTABLE'     00400015
IHKCDSCH CSECT                                                          00800015
*                                                                     * 01200015
*STATUS - CHANGE LEVEL 0                                              * 01600015
*                                                                     * 02000015
*FUNCTION/OPERATION -                                                 * 02400015
*                                                                     * 02800015
*   THIS ROUTINE SEARCHES WITHIN THE FASTABLE TO LOCATE THE ENTRY     * 03200015
*   WHICH CONTAINS INFORMATION ABOUT A PARTICULAR JOB.  A SERIAL      * 03600015
*   SEARCH IS PERFORMED, STARTING AT THE LOW ADDRESS ENTRY AND        * 04000015
*   PROCEDING THROUGH THE FASTABLE, CHECKING EACH ENTRY IN ORDER      * 04400015
*   UNTIL EITHER THE REQUESTED JOBNAME IS FOUND, OR ALL ENTRIES       * 04800015
*   HAVE BEEN CHECKED.                                                * 05200015
*                                                                     * 05600015
*ENTRY POINTS -                                                       * 06000015
*                                                                     * 06400015
*        'IHKCDSCH' - SEARCH FASTABLE FOR JOBNAME                     * 06800015
*                                                                     * 07200015
*   CALLING SEQUENCE - LA    1,STRING OF 8 CHARACTERS                 * 07600015
*                      L     15,=V(IHKCDSCH)                          * 08000015
*                      BALR  14,15                                    * 08400015
*                                                                     * 08800015
*   THE PARAMETER PASSED IN REGISTER 1 IS THE ADDRESS OF A STRING OF  * 09200015
*   8 CHARACTERS WHICH DEFINE THE NAME OF THE PARTICULAR JOB TO BE    * 09600015
*   SEARCHED FOR WITHIN THE FASTABLE.  IF THE JOBNAME IS LESS THAN 8  * 10000015
*   CHARACTERS, IT MUST BE LEFT JUSTIFIED WITHIN THE 8 CHARACTER FIELD* 10400015
*   AND FILLED TO THE RIGHT WITH SPACES (X'40'),                      * 10800015
*                                                                     * 11200015
*INPUT -                                                              * 11600015
*   NO INPUT OTHER THAN THE PARAMETER DESCRIBED ABOVE.                * 12000015
*                                                                     * 12400015
*OUTPUT -                                                             * 12800015
*   N/A (SEE EXITS - NORMAL)                                          * 13200015
*                                                                     * 13600015
*EXTERNAL ROUTINES -                                                  * 14000015
*                                                                     * 14400015
*   THERE ARE NO SUBROUTINES CALLED.                                  * 14800015
*                                                                     * 15200015
*   EXTERNAL REFERENCES ARE MADE TO CONSTANTS AND TABLES FOUND IN     * 15600015
*   MODULE 'IHKCDTAB' - RJE CONTROL SYSTEM TABLES.                    * 16000015
*                                                                     * 16400015
*   EXTERNAL TABLES REFERENCED -                                      * 16800015
*        'IHKCDFTB' - FASTABLE (DATA ON EACH ROMOTE JOB)              * 17200015
*                                                                     * 17600015
*   EXTERNAL CONSTANTS REFERENCED -                                   * 18000015
*                                                                     * 18400015
*        'IHKCDFLN' - NUMBER OF BYTES PER ENTRY OF FASTABLE.          * 18800015
*                      (HALF-WORD)                                    * 19200015
*        'IHKCDFNB' - MAXIMUM NUMBER OF JOBS THAT CAN BE DEFINED IN   * 19600015
*                      THE FASTABLE. (HALF-WORD)                      * 20000015
*                                                                     * 20400015
*EXITS - NORMAL                                                       * 20800015
*                                                                     * 21200015
*   IF REGISTER 15=0, A MATCHING JOBNAME WAS FOUND.  REGISTER 1 HAS   * 21600015
*   THE ADDRESS OF THE FIRST BYTE OF THE FASTABLE ENTRY WHICH CONTAINS* 22000015
*   THE DESIRED JOBNAME.                                              * 22400015
*                                                                     * 22800015
*   IF REGISTER 15=4, NO MATCHING JOBNAME WAS FOUND.  REGISTER 1 HAS  * 23200015
*   THE ADDRESS OF THE FIRST BYTE OF AN INACTIVE FASTABLE ENTRY WHICH * 23600015
*   IS AVAILABLE FOR USE BY A NEW JOB JUST ENTERING THE RJE SYSTEM.   * 24000015
*                                                                     * 24400015
*EXITS - ERROR                                                        * 24800015
*                                                                     * 25200015
*   IF REGISTER 15=8, NO MATCHING JOBNAME WAS FOUND.  REGISTER 1 HAS  * 25600015
*   THE SAME INPUT VALUE UNCHANGED.  THE FASTABLE IS COMPLETELY FULL  * 26000015
*   OF ACTIVE RJE JOBS.  NO NEW JOB CAN ENTER THE SYSTEM UNTIL ONE OF * 26400015
*   THE ACTIVE JOBS BECOMES DELETED AND THUS HAS RELEASED ITS         * 26800015
*   FASTABLE AREA.                                                    * 27200015
*                                                                     * 27600015
*TABLES/WORK AREAS -                                                  * 28000015
*                                                                     * 28400015
*   STANDARD LINKAGE SAVE AREA HAS ONLY 3 INSTEAD OF THE USUAL 18 FULL* 28800015
*   WORDS SINCE NO SUBROUTINES ARE CALLED.  OTHER TABLES ARE EXTERNAL.* 29200015
*                                                                     * 29600015
*ATTRIBUTES -                                                         * 30000015
*                                                                     * 30400015
*  REUSABLE.                                                          * 30800015
*                                                                     * 31200015
*  STANDARD ENTRY LINKAGE CONVENTIONS ARE FOLLOWED.                   * 31600015
*                                                                     * 32000015
*NOTES -                                                              * 32400015
*                                                                     * 32800015
*   THIS ROUTINE WOULD BE CALLED IN TWO SITUATIONS -                  * 33200015
*   1. INFORMATION ABOUT A CURRENTLY ACTIVE JOB IS DESIRED, OR IS TO  * 33600015
*   BE MODIFIED. 'IHKCDSCH' IS TO LOCATE THIS INFORMATION WITHIN THE  * 34000015
*   FASTABLE, AND TO INDICATE THIS LOCATION TO THE USER.  THE RETURN  * 34400015
*   CODE OF 0 IN REGISTER 15 IS THE DESIRED RESPONSE.                 * 34800015
*                                                                     * 35200015
*   2. IT IS DESIRED TO ENTER INTO THE FASTABLE THE NAME OF A NEW JOB.* 35600015
*   'IHKCDSCH' IS TO LOCATE AN AVAILABLE SPACE IN THE FASTABLE WHICH  * 36000015
*   IS READY TO RECEIVE THE NEW JOBNAME AND ANY OTHER RELATED         * 36400015
*   INFORMATION.  IT IS ALSO TO CHECK FOR THE POSSIBILITY OF A        * 36800015
*   DUPLICATE JOBNAME BEING ALREADY DEFINED, OR OF THE FASTABLE'S     * 37200015
*   BEING FULL OF CURRENTLY ACTIVE JOBS AND THEREFORE BEING UNABLE TO * 37600015
*   RECEIVE ANY NEW JOBS.  THE RETURN CODE OF 4 IN REGISTER 15 IS THE * 38000015
*   DESIRED RESPONSE.                                                 * 38400015
*                                                                     * 38800015
*                                                                     * 39200015
*   THE OPERATION OF THIS SUBROUTINE DOES NOT DEPEND UPON A PARTICULAR* 39600015
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 40000015
*                                                                     * 40400015
*                                                                     * 40800015
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 41200015
*                                                                       41600015
*              R E G I S T E R    A S S I G N M E N T S                 42000015
*                                                                       42400015
R1       EQU   1                        INPUT PARAMETER                 42800015
*                                                                       43200015
TABLE    EQU   3                        POINTER TO FASTABLE ENTRY       43600015
*                                                                       44000015
FLAG     EQU   4                        VALUE=0,NO INACTIVE ENTRY FOUND 44400015
*                                       VALUE=1,AT LEAST ONE INACTIVE   44800015
*                                         ENTRY FOUND.                  45200015
*                                                                       45600015
INACTIVE EQU   5                        ADDRESS OF INACTIVE ENTRY       46000015
*                                                                       46400015
LIMIT    EQU   6                        NUMBER OF FASTABLE ENTRIES      46800015
*                                                                       47200015
TEMP     EQU   7                        TEMPORARY STORAGE               47600015
*                                                                       48000015
VCONBASE EQU   8                        BASE OF ADDRESS VECTOR TABLE    48400015
*                                                                       48800015
BUMP     EQU   9                        NUMBER OF BYTES PER FASTABLE    49200015
*                                         ENTRY                         49600015
*                                                                       50000015
BASE     EQU   12                       PROGRAM BASE                    50400015
*                                                                       50800015
R13      EQU   13                       SAVEAREA POINTER                51200015
*                                                                       51600015
R15      EQU   15                       RETURN CODE                     52000015
*                                                                       52400015
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 52800015
*                                                                       53200015
         SAVE  (14,12),,*                                               53600015
         BALR  BASE,0                                                   54000015
         USING *,BASE                                                   54400015
         ST    R13,SAVE+4                                               54800015
         LA    TEMP,SAVE                                                55200015
         ST    TEMP,8(R13)                                              55600015
         L     VCONBASE,CACOM           SET BASE OF AVT                 56000015
         USING IHKZZAVT,VCONBASE        ESTABLISH ADDRESSABILITY OF AVT 56400015
*                                                                       56800015
         SR    FLAG,FLAG                SET TO 'NO INACTIVE FOUND'      57200015
         L     TABLE,IHKZZFTB           GET START OF FASTABLE           57600015
         USING FASTAB,TABLE             BASE FOR DSECT OF FASTABLE      58000015
*                                                                       58400015
         L     TEMP,IHKZZFLN            GET UNMBER BYTES PER ENTRY      58800015
         LH    BUMP,0(TEMP)               OF FASTABLE                   59200015
*                                                                       59600015
         L     TEMP,IHKZZFNB            GET NUMBER OF ENTRIES           60000015
         LH    LIMIT,0(TEMP)              OF FASTABLE                   60400015
*                                                                       60800015
LOOP     CLI   FASTNAME,FASTINAC        IS ENTRY INACTIVE               61200015
         BC    7,ACTIVE                 BRANCH IF ACTIVE                61600015
*                                                                       62000015
         LTR   FLAG,FLAG                IS THIS THE 1ST INACTIVE ENTRY  62400015
         BC    7,NOTFIRST               BRANCH IF NOT THE FIRST INACTIV 62800015
*                                                                       63200015
*                                       THIS IS THE 1ST INACTIVE ENTRY  63600015
         LA    FLAG,INACFLAG            SET FLAG TO INACTIVE FOUND      64000015
         LR    INACTIVE,TABLE           SAVE INACTIVE ENTRY ADDRESS     64400015
NOTFIRST AR    TABLE,BUMP               SET INDEX TO NEXT ENTRY         64800015
         BCT   LIMIT,LOOP               CHECK NEXT ENTRY, IF ANY        65200015
*                                                                       65600015
*                                       ALL ENTRIES CHECKED.            66000015
*                                       NO MATCHING JOBNAME FOUND       66400015
         LTR   FLAG,FLAG                WERE ANY INACTIVE ENTRIES FOUND 66800015
         BC    8,ZERO                   BRANCH IF NONE WERE FOUND       67200015
*                                                                       67600015
*                                       AN INACTIVE ENTRY WAS FOUND     68000015
         ST    INACTIVE,SAVEREG1(R13)   PASS ADDRESS INTO REGISTER 1    68400015
         LA    R15,CODE4                EXIT, INACTIVE FOUND RETURN     68800015
         B     STOP                                                     69200015
*                                                                       69600015
ZERO     LA    R15,CODE8                EXIT, FASTABLE FULL RETURN      70000015
         B     STOP                                                     70400015
*                                                                       70800015
ACTIVE   CLC   FASTNAME,0(R1)           IS THIS THE WANTED ENTRY        71200015
         BC    7,NOTFIRST               BRANCH IF NOT A MATCH           71600015
*                                                                       72000015
*                                       MATCHING JOBNAME FOUND          72400015
         ST    TABLE,SAVEREG1(R13)      PASS ADDRESS INTO REGISTER 1    72800015
         SR    R15,R15                  EXIT,MATCHING JOBNAME FOUND     73200015
STOP     RETURN (14,12),T,RC=(15)                                       73600015
*                                                                       74000015
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 74400015
*                                                                       74800015
*                       C O N S T A N T S                               75200015
*                                                                       75600015
SAVE     DC    3F'0'                    SAVE AREA                       76000015
*                                                                       76400015
CACOM    DC    A(IHKCACOM)              ADDR OF ADDRESS VECTOR TABLE    76800015
         EXTRN IHKCACOM                                                 77200015
*                                                                       77600015
FASTINAC EQU   X'40'                    INACTIVE ID                     78000015
INACFLAG EQU   1                        NON-0 INDICATES INACTIVE FOUND  78400015
SAVEREG1 EQU   24                       DISP OF REG 1 IN SAVEAREA       78800015
CODE4    EQU   4                        RETURN CODE-INACTIVE SLOT FOUND 79200015
CODE8    EQU   8                        RETURN CODE-FASTABLE FULL       79600015
*                                                                       80000015
         IHKDSECT ,,FASTAB,,,AVT                                        80400015
*                                                                       80800015
         END                                                            81200015
