HATS   TITLE   'ACTIVE AND TERMS SHOW REQUEST PROCESSOR'                00200017
IHKCHATS CSECT                                                          00400017
         SPACE                                                          00600017
         ENTRY IHKCASHA                                                 00800017
         ENTRY IHKCASHT                                                 01000017
         SPACE                                                          01200017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   01400017
*                                                                   *   01600017
*                                                                   *   01800017
*   F U N C T I O N / O P E R A T I O N - -                         *   02000017
*                                                                   *   02200017
*     THIS MODULE RESPONDS TO THE CENTRAL COMMANDS ENTERED BY THE   *   02400017
*       CENTRAL OPERATOR TO RETRIEVE INFORMATION RELATIVE TO THE    *   02600017
*       WORK STATIONS IN THE RJE SYSTEM.  HE CAN REQUEST -          *   02800017
*       1.  A LIST OF ALL WORK STATIONS IN THE RJE SYSTEM.          *   03000017
*             SHOW TERMS                                            *   03200017
*       2.  A LIST OF THE ACTIVE WORK STATIONS IN THE RJE SYSTEM.   *   03400017
*             SHOW ACTIVE                                           *   03600017
*       3.  THE STATE OF A PARTICULAR WORK STATION IN HIS SYSTEM.   *   03800017
*             SHOW TERMS,TERMID                                     *   04000017
*                                                                   *   04200017
*     THE RESPONSE TO THESE REQUESTS CONTAINS THE NAME OF THE WORK  *   04400017
*       STATION AND AN INDICATION OF WHETHER OR NOT THE WORK STATION*   04600017
*       IS ACTIVE. IF THE WORK STATION IS ACTIVE, THE EBCDIC UNIT-  *   04800017
*       NAME FOR THE COMMUNICATION LINE ON WHICH IT IS ATTACHED IS  *   05000017
*       DISPLAYED.  IN ADDITION, IF THERE IS A USER LOGGED ON THE   *   05200017
*       WORK STATION, HIS USERID IS DISPLAYED AS PART OF THE        *   05400017
*       RESPONSE                                                    *   05600017
*                                                                   *   05800017
*                                                                   *   06000017
*   E N T R Y   P O I N T S - -                                     *   06200017
*                                                                   *   06400017
*     IHKCASHT AND IHKCASHA ARE COMMON ENTRY POINTS ATTRIBUTED TO   *   06600017
*       THIS MODULE.  IHKCHSHT IS THE ENTRY POINT USED BY IHKCAINT  *   06800017
*       ON RECEIPT OF A SHOW TERMS OR A SHOW TERMS,TERMID COMMAND.  *   07000017
*       IHKCHSHA IS THE ENTRY POINT USED BY IHKCAINT ON RECEIPT     *   07200017
*       OF A SHOW ACTIVE COMMAND.                                   *   07400017
*                                                                   *   07600017
*             CALLING SEQUENCE FOR IHKCASHT ENTRY POINT             *   07800017
*                                                                   *   08000017
*                   LOAD  EP=IHKCASHT                               *   08200017
*                   LR    15,0                                      *   08400017
*                   L     1,ADDRESS OF RJE COMMUNICATION REGION     *   08600017
*                   BALR  14,15                                     *   08800017
*                                                                   *   09000017
*                   DELETE EP=IHKCASHT                              *   09200017
*                                                                   *   09400017
*             CALLING SEQUENCE FOR IHKCASHA ENTRY POINT             *   09600017
*                                                                   *   09800017
*                   LOAD  EP=IHKCASHA                               *   10000017
*                   LR    15,0                                      *   10200017
*                   L     1,ADDRESS OF RJE COMMUNICATION REGION     *   10400017
*                   BALR  14,15                                     *   10600017
*                                                                   *   10800017
*                   DELETE EP=IHKCASHA                              *   11000017
         EJECT                                                          11200017
