         TITLE 'RJE WARMSTART'                                          00600015
IHKCFWMS CSECT                                                          01200015
*********************************************************************** 01800015
*STATUS- CHANGE LEVEL 0                                               * 02400015
*                                                                     * 03000015
*FUNCTION/OPERATION-                                                  * 03600015
*   AFTER A SYSTEM FAILURE THIS ROUTINE IS LOADED BY RJENIP TO RE-    * 04200015
*   INITIALIZE THE FAST TABLE. THE ACTIVE ENTRIES WILL ACCURATELY     * 04800015
*   REFLECT THE JOBS SUBMITTED BY REMOTE USERS WHICH ARE PRESENT IN   * 05400015
*   THE SYSTEM.                                                       * 06000015
*        1.  IF THE JOB ENTRY IS MARKED INCOMPLETE, IT REPRESENTS AN  * 06600015
*           ENTRY ON THE O/S INPUT QUEUE, OR HOLD QUEUE, OR A JOB ON  * 07200015
*           THE CLASS Z OUTPUT QUEUE WHICH WAS NOT DEQUEUED BEFORE    * 07800015
*           MALFUNCTION. NO ACTION OCCURS WHEN THE ENTRY IS MARKED    * 08400015
*           INCOMPLETE.                                               * 09000015
*        2. IF THE JOB ENTRY IS MARKED COMPLETE, IT REPRESENTS A JOB  * 09600015
*           WHICH PASSED THROUGH THE RJE SYSDEQ ROUTINE PRIOR TO      * 10200015
*           SYSTEM FAILURE. THE BITS SET PREVIOUSLY BY JOBEND AND     * 10800015
*           SYSDEQ TO INDICATE ACTIONS PERFORMED ARE RESET TO INDICATE* 11400015
*           RE-PERFORMANCE IS REQUIRED WHEN NORMAL OPERATIONS RESUME. * 12000015
*           IF BIT 1 OF THE FAST TABLE FASTDSB IS ON, BIT 0 OF THE    * 12600015
*           FASTDSBE IS TURNED ON. LIKEWISE, IF BIT 2 OF THE FASTDSB  * 13200015
*           IS ON, BIT 1 OF THE FASTDSBE IS TURNED ON. ALL BITS OF    * 13800015
*           THE FASTDSB ARE TURNED OFF. BITS 1 AND 2 OF THE FASTDSB   * 14400015
*           INDICATE JOB ENQUEUED FOR DELIVERY TO SOURCE AND ALTERNATE* 15000015
*           RESPECTIVELY. BITS 0 AND 1 OF THE FASTDSBE INDICATE BY-   * 15600015
*           PASSED OUTPUT FOR SOURCE AND ALTERNATELY.                 * 16200015
*                                                                     * 16800015
*ENTRY POINT-                                                         * 17400015
*        IHKCFUMS- THIS IS THE ONLY ENTRY POINT.                      * 18000015
*                                                                     * 18600015
*INPUT                                                                * 19200015
*   UPON ENTRY TO THIS ROUTINE REGISTER 1 POINTS TO AN INPUT PARAMETER* 19800015
*   LIST WHICH IS THE RJE COMMUNICATIONS REGION.                      * 20400015
*                                                                     * 21000015
*OUTPUT-                                                              * 21600015
*   THE FAST TABLE ENTRIES ACCURATELY REFLECT THE RJE MOBS IN THE     * 22200015
*   SYSTEM.                                                           * 22800015
*                                                                     * 23400015
*EXTERNAL ROUTINES- N/A                                               * 24000015
*                                                                     * 24600015
*EXITS-NORMAL-                                                        * 25200015
*   REGISTER 15 CONTAINS A RETURN CODE OF 0.                          * 25800015
*EXITS-ERROR- N/A                                                     * 26400015
*                                                                     * 27000015
*TABLES/WORK AREAS- N/A                                               * 27600015
*                                                                     * 28200015
*ATTRIBUTES-                                                          * 28800015
*   THIS ROUTINE IS NON-RESIDENT AND SERIALLY RE-USABLE.              * 29400015
*                                                                     * 30000015
*NOTES-                                                                 30600015
*   THIS ROUTINE IS NOT DEPENDENT UPON THE EXTERNAL CHARACTER SET USED* 31200015
*********************************************************************** 31800015
PARA     EQU   1                        PARAMETER REGISTER            * 32400015
PARBASE  EQU   2                        PARAMETER LIST DSECT BASE     * 33000015
WORK     EQU   3                                                      * 33600015
CTR      EQU   4                        LOOP CTR FOR FASTABLE SEARCH  * 34200015
INDEX    EQU   5                        INCREMENT THROUGH FASTABLE    * 34800015
ADDR     EQU   6                        ADDRESS OF FASTABLE ENTRY     * 35400015
TEMP     EQU   10                       TEMPORARY HOLDER              * 36000015
BASE     EQU   12                       PROGRAM BASE                  * 36600015
SAVE     EQU   13                       ADDRESS OF CURRENT SAVEAREA   * 37200015
RETURN   EQU   14                       RET0RN ADDRESS HOLDER         * 37800015
ENTRY    EQU   15                       ENTRY POINT ADDRESS           * 38400015
         USING RJECOMM,PARA                                             39000015
         USING FASTAB,ADDR                                              39600015
         STM   RETURN,BASE,12(SAVE)     SAVE REGISTERS                  40200015
         BALR  BASE,0                   ESTABLISH PROGRAM BASE          40800015
         USING *,BASE                                                   41400015
         ST    SAVE,SAVEAREA+4          SAVE CALLERS SAVEAREA ADDRESS   42000015
         LA    WORK,SAVEAREA            GET PRESENT SAVEAREA ADDRESS    42600015
         ST    WORK,8(SAVE)             BACK CHAIN ADDRESS              43200015
         LR    SAVE,WORK                SET UP FOR CALLED PROGRAMS      43800015
