STA      TITLE 'STATUS'                                                 00200017
IHKCFSTA CSECT                                                          00400017
*3231022000,026000-032000,040000,148000,300000,308000-310000,      000A 00600017
*3231338000,346000,396000-398000,404000,460000,538000,             000A 00800017
*3231678000-686000                                                 000A 01000017
*1710250000,272000,296000,354000,412000,446000,570000,716000       000B 01200017
*********************************************************************** 01400017
*STATUS- CHANGE LEVEL 0                                               * 01600017
*                                                                     * 01800017
*FUNCTION/OPERATION-                                                  * 02000017
*   THIS ROUTINE PROCESSES THE STATUS COMMAND.                        * 02200017
*                                                                     * 02400017
*ENTRY POINTS-                                                        * 02600017
*        IHKCFSTA- PROCESSES THE STATUS COMMAND THE CALLING SEQUENCE- * 02800017
*                        LA   1,ADDRESS VECTOR TABLE               000A 03000017
*                        CALL IHKCFSTA                                * 03200017
*                                                                     * 03400017
*        IHKCFSTB- DETERMINES THE STATUS OF 1 PARTICULAR JOB. THE     * 03600017
*                  CALLING SEQUENCE-                                  * 03800017
*                        LA   1,PARALIST                           000A 04000017
*              WHERE PARALIST IS DEFINED AS:                          * 04200017
*              WORD 1- ADDRESS OF THE ASSOCIATED FASTABLE ENTRY    000A 04400017
*              WORD 2- ADDRESS OF THE ADDRESS VECTOR TABLE         000A 04600017
*                                                                     * 04800017
*INPUT- THE ONLY INPUT CONSISTS OF THE PARAMETERS DESCRIBED ABOVE.    * 05000017
*       A DESCRIPTION OF THE ADDRESS VECTOR TABLE APPEARS BEFORE   000A 05200017
*       EXPANSION OF THE DSECT IHKZZAVT.                           000A 05400017
*                                                                     * 05600017
*OUTPUT-                                                              * 05800017
*   IHKCFSTA-THE ONLY OUTPUT IS IN THE FORM OF A MESSAGE.             * 06000017
*   1. STATUS REPORT- 1 PER JOB MEETING REQUIREMENTS                  * 06200017
*      'IHK008I STATUS  JOBNAME  UUU  VVV  EXECUTING  SSSSSSSS        * 06400017
*                                          SCHED NNNN                 * 06600017
*                                          NORMAL END                 * 06800017
*                                          ABNORM END                 * 07000017
*                                          DISK ERROR                 * 07200017
*              UUU- SOURCE'S USERID                                   * 07400017
*              VVV- ALTERNATE'S USERID                                * 07600017
*              DISK ERROR- JOBNAME COULD NOT BE READ FROM SYS1.SYSJOBQE 07800017
*   2. JOB NOT FOUND IN FASTABLE                                      * 08000017
*      'IHK004I NO JOB(S) IN SYSTEM JOBNAME UUU SSSSSSSS'             * 08200017
*   3. SUBMITTER IS NEITHER SOURCE NOR ALTERNATE                      * 08400017
*      'IHK006I INVALID RECEIVER OF JOB NAME UUU SSSSSSSS'            * 08600017
*   IHKCFSTB                                                          * 08800017
*   1. REGISTER 1 WILL POINT TO A 10-BYTE AREA CONTAINING ONE OF THE  * 09000017
*      POSSIBLE STATES  *EXECUTING                                    * 09200017
*                      * SCHED NNNN                                   * 09400017
*                     *  NORMAL END                                   * 09600017
*                      * ABNORM END                                   * 09800017
*                       *DISK ERROR                                   * 10000017
*   2. IF A DISK ERROR RESPONSE IS SENT BECAUSE THE JOBNAME COULD NOT * 10200017
*      BE READ FROM SYS1.SYSJOBQE, THE FOLLOWING MESSAGE IS SENT TO   * 10400017
*      THE CENTRAL OPERATOR-                                          * 10600017
*      'IHK063I DISK ERROR Q MGR'                                     * 10800017
*                                                                     * 11000017
*EXTERNAL ROUTINES-                                                   * 11200017
*        IHKCCSGN- SEARCHES FASTABLE FOR JOBNAME                      * 11400017
*        IHKCBLDM- BUILDS SYSTEM MESSAGES                             * 11600017
*        IHKCDSCH- SEARCHES FASTABLE FOR JOBNAME                      * 11800017
*        IEFLOCDQ- O/S QUEUE SEARCH                                   * 12000017
*        IEFALTRA- ENABLES ACCESS TO O/S QUEUE MANAGER AREA ON DIRECT * 12200017
*                  ACCESS                                             * 12400017
*                                                                     * 12600017
*EXITS-NORMAL-                                                        * 12800017
*   NORMAL RETURN IS BY REGISTER 14 TO THE CALLING ROUTINE WITH A     * 13000017
*   CODE OF ZERO IN REGISTER 15. EXIT FROM IHKCFSTB PUTS IN REGISTER  * 13200017
*   1 A POINTER TO A 10-BYTE FIELD CONTAINING THE STATUS MESSAGE AS   * 13400017
*   DESCRIBED ABOVE.                                                  * 13600017
*                                                                     * 13800017
*EXITS-ERROR-                                                         * 14000017
*   N/A                                                               * 14200017
*                                                                     * 14400017
*TABLES/WORK AREAS-                                                   * 14600017
*   A SAVE AREA OF 18 WORDS IS PROVIDED TO PASS TO CALLED ROUTINES.   * 14800017
*   ONE 16-BYTE AREA IS PROVIDED TO IEFLOC FOR PASSING BACK SEARCH    * 15000017
*   RESULTS. A 20 BYTE PARAMETER AREA IS USED TO INTERFACE WITH IEFLOC* 15200017
*                                                                     * 15400017
*ATTRIBUTES-                                                          * 15600017
*   SERIALLY REUSABLE, NON-RESIDENT                                000A 15800017
*                                                                     * 16000017
*NOTES-                                                               * 16200017
*   THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL             * 16400017
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 16600017
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING           * 16800017
*   HAS BEEN ARRANGED SO THAT REDEFINITION OF 'CHARACTER'             * 17000017
*   CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE         * 17200017
*   FOR THE NEW DEFINITIONS.                                          * 17400017
*                                                                     * 17600017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 17800017
*                                                                     * 18000017
*                        R E G I S T E R S                            * 18200017
*                                                                     * 18400017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 18600017
ZONE     EQU   0                                                      * 18800017
PARA     EQU   1                                                      * 19000017
CTR      EQU   2                        BCT COUNTER                   * 19200017
WORK     EQU   3                                                      * 19400017
LEN      EQU   4                        LENGTH OF FASTABLE ENTRY      * 19600017
VCONBASE EQU   4                                                   000A 19800017
LENG     EQU   5                        LENGTH OF USER DIRECTORY ENTRY* 20000017
TDIRBASE EQU   5                        BASE FOR REFERENCING TDIR     * 20200017
TEMP     EQU   6                        TEMPORARY HOLDER              * 20400017
FASTBASE EQU   7                        BASE FOR FASTABLE             * 20600017
UDIRBASE EQU   8                        BASE FOR USER DIRECTORY       * 20800017
INDEX    EQU   9                        INCREMENT FOR SEARCH          * 21000017
SW       EQU   10                       ON FOR NO ERROR MESSAGE       * 21200017
CARDBASE EQU   11                       BASE FOR CARD IMAGE           * 21400017
BASE     EQU   12                                                     * 21600017
SAVE     EQU   13                                                     * 21800017
RETURN   EQU   14                                                     * 22000017
ENTRY    EQU   15                                                     * 22200017
*                                                                     * 22400017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 22600017
*                                                                     * 22800017
         STM   RETURN,BASE,12(SAVE)     SAVE REGISTERS                  23000017
         USING IHKCFSTA,BASE            BASE PROMISED                   23200017
         LR    BASE,ENTRY               SET UP BASE AS PROMISED         23400017
         USING IHKZZAVT,VCONBASE                                   000A 23600017
         LR    VCONBASE,PARA                                       000A 23800017
         ST    VCONBASE,VCONSAVE                                   000A 24000017
