*3200084000-090000,152000,330000-332000,336000,464000,652000,      000A 00050018
*3200656000,694000-698000,706000-714000                            000A 00100018
*1090006000,744000                                                 000C 00150018
MSG      TITLE 'MESSAGE'                                                00200016
IHKCFMSG CSECT                                                          00400016
* STATUS- CHANGE LEVEL=2                                           000C 00600018
*                                                                     * 00800016
* FUNCTION/OPERATION- THE MESSAGE COMMAND PROCESSOR RELAYS MESSAGES   * 01000016
*       FROM USER TO TERMINAL,USER, OR CENTRAL OPERATOR AND FROM THE  * 01200016
*       CENTRAL OPERATOR TO A TERMINAL OR USER. ACTION TAKEN DEPENDS  * 01400016
*       UPON THE PARTICULAR PARAMETERS OF THE COMMAND-                * 01600016
*       * THE TERMINAL CAN RECEIVE IF THE 'ENQUEUE MESSAGES' BIT OF   * 01800016
*         THE TDIRSTAT BYTE IS ON. THE USER CAN RECEIVE IF HE IS      * 02000016
*         LOGGED ON A TERMINAL WHICH CAN ITSELF RECEIVE.              * 02200016
*                                                                     * 02400016
*            1. U SPECIFIED ONLY                                      * 02600016
*               A. USER ABLE TO RECEIVE - MESSAGE SENT TO USER        * 02800016
*               B. USER NOT ABLE TO RECEIVE - MESSAGE NOT SENT        * 03000016
*                                                                     * 03200016
*            2. T SPECIFIED ONLY                                      * 03400016
*               A. TERMINAL ABLE TO RECEIVE - MESSAGE SENT TO TERMINAL* 03600016
*               B. TERMINAL NOT ABLE TO RECEIVE - MESSAGE ADDED TO    * 03800016
*                  DATA SET FOR MESSAGES MAINTAINED ON DIRECT ACCESS  * 04000016
*                  DEVICE                                             * 04200016
*                                                                     * 04400016
*            3. U AND T SPECIFIED                                     * 04600016
*               A. USER ABLE TO RECEIVE - MESSAGE SENT TO USER        * 04800016
*               B. USER UNABLE TO RECEIVE -                           * 05000016
*                   1. TERMINAL ABLE TO RECEIVE - MESSAGE SENT        * 05200016
*                   2. TERMINAL UNABLE TO RECEIVE - MESSAGE ADDED TO  * 05400016
*                      DATA SET FOR MESSAGES MAINTAINED ON DIRECT     * 05600016
*                      ACCESS DEVICE                                  * 05800016
*                                                                     * 06000016
*            4. NO U OR T SPECIFIED                                   * 06200016
*               A. CENTRAL COMMAND - MESSAGE SENT TO ALL ACTIVE       * 06400016
*                  TERMINALS                                          * 06600016
*               B. REMOTE COMMAND - MESSAGE SENT TO CENTRAL CPU       * 06800016
*                                                                     * 07000016
*            5. D SPECIFIED - MESSAGES FOR THE TERMINAL ID GIVEN ARE  * 07200016
*                  REMOVED FROM THE MESSAGES PENDING DATA SET         * 07400016
*                                                                     * 07600016
* ENTRY POINT-  IHKCFMSG                                              * 07800016
*                                                                     * 08000016
* INPUT- STANDARD SUBROUTINE LINKAGE PREVAILS AT ENTRY TO THIS ROUTINE* 08200016
*       REGISTER 1- ADDRESS OF THE AVT (ADDRESS VECTOR TABLE) WHOSE000A 08400016
*                   DESCRIPTION APPEARS BEFORE THE EXPANSION OF THE000A 08600016
*                   DSECT IHKZZAVT                                 000A 08800016
*                                                                     * 09000016
* OUTPUT-1.IF THE MESSAGE CAN BE SENT, IT IS FORMATTED TO MAKE IT     * 09200016
*          MEANINGFUL AND PASSED ON THROUGH BUILD MESSAGE FOR         * 09400016
*          ENQUEUING.                                                 * 09600016
*                                                                     * 09800016
*        2.IF THE MESSAGE IS TO BE HELD IHKCDMEQ IS CALLED AND PASSED * 10000016
*          THE FORMATTED MESSAGE                                      * 10200016
*                                                                     * 10400016
*        3.IF DELETION IS REQUESTED AND CAN BE DONE, ALL MESSAGES FOR * 10600016
*          THE TERMINAL SPECIFIED ARE REMOVED FROM THE DATA SET BY    * 10800016
*          IHKCDMDE.                                                  * 11000016
*                                                                     * 11200016
*        4.IN ALL CASES A MESSAGE IS SENT TO THE SENDER WITH THE      * 11400016
*          SEQUENCE NUMBER AND THE STATUS OF THE COMMAND.             * 11600016
*          IN THE CASE OF AN I/O ERROR A DISK ERROR MESSAGE REPLACES  * 11800016
*          ANY NORMAL RETURN MESSAGE.                                 * 12000016
*                                                                     * 12200016
* EXTERNAL ROUTINES- IHKCBSTD-SEARCH TERMINAL DIRECTORY FOR TERMINAL  * 12400016
*                             SPECIFIED                               * 12600016
*                    IHKCCSUD-SEARCH USER DIRECTORY FOR USER SPECIFIED* 12800016
*                    IHKCDMDE-DELETE MESSAGES FROM MESSAGE PENDING    * 13000016
*                             DATA SET                                * 13200016
*                    IHKCDMEQ-ADD MESSAGES TO MESSAGE PENDING DATA    * 13400016
*                             SET FOR A TERMINAL                      * 13600016
*                    IHKCBLDM-SEND COMMAND CARD MESSAGES AND STATUS   * 13800016
*                             MESSAGES                                * 14000016
*                                                                     * 14200016
* EXIT-NORMAL- REGISTER 15-0 IF COMMAND WAS COMPLETELY PROCESSED      * 14400016
* EXIT-ERROR- REGISTER 15-NON-0 IF UNUSUAL END                        * 14600016
*                                                                     * 14800016
* ATTRIBUTES- SERIALLY REUSABLE, NON-RESIDENT                      000A 15000016
* NOTE- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL         * 15200016
*       REPRESENTATION  OF THE EXTERNAL CHARACTER SET WHICH IS        * 15400016
*       EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING       * 15600016
*       HAS BEEN ARRANGED SO THAT REDEFINITION OF 'CHARACTER'         * 15800016
*       CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE     * 16000016
*       FOR THE NEW DEFINITIONS.                                      * 16200016
*                                                                     * 16400016
** ** ** ** ** ** ** ** **   R E G I S T E R S  ** ** ** ** ** ** ** ** 16600016
*                                                                     * 16800016
ZONE     EQU   0                                                      * 17000016
PARA     EQU   1                                                      * 17200016
WORK     EQU   3                                                      * 17400016
CDBASE   EQU   4                                                      * 17600016
TDBASE   EQU   5                                                      * 17800016
EVEN     EQU   6                                                      * 18000016
ODD      EQU   7                                                      * 18200016
BAL      EQU   8                                                      * 18400016
SAVECODE EQU   9                                                   000A 18600016
VCONBASE EQU   11                                                  000A 18800016
BASE     EQU   12                                                     * 19000016
SAVE     EQU   13                                                     * 19200016
RETURN   EQU   14                                                     * 19400016
ENTRY    EQU   15                                                     * 19600016
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  19800016
*                                                                     * 20000016
         STM   RETURN,BASE,12(SAVE)     SAVE REGISTERS                  20200016
         BALR  BASE,0                   ESTABLISH BASE REGISTER         20400016
         USING *,BASE                                                   20600016
         ST    SAVE,SAVE1+4             SAVE CALLER'S SAVEAREA ADDRESS  20800016
         LA    WORK,SAVE1               GET PRESENT SAVEAREA ADDRESS    21000016
         ST    WORK,8(SAVE)             BACK CHAIN ADDRESS              21200016
         LR    SAVE,WORK                SET UP FOR CALLED PROGRAMS      21400016
         B     Z                                                        21600016
         DC    C'IHKCFMSG,DISK ERROR,7/19/67'                           21800016
