DLT      TITLE 'DELETE'                                                 00300017
IHKCGDLT CSECT                                                          00600017
*3261393000,432000,468000,522000,546000,636000,678000,699000       000A 00900017
*0790693000                                                        000B 01200017
*0790021000                                                        000B 01500017
*********************************************************************** 01800017
*                                                                     * 02100017
*TITLE 'IHKCGDLT'-DELETE                                              * 02400017
*STATUS - CHANGE LEVEL 2                                           000B 02700017
*FUNCTION/OPERATION:                                                  * 03000017
*   THIS ROUTINE PROCESSES THE DELETE COMMAND. THE FOLLOWING FORMS OF * 03300017
*   THE COMMAND ARE ACTED UPON:                                       * 03600017
*                                                                     * 03900017
*   A-DELETE A SPECIFIC JOB. THIS IS A REQUEST TO DELETE FROM THE RJE * 04200017
*   SYSTEM ALL REFERENCES TO THE SPECIFIED JOB. NAMED DATA SETS ARE   * 04500017
*   NOT DELETED AND REMAIN UNDER O/S CONTROL. THIS IS ACCOMPLISHED AS * 04800017
*   FOLLOWS:                                                          * 05100017
*                                                                     * 05400017
*   THE FAST TABLE IS SEARCHED FOR THE JOB USING IHKCDSCH.            * 05700017
*                                                                     * 06000017
*   1-IF THE JOB IS NOT FOUND, A 'JOB NOT IN SYSTEM' MESSAGE IS SENT  * 06300017
*   TO THE USER.                                                      * 06600017
*                                                                     * 06900017
*   2-IF THE COMMAND SUBMITTER DID NOT ORIGINATE THE JOB, AN 'INVALID * 07200017
*   RECEIVER' MESSAGE IS RETURNED.                                    * 07500017
*                                                                     * 07800017
*   3-IF THE COMMAND IS VALID, CONTROL IS PASSED TO IHKCGDT2 TO       * 08100017
*   REMOVE THE JOB FROM THE RJE SYSTEM.                               * 08400017
*                                                                     * 08700017
*   4-UPON RECEIVING CONTROL BACK FROM IHKCGDT2, THE FOLLOWING ACTION * 09000017
*   OCCURS:                                                           * 09300017
*                                                                     * 09600017
*   4.1-IF THE RETURN CODE IS ZERO, A 'JOB DELETED' MESSAGE, FOLLOWED * 09900017
*   BY JOBNAME, IS RETURNED.                                          * 10200017
*                                                                     * 10500017
*   4.2-IF THE RETURN CODE IS NON-ZERO, A 'JOB NOT IN SYSTEM' MESSAGE * 10800017
*   IS RETURNED INDICATING THE JOB OUTPUT WAS ALREADY ENQUEUED FOR    * 11100017
*   DELIVERY AND COULD NOT BE DELETED.                                * 11400017
*                                                                     * 11700017
*   B-DELETE ALL JOBS ORIGINATED BY THE DELETE COMMAND SUBMITTER.     * 12000017
*   THIS IS A REQUEST TO REMOVE FROM THE RJE SYSTEM ALL REFERENCES    * 12300017
*   TO ALL JOBS ORIGINATED BY THE COMMAND SUBMITTER (EXCEPT NAMED     * 12600017
*   DATA SETS WHICH REMAIN UNDER O/S CONTROL.) THE FOLLOWING ACTIONS  * 12900017
*   ARE TAKEN:                                                        * 13200017
*                                                                     * 13500017
*   USING IHKCGSGN, THE FAST TABLE IS SEARCHED FOR JOBS SUBMITTED BY  * 13800017
*   THE COMMAND SUBMITTER.                                            * 14100017
*                                                                     * 14400017
*   1-IF NO JOB IS FOUND, A 'JOB NOT IN SYSTEM' MESSAGE IS RETURNED.  * 14700017
*                                                                     * 15000017
*   2-IF A JOB IS FOUND, CONTROL IS PASSED TO IHKCGDT2 TO REMOVE IT   * 15300017
*   FROM THE SYSTEM.                                                  * 15600017
*                                                                     * 15900017
*   3-WHEN CONTROL IS RETURNED, THE RETURN CODE IS CHECKED AND EITHER:* 16200017
*                                                                     * 16500017
*   3.1-A 'JOB DELETED' MESSAGE, FOLLOWED BY THE JOBNAME, IS RETURNED * 16800017
*   IF THE CODE IS ZERO AND THE JOB IS COMPLETE, OR                   * 17100017
*                                                                     * 17400017
*   3.2-A 'JOB NOT IN SYSTEM' MESSAGE FOR THIS JOB IS SENT IF THE CODE* 17700017
*   IS NON-ZERO.                                                      * 18000017
*                                                                     * 18300017
*   3.3-NO MESSAGE IS SENT UNTIL JOB END IF THE CODE IS ZERO AND THE  * 18600017
*   JOB IS NOT COMPLETE.                                              * 18900017
*                                                                     * 19200017
*   4-STEPS 2 AND 3 ABOVE ARE REPEATED UNTIL ALL JOBS HAVE BEEN       * 19500017
*   PROCESSED.                                                        * 19800017
*                                                                     * 20100017
*ENTRY POINTS:                                                        * 20400017
*        IHKCGDLT IS THE ONLY ENTRY POINT. IT IS CALLED TO PROCESS    * 20700017
*   THE DELETE COMMAND AND DATA IS PASSED BY NAME AS FOLLOWS:         * 21000017
*        LA 1,PARALIST                                                * 21300017
*        CALL IHKCGDLT                                                * 21600017
*                                                                     * 21900017
*INPUT:                                                               * 22200017
*   PARALIST IS THE ADDRESS VECTOR TABLE WHOSE DESCRIPTION APPEARS 000A 22500017
*   BEFORE THE EXPANSION OF THE DSECT IHKZZAVT.                    000A 22800017
*                                                                     * 23100017
*OUTPUT-                                                              * 23400017
*   THIS ROUTINE SENDS MESSAGES TO THE USER INFORMING HIM OF THE      * 23700017
*   STATUS OF THE COMMAND. UPDATED VERSIONS OF THE FAST TABLE ENTRIES * 24000017
*   ARE WRITTEN TO DISK.                                              * 24300017
*                                                                     * 24600017
*EXTERNAL ROUTINES:                                                   * 24900017
*        IHKCGDT2-DELETES THE JOB FROM THE RJE SYSTEM                 * 25200017
*        IHKCBLDM-BUILDS SYSTEM MESSAGES                              * 25500017
*        IHKCCSGN-SEARCHES FAST TABLE FOR JOBS BY A GIVEN USER        * 25800017
*        IHKCDSCH-SEARCHES FAST TABLE FOR A SPECIFIC JOB              * 26100017
*                                                                     * 26400017
*EXITS-NORMAL:                                                        * 26700017
*   NORMAL RETURN IS BY REGISTER 14 TO THE CALLING ROUTINE WITH A     * 27000017
*   CODE OF ZERO IN REGISTER 15                                       * 27300017
*EXITS-ERROR: N/A                                                     * 27600017
*                                                                     * 27900017
*ATTRIBUTES: NON-RESIDENT.                                         000A 28200017
*                                                                     * 28500017
*TABLES/WORK AREAS: N/A                                               * 28800017
*                                                                     * 29100017
*NOTES:                                                               * 29400017
*   THE OPERATION OF THIS ROUTINE DEPENDS UPON AN INTERNAL REPRESENT- * 29700017
*   ATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE    * 30000017
*   ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED SO THAT   * 30300017
*   REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT * 30600017
*   IN A CORRECT MODULE FOR THE NEW DEFINTIONS.                       * 30900017
*                                                                     * 31200017
*********************************************************************** 31500017
R0       EQU   0                                                   000A 31800017
PARREG   EQU   1                       PARAMETER LIST REGISTER          32100017
WORK     EQU   4                       GENERAL WORK REGISTER            32400017
R5       EQU   5                                                        32700017
VCONBASE EQU   6                                                   000A 33000017
FASTBASE EQU   9                       BASE FOR FAST TABLE              33300017
TRMBASE  EQU   10                      BASE FOR TERMINAL DIRECTORY      33600017
CDBASE   EQU   11                      BASE FOR CARD IMAGE              33900017
BASE     EQU   12                      BASE FOR IHKCGDLT                34200017
SAVREG   EQU   13                      SAVE AREA REGISTER               34500017
RETREG   EQU   14                      RETURN POINT REGISTER            34800017
ENTREG   EQU   15                      ENTRY POINT REGISTER             35100017
         SAVE  (14,12),,*                                               35400017
         BALR  BASE,0                  ESTABLISH ADDRESSABILITY         35700017
         USING *,BASE                                                   36000017
         USING IHKZZAVT,VCONBASE                                   000A 36300017
         LR    VCONBASE,PARREG     SAVE REGISTER 1 FOR DSECT OF AVT000A 36600017
         ST    VCONBASE,VCONSAVE   SAVE BASE FOR AVT DSECT         000A 36900017
         LA    WORK,SAVE               CHAIN SAVE AREA TO CALLING RTN   37200017
         ST    SAVREG,SAVE+4            AND PLACE ADDRESS OF ACTIVE     37500017
         ST    WORK,8(SAVREG)           SAVE AREA IN REGISTER 13        37800017
         LR    SAVREG,WORK              *                               38100017
         NI    SWITCH,X'00'            INITIALIZE JOB FOUND SWITCH      38400017
         L     CDBASE,4(PARREG)        ESTABLISH ADDRESSABILITY FOR     38700017
         USING DCARD,CDBASE             CARD DUMMY SECTION              39000017
         L     TRMBASE,0(PARREG)       ESTABLISH ADDRESSABILITY FOR     39300017
         USING TDIREC,TRMBASE           TERMINAL ENTRY DUMMY SECTION    39600017
         LOAD  EPLOC=DLTADDT2      LOAD IHKCGDT2                   000A 39900017
         ST    R0,ADDT2            SAVE ENTRY POINT OF IHKCGDT2    000A 40200017
         CLI   CMDID,C'J'              IF SPECIFIC DELETE COMMAND,      40500017
         BE    DLT040                   GO TO SPECIFIC HANDLING ROUTINE 40800017
         XC    PARA(4),PARA            INDICATE SEARCH FASTAB ENTRY 1   41100017
         MVC   PARA+4(3),TDIRUSID      INDICATE SEARCH FOR JOBS BY USER 41400017
         MVC   PARA+7(3),PARA+4         ONLY                            41700017
         MVI   PARA+10,C'C'             *                               42000017
