BGN2     TITLE    'IHKRJBGN - RJE STARTER MODULE  '                     00300018
IHKCHBGN CSECT                                                          00600018
         ENTRY IHKRJBGN                                                 00900018
         ENTRY IHKCHAS                                           A25573 00920020
         ENTRY IHKCBRDP,IHKCBRDE   THESE  ENTRY POINTS WILL NEVERA28210 00950019
IHKCBRDP DS    0H      BE USED SINCE THEY ARE ASSOCIATED WITH    A28210 01000019
IHKCBRDE DS    0H      SUBTASK ABEND BUT ARE NECESSARY TO ALLOW  A28210 01050019
*                      THE SAME DISPATCHER TO BE USED FOR BOTH   A28210 01100019
*                      MVT AND MFT.                              A28210 01150019
*2201180000-183000                                                 000C 01200018
* 618000                                                         A24702 01300019
* 285000,384000                                                  A25573 01350020
* 516000,519000                                                  A29513 01400020
* 606400,608600-608800                                           A28929 01450020
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   01500018
*                                                                   *   01800018
*  S T A T U S - -                                                  *   02100018
*     CHANGE LEVEL 1                                                *   02400018
*                                                                   *   02700018
*  F U N C T I O N / O P E R A T I O N - -                          *   03000018
*     THIS ROUTINE IS GIVEN CONTROL BY THE SYSTEM TASK CONTROL      *   03300018
*     ROUTINE AT RJE SYSTEM START UP.  AN ENQ MACRO IS ISSUED TO    *   03600018
*     INSURE THAT ONLY ONE RJE TASK IS ACTIVE IN THE SYSTEM.  IF    *   03900018
*     ENQ RETURNS AN INDICATION THAT ANOTHER RJE TASK IS ACTIVE,    *   04200018
*     THE CURRENT START UP REQUEST IS REJECTED, A MESSAGE WRITTEN   *   04500018
*     INFORMING THE CENTRAL OPERATOR AND RETURN MADE TO STC.  IF    *   04800018
*     NO OTHER RJE TASKS ARE ACTIVE, CONTROL IS PASSED TO THE RJE   *   05100018
*     INITIALIZATION MODULE, IHKCHNIP.  IF INITIALIZATION IS NOT    *   05400018
*     SUCCESSFUL, THE RJE RESOURCE IS FREED WITH A DEQ MACRO, AND   *   05700018
*     RETURN IS MADE TO STC.                                        *   06000018
*                                                                   *   06300018
*        A SUCCESSFUL RETURN FROM INITIALIZATION INSURES THAT THE   *   06600018
*     RJE TABLES WERE ROLLED IN, THE SYNTAX OF THE START COMMAND    *   06900018
*     WAS CORRECT AND THE CONTROL BLOCKS NECESSARY FOR USING THE    *   07200018
*     R/I AS A SUBROUTINE WERE CONSTRUCTED.  AT THIS TIME, CONTROL  *   07500018
*     IS PASSED TO IEFVH1, WHICH IN TURN GIVES CONTROL TO RJE       *   07800018
*     PROCESSING ROUTINES WITH THE R/I INCORE ACCESS METHOD 'GET'.  *   08100018
*                                                                   *   08400018
*       BEGIN RECEIVES CONTROL BACK FROM IEFVH1 WHEN EITHER THE RJE *   08700018
*     PROCESSING ROUTINES RETURN TO THE R/I END OF DATA ADDRESS OR  *   09000018
*     THE R/I HAS ENCOUNTERED AN ERROR WHERE IT CANT PROCEED.  IF   *   09300018
*     RETURN IS NOT A RESULT OF EODAD, THE R/I RETURNS A NONZERO    *   09600018
*     RETURN CODE.                                                  *   09900018
*                                                                   *   10200018
*       REGARDLESS OF HOW CONTROL WAS RETURNED TO BEGIN BY THE      *   10500018
*     R/I AND ALSO AFTER UNSUCCESSFUL INITIALIZATION ATTEMPTS,      *   10800018
*     BEGIN PASSES CONTROL TO IHKCHUCK TO CLOSEDOWN AND CLEANUP     *   11100018
*     THE RJE PARTITION.  WHEN CONTROL RETURNS FROM IHKCHUCK, THE   *   11400018
*     SUCCESS OF THE VENTURE IS CHECKED.  IF THE RETURN WAS GOOD    *   11700018
*     FROM BOTH IEFVH1 AND IHKCHUCK, THE NORMAL CLOSEDOWN MESSAGE   *   12000018
*     IS DISPLAYED FOR THE CENTRAL OPERATOR.  IF THE R/I RETURNED   *   12300018
*     A BAD RETURN CODE, AN ABNORMAL CLOSEDOWN MESSAGE IS DISPLAYED.*   12600018
*     IHKCHUCK HANDLES DISPLAYING ITS OWN MESSAGES IF ERRORS ARE    *   12900018
*     ENCOUNTERED IN CLOSEDOWN.                                     *   13200018
*                                                                   *   13500018
*       AFTER DETERMINING WHETHER OR NOT A MESSAGE IS REQUIRED ON   *   13800018
*     RETURN FROM IHKCHUCK, THE RJE RESOURCE IS FREED BY ISSUING    *   14100018
*     A DEQ MACRO, AND RETURN MADE TO STC.                          *   14400018
*                                                                   *   14700018
*                                                                   *   15000018
*  E N T R Y   P O I N T S - -                                      *   15300018
*                                                                   *   15600018
*     IHKCHAS IS THE ENTRY POINT USED BY STAE AT ABEND TIME.     A25573 15650020
*     IHKEODAD IS A DUMMY ENTRY POINT - CORRESPONDS TO THE       A24702 15700019
*        SUBTASK ABEND ENTRY IN IHKXJBGN.                        A24702 15800019
*     IHKRJBGN IS THE ENTRY POINT FOR START UP. IT IS ALSO       A24702 15900019
*     DEFINED AS THE ENTRY POINT FOR THE RJE LOAD MODULE, ALSO OF   *   16200018
*     THE SAME NAME, WITH THE LINKAGE EDITOR ENTRY STATEMENT.       *   16500018
*                                                                   *   16800018
*                                                                   *   17100018
*  I N P U T - -                                                    *   17400018
*                                                                   *   17700018
*     THE FOLLOWING PARAMETER LIST:                                000C 18100018
*                                                                   *   18600018
*        WORD ONE  - PARAMETER BUFFER ADDRESS OF THE EXEC STATEMENT *   18900018
*                    PARAMETER FIELD THE FIRST TWO BYTES OF WHCIH   *   19200018
*                    CONTAIN THE NUMBER OF BYTES OF PARAMETERS PLUS *   19500018
*                    THE TWO LENGTH BYTES                           *   19800018
*        WORD TWO  - THE COMMUNICATIONS ECB ADDRESS WHICH IS        *   20100018
*                    POSTED WHEN THE COMMUNICATIONS TASK FINDS AN   *   20400018
*                    RJE CENTRAL COMMAND.                           *   20700018
*        WORD THREE- THE COMMAND INPUT BUFFER ADDRESS CONTAININING  *   21000018
*                    THE PARAMETERS ON THE START COMMAND WHICH      *   21300018
*                    REFERENCED AN RJE PROCEDURE                    *   21600018
*        WORD FOUR - POINTER TO CONSOLE ID                         000C 21700018
*                                                                   *   21900018
*                                                                   *   22200018
*  O U T P U T - -                                                  *   22500018
*                                                                   *   22800018
*     NORMAL CLOSEDOWN MESSAGE IF THINGS WENT WELL                  *   23100018
*     START RJE REJECTED IF RJE IS ALREADY AN ACTIVE TASK IN THE    *   23400018
*     SYSTEM                                                        *   23700018
*     ABNORMAL CENTRAL CLOSEDOWN MESSAGE IF THE R/I RETURNS A       *   24000018
*     NONZERO RETURN CODE.                                          *   24300018
*                                                                   *   24600018
*                                                                   *   24900018
*  E X T E R N A L   R O U T I N E S - -                            *   25200018
*                                                                   *   25500018
*     IHKCHNIP - RJE INITIALIZATION                                 *   25800018
*     IEFVH1   - R/I USED AS A SUBROUTINE                           *   26100018
*     IHKCBLDM - BUILD MESSAGES TO DISPLAY FOR CENTRAL OPERATOR     *   26400018
*     IHKCHUCK - RJE CLOSEDOWN AND CLEAN UP                         *   26700018
*                                                                   *   27000018
*  E X I T S - -                                                    *   27300018
*                                                                   *   27600018
*     NORMAL- RETURN TO SYSTEM TASK CONTROL WITH ZERO RETURN CODE   *   27900018
*                                                                   *   28200018
*     ERROR- RETURN TO STAE FOR ABEND                            A25573 28500020
*                                                                   *   28800018
*  T A B L E S / W O R K   A R E A S - -                            *   29100018
*                                                                   *   29400018
*     STANDARD 18 WORD SAVE AREA                                    *   29700018
*                                                                   *   30000018
*  A T T R I B U T E S - -                                          *   30300018
*                                                                   *   30600018
*     SERIALLY REUSEABLE                                            *   30900018
*                                                                   *   31200018
*                                                                   *   31500018
*  N O T E S - -                                                    *   31800018
*                                                                   *   32100018
*     N/A                                                           *   32400018
*                                                                   *   32700018
*                                                                   *   33000018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   33300018
     EJECT                                                              33600018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   33900018
        SPACE                                                           34200018