*                                                                   *   11400017
*   I N P U T - -                                                   *   11600017
*                                                                   *   11800017
*     THE INPUT OF THIS MODULE IS OBTAINED FROM THE FIRST TWO       *   12000017
*       ADDRESSES POINTED TO BY REGISTER ONE.  THE FIRST WORD OF    *   12200017
*       THE PARAMETER LIST IS NOT USED.  THE SECOND WORD POINTS TO  *   12400017
*       A 95 BYTE RJE COMMAND RECORD WITH THE FOLLOWING FORMAT.     *   12600017
*                                                                   *   12800017
*       *---------------------------------------------------*       *   13000017
*       *                         *                         *       *   13200017
*       *  80 BYTE COMMAND IMAGE  *  15 BYTE CONDENSATION   *       *   13400017
*       *                         *                         *       *   13600017
*       *---------------------------------------------------*       *   13800017
*                                                                   *   14000017
*       DESCRIPTION                                                 *   14200017
*         BYTE      USE                                             *   14400017
*        0-79      COMMAND IMAGE - 80 BYTE IMAGE OF COMMAND WHICH   *   14600017
*                        WAS RECEIVED AND INTERUPTED BY THE COMMAND *   14800017
*                        INTERPRETER (IHKCAINT).                    *   15000017
*        80-94     COMMAND CONDENSATION                             *   15200017
*                   BYTE      USE                                   *   15400017
*                    80        COMMAND TYPE- CONTAINS C'H' TO       *   15600017
*                                  INDICATE SHOW                    *   15800017
*                    81        OPERAND TYPE- CONTAINS               *   16000017
*                                - C'A' FOR SHOW ACTIVE             *   16200017
*                                - C'T' FOR SHOW TERMS OR           *   16400017
*                                            SHOW TERMS,TERMID      *   16600017
*                    82-87     REQUEST TYPE- CONTAINS               *   16800017
*                                - BINARY ZERO FOR MAJOR REQUEST,   *   17000017
*                                   SHOW ACTIVE OR SHOW TERMS       *   17200017
*                                - EBCDIC TERMID FOR SPECIFIC       *   17400017
*                                   REQUEST - SHOW TERMS,TERMID     *   17600017
*                    88-94     RESERVED                             *   17800017
*                                                                   *   18000017
*                                                                   *   18200017
*   O U T P U T - -                                                 *   18400017
*                                                                   *   18600017
*     THE OUTPUT OF THIS ROUTINE IS A PRINTER/KEYBOARD DISPLAY OF   *   18800017
*       THE STATES OF THE WORK STATION(S) IN THE RJE SYSTEM.        *   19000017
*       REPORTING CONTINUES UNTIL ALL WORK STATIONS HAVE BEEN       *   19200017
*       CHECKED WHICH COULD SATISY THE REQUEST MADE ON THE ROUTINE. *   19400017
*                                                                   *   19600017
*     MESSAGES HAVE THE FOLLING FORMAT                              *   19800017
*                                                                   *   20000017
*       IHK027I TERMID I                 FOR INACTIVE WORK STATION  *   20200017
*       IHK027I TERMID A UNITNAME        FOR ACTIVE WORK STATION    *   20400017
*       IHK027I TERMID P UNITNAME USERID FOR PROCESSING WORK STATION*   20600017
*                                                                   *   20800017
*     IN ADDITION FOR A SHOW ACTIVE REQUEST, THE MESSAGE --         *   21000017
*                                                                   *   21200017
*       IHK027I NO ACTIVE WORK STATIONS -- IS DISPLAYED IF THERE    *   21400017
*       ARE NO ACTIVE WORK STATIONS WHEN THE REQUEST IS MADE.       *   21600017
         EJECT                                                          21800017