TAG      ST    SAVE,SAVE1+4             SAVE CALLER'S SAVEAREA ADDRESS  24200017
         LA    WORK,SAVE1               GET PRESENT SAVEAREA ADDRESS    24400017
         ST    WORK,8(SAVE)             BACK CHAIN ADDRESS              24600017
         LR    SAVE,WORK                SET UP FOR CALLED PROGRAMS      24800017
         B     Z                                                        25000017
         DC    C'IHKCFSTA'                                         000B 25200017
Z        DS    0H                                                       25400017
         L     CARDBASE,4(PARA)         SET UP DSECT FOR CARD           25600017
         USING CMDCDS,CARDBASE                                          25800017
         MVC   SEQ(8),SEQUENCE                                          26000017
         MVC   BLANK2(9),SEQUENCE-1     PUT SEQUENCE NO IN MESSAGE      26200017
         L     TDIRBASE,0(PARA)         SET UP DSECT FOR DIRECTORY      26400017
         USING TERMDIR,TDIRBASE                                         26600017
         ST    TDIRBASE,TADDR                                           26800017
         ST    TDIRBASE,ADTDIR          SAVE TERMINAL DIRECTORY ADDRESS 27000017
         MVC   DEST(3),TDIRUSID         PUT REQUESTOR'S ID. IN PARALIST 27200017
         XC    SGNLIST(4),SGNLIST       INDICATE SEARCH FROM TOP   000B 27400017
         MVC   USERNAME(3),TDIRUSID     PUT REQUESTOR'S ID IN MESSAGE   27600017
         MVI   BLANK1,C' '                                              27800017
         XR    SW,SW                    INITIALIZE OFF                  28000017
         CLI   CODE,C'U'                IS REQUEST FOR ALL USERID JOBS  28200017
         BE    USERID                   GO TO PROCESS FOR USERID JOBS   28400017
         CLI   CODE,X'00'               IS REQUEST FOR HIS JOBS         28600017
         BE    MYJOBS                   GO TO PROCESS JOBS FROM HIM     28800017
         CLI   CODE,C'J'                IS REQUEST FOR SPECIFIC JOBNAME 29000017
         BE    JOBNAM                   GO TO PROCESS SPECIFIC JOBNAME  29200017
         CLI   CODE,C'T'                IS REQUEST FOR TERM OUTPUT      29400017
         BE    TERMINAL                 GO TO PROCESS TERMINAL OUTPUT   29600017