*    S Y M B O L I C   R E G I S T E R S   U S E D   BY   T H I S       34500018
*     M O D U L E                                                       34800018
         SPACE 2                                                        35100018
ZIP      EQU   0              WORK REGISTER                             35400018
PAR      EQU   1              PARAMETER LIST ADDRESS FOR LINKAGE        35700018
WOK      EQU   2              GENERAL WORK REGISTER                     36000018
AVT      EQU   3              RJE ADDRESS TABLE DSECT BASE              36300018
SWH      EQU   4              ERROR MSG SENT ALREADY REMBERER           36600018
NU       EQU   5              NOT USED                                  36900018
NU0      EQU   6              NOT USED                                  37200018
NU1      EQU   7              NOT USED                                  37500018
NU2      EQU   8              NOT USED                                  37800018
NU3      EQU   9              NOT USED                                  38100018
NU4      EQU   10                  WORK REGISTER FOR STAE ENTRY  A25573 38400020
NU5      EQU  11              NOT USED                                  38700018
BAS      EQU  12              MODULE BASE REGISTER                      39000018
SAV      EQU  13              SAVE AREA ADDRESS REGISTER                39300018
BAC      EQU  14              RETURN POINT REGISTER FOR LINKAGE         39600018
GO       EQU  15              ENTRY POINT REGISTER FOR LINKAGE AND      39900018
*                             - RETURN CODE CONTAINER ON RETURN         40200018
        SPACE 2                                                         40500018
