OUT      TITLE 'OUTPUT'                                                 00200019
IHKCFOUT CSECT                                                          00400019
*2830414000,462000,498000,624000,726000,768000,777000              000A 00600019
*0790834000-840000                                                 000B 00800019
* 418000,420000                                                  A29484 00900019
*                                                                     * 01000019
*                                                                     * 01200019
* STATUS- CHANGE LEVEL=0                                              * 01400019
*                                                                     * 01600019
* FUNCTION/OPERATION-THE OUTPUT COMMAND PROCESSOR INTERPRETS THE      * 01800019
*      REQUEST OF THE USER AFTER THE COMMAND CARD HAS BEEN RE-        * 02000019
*      FORMATTED BY THE COMMAND INTERPRETER. THERE ARE FOUR POSSIBLE  * 02200019
*      KINDS OF REQUESTS-                                             * 02400019
*                                                                     * 02600019
*            JOBNAME-REQUEST FOR A PARTICULAR JOB BY NAME. IF THE     * 02800019
*                    REQUEST IS VALID AND THE JOB IS COMPLETE, THE    * 03000019
*                    OUTPUT IS ENQUEUED FOR THE PROPER TERMINAL AND   * 03200019
*                    CONTROL IS RETURNED TO THE CALLER. IF THE        * 03400019
*                    REQUESTOR IS FOUND TO BE AN INVALID RECIPIENT,   * 03600019
*                    HE IS NOTIFIED. IF THE REQUEST IS VALID, BUT THE * 03800019
*                    JOB IS NOT COMPLETE, THE USER IS NOTIFIED. IF    * 04000019
*                    THE JOB IS MARKED AS ALREADY ENQUEUED OF IF THE  * 04200019
*                    JOB IS NOT IN THE FASTABLE, THE REQUESTOR IS     * 04400019
*                    NOTIFIED THAT THE JOB IS NOT IN THE SYSTEM.      * 04600019
*                                                                     * 04800019
*            *-REQUEST FOR ALL JOBS REQUESTOR MAY RECEIVE, REGARDLESS * 05000019
*                    OF ORIGINATOR. ALL JOBS HE MAY RECEIVE ARE EN-   * 05200019
*                    QUEUED FOR THE PROPER TERMINAL. IF THERE IS NO   * 05400019
*                    JOB OF THIS DESCRIPTION, THE USER IS NOTIFIED.   * 05600019
*            USERID- REQUEST FOR ALL JOBS REQUESTOR MAY RECEIVE       * 05800019
*                    SUBMITTED UNDER A PARTICULAR ID. THE ID MAY BE   * 06000019
*                    HIS OWN. THIS REQUEST IS ONLY A QUALIFICATION OF * 06200019
*                    THE * AND IS TREATED IN A SIMILAR WAY.           * 06400019
*            BLANK-REQUEST FOR ALL OF REQUESTORS JOBS. THE SAME OUTPUT* 06600019
*                    IS RECEIVED WHEN A USER SPECIFIES HIS OWN ID. THE* 06800019
*                    REQUEST IS HANDLED IN THE SAME MANNER AS THE *.  * 07000019
*                    MESSAGE SENT TO REQUESTOR WHEN NO OUTPUT IS FOUND* 07200019
*                    FOR HIM-                                         * 07400019
*                    'NO OUTPUT IN SYSTEM'                            * 07600019
*      AFTER ALL PROPER OUTPUT HAS BEEN ENQUEUED OR A MESSAGE HAS     * 07800019
*      BEEN SENT, CONTROL IS RETURNED TO THE CALLING ROUTINE.         * 08000019
*                                                                     * 08200019
* ENTRY POINTS-  IHKCFOUT-PROCESS OUTPUT COMMAND, DATA PASSED BY      * 08400019
*                LOCATION                                             * 08600019
*                IHKCFQOP-SUBROUTINE TO ENQUEUE OUTPUT                * 08800019
*                                                                     * 09000019
* INPUT- IHKCFOUT                                                     * 09200019
*        REGISTER 1- ADDRESS OF THE ADDRESS VECTOR TABLE           000A 09400019
*        IHKCFQOP- SEE SUBROUTINE FOR DESCRIPTION                     * 09600019
*                                                                     * 09800019
* OUTPUT- OUTPUT ENQUEUED OR MESSAGE SENT                             * 10000019
*         INDICATION OF ENQUEUING MADE IN FASTABLE FOR SOURCE OR      * 10200019
*         ALTERNATE.                                                  * 10400019
* EXTERNAL ROUTINES- IHKCCSGN-SEARCH FAST TABLE FOR VALID JOB FOR     * 10600019
*                             SPECIFIED RECIPIENT                     * 10800019
*                    IHKCDSCH-SEARCH FAST TABLE FOR JOBNAME SPECIFIED * 11000019
*                    IHKCBLDM-BUILD APPROPRIATE MESSAGE FOR TERMINAL  * 11200019
*                    IHKCCPLM-ALLOT QUEUE FROM SUBPOOL                * 11400019
*                    IHKCCQMG-ENQUEUE REQUEST FOR OUTPUT              * 11600019
*                    IHKCDFMR-WRITE ENTRY FROM FAST TABLE ONTO DISC   * 11800019
*                                                                     * 12000019
* EXITS- ONLY NORMAL RETURNS TO CALLING ROUTINE                       * 12200019
*                                                                     * 12400019
* ATTRIBUTES- REUSABLE, NON-RESIDENT                               000A 12600019
*                                                                     * 12800019
* NOTE- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL         * 13000019
*       REPRESENTATION  OF THE EXTERNAL CHARACTER SET WHICH IS        * 13200019
*       EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING       * 13400019
*       HAS BEEN ARRANGED SO THAT REDEFINITION OF 'CHARACTER'         * 13600019
*       CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE     * 13800019
*       FOR THE NEW DEFINITIONS.                                      * 14000019
** ** ** ** ** ** ** ** **   R E G I S T E R S  ** ** ** ** ** ** ** ** 14200019
*                                                                     * 14400019
ZONE     EQU   0                                                      * 14600019
PARA     EQU   1                                                      * 14800019
WORK     EQU   3                                                      * 15000019
CDBASE   EQU   4                                                      * 15200019
FTBASE   EQU   5                                                      * 15400019
VCONBASE EQU   6                                                   000A 15600019
BASE     EQU   12                                                     * 15800019
SAVE     EQU   13                                                     * 16000019
RETURN   EQU   14                                                     * 16200019
ENTRY    EQU   15                                                     * 16400019
*                                                                     * 16600019
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  16800019
*                                                                     * 17000019
         STM   RETURN,BASE,12(SAVE)     SAVE REGISTERS                  17200019
         BALR  BASE,0                   ESTABLISH BASE REGISTER         17400019
         USING *,BASE                                                   17600019
         B     AROUNDID                                            000B 17800019
         DC    C'IHKCFOUT'                                         000B 18000019