ALLJOBS  XC    SOURCE(3),SOURCE         ALL JOBS FOR REQUESTOR     000B 29800017
         B     SEARCH                   SEARCH FASTABLE                 30000017
USERID   MVC   SOURCE(3),EXPAN          ALL USER JOBS                   30200017
         B     SEARCH                   SEARCH FASTABLE                 30400017
MYJOBS   MVC   SOURCE(3),DEST           ALL HIS OWN JOBS                30600017
SEARCH   BAL   INDEX,SEARCH1            SEARCH ROUTINE AND CHECK        30800017
         LTR   SW,SW                    WAS ANY GOOD JOB FOUND          31000017
         BZ    SETPARM1                 IF NOT, SEND OUT MESSAGE        31200017
         B     GOOD                     RETURN TO CALLER                31400017
SEARCH1  LA    PARA,SGNLIST             PASS PARAMETER LIST             31600017
         L     ENTRY,IHKZZSGN                                      000A 31800017
         BALR  RETURN,ENTRY                                        000A 32000017
         LTR   ENTRY,ENTRY              TEST FOR JOB FOUND              32200017
         BCR   2,INDEX                  RETURN TO CALLER                32400017
         LA    SW,1                     TURN ON SWITCH FOR JOB FOUND    32600017
         L     LEN,IHKZZFLN                                        000A 32800017
         LH    LEN,0(LEN)               LOAD LENGTH                     33000017
         STH   LEN,STALEN                                          000A 33200017
         L     VCONBASE,VCONSAVE                                   000A 33400017
         LR    TEMP,PARA                SAVE FASTABLE ENTRY ADDRESS     33600017
         ST    PARA,LIST                                           000A 33800017
         LA    PARA,LIST                                           000A 34000017
         LA    ENTRY,IHKCFSTB           GO TO ROUTINE TO CHECK STATUS   34200017
         BALR  RETURN,ENTRY                                             34400017
         LA    PARA,TADDR                                               34600017
         BAL   WORK,BLDMSG              GO TO BUILDMSG ROUTINE          34800017
         AH    TEMP,STALEN                                         000A 35000017
         ST    TEMP,SGNLIST             PUT NEW STARTING ADDR IN PARAMS 35200017
         B     SEARCH1                                                  35400017