Z        DS    0H                                                       22000016
*                                                                       22200016
*        END OF STANDARD ENTRY LINKAGE                                * 22400016
*                                                                       22600016
         USING IHKZZAVT,VCONBASE                                   000A 22800016
         USING CMDCDS,CDBASE                                            23000016
         LR    VCONBASE,PARA                                       000A 23200016
         MVC   PARALIST,IHKZZCBS                                   000A 23400016
         MVC   PARALIST+4,IHKZZDSP                                 000A 23600016
         MVC   PARALIST+12,IHKZZTDR                                000A 23800016
         MVC   PARALIST+16,IHKZZTMR                                000A 24000016
         L     CDBASE,4(PARA)           SET UP BASE FOR COMMAND CARD    24200016
         MVI   KEY,C' '                 CLEAR PARAMETER AREA            24400016
         MVC   KEY+1(27),KEY                 FOR IHKCBLDM               24600016
         CLI   TYPE,C'G'                IS MESSAGE FROM CENTRAL         24800016
         BE    DOWN                     IF SO, DONT GO TO TDIR          25000016
*                                                                       25200016
*        INITIALIZE RETURN MESSAGE FOR REMOTE                         * 25400016
*                                                                       25600016
         MVC   MSGBACK(4),0(PARA)       SAVE TERMINAL DIRECTORY ADDRESS 25800016
         L     ENTRY,0(PARA)            SET UP BASE REGISTER FOR        26000016
         USING TERMDIR,ENTRY            TERMINAL DIRECTORY DSECT        26200016
         MVC   USID(4),TDIRUSID         SAVE CALLING USERID             26400016
         MVI   USID+3,C' '                                              26600016
         DROP  ENTRY                    DROP DSECT BASE                 26800016