*                                                                   *   22000017
*     THE MESSAGE -- IHK027I NO WORK STATIONS --  IS DISPLAYED IF   *   22200017
*       THERE ARE NO ENTRIES IN THE TERMINAL DIRECTORY.             *   22400017
*                                                                   *   22600017
*     IN THE EVENT THE OPERATOR SUBMITS A SHOW TERMS, TERMID WITH AN*   22800017
*       INVALID TERMID THE MESSAGE  -- IHK042I INVALID TERMID SHOW -*   23000017
*       IS DISPLAYED.                                               *   23200017
*                                                                   *   23400017
*                                                                   *   23600017
*   E X T E R N A L   R O U T I N E S - -                           *   23800017
*                                                                   *   24000017
*     IHKCBSTD- SEARCH TERMINAL DIRECTORY FOR TERMID ON A SPECIFIC  *   24200017
*               REQUEST                                             *   24400017
*     IHKCBLDM- CONSTRUCT AND DISPLAY MESSAGES FOR CENTRAL OPERATOR *   24600017
*                                                                   *   24800017
*                                                                   *   25000017
*   E X I T S - -                                                   *   25200017
*                                                                   *   25400017
*     NORMAL- RETURN TO CALLING ROUTINE WITH ZERO RETURN CODE       *   25600017
*                                                                   *   25800017
*     ERROR- N/A                                                    *   26000017
*                                                                   *   26200017
*                                                                   *   26400017
*   T A B L E S / W O R K   A R E A S - -                           *   26600017
*                                                                   *   26800017
*     STANDARD 18-WORD SAVE AREA                                    *   27000017
*     24 BYTE MESSAGE TEXT BUFFER                                   *   27200017
*                                                                   *   27400017
*                                                                   *   27600017
*   A T T R I B U T E S - -                                         *   27800017
*                                                                   *   28000017
*     SERIALLY REUSABLE AND NON-RESIDENT                            *   28200017
*                                                                   *   28400017
*                                                                   *   28600017
*   N O T E S - -                                                   *   28800017
*                                                                   *   29000017
*     COMMENTS ARE KEYED TO PROGRAMMERS FAMILIAR WITH THE MYSTERIES *   29200017
*       OF OS/360 ASSEMBLER LANGUAGE WHICH DEPENDS UPON AN INTERNAL *   29400017
*       REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS       *   29600017
*       EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE PROGRAM   *   29800017
*       HAS BEEN ARRANGED SO THAT REDEFINITION OF CHARACTER         *   30000017
*       CONSTANTS BY REASSEMBLY WILL RESULT IN A CORRECT MODULE FOR *   30200017
*       THE NEW DEFINITIONS.                                        *   30400017
*                                                                   *   30600017
*                                                                   *   30800017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   31000017
         EJECT                                                          31200017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   31400017
*                                                                   *   31600017
*             S Y M B O L I C   R E G I S T E R S                   *   31800017
*                                                                   *   32000017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   32200017
         SPACE                                                          32400017
ZIP      EQU   0         WORK REGISTER                                  32600017
PAR      EQU   1         PARAMETER LIST ADDRESS FOR LINKAGE             32800017
TDE      EQU   2         CURRENT TERMINAL DIRECTORY ADDRESS (DSECT)     33000017
LNG      EQU   3         LENGTH OF TERMINAL DIRECTORY ENTRY             33200017
CNT      EQU   4         NUMBER OF TERMINAL DIRECTORY ENTRIES           33400017
AVT      EQU   5         RJE COMMUNICATION REGION ADDRESS (DSECT)       33600017
REC      EQU   6         COMMAND INPUT RECORD ADDRESS (DSECT)           33800017
ACT      EQU   7         ACTIVE MESSAGE SWITCH- ZERO IF ACTIVE FOUND    34000017
BAL      EQU   8         INTERNAL SUBROUTINE BRANCH REGISTER            34200017
WOK      EQU   9         WORK REGISTER                                  34400017
USE      EQU  10         WORK REGISTER                                  34600017
NU2      EQU  11         NOT USED                                       34800017
BAS      EQU  12         MODULE BASE REGISTER                           35000017
SAV      EQU  13         SAVE AREA ADDRESS REGISTER                     35200017
BAC      EQU  14         RETURN POINT REGISTER FOR LINKAGE              35400017
GO       EQU  15         ENTRY POINT AND RETURN CODE REG FOR LINKAGE    35600017
         SPACE 2                                                        35800017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   36000017
*                                                                   *   36200017
*     S Y M B O L I C   L E N G T H S ,   D I S P L A C E M E N T S *   36400017
*                          AND  V A L U E S                         *   36600017
*                                                                   *   36800017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   37000017
         SPACE                                                          37200017
* DISPLACEMENTS -                                                       37400017
         SPACE                                                          37600017
ZERO     EQU   0                                                        37800017
ONE      EQU   1                                                        38000017
TWO      EQU   2                                                        38200017
THRE     EQU   3                                                        38400017
FOUR     EQU   4                                                        38600017
ATE      EQU   8                                                        38800017
TWLV     EQU  12                                                        39000017
UCB      EQU  13                                                        39200017
UCBAD    EQU  28                                                        39400017
         SPACE                                                          39600017
* LENGTHS -                                                             39800017
         SPACE                                                          40000017