*                                                                       44400015
*        END OF STANDARD ENTRY LINKAGE                                  45000015
*                                                                       45600015
         LR    PARBASE,PARA             SET UP PARAMETER DSECT BASE     46200015
         L     WORK,COMMFNB             INITIALIZE LOOP TO NO. ENTRIES  46800015
         LH    CTR,0(WORK)                                              47400015
         L     WORK,COMMFLN             GET FASTABLE LENGTH FOR UPDATE  48000015
         LH    INDEX,0(WORK)                                            48600015
         L     ADDR,COMMFTB             INITIALIZE SEARCH OF FASTABLE   49200015
LOOP     CLI   FASTNAME,C' '            IS ENTRY ACTIVE                 49800015
         BE    BELOW                    UPDATE POINTER AND CONTINUE     50400015
         TM    FASTDSB,X'80'            IS JOB COMPLETE                 51000015
         BZ    BELOW                                                    51600015
         TM    FASTDSB,X'40'            IS JOB ENQUEUED FOR SOURCE      52200015
         BZ    X                        IF NOT CHECK ALTERNATE          52800015
         OI    FASTDSBE,X'80'           TURN ON BYPASSED FOR SOURCE     53400015
         B     XX                       RESUME PROCESS                  54000015
X        TM    FASTDSBE,X'20'           IS JOB ENQUEUED FOR ALTERNATE   54600015
         BZ    XX                       IF NOT CONTINUE PROCESS         55200015
         OI    FASTDSBE,X'40'           TURN ON BYPASSED FOR ALTERNATE  55800015
XX       NI    FASTDSB,X'00'            ZERO DSB BITS                   56400015
BELOW    AR    ADDR,INDEX               INCREMENT POINTER IN FASTABLE   57000015
         BCT   CTR,LOOP                                                 57600015
         XR    ENTRY,ENTRY              NORMAL RETURN                   58200015
         L     SAVE,SAVEAREA+4                                          58800015
         RETURN (14,12),T,RC=(15)                                       59400015
SAVEAREA DS    3F                       PROGRAM SAVEAREA              * 60000015
FASTAB   DSECT                                                        * 60600015
FASTNAME DS    CL8                      JOBNAME FROM JCL JOB CARD     * 61200015
FASTJIB  DS    C                        JOB INFORMATION BYTE          * 61800015
FASTJEDT DS    CL3                      ADDRESS OF JED TABLE          * 62400015
FASTDSB  DS    C                        DELIVERY STATUS BYTE          * 63000015
FASTDSBE DS    C                        DELIVERY STATUS BYTE EXTENDED * 63600015
FASTTTR  DS    CL3                      ADDRESS OF DISC FASTABLE ENTRY* 64200015
FASTALT  DS    CL3                      ALTERNATE RECEIVER IDENT      * 64800015
FASTCNT  DS    C                        COUNT OF RJE CLOSEDOWNS       * 65400015
FASTUSE  DS    CL3                      SOURCE USER IDENTIFICATION    * 66000015
RJECOMM  DSECT                                                          66600015
COMMJLN  DS    F                   ADDRESS OF IHKCDJLN                  67200015
COMMSDQS DS    F                   STOP ACK ECB FOR SYSDEQ              67800015
COMMEDAD DS    F                   ADDRESS OF READERS ENTRY POINT THAT  68400015
*                                  WILL ENTER EODAD ROUTINE.            69000015
COMMDISP DS    F                   ADDRESS OF IHKAADSP                  69600015
COMMSWT  DS    C                   RJE COMMUNICATION SWITCHES           70200015
COMMCSCB DS    F                   CSCB ADDRESS                         70800015
COMMSLOT DS    F                   CENTRAL COMMANDS ECB SLOT IN DISP.   71400015
COMMICAM DS    F                   RJE READER ENTRY POINT               72000015
COMMEDIT DS    F                   RJE JCL EDIT ENTRY POINT             72600015
COMMNEL  DS    F                   NEL PASSED OT OS R/I                 73200015
COMMLLN  DS    F                   ADDRESS OF IHKCDLLN                  73800015
COMMLNB  DS    F                   ADDRESS OF IHKCDLNB                  74400015
COMMLNT  DS    F                   ADDRESS OF IHKCDLNT                  75000015
COMMROLL DS    0F                  PARAMETERS FOR ROLL-IN, ROLL-OUT,    75600015
*                                  AND WARMSTART.                       76200015
COMMFES  DS    F                   ADDRESS OF IHKCDFES                  76800015
COMMFMR  DS    F                   ADDRESS OF IHKCDFMR                  77400015
COMMCMR  DS    F                   ADDRESS OF IHKCDCMR                  78000015
COMMOMR  DS    F                   ADDRESS OF IHKCDOMR                  78600015
        DS     F                                                        79200015
COMMFTB  DS    F                   ADDRESS OF IHKCDFTB                  79800015
COMMFLN  DS    F                   ADDRESS OF IHKCDFLN                  80400015
COMMFNB  DS    F                   ADDRESS OF IHKCDFNB                  81000015
COMMUDR  DS    F                   ADDRESS OF IHKCDUDR                  81600015
COMMULN  DS    F                   ADDRESS OF IHKCDULN                  82200015
COMMUNB  DS    F                   ADDRESS OF IHKCDUNB                  82800015
COMMTDR  DS    F                   ADDRESS OF IHKCDTDR                  83400015
COMMTLN  DS    F                   ADDRESS OF IHKCDTLN                  84000015
COMMTNB  DS    F                   ADDRESS OF IHKCDTNB                  84600015
         END                                                            85200015