DLT010   LA    PARREG,PARA             PUT ADDRESS OF LIST IN REGISTER  42300017
         L     ENTREG,IHKZZSGN                                     000A 42600017
         BALR  RETREG,ENTREG                                       000A 42900017
         LTR   ENTREG,ENTREG           IF RETURN CODE IS NOT ZERO,      43200017
         BNZ   DLT020                   GO TO NO JOB ROUTINE            43500017
         LR    FASTBASE,PARREG         ESTABLISH ADDRESSABILITY FOR     43800017
         USING FASTAB,FASTBASE          THE FAST TABLE                  44100017
         OI    SWITCH,X'80'            TURN ON JOB FOUND SWITCH         44400017
         MVC   MSGPARA+7(8),FASTNAME   GET NAME OF JOB                  44700017
         MVI   MSGPARA+15,C' '                                          45000017
         MVC   MSGPARA+16(3),FASTUSE   USER IDENTIFIER                  45300017
         MVI   MSGPARA+19,C' '                                          45600017
         MVC   MSGPARA+20(8),SEQ       SEQUENCE NUMBER OF MESSAGE       45900017
         ST    PARREG,DT2PARA          PUT ADDRESS OF FASTAB ENTRY IN   46200017
         LA    PARREG,DT2PARA           LIST AND PASS IT TO DELETION    46500017
         L     ENTREG,ADDT2                                        000A 46800017
         BALR  RETREG,ENTREG            *                               47100017
         LTR   ENTREG,ENTREG           IF RETURN CODE IS NOT ZERO,      47400017
         BNZ   DLT110                  SEND 'JOB AWIATING DELIVERY'     47700017
         TM    FASTDSB,X'80'           IF JOB IS NOT COMPLETE,          48000017
         BZ    DLT015                   SEND NO MESSAGE                 48300017
         LA    WORK,47                 MESSAGE OFFSET FOR 'JOB DELETED' 48600017
         STH   WORK,MSGPARA+4           MESSAGE                         48900017
         LA    WORK,21                 MESSAGE LENGTH                   49200017
         STC   WORK,MSGPARA+6                                           49500017
         ST    TRMBASE,MSGPARA         TERMINAL ADDRESS                 49800017
         LA    PARREG,MSGPARA          ADDRESS OF BUFFER                50100017
         L     ENTREG,IHKZZLDM                                     000A 50400017
         BALR  RETREG,ENTREG                                       000A 50700017