*                                                                       27000016
*        SET UP MESSAGE FROM CONTROL CARD                             * 27200016
*                                                                       27400016
CHECKOUT MVC   S1(8),SEQUENCE           INSERT CARD SEQUENCE NUM        27600016
         MVI   MESSAGE,C' '             CLEAR MESSAGE AREA              27800016
         MVC   MESSAGE+1(40),MESSAGE                                    28000016
         XR    EVEN,EVEN                CLEAR FOR USE                   28200016
         XR    ODD,ODD                                                  28400016
         IC    EVEN,BEG                 GET RELATIVE DISPLACEMENTS      28600016
         IC    ODD,END                                                  28800016
         AR    EVEN,CDBASE              GET ACTUAL BEG. AND ENDING      29000016
         AR    ODD,CDBASE               ADDRESSES OF MESSAGE            29200016
         LA    WORK,1                                                   29400016
         AR    EVEN,WORK                GET FROM ADDRESS                29600016
         SR    ODD,EVEN                 GET ACTUAL LENGTH OF MESSAGE    29800016
         SR    ODD,WORK                 REDUCE LENGTH FOR EXECUTE       30000016
         LA    WORK,MESSAGE             GET TO ADDRESS                  30200016
         EX    ODD,MOVE1                MOVE MESSAGE                    30400016
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   30600016
         MVC   TO(3),BLANK              INITIALIZE DESTINATION          30800016
         MVC   FROM(3),USID             PUT IN SENDERS ID               31000016
         CLI   U,X'00'                  CHECK FOR USERID SPECIFIED      31200016
         BNE   SCHUDIR                  IF SO, CHECK FOR USER LOGGED ON 31400016
         CLI   T,X'00'                  CHECK FOR TDIRID SPECIFIED      31600016
         BNE   ACTIVE                   IF SO, CHECK FOR ACTIVE TERM    31800016
         CLI   TYPE,C'G'                IS NO OPERAND CARD FROM CENTRAL 32000016
         BE   ALLTERMS                  IF SO, SEND TO ALL TERMINALS    32200016
*                                                                       32400016
*        MESSAGE BY DEFAULT TO CENTRAL OPERATOR                       * 32600016
*                                                                       32800016
         MVC   KEY(8),CENT              INSERT 'CENTRAL'                33000016
         XR    WORK,WORK                                                33200016
         ST    WORK,MSGPARMS            IND MSG FOR CENTRAL OPERATOR    33400016
         B     MSGTOTER                 GO TO SEND MESSAGES             33600016
*                                                                       33800016
*        MESSAGE BY DEFAULT TO ALL ACTIVE TERMINALS                   * 34000016
*                                                                       34200016
ALLTERMS L     TDBASE,IHKZZTDR                                     000A 34400016
         L     EVEN,IHKZZTNB                                       000A 34600016
         LH    WORK,0(EVEN)             LOAD NUMBER OF ENTRIES          34800016
         L     EVEN,IHKZZTLN                                       000A 35000016
         LH    ODD,0(EVEN)              GET LENGTH CONSTANT             35200016
         USING TERMDIR,TDBASE                                           35400016