L3       EQU   3                                                        40200017
L4       EQU   4                                                        40400017
L8       EQU   8                                                        40600017
L13      EQU  13                                                        40800017
L20      EQU  20                                                        41000017
L23      EQU   23                                                       41200017
         EJECT                                                          41400017
        SPACE   4                                                       41600017
* VALUES -                                                              41800017
         SPACE                                                          42000017
ACTIVE EQU     C'A'                                                     42200017
ACTREQ   EQU   C'A'                                                     42400017
BLNK     EQU   C' '                                                     42600017
BADTID   EQU   6                                                        42800017
INACTIVE EQU   C'I'                                                     43000017
PROCESS  EQU   C'P'                                                     43200017
MAJOR    EQU   X'00'                                                    43400017
NOU      EQU   X'00'                                                    43600017
         SPACE                                                          43800017
         EJECT                                                          44000017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   44200017
*                                                                   *   44400017
*                E N T R Y   L I N K A G E                          *   44600017
*                                                                   *   44800017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   45000017
         SPACE                                                          45200017
IHKCASHT DS    0H                  ENTRY POINT FOR SHOW TERMS,(TERMID)  45400017
IHKCASHA DS    0H                  ENTRY POINT FOR SHOW ACTIVE          45600017
         SPACE                                                          45800017
         B     TWLV(ZIP,GO)        BRANCH AROUND IDENTIFIER             46000017
         SPACE                                                          46200017
         DC    CL8'IHKCHATS'       MODULE IDENTIFIER                    46400017
         SPACE                                                          46600017
         STM   BAC,BAS,TWLV(SAV)   SAVE CALLING MODULE REGISTERS FOR    46800017
*                                  - RETURN LINKAGE                     47000017
         BALR  BAS,ZIP             SET UP MODULE ADDRESSABILITY         47200017
    USING      *,BAS               TELL ASSEMBLER CHOICE OF BASE REG.   47400017
         SPACE                                                          47600017
         SPACE                                                          47800017
         LA    WOK,SATSAV          GET MODULE SAVE AREA ADDRESS         48000017
         ST    WOK,ATE(SAV)        PUT IT IN CALLING SAVE AREA          48200017
         ST    SAV,FOUR(WOK)       KEEP CALLING SAVE AREA ADDRESS IN    48400017
*                                  * MODULE SAVE AREA FOR RETURN LNKAGE 48600017
         LR    SAV,WOK             SET UP SAVE REG FOR MODULE LINKAGE   48800017
         SPACE 2                                                        49000017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   49200017
*                                                                   *   49400017
*     I N I T I A L I Z E   AND   R E T R I E V E   P A R M S       *   49600017
*                                                                   *   49800017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   50000017
         SPACE                                                          50200017
         LR    AVT,PAR             GET RJE COMMUNICATION REGION ADDRESS 50400017
         LR    ACT,AVT             SET ACTIVE MESSAGE SWITCH NONZERO    50600017
         SPACE                                                          50800017
    USING      IHKZZAVT,AVT        TELL ASSEMBLER ABOUT DSECT           51000017
         SPACE                                                          51200017
         L     REC,IHKZZCDE        GET COMMAND INPUT RECORD ADDRESS     51400017
         SPACE                                                          51600017
    USING      CIRD,REC            TELL ASSEMBLER ABOUT DSECT           51800017
         LM    TDE,CNT,IHKZZTDR    GET TERMINAL DIRECTORY DESCRIPTIVE   52000017
*                                  * ADDRESSES                          52200017
*                                  ** TDE- TERMINAL STARTING ADDRESS    52400017
*                                  ** NUM- ENTRY LENGTH HALF-WORD ADDR  52600017
*                                  ** CNT- ENTRY NUMBER HALF-WORD ADDR  52800017
         SPACE                                                          53000017
         SPACE                                                          53200017
         LH    LNG,ZERO(LNG)       GET TDIR ENTRY LENGTH                53400017
         LH    CNT,ZERO(CNT)       GET TDIR ENTRY NUMBER                53600017
         LTR   CNT,CNT             ARE THERE ANY ENTRIES IN TDIR        53800017
         BZ    SATNOT              NO, TELL OPERATOR NO ENTRIES         54000017
         SPACE                                                          54200017
    USING      TDIREC,TDE          TELL ASSEMBLER ABOUT DSECT           54400017
         EJECT                                                          54600017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   54800017