DLT015   L     PARREG,DT2PARA          RETRIEVE ADDRESS OF FASTAB ENTRY 51000017
         LA    PARREG,UPDATE(PARREG)    AND UPDATE IT TO USE AS PTR     51300017
         ST    PARREG,PARA              TO CONTINUE SEARCH OF FASTAB    51600017
         B     DLT010                   *                               51900017
*                                                                       52200017
DLT020   TM    SWITCH,X'80'            IF JOB FOUND SWITCH IS ON,       52500017
         BO    DLT090                   RETURN                          52800017
         MVC   MSGPARA+7(7),DELETEN    FUNCTION                         53100017
         MVC   MSGPARA+14(3),TDIRUSID  MOVE INTO MESSAGE AREA THE USER  53400017
         MVI   MSGPARA+17,C' '          ID AND THE SEQUENCE NUMBER      53700017
         MVC   MSGPARA+18(8),SEQ        *                               54000017
         LA    WORK,22                 INIDCATE 'JOB NOT IN SYSTEM'     54300017
         STH   WORK,MSGPARA+4           MESSAGE AND BRANCH TO ROUTINE   54600017
         LA    WORK,19                  TO SEND MESSAGE                 54900017
         B     DLT080                   *                               55200017
*                                                                       55500017
DLT040   LA    PARREG,JBNAME           POINTER TO JOB NAME              55800017
         MVC   MSGPARA+7(8),JBNAME     JOBNAME FOR MESSAGE         000B 56100017
         L     ENTREG,IHKZZSCH                                     000A 56400017
         BALR  RETREG,ENTREG                                       000A 56700017
         LTR   ENTREG,ENTREG           IF RETURN CODE IS NOT ZERO,      57000017
         BNZ   DLT050                   JOB WAS NOT FOUND               57300017
         LR    FASTBASE,PARREG         SET FAST TABLE BASE              57600017
         ST    PARREG,DT2PARA          POINTER TO FASTAB ENTRY ADDRESS  57900017
         CLC   FASTUSE,TDIRUSID        IF USER IS NOT JOB ORIGINATOR,   58200017
         BNE   DLT060                   GO TO INVALID ROUTINE           58500017
         LA    PARREG,DT2PARA           ADDRESS OF PARAMETERS           58800017
         L     ENTREG,ADDT2                                        000A 59100017
         BALR  RETREG,ENTREG                                       000A 59400017
         LTR   ENTREG,ENTREG           IF RETURN CODE IS NOT ZERO,      59700017
         BNZ   DLT120                   PUT OUT MESSAGE                 60000017
         TM    FASTDSB,X'80'           IF JOB IS NOT COMPLETE,          60300017
         BZ    DLT090                   RETURN WITHOUT MESSAGE          60600017
         LA    WORK,47                 INDICATE 'JOB DELETED' MESSAGE   60900017
         STH   WORK,MSGPARA+4           AND GO TO ROUTINE TO SEND       61200017
         B     DLT070                   MESSAGE                         61500017
