DT2      TITLE 'DELETE2'                                                00300017
IHKCGDT2 CSECT                                                          00600017
*2513030000                                                        000C 00700018
*3260336000,342000,348000,396000,525000,534000-540000,618000       000A 00900017
*3260552000                                                        000A 01200017
*1090549000-558000,714000-717000,363000-366000,375000-378000,      000B 01500017
*1090576000,582000                                                 000B 01800017
*A 543100-545100                                                 A47442 01870021
*C 684000,711000                                                 A47442 01940021
*                                                                     * 02010021
*********************************************************************** 02100017
*                                                                     * 02400017
*TITLE 'IHKCGDT2'-DELETE2                                             * 02700017
*                                                                     * 03000021
* STATUS: CHANGE LEVEL 3, RELEASE 21.7                                * 03100021
*                                                                     * 03200021
*FUNCTION/OPERATION:                                                  * 03300017
*   THIS ROUTINE REMOVES ALL REFERENCES TO A GIVEN JOB FROM THE RJE   * 03600017
*   SYSTEM (EXCEPT NAMED DATA SETS WHICH REMAIN UNDER O/S CONTROL.)   * 03900017
*   THIS IS DONE IN THE FOLLOWING MANNER:                             * 04200017
*                                                                     * 04500017
*   A-IF A JOB IS NOT COMPLETE, AN O/S CANCEL COMMAND IS SUBMITTED    * 04800017
*   FOR THE JOB AND THE 'JOB DELETE' BIT IS SET ON.                   * 05100017
*                                                                     * 05400017
*   B-IF THE JOB IS COMPLETE, SEVERAL TESTS ARE MADE AND THE FOLLOWING* 05700017
*   ACTION IS PERFORMED:                                              * 06000017
*                                                                     * 06300017
*   1-IF THE JOB HAS IMMEDIATE OUTPUT, IT IS NOT REMOVED FROM THE     * 06600017
*   SYSTEM (SINCE IT HAS ALREADY BEEN ENQUEUED FOR DELIVERY.)         * 06900017
*                                                                     * 07200017
*   2-IF THE JOB HAS DEFERRED OUTPUT AND THE OUTPUT HAS ALREADY BEEN  * 07500017
*   ENQUEUED FOR DELIVERY, THE JOB IS NOT REMOVED.                    * 07800017
*                                                                     * 08100017
*   3-IF THE JOB HAS DEFERRED OUTPUT, NOT ALREADY ENQUEUED, THREE     * 08400017
*   ROUTINES ARE CALLED TO REMOVE IT FROM THE SYSTEM.                 * 08700017
*                                                                     * 09000017
*   3.1-THE O/S QUEUE MANAGER READ ROUTINE IS CALLED TO READ IN THE   * 09300017
*   DATA SET BLOCKS (DSB) FOR THE JOB.                                * 09600017
*                                                                     * 09900017
*   3.2-THE DATA SET SCRATCH ROUTINE (IHKCDRMV) IS CALLED TO DELETE   * 10200017
*   THE ASSOCIATED DATA SETS.                                         * 10500017
*                                                                     * 10800017
*   3.3-THE O/S QUEUE MANAGER DELETE ROUTINE IS CALLED TO DELETE THE  * 11100017
*   O/S QUEUE SPACE.                                                  * 11400017
*                                                                     * 11700017
*   C-IF THE JOB IS REMOVED BY EITHER A OR B ABOVE, THE LAST ACTION   * 12000017
*   TAKEN IS TO PLACE A CHARACTER BLANK INTO THE FIRST BYTE OF        * 12300017
*   FASTNAME TO REMOVE THE JOB FROM THE RJE TABLES.                   * 12600017
*                                                                     * 12900017
*ENTRY POINTS:                                                        * 13200017
*        IHKCGDT2 IS THE ONLY ENTRY POINT. IT IS ENTERED TO REMOVE    * 13500017
*   A SPECIFIED JOB FROM THE RJE SYSTEM. THE FOLLOWING CALLING        * 13800017
*   SEQUENCE IS USED TO PASS PARAMETERS BY NAME:                      * 14100017
*        LA 1,PARALIST                                                * 14400017
*        CALL IHKCGDT2                                                * 14700017
*                                                                     * 15000017
*INPUT:                                                               * 15300017
*   INPUT IS IN THE FORM OF A PARAMETER LIST. IF ENTRY IS FROM THE    * 15600017
*   SYSOUTDQ ROUTINE, THE LIST HAS THE FOLLOWING FORM:                * 15900017
*        LIST DC X'80'                                                * 16200017
*             DC A(QMPA-50)                                           * 16500017
*             DC A(ADDRESS VECTOR TABLE)                           000A 16800017
*   IF ENTRY IS FROM ANY OTHER ROUTINE, THE LIST IS AS FOLLOWS:       * 17100017
*        LIST DC A(FAST TABLE ENTRY)                                  * 17400017
*             DC A(ADDRESS VECTOR TABLE)                           000A 17700017
*                                                                     * 18000017
*OUTPUT: N/A                                                          * 18300017
*                                                                     * 18600017
*EXTERNAL ROUTINES:                                                   * 18900017
*        IHKCDJMR-READS IN JED TABLE FROM DISK                        * 19200017
*        IHKCDFMR-WRITES UPDATED FAST TABLE TO DISK                   * 19500017
*        IHKCDRMV-SCRATCHES GIVEN DATA SET                            * 19800017
*        IEFQDELE-DELETES O/S QUEUE SPACE                             * 20100017
*        IEFQMSSS-READS IN SMB/DSB FROM DISK                          * 20400017
*                                                                     * 20700017
*EXITS-NORMAL:                                                        * 21000017
*   NORMAL RETURN IS BY REGISTER 14 TO THE CALLING ROUTINE WITH A     * 21300017
*   RETURN CODE OF ZERO IN REGISTER 15.                               * 21600017
*                                                                     * 21900017
*EXITS-ERROR:                                                         * 22200017
*   IF A JOB IS NOT IS NOT REMOVED FROM THE SYSTEM, DUE TO ITS BEING  * 22500017
*   ENQUEUED FOR DELIVERY, A RETURN CODE OF FOUR IS PASSED TO THE     * 22800017
*   CALLING ROUTINE IN REGISTER 15.                                   * 23100017
*                                                                     * 23400017
*TABLES/WORK AREAS:                                                   * 23700017
*   A 98 BYTE WORK AREA IS USED TO RECEIVE THE JED TABLE INFORMATION. * 24000017
*   A 19 BYTE BUFFER IS USED TO BUILD THE O/S CANCEL COMMAND. A 176   * 24300017
*   BYTE BUFFER IS USED TO RECEIVE THE SMB/DSB READ IN BY O/S QUEUE   * 24600017
*   MANAGER                                                           * 24900017
*                                                                     * 25200017
*ATTRIBUTES: SERIALLY REUSABLE                                        * 25500017
*   NON-RESIDENT.                                                  000A 25800017
*                                                                     * 26100017
*NOTES:                                                               * 26400017
*   THE OPERATION OF THIS ROUTINE DEPENDS UPON AN INTERNAL REPRESENT- * 26700017
*   ATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE    * 27000017
*   ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED SO THAT   * 27300017
*   REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT * 27600017
*   IN A CORRECT MODULE FOR THE NEW DEFINTIONS.                       * 27900017
*                                                                     * 28200017
*********************************************************************** 28500017
R0       EQU   0                       SUPERVISOR PARAMETER REGISTER    28800017
PARREG   EQU   1                       PARAMETER LIST REGISTER          29100017
WORK2    EQU   2                        *                               29400017
WORK3    EQU   3                        *                               29700017
WORK     EQU   4                       GENERAL WORK REGISTERS           30000017
VCONBASE EQU   5                                                   000A 30300017
R6       EQU   6                       POINTER TO SYSDQ PARAMETERS      30600017
R7       EQU   7                       WORK REGISTER                    30900017
R8       EQU   8                       ADDRESS OF HIGHER SAVE AREA      31200017
JEDBASE  EQU   9                       BASE FOR JED TABLE ENTRY         31500017
QMBASE   EQU   10                      BASE FOR QUEUE MANAGER AREA      31800017
FASTBASE EQU   11                      BASE FOR FAST TABLE ENTRY        32100017
BASE     EQU   12                      BASE FOR IHKCGDT2                32400017
SAVREG   EQU   13                      SAVE AREA REGISTER               32700017
RETREG   EQU   14                      RETURN POINT REGISTER            33000017
ENTREG   EQU   15                      ENTRY POINT REGISTER             33300017
         SAVE  (14,12),,*                                               33600017
         BALR  BASE,0                  ESTABLISH ADDRESSABILITY         33900017
         USING *,BASE                                                   34200017
         USING IHKZZAVT,VCONBASE                                   000A 34500017
         L     VCONBASE,4(PARREG)                                  000A 34800017
         SR    RETREG,RETREG       PREPARE FOR LOCKED DOOR         000B 35100017
         L     ENTREG,IHKZZDSP     ADDRESS OF DISPATCHER           000B 35400017
         TS    BUSY                CHECK FOR LOCK DOOR             000B 35700017
         BCR   7,ENTREG            GO TO DISPATCHER IF LOCKED      000B 36000017
         LA    WORK,SAVE               CHAIN SAVE AREA TO CALLING RTN   36300017
         ST    WORK,8(SAVREG)           *                               36600017
         ST    SAVREG,SAVE+4            *                               36900017
         LR    R8,SAVREG               SAVE ADDRESS OF HIGHER SAVE      37200017
         LR    SAVREG,WORK              *                               37500017
         LR    R6,PARREG               SAVE PARAMETER POINTER           37800017
         LA    PARREG,DUMWAIT      ADDRESS OF POSTED ECB           000B 38100017
         BALR  RETREG,ENTREG       DUMMY WAIT                      000B 38400017
         LOAD  EPLOC=DT2ADRMV      LOAD IHKCDRMV                   000A 38700017
         LR    WORK3,R0                 AND SAVE ENTRY POINT            39000017
         L     WORK2,IHKZZSSS      GET ADDRESS OF IEFQMSSS         000B 39300017
         L     R7,IHKZZELE         GET ADDRESS OF IEFQDELE         000B 39600017
         TM    0(R6),X'80'             IF BIT IS ON,                    39900017
         BO    DT070                    ENTRY WAS FROM SYSDQ            40200017
         L     FASTBASE,0(R6)          ESTABLISH ADDRESSABILITY FOR000A 40500017
         USING FASTAB,FASTBASE          FAST TABLE DUMMY SECTION        40800017
         CLI   FASTNAME,X'40'          HAS JOB BEEN DELETED ?    A35651 40900020
         BE    DT025                   YES, DON'T TRY IT AGAIN   A35651 41000020
         TM    FASTDSB,X'80'           IF JOB IS NOT COMPLETE,          41100017
         BZ    DT040                    ISSUE O/S CANCEL COMMAND        41400017
         TM    FASTJIB,X'80'           IF JOB HAS IMMEDIATE OUTPUT,     41700017
         BO    DT050                    RETURN WITH CODE 4              42000017
         TM    FASTDSB,X'60'           IF DEFERRED OUTPUT HAS ALREADY   42300017
         BC    7,DT050                  BEEN ENQUEUED, RETURN CODE 4    42600017
         LA    PARREG,PARA             SET PARAMETERS FOR REQUEST TO    42900017
         ST    PARREG,PARA+6            READ JED TABLE INTO CORE        43200017
         ST    FASTBASE,PARA+2          *                               43500017
         LA    PARREG,PARA+2           ADDRESS OF PARAMETERS            43800017
         L     ENTREG,IHKZZJMR                                     000A 44100017
         BALR  RETREG,ENTREG                                       000A 44400017
         SH    ENTREG,H4               IF JED ERROR OCCURRED,           44700017
         BZ    DT080                    GO TO ERROR ROUTINE             45000017
         LA    JEDBASE,PARA-2          ESTABLISH ADDRESSABILITY FOR JED 45300017
         USING JEDTAB,JEDBASE           TABLE DUMMY SECTION             45600017