AROUNDID DS    0H                                                  000B 18200019
         USING IHKZZAVT,VCONBASE                                   000A 18400019
         LR    VCONBASE,PARA                                       000A 18600019
         ST    VCONBASE,VCONSAVE                                   000A 18800019
         ST    SAVE,SAVE1+4             SAVE CALLER'S SAVEAREA ADDRESS  19000019
         LA    WORK,SAVE1               GET PRESENT SAVEAREA ADDRESS    19200019
         ST    WORK,8(SAVE)             BACK CHAIN ADDRESS              19400019
         LR    SAVE,WORK                SET UP FOR CALLED PROGRAMS      19600019
*                                                                       19800019
*        END OF STANDARD ENTRY LINKAGE                                * 20000019
*                                                                       20200019
         MVI   ADTDIR,C' '              BEGIN TO PAD WITH BLANKS        20400019
         MVC   ADTDIR+1(35),ADTDIR      CONTINUE PADDING                20600019
         MVC   LIST(4),0(PARA)          PUT TDIR ADDRESS IN PARALIST    20800019
         L     CDBASE,4(PARA)           SET UP BASE REGISTER FOR        21000019
         USING CMDCDS,CDBASE                                            21200019
         L     ENTRY,0(PARA)                                            21400019
         USING TERMDIR,ENTRY            TERMINAL DIRECTORY DSECT        21600019
         ST    ENTRY,ADTDIR             SAVE TERMINAL DIRECTORY ADDRESS 21800019
         MVC   USID(4),TDIRUSID         SAVE CALLING USERID             22000019
         MVC   ADTDIR+16(3),USID        PUT USERID IN PARALIST          22200019
         DROP  ENTRY                    DROP DSECT BASE                 22400019
         SR    WORK,WORK                INITIALIZE ALL SEARCHES TO THE  22600019
         ST    WORK,PARALIST            FIRST OF THE FASTABLE           22800019
         CLI   CODE,C'J'                                                23000019
         BE    JOBNAME                  IF SO, GO TO SPECIFIED ROUTINE  23200019
         MVC   DSTNPX(3),USID           INDICATE ID FOR DESTINATION     23400019
         CLI   CODE,C'*'                IF USER WANTS ALL OUTPUT        23600019
         BE    ALLJOBS                 AVAILABLE TO HIM, GO TO ROUTINE  23800019
         CLI   CODE,C'U'                IF USER WANTS ALL OF SOMEONE'S  24000019
         BE    USERID                   OUTPUT AVAILABLE TO HIM, BRANCH 24200019
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  24400019
*                                                                       24600019
* ENQUEUE ALL OF SUBMITTER'S JOBS WHICH ARE COMPLETE                  * 24800019
*                                                                       25000019
MYJOBS   MVC   SRCEPX(3),USID           IF USER WANTS ALL OF HIS OUTPUT 25200019
*                                       INDICATE HIS ID AS SOURCE       25400019
         B     SEARCH                   PREFIX FOR SEARCH OF FASTABLE   25600019