FOUR     EQU   4                                                        40800018
ATE      EQU   8                                                        41100018
TWLV     EQU   12                                                       41400018
O19      EQU   19                                                       41700018
O40      EQU   40                                                       42000018
O72      EQU   72                                                       42300018
ZERO     EQU   0                   INDICATES NO VALUE            A28929 42400020
ABNOCLOS EQU   X'01'               BIT FOR ABNORMAL CLOSEDOWN    A28929 42500020
        SPACE   2                                                       42600018
*     E N T R A N C E   L I N K A G E   AND   G E T   P A R M S         42900018
        SPACE                                                           43200018
IHKRJBGN DS    0H                                                       43500018
         STM   BAC,BAS,TWLV(SAV)   SAVE SYSTEM TASK CONTROL'S REGS      43800018
*                                  - FOR RETURN LINKAGE                 44100018
         BALR  BAS,ZIP             SET UP MODULE ADDRESSABILITY         44400018
        SPACE                                                           44700018
         USING *,BAS               TELL ASSEMBLER CHOICE OF BASE REG    45000018
BASE     EQU   *                                                 A25573 45100020
         B     AROUNDID            BRANCH AROUND IDENTIFIER             45300018
        SPACE                                                           45600018
         DC    C'IHKCHBGN'         MODULE IDENTIFIER                    45900018
        SPACE                                                           46200018