DLT050   LA    WORK,22                 INDICATE 'JOB NOT IN SYSTEM'     61800017
         STH   WORK,MSGPARA+4           MESSAGE                         62100017
         MVC   MSGPARA+7(7),DELETEN    FUNCTION                         62400017
         MVC   MSGPARA+14(8),JBNAME    JOB N AME                        62700017
         MVI   MSGPARA+22,C' '                                          63000017
         MVC   MSGPARA+23(3),TDIRUSID  USER IDENTIFIER                  63300017
         LA    WORK,28                 MESSAGE LENGTH                   63600017
         MVI   MSGPARA+26,C' '                                          63900017
         MVC   MSGPARA+27(8),SEQ       SEQUENCE NUMBER                  64200017
         B     DLT080                                                   64500017
DLT060   LA    WORK,21                 INDICATE 'INVALID RECEIVER'      64800017
         STH   WORK,MSGPARA+4           MESSAGE                         65100017
DLT070   DS    0H                                                  000B 65400017
         MVI   MSGPARA+15,C' '          NAME AND THE USER I D           65700017
         MVC   MSGPARA+16(3),TDIRUSID   *                               66000017
         MVI   MSGPARA+19,C' '                                          66300017
         MVC   MSGPARA+20(8),SEQ       SEQUENCE NUMBER                  66600017
         LA    WORK,21                 LENGTH OF TEXT                   66900017