SETPARM1 MVI   LENGTH,X'12'             SET LENGTH OF MESSAGE      000B 35600017
         LA    WORK,22                  INDICATE MESSAGE                35800017
         STH   WORK,OFFSET                NO JOBS IN SYSTEM             36000017
         MVC   JOBNAME(12),USERNAME     SHIFT MESSAGE                   36200017
         B     MSG                      GO TO SEND OUT MESSAGE          36400017
BLDMSG   L     ENTRY,IHKZZLDM                                      000A 36600017
         BALR  RETURN,ENTRY                                        000A 36800017
         BR    WORK                     RETURN TO CALLER                37000017
JOBNAM   MVC   JOBNAME(8),EXPAN         PUT JOBNAME IN MESSAGE          37200017
         LA    PARA,JOBNAME             SET PARAMETER FOR SEARCH        37400017
         L     ENTRY,IHKZZSCH                                      000A 37600017
         BALR  RETURN,ENTRY                                        000A 37800017
         LTR   ENTRY,ENTRY              CHECK FOR JOB FOUND             38000017
         BP    SETPARM3                 GO TO SET PARAMS FOR IHKCBLDM   38200017
         LR    FASTBASE,PARA            SET REGISTER FOR FASTABLE BASE  38400017
         USING FASTAB,FASTBASE                                          38600017
         CLC   USERNAME(3),FASTUSE      IS REQUESTOR THE ORIGINATOR     38800017
         BNE   ALT                      IF NOT, CHECK ALTERNATE         39000017
VALID    LA    ENTRY,IHKCFSTB           GO TO ROUTINE TO CHECK STATUS   39200017
         ST    PARA,LIST                                           000A 39400017
         LA    PARA,LIST                                           000A 39600017
         BALR  RETURN,ENTRY                                             39800017
         LA    PARA,TADDR                                               40000017
         BAL   WORK,BLDMSG              GO TO BUILDMSG ROUTINE          40200017
         B     GOOD                                                     40400017
ALT      CLC   USERNAME(3),FASTALT      IS REQUESTOR THE ALTERNATE      40600017
         BE    VALID                    IF SO, CHECK STATUS             40800017
SETPARM2 LA    WORK,21                  INSERT OFFSET FOR INVALID       41000017
JOIN     STH   WORK,OFFSET               RECEIVER OF A PARTICULAR JOB   41200017
         MVI   LENGTH,X'1C'             INSERT CORRECT LENGTH      000B 41400017
MSG      LA    PARA,ADTDIR              PASS PARAMETER LIST ADDRESSES   41600017
         BAL   WORK,BLDMSG              GO TO BUILD MESSAGE             41800017
         B     GOOD                     GO TO SET RETURN CODE           42000017
PRESET   MVC   JOBNAME(8),TERMNAME      MOVE TERMNAME INTO MESSAGE 000A 42200017
SETPARM3 LA    WORK,22                  INSERT OFFSET FOR NO JOB IN SYS 42400017
         B     JOIN                                                     42600017
TERMINAL MVC   TERMNAME(8),TDIRTERM     GET TERMINAL IDENTIFICATION     42800017
         DROP  TDIRBASE                                                 43000017
         L     UDIRBASE,IHKZZUDR                                   000A 43200017
         L     WORK,IHKZZUNB                                       000A 43400017
         LH    CTR,0(WORK)              LOAD NUMBER OF ENTRIES          43600017
         L     WORK,IHKZZULN                                       000A 43800017
         LH    LENG,0(WORK)             GET LENGTH CONSTANT             44000017
         USING UDIREC,UDIRBASE                                          44200017
COMPARE  CLC   TERMNAME(8),UDIRTERM     WERE USERS ON THE SAME TERMINAL 44400017
         BNE   BELOW                    IF NOT DO NOT SEARCH FOR JOBS   44600017
         XC    SGNLIST(4),SGNLIST       BEGIN SEARCH AT TOP OF FAST000B 44800017
         MVC   SOURCE(3),UDIRUSID       ASK FOR ALL OF REQUESTOR'S JOBS 45000017
         MVC   DEST(3),UDIRUSID         INDICATE USER AS REQUESTOR      45200017
         BAL   INDEX,SEARCH1            GO TO GENERAL SEARCH            45400017
BELOW    AR    UDIRBASE,LENG            UPDATE POINTER IN UDIR          45600017
         BCT   CTR,COMPARE              IF NOT END, GO BACK             45800017
         LTR   SW,SW                    DOES ERROR MESSAGE GO OUT       46000017
         BZ    PRESET                                              000A 46200017