AROUNDID LA    WOK,BGNSAV          GET BEGIN'S SAVE AREA ADDRESS        46500018
         ST    WOK,ATE(SAV)        PUT IT IN STC SAVE AREA              46800018
         ST    SAV,FOUR(WOK)       PUT STC SAVE AREA ADDRESS IN         47100018
*                                  - BEGIN SAVE AREA                    47400018
         LR    SAV,WOK             SET UP SAVE REG FOR MODULE           47700018
*                                  - LINKAGES                           48000018
         L     AVT,BGNCACOM        GET ADDRESS OF RJE ADDRESSES         48300018
*                                  - AND USE AS DSECT BASE              48600018
        SPACE                                                           48900018
         USING IHKZZAVT,AVT        TELL ASSEMBLER ABOUT THIS DSECT      49200018
        SPACE                                                           49500018
         ST    PAR,IHKZZSCB        PLACE SPL  IN THE AVT FOR RJE USE    49800018
         USING CIB,WOK                                           A29513 49850020
         EXTRACT  CPL,FIELDS=COMM                                A29513 49900020
         L     PAR,CPL                                           A29513 49950020
         L     WOK,FOUR(PAR)       LOAD POINTER TO PARM FIELD    A29513 50000020
         MVC   IHKZZOFS(1),CIBCONID GET CIB POINTER              A29513 50050020
        SPACE   2                                                       50100018
*    I N S U R E   T H A T   R J E   IS NOT   A L R E A D Y             50400018
*     A C T I V E   IN THE   S Y S T E M                                50700018
        SPACE                                                           51000018
    ENQ      (IHKRJE,R$,,2,SYSTEM),RET=USE                              51300018
        SPACE                                                           52200018
         LR    SWH,SAV             REMBER NO MSG SENT YET               52500018
         LTR   GO,GO               IS RJE ALREADY ACTIVE                52800018
         BNZ   ONLYONE             YES, SORRY ABOUT THAT CHIEF --       53100018
*                                  - ONLY ONE RJE TASK AT A TIME        53400018
        SPACE 2                                                         53700018
*    I N I T I A L I Z E   THE   R J E   T A S K                        54000018
       SPACE                                                            54300018
         LA    PAR,BGNCACOM        GIVE RJENIP ITS PARMS                54600018
    LINK       EPLOC=BGNCBNIP      GIVE OLD NIP A GO AT IT              54900018
        SPACE                                                           55200018
         LTR   GO,GO               WAS INITIALIZE SUCCESSFUL            55500018
         BNZ   BADSHOW1            NO FORGET ABOUT RUNNING RJE          55800018
         LR    NU4,PAR             SAVE ADDRESS RETURNED FROM NIPA25573 55900020
         STAE  IHKCHAS,CT,PURGE=HALT   TO GET CONTROL AT ABEND   A25573 56000020
        SPACE   2                                                       56100018
*      G O   L E T   R J E   H A V E   A   G O   AT   I T               56400018
         LR    PAR,NU4             GIVE R/I ITS PARMS            A25573 56500020
       SPACE                                                            56700018
    LINK       EPLOC=BGNEFVH1      ENTER R/I AS A SUBROUTINE            57000018
        SPACE                                                           57300018
         ST    PAR,IHKZZNEL        PLACE R/I NEL ADDRESS IN AVT         57600018
         L     NU3,IHKZZRCS        GET ADDRESS OF STOPBITS       A28929 57630020
         XR    NU4,NU4             TELL IHKCHUCK OF NORMAL CLOSE-A28929 57660020
*                                  DOWN BY PUTTINE ZERO IN REG4  A28929 57690020
         TM    ZERO(NU3),ABNOCLOS  IS THIS ABNORMAL CLOSEDOWN    A28929 57720020
*                                  DID RJE CHOSE TO ABEND ITSELF A28929 57750020
         BZ    NOTABNO             NO, DON'T TELL IHKCHUCK       A28929 57780020
         LA    NU4,NOTABNO         NOTE THIS FOR IHKCHUCK        A28292 57810020