*                                                                       25800019
* ENQUEUE ALL JOBS AVAILABLE TO REQUESTOR                             * 26000019
*                                                                       26200019
ALLJOBS  XC    SRCEPX(3),SRCEPX         INDICATE ALL JOBS FOR USER 000B 26400019
         B     SEARCH                   REQUESTED IN SEARCH OF FASTABLE 26600019
*                                                                       26800019
* ENQUEUE ALL OF SOME USER'S JOBS AVAILABLE TO THE REQUESTOR          * 27000019
*                                                                       27200019
USERID   MVC   SRCEPX(3),EXPAN          INDICATE SPECIFIED ID AS SOURCE 27400019
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 27600019
*                                                                       27800019
*        SEARCH FOR ALL JOBS MEETING SPECIFICATIONS                   * 28000019
*                                                                       28200019
SEARCH   LA    PARA,PARALIST            CALL SRCHGEN TO SCAN FASTABLE   28400019
         L     ENTRY,IHKZZSGN                                      000A 28600019
         BALR  RETURN,ENTRY                                        000A 28800019
*                                       ON A COMPLETED JOB              29000019
         LTR   ENTRY,ENTRY              TEST RETURN CODE FOR JOB FOUND  29200019
         BNZ   SENDMSG4                 IF NOT SEND MESSAGE             29400019
SENDOUT  LR    FTBASE,PARA                                              29600019
         USING FASTAB,FTBASE                                            29800019
         ST    PARA,LIST+4              PUT FASTABLE ADDRESS IN LIST    30000019
         ST    PARA,PARALIST            UPDATE FTABLE POINTER           30200019
         NI    LIST+4,X'7F'             TURN OFF HIGH ORDER BIT         30400019
         CLC   USID(3),FASTUSE          IS REQUESTOR THE SUBMITTER      30600019
         BE    CALLSUB                                                  30800019
         OI    LIST+4,X'80'             TURN ON HIGH ORDER BIT          31000019
CALLSUB  LA    PARA,LIST                                                31200019
         LA    ENTRY,IHKCFQOP           GO TO ROUTINE TO ENQUEUE OUTPUT 31400019
         BALR  RETURN,ENTRY                                             31600019
         LA    PARA,PARALIST            CALL SRCHGEN TO SCAN FASTABLE   31800019
         L     ENTRY,IHKZZSGN                                      000A 32000019
         BALR  RETURN,ENTRY                                        000A 32200019