DT005    LA    QMBASE,JEDTQMPA         ESTABLISH ADDRESSABILITY FOR     45900017
         USING IOPARAMS,QMBASE          QUEUE MANAGER PARAMETER AREA    46200017
         MVC   PARA+10(4),JEDTQMPE     SAVE CALLER'S BUFFER PTR    000B 46500017
         ST    QMBASE,PARA+6           SAVE ADDRESS OF QMPA             46800017
         MVI   QMPOP,QMREAD            INDICATE READ FUNCTION           47100017
         LA    WORK,JEDTQMPE       ADDRESS OF EXTENTION                 47400017
         ST    WORK,QMPCL          POINTER TO EXTENTION                 47700017
         MVI   QMPCL,X'11'             INDICATE ONE RECORD              48000017
         L     WORK,JEDTQMPE+4         GET POINTER TO FIRST RECORD      48300017
         LA    PARREG,RDBUFF           GET ADDRESS OF READ BUFFER AND   48600017
         ST    PARREG,JEDTQMPE          PUT ADDRESS IN PARAMETER AREA   48900017
         ST    PARREG,PARA+2            *                               49200017
DT010    ST    WORK,JEDTQMPE+4         INDICATE WHICH RECORD TO READ    49500017
         LA    PARREG,JEDTQMPA         ADDRESS OF PARAMETER AREA TO     49800017
         LR    ENTREG,WORK2             SEND TO QUEUE TO                50100017
         BALR  RETREG,ENTREG            REQUEST A READ                  50400017
         LTR   ENTREG,ENTREG           IF READ ERROR,                   50700017
         BNZ   DTERR1                   SEND ERROR MESSAGE              51000017
         LA    PARREG,DUMWAIT      ADDRESS OF POSTED ECB           000B 51300017
         L     ENTREG,IHKZZDSP     ADDRESS OF DISPATCHER           000B 51600017
         BALR  RETREG,ENTREG       DUMMY WAIT                      000B 51900017
         L     PARREG,PARA+2           ADDRESS OF SMB/DSB               52200017
         CLI   14(PARREG),DSBID        IF NOT DATA SET BLOCK            52500017
         BNE   DT015                    TEST FOR LAST IN CHAIN          52800017
         LR    ENTREG,WORK3            ADDRESS OF DATA SET SCRATCH RTN  53100017
         LA    PARREG,PARA+2           ADDRESS OF PARAMETER LIST        53400017
         BALR  RETREG,ENTREG           REQUEST SCRATCH OF DATA SET      53700017
         CH    ENTREG,NINE             IF RETURN CODE IS NINE,          54000017
         BE    DTERR1                   SEND ERROR MESSAGE              54300017
         LTR   ENTREG,ENTREG           TEST FOR VOLID FOUND      A47442 54310021
         BZ    DT015                    IF YES, BRANCH           A47442 54320021