*                                                                   *   55000017
*      D E T E R M I N E   R E Q U E S T   T Y P E                  *   55200017
*                                                                   *   55400017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   55600017
         SPACE                                                          55800017
         CLI   RTYPE,MAJOR         IS THIS A MAJOR REQUEST              56000017
         BNE   SATSPEC             NO, PROCESS SPECIFIC REQUEST         56200017
         SPACE 2                                                        56400017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   56600017
*                                                                   *   56800017
*   P R O C E S S   M A J O R   W O R K   S T A T I O N             *   57000017
*    S T A T U S   R E Q U E S T                                    *   57200017
*                                                                   *   57400017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   57600017
         SPACE                                                          57800017
SATLOP   DS    0H             ***** DEFINE TAG FOR BRANCHING            58000017
         BAL   BAC,SATSUB          HANDLE REPORTING FOR THIS ENTRY      58200017
         SPACE                                                          58400017
         MVI   SATTXT,BLNK         BLANK VARIABLE TEXT BUFFER FOR NEXT  58600017
*                                  - ENTRY                              58800017
         MVC   SATTXT+ONE(L23),SATTXT   CASCADE BLANK THOUGH BUFFER     59000017
         SPACE                                                          59200017
         AR    TDE,LNG             STEP TO NEXT TDIR ENTRY              59400017
         BCT   CNT,SATLOP          PROCESS REMAINING ENTRIES            59600017
         SPACE                                                          59800017
         CLI   OTYPE,ACTREQ        WAS THIS AN ACTIVE REQUEST           60000017
         BNE   SATOUT              NO, REPORTING COMPLETE - RETURN      60200017
         SPACE                                                          60400017
         LTR   ACT,ACT             WAS THERE AN ACTIVE WORK STATION     60600017
         BNZ   SATNAT              NO, TELL OPERATOR NONE ACTIVE        60800017
         SPACE 2                                                        61000017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   61200017
*                                                                   *   61400017
*              R E T U R N   L I N K A G E                          *   61600017
*                                                                   *   61800017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   62000017
         SPACE                                                          62200017
SATOUT   DS    0H             ***** DEFINE TAG FOR BRANCHING            62400017
         XR    GO,GO               SET ZERO RETURN CODE                 62600017
         L     SAV,SATSAV+FOUR     GET CALLING SAVE AREA ADDRESS        62800017
         SPACE                                                          63000017
    RETURN     (14,12),T,RC=(15)   RETURN TO CALLING ROUTINE            63200017
         EJECT                                                          63400017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   63600017
*                                                                   *   63800017
*                 W O R K   S T A T I O N                           *   64000017
*     S T A T U S   R E P O R T I N G   S U B R O U T I N E         *   64200017
*                                                                   *   64400017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   64600017
         SPACE                                                          64800017
SATSUB   DS    0H        ***** TAG FOR BRANCHING                        65000017
         TM    TDIRSWCH,TDIRRJSN   IS WORK STATION ACTIVE               65200017
         BZ    SATINA              NO, PROCESS INACTIVE                 65400017
         SPACE                                                          65600017
* GET EBCDIC UNITNAME FOR LINE ON WHICH WORK STATION IS ATTACHED        65800017
         SPACE                                                          66000017
         L     WOK,TDIRLCB         GET LINE CONTROL BLOCK ADDRESS       66200017
         LTR   WOK,WOK             IS WORK STATION REALLY ACTIVE        66400017
         BZ    SATINA              NO, HAD A MISCARRIAGE OF ACTIVITY    66600017
    USING      LCBDSECT,WOK        YES, TELL ASMBLR OF LCB DSECT        66800017
         SPACE                                                          67000017
         MVI   STATE,ACTIVE        SHOW WORK STATION IN ACTIVE STATE    67200017
         XR    ACT,ACT             REMBER ACTIVE WORK STATION REPORTED  67400017
         SPACE                                                          67600017
         L     WOK,LCBLDECB        GET DATA EVENT CONTROL BLOCK ADDRESS 67800017
    USING      IECTDECB,WOK        TELL ASSEMBLER OF DECB DSECT         68000017
         SPACE                                                          68200017
         XR    USE,USE             CLEAR REGISTER FOR NEXT INSTURCTION  68400017
         IC    USE,DECRLN          GET RELATIVE LINE NUMBER FOR LINE    68600017
         L     WOK,DECDCBAD        GET DATA CONTROL BLOCK ADDRESS       68800017
    USING      IHADCB,WOK          TELL ASSEMBLER OF DSECT              69000017
         SPACE                                                          69200017
         SLL   USE,TWO             MULTIPLY RELATIVE LINENUMBER BY FOUR 69400017
         L     WOK,DCBDEBAD        GET DATA EXTENT BLOCK ADDRESS        69600017
    DROP       WOK                 FORGET ALL AND ANY TEMP DSECTS       69800017
         SPACE                                                          70000017
         L     WOK,UCBAD(USE,WOK)  GET UNIT CONTROL BLOCK ADDR FOR LINE 70200017
         MVC   UNIT(L3),UCB(WOK)   MOVE EBCDIC UNITNAME INTO MSG TEXT   70400017
         SPACE                                                          70600017
         CLI   TDIRUSID,NOU        USER LOGGED ON WORK STATION          70800017
         BE    SATNOU              NO, WORK STATION IN INACTIVE STATE   71000017
         SPACE                                                          71200017
         MVC   USER(L3),TDIRUSID   YES, MOVE HIS USERID INTO MSG TEXT   71400017
         MVI   STATE,PROCESS       SHOW WORK STATION IN PROCESS STATE   71600017
         SPACE                                                          71800017