BACK     TM    TDIRSTAT,X'10'           CHECK STATUS OF TERMINAL        35600016
         BZ    WAYOUT                                                   35800016
SEND1    ST    TDBASE,MSGPARMS          INSERT TDIR ENTRY ADDRESS       36000016
         LA    PARA,MSGPARMS            IN PARALIST FOR IHKCBLDM        36200016
         BAL   BAL,BUILDMSG             GO TO CALL BUILD MSG            36400016
WAYOUT   AR    TDBASE,ODD               INCREMENT TDIR ADDRESS          36600016
         BCT   WORK,BACK                IF MORE, GO BACK                36800016
         MVC   KEY(9),TERMS             IF MSG IS FOR ALL TERMINALS     37000016
         LA    WORK,33                  SET UP ENQUEUED OFFSET          37200016
         STH   WORK,MSGBACK+4           FOR RETURN MESSAGE              37400016
         MVI   MSGBACK+6,X'1B'          REDUCE MAXIMUM LENGTH           37600016
         B     SENDMSG2                 SEND MSG BACK TO CENTRAL        37800016
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   38000016
DOWN     CLI   D,C'D'                   CHECK FOR DELETE PARAMETER      38200016
         BNE   BELOW                    IF NOT, CONTINUE AS USUAL       38400016
*                                                                       38600016
*        DELETE OPTION FROM CENTRAL                                   * 38800016
*                                                                       39000016
         MVC   TDID(8),T                GET TERMINAL ID                 39200016
         BAL   BAL,STD                  GO TO CALL STD                  39400016
         LTR   ENTRY,ENTRY              CHECK FOR GOOD RETURN           39600016
         BNZ   NOTFOUND                 IF NOT SEND MESSAGE             39800016
         MVC   ID(8),TDID                                               40000016
         MVC   DELETE+7(9),TERM         FILL PARAMETER LIST             40200016
         LA    WORK,36                                                  40400016
         STH   WORK,OFFSET                                              40600016
         MVI   LENGTH,X'09'             SET PARAMETER LENGTH            40800016
         ST    PARA,TDIR                PUT TDIR ADDR IN PARALIST       41000016
        LOAD  EP=IHKCDMDE                                               41200016
        LR    ENTRY,ZONE                                                41400016
        LA    PARA,PARALIST                                             41600016
        BALR  RETURN,ENTRY                                              41800016
         LR    SAVECODE,ENTRY           SAVE RETURN CODE           000A 42000016
        DELETE EP=IHKCDMDE                                              42200016
         LTR   ENTRY,SAVECODE           WERE THEY DELETED          000A 42400016
         BNZ   MDEERROR                 IF NOT, SEND I/O ERROR MSG      42600016
MDEMSG   LA    PARA,DELETE                                              42800016
         B     FINISH                   GO TO BUILDMSG AND THEN OUT     43000016
MDEERROR STH   ENTRY,OFFSET             SEND PASSED OFFSET              43200016
         MVI   LENGTH,X'00'             NO PARAMETERS PASSED            43400016
         B     MDEMSG                                                   43600016
NOTFOUND MVC   DELETE+7(3),MSG          FILL PARAMETER LIST             43800016
         LA    WORK,6                                                   44000016
         STH   WORK,OFFSET                                              44200016
         MVI   LENGTH,X'03'                                             44400016
         LA    PARA,DELETE                                              44600016
         B     FINISH                   GO TO BUILDMSG AND THEN OUT     44800016
*                                                                       45000016
*        INITIALIZE RETURN MESSAGE FOR CENTRAL                        * 45200016
*                                                                       45400016
BELOW    MVC   USID(4),CEN              PUT ABBR IN WHEN FROM CENTRAL   45600016
         MVC   MSGBACK(4),ZERO          AND CONTINUE                    45800016
         B     CHECKOUT                                                 46000016
