BDR      TITLE 'BRDCSTR'                                                01000016
IHKCFBDR CSECT                                                          02000016
*2830660000,710000                                                 000A 03000016
*********************************************************************** 04000016
*STATUS-CHANGE LEVEL 0                                                * 05000016
*                                                                     * 06000016
*FUNCTION/OPERATION-                                                  * 07000016
*   THIS ROUTINE PROCESSES A REQUEST FOR BROADCAST MESSAGES OR DELAYED* 08000016
*   MESSAGES AND ENQUEUES A DUMMY QUEUE ENTRY BLOCK ON THE REQUESTING * 09000016
*   TERMINAL QUEUE.                                                   * 10000016
*                                                                     * 11000016
*ENTRY POINT-                                                         * 12000016
*        IHKCFBDR-THIS IS THE ONLY ENTRY POINT. THE CALLING SEQUENCE  * 13000016
*   IS:                  LA   1,PARLIST                               * 14000016
*                        CALL IHKCFBDR                                * 15000016
*                                                                     * 16000016
*INPUT-INPUT IS A PARAMETER LIST ON A FULL WORD BOUNDARY-             * 17000016
*   PARLIST IS THE ADDRESS VECTOR TABLE (AVT) WHOSE DESCRIPTION    000A 18000016
*   APPEARS BEFORE THE EXPANSION OF THE DSECT IHKZZAVT             000A 19000016
*                                                                     * 20000016
*OUTPUT-A MESSAGE QUEUE ENTRY BLOCK IS ENQUEUED ON THE TERMINAL QUEUE * 21000016
*   FOR THE REQUESTOR WITH NO MESSAGE AND AN INDICATOR IN THE HIGH    * 22000016
*   ORDER BYTE TO DISTINGUISH BROADCAST AND MESSAGE REQUESTS-         * 23000016
*        X'88' BROADCAST MESSAGES                                     * 24000016
*        X'84' DELAYED MESSAGES                                       * 25000016
*                                                                     * 26000016
*EXTERNAL ROUTINES-                                                   * 27000016
*        IHKCCPLM-RETRIEVE A MESSAGE QUEUE ENTRY BLOCK FROM FREEPOOL  * 28000016
*        IHKCCQMG-ENQUEUE QEB ON TERMINAL QUEUE FOR REQUESTOR         * 29000016
*                                                                     * 30000016
*EXIT-NORMAL-REGISTER 15=0                                            * 31000016
*    -ERROR-N/A                                                       * 32000016
*                                                                     * 33000016
*TABLES/WORK AREAS-18-WORD SAVEAREA FOR CALLED ROUTINES               * 34000016
*                                                                     * 35000016
*ATTRIBUTES-                                                          * 36000016
*   SERIALLY REUSABLE. STANDARD SUBROUTINE LINKAGE PREVAILS.          * 37000016
*   NON-RESIDENT                                                   000A 38000016
*                                                                     * 39000016
* NOTE- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL         * 40000016
*       REPRESENTATION  OF THE EXTERNAL CHARACTER SET WHICH IS        * 41000016
*       EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING       * 42000016
*       HAS BEEN ARRANGED SO THAT REDEFINITION OF 'CHARACTER'         * 43000016
*       CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE     * 44000016
*       FOR THE NEW DEFINITIONS.                                      * 45000016
ZONE     EQU   0                                                      * 46000016
PARA     EQU   1                                                      * 47000016
TEMP     EQU   2                                                        48000016
WORK     EQU   3                                                      * 49000016
VCONBASE EQU   5                                                   000A 50000016
BASE     EQU   12                                                     * 51000016
SAVE     EQU   13                                                     * 52000016
RETURN   EQU   14                                                     * 53000016
ENTRY    EQU   15                                                     * 54000016
         USING IHKZZAVT,VCONBASE                                   000A 55000016
         STM   RETURN,BASE,12(SAVE)     SAVE REGISTERS                  56000016
         BALR  BASE,0                   ESTABLISH BASE REGISTER         57000016
         USING *,BASE                                                   58000016
         ST    SAVE,SAVE1+4             SAVE CALLER'S SAVEAREA ADDRESS  59000016
         LA    WORK,SAVE1               GET PRESENT SAVEAREA ADDRESS    60000016
         ST    WORK,8(SAVE)             BACK CHAIN ADDRESS              61000016
         LR    SAVE,WORK                SET UP FOR CALLED PROGRAMS      62000016
         LR    VCONBASE,PARA                                       000A 63000016
         TM    8(PARA),X'FF'            SEE IF ENTRY FROM RJSTART  000A 64000016
         BZ    AROUND                     IF NOT, VCONBASE IS RIGHT000A 65000016
         L     VCONBASE,8(PARA)           IF SO, RELOAD VCONBASE   000A 66000016
AROUND   DS    0H                                                  000A 67000016
         L     WORK,0(PARA)             SAVE TDIR ADDRESS               68000016
         L     TEMP,4(PARA)             CHECK FOR MESSAGE OR BROADCAST  69000016
         XR    PARA,PARA                INDICATE TO RETREIVE QEB        70000016
         XR    ZONE,ZONE                FOR A SYSTEM MESSAGE            71000016
         STM   ZONE,PARA,BDRLIST   SET UP PARAMETER LIST FOR PLM   000A 72000016
         LA    PARA,BDRLIST        GET ADDRESS OF PARAMETER LIST   000A 73000016
         L     ENTRY,IHKZZPLM      GET ADDRESS OF POOL MANAGER     000A 74000016
         BALR  RETURN,ENTRY        GO ON TO POOL MANAGER           000A 75000016
         LR    ZONE,WORK                PUT TDIR ADDRESS IN PARALIST    76000016
         LTR   TEMP,TEMP                IF ZERO,SET BITS FOR A DUMMY    77000016
         BZ    SETMSG                   MESSAGE QEB                     78000016
         MVI   0(PARA),X'88'            INDICATE DUMMY BROADCAST QEB    79000016
ENQUEUE  STM   ZONE,PARA,BDRLIST   SET UP PARAMETER LIST FOR QMG   000A 80000016
         LA    PARA,BDRLIST        GET ADDRESS OF PARAMETER LIST   000A 81000016
         L     ENTRY,IHKZZQMG      GO TO Q MANAGER                 000A 82000016
         BALR  RETURN,ENTRY                                        000A 83000016
         XR    ENTRY,ENTRY                                              84000016
         L     SAVE,SAVE1+4             RESTORE SAVEAREA ADDRESS        85000016
         RETURN (14,12),T,RC=(15)                                       86000016
SETMSG   MVI   0(PARA),X'84'            INDICATE DUMMY MESSAGE QEB      87000016
         B     ENQUEUE                                                  88000016
SAVE1    DS    18F                      SAVE AREA FOR CALLED ROUTINES   89000016
BDRLIST  DS    2F                                                  000A 90000016
         IHKDSECT ,,,,,AVT                                         000A 91000016
         END                                                            92000016
