ALT      TITLE 'ALERT'                                                  00200017
IHKCGALT CSECT                                                          00400017
*2801330000,350000,424000,492000,574000,650000,660000,680000,      000A 00600017
*2801690000                                                        000A 00800017
*0790378000-380000,396000,422000,456000-458000,510000,546000-548000000B 01000017
*0790568000,594000                                                 000B 01200017
*0790686000-720000                                                 000B 01400017
*0790016000                                                        000B 01600017
*********************************************************************** 01800017
*                                                                     * 02000017
*TITLE 'IHKCGALT'-ALERT                                               * 02200017
*STATUS - CHANGE LEVEL 2                                           000B 02400017
*FUNCTION/OPERATION:                                                  * 02600017
*   THIS ROUTINE PROCESSES THE ALERT COMMAND. THE FOLLOWING ALERT     * 02800017
*   REQUESTS ARE ACTED UPON BY THIS ROUTINE:                          * 03000017
*                                                                     * 03200017
*   1- ALERT FOR A SPECIFIC JOB (SPECIFIC ALERT). THIS FORM OF THE    * 03400017
*   ALERT COMMAND IS A REQUEST TO BE ALERTED WHEN A SPECIFIC JOB      * 03600017
*   COMPLETES (FOR WHICH THE ALERT SUBMITTER IS A VALID RECIPIENT).   * 03800017
*   USING THE JOBNAME AS A SEARCH ARGUMENT, A SEARCH IS MADE OF THE   * 04000017
*   FAST TABLE. IF THE JOB IS NOT FOUND, A 'JOB NOT IN SYSTEM'        * 04200017
*   RESPONSE IS GIVEN. IF THE JOB IS COMPLETE, THE USER RECEIVES      * 04400017
*   EITHER AN 'INVALID RECEIVER' MESSAGE, IF HE IS NOT A VALID RE-    * 04600017
*   CIPIENT OF THE OUTPUT, OR AN ALERT MESSAGE WITH ANY USER NOTIFY   * 04800017
*   INFORMATION APPENDED. IF THE USER IS A VALID RECIPIENT AND THE    * 05000017
*   JOB IS INCOMPLETE, THE USER RECEIVES A 'JOB NOT COMPLETE' MESSAGE * 05200017
*   AND EITHER THE 'SPECIFIC ALERT SOURCE' BIT IN FASTJIB (FAST TABLE * 05400017
*   JOB INFORMATION BYTE) IF THE ALERT SUBMITTER ORIGINATED THE JOB,  * 05600017
*   OR THE 'SPECIFIC ALERT ALTERNATE' BIT IN FASTJIB, IF THE ALERT    * 05800017
*   SUBMITTER IS THE DESIGNATED ALTERNATE, IS SET. THE PROPER ALERT   * 06000017
*   RESPONSE CAN THEN BE INITIATED AT JOB COMPLETION WHEN THESE BITS  * 06200017
*   ARE CHECKED.                                                      * 06400017
*                                                                     * 06600017
*   2- USER REQUESTS TO BE ALERTED WHEN ANY JOB SUBMITTED BY HIM      * 06800017
*   COMPLETES (MINOR ALERT).                                          * 07000017
*                                                                     * 07200017
*   (A) IF ANY COMPLETED JOBS BY THIS USER (WHOSE OUTPUT HAS NOT      * 07400017
*   PREVIOUSLY BEEN DELIVERED TO HIM, AND FOR WHICH HE HAS NOT PRE-   * 07600017
*   VIOUSLY RECEIVED A NOTIFY MESSAGE) RESIDE IN THE SYSTEM, THE      * 07800017
*   IMMEDIATE RESPONSE IS AN ALERT MESSAGE (FOR EACH JOB) WITH ANY    * 08000017
*   USER NOTIFY INFORMATION APPENDED.                                 * 08200017
*                                                                     * 08400017
*   (B) IN ORDER TO KEEP THE REQUEST PENDING IN THE SYSTEM, THE       * 08600017
*   'MINOR ALERT' BIT IN USERSTAT (USER DIRECTORY USER STATUS) IS SET * 08800017
*   FOR THIS USER. WHENEVER ANY JOB ORIGINATED BY THIS USER COMPLETES,* 09000017
*   THIS BIT IS CHECKED AND, IF IT IS ON, THE APPROPRIATE ALERT MES-  * 09200017
*   SAGE IS ISSUED AT THIS TIME.                                      * 09400017
*                                                                     * 09600017
*   (C) IF THERE ARE NO COMPLETE JOBS ORIGINATED BY THE ALERT SUBMIT- * 09800017
*   TER (SAME CONDITIONS AS (A) ABOVE) RESIDING IN THE SYSTEM, THE    * 10000017
*   ALERT SUBMITTER RECEIVES A 'JOB(S) NOT COMPLETE' MESSAGE TO       * 10200017
*   INDICATE THAT THE ALERT WAS PROCESSED AND THE ALERT REMAINS       * 10400017
*   PENDING AS ABOVE.                                                 * 10600017
*                                                                     * 10800017
*   3- USER REQUESTS TO BE ALERTED WHEN ANY JOB COMPLETES FOR WHICH   * 11000017
*   HE IS A VALID RECIPIENT OF ITS OUTPUT (MAJOR ALERT).              * 11200017
*                                                                     * 11400017
*   (A) IF ANY COMPLETED JOBS FOR WHICH FOR WHICH THE SUBMITTER IS A  * 11600017
*   VALID RECIPIENT OF ITS OUTPUT (WHOSE OUTPUT HAS NOT PREVIOUSLY    * 11800017
*   BEEN DELIVERED TO HIM, AND FOR WHICH HE HAS NOT PREVIOUSLY BEEN   * 12000017
*   NOTIFIED OR ALERTED, RESIDE IN THE SYSTEM, THE IMMEDIATE RESPONSE * 12200017
*   IS AN ALERT MESSAGE (FOR EACH JOB) WITH ANY USER NOTIFY INFORMA-  * 12400017
*   TION APPENDED.                                                    * 12600017
*                                                                     * 12800017
*   (B) THE ALERT IS KEPT PENDING IN THE SYSTEM BY SETTING THE 'MAJOR * 13000017
*   ALERT' BIT IN UDIRSTAT (USER DIRECTORY USER STATUS FOR THIS USER. * 13200017
*                                                                     * 13400017
*   (C) IF NO COMPLETE JOBS FOR WHICH THE ALERT SUBMITTER IS A VALID  * 13600017
*   RECIPIENT OF ITS OUTPUT RESIDE IN THE SYSTEM, THE 'JOB(S) NOT     * 13800017
*   COMPLETE' MESSAGE IS GIVEN AND THE ALERT REMAINS PENDING IN THE   * 14000017
*   SYSTEM AS IN (B) ABOVE.                                           * 14200017
*                                                                     * 14400017
*   4- USER REQUESTS TO CANCEL ANY PENDING ALERTS ISSUED BY HIM       * 14600017
*   (ALERT CANCEL).                                                   * 14800017
*                                                                     * 15000017
*   (A) THE 'MAJOR ALERT' AND 'MINOR ALERT' BITS IN THE USER DIRECT-  * 15200017
*   ORY ARE TURNED OFF FOR THIS USER.                                 * 15400017
*                                                                     * 15600017
*   (B) ALL 'SPECIFIC ALERT' REQUESTS FOR JOBS WITH OUTPUT FOR THIS   * 15800017
*   USER ARE CANCELLED, IF THE ALERT SUBMITTER ORIGINATED THE JOB,    * 16000017
*   THE 'ALERT SOURCE' BIT IN FASTJIB (FAST TABLE JOB INFORMATION     * 16200017
*   BYTE) IS TURNED OFF. IF THE ALERT SUBMITTER IS THE DESIGNATED     * 16400017
*   ALTERNATE, THE 'ALERT ALTERNATE' BIT IN FASTJIB IS TURNED OFF.    * 16600017
*                                                                     * 16800017
*   (C) AN 'ALERTS CANCELLED' MESSAGE IS ISSUED FOR EACH ALERT CANCEL * 17000017
*   COMMAND PROCESSED.                                                * 17200017
*                                                                     * 17400017
*ENTRY POINTS:                                                        * 17600017
*        IHKCGALT IS CALLED TO PROCESS THE ALERT COMMAND. DATA IS     * 17800017
*   PASSED BY NAME AS IN THE FOLLOWING CALLING SEQUENCE:              * 18000017
*        LA 1,PARALIST                                                * 18200017
*        CALL IHKCGALT                                                * 18400017
*                                                                     * 18600017
*INPUT:                                                               * 18800017
*   REGISTER 1 POINTS TO THE ADDRESS VECTOR TABLE WHOSE DESCRIPTION000A 19000017
*   APPEARS BEFORE THE EXPANSION OF THE DSECT IHKZZAVT.            000A 19200017
*                                                                     * 19400017
*OUTPUT:                                                              * 19600017
*   OUTPUT FROM THIS ROUTINE IS A MESSAGE TO THE COMMAND SUBMITTER    * 19800017
*   ALERTING HIM OF COMPLETE JOBS OR A MESSAGE INDICATING THE STATUS  * 20000017
*   OF THE ALERT COMMAND. IF ANY CHANGES HAVE BEEN MADE IN BIT SET-   * 20200017
*   TINGS IN FAST TABLE OR THE USER DIRECTORY, THE NEW TABLES ARE     * 20400017
*   WRITTEN OUT ON DISK.                                              * 20600017
*                                                                     * 20800017
*EXTERNAL ROUTINES:                                                   * 21000017
*        IHKCDSCH-SEARCH FASTAB FOR PARTICULAR JOBNAME                * 21200017
*        IHKCDJMR-READ USER NOTIFY INFORMATION FROM DISK TO CORE      * 21400017
*        IHKCDUMR-WRITE UPDATED USER DIRECTORY ONTO DISK              * 21600017
*        IHKCDFMR-WRITE UPDATED FAST TABLE ONTO DISK                  * 21800017
*        IHKCBLDM-BUILD SYSTEM MESSAGES                               * 22000017
*        IHKCCSGN-SEARCH FAST TABLE FOR UNDELIVERED OUTPUT            * 22200017
*        IHKCCSUD-SEARCH USER DIRECTORY FOR USER ENTRY                * 22400017
*                                                                     * 22600017
*EXITS-NORMAL:                                                        * 22800017
*   NORMAL RETURN IS VIA REGISTER 14 TO THE CALLING ROUTINE. A RETURN * 23000017
*   CODE OF ZERO IS PASSED IN REGISTER 15.                            * 23200017
*                                                                     * 23400017
*EXITS-ERROR: N/A                                                     * 23600017
*                                                                     * 23800017
*TABLES/WORK AREAS:                                                   * 24000017
*   A 98 BYTE WORK AREA IS USED TO RECEIVE THE ENTRY FROM JEDTAB      * 24200017
*   WHICH CONTAINS THE USER NOTIFY INFORMATION.                       * 24400017
*                                                                     * 24600017
*ATTRIBUTES: SERIALLY REUSABLE, NON-RESIDENT                       000A 24800017
*                                                                     * 25000017
*NOTES:                                                               * 25200017
*   THE OPERATION OF THIS ROUTINE DEPENDS UPON AN INTERNAL REPRESEN-  * 25400017
*   TATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE   * 25600017
*   ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED SO THAT   * 25800017
*   REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT * 26000017
*   IN A CORRECT MODULE FOR THE NEW DEFINITIONS.                      * 26200017
*                                                                     * 26400017
*********************************************************************** 26600017
*                                                                       26800017
*              REGISTER ASSIGNMENTS                                     27000017
*                                                                       27200017
PARREG0  EQU   0                       PARAMETER REGISTER               27400017
PARREG   EQU   1                       PARAMETER LIST REGISTER          27600017
VCONBASE EQU   4                                                   000A 27800017
USERBSE  EQU   5                       BASE FOR USER DIRECTORY          28000017
WORK     EQU   6                       GENERAL WORKING REGISTER         28200017
MSGR     EQU   8                       MESSAGE REGISTER FOR CANCEL      28400017
PARREGA  EQU   9                       AUXILIARY PARAMETER REGISTER     28600017
TRMBASE  EQU   10                      BASE FOR TDIR DUMMY SECTION      28800017
CDBASE   EQU   11                      BASE FOR DCARD DUMMY SECTION     29000017
BASE     EQU   12                      BASE REGISTER FOR MODULE         29200017
SAVREG   EQU   13                      SAVE AREA REGISTER               29400017
RETREG   EQU   14                      RETURN REGISTER                  29600017
ENTREG   EQU   15                      ENTRY POINT REGISTER             29800017
*                                                                       30000017
         SAVE  (14,12),,*                                               30200017
         BALR  BASE,0                  ESTABLISH ADDRESSABILITY         30400017
         USING *,BASE                  *                                30600017
         USING IHKZZAVT,VCONBASE                                   000A 30800017
         LR    VCONBASE,PARREG                                     000A 31000017
         LA    WORK,ALTSAVE            CHAIN SAVE AREAS                 31200017
         ST    SAVREG,4(WORK)          *                                31400017
         ST    WORK,8(SAVREG)          *                                31600017
         LR    SAVREG,WORK             ADDRESS OF ACTIVE SAVE AREA      31800017
         NI    SWITCH,X'00'            INITIALIZE SWITCHES              32000017
         L     CDBASE,4(PARREG)        ADDRESSABILITY FOR CARD IMAGE    32200017
         USING DCARD,CDBASE             DUMMY SECTION                   32400017
         ST    CDBASE,CRDADR           SAVE ADDRESS OF CARD IMAGE       32600017
         L     TRMBASE,0(PARREG)       ADDRESSABILITY FOR TERMINAL      32800017
         USING TDIREC,TRMBASE           DIRECTORY DUMMY SECTION         33000017
         ST    TRMBASE,TERMID          SAVE TERMINAL ENTRY              33200017
         MVC   USERID(3),TDIRUSID      GET USER FOR THIS TERMINAL       33400017
         MVI   USERID+3,C' '           PAD TO THE RIGHT WITH BLANK      33600017
         DROP  TRMBASE                                                  33800017
         CLI   CMDID,C'J'              IF CODE IS J, GO TO THE SPECIFIC 34000017
         BE    JOBNAME                  ALERT ROUTINE                   34200017
         L     PARREG,USERID           PARAMETERS FOR SEARCH OF USER    34400017
         L     ENTREG,IHKZZSUD                                     000A 34600017
         BALR  RETREG,ENTREG                                       000A 34800017
         ST    PARREG,USERADR          SAVE ADDRESS OF DIRECTORY ENTRY  35000017
         CLI   CMDID,C'/'              IF CODE IS NOT SLASH,            35200017
         BNE   ALTCOMN                  GO TO ALERT ROUTINE             35400017
         USING UDIREC,PARREG           ADDRESSABILITY FOR UDIR          35600017
         NI    UDIRSTAT,X'9F'          CLEAR ALERT BITS IN DIRECTORY    35800017
         DROP  PARREG                                                   36000017
         XC    PARA(7),PARA            SET PARAMETERS FOR SEARCH FOR    36200017
         MVC   PARA+7(3),USERID         JOBS FOR USER                   36400017
CONSRCH  LA    PARREG,PARA             ADDRESS OF PARAMETER LIST        36600017
         L     ENTREG,IHKZZSGN                                     000A 36800017
         BALR  RETREG,ENTREG                                       000A 37000017
         LTR   ENTREG,ENTREG           IF NO JOB FOUND,                 37200017
         BNZ   CNLMSG                   ISSUE CANCEL MESSAGE            37400017
         LR    PARREGA,PARREG          SAVE POINTER TO FASTAB ENTRY     37600017
         USING FASTAB,PARREG                                            37800017
         CLC   FASTUSE,USERID          IF USER IS NOT SOURCE, BRANCH TO 38000017
         BNE   CNALT                    TEST FOR ALTERNATE              38200017
         NI    FASTJIB,X'FB'           CANCEL SPECIFIC ALERT FOR SOURCE 38400017
CNLRET   DS    0H                                                  000B 38600017
         LA    PARREG,FTL(PARREG)      UPDATE SEARCH POINTER            38800017
         ST    PARREG,PARA             *                                39000017
         B     CONSRCH                                                  39200017
*                                                                       39400017
CNALT    NI    FASTJIB,X'FD'           CANCEL ALERT FOR ALTERNATE       39600017
         B     CNLRET                                                   39800017
         DROP  PARREG                                                   40000017
CNLMSG   DS    0H                                                  000B 40200017
         LA    WORK,37                 INDICATE 'ALERT CANCELLED'       40400017
         STH   WORK,MSGPARA+4           MESSAGE                         40600017
         LA    WORK,12                  LENGTH                          40800017
         STC   WORK,MSGPARA+6           *                               41000017
         MVC   MSGPARA+7(4),USERID      USER                            41200017
         MVC   MSGPARA+11(8),SEQ        SEQUENCE NUMBER OF MESSAGE      41400017
         MVC   MSGPARA(4),TERMID                                        41600017
         B     SENDMSG                                                  41800017
*                                                                       42000017
ALTCOMN  OI    SWITCH,X'80'            INDICATE ENTERED MAJOR ALERT RTN 42200017
         LR    USERBSE,PARREG          ADDRESSABILITY FOR USER DIRECT-  42400017
         USING UDIREC,USERBSE           ORY DUMMY SECTION               42600017
         XC    PARA(7),PARA            PREPARE PARAMETER LIST FOR       42800017
         MVC   PARA+7(3),USERID         SEARCH OF FASTAB                43000017
         CLI   CMDID,C'*'              IF IDENTIFIER IS NOT ASTERISK,   43200017
         BNE   MINORALT                 SET MINOR ALERT PARAMETERS      43400017
         OI    UDIRSTAT,X'20'          SET MAJOR ALERT INDICATOR ON     43600017
SRCHGN1  LA    PARREG,PARA             ADDRESS OF PARAMETER LIST        43800017
         L     ENTREG,IHKZZSGN                                     000A 44000017
         BALR  RETREG,ENTREG                                       000A 44200017
         LTR   ENTREG,ENTREG           IF JOB NOT FOUND,                44400017
         BNZ   EXITRTN                   BRANCH TO EXIT ROUTINE         44600017
         LR    PARREGA,PARREG          SAVE POINTER TO FASTAB ENTRY     44800017
         USING FASTAB,PARREG           ADDRESS FASTAB DUMMY SECTION     45000017
         CLC   FASTUSE,USERID          IF USER IS NOT SOURCE, BRANCH TO 45200017
         BNE   JOBALT                   ALTERNATE ROUTINE               45400017
         OI    FASTDSB,X'08'           INDICATE SOURCE ALERTED          45600017
RTRN1    BAL   WORK,MSGPREP            ALERT USER                       45800017
         LA    PARREG,FTL(PARREGA)     UPDATE SEARCH POINTER            46000017
         ST    PARREG,PARA             *                                46200017
         NI    SWITCH,X'7F'            TURN JOB FOUND SWITCH OFF        46400017
         B     SRCHGN1                                                  46600017
JOBALT   OI    FASTDSB,X'04'           INDICATE ALTERNATE ALERTED       46800017
         B     RTRN1                                                    47000017
         DROP  PARREG                                                   47200017
MINORALT MVC   PARA+4(3),USERID        INDICATE MINOR ALERT SEARCH      47400017
         OI    UDIRSTAT,X'40'          TURN ON MINOR ALERT INDICATOR    47600017
         B     SRCHGN1                 *                                47800017
EXITRTN  TM    SWITCH,X'80'            IF JOB FOUND SWITCH IS OFF,      48000017
         BZ    RETURN                   NO MESSAGE IS SENT              48200017
         LA    WORK,18                 *                                48400017
         STC   WORK,MSGPARA+6          *                                48600017
         CLI   CMDID,C'*'              IF MAJOR ALERT,                  48800017
         BO    BLNKOUT                  THERE IS NO USER ID             49000017
         MVC   MSGPARA+13(4),USERID    *                                49200017
BLNKRTN  MVC   MSGPARA+17(8),SEQ       *                                49400017
PREPMSG  MVC   MSGPARA+7(6),ALERTN     ROUTINE NAME                     49600017
         LA    WORK,22                 INDICATE 'NO JOB(S) IN SYSTEM'   49800017
         STH   WORK,MSGPARA+4           MESSAGE                         50000017
         MVC   MSGPARA(4),TERMID       SET UP PARAMETER LIST FOR MSG    50200017
SENDMSG  LA    PARREG,MSGPARA          *                                50400017
         L     ENTREG,IHKZZLDM                                     000A 50600017
         BALR  RETREG,ENTREG                                       000A 50800017
RETURN   L     SAVREG,4(SAVREG)        RETURN TO CALLING ROUTINE        51000017
         RETURN (14,12),T,RC=0         *                                51200017
*                                                                       51400017
*                                                                       51600017
JOBNAME  LA    PARREG,JBNAME           POINTER TO JOB NAME              51800017
         L     ENTREG,IHKZZSCH                                     000A 52000017
         BALR  RETREG,ENTREG           JOBNAME                          52200017
         LTR   ENTREG,ENTREG           IF NO JOB FOUND,                 52400017
         BNZ   NOJOBMSG                 PRINT MESSAGE TO THIS EFFECT    52600017
         LR    PARREGA,PARREG          SAVE POINTER TO FASTAB ENTRY     52800017
         USING FASTAB,PARREG           ADDRESSABILITY FOR FASTAB        53000017
         TM    FASTDSB,X'80'           IF JOB NOT COMPLETE,             53200017
         BZ    INCOMPLT                  BRANCH TO SET INDICATORS       53400017
         CLC   FASTUSE,USERID          IF USER NOT SOURCE,              53600017
         BNE   TESTALT                  TEST FOR VALID ALTERNATE        53800017
         OI    FASTDSB,X'08'           INDICATE SOURCE ALERTED          54000017
ALTMSG   BAL   WORK,MSGPREP            ALERT SOURCE                     54200017
         B     RETURN                                                   54400017
TESTALT  CLC   FASTALT,USERID          IF USER IS NOT VALID ALTERNATE,  54600017
         BNE   NOTVAL                   INFORM HIM OF FACT              54800017
         OI    FASTDSB,X'04'           INDICATE ALTERNATE NOTIFIED      55000017
         B     ALTMSG                                                   55200017
INCOMPLT CLC   FASTUSE,USERID          IF USER IS NOT SOURCE,           55400017
         BNE   TESTALT2                 TEST FOR VALID RECEIVER         55600017
         OI    FASTJIB,X'04'           INDICATE SPECIFIC ALERT SOURCE   55800017
         DROP  PARREG                                                   56000017
JBNCRET  DS    0H                                                  000B 56200017
         LA    WORK,23                 INDICATE 'JOB NOT COMPLETE '     56400017
         STH   WORK,MSGPARA+4           MESSAGE TO BE SENT              56600017
MSGCOMN  MVC   MSGPARA(4),TERMID       SET MESSAGE PARAMETERS           56800017
         LA    WORK,21                 *                                57000017
         STC   WORK,MSGPARA+6          *                                57200017
         MVC   MSGPARA+7(8),JBNAME     *                                57400017
         MVI   MSGPARA+15,C' '         *                                57600017
         MVC   MSGPARA+16(4),USERID    *                                57800017
         MVC   MSGPARA+20(8),SEQ       SEQUENCE NUMBER                  58000017
         LA    PARREG,MSGPARA          ADDRESS OF PARAMETER LIST        58200017
         L     ENTREG,IHKZZLDM                                     000A 58400017
         BALR  RETREG,ENTREG                                       000A 58600017
         B     RETURN                                                   58800017
         USING FASTAB,PARREG                                            59000017
TESTALT2 CLC   FASTALT,USERID          IF USER NOT VALID RECEIVER,      59200017
         BNE   NOTVAL                   BRANCH TO MSG ROUTINE           59400017
         OI    FASTJIB,X'02'           SET SPECIFIC ALERT ALTERNATE BIT 59600017
         B     JBNCRET                                                  59800017
*                                                                       60000017
NOTVAL   LA    WORK,21                 INDICATE 'INVALID RECEIVER' MSG  60200017
         STH   WORK,MSGPARA+4          AND GO TO ROUTINE TO BUILD MSG   60400017
         B     MSGCOMN                  PARAMETERS FOR OUTPUT           60600017
*                                                                       60800017
NOJOBMSG LA    WORK,27                 'NO JOB(S)' MESSAGE              61000017
         STC   WORK,MSGPARA+6           *                               61200017
         MVC   MSGPARA+13(8),JBNAME     JOB NAME                        61400017
         MVI   MSGPARA+21,C' '                                          61600017
         MVC   MSGPARA+22(4),USERID     USER                            61800017
         MVC   MSGPARA+26(8),SEQ        SEQUENCE NUMBER                 62000017
         B     PREPMSG                                                  62200017
*                                                                       62400017
MSGPREP  MVC   MSGPARA(4),TERMID       PREPARE PARAMETERS FOR MESSAGE   62600017
         TM    FASTDSB,X'10'           IF JOB TERMINATED ABNORMALLY,    62800017
         BO    ABTERM                   SEND ABEND MESSAGE              63000017
         LA    MSGR,31                 'NOTIFY' OFFSET                  63200017
ABTRMRTN STH   MSGR,MSGPARA+4          *                                63400017
         LA    MSGR,12                 *                                63600017
         STC   MSGR,MSGPARA+6          *                                63800017
         MVC   MSGPARA+7(8),FASTNAME   *                                64000017
         MVI   MSGPARA+15,C' '         *                                64200017
         MVC   MSGPARA+16(3),USERID    *                                64400017
         TM    FASTJIB,X'08'           IF THERE IS NO USER INFORMATION, 64600017
         BZ    PUTMSG                   REQUEST MESSAGE OUTPUT          64800017
         DROP  PARREG                                                   65000017
         ST    PARREG,INFO             PREPARE PARAMETERS FOR           65200017
         LA    PARREG,MSGPARA+20        RETRIEVAL OF JED TABLE          65400017
         ST    PARREG,INFO+4            INFORMATION                     65600017
         LA    PARREG,INFO              *                               65800017
         L     ENTREG,IHKZZJMR                                     000A 66000017
         BALR  RETREG,ENTREG                                       000A 66200017
         LA    MSGR,38                 PUT NEW BYTE COUNT IN MESSAGE    66400017
         STC   MSGR,MSGPARA+6           PARAMETER LIST                  66600017
         MVI   MSGPARA+19,C' '         SPACE BEFORE USER INFORMATION    66800017
PUTMSG   LA    PARREG,MSGPARA          ADDRESS OF MSG PARAMETER LIST    67000017
         L     ENTREG,IHKZZLDM                                     000A 67200017
         BALR  RETREG,ENTREG                                       000A 67400017
         BR    WORK                    RETURN TO CALLING ROUTINE        67600017
ABTERM   LA    MSGR,38                 'NOTIFY ABEND' MESSAGE           67800017
         B     ABTRMRTN                                                 68000017
BLNKOUT  MVC   MSGPARA+13(4),BLANKS    BLANK USER ID IN MESSAGE         68200017
         B     BLNKRTN                                                  68400017
*                                                                     * 68600017
*                                                                       68800017
*              CONSTANTS AND WORK AREA                                  69000017
*                                                                       69200017
*                                                                     * 69400017
FTL      EQU   24                      LENGTH OF FAST TABLE             69600017
ALERTN   DC    C'ALERT'                OPERATION                        69800017
BLANKS   DC    C'    '                                                  70000017
PARA     DS    1F                      PARAMETER LIST FOR SEARCHES      70200017
         DS    3C                      *                                70400017
         DS    3C                      *                                70600017
         DC    C'A'                    SEARCH TYPE INDICATOR            70800017
SWITCH   DS    1C                      DISK UPDATE SWITCHES             71000017
ALTSAVE  DS    18F                     SAVE AREA FOR ALERT ROUTINES     71200017
USERADR  DS    1F                      ADDRESS OF ENTRY IN UDIR         71400017
USERID   DS    1F                      USER IDENTIFIER                  71600017
TERMID   DS    1F                      ADDRESS OF ENTRY IN TDIR         71800017
CRDADR   DS    1F                      ADDRESS OF CAOMMAND CARD IMAGE   72000017
MSGPARA  DS    9F                      PARAMETER LIST FOR MESSAGES      72200017
INFO     DS    98C                     AREA FOR JEDTAB ENTRY            72400017
DCARD    DSECT                                                          72600017
         DS    72C                     CARD IMAGE OF COMMAND            72800017
SEQ      DS    8C                      SEQUENCE NUMBER                  73000017
         DS    1C                      CODE A FOR ALERT                 73200017
CMDID    DS    1C                      TYPE CODE                        73400017
JBNAME   DS    8C                      JOBNAME, IF PRESENT              73600017
         DS    5C                      BLANK                            73800017
FASTAB   DSECT                                                          74000017
FASTNAME DS    CL8                 'JOBNAME' FROM JCL CARD              74200017
FASTJIB  DS    C                   JOB INFORMATION BYTE                 74400017
FASTJEDT DS    CL3                 ADDRESS OF JED TABLE                 74600017
FASTDSB  DS    C                   DELIVERY STATUS BYTE                 74800017
FASTDSBE DS    C                   DELIVERY STATUS BYTE EXTENDED        75000017
FASTTTR  DS    CL3                 ADDRESS OF DISC FASTABLE ENTRY       75200017
FASTALT  DS    CL3                 ALTERNATE RECEIVER DESIGNATION       75400017
FASTCNT  DS    C                   COUNT OF RJE CLOSEDOWNS SINCE        75600017
*                                    CREATION OF DEFERRED OUTPUT        75800017
FASTUSE  DS    CL3                 USER IDENTIFIER                      76000017
JEDTAB   DSECT                                                          76200017
JEDNMSG  DS    CL25                NOTIFY MESSAGE TEXT                  76400017
JEDTSOUT DS    25C                 SYSOUT CLASSES OE OUTPUT DEVICES     76600017
JEDTQMPA DS    CL36                O/S QUEUE MANAGER PARAMETER AREA     76800017
JEDTQMPE DS    CL8                 O/S EXTERNAL QUE MANAGER PARAM AREA  77000017
JEDTTTR0 DS    CL3                 TTR OF FIRST SYSOUT RECORD           77200017
*                                    OF THIS JOB                        77400017
JEDTTYPE DS    C               TYPE OF RECORD POINTED TO BY TTR         77600017
UDIREC   DSECT                                                          77800017
UDIRTERM DS    CL8                 ADDRESS OF DERMINAL DIRECTORY ENTRY  78000017
UDIRSTAT DS    C                   STATUS OF USER                       78200017
UDIRUSID DS    CL3                 USER IDENTIFICATION                  78400017
UDIRUKEY DS    CL3                 USERS KEY                            78600017
UDIRTTR  DS    CL3                      TTR ADDRESS OF TDIR ON DISC     78800017
TDIREC   DSECT                                                          79000017
TDIRTERM DS    CL8                 TERMINAL IDENTIFICATION              79200017
TDIRUSID DS    CL3                 USER ID                              79400017
TDIRSTAT DS    C                   STATUS BYTE                          79600017
TDIRRB   DS    C                   NOT USED                             79800017
TDIRTTR  DS    CL3                       TTR ADDRESS OF TDIR ON DISC    80000017
TDIRFQEB DS    CL4                      ADDR OF 1ST Q ENTRY BLOCK       80200017
TDIRLQEB DS    CL4                       ADDR OF LAST Q ENTRY BLOCK     80400017
TDIRLMEL DS    CL4                       ADDR OF LAST MESSAGE ELEMENT   80600017
TDIRFORM DS    CL4                      PRINTER FORM NUMBER             80800017
TDIRSECB DS    CL4                 'STOP ACK ECB' (FULL WORD BOUNDARY)  81000017
TDIRSWCH DS    CL3                 LINE ANALYSIS SWITCHES AND REMOTE    81200017
*                                    HARDWARE CONFIGURATION             81400017
TDIRPRNT DS    C                   REMOTE PRINTER LINE SIZE             81600017
TDIRDFTM DS    CL16                DEFINE TERMINAL LIST                 81800017
TDIRLCB  DS    CL4                 ADDRESS OF LINE CONTROL BLOCK (LCB)  82000017
         IHKDSECT ,,,,,AVT                                         000A 82200017
         END                                                            82400017