*                                       ID'S ON A COMPLETED JOB         32400019
         LTR   ENTRY,ENTRY              TEST RETURN CODE FOR JOB FOUND  32600019
         BZ    SENDOUT                  IF SO PUT OUT                   32800019
         B     GOBACK                   IF NOT GO BACK TO CALLER        33000019
*                                                                     * 33200019
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 33400019
*                                                                       33600019
* ENQUEUE JOB FOR REQUESTOR IF HE IS A VALID RECIPIENT                * 33800019
*                                                                       34000019
JOBNAME  MVC   ADTDIR+7(8),EXPAN        PUT JOBNAME IN PARAMETER LIST   34200019
         LA    PARA,EXPAN               PUT JOBNAME IN REG 1 FOR PARAM  34400019
         L     ENTRY,IHKZZSCH                                      000A 34600019
         BALR  RETURN,ENTRY                                        000A 34800019
         LTR   ENTRY,ENTRY              IF JOB IS NOT FOUND SEND MESS   35000019
         BNZ   SENDMSG1                 TO INDICATE THIS TO USER        35200019
         LR    FTBASE,PARA                                              35400019
         USING FASTAB,FTBASE                                            35600019
         ST    PARA,LIST+4              PUT FASTABLE ADDRESS IN LIST    35800019
         CLC   USID(3),FASTUSE          IS REQUESTOR THE SUBMITTER      36000019
         BNE   TESTALT                  IF NOT,CHECK FOR VALID USER     36200019
         NI    LIST+4,X'7F'             TURN OFF HIGH ORDER BIT         36400019
ENQUEUED TM    FASTDSB,X'60'            TEST FOR JOB ALREADY ENQUEUED   36600019
         BM    SENDMSG0                                                 36800019
         TM    FASTDSB,X'80'            TEST FOR JOB COMPLETED          37000019
         BZ    SENDMSG2                 IF NOT, TELL REQUESTOR          37200019
         LA    PARA,LIST                                                37400019
         LA    ENTRY,IHKCFQOP           GO TO ROUTINE TO ENQUEUE OUTPUT 37600019
         BALR  RETURN,ENTRY                                             37800019
         B     GOBACK                   RETURN TO CALLING ROUTINE       38000019
TESTALT  CLC   USID(3),FASTALT          SEE IF HE IS ALTERNATE          38200019
         BNE   SENDMSG3                 IF NOT, SEND MESSAGE            38400019
         OI    LIST+4,X'80'             TURN ON HIGH ORDER BIT          38600019
         B     ENQUEUED                 GO TO TEST FOR ALREADY ENQUEUED 38800019
*                                                                       39000019
*        SEND APPROPRIATE MESSAGE WHEN NO OUTPUT IS SENT              * 39200019
*                                                                       39400019
SENDMSG0 LA    WORK,52             JOB WAITING DELIVERY                 39600019
         B     SENDMSG                                                  39800019
SENDMSG1 LA    WORK,22                  JOB NOT IN SYSTEM               40000019
         MVC   ADTDIR+24(3),ADTDIR+16                                   40200019
         MVC   ADTDIR+15(8),ADTDIR+7                                    40400019
         MVC   ADTDIR+7(7),CMD          INSERT OPERATION NAME           40600019
         MVC   ADTDIR+28(8),SEQUENCE                                    40800019
         B     SENDMSGS                                                 41000019
SENDMSG2 LA    WORK,23             JOB NOT COMPLETE                     41200019
         B     SENDMSG                                                  41400019
SENDMSG3 LA    WORK,21             INVALID RECIPIENT                    41600019
         MVI   ADTDIR+6,X'1E'      LENGTH OF DYNAMIC DATA        A29484 41800019
         STH   WORK,ADTDIR+4       STORE MESSAGE OFFSET          A29484 42000019
         MVC   OPLIST(7),ADTDIR    PREPARE TO PUT OPERATION IN MSG 000B 42200019
         MVC   OPLIST+7(8),CMD     MOVE IN OPERATION               000B 42400019
         LA    PARA,OPLIST         POINT TO NEW MESSAGE BUFFER     000B 42600019
         MVC   ADTDIR+20(8),SEQUENCE SEQUENCE NUMBER               000B 42800019
         B     NEWTAG                                              000B 43000019