DTNOVOL  MVC   MSGPARA+7(6),0(ENTREG)  MOVE VOLID                A47442 54330021
         MVI   MSGPARA+13,X'40'                                  A47442 54340021
         MVC   MSGPARA+14(8),FASTNAME   MOVE JOBNAME             A47442 54350021
         MVI   MSGPARA+22,X'40'                                  A47442 54360021
         L     PARREG,PARA+2           PTR TO DDNAME             A47442 54370021
         MVC   MSGPARA+23(8),20(PARREG)  MOVE DDNAME             A47442 54380021
         LA    WORK,74                                           A47442 54390021
         STH   WORK,MSGPARA+4           STORE OFFSET             A47442 54400021
         LA    WORK,24                                           A47442 54410021
         STC   WORK,MSGPARA+6           STORE LENGTH             A47442 54420021
         TM    0(R6),X'80'             IF ENTRY FROM SYSDEQ      A47442 54430021
         BO    DTERRC                  THEN NO TDE PTR SO        A47442 54440021
*                                      SEND MSG ONLY TO CENTRAL  A47442 54450021
         L     PARREG,SAVE+4           ENTRY IS FROM DLT         A47442 54460021
         MVC   MSGPARA(4),60(PARREG)   SO ENQUEUE                A47442 54470021
         LA    PARREG,MSGPARA          TERMINAL QEUE             A47442 54480021
         L     ENTREG,IHKZZLDM                                   A47442 54490021
         BALR  RETREG,ENTREG                                     A47442 54500021
         B     DTERRC                                            A47442 54510021