GOOD     XR    ENTRY,ENTRY              SET GOOD RETURN CODE            46400017
OUT      L     SAVE,SAVE1+4                                             46600017
         RETURN (14,12),T,RC=(15)                                       46800017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 47000017
*                                                                    *  47200017
*                S T A T U S   S U B R O U T I N E                    * 47400017
*                                                                    *  47600017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 47800017
IHKCFSTB STM   RETURN,BASE,12(SAVE)     SAVE REGISTERS                  48000017
         USING IHKCFSTB,ENTRY           TEMPORARY BASE                  48200017
         L     BASE,ADBASE              RESTORE PROGRAM BASE            48400017
         DROP  ENTRY                                                    48600017
         L     VCONBASE,4(PARA)                                    000A 48800017
         ST    SAVE,SAVEAREA+4          SAVE CALLER'S SAVEAREA ADDR     49000017
         LA    WORK,SAVEAREA            EXCHANGE SAVEAREA ADDRS         49200017
         ST    WORK,8(SAVE)                                             49400017
         LR    SAVE,WORK                                                49600017
         LA    WORK,39                 INITIALIZE QUEUE NUMBER     000B 49800017
         ST    WORK,QCR                 IN PARAMETER AREA          000B 50000017
         L     FASTBASE,0(PARA)                                    000A 50200017
         MVC   U,FASTUSE                PUT ORIGINATOR'S ID IN MESSAGE  50400017
         CLI   FASTALT,X'00'                                       000A 50600017
         BE    MVBLANKS                                            000A 50800017
         MVC   A,FASTALT                PUT ALTERNATE'S ID IN MESSAGE   51000017
         B     STAALT                                              000A 51200017
MVBLANKS MVC   A,BLANKS                                            000A 51400017
STAALT   DS    0H                                                  000A 51600017
         MVC   J,FASTNAME               PUT JOBNAME IN MESSAGE          51800017
         TM    FASTDSB,X'90'            IS JOB COMPLETE-NORM OR ABNORM  52000017
         BM    NORM                     COMPLETE AND NORMAL END         52200017
         BO    ABNORM                   COMPLETE AND ABNORMAL END       52400017
         SR    WORK,WORK                OTHERWISE GO TO O/S JOB QUEUE   52600017
         ST    WORK,INFOAREA                                            52800017
TRYMOR   CLI   QCR+3,54                IF ALL JOB QUEUES,          000B 53000017
         BNL   HOLDQ                    TEST THE HOLD QUEUE        000B 53200017
         CLI   QCR+3,1                 IF HOLD QUEUE CHECKED,      000B 53400017
         BE    EXEC                     SAY JOB IS EXECUTING       000B 53600017
         LA    PARA,DUMECB             GO TO DISPATCHER            000B 53800017
         L     ENTRY,IHKZZDSP           FOR A DUMMY WAIT           000B 54000017
         BALR  RETURN,ENTRY                                        000B 54200017
         L     WORK,QCR                PICK UP QUEUE NUMBER        000B 54400017
         LA    WORK,1(0,WORK)          UPDATE FOR NEXT QUEUE       000B 54600017
         ST    WORK,QCR                PUT IN PARAMETER AREA       000B 54800017
GOSRCH   DS    0H                                                  000B 55000017
         ENQ   MF=(E,IEFALTRA)         ENQ FOR ACCESS TO QUEUE     000B 55200017
         LA    PARA,LOC                 SET IEFLOC PARAMETERS           55400017
         LINK  EP=LOC                                                   55600017
         DEQ   MF=(E,IEFALTRA)          DEQ FROM QMGR'S AREA ON D A     55800017
         LTR   ENTRY,ENTRY              TEST FOR GOOD RETURN            56000017
         BNZ   IOERROR                                                  56200017
         L     WORK,INFOAREA                                            56400017
         LTR   WORK,WORK                WAS JOB FOUND                   56600017
         BZ    TRYMOR                  RETURN TO TEST NEXT QUEUE   000B 56800017
         CVD   WORK,CONVERT             CONVERT JOB POSITION ON QUEUE   57000017
         UNPK  NUMBER,CONVERT           TO DECIMAL THEN CHARACTER       57200017
         OI    NUMBER+3,X'F0'                                           57400017
         MVC   STATE,SC                 PUT SCHEDULED POSITION IN MSG   57600017
         B     PREOUT                                                   57800017