SENDMSG4 LA    WORK,58             NO JOB FOUND                         43200019
         MVC   ADTDIR+7(8),CMD          INSERT OPERATION NAME           43400019
SENDMSG  MVC   ADTDIR+20(8),SEQUENCE    PUT SEQUENCE IN PARALIST        43600019
SENDMSGS MVI   ADTDIR+6,X'1C'           INSERT MSG LENGTH               43800019
         LA    PARA,ADTDIR              GOTO ROUTINE TO SEND MESSAGES   44000019
         STH   WORK,ADTDIR+4            PUT OFFSET IN PARAMETER LIST    44200019
NEWTAG   DS    0H                                                  000B 44400019
         L     ENTRY,IHKZZLDM                                      000A 44600019
         BALR  RETURN,ENTRY                                        000A 44800019
*                                                                       45000019
*        RETURN TO CALLING ROUTINE                                    * 45200019
*                                                                       45400019
GOBACK   L     SAVE,SAVE1+4             RESTORE REGISTERS               45600019
         XR    ENTRY,ENTRY              SEND GOOD RETURN CODE           45800019
         RETURN (14,12),T,RC=(15)                                       46000019
*                                                                     * 46200019
** ** ** ** ** ** ** ** **   C O N S T A N T S  ** ** ** ** ** ** ** ** 46400019
*                                                                     * 46600019
*   THE FOLLOWING THREE WORDS ARE USED AS ONE PARAMETER LIST       000B 46800019
LIST     DS    2F                                                       47000019
VCONSAVE DS    F                                                   000A 47200019
USID     DS    F                                                        47400019
SAVE1    DS    18F                                                      47600019
PARALIST DS    F                                                        47800019
SRCEPX   DS    CL3  SOURCE PREFIX IN SEARCH PARAMETER LIST              48000019
DSTNPX   DS    CL3  DESTINATION PREFIX-USER CURRENTLY LOGGED ON         48200019
         DC    C'O'                                                     48400019
OPLIST   DS    2F                  THIS IS USED WITH THE FOLLOWING 000BX48600019
                                   PARAMETER LIST FOR 'INVALID     000BX48800019
                                   RECIPIENT' MESSAGE              000B 49000019
ADTDIR   DS    9F                                                       49200019
CMD      DC    C'OUTPUT  '                                         000B 49400019
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  49600019
*        IHKCFQOP                                                     * 49800019
*        REGISTER 1- POINTER TO PARAMETER LIST AS FOLLOWS-            * 50000019
*                    WORD 1- ADDRESS OF TERMINAL DIRECTORY ENTRY FOR  * 50200019
*                            OUTPUT DESTINATION                       * 50400019
*                    WORD 2- ADDRESS OF FAST TABLE ENTRY FOR OUTPUT   * 50600019
*                            HIGH ORDER BIT ON INDICATES ALTERNATE    * 50800019
*                              DESTINATION                            * 51000019
*                            HIGH ORDER BIT NOT ON INDICATES SOURCE   * 51200019
*  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  *  51400019
IHKCFQOP STM   RETURN,BASE,12(SAVE)     SAVE REGISTERS                  51600019
         BALR  BASE,0                   ESTABLISH BASE REGISTER         51800019
         USING *,BASE                                                   52000019
         L     VCONBASE,8(PARA)                                    000A 52200019
         XR    RETURN,RETURN            CLEAR FOR LOCK FEATURE          52400019
         L     ENTRY,IHKZZDSP                                      000A 52600019
         TS    BIT                      TEST BUSY BIT                   52800019
         BCR   7,ENTRY                  GO TO DISPATCHER IF BUSY        53000019
         ST    SAVE,SAVEAREA+4                                          53200019
         LA    WORK,SAVEAREA                                            53400019
         ST    WORK,8(SAVE)             BACK CHAIN ADDRESS              53600019
         LR    SAVE,WORK                SET UP FOR CALLED PROGRAMS      53800019