*                                  BY PUTTING PLUS IN REG 4      A28929 57840020
NOTABNO  EQU   *                                                 A28929 57870020
         LTR   GO,GO               TEST R/I RETURN CODE FOR OK          57900018
         BZ    BADSHOW             CONTRARY TO POPULAR OPINION          58200018
*                                  - EVERYTHING FINE SO FAR             58500018
        SPACE                                                           58800018
         MVI   MSGOFF,O19          NOT OK, TELL OPERATOR ABOUT R/I ERR  59100018
         BAL   BAC,SNDMSG          SEND ABNORMAL CLOSEDOWN TO OP        59400018
        SPACE                                                           59700018
    WTO        ,MF=(E,(1))         GIVE THE BEAUTY TO OPERATOR          60000018
        SPACE                                                           60300018
BADSHOW1 XR    SWH,SWH             REMBER ERROR MSG SENT                60600018
         SR    NU4,NU4             SET NORMAL PROCESSING SWITCH  A25573 60620020
         B     BADSHOW             BYPASS STAE PROCESSING        A28929 60640020
IHKCHAS  EQU   *                   ENTRY POINT FOR STAE AT ABEND A25573 60660020
         USING *,GO                SET UP TEMPORARY BASE         A25573 60680020
         STM   BAC,BAS,TWLV(SAV)   SAVE REGS FOR STAE            A25573 60700020
         L     BAS,STAEBASE        PICK UP BGN'S BASE REG        A25573 60720020
         DROP  GO                                                A25573 60740020
         LA    WOK,BGNSAV          GET BGN'S SAVE AREA ADDRESS   A25573 60760020
         ST    WOK,ATE(SAV)        PUT IT IN STAE SAVE AREA      A25573 60780020
         ST    SAV,FOUR(WOK)                                     A25573 60800020
         LR    SAV,WOK             SET UP NEW SAVE REG           A25573 60820020
         LNR   NU4,BAS             SET NEGATIVE PARM FOR CHUCK   A25573 60840020
        SPACE   2                                                       60900018
*     B R I N G   IN   C H U C K   TO   C L E A N - U P                 61200018
        SPACE                                                           61500018
IHKEODAD DS    0H                  SHOULD NOT OCCUR - MVT ONLY   A24702 61700019
BADSHOW  LA    PAR,UCKPARMS        GET ADDRESS OF CHUCK PARMS    A24702 61900019
         ST    NU4,UCKTYPE         SET TYPE OF OPERATION WANTED  25573  62000020
    LINK       EPLOC=BGNCHUCK      GET CHUCK IN AND PASS CONTROL        62100018
        SPACE                                                           62400018
         LTR   GO,GO               HOW DID THINGS GO WITH CHUCK         62700018
         BNZ   DEQ                 CHUCK HAD TROUBLES, DUCK OUT         63000018
        SPACE                                                           63300018
*    CHUCK CHECKED OUT OK, BUT DID RJE HAVE AN EARLIER PROBLEM          63600018
        SPACE                                                           63900018
         LTR   SWH,SWH             HAS ERROR MSG ALREADY BEEN SENT      64200018
         BZ    DEQ                 HANG IT UP, MSG SENT                 64500018
        SPACE                                                           64800018
         MVI   MSGOFF,O40          SELECT CLOSEDOWN MESSAGE             65100018
*                          IHK016I RJE CLOSED DOWN                      65400018
         BAL   BAC,SNDMSG          GO BUILD A MESSAGE                   65700018
        SPACE                                                           66000018
DEQNEXT  DS    0H                                                       66300018
    WTO        ,MF=(E,(1))         SEND GREETINGS TO OPERATOR           66600018
        SPACE   2                                                       66900018
*    R E L E A S E   R J E   FOR   S U B S E Q U E N T                  67200018
*     S T A R T S                                                       67500018
        SPACE                                                           67800018
DEQ      DS    0H                                                       68100018
    DEQ         (IHKRJE,R$,2,SYSTEM),RET=HAVE   FREE RJE RESOURCE       68400018
         SPACE 2                                                        68700018