DT015    SR    WORK,WORK                                                54600017
         CH    WORK,RDBUFF+4           IF THIS POINTER IS ZERO, THE     54900017
         BNE   DT060                    LAST BLOCK HAS BEEN READ        55200017
         MVI   QMPOP,QMDELE            INDICATE DELETE REQUEST          55500017
         LR    ENTREG,R7               ENTRY POINT OF IEFQDELE          55800017
         LA    PARREG,JEDTQMPA          LIST REQUESTING A DELETION      56100017
         BALR  RETREG,ENTREG            *                               56400017
         LTR   ENTREG,ENTREG           IF DELETE ERROR,                 56700017
         BNZ   DTERR2                   SEND ERROR MESSAGE              57000017
DT020    DS    0H                                                  000B 57300017
         TM    0(R6),X'80'             IF ENTERED FROM SYSDQ,      000B 57600017
         BO    DT090                    DO NOT SCRATCH RJE TABLES  000B 57900017
         MVI   FASTNAME,X'40'          REMOVE JOB FROM RJE TABLES  000B 58200017
DT021    LR    PARREG,FASTBASE         CALL ROUTINE TO UPDATE THE       58500017
        L     ENTREG,IHKZZFMR          FAST TABLE ENTRY            000A 58800017
         BALR  RETREG,ENTREG                                       000A 59100017