*                                                                       46200016
*        PROCESS FOR USERID SPECIFIED                                 * 46400016
*                                                                       46600016
SCHUDIR  MVC   USERID(3),U              SAVE USERID SPECIFIED           46800016
         MVC   TO(3),U                  PUT USID IN PARAMETER LIST      47000016
         MVC   KEY(3),U                 INSERT USERID IN MSG            47200016
         L     PARA,USERID              SEARCH USER DIRECTORY FOR       47400016
         L     ENTRY,IHKZZSUD                                      000A 47600016
         BALR  RETURN,ENTRY                                        000A 47800016
         LTR   PARA,PARA                IS THIS USER IN THE SYSTEM      48000016
         BZ    INVALID                  GO TO INSERT ERROR MSG          48200016
         LR    EVEN,PARA                SET UP BASE TO ACCESS           48400016
         USING UDIREC,EVEN              USER DIRECTORY                  48600016
         MVC   TDID(8),UDIRTERM         FIND WHERE USER WAS LOGGED ON   48800016
         BAL   BAL,STD                  GO TO CALL STD                  49000016
         LTR   ENTRY,ENTRY              IF TERMINAL ENTRY WAS NOT FOUND 49200016
         BNZ   TERMSPEC                 IF NOT SEE IF TERM IS SPECIFIED 49400016
LOGGEDON LR    TDBASE,PARA              SET UP BASE TO ACCESS           49600016
         USING TERMDIR,TDBASE           TERMINAL DIRECTORY ENTRY        49800016
         CLC   USERID(3),TDIRUSID       IS USER LOGGED ON               50000016
         BNE   TERMSPEC                 IF NOT SEE IF TERM IS SPECIFIED 50200016
         ST    TDBASE,MSGPARMS          PUT TDIR ADDR IN PARALIST       50400016
         TM    TDIRSTAT,X'10'           CHECK STATUS OF TERMINAL        50600016
         BZ    TERMSPEC                 IF PASSIVE CHECK FOR TERM SPEC  50800016
MSGTOTER LA    WORK,33                  SET UP OFFSET                   51000016
         STH   WORK,MSGBACK+4           SET UP RETURN MSG               51200016
         MVI   MSGBACK+6,X'1B'          REDUCE MAXIMUM LENGTH           51400016
         B     SENDMSG1                 AND SEND BOTH MESSAGES          51600016
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   51800016
INVALID  MVC   S2(8),S1                 SHIFT SEQUENCE NUMBER           52000016
         MVC   S1(8),INV                INSERT 'INVALID'                52200016
         B     ERROR                    BRANCH TO ERROR EXIT            52400016
*                                                                       52600016
*        PROCESS FOR TERMID SPECIFIED                                 * 52800016
*                                                                       53000016
TERMSPEC CLI   T,X'00'                  CHECK FOR TERMINAL SPECIFIED    53200016
         BE    ERROR                    BRANCH TO ERROR EXIT            53400016
ACTIVE   MVC   TDID(8),T                GET TERMINAL SPECIFIED          53600016
         MVC   KEY(8),T                 INSERT TERMINAL ID IN MSG       53800016
         BAL   BAL,STD                  GO TO CALL STD                  54000016
         LTR   ENTRY,ENTRY              IF TERMINAL ENTRY WAS FOUND     54200016
         BNZ   INVALID                  INSERT 'INVALID'                54400016
STATUS   LR    TDBASE,PARA              SET UP BASE TO ACCESS           54600016
         USING TERMDIR,TDBASE           TERMINAL DIRECTORY ENTRY        54800016
         ST    TDBASE,MSGPARMS          PUT TDIR ADDR IN PARALIST       55000016
         TM    TDIRSTAT,X'10'           CHECK STATUS OF TERMINAL        55200016
         BZ    GOTOED                   ENQUEUE FOR INACTIVE TERMINAL   55400016
         B     MSGTOTER                 GO TO SEND BOTH MSGS            55600016
*                                                                       55800016
*        MESSAGE TO MESSAGE PENDING DATA SET                          * 56000016
*                                                                       56200016
GOTOED   LA    WORK,32                  SET UP OFF SET FOR              56400016
         STH   WORK,MSGBACK+4           MSG PENDING TERMINAL STARTUP    56600016
         ST    TDBASE,TDIR              PUT TDIR ADDR IN PARALIST       56800016
         LOAD EP=IHKCDMEQ                                               57000016
        LR    ENTRY,ZONE                                                57200016
        LA    PARA,PARALIST                                             57400016
        BALR  RETURN,ENTRY                                              57600016
         LR    SAVECODE,ENTRY           SAVE RETURN CODE           000A 57800016
        DELETE EP=IHKCDMEQ                                              58000016
         LTR   ENTRY,SAVECODE           WERE MESSAGES ENQUEUED     000A 58200016
         BZ    SENDMSG2                 RETURN MSG TO SENDER            58400016
         LA    WORK,4                                                   58600016
         CLR   WORK,ENTRY               WAS MESSAGE DATA SET FULL       58800016
         BE    ERROR                    IF SO, SEND APPROPRIATE MSG     59000016
         MVI   LENGTH,X'00'             NO PARAMETERS PASSED            59200016
         STH   ENTRY,OFFSET             SEND PASSED OFFSET              59400016
         LA    PARA,DELETE              SET PARAMETER LIST ADDRESS      59600016
         BAL   BAL,BUILDMSG             SEND I/O ERROR MESSAGE          59800016
         CLC   ZERO,MSGBACK             IS THIS MSG OR MSGR             60000016
         BE    OUT                      IF CENTRAL, ALL OVER            60200016
         MVC   S2(8),S1                 SHIFT SEQUENCE                  60400016
         MVC   KEY+9(10),DISK           PUT 'DISK ERROR' IN MSG TO USER 60600016
         B     ERROR                    AND SEND                        60800016