*                                                                       54000019
*        END OF STANDARD ENTRY LINKAGE INCLUDING LOCK FUNCTION        * 54200019
*                                                                       54400019
         L     FTBASE,4(PARA)                                           54600019
         USING FASTAB,FTBASE                                            54800019
         L     ZONE,0(PARA)             GET TDIR ADDRESS                55000019
         SR    PARA,PARA                ASK POOL MGR FOR BLOCK TO       55200019
         STM   ZONE,PARA,PARLIST                                   000A 55400019
         LA    PARA,PARLIST                                        000A 55600019
         L     ENTRY,IHKZZPLM                                      000A 55800019
         BALR  RETURN,ENTRY                                        000A 56000019
         NI    0(PARA),X'1F'            ZERO FIRST 3 BITS OF QUEUE      56200019
         ST    FTBASE,4(PARA)           PUT FASTABLE ADDR IN QEB WORD 2 56400019
         STM   ZONE,PARA,PARLIST                                   000A 56600019
         LA    PARA,PARLIST                                        000A 56800019
         L     ENTRY,IHKZZQMG                                      000A 57000019
         BALR  RETURN,ENTRY                                        000A 57200019
         TM    4(PARA),X'80'            IS ALT DESTINATION RECIPIENT    57400019
         BO    TURNON                                                   57600019
         OI    FASTDSB,X'40'            INDICATE ENQD FOR SOURCE        57800019
         B     WRITEOUT                                                 58000019
TURNON   OI    FASTDSB,X'20'            INDICATE ENQUD FOR ALTERNATE    58200019
WRITEOUT DS    0H                                                  000B 58400019
         NI    BIT,X'00'                UNLOCK DOOR                     58600019
         L     SAVE,SAVEAREA+4                                          58800019
         RETURN (14,12),T                                               59000019
*                                                                     * 59200019
** ** ** ** ** ** ** ** **   C O N S T A N T S  ** ** ** ** ** ** ** ** 59400019
*                                                                     * 59600019
BIT      DC    X'00'               BUSY BIT                           * 59800019
PARLIST  DS    2F                                                  000A 60000019
SAVEAREA DS    18F                                                      60200019
*                                                                     * 60400019
** ** ** ** ** ** ** ** D U M M Y S E C T I O N S ** ** ** ** ** ** *** 60600019
*                                                                     * 60800019
TERMDIR  DSECT      TERMINAL DIRECTORY DUMMY SECTION                  * 61000019
TDIRTERM DS    CL8                                                    * 61200019
TDIRUSID DS    CL3                                                    * 61400019
TDIRSTAT DS    C                                                      * 61600019
TDIRRB   DS    C                                                      * 61800019
TDIRTTR  DS    CL3                                                    * 62000019
TDIRFQEB DS    CL4                                                    * 62200019
TDIRLQEB DS    CL4                                                    * 62400019
TDIRLMEL DS    CL4                                                    * 62600019
TDIRFORM DS    CL4                                                    * 62800019
FASTAB   DSECT      FAST TABLE DUMMY SECTION                          * 63000019
FASTNAME DS    CL8                                                    * 63200019
FASTJIB  DS    C                                                      * 63400019
FASTJEDT DS    CL3                                                    * 63600019
FASTDSB  DS    C                                                      * 63800019
FASTSSB  DS    C                                                      * 64000019
FASTTTR  DS    CL3                                                    * 64200019
FASTALT  DS    CL3                                                    * 64400019
FASTCNT  DS    C                                                      * 64600019
FASTUSE  DS    CL3                                                    * 64800019
CMDCDS   DSECT      COMMAND CARD DUMMY SECTION                        * 65000019
CARD     DS    CL72                                                   * 65200019
SEQUENCE DS    CL8                                                    * 65400019
         DS    C                                                      * 65600019
CODE     DS    C                                                      * 65800019
EXPAN    DS    CL8                                                    * 66000019
         ENTRY IHKCFQOP                                                 66200019
         IHKDSECT ,,,,,AVT                                         000A 66400019
         END                                                            66600019