DT025    SR    ENTREG,ENTREG           RETURN CODE ZERO                 59400017
         ST    ENTREG,16(R8)           SET RETURN CODE                  59700017
DT030    DS    0H                                                       60000017
         DELETE EPLOC=DT2ADRMV                                     000A 60300017
         LR    SAVREG,R8               RESTORE SAVE AREA POINTER        60600017
         NI    BUSY,X'00'              UNLOCK DOOR                 000B 60900017
         RETURN (14,12),T                                               61200017
DT040    MVC   JOBN(8),FASTNAME        PREPARE AND REQUEST AN O/S       61500017
         LA    PARREG,CNLBUF            CANCEL COMMAND                  61800017
         SR    R0,R0               ZIP R0                          000C 61900018
         MGCR  (1)                 ISSUE CANCEL MACRO                   62100017
         OI    FASTJIB,X'10'           TURN ON 'JOB DELETE' BIT         62400017
         B     DT025                                                    62700017
DT050    LA    ENTREG,4                RETURN WITH CODE EQUAL 4         63000017
         ST    ENTREG,16(R8)           SET RETURN CODE                  63300017
         B     DT030                                                    63600017
DT060    L     WORK,PARA+2             ADDRESS OF DATA SET BLOCK        63900017
         L     WORK,4(WORK)            POINTER TO NEXT BLOCK            64200017
         B     DT010                                                    64500017
DT070    L     JEDBASE,0(R6)           ADDRESSABILITY FOR JED TABLE     64800017
         SH    JEDBASE,H2                                               65100017
         B     DT005                                                    65400017
DT080    MVI   FASTNAME,X'00'          DISABLE ENTRY                    65700017
         B     DT021                                                    66000017
DT090    MVC   JEDTQMPE(4),PARA+10     RESTORE CALLER'S BUFFER PTR 000B 66300017
         B     DT025                   RETURN                      000B 66600017
DTERR1   MVC   MSGPARA+7(8),FASTNAME   JOB NAME                         66900017
         LA    WORK,8                                                   67200017
DTERRB   STC   WORK,MSGPARA+6                                           67500017
         LA    WORK,67                 OFFSET                           67800017
         STH   WORK,MSGPARA+4                                           68100017
DTERRC   XC    MSGPARA(4),MSGPARA                                A47442 68400021
         LA    PARREG,MSGPARA          ADDRESS OF BUFFER                68700017
         L     ENTREG,IHKZZLDM                                     000A 69000017
         BALR  RETREG,ENTREG                                       000A 69300017
         B     DT020                   RETURN                           69600017
DTERR2   SR    WORK,WORK               NO MESSAGE TEXT                  69900017
         B     DTERRB                                                   70200017
NINE     DC    H'9'                                                     70500017
         DS    0F                                                  000A 70800017
MSGPARA  DS    32C                     MESSAGE BUFFER            A47442 71100021
DSBID    EQU   X'FF'                   DATA SET BLOCK ID                71400017
BUSY     DC    X'00'                   LOCKED DOOR SWITCH          000B 71700017
         CNOP  2,4                                                      72000017
PARA     DS    0CL98                   JED TABLE INPUT AREA             72300017
         DS    50C                                                      72600017
QMPA     DS    48C                                                      72900017
CNLBUF   DC    XL2'14'                 BUFFER FOR O/S CANCEL COMMAN000B 73200017
         DC    2X'00'                   *                               73500017
         DC    C'CANCEL '               *                               73800017