SATNOU   DS    0H             ***** TAG FOR BRANCHING                   72000017
         MVC   TERMID(L8),TDIRTERM  MOVE TERMID INTO MSG TEXT           72200017
         SPACE                                                          72400017
         LA    PAR,SATMSG          GET PARM LIST ADDRESS FOR IHKCBLDM   72600017
         L     GO,IHKZZLDM         GET IHKCBLDM ENTRY POINT             72800017
         BR    GO                  SEND STATUS OF WORK STATION TO       73000017
*                                  - CENTRAL OPERATOR                   73200017
         EJECT                                                          73400017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   73600017
*                                                                   *   73800017
*    P R O C E S S   I N A C T I V E   T D I R   E N T R Y          *   74000017
*                                                                   *   74200017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   74400017
         SPACE                                                          74600017
SATINA   DS    0H             ***** DEFINE TAG FOR BRANCHING            74800017
         MVI   STATE,INACTIVE      SHOW WORK STATION IN INACTIVE STATE  75000017
         CLI   OTYPE,ACTREQ        PROCESSING ACTIVE ONLY               75200017
         BNE   SATNOU              NO, PROCESS INACTIVE ENTRY           75400017
         SPACE                                                          75600017
         BR    BAC                 YES, FORGET ABOUT THIS ENTRY AND     75800017
*                                  - PROCESS NEXT IF REQUIRED           76000017
         SPACE 2                                                        76200017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   76400017
*                                                                   *   76600017
*        H A N D L E   S P E C I F I C   R E Q U E S T              *   76800017
*                                                                   *   77000017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   77200017
         SPACE                                                          77400017
SATSPEC  DS    0H             ***** DEFINE TAG FOR BRANCHING            77600017
         L     GO,IHKZZSTD         GET IHKCBSTD ENTRY POINT             77800017
         LA    PAR,RTYPE           GET PARMS FOR IHKCBSTD               78000017
         BALR  BAC,GO              SEARCH TERMINAL DIRECTORY FOR TERMID 78200017
         SPACE                                                          78400017
         LTR   GO,GO               WAS TERMID FOUND IN TDIR             78600017
         BNZ   SATTID              NO, OPERATOR CONFUSED                78800017
         SPACE                                                          79000017
         LR    TDE,PAR             SET UP TDIR ENTRY BASE               79200017
         BAL   BAC,SATSUB          HANDLE REPORTING FOR THIS ENTRY      79400017
         SPACE                                                          79600017
         B     SATOUT              HANG IT UP                           79800017
         SPACE 2                                                        80000017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   80200017
*                                                                   *   80400017
*     P R O C E S S   T E R M I D   E R R O R   M E S S A G E       *   80600017
*                                                                   *   80800017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   81000017
         SPACE                                                          81200017
SATTID   DS    0H             ***** TAG FOR BRANCHING                   81400017
         MVC   SATTXT(L8),RTYPE    MOVE INVALIDE TERMID INTO MSG TEXT   81600017
         MVC   OPTYPE(L4),SHOW     MOVE COMMAND OPERATION INTO MSG TEXT 81800017
         MVI   MSGOFF,BADTID       MOVE OFFSET INTO IHKCBLDM PARM LIST  82000017
         SPACE                                                          82200017