HOLDQ    DS    0H                                                  000B 58000017
         MVI   QCR+3,1                 INDICATE HOLD QUEUE         000B 58200017
         B     GOSRCH                  GO SEARCH HOLD QUEUE        000B 58400017
NORM     MVC   STATE,NO                 NORMAL END IN MESSAGE           58600017
         B     PREOUT                                                   58800017
ABNORM   MVC   STATE,AB                 PUT ABNORMAL END IN MESSAGE     59000017
         B     PREOUT                                                   59200017
EXEC     MVC   STATE,EX                 PUT EXECUTING IN MESSAGE        59400017
PREOUT   LA    PARA,STATE               SET RETURN MSG                  59600017
OUT2     L     SAVE,SAVEAREA+4          RESTORE SAVE ADDR               59800017
         ST    PARA,24(SAVE)                                            60000017
         RETURN (14,12),T                                               60200017
IOERROR  XC    ADTDIR(4),ADTDIR         SET UP PARAMETER LIST      000B 60400017
         LA    WORK,67                  SEND Q MGR MESSAGE              60600017
         STH   WORK,OFFSET                                              60800017
         MVI   LENGTH,X'00'             INDICATE NO PARAMETERS          61000017
         LA    PARA,ADTDIR              SET UP LIST ADDRESS             61200017
         L     ENTRY,IHKZZLDM                                      000A 61400017
         BALR  RETURN,ENTRY                                        000A 61600017
         MVC   STATE,DI                 PUT DISK ERROR IN MESSAGE       61800017
         B     PREOUT                                                   62000017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 62200017
*                                                                     * 62400017
*                        C O N S T A N T S                            * 62600017
*                                                                     * 62800017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 63000017
** ** ** **  I H K C C S G N    P A R A M E T E R  L I S T  ** ** ** ** 63200017
SGNLIST  DS    F                        STARTING ADDRESS OF SEARCH   *  63400017
SOURCE   DS    CL3                      SOURCE PREFIX                 * 63600017
DEST     DS    CL3                      DESTINATION PREFIX            * 63800017
         DC    C'C'                     ASK FOR ANY STATUS            * 64000017
*                                                                     * 64200017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 64400017
*                                                                     * 64600017
** ** ** ** ** IHKCBLDM PARAMETER LIST - RETURN MESSAGE  ** ** ** ** ** 64800017
*                                                                     * 65000017
ADTDIR   DS    F                        TERMINAL ADDRESS              * 65200017
OFFSET   DS    H                        OFFSET TO BE INSERTED         * 65400017
LENGTH   DS    C                        LENGTH TO BE INSERTED         * 65600017
         DC    CL7'STATUS '             OPERATION                  000B 65800017
JOBNAME  DS    CL8                      JOB REQUESTED                 * 66000017
BLANK1   DS    C                                                      * 66200017
USERNAME DS    CL3                      USER REQUESTING JOB(S)        * 66400017
BLANK2   DS    C                                                      * 66600017
SQNUM    DS    CL8                      SEQUENCE NUMBER               * 66800017
*                                                                     * 67000017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 67200017
*                                                                     * 67400017
** ** ** ** ** IHKCBLDM PARAMETER LIST  -  STATUS REPORT ** ** ** ** ** 67600017
*                                                                     * 67800017
TADDR    DS    F                        TDIR ADDRESS                  * 68000017
         DC    X'0030'                  OFFSET                        * 68200017
         DC    X'24'                   LENGTH                        -  68400017
J        DS    CL8                      JOBNAME                       * 68600017
         DC    C' '                                                   * 68800017
U        DS    CL3                      ORIGINATOR                    * 69000017
         DC    C' '                                                   * 69200017
A        DS    CL3                      ALTERNATE                     * 69400017
         DC    C' '                                                   * 69600017
STATE    DS    CL10                     STATUS                        * 69800017
         DC    C' '                                                   * 70000017
SEQ      DS    CL8                      SEQUENC NUMBER                * 70200017
*                                                                     * 70400017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 70600017
*                                                                     * 70800017
LOC      DC    A(J)                     ADDRESS OF JOBNAME              71000017
         DC    A(N)                     ADDRESS OF NUMBER CONSTANT      71200017
         DC    A(QCR)                   ADDRESS OF Q CONTROL RECORD NO. 71400017
         DC    A(INFOAREA)              ADDRESS OF INFORAMTION AREA     71600017
         DC    A(SLOT)                                                  71800017