DLT080   STC   WORK,MSGPARA+6           *                               67200017
         ST    TRMBASE,MSGPARA         INDICATE WHICH TERMINAL          67500017
         LA    PARREG,MSGPARA          POINTER TO PARAMETER LIST        67800017
         L     ENTREG,IHKZZLDM                                     000A 68100017
         BALR  RETREG,ENTREG                                       000A 68400017
DLT090   L     SAVREG,4(SAVREG)        RESTORE AND RETURN               68700017
         DELETE EPLOC=DLTADDT2     DELETE IHKCGDT2                 000A 69000017
         RETURN (14,12),T,RC=0                                          69300017
DLT100   LA    WORK,52                 INDICATE 'JOB WAITING DELIVERY'  69600017
         STH   WORK,MSGPARA+4           MESSAGE                         69900017
         MVI   MSGPARA+15,C' '          *                               70200017
         MVI   MSGPARA+19,C' '                                          70500017
         MVC   MSGPARA+20(8),SEQ       SEQUENCE NUMBER                  70800017
         MVC   MSGPARA+16(3),TDIRUSID   USER IDENTIFIER                 71100017
         LA    WORK,21                 MESSAGE LENGTH                   71400017
         STC   WORK,MSGPARA+6                                           71700017
         ST    TRMBASE,MSGPARA         TERMINAL FOR MESSAGE             72000017
         LA    PARREG,MSGPARA          ADDRESS OF MESSAGE BUFFER        72300017
         L     ENTREG,IHKZZLDM                                     000A 72600017
         BALR  RETREG,ENTREG                                       000A 72900017
         BR    R5                                                       73200017
DLT110   BAL   R5,DLT100               SEND MESSAGE                     73500017
         B     DLT015                  CONTINUE SEARCH                  73800017
DLT120   BAL   R5,DLT100               SEND MESSAGE                     74100017
         B     DLT090                  RETURN                           74400017
UPDATE   EQU   24                      LENGTH OF FAST TABLE ENTRY       74700017
ADDT2    DS    F                   ENTRY POINT OF IHKCGDT2         000A 75000017
DLTADDT2 DC    C'IHKCGDT2'                                         000A 75300017
DT2PARA  DS    F                       PARAMETER LIST FOR DELETION      75600017
VCONSAVE DS    F                   ADDRESS OF AVT                  000A 75900017
PARA     DS    11C                     PARAMETER LIST FOR SEARCHES      76200017
         DS    0F                                                       76500017
MSGPARA  DS    35C                     PARAMETER LIST FOR MESSAGES      76800017
DELETEN  DC    C'DELETE '              FUNCTION                         77100017
SAVE     DS    18F                     SAVE AREA                        77400017
SWITCH   DS    CL1                     JOB FOUND SWITCH                 77700017
DCARD    DSECT                                                          78000017
         DS    72C                                                      78300017