SATSND   DS    0H             ***** TAG FOR BRANCHING                   82400017
         LA    PAR,SATMSG          GET PARM LIST ADDRESS                82600017
         L     GO,IHKZZLDM         GET IHKCBLDM ENTRY POINT             82800017
         BALR  BAC,GO              BUILD AND DISPLAY IHK006I MESSAGE    83000017
         SPACE                                                          83200017
         B     SATOUT                                                   83400017
         EJECT                                                          83600017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   83800017
*                                                                   *   84000017
*    P R O C E S S   N U L L   R E Q U E S T                        *   84200017
*                                                                   *   84400017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   84600017
         SPACE 2                                                        84800017
SATNOT   DS    0H             ***** TAG FOR BRANCHING                   85000017
         MVC   NUL0(L13),WOKSTA    MOVE TEXT INTO MSG TEXT              85200017
         B     SATSND              RATTLE OPERATOR'S BALL               85400017
         SPACE                                                          85600017
SATNAT   DS    0H             ***** TAG FOR BRANCHING                   85800017
         MVC   SATTXT(L23),NOACT   MOVE NO ACTIVE INTO MSG TEXT         86000017
         B     SATSND              RATTLE OPERATOR'S BALL               86200017
         SPACE                                                          86400017
         EJECT                                                          86600017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   86800017
*                                                                   *   87000017
*     C O N S T A N T S   AND   W O R K / A R E A S                 *   87200017
*                                                                   *   87400017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   87600017
         SPACE 2                                                        87800017
SATSAV   DC    18F'0'              MODULE SAVE AREA                     88000017
         SPACE                                                          88200017
*   IHKCBLDM PARAMETER LIST                                             88400017
         SPACE                                                          88600017
SATMSG   DC    F'0'                DESTINATION- CENTRAL OPERATOR        88800017
         DC    X'00'                                                    89000017
MSGOFF   DC    X'2E'               OFFSET OF IHK0X7I MESSAGE (46)       89200017
         DC    X'18'               LENGTH OF MSG TEXT 24 CHARACTERS     89400017
SATTXT   DS    0CL24               VARIABLE MSG TEXT BUFFER             89600017
TERMID   DS    0CL9                TERMID FIELD                         89800017
         DC    CL3'NO'             CANNED TEXT                          90000017
NUL0     DS    0CL20               TEXT FIELD FOR NULL REQUESTS         90200017
         DC    CL6' '              PAD FOR TERMID FIELD                 90400017
OPTYPE   DS    0CL4                COMMAND OPERATION                    90600017
STATE    DC    CL2' '              OR WORK STATION STATE FIELD          90800017
UNIT     DC    CL4' '              UNIT NAME OF LINE IN USE             91000017
USER     DC    CL4' '              USERID OF USER LOGGED ON             91200017
         DC    CL5' '              PAD FOR NULL REQUESTS                91400017
         SPACE                                                          91600017
SHOW     DC    CL4'SHOW'                                                91800017
NOACT    DC    CL10'NO ACTIVE '                                         92000017
WOKSTA   DC    CL13'WORK STATIONS'                                      92200017
         SPACE 2                                                        92400017
         SPACE 2                                                        92600017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 92800017
*-*                                                                 *-* 93000017
*-*    C O M M A N D   I N P U T   R E C O R D   D S E C T          *-* 93200017
*-*                                                                 *-* 93400017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 93600017
         SPACE 2                                                        93800017
CIRD     DSECT                                                          94000017
CIMAGE   DS    CL80           COMMAND IMAGE                             94200017
CTYPE    DS    CL1            COMMAND OPERATION TYPE                    94400017
OTYPE    DS    CL1            COMMAND OPERAND TYPE                      94600017
RTYPE    DS    CL8            COMMAND REQUEST TYPE                      94800017
*                             - SPECIFIC IF NONZERO                     95000017
RESV     DS    CL5            RESERVED                                  95200017
         SPACE 2                                                        95400017
   IHKDSECT    TDIR,,,,LCB,AVT                                          95600017
         EJECT                                                          95800017
       IECTDECB                                                         96000017
         EJECT                                                          96200017
       DCBD    DSORG=BX,DEVD=BS                                         96400017
         SPACE                                                          96600017
         END                                                            96800017