*                                                                     * 72000017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 72200017
*                                                                     * 72400017
N        DC    F'1'                     1 JOB INDICATED ON LIST         72600017
QCR      DC    F'40'                    JOB QUEUE INDICATED             72800017
INFOAREA DS    4F                       AREA OF RETURN INFORMATION      73000017
SLOT     DS    F                        NO. OF JOBS FOUND RETURNED      73200017
CONVERT  DS    D                        AREA FOR CONVERSION TO DECIMAL  73400017
SAVE1    DS    18F                      SAVE AREA FOR CALLED ROUTINES   73600017
         DS    0F                                                  000B 73800017
DUMECB   DC    X'40000000'             DUMMY POSTED ECB            000B 74000017
IEFALTRA ENQ   (IEFSQCBS,IEFQ1QCB,E,2,SYSTEM),MF=L                      74200017
IEFSQCBS DC    C'SYSIEFSD'              MAJOR NAME                      74400017
IEFQ1QCB DC    C'Q1'                    MINOR NAME                      74600017
BLANKS   DC    C'   '                                              000A 74800017
STALEN   DS    H                                                   000A 75000017
SAVEAREA DS    18F                      SAVE AREA FOR SUBROUTINES       75200017
ADBASE   DC    A(IHKCFSTA)                                              75400017
TERMNAME DS    CL8                                                      75600017
LIST     DS    F                                                   000A 75800017
VCONSAVE DS    F                                                   000A 76000017
         ENTRY IHKCFSTB                                                 76200017
*                                                                     * 76400017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 76600017
*                                                                     * 76800017
EX       DC    C'EXECUTING '            MESSAGE CONSTANTS               77000017
AB       DC    C'ABNORM END'                                            77200017
NO       DC    C'NORMAL END'                                            77400017
SC       DC    C'SCHED '                                                77600017
NUMBER   DS    F                                                        77800017
DI       DC    C'DISK ERROR'                                            78000017
*                                                                       78200017
** ** ** ** ** ** ** ** D U M M Y S E C T I O N S ** ** ** ** ** ** **  78400017
*                                                                     * 78600017
UDIREC   DSECT                                                        * 78800017
UDIRTERM DS    CL8                      TERMINAL IDENTIFIER           * 79000017
UDIRSTAT DS    C                        STATUS OF USER                * 79200017
UDIRUSID DS    CL3                      USER IDENTIFICATION           * 79400017
UDIRUKEY DS    CL3                      USERS KEY                     * 79600017
UDIRTTR  DS    CL3                      TTR ADDRESS OF THIS ENTRY     * 79800017
TERMDIR  DSECT      TERMINAL DIRECTORY DUMMY SECTION                  * 80000017
TDIRTERM DS    CL8                                                    * 80200017
TDIRUSID DS    CL3                                                    * 80400017
TDIRSTAT DS    C                                                      * 80600017
TDIRRB   DS    C                                                      * 80800017
TDIRTTR  DS    CL3                                                    * 81000017
TDIRFQEB DS    CL4                                                    * 81200017
TDIRLQEB DS    CL4                                                    * 81400017
TDIRLMEL DS    CL4                                                    * 81600017
TDIRFORM DS    CL4                                                    * 81800017
FASTAB   DSECT      FAST TABLE DUMMY SECTION                          * 82000017
FASTNAME DS    CL8                                                    * 82200017
FASTJIB  DS    C                                                      * 82400017
FASTJEDT DS    CL3                                                    * 82600017
FASTDSB  DS    C                                                      * 82800017
FASTSSB  DS    C                                                      * 83000017
FASTTTR  DS    CL3                                                    * 83200017
FASTALT  DS    CL3                                                    * 83400017
FASTCNT  DS    C                                                      * 83600017
FASTUSE  DS    CL3                                                    * 83800017
CMDCDS   DSECT      COMMAND CARD DUMMY SECTION                        * 84000017
CARD     DS    CL72                                                   * 84200017
SEQUENCE DS    CL8                                                    * 84400017
         DS    C                                                      * 84600017
CODE     DS    C                                                      * 84800017
EXPAN    DS    CL8                                                    * 85000017
*                                                                     * 85200017
         IHKDSECT ,,,,,AVT                                         000A 85400017
** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** ** 85600017
         END                                                            85800017