SEQ      DS    CL8                     SEQUENCE NUMBER                  78600017
         DS    C                                                        78900017
CMDID    DS    C                       COMMAND IDENTIFIER               79200017
JBNAME   DS    CL8                     NAME OF JOB                      79500017
         DS    5C                                                       79800017
FASTAB   DSECT                                                          80100017
FASTNAME DS    CL8                 'JOBNAME' FROM JCL CARD              80400017
FASTJIB  DS    C                   JOB INFORMATION BYTE                 80700017
FASTJEDT DS    CL3                 ADDRESS OF JED TABLE                 81000017
FASTDSB  DS    C                   DELIVERY STATUS BYTE                 81300017
FASTDSBE DS    C                   DELIVERY STATUS BYTE EXTENDED        81600017
FASTTTR  DS    CL3                 ADDRESS OF DISC FASTABLE ENTRY       81900017
FASTALT  DS    CL3                 ALTERNATE RECEIVER DESIGNATION       82200017
FASTCNT  DS    C                   COUNT OF RJE CLOSEDOWNS SINCE        82500017
*                                    CREATION OF DEFERRED OUTPUT        82800017
FASTUSE  DS    CL3                 USER IDENTIFIER                      83100017
JEDTAB   DSECT                                                          83400017
         CNOP  2,4                                                      83700017
JEDNMSG  DS    CL25                NOTIFY MESSAGE TEXT                  84000017
JEDTSOUT DS    25C                 SYSOUT CLASSES OE OUTPUT DEVICES     84300017
JEDTQMPA DS    CL36                O/S QUEUE MANAGER PARAMETER AREA     84600017
JEDTQMPE DS    CL8                 O/S EXTERNAL QUE MANAGER PARAM AREA  84900017
JEDTTTR0 DS    CL3                 TTR OF FIRST SYSOUT RECORD           85200017
*                                    OF THIS JOB                        85500017
JEDTTYPE DS    C               TYPE OF RECORD POINTED TO BY TTR         85800017
UDIREC   DSECT                                                          86100017
UDIRTERM DS    CL8                 ADDRESS OF DERMINAL DIRECTORY ENTRY  86400017
UDIRSTAT DS    C                   STATUS OF USER                       86700017
UDIRUSID DS    CL3                 USER IDENTIFICATION                  87000017
UDIRUKEY DS    CL3                 USERS KEY                            87300017
UDIRTTR  DS    CL3                      TTR ADDRESS OF TDIR ON DISC     87600017
TDIREC   DSECT                                                          87900017
TDIRTERM DS    CL8                 TERMINAL IDENTIFICATION              88200017
TDIRUSID DS    CL3                 USER ID                              88500017
TDIRSTAT DS    C                   STATUS BYTE                          88800017
TDIRRB   DS    C                   NOT USED                             89100017
TDIRTTR  DS    CL3                       TTR ADDRESS OF TDIR ON DISC    89400017
TDIRFQEB DS    CL4                      ADDR OF 1ST Q ENTRY BLOCK       89700017
TDIRLQEB DS    CL4                       ADDR OF LAST Q ENTRY BLOCK     90000017
TDIRLMEL DS    CL4                       ADDR OF LAST MESSAGE ELEMENT   90300017
TDIRFORM DS    CL4                      PRINTER FORM NUMBER             90600017
TDIRSECB DS    CL4                 'STOP ACK ECB' (FULL WORD BOUNDARY)  90900017
TDIRSWCH DS    CL3                 LINE ANALYSIS SWITCHES AND REMOTE    91200017
*                                    HARDWARE CONFIGURATION             91500017
TDIRPRNT DS    C                   REMOTE PRINTER LINE SIZE             91800017
TDIRDFTM DS    CL16                DEFINE TERMINAL LIST                 92100017
TDIRLCB  DS    CL4                 ADDRESS OF LINE CONTROL BLOCK (LCB)  92400017
         IHKDSECT ,,,,,AVT                                         000A 92700017
         END                                                            93000017