*      R E T U R  N   L I N K A G E                                     69000018
        SPACE                                                           69300018
         L     SAV,BGNSAV+FOUR     GET STC SAVE AREA ADDRESS            69600018
         XR    GO,GO               SET RETURN CODE                      69900018
    RETURN     (14,12),T,RC=(15)   RETURN TO STC                        70200018
        SPACE   2                                                       70500018
*    H A N D L E   R E Q U I R E D   E R R O R   M E S S A G E S        70800018
        SPACE                                                           71100018
ONLYONE  MVI   MSGOFF,O72          SELECT REJECTED MSG                  71400018
        SPACE                                                           71700018
SNDMSG1  LA    BAC,DEQNEXT         GET RETURN POINT                     72000018
        SPACE                                                           72300018
SNDMSG   LA    PAR,BGNMSG          GET BLDM PARM LIST ADDR              72600018
         L     GO,IHKZZLDM         GET ENTRY POINT FOR BLDM             72900018
         BR    GO                  GO GET MSG BUILT                     73200018
      EJECT                                                             73500018
*    C O N S T A N T S   AND   W O R K   A R E A S                      73800018
BGNSAV   DC    18F'0'                                                   74100018
STAEBASE DC    A(BASE)             SO STAE CAN USE BASE REG      A25573 74110020
         SPACE 1                                                 A25573 74120019
*   NOTE: THE PARAMETER LIST FOR IHKCHUCK IS NOW THE FOLLOWING   A24702 74140019
*        TWO WORDS.                                              A24702 74160019
UCKPARMS DC    A(IHKCACOM)         AVT ADDRESS                   A24702 74180019
UCKTYPE  DC    F'0'                INDICATOR OF OPERATION WANTED A24702 74200019
*                       ZERO - NORMAL CLOSEDOWN                  A24702 74220019
*                       PLUS - ABNORMAL CLOSEDOWN                A28929 74223020
*                       MINUS - STAE PROCESSING ( RJE ABEND )    A25573 74226020
         DC    V(IHKCDLCB)         POINTER TO FIRST LCB          A28929 74229020
         DC    V(IHKCDNOL)         POINTER TO NUMBER OF LCBS     A28929 74232020
         DC    V(IHKCDLGL)         POINTER TO LENGTH OF LCBS     A28929 74235020
         SPACE 2                                                 A24702 74240019
         ORG   *-8                 DUMMY UP ECBS FOR MVT SUBTASK A24702 74260019
IHKBGNIN DS    2F                    DSECT IN RJE DISPATCHER     A24702 74280019
         DC    2F'0'               MAKE SURE THESE ECBS ARE NOT  A24702 74300019
*                                    POSTED IN MFT               A24702 74320019
         ENTRY IHKBGNIN,IHKEODAD                                 A24702 74340019
BGNCACOM DC    A(IHKCACOM)         ADDRESS OF RJE AVT                   74400018
         DC    A(IHKCHRDR)         ADDRESS OF READER                    74700018
       SPACE                                                            75000018
BGNMSG   DC    X'FFFFFFFF'         INDICATE RETURN                      75300018
         DC    X'00'               PAD                                  75600018
MSGOFF   DC    X'00'               OFFSET OF MSG IN DIRECTORY           75900018
MSGLNG   DC    X'00'               LENGTH OF VARIABLE TEXT              76200018
       SPACE                                                            76500018
IHKRJE   DC    CL8'IHKRJE'                                              76800018
R$       DC    CL2'R$'                                                  77100018
       SPACE                                                            77400018
BGNEFVH1 DC    CL8'IEFVH1'                                              77700018
BGNCHUCK DC    CL8'IHKCHUCK'                                            78000018
BGNCBNIP DC    CL8'IHKCHNIP'                                            78300018
       SPACE                                                            78600018
         EXTRN      IHKCACOM,IHKCHRDR                                   78900018
CPL      DS    0F                                                A29513 78950020
ECB      DC    A(0)                                              A29513 79000020
ACIB     DC    A(0)                                              A29513 79050020
CIB      DSECT                                                   A29513 79100020
         IEZCIB                                                         79150020
       SPACE                                                            79200018
     IHKDSECT  ,,,,,AVT                                                 79500018
         END                                                            79800018