*                                                                       61000016
*        MSG IGNORED- INVALID USERID OR TERMID OR UNABLE TO HOLD      * 61200016
*                                                                       61400016
ERROR    LA    WORK,34                  IF NOT LET SENDER KNOW          61600016
         STH   WORK,MSGBACK+4                                           61800016
         B     SENDMSG2                                                 62000016
*                                                                       62200016
*        MESSAGE ENQUEUING                                            * 62400016
*                                                                       62600016
SENDMSG1 LA    PARA,MSGPARMS            SET UP MESSAGE PARAMETERS AND   62800016
         BAL   BAL,BUILDMSG             GO TO CALL BUILD MSG            63000016
*                                                                       63200016
*        MESSAGE RESPONSE                                             * 63400016
*                                                                       63600016
SENDMSG2 LA    PARA,MSGBACK             SET UP MSG PARMS FOR SENDER'S   63800016
FINISH   BAL   BAL,BUILDMSG             GO TO CALL BUILDMSG             64000016
         MVI   MSGBACK+6,X'1C'          RESET PARAMETER LENGTH          64200016
*                                                                       64400016
*        EXITS- RETURN TO CALLER                                      * 64600016
*                                                                       64800016
         XR    ENTRY,ENTRY              CLEAR RETURN CODE REGISTER      65000016
OUT      L     SAVE,SAVE1+4             RESTORE REGISTERS               65200016
         RETURN (14,12),T,RC=(15)                                       65400016
*                                                                       65600016
*        INTERNAL SUBROUTINES                                         * 65800016
*                                                                       66000016
STD      LA    PARA,TDID                SET UP PARAMETER                66200016
         L     ENTRY,IHKZZSTD                                      000A 66400016
         BALR  RETURN,ENTRY                                        000A 66600016
         BR    BAL                      RETURN TO CALLER                66800016
BUILDMSG L     ENTRY,IHKZZLDM                                      000A 67000016
         BALR  RETURN,ENTRY                                        000A 67200016
         BR    BAL                      RETURN TO CALLER                67400016
*                                                                       67600016
** ** ** ** ** ** ** ** **   C O N S T A N T S  ** ** ** ** ** ** ** ** 67800016
INV      DC    C' INVALID'                                              68000016
CENT     DC    C'CENTRAL '                                              68200016
TERMS    DC    C'TERMINALS'                                             68400016
CEN      DC    C'*C* '                                                  68600016
DISK     DC    C'DISK ERROR'                                            68800016
USERID   DC    F'0'                     DESTINATION USER IDENTIFICATION 69000016
ZERO     DC    F'0'                                                     69200016
TDID     DS    2F                       TERMINAL DIRECTORY ADDRESS      69400016
SAVE1    DS    18F                      SAVE AREA FOR CALLED ROUTINES   69600016
USID     DS    F                        CALLING USER IDENTIFICATION     69800016
MOVE1    MVC   0(0,WORK),0(EVEN)        MOVE MESSAGE                    70000016
TERM     DC    C' '                     DELETE MESSAGE PARAMETERS-      70200016
ID       DS    CL8                                GOOD                  70400016
MSG      DC    C'MSG '                  DELETE MESSAGE PARAMETER-BAD    70600016
BLANK    DC    C'    '                                                  70800016
*                                                                     * 71000016
******   MEQ AND MDE PARALIST-ENQUEUE MESSAGE OR DELETE MESSAGES ****** 71200016
*                                                                     * 71400016
PARALIST DS    2F                                                  000A 71600016
TDIR     DS    3F                                                  000A 71800016
        DC    A(MSGBEG)                ADDRESS OF MESSAGE TO ENQ     *  72000016
