 TITLE 'IHKCEDIT     JCL EDIT'                                          00200015
IHKCEDIT CSECT                                                          00400015
*                                                                     * 00600015
* 758000                                                           000D 00700020
*                                                                A32855 00750020
*D652000                                                         A53069 00800021
*A440800-441200,652400-653600,680600-681200                      A53069 00830021
*C436000                                                         A53069 00860021
*                                                                     * 00890021
* STATUS: CHANGE LEVEL 1, RELEASE 21.7                                * 00920021
*                                                                     * 00950021
*FUNCTION-                                                            * 01000015
*   THIS ROUTINE IS RESPONSIBLE FOR CHANGING THE SYSOUT CLASS AND     * 01200015
*   MSGCLASS CLASSNAME SPECIFIED ON THE JCL ENTERED WITH A REMOTE JOB * 01400015
*   TO THE RJE SYSOUT CLASS WHICH IS DEFINED BY THE RJETABL MACRO.    * 01600015
*   THE CHANGE OF SYSOUT CLASS WILL NOT BE MADE FOR ANY DATA SET WHICH* 01800015
*   IS TO BE DIRECTED TO THE CENTRAL AND IS SPECIFIED IN THE CENTRAL  * 02000015
*   PARAMETER OF THE JED STATEMENT.  THE ORIGINAL MSGCLASS CLASSNAME  * 02200015
*   AND ANY SYSOUT CLASSNAMES FOR DATA SETS NOT ROUTED TO CENTRAL ARE * 02400015
*   STORED IN THE JED TABLE JEDTSOUT.                                 * 02600015
*ENTRY POINT-                                                         * 02800015
*        IHKCEDIT IS THE ONLY ENTRY POINT.                            * 03000015
*   IHKCEDIT RECEIVES CONTROL FROM THE OS INTERPRETER, AFTER IEFVFA   * 03200015
*   (THE OS JCL SCAN ROUTINE) HAS ACCUMULATED AND CONVERTED TO        * 03400015
*   INTERNAL TEXT ONE COMPLETE JCL STATEMENT (INCLUDING CONTINUATION  * 03600015
*   AND OVERRIDES).                                                   * 03800015
*TABLES/WORK AREAS-                                                   * 04000015
*   IHKCEJDT, THE IN-CORE DUMMY JED TABLE PROVIDED BY IHKCEJPR, IS    * 04200015
*   USED FOR STORING SYSOUT AND MSGCLASS CLASSNAMES.                  * 04400015
*   IHKCELST, THE CENTRAL PARAMETER AREA BUILT BY IHKCEJPR, IS        * 04600015
*   REFERENCED TO DETERMINE WHICH OUTPUT DATA SETS ARE TO BE ROUTED   * 04800015
*   TO CENTRAL.                                                       * 05000015
*INPUT-                                                               * 05200015
*      AT ENTRY TO IHKCEDIT, REGISTER 13 CONTAINS A POINTER TO A SAVE * 05400015
*   AREA AND REGISTER 1 CONTAINS A POINTER TO THE FOLLOWING THREE     * 05600015
*   WORD PARAMETER LIST-                                              * 05800015
*      FIRST WORD-  TEXT BUFFER POINTER                               * 06000015
*      SECOND-      QMPA POINTER                                      * 06200015
*      THIRD-       QUEUE MANAGER ENTRY POINT                         * 06400015
*   THE TEXT BUFFER POINTER POINTS TO THE FIRST TEXT BUFFER FOR A     * 06600015
*   STATEMENT.  THE ACTUAL TEXT BEGINS IN THE SECOND WORD OF THE      * 06800015
*   BUFFER.  THE FIRST WORD IS A BINARY ZERO UNLESS THE INTERNAL      * 07000015
*   TEXT FOR THIS STATEMENT IS CONTINUED IN ANOTHER BUFFER.   (THIS   * 07200015
*   IS NOT THE USUAL CASE.(  IF  THE TEXT IS CONTINUED, THE FIRST     * 07400015
*   WORD CONTAINS THE 3 BYTE RIGHT-ADJUSTED TTR OF THE NEXT BUFFER,   * 07600015
*   AND AN IDENTIFIER OF X'0B'.  THE QMPA AND QUEUE MANAGER ENTRY     * 07800015
*   POINT ARE PROVIDED IN CASE THE INTERNAL TEXT IS CONTINUED.  THE   * 08000015
*   CONTINUATION BUFFER RESIDES ON QUEUE MANAGER SPACE ON DISK.  IT   * 08200015
*   MAY BE READ INTO CORE AND RE-WRITTEN TO DISK USING THE QUEUE      * 08400015
*   MANAGER ROUTINES.                                                 * 08600015
*OUTPUT-                                                              * 08800015
*      THE INTERNAL TEXT BUFFER IS LEFT,IN CORE (OR RE-WRITTEN TO     * 09000015
*   DISK IF IT IS A CONTINUATION BUFFER( WITH THE NECESSARY           * 09200015
*   CLASSNAME CHANGES MADE.                                           * 09400015
*EXTERNAL REFERENCES-                                                 * 09600015
*        IHKCEJDT-DUMMY IN-CORE JED TABLE                             * 09800015
*        IHKCELST-CENTRAL PARAMETER AREA                              * 10000015
*        IHKCDSOC-SYSOUT CLASS CLASSNAMES DEFINED IN RJETABL MACRO    * 10200015
*EXITS-                                                               * 10400015
*      RETURN VIA REGISTER 14 TO IEFVFA.                              * 10600015
*ATTRIBUTES-                                                          * 10800015
*      SERIALLY REUSABLE                                              * 11000015
*NOTES- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR* 11200015
*    INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.           * 11400015
*                                                                       11600015
*            REGISTERS                                                  11800015
*                                                                       12000015
PAREG    EQU   1                                                        12200015
EXLENGTH EQU   2                                                        12400015
RECORDAD EQU   3                                                        12600015
DDNAMEAD EQU   4                                                        12800015
POINTER  EQU   5                                                        13000015
COUNT    EQU   6                                                        13200015
WORK     EQU   7                                                        13400015
THUMB    EQU   8                                                        13600015
MARKER   EQU   9                                                        13800015
NUMBER   EQU   10                                                       14000015
TEMP     EQU   11                                                       14200015
BASE     EQU   12                                                       14400015
SAVE     EQU   13                                                       14600015
RETURN   EQU   14                                                       14800015
EXIT     EQU   15                                                       15000015
         SAVE  (14,12),,*                                               15200015
         BALR  BASE,0              ESTABLISH BASE REGISTER              15400015
         USING *,BASE                                                   15600015
         USING IOPARAMS,PAREG                                           15800015
         LA    TEMP,SAREA                                               16000015
         ST    TEMP,8(SAVE)                                             16200015
         ST    SAVE,SAREA+4                                             16400015
         LR    SAVE,TEMP                                                16600015
         LM    2,11,MYREGS                                              16800015
         L     RECORDAD,0(PAREG)   ADDRESS OF INTERNAL TEXT BUFFER      17000015
         MVC   ADQMPA(4),4(PAREG)  KEEP ADDRESS OF QMPA                 17200015
         MVC   ADQMGR(4),8(PAREG)  QMGR ENTRY POINT                     17400015
         LA    PAREG,DUMECB        ADDRESS OF DUMMY POSTED ECB          17600015
         CALL  IHKAADSP            LOOP THROUGH DISPATCHER              17800015
         L     PAREG,ADQMPA                                             18000015
         MVC   SAVEQMPA(36),QMNAM  SAVE CALLER'S QMPA                   18200015
         NI    EDITSW,X'7F'        OFF FOR CURRENT BUFFER IS THE FIRST  18400015
         CLI   4(RECORDAD),JOBK    IS IT A JOB STATEMENT - IF SO        18600015
         BE    PROCJOB               BRANCH TO PROCESS JOB STATEMENT    18800015
         CLI   4(RECORDAD),DDK     IS IT A DD STATEMENT-IF SO           19000015
         BE    PROCDD                  BRANCH TO PROCESS DD STATEMENT   19200015
****************************************************************        19400015
*                                                                       19600015
*            PROCESS EXEC STATEMENT                                     19800015
*                                                                       20000015
****************************************************************        20200015
         MVI   SARG,C' '                                                20400015
         MVC   SARG+1(17),SARG     BLANK AREA FOR STEP.DDNAME           20600015
         SR    EXLENGTH,EXLENGTH                                        20800015
         IC    EXLENGTH,6(RECORDAD) LENGTH OF STEPNAME                  21000015
         LTR   EXLENGTH,EXLENGTH   CHECK FOR NO STEP NAME               21200015
         BZ    PROCEX1                                                  21400015
         CLI   6(RECORDAD),X'08'  STEPNAME OVER 8 CHARS          A32855 21430020
         BC    12,EXOK   NO BRANCH                               A32855 21460020
         IC    EXLENGTH,EIGHT                                    A32855 21500020
EXOK     EQU   *                                                 A32855 21550020
         S     EXLENGTH,ONE        MINUS ONE FOR MOVE                   21600015
         EX    EXLENGTH,STEPMOVE                                        21800015
         LA    EXLENGTH,1(EXLENGTH) BUMP LENGTH TO ORIGINAL VALUE       22000015
         LA    DDNAMEAD,SARG(EXLENGTH) POINTS TO SPACE FOR PERIOD       22200015
         MVI   0(DDNAMEAD),C'.'                                         22400015
         LA    DDNAMEAD,1(DDNAMEAD)     POINTS TO SPACE FOR DDNAME      22600015
EDITEXIT STM   2,11,MYREGS         SAVE EDIT'S REGS                     22800015
         L     PAREG,ADQMPA                                             23000015
         MVC   QMNAM(36),SAVEQMPA  RESTORE CALLER'S QMPA                23200015
         L     SAVE,SAREA+4        ADDRESS OF OS'S SAVE AREA            23400015
         RETURN (14,12),T,RC=0                                          23600015
PROCEX1  MVI   SARG+8,C'.'                                              23800015
         LA    DDNAMEAD,SARG+9     NO STEP NAME                         24000015
         B     EDITEXIT            RETURN                               24200015
****************************************************************        24400015
*                                                                       24600015
*            PROCESS JOB STATEMENT                                      24800015
*                                                                       25000015
****************************************************************        25200015
PROCJOB  CLC   7(8,RECORDAD),ERRORNM CHECK FOR ERROR JOBNAME            25400015
         BNE   PROCJOBA            BRANCH IF NORMAL CASE                25600015
         L     WORK,ADJOBNM        ADDRESS OF JOBNAME IN IHKCERDR       25800015
         MVC   7(8,RECORDAD),0(WORK) MOVE JOBNAME TO TEXT BUFFER        26000015
PROCJOBA MVI   KEYSARG,MSGCLAJK    BRANCH TO INTERNAL SUBROUTINE TO     26200015
         BAL   THUMB,SCANBUFF        SEARCH FOR MSGCLASS KEYWORD        26400015
         L     WORK,ADSOC          POINTER TO SYSOUT CLASSES            26600015
         MVI   DUMMYMC,MSGCLAJK    MSGCLASS KEY TO DUMMY MSGCLASS       26800015
         MVC   DUMMYMC+3(1),3(WORK) SET DUMMY MSGCLASS EQUAL TO SYSRJE  27000015
         L     THUMB,ADJEDTAB      POINTER TO JEDTSOUT                  27200015
         MVI   0(THUMB),X'00'      ZERO JED TABLE SYSOUT CLASSES        27400015
         MVC   1(24,THUMB),0(THUMB)                                     27600015
         CLI   0(POINTER),MSGCLAJK TEST FOR MSGCLASS KEYWORD FOUND      27800015
         BNE   PROCJOB5                                                 28000015
         CLC   3(1,POINTER),0(WORK)  CHECK FOR SYSPRINT SPECIFIED       28200015
         BNE   PROCJOB1                                                 28400015
         MVC   0(1,THUMB),0(WORK)    STORE MSGCLASS IN JED TAB          28600015
         B     PROCJOB4                                                 28800015
PROCJOB1 CLC   3(1,POINTER),1(WORK)  CHECK FOR SYSPUNCH                 29000015
         BNE   PROCJOB2                                                 29200015
         MVC   0(1,THUMB),1(WORK)    STORE MSGCLASS                     29400015
         B     PROCJOB4                                                 29600015
PROCJOB2 CLC   3(1,POINTER),2(WORK)  CHECK FOR SYSUSER                  29800015
         BNE   PROCJOB3                                                 30000015
         MVC   0(1,THUMB),2(WORK)  STORE MSGCLASS                       30200015
         B     PROCJOB4                                                 30400015
PROCJOB3 MVC   0(1,THUMB),0(WORK)    STORE SYSPRINT IN JCDTAB MSGCLASS  30600015
PROCJOB4 MVC   3(1,POINTER),3(WORK)  STORE SYSRJE IN INTERNAL TEXT      30800015
PROCJOB6 TM    EDITSW,X'80'        MUST THIS BUFFER BE RE-WRITTEN       31000015
         BZ    PROCJB6                                                  31200015
         L     PAREG,ADQMPA                                             31400015
         MVI   QMPOP,QMWRTE        FUNCTION CODE FOR WRITE              31600015
         L     EXIT,ADQMGR                                              31800015
         CALL  (15)                                                     32000015
PROCJB6  LA    THUMB,1(THUMB)      STORE BEGINNING ADDRESS OF JEDTSOUT  32200015
         ST    THUMB,AJEDSOUT        FOR NEXT DD STATEMENT              32400015
         SR    DDNAMEAD,DDNAMEAD                                        32600015
         B     EDITEXIT            BRANCH TO RETURN                     32800015
PROCJOB5 MVC   0(1,THUMB),0(WORK)  STORE SYSPRT IN JEDTAB MSGCLASS      33000015
         LA    WORK,171(RECORDAD)                                       33200015
         CR    POINTER,WORK        IS THERE ROOM TO ADD MSGCLASS TO     33400015
         BH    PROCJOB7                CURRENT BUFFER                   33600015
         MVC   0(5,POINTER),DUMMYMC  ADD MSGCLASS TO BUFFER             33800015
         B     PROCJOB6                                                 34000015
PROCJOB7 L     PAREG,ADQMPA                                             34200015
         MVI   QMPOP,QMASGN        FUNCTION CODE FOR ASSIGN             34400015
         MVI   QMPCM,X'10'         ASSIGN ONE RECORD                    34600015
         TM    EDITSW,X'80'        DOES CURRENT RECORD NEED TO BE       34800015
         BZ    PROCJOB8              REWRITTEN                          35000015
         MVC   KEEPTTR(4),QMPEX    KEEP TTR OF CURRENT RECORD           35200015
PROCJOB8 L     EXIT,ADQMGR         CALL QUEUE MANAGER TO ASSIGN NEW     35400015
         CALL  (15)                  BUFFER                             35600015
         MVC   0(4,RECORDAD),QMPCA   PUT TTR OF NEW RCC IN OLD REC      35800015
         MVI   3(RECORDAD),X'0B'   IDENTIFIER USED BY CALLING ROUTINE   36000015
         MVI   0(POINTER),KCONT    INDICATE OVERFLOW- KEY CONTINUATION  36200015
         TM    EDITSW,X'80'        MUST CURRENT RECORD BE WRITTEN       36400015
         BZ    PROCJOB9                                                 36600015
         L     PAREG,ADQMPA                                             36800015
         MVC   QMPEX(4),KEEPTTR    TTR0 OF CURRENT RECORD               37000015
         MVI   QMPEX+3,X'00'                                            37200015
         MVC   QMPCA(4),ADEXTRN                                         37400015
         MVI   QMPOP,QMWRTE        FUNCTION CODE FOR WRITE              37600015
         MVI   QMPNC,X'01'         WRITE ONE RECORD                     37800015
         L     EXIT,ADQMGR         REWRITE BUFFER RECORD TO DISK        38000015
         CALL  (15)                                                     38200015
PROCJOB9 MVC   QMPEX(4),0(RECORDAD)  WRITE NEW RECORD                   38400015
         L     PAREG,ADQMPA                                             38600015
         MVI   QMPEX+3,X'00'       TTR0                                 38800015
         MVC   QMPCA(4),ADDUMMY    ADDRESS OF DUMMY RECORD              39000015
         MVI   QMPOP,QMWRTE                                             39200015
         MVI   QMPNC,X'01'                                              39400015
         L     EXIT,ADQMGR         WRITE DUMMY RECORD TO DISK           39600015
         CALL  (15)                                                     39800015
         SR    DDNAMEAD,DDNAMEAD                                        40000015
         B     EDITEXIT            BRANCH TO RETURN                     40200015
****************************************************************        40400015
*                                                                       40600015
*            PROCESS DD STATEMENT                                       40800015
*                                                                       41000015
****************************************************************        41200015
PROCDD   ST    DDNAMEAD,KEEP                                            41400015
         LTR   DDNAMEAD,DDNAMEAD   CHECK FOR NO STEP NAME               41600015
         BZ    EDITEXIT            RETURN FOR NEXT STATEMENT            41800015
PROCDD1  MVI   0(DDNAMEAD),C' '    BLANK OUT AREA FOR DDNAMEAD          42000015
         LA    DDNAMEAD,1(DDNAMEAD)                                     42200015
         C     DDNAMEAD,ADEND      CHECK FOR END OF AREA                42400015
         BL    PROCDD1                                                  42600015
         L     DDNAMEAD,KEEP                                            42800015
         SR    EXLENGTH,EXLENGTH                                        43000015
         IC    EXLENGTH,6(RECORDAD) DDNAME LENGTH                       43200015
        LTR   EXLENGTH,EXLENGTH    CHECK FOR NO DDNAME                  43400015
         BZ    PRCDD0                                            A53069 43600021
         CLI   6(RECORDAD),X'08'   DDNSME OVER 8 CHARS           A32855 43630020
         BC    12,EXOK1     NO BRANCH                            A32855 43660020
         IC    EXLENGTH,EIGHT                                    A32855 43700020
EXOK1    EQU   *                                                 A32855 43750020
         S     EXLENGTH,ONE        MINUS ONE FOR MOVE                   43800015
         EX    EXLENGTH,DDMOVE     MOVE DDNAME TO SARG                  44000015
         SPACE                                                          44040021
PRCDD0   MVI   KEYSARG,DUMMK  IS THIS A DD DUMMY CARD            A53069 44080021
         BAL   THUMB,SCANBUFF      IF SO, DONT LOOK FOR SYSOUT   A53069 44120021
         SPACE                                                          44160021
PRCDD1   MVI   KEYSARG,SYSOUTK     BRANCH TO INTERNAL SUBROUTINE TO     44200015
*                                      SEARCH FOR SYSOUT KEYWORD        44400015
         BAL   THUMB,SCANBUFF                                           44600015
         CLI   0(POINTER),SYSOUTK  WAS KEYWORD FOUND                    44800015
         BNE   EDITEXIT            EXIT IF NOT                          45000015
         CLI   2(POINTER),X'00'    WAS VALUE SPECIFIED?            1658 45060000
         BE    EDITEXIT            NO, DO NOT PROCESS KEYWORD      1658 45120000
         L     MARKER,ADCELST      ADDRESS OF CENTRAL PARAMETER LIST    45200015
         CLC   0(4,MARKER),CENALL  CHECK FOR CENTRAL=ALL                45400015
         BE    PROCDD7                                                  45600015
PROCDD2  CLI   0(MARKER),C' '      UNUSED ENTRY                         45800015
         BE    PROCDD4             EXIT UNFOUND                         46000015
         CLI   17(MARKER),X'FF'    FLAGGED ENTRY                        46200015
         BE    PROCDD3                                                  46400015
         CLC   0(17,MARKER),SARG   MATCHING ENTRY                       46600015
         BE    PROCDD7               FOUND                              46800015
PROCDD3  LA    MARKER,18(MARKER)   BUMP TO NEXT ENTRY                   47000015
         C     MARKER,ENDCELST     CHECK FOR END OF LIST                47200015
         BL    PROCDD2                                                  47400015
PROCDD4  L     THUMB,ADSOC         NO MATCHING ENTRY FOUND              47600015
         LA    WORK,171(RECORDAD)  SARG NOT IN CENTRAL PARAMETER LIST   47800015
         CR    POINTER,WORK        SOES CLASSNAME PARAMETER APPEAR IN   48000015
         BL    PRCDD4                                                   48200015
         BAL   WORK,NEWREC         CONTINUATION BUFFER-BRANCH IF SO     48400015
PRCDD4   LA    POINTER,3(POINTER)  POSITION TO CLASSNAME                48600015
PROCDD5  L     MARKER,AJEDSOUT                                          48800015
         C     MARKER,ENDSOUT      IS JEDTSOUT FULL                     49000015
         BNL   PROCDD6             BRANCH IF FULL                       49200015
         LA    WORK,1(MARKER)      SUMP TO NEXT SPOT IN JEDTSOUT        49400015
         ST    WORK,AJEDSOUT                                            49600015
         CLC   0(1,POINTER),0(THUMB)    SYSPRNT                         49800015
         BNE   PROCDDB                                                  50000015
         MVC   0(1,MARKER),0(POINTER)   STORE CLASSNAME IN JEDTSOUT     50200015
         B     PROCDD6                                                  50400015
PROCDDB  CLC   0(1,POINTER),1(THUMB)    SYSPNCH                         50600015
         BNE   PROCDDC                                                  50800015
         MVC   0(1,MARKER),0(POINTER)   STORE CLASSNAME                 51000015
         B     PROCDD6                                                  51200015
PROCDDC  CLC   0(1,POINTER),2(THUMB)    SYSUSER                         51400015
         BNE   PROCDDD             WAS NOT PRT,PNCH, OR USER            51600015
         MVC   0(1,MARKER),0(POINTER)   STORE CLASSNAME                 51800015
PROCDD6  MVC   0(1,POINTER),3(THUMB)    SUBSTITUTE SYSRJE               52000015
PROCDD8  TM    EDITSW,X'80'        MUST THIS RECORD BE REWRITTEN        52200015
         BO    PROCDD9             BRANCH TO WRITE IF SO                52400015
         B     EDITEXIT                                                 52600015
PROCDDD  MVC   0(1,MARKER),0(THUMB)  STORE SYSPRNT IN JEDTSOUT          52800015
         B     PROCDD6                                                  53000015
PROCDD7  MVI   17(MARKER),X'FF'    FLAG ENTRY USED                      53200015
         LA    WORK,171(RECORDAD)   IS CLASSNAME IN CONTINUATION BUFFER 53400015
         CR    POINTER,WORK                                             53600015
         BL    PRCDD7                                                   53800015
         BAL   WORK,NEWREC          BRANCH TO READ NEXT BUFFER IF SO    54000015
PRCDD7   L     WORK,ADSOC                                               54200015
         CLC   3(1,POINTER),3(WORK) SYSRJE SPECIFIED                    54400015
         BNE   PROCDD8             BRANCH TO EXIT                       54600015
         MVC   3(1,POINTER),0(WORK) PUT SYSPRT IN STATEMENT             54800015
         B     PROCDD8                                                  55000015
PROCDD9  L     PAREG,ADQMPA                                             55200015
         MVI   QMPOP,QMWRTE                                             55400015
         L     EXIT,ADQMGR                                              55600015
         CALL  (15)                                                     55800015
         B     EDITEXIT                                                 56000015
NEWREC   TM    EDITSW,X'80'        MUST CURRENT BUFFER BE RE-WRITTEN    56200015
         BZ    NEWREC2             BRANCH IF NOT                        56400015
         L     PAREG,ADQMPA                                             56600015
         MVI   QMPOP,QMWRTE                                             56800015
         L     EXIT,ADQMGR                                              57000015
         CALL  (15)                RE-WRITE CURRENT BUFFER TO DISK      57200015
NEWREC2  L     PAREG,ADQMPA                                             57400015
         MVC   QMPCL(4),ADEXTRN    ADDRESS EXTERNAL AREA                57600015
         MVC   QMPEX(4),0(RECORDAD) TTR OF NEXT BUFFER                  57800015
         MVI   QMPEX+3,X'00'                                            58000015
         MVI   QMPNC,X'01'         READ ONE RECORD                      58200015
         MVC   QMPCA(4),ADOVERF    ADDRESS TO READ INTO                 58400015
         MVI   QMPOP,QMREAD        FUNCTION CODE FOR READ               58600015
         L     EXIT,ADQMGR         READ NEXT BUFFER                     58800015
         CALL  (15)                                                     59000015
         L     RECORDAD,QMPCA                                           59200015
         LA    POINTER,2(RECORDAD)                                      59400015
         BR    WORK                RETURN TO PROCESS                    59600015
*                                                                       59800015
*            INTERNAL SUBROUTINE TO SCAN TEXT BUFFER FOR A              60000015
*               PARTICULAR KEYWORD                                      60200015
*                                                                       60400015
SCANBUFF LA    POINTER,4(RECORDAD) INIT TO FIRST KEYWORD                60600015
SCANB5   LA    POINTER,1(POINTER)  INCREMENT PAST KEYWORD               60800015
         SR    NUMBER,NUMBER                                            61000015
         IC    NUMBER,0(POINTER)   NUMBER OF POSITIONAL PARAMETERS      61200015
SCANB1   LA    POINTER,1(POINTER)  BUMP TO NEXT BYTE                    61400015
         LTR   NUMBER,NUMBER       NO (MORE) PARAMETERS                 61600015
         BE    SCANB2                                                   61800015
         TM    0(POINTER),X'80'    IS THIS A COUNT FIELD - HIGH ORDER   62000015
         BO    SCANSUB                BIT ON-BRANCH IF SO               62200015
         CLI   0(POINTER),LCONT    CHECK FOR LENGTH CONTINUATION        62400015
         BNE   SCANB1A                                                  62600015
         BAL   MARKER,NEWBUFF      BRANCH TO READ NEXT BUFFER           62800015
SCANB1A  SR    WORK,WORK                                                63000015
         IC    WORK,0(POINTER)     PICK UP LENGTH                       63200015
         AR    POINTER,WORK        INCREMENT TO END OF PARAMETER        63400015
SCANB4   S     NUMBER,ONE          DECREMENT NO. OF PARAMETERS          63600015
         B     SCANB1              BRANCH TO CONTINUE PROCESSING        63800015
SCANB2   CLI   0(POINTER),ENDK     CHECK FOR END KEY                    64000015
         BNE   SCANB3                                                   64200015
         BR    THUMB               EXIT WITH KEYWORD UNFOUND            64400015
SCANB3   CLI   0(POINTER),KCONT    CHECK FOR OVERFLOW BUFFER            64600015
         BNE   SCANB3A                                                  64800015
         BAL   MARKER,NEWBUFF      BRANCH TO READ NEXT BUFFER           65000015
         SPACE                                                          65200021
SCANB3A  CLI   KEYSARG,DUMMK  IS THIS THE DD DUMMY TEST          A53069 65240021
         BE    DUMTST         YES - BRANCH                       A53069 65280021
         SPACE                                                          65320021
         CLC   0(1,POINTER),KEYSARG NO,TEST FOR (OTHER) KEYWD    A53069 65360021
         BNE   SCANB5                                                   65400015
         BR    THUMB               EXIT   WITH KEYWORD FOUND            65600015
SCANSUB  SR    COUNT,COUNT                                              65800015
         IC    COUNT,0(POINTER)                                         66000015
         N     COUNT,HIGHOFF       OFF HIGH ORDER BIT OF LOW ORDER BYTE 66200015
SCANSUB1 LA    POINTER,1(POINTER)  BUMP TO LENGTH FIELD                 66400015
         CLI   0(POINTER),LCONT    CHECK FOR OVERFLOW BUFFER            66600015
         BNE   SCANSUB2                                                 66800015
         BAL   MARKER,NEWBUFF      BRANCH TO READ IN NEXT BUFFER        67000015
SCANSUB2 SR    WORK,WORK                                                67200015
         IC    WORK,0(POINTER)     PICK UP LENGTH                       67400015
         AR    POINTER,WORK        INCREMENT TO END OF PARAMETER        67600015
         BCT   COUNT,SCANSUB1                                           67800015
         B     SCANB4                                                   68000015
         SPACE                                                          68030021
DUMTST   CLI   0(POINTER),DUMMK    IS 1ST DD ATTR DUMMY          A53069 68060021
         BE    EDITEXIT  YES - DONT LOOK FOR SYSOUT - EXIT       A53069 68090021
         BR    THUMB          NO - RETURN TO LOOK FOR SYSOUT     A53069 68120021
         SPACE                                                          68150021
NEWBUFF  L     PAREG,ADQMPA        BASE REG FOR QMPA DSECT              68200015
         TM    EDITSW,X'80'        DOES CURRENT BUFFER NEED TO BE       68400015
         BZ    NEWBUFF2              RE-WRITTEN- BRANCH IF NOT          68600015
         MVI   QMPOP,QMWRTE        SET UP TO REWRITE THE CURRENT BUFFER 68800015
         L     EXIT,ADQMGR                                              69000015
         CALL  (15)                CALL QUEUE MANAGER WRITE             69200015
         L     PAREG,ADQMPA                                             69400015
NEWBUFF1 MVI   QMPOP,QMREAD        FUNCTION CODE FOR READ               69600015
         L     EXIT,ADQMGR                                              69800015
         CALL  (15)                                                     70000015
         L     RECORDAD,QMPCA                                           70200015
         LA    POINTER,4(RECORDAD)                                      70400015
         BR    MARKER                                                   70600015
NEWBUFF2 OI    EDITSW,X'80'        SHOWS NEED TO REWRITE THIS BUFFER    70800015
         L     PAREG,ADQMPA                                             71000015
         MVC   QMPCL(4),ADEXTRN                                         71200015
         MVC   QMPCA(4),ADOVERF                                         71400015
         MVI   QMPNC,X'01'         READ ONE RECORD                      71600015
         MVC   QMPEX(4),0(RECORDAD) MOVE IN TTR                         71800015
         MVI   QMPEX+3,X'00'       TTR0                                 72000015
         B     NEWBUFF1                                                 72200015
*                                                                       72400015
*            CONSTANTS AND WORK AREAS                                   72600015
*                                                                       72800015
SAREA    DS    18F                                                      73000015
MYREGS   DS    10F                                                      73200015
SAVEQMPA DS    CL36                FOR CALLER'S QMPA                    73400015
ADQMPA   DS    F                                                        73600015
ADQMGR   DS    F                                                        73800015
KEEP     DS    F                                                        74000015
KEEPTTR  DS    F                                                        74200015
DUMECB   DC    X'40000000'         DUMMY POSTED ECB                     74400015
EDITSW   DC    X'00'                                                    74600015
EIGHT    DC    X'08'               MAX DDNAME LENGTH ALLOWED     A32855 74700020
ONE      DC    F'1'                                                     74800015
HIGHOFF  DC    X'FFFFFF7F'                                              75000015
KEYSARG  DC    X'00'               KEYWORD FOR SEARCH SUBROUTINE        75200015
CENALL   DC    CL4'ALL'                                                 75400015
ADDUMMY  DC    A(DUMMYMC)                                               75600015
DUMMYMC  DC    X'40010140FE'       MSGCLASS = SYSRJE               000D 75800020
ERRORNM  DC    CL8'JOBFAIL'        ERROR JOBNAME GIVEN BY O/S           76000015
         EXTRN IHKCEJBN                                                 76200015
ADJOBNM  DC    A(IHKCEJBN)         ADDRESS OF JOBNAME IN IHKCERDR       76400015
         EXTRN IHKCEJDT                                                 76600015
ADJEDTAB DC    A(IHKCEJDT+25)                                           76800015
ENDSOUT  DC    A(IHKCEJDT+50)                                           77000015
         EXTRN IHKCDSOC                                                 77200015
ADSOC    DC    A(IHKCDSOC)                                              77400015
AJEDSOUT DS    F                                                        77600015
         EXTRN IHKCELST                                                 77800015
ADCELST  DC    A(IHKCELST)                                              78000015
ENDCELST DC    A(IHKCELST+180)                                          78200015
SARG     DC    CL17' '                                                  78400015
ENDSARG  EQU   *                                                        78600015
ADEND    DC    A(ENDSARG)                                               78800015
*                                                                       79000015
STEPMOVE MVC   SARG(0),7(RECORDAD) MOVE STEPNAME TO SARG                79200015
DDMOVE   MVC   0(0,DDNAMEAD),7(RECORDAD) MOVE DDNAME TO SARG            79400015
*                                                                       79600015
         IEFVKEYS                  MACRO FOR KEYWORD CODES              79800015
*                                                                       80000015
*                                                                       80200015
         IEFQMNGR                  QUEUE MANAGER PARAMETER AREA         80400015
IHKCEDIT CSECT                                                          80600015
QMPCA    DS    F                                                        80800015
QMPEX    DS    F                                                        81000015
ADEXTRN  DC    A(QMPCA)                                                 81200015
ADOVERF  DC    A(OVERFLOW)                                              81400015
OVERFLOW DS    CL176                                                    81600015
*                                                                       81800015
*                                                                       82000015
         END                                                            82200015