JOBN     DC    CL9' '                   AREA FOR NAME OF JOB       000B 74100017
SAVE     DS    18F                     SAVE AREA                        74400017
DUMWAIT  DC    X'40000000'             POSTED ECB FOR DUMMY WAIT   000B 74700017
DT2ADRMV DC    C'IHKCDRMV'                                         000A 75000017
RDBUFF   DS    176C                    QUEUE MANAGER READ AREA          75300017
H2       DC    H'2'                    ADJUSTMENT CONSTANT              75600017
H4       DC    H'4'                                                     75900017
         IEFQMNGR                                                       76200017
FASTAB   DSECT                                                          76500017
FASTNAME DS    CL8                 'JOBNAME' FROM JCL CARD              76800017
FASTJIB  DS    C                   JOB INFORMATION BYTE                 77100017
FASTJEDT DS    CL3                 ADDRESS OF JED TABLE                 77400017
FASTDSB  DS    C                   DELIVERY STATUS BYTE                 77700017
FASTDSBE DS    C                   DELIVERY STATUS BYTE EXTENDED        78000017
FASTTTR  DS    CL3                 ADDRESS OF DISC FASTABLE ENTRY       78300017
FASTALT  DS    CL3                 ALTERNATE RECEIVER DESIGNATION       78600017
FASTCNT  DS    C                   COUNT OF RJE CLOSEDOWNS SINCE        78900017
*                                    CREATION OF DEFERRED OUTPUT        79200017
FASTUSE  DS    CL3                 USER IDENTIFIER                      79500017
JEDTAB   DSECT                                                          79800017
         CNOP  2,4                                                      80100017
JEDNMSG  DS    CL25                NOTIFY MESSAGE TEXT                  80400017
JEDTSOUT DS    25C                 SYSOUT CLASSES OE OUTPUT DEVICES     80700017
JEDTQMPA DS    CL36                O/S QUEUE MANAGER PARAMETER AREA     81000017
JEDTQMPE DS    CL8                 O/S EXTERNAL QUE MANAGER PARAM AREA  81300017
JEDTTTR0 DS    CL3                 TTR OF FIRST SYSOUT RECORD           81600017
*                                    OF THIS JOB                        81900017
JEDTTYPE DS    C               TYPE OF RECORD POINTED TO BY TTR         82200017
UDIREC   DSECT                                                          82500017
UDIRTERM DS    CL8                 ADDRESS OF DERMINAL DIRECTORY ENTRY  82800017
UDIRSTAT DS    C                   STATUS OF USER                       83100017
UDIRUSID DS    CL3                 USER IDENTIFICATION                  83400017
UDIRUKEY DS    CL3                 USERS KEY                            83700017
UDIRTTR  DS    CL3                      TTR ADDRESS OF TDIR ON DISC     84000017
TDIREC   DSECT                                                          84300017
TDIRTERM DS    CL8                 TERMINAL IDENTIFICATION              84600017
TDIRUSID DS    CL3                 USER ID                              84900017
TDIRSTAT DS    C                   STATUS BYTE                          85200017
TDIRRB   DS    C                   NOT USED                             85500017
TDIRTTR  DS    CL3                       TTR ADDRESS OF TDIR ON DISC    85800017
TDIRFQEB DS    CL4                      ADDR OF 1ST Q ENTRY BLOCK       86100017
TDIRLQEB DS    CL4                       ADDR OF LAST Q ENTRY BLOCK     86400017
TDIRLMEL DS    CL4                       ADDR OF LAST MESSAGE ELEMENT   86700017
TDIRFORM DS    CL4                      PRINTER FORM NUMBER             87000017
TDIRSECB DS    CL4                 'STOP ACK ECB' (FULL WORD BOUNDARY)  87300017
TDIRSWCH DS    CL3                 LINE ANALYSIS SWITCHES AND REMOTE    87600017
*                                    HARDWARE CONFIGURATION             87900017
TDIRPRNT DS    C                   REMOTE PRINTER LINE SIZE             88200017
TDIRDFTM DS    CL16                DEFINE TERMINAL LIST                 88500017
TDIRLCB  DS    CL4                 ADDRESS OF LINE CONTROL BLOCK (LCB)  88800017
         IHKDSECT ,,,,,AVT                                         000A 89100017
         END                                                            89400017