*                                                                     * 72200016
******   BUILDMSG PARALIST-DELETION STATUS MESSAGE               ****** 72400016
*                                                                     * 72600016
DELETE   DC    F'0'                     MESSAGE PARAMETERS-TO CENTRAL * 72800016
OFFSET   DS    H                        PROPER OFFSET INSERTED        * 73000016
LENGTH   DS    C                        PROPER LENGTH INSERTED        * 73200016
         DS    CL9                      PROPER PARAMETER INSERTED     * 73400016
*                                                                     * 73600016
******   BUILDMSG PARALIST-MESSAGE COMMAND MESSAGE               ****** 73800016
*                                                                     * 74000016
MSGPARMS DS    F                        TERMINAL ADDRESS INSERTED     * 74200016
         DC    X'0046'                  NULL MESSAGE               000C 74400018
         DC    X'3B'                    FULL MESSAGE LENGTH           * 74600016
MSGBEG   DC    C'RJE MSG '              MESSAGE ID                    * 74800016
TO       DS    CL3                      DESTINATION INDICATED         * 75000016
         DC    C' FR '                                                * 75200016
FROM     DS    CL3                      ORIGIN INDICATED              * 75400016
         DC    C' '                                                   * 75600016
MESSAGE  DS    CL41                     TAKEN FROM SUBMITTER'S CARD   * 75800016
*                                                                     * 76000016
******   BUILDMSG PARALIST-MESSAGE COMMAND STATUS MESSAGE        ****** 76200016
*                                                                     * 76400016
MSGBACK  DS    F                        TERMINAL ADDRESS INSERTED     * 76600016
         DS    H                        PROPER OFFSET INSERTED        * 76800016
         DC    X'1C'                    LENGTH INDICATOR              * 77000016
KEY      DS    CL10                     ENQUEUED DESTINATION INSERTED * 77200016
S1       DS    CL10                     SEQUENCE NO, INVALID, OR DISK * 77400016
S2       DS    CL8                      SEQUENCE NUMBER IF INVALID    * 77600016
*                                                                     * 77800016
** ** ** ** ** ** ** ** D U M M Y S E C T I O N S ** ** ** ** ** ** *** 78000016
CMDCDS   DSECT                     DUMMY SETION FOR COMMAND CARD IMAGE* 78200016
CARD     DS    CL72                                                   * 78400016
SEQUENCE DS    CL8                                                    * 78600016
TYPE     DS    C                                                      * 78800016
U        DS    CL3                                                    * 79000016
T        DS    CL8                                                    * 79200016
BEG      DS    C                                                      * 79400016
END      DS    C                                                      * 79600016
D        DS    C                                                      * 79800016
FASTAB   DSECT                     FAST TABLE DUMMY SECTION           * 80000016
FASTNAME DS    CL8                                                    * 80200016
FASTJIB  DS    C                                                      * 80400016
FASTJEDT DS    CL3                                                    * 80600016
FASTDSB  DS    C                                                      * 80800016
FASTSSB  DS    C                                                      * 81000016
FASTTTR  DS    CL3                                                    * 81200016
FASTALT  DS    CL3                                                    * 81400016
FASTCNT  DS    C                                                      * 81600016
FASTUSE  DS    CL3                                                    * 81800016
TERMDIR  DSECT                     TERMINAL DIRECTORY DUMMY SECTION   * 82000016
TDIRTERM DS    CL8                                                    * 82200016
TDIRUSID DS    CL3                                                    * 82400016
TDIRSTAT DS    C                                                      * 82600016
TDIRRB   DS    C                                                      * 82800016
TDIRTTR  DS    CL3                                                    * 83000016
TDIRFQEB DS    CL4                                                    * 83200016
TDIRLQEB DS    CL4                                                    * 83400016
TDIRLMEL DS    CL4                                                    * 83600016
TDIRFORM DS    CL4                                                    * 83800016
UDIREC   DSECT                     USER DIRECTORY DUMMY SECTION       * 84000016
UDIRTERM DS    CL8                                                    * 84200016
UDIRSTAT DS    C                                                      * 84400016
UDIRUSID DS    CL3                                                    * 84600016
UDIRUKEY DS    CL3                                                    * 84800016
UDIRTTR  DS    CL3                                                    * 85000016
         IHKDSECT ,,,,,AVT                                         000A 85200016
         END                                                            85400016
