CNTM     TITLE 'IHKCHCNT - CENOUT COMMAND PROCESSOR'                    00100019
IHKCHCNT CSECT                                                          00200019
* 162000,331000                                                  A26539 00250019
*********************************************************************** 00300019
*                                                                     * 00400019
*STATUS: CHANGE LEVEL 0                                               * 00500019
*FUNCTION/OPERATION:                                                  * 00600019
*   THIS ROUTINE IS CALLED TO PROCESS THE CENOUT CENTRAL COMMAND. IT  * 00700019
*REMOVES THE OUTPUT FOR A SPECIFIED JOB FROM THE RJE OUTPUT QUEUE AND * 00800019
*ENQUEUES IT ON THE CENTRAL SYSOUT CLASSES AS SPECIFIED IN THE JED    * 00900019
*TABLE. THE OUTPUT CAN THEN BE PROCESSED BY THE CENTRAL SYSTEM OUTPUT * 01000019
*WRITERS. AFTER THE OUTPUT HAS BEEN ENQUEUED ON THE CENTRAL QUEUES,   * 01100019
*THIS ROUTINE ISSUES A MESSAGE TO THE CENTRAL OPERATOR INDICATING     * 01200019
*WHICH SYSOUT CLASSES WERE USED. CENOUT THEN TURNS OFF THE DISCON-    * 01300019
*TINUED OUTPUT BIT IN THE TERMINAL DIRECTORY IN CASE THE PROCESSED    * 01400019
*JOB HAD BEEN PARTIALLY TRANSMITTED BY THE RJE WRITER. THIS STOPS THE * 01500019
*WRITER FROM TRYING TO CONTINUE AN ALREADY PROCESSED, PARTIALLY TRANS-* 01600019
*MITTED, JOB. FINALLY, THE FAST TABLE ENTRY FOR THIS JOB IS CLEARED.  * 01700019
*THE FOLLOWING CASES ARE EXCEPTIONS TO THE ABOVE PROCEDURE:           * 01800019
*                                                                     * 01900019
*A-IF THE SPECIFIED JOB IS NOT IN THE SYSTEM, A 'JOB NOT IN SYSEM'    * 02000019
*MESSAGE IS RETURNED TO THE CENTRAL OPERATOR.                         * 02100019
*                                                                     * 02200019
*B-IF THE SPECIFIED JOB IS NOT COMPLETE, A 'JOB NOT COMPLETE' MESSAGE * 02300019
*IS SENT TO THE CENTRAL OPERATOR.                                     * 02400019
*                                                                     * 02500019
*C-IF THE OUTPUT IS PRESENTLY ENQUEUED FOR AN ACTIVE TERMINAL,        * 02600019
*(I.E., SOMEONE HAS ALREADY REQUESTED THE OUTPUT,) A 'JOB WAITING DE- * 02700019
*LIVERY' MESSAGE IS RETURNED TO INDICATE THAT THE OUTPUT CANNOT BE    * 02800019
*DELIVERED TO CENTRAL.                                                * 02900019
*                                                                     * 03000019
*ENTRY POINTS:                                                        * 03100019
*   IHKCHCNT IS THE ONLY ENTRY POINT.  CALLING SEQUENCE IS AS FOLLOWS:* 03200019
*        LOAD EP=IHKCHCNT                                             * 03300019
*        LR    15,0                                                   * 03400019
*        LA    1,PARAMETER LIST                                       * 03500019
*        BALR   14,15                                                 * 03600019
*INPUT:                                                               * 03700019
*   INPUT IS THE FOLLOWING PARAMETER LIST:                            * 03800019
*        WORD0-N/A                                                    * 03900019
*        WORD1-ADDRESS OF COMMAND CARD IMAGE AND EXPANSION            * 04000019
*        WORD2 AND FOLLOWING-A LIST OF ADDRESSES OF RJE SERVICE       * 04100019
*ROUTINES.                                                            * 04200019
*                                                                     * 04300019
*OUTPUT: N/A                                                          * 04400019
*                                                                     * 04500019
*EXTERNAL ROUTINES:                                                   * 04600019
*        IHKCBLDM-BUILDS SYSTEM MESSAGES                              * 04700019
*        IHKCBSTD-SEARCHES TERMINAL DIRECTORY                         * 04800019
*        IHKCCSUD-SEARCHES USER DIRECTORY                             * 04900019
*        IHKCDJMR-FAST TABLE MANAGER                                  * 05000019
*        IHKCDSCH-SEARCHES FAST TABLE FOR JOB NAME                    * 05100019
**       IEFQMSSS-O/S QUEUE MANAGER ROUTINES                          * 05200019
*        IEFQDELE-O/S QUEUE SPACE DELETION ROUTINE                    * 05300019
*        IHKAADSP-DUMMY PASS THROUGH DISPATCHER                       * 05400019
*                                                                     * 05500019
*EXITS-NORMAL:                                                        * 05600019
*   NORMAL RETURN IS BY REGISTER 14 TO THE CALLING ROUTINE WITH A     * 05700019
*CODE OF ZERO IN REGISTER 15.                                         * 05800019
*                                                                     * 05900019
*EXITS-ERROR: N/A                                                     * 06000019
*                                                                     * 06100019
*TABLES/WORK AREAS:                                                   * 06200019
*   A 98 BYTE WORK AREA IS USED TO RECEIVE THE JED TABLE ENTRY. ONE   * 06300019
*176 BYTE BUFFER   IS USED FOR READING AND WRITING SMB/DSB'S WITH     * 06400019
*THE O/S QUEUE MANAGER.  ONE  52 BYTE QUEUE MANAGER PARAMETER AREA    * 06500019
*IS USED TO INTERFACE WITH THE O/S QUEUE MANAGER.                    *  06600019
*                                                                     * 06700019
*ATTRIBUTES:                                                          * 06800019
*   SERIALLY REUSABLE, NON-RESIDENT.                                  * 06900019
*                                                                     * 07000019
*NOTES:                                                               * 07100019
*   THE OPERATION OF THIS ROUTINE DEPENDS UPON AN INTERNAL REPRESENT- * 07200019
*   ATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE    * 07300019
*   ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED SO THAT   * 07400019
*   REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT * 07500019
*   IN A CORRECT MODULE FOR THE NEW DEFINTIONS.                       * 07600019
*                                                                     * 07700019
*********************************************************************** 07800019
*********************************************************************** 07900019
*                                                                     * 08000019
*              REGISTER ASSIGNMENTS                                   * 08100019
*                                                                     * 08200019
*********************************************************************** 08300019
R0       EQU   0                   SUPERVISOR PARAMETER REGISTER        08400019
R1       EQU   1                   PARAMETER LIST REGISTER              08500019
R2       EQU   2                   GENERAL WORK REGISTER                08600019
R3       EQU   3                   INDEX FOR SYSOUT CLASSES             08700019
R4       EQU   4                   ADDRESS OF CARD IMAGE                08800019
R5       EQU   5                   ADDRESS OF QUEUE MANAGER ROUTINES    08900019
R6       EQU   6                   BASE FOR DSECT OF QMPAS              09000019
R7       EQU   7                   ADDRESS OF READ QMPA                 09100019
R8       EQU   8                   ADDRESS OF FAST TABLE                09200019
R9       EQU   9                   ADDRESS OF INPUT PARAMETER LIST      09300019
R10      EQU   10                  ADDRESS OF JED TABLE                 09400019
R11      EQU   11                  INTERNAL LINK REGISTER               09500019
R12      EQU   12                  BASE REGISTER                        09600019
R13      EQU   13                  SAVE AREA REGISTER                   09700019
R14      EQU   14                  RETURN POINT REGISTER                09800019
R15      EQU   15                  ENTRY POINT REGISTER                 09900019
*********************************************************************** 10000019
*                                                                       10100019
         SAVE  (14,12),,*                                               10200019
         BALR  R12,R0              ESTABLISH ADDRESSABILITY             10300019
         USING *,R12                                                    10400019
         LA    R2,SAVE             CHAIN SAVE AREAS                     10500019
         ST    R2,8(R13)            *                                   10600019
         ST    R13,4(R2)            *                                   10700019
         LR    R13,R2               *                                   10800019
         NI    SWITCH,X'00'        INITIALIZE SWITCHES                  10900019
         LA    R3,26                AND SYSOUT CLASS POINTER            11000019
         LR    R9,R1               SAVE POINTER TO PARAMETERS           11100019
         USING QMPASECT,R6         SET UP ADDRESSIBILITY FOR QMPASECT   11200019
         USING IHKZZAVT,R9                                              11300019
         L     R4,4(R9)            ESTABLISH ADDRESSABILITY FOR         11400019
         USING DCARD,R4             CARD IMAGE                          11500019
         LA    R1,JBNAME           POINTER TO JOB NAME                  11600019
         L     R15,SCH             REQUEST SEARCH OF FAST TABLE FOR     11700019
         BALR  R14,R15              JOB NAME                            11800019
         LTR   R15,R15             IF RETURN CODE IS NOT ZERO,          11900019
         BNZ   CNT0200              NO JOB WAS FOUND                    12000019
         LR    R8,R1               ESTABLISH ADDRESSABILITY FOR         12100019
         USING FASTAB,R8            FAST TABLE                          12200019
         TM    FASTDSB,X'80'       IF JOB NOT COMPLETE,                 12300019
         BZ    CNT0210              ISSUE MESSAGE                       12400019
         TM    FASTJIB,X'80'       IF OUTPUT IS IMMEDIATE,              12500019
         BO    CNT0213              CHECK FOR BYPASSED OUTPUT           12600019
         TM    FASTDSB,X'60'       IF OUTPUT HAS BEEN ENQUEUED,         12700019
         BC    7,CNT0215            REQUEST CANNOT BE SERVICED          12800019
*                                                                       12900019
CNT0002  ST    R1,JDTB+2           SET PARAMETERS FOR RETRIEVAL OF      13000019
         LA    R1,JDTB              JED TABLE                           13100019
         ST    R1,JDTB+6            *                                   13200019
         LA    R1,JDTB+2            *                                   13300019
         L     R15,JMR             REQUEST JED TABLE                    13400019
         BALR  R14,R15                                                  13500019
         LTR   R15,R15             IF JED ERROR OCCURRED,               13600019
         BNZ   CNTJED               GO TO ERROR ROUTINE                 13700019
         LA    R10,JDTB-2          ESTABLISH ADDRESSABILITY FOR         13800019
         USING JEDTAB,R10           JED TABLE                           13900019
         LA    R7,DQMPA            ESTABLISH ADDRESSABILITY FOR         14000019
         USING IOPARAMS,R7          QUEVE MANAGER PARAMETERS FOR READ   14100019
         MVI   QMPOP,QMREAD        READ FUNCTION CODE                   14200019
         LA    R2,JEDTQMPE         PUT ADDRESS OF EXTENTION IN          14300019
         ST    R2,QMPCL             PARAMETER LIST                      14400019
         MVI   QMPCL,X'11'         READ ONLY ONE RECORD                 14500019
         LA    R2,RDBUFF           PUT ADDRESS OF BUFFER                14600019
         ST    R2,JEDTQMPE          IN EXTENTION                        14700019
         L     R5,IHKZZSSS             GET AND SAVE ADDRESS OF Q MGR    14800019
*                                                                       14900019
CNT0005  LR    R1,R7               ADDRESS OF PARAMETER AREA            15000019
         LR    R15,R5              ADDRESS OF QUEUE MANAGER             15100019
         BALR  R14,15              READ RECORD                          15200019
         LTR   R15,R15             IF CODE IS NOT ZERO,                 15300019
         BNZ   CNTERR               ERROR OCCURRED                      15400019
         MVC   RDNXT(3),RDBUFF+4   SAVE TTR OF NEXT RECORD TO READ      15500019
         CLI   RDBUFF+5,X'00'      IF NOT LAST RECORD,                  15600019
         BNE   CNT0010              CONTINUE PROCESSING                 15700019
         OI    SWITCH,X'10'        INDICATE LAST RECORD                 15800019
         CLI   RDBUFF+14,X'00'     IF RECORD IS ZERO RECORD,            15900019
         BE    CNT0080              GO TO LAST RECORD ROUTINE           16000019
*                                                                       16100019
CNT0010  DS    0H                                                A26539 16150019
CNTDSB15 EQU   X'15'               IDENTIFICATION OF DSB         A26539 16200019
         CLI   RDBUFF+3,CNTDSB15   IF SMB,                       A26539 16250019
         BNE   CNT0070              GET MESSAGE CLASS                   16300019
         IC    R2,2(R3,R10)        GET SYSOUT CLASS                     16400019
         LA    R3,1(R3)            UPDATE SYSOUT CLASS INDEX            16500019
         CH    R3,EXCESS           IF NO CLASSES REMAINING,             16600019
         BH    CNT0030              USE PRINTER CLASS                   16700019
*                                                                       16800019
CNT0020  STC   R2,CLASS            PUT CLASS IN KNOWN LOCATION          16900019
         L     R2,CLASWRD          GET ADDRESS OF SYSOUT CLASSES        17000019
         CLC   CLASS,2(R2)         IF CLASS IS USER EXIT,               17100019
         BE    CNT0120              GO TO USER EXIT ROUTINE             17200019
         CLC   CLASS,1(R2)         IF CLASS IS PUNCH,                   17300019
         BE    CNT0160              GO TO PUNCH ROUTINE                 17400019
*********************************************************************** 17500019
*                                                                     * 17600019
*              PROCESS PRINTER CLASS                                  * 17700019
*                                                                     * 17800019
*********************************************************************** 17900019
CNT0030  DS    0H                                                       18000019
         LA    R6,QMPAA            SET DSECT FOR QMPAA                  18100019
         TM    SWITCH,X'80'        IF USE SWITCH IS NOT ZERO,           18200019
         BO    SUB2                GO TEST FOR SMB                      18300019
         OI    SWITCH,X'80'        TURN ON USE SWITCH FOR PRINTER       18400019
         XC    QMPAA+8(24),QMPAA+8 INITIALIZE PARAMETER AREA            18500019
         MVC   QMPAA+15(1),4(R2)   INDICATE PRINTER CLASS IN QMPA       18600019
         B     SUB1                GO TO SUBROUTINE 1                   18700019
*********************************************************************** 18800019
*                                                                     * 18900019
*              PROCESS PUNCH CLASS                                    * 19000019
*                                                                     * 19100019
*********************************************************************** 19200019
CNT0160  DS    0H                                                       19300019
         LA    R6,QMPAB            SET DSECT FOR QMPAB                  19400019
         TM    SWITCH,X'40'        IF USE SWITCH IS NOT ZERO,           19500019
         BO    SUB2                TEST FOR SMB                         19600019
         OI    SWITCH,X'40'        TURN ON USE SWITCH                   19700019
         XC    QMPAB+8(24),QMPAB+8 INITIALIZE PARAMETER AREA            19800019
         MVC   QMPAB+15(1),6(R2)   INDICATE PUNCH CLASS                 19900019
         B     SUB1                GO TO SUBROUTINE 1                   20000019
*********************************************************************** 20100019
*                                                                     * 20200019
*              PROCESS USER EXIT CLASS                                * 20300019
*                                                                     * 20400019
*********************************************************************** 20500019
CNT0120  DS    0H                                                       20600019
         LA    R6,QMPAC            SET DSECT FOR QMPAC                  20700019
         TM    SWITCH,X'20'        IF USE SWITCH IS NOT ZERO,           20800019
         BO    SUB2                TEST FOR SMB                         20900019
         OI    SWITCH,X'20'        TURN ON USE SWITCH                   21000019
         XC    QMPAC+8(24),QMPAC+8 INITIALIZE PARAMETER AREA            21100019
         MVC   QMPAC+15(1),5(R2)   INDICATE USER EXIT CLASS             21200019
         B     SUB1                GO TO SUBROUTINE 1                   21300019
*********************************************************************** 21400019
*                                                                     * 21500019
*              MESSAGE CLASS PROCESSING                               * 21600019
*                                                                     * 21700019
*********************************************************************** 21800019
CNT0070  IC    R2,JEDTSOUT         GET MESSAGE CLASS                    21900019
         B     CNT0020                                                  22000019
*********************************************************************** 22100019
*                                                                     * 22200019
*              CLEAN UP AND RETURN TO CALLER                          * 22300019
*                                                                     * 22400019
*********************************************************************** 22500019
CNT0080  XC    RDBUFF(176),RDBUFF  CREATE ZERO RECORD                   22600019
         LA    R2,RDBUFF           ADDRESS OF BUFFER                    22700019
         MVI   MSGPARA+15,C' '     BLANK OUT CLASSES IN MESSAGE         22800019
         MVC   MSGPARA+16(5),MSGPARA+15                                 22900019
         L     R3,CLASWRD          ADDRESS OF CLASSES                   23000019
         TM    SWITCH,X'80'        IF PRINTER USE CLASS IS ZERO,        23100019
         BZ    CNT0090              SKIP THIS CLASS                     23200019
         MVC   QMPAA+15(1),4(R3)   CLASS FOR PRINTER                    23300019
         LA    R6,QMPAA            SET DSECT FOR QMPAA                  23400019
         BAL   R11,SUB4            GO TO SUBROUTINE 4                   23500019
         MVC   MSGPARA+16(1),0(R3) CLASS FOR PRINTER IN MESSAGE         23600019
*                                                                       23700019
CNT0090  TM    SWITCH,X'40'        IF USE FOR PUNCH IS ZERO,            23800019
         BZ    CNT0100              SKIP PUNCH CLASS                    23900019
         MVC   QMPAB+15(1),5(R3)   PUNCH CLASS                          24000019
         LA    R6,QMPAB            SET DSECT FOR QMPAB                  24100019
         BAL   R11,SUB4            GO TO SUBROUTINE 4                   24200019
         MVC   MSGPARA+18(1),1(R3) PUNCH CLASS FOR MESSAGE              24300019
*                                                                       24400019
CNT0100  TM    SWITCH,X'20'        IF USE FOR USER EXIT IS ZERO,        24500019
         BZ    CNT0110              SKIP CLASS                          24600019
         MVC   QMPAC+15(1),6(R3)   USER EXIT CLASS                      24700019
         LA    R6,QMPAC            SET DSECT FOR QMPAC                  24800019
         BAL   R11,SUB4            GO TO SUBROUTINE 4                   24900019
         MVC   MSGPARA+20(1),2(R3) USER EXIT CLASS FOR MESSAGE          25000019
*                                                                       25100019
CNT0110  DS    0H                                                       25200019
         LA    R2,49                OFFSET                              25300019
         STH   R2,MSGPARA+4                                             25400019
         LA    R2,14                LENGTH                              25500019
         BAL   R11,SUB3A           GO TO SUBROUTINE 3                   25600019
*                                                                       25700019
CNT0112  DS    0H                                                       25800019
         MVI   DQMPA+8,QMDELE      PUT DELETE CODE IN QMPA FOR RJE      25900019
         L     R15,IHKZZELE            GET ADDRESS OF Q MGR DELETE      26000019
         LA    R1,DQMPA            ADDRESS OF QMPA FOR RJE CLASS        26100019
         BALR  R14,R15             DELETE RJE CLASS QUEUE SPACE         26200019
         LTR   R15,R15             IF RETURN CODE IS NOT ZERO,          26300019
         BNZ   CNTERR0              AN ERROR CONDITION EXISTS           26400019
*                                                                       26500019
CNT0112A MVI   FASTNAME,X'40'          REMOVE JOB FROM RJE TABLES       26600019
*                                                                       26700019
CNT0113  LR    R1,R8               ADDRESS OF FAST TABLE ENTRY          26800019
         L     R15,FMR             ADDRESS OF FAST TABLE MANAGER        26900019
         BALR  R14,R15             UPDATE FAST TABLE                    27000019
*                                                                       27100019
CNT0114  L     R13,4(R13)          RESTORE AND RETURN                   27200019
         RETURN (14,12),T,RC=0                                          27300019
*                                                                       27400019
*********************************************************************** 27500019
*                                                                     * 27600019
*              SET UP FOR ERROR MESSAGES                              * 27700019
*                                                                     * 27800019
*********************************************************************** 27900019
CNT0200  LA    R2,22               MESSAGE PARAMETERS-OFFSET FOR        28000019
*                                                                       28100019
CNT0205  STH   R2,MSGPARA+4         'JOB NOT IN SYSTEM' MESSAGE         28200019
         LA    R2,8                 LENGTH                              28300019
         BAL   R11,SUB3A           GO TO SUBROUTINE 3                   28400019
         B     CNT0114                                                  28500019
*                                                                       28600019
CNT0210  LA    R2,23               INDICATE 'JOB NOT COMPLETE' MESSAGE  28700019
         B     CNT0205                                                  28800019
*                                                                       28900019
CNT0213  TM    FASTDSBE,X'C0'      IF OUTPUT IS BYPASSED,               29000019
         BC    7,CNT0002            CENOUT THE OUTPUT                   29100019
*                                                                       29200019
CNT0215  LA    R2,52               'JOB WAITING DELIVERY' MSG OFFSET    29300019
         B     CNT0205             SEND MESSAGE                         29400019
*                                                                       29500019
CNTJED   MVI   FASTNAME,X'00'      DISABLE FAST TABLE ENTRY             29600019
         B     CNT0113             RETURN                               29700019
*                                                                       29800019
CNTERR0  MVC   MSGPARA+7(8),FASTNAME JOB NAME FOR MESSAGE               29900019
         LA    R2,8                MESSAGE LENGTH                       30000019
*                                                                       30100019
CNTERR1  STC   R2,MSGPARA+6                                             30200019
         LA    R2,67               OFFSET                               30300019
         STH   R2,MSGPARA+4                                             30400019
         BAL   R11,SUB3            GO TO SUBROUTINE 3                   30500019
        B     CNT0112A                                                  30600019
CNTERR   SR    R2,R2               MESSAGE LENGTH EQUAL ZERO            30700019
         B     CNTERR1                                                  30800019
*********************************************************************** 30900019
*                                                                     * 31000019
*              INITIAL PROCESSING FOR EACH QUEUE                      * 31100019
*                                                                     * 31200019
*********************************************************************** 31300019
SUB1     DS    0H                                                       31400019
         MVC   QMPAS(8),DQMPA      PUT NAME IN PARAMETERS               31500019
         MVI   QMPAS+8,QMASGS      ASSIGN/START FUNCTION CODE           31600019
         MVI   QMPAS+32,X'21'      ASSIGN TWO TTR                       31700019
         LR    R1,R6               GET ADDRESS OF PRESENT QMPA IN R1    31800019
         LR    R15,R5              GO TO QUEUE MANAGER TO ASSIGN        31900019
         BALR  R14,R15              INITIALLY                           32000019
         LTR   R15,R15             IF RETURN CODE IS NOT ZERO,          32100019
         BNZ   CNTERR               ERROR HAS OCCURRED                  32200019
         MVC   TTR1(3),QMPASE      SAVE FIRST TWO TTR                   32300019
         MVC   TTR2(3),QMPASE+4    *                                    32400019
*********************************************************************** 32500019
*                                                                     * 32600019
*              WRITE/ASSIGN FOR SUBSEQUENT ENTRIES                    * 32700019
*                                                                     * 32800019
*********************************************************************** 32900019
SUB2     DS    0H                                                       33000019
         CLI   RDBUFF+3,CNTDSB15   IF SMB,                       A26539 33100019
         BNE   CNT0060              GO TO SMB ROUTINE                   33200019
CNT00    EQU   X'00'               TO CHECK FOR ZERO LENGTH      A26539 33220019
         CLI   RDBUFF+14,CNT00     IS IT ZERO LENGTH DSB?        A26539 33240019
         BE    CNT0050             YES, DO NOT PROCESS           A26539 33260019
         MVI   QMPAS+32,X'11'      ASSIGN ONE TTR                       33300019
         MVI   QMPAS+8,QMASGN      ASSIGN FUNCTION CODE                 33400019
         LR    R15,R5                                                   33500019
         LR    R1,R6               GET ADDRESS OF PRESENT QMPA IN R1    33600019
         BALR  R14,R15             ASSIGN 1 TTR                         33700019
         LTR   R15,R15             IF RETURN CODE IS NOT ZERO,          33800019
         BNZ   CNTERR               ERROR HAS OCCURRED                  33900019
         MVC   JFCBTTR(3),TTR2     TTR FOR JFCB                         34000019
         MVC   TTR2,QMPASE         TTR FOR NEXT RECORD                  34100019
         MVC   OLDJFCB(3),RDBUFF+28 OLD TTR FOR JFCB                    34200019
         MVC   RDBUFF(3),TTR1      TTR OF THIS DSB                      34300019
         MVC   RDBUFF+4(3),TTR2    TTR OF NEXT BLOCK                    34400019
         MVC   RDBUFF+28(3),JFCBTTR TTR OF JFCB                         34500019
         MVC   QMPASE+4(3),TTR1    WRITE TO THIS TTR                    34600019
         LA    R2,RDBUFF            FROM THIS BUFFER                    34700019
         ST    R2,QMPASE           *                                    34800019
         MVI   QMPAS+8,QMWRTA      WRITE/ASSIGN CODE                    34900019
         LA    R1,DUMWAIT              ADDRESS OF POSTED ECB            35000019
         L     R15,IHKZZDSP            ADDRESS OF DISPATCHER            35100019
         BALR  R14,R15             DUMMY WAIT                           35200019
         LR    R15,R5              GO TO QUEUE MANAGER TO WRITE THIS    35300019
         LR    R1,R6               GET ADDRESS OF PRESENT QMPA IN R1    35400019
         BALR  R14,R15              *                                   35500019
         LTR   R15,R15             IF CODE IS NOT ZERO,                 35600019
         BNZ   CNTERR               ERROR HAS OCCURRED                  35700019
         MVC   TTR1(3),TTR2        ADDRESS OF NEXT BLOCK                35800019
         MVC   TTR2(3),QMPASE      ADDRESS OF CHAIN BLOCK               35900019
         MVC   JEDTQMPE+4(3),OLDJFCB THE TTR TO READ JFCB               36000019
         LA    R1,DUMWAIT              ADDRESS OF POSTED ECB            36100019
         L     R15,IHKZZDSP            ADDRESS OF DISPATCHER            36200019
         BALR  R14,R15             DUMMY WAIT                           36300019
         LR    R15,R5              READ THE JFCB INTO CORE              36400019
         LA    R1,DQMPA             *                                   36500019
         BALR  R14,R15              *                                   36600019
         LTR   R15,R15             IF CODE IS NOT ZERO,                 36700019
         BNZ   CNTERR               ERROR HAS OCCURRED                  36800019
         MVI   QMPAS+8,QMWRTE      WRITE ONLY CODE                      36900019
         MVC   QMPASE+4(3),JFCBTTR WRITE TO THIS TTR                    37000019
         LA    R2,RDBUFF            FROM THIS BUFFER                    37100019
         ST    R2,QMPASE           *                                    37200019
         LA    R1,DUMWAIT              ADDRESS OF POSTED ECB            37300019
         L     R15,IHKZZDSP            ADDRESS OF DISPATCHER            37400019
         BALR  R14,R15             DUMMY WAIT                           37500019
         LR    R1,R6               GET ADDRESS OF PRESENT QMPA IN R1    37600019
         LR    R15,R5              REQUEST A WRITE JFCB                 37700019
         BALR  R14,R15              *                                   37800019
         LTR   R15,R15             IF CODE IS NOT ZERO,                 37900019
         BNZ   CNTERR               ERROR OCCURRED                      38000019
*                                                                       38100019
CNT0050  TM    SWITCH,X'10'        IF LAST RECORD HAS BEEN PROCESSED,   38200019
         BO    CNT0080              GO TO ENDING ROUTINE                38300019
         MVC   JEDTQMPE+4(3),RDNXT TTR OF NEXT RECORD                   38400019
         B     CNT0005             GO TO READ NEXT RECORD               38500019
*                                                                       38600019
CNT0060  DS    0H                                                       38700019
         MVC   RDBUFF(3),TTR1      TTR OF THIS BLOCK                    38800019
         MVC   RDBUFF+4(3),TTR2    TTR OF NEXT BLOCK                    38900019
         MVC   QMPASE+4(3),TTR1    WRITE TO THIS TTR                    39000019
         MVI   QMPAS+8,QMWRTA      WRITE/ASSIGN CODE                    39100019
         MVI   QMPAS+32,X'11'      WRITE/ASSIGN ONE TTR                 39200019
         LA    R2,RDBUFF           WRITE FROM THIS BUFFER               39300019
         ST    R2,QMPASE           *                                    39400019
         LR    R1,R6               GET ADDRESS OF PRESENT QMPA IN R1    39500019
         LR    R15,R5              REQUEST WRITE                        39600019
         BALR  R14,R15              *                                   39700019
         LTR   R15,R15             IF CODE IS NOT ZERO                  39800019
         BNZ   CNTERR               ERROR OCCURRED                      39900019
         MVC   TTR1(3),TTR2        SAVE NEXT TTR                        40000019
         MVC   TTR2(3),QMPASE                                           40100019
         B     CNT0050             TEST FOR LAST RECORD                 40200019
*********************************************************************** 40300019
*                                                                     * 40400019
*              SEND ERROR MESSAGE VIA IHKCBLDM                        * 40500019
*                                                                     * 40600019
*********************************************************************** 40700019
SUB3A    DS    0H                                                       40800019
         CLI   MSGPARA+5,22        IS THIS INVALID RECIPIENT MESSAGE    40900019
         BNE   NEWTAG              NO, CONTINUE                         41000019
         MVC   MSGPARA+14(8),JBNAME SET UP JOB NAME IN MESSAGE          41100019
         MVI   MSGPARA+6,X'0F'     MESSAGE LENGTH                       41200019
         B     SUB3                FINISH MESSAGE                       41300019
NEWTAG   MVC   MSGPARA+7(8),JBNAME  JOB NAME                            41400019
         STC   R2,MSGPARA+6         *                                   41500019
*                                                                       41600019
SUB3     DS    0H                                                       41700019
         XC    MSGPARA(4),MSGPARA   INDICATE SEND TO CENTRAL            41800019
         L     R15,BLDM             ADDRESS OF MESSAGE ROUTINE          41900019
         LA    R1,MSGPARA           ADDRESS OF MESSAGE BUFFER           42000019
         BALR  R14,R15              SEND MESSAGE                        42100019
         BR    R11                 RETURN                               42200019
*********************************************************************** 42300019
*                                                                     * 42400019
*              WRITE/ENQUEUE SUBROUTINE                               * 42500019
*                                                                     * 42600019
*********************************************************************** 42700019
SUB4     DS    0H                                                       42800019
         ST    R2,QMPASE                                                42900019
         MVC   RDBUFF(3),TTR1      TTR OF THIS RECORD                   43000019
         MVI   QMPAS+8,QMWREN      WRITE/ENQUEUE CODE                   43100019
         MVC   QMPASE+4(3),TTR1    *                                    43200019
         LR    R15,R5              ADDRESS OF QUEUE MANAGER             43300019
         LR    R1,R6               GET ADDRESS OF PRESENT QMPA IN R1    43400019
         BALR  R14,R15             WRITE AND ENQUEUE                    43500019
         LTR   R15,R15             IF CODE IS NOT ZERO,                 43600019
         BNZ   CNTERR               ERROR OCCURRED                      43700019
         BR    R11                 RETURN                               43800019
*                                                                       43900019
*********************************************************************** 44000019
*                                                                     * 44100019
*              CONSTANTS/WORK AREAS                                   * 44200019
*                                                                     * 44300019
*********************************************************************** 44400019
SWITCH   DS    1C                  CLASS SWITCHES                       44500019
CLASS    DS    CL1                 SYSOUT CLASS                         44600019
SAVE     DS    18F                 SAVE AREA                            44700019
DUMWAIT  DC    X'40000000'             POSTED ECB FOR DUMMY WAIT        44800019
QMPAA    DS    8F                  WRITE QUEUE MANAGER PARAMETER AREA   44900019
         DC    X'11'                *                                   45000019
         DC    AL3(QMPAAE)                                              45100019
QMPAAE   DC    A(0)                 EXTENTION                           45200019
         DC    F'0'                                                     45300019
TTR1A    DS    3C                  STORAGE FOR TTR FOR CLASSES          45400019
TTR2A    DS    3C                   *                                   45500019
         CNOP  2,4                                                      45600019
JDTB     DS    50C                 BUFFER FOR JED TABLE                 45700019
DQMPA    DS    48C                  READ QMPA                           45800019
QMPAB    DS    8F                  WRITE QUEUE MANAGER PARAMETER AREA   45900019
         DC    X'11'                *                                   46000019
         DC    AL3(QMPABE)                                              46100019
QMPABE   DC    A(0)                 EXTENTION                           46200019
         DC    F'0'                                                     46300019
TTR1B    DS    3C                   *                                   46400019
TTR2B    DS    3C                   *                                   46500019
EXCESS   DC    H'50'               MAXIMUM VALUE OF SYSOUT POINTER      46600019
QMPAC    DS    8F                  WRITE QUEUE MANAGER PARAMETER AREA   46700019
         DC    X'11'                *                                   46800019
         DC    AL3(QMPACE)                                              46900019
QMPACE   DC    A(0)                 EXTENTION                           47000019
         DC    F'0'                                                     47100019
TTR1C    DS    3C                   *                                   47200019
TTR2C    DS    3C                   *                                   47300019
JFCBTTR  DS    3C                  JFCB POINTER                         47400019
OLDJFCB  DS    3C                  OLD JFCB POINTER                     47500019
  DS  0F                                                                47600019
MSGPARA  DS    0CL22               MESSAGE BUFFER                       47700019
         DS    CL7                                                      47800019
         DC    CL7'CENOUT'                                              47900019
         DS    CL8                                                      48000019
RDNXT    DS    3C                  TTR FOR NEXT READ                    48100019
RDBUFF   DS    176C                INPUT BUFFER-CLASS FOR RJE           48200019
QMPASECT DSECT                     DSECT OF QMPA BEING PROCESSED        48300019
QMPAS    DS    8F                                                       48400019
         DS    XL1                                                      48500019
         DS    AL3                                                      48600019
QMPASE   DS    A                                                        48700019
         DS    F                                                        48800019
TTR1     DS    CL3                                                      48900019
TTR2     DS    CL3                                                      49000019
DCARD    DSECT                                                          49100019
         DS    72C                                                      49200019
SEQ      DS    CL8                                                      49300019
         DS    C                                                        49400019
CMDID    DS    C                                                        49500019
JBNAME   DS    CL8                                                      49600019
         DS    5C                                                       49700019
FASTAB   DSECT                                                          49800019
FASTNAME DS    CL8                 'JOBNAME' FROM JCL CARD              49900019
FASTJIB  DS    C                   JOB INFORMATION BYTE                 50000019
FASTJEDT DS    CL3                 ADDRESS OF JED TABLE                 50100019
FASTDSB  DS    C                   DELIVERY STATUS BYTE                 50200019
FASTDSBE DS    C                   DELIVERY STATUS BYTE EXTENDED        50300019
FASTTTR  DS    CL3                 ADDRESS OF DISC FASTABLE ENTRY       50400019
FASTALT  DS    CL3                 ALTERNATE RECEIVER DESIGNATION       50500019
FASTCNT  DS    C                   COUNT OF RJE CLOSEDOWNS SINCE        50600019
*                                    CREATION OF DEFERRED OUTPUT        50700019
FASTUSE  DS    CL3                 USER IDENTIFIER                      50800019
JEDTAB   DSECT                                                          50900019
         CNOP  2,4                                                      51000019
JEDNMSG  DS    CL25                NOTIFY MESSAGE TEXT                  51100019
JEDTSOUT DS    25C                 SYSOUT CLASSES OE OUTPUT DEVICES     51200019
JEDTQMPA DS    CL36                O/S QUEUE MANAGER PARAMETER AREA     51300019
JEDTQMPE DS    CL8                 O/S EXTERNAL QUE MANAGER PARAM AREA  51400019
JEDTTTR0 DS    CL3                 TTR OF FIRST SYSOUT RECORD           51500019
*                                    OF THIS JOB                        51600019
JEDTTYPE DS    C               TYPE OF RECORD POINTED TO BY TTR         51700019
UDIREC   DSECT                                                          51800019
UDIRTERM DS    CL8                 ADDRESS OF DERMINAL DIRECTORY ENTRY  51900019
UDIRSTAT DS    C                   STATUS OF USER                       52000019
UDIRUSID DS    CL3                 USER IDENTIFICATION                  52100019
UDIRUKEY DS    CL3                 USERS KEY                            52200019
UDIRTTR  DS    CL3                      TTR ADDRESS OF TDIR ON DISC     52300019
TDIREC   DSECT                                                          52400019
TDIRTERM DS    CL8                 TERMINAL IDENTIFICATION              52500019
TDIRUSID DS    CL3                 USER ID                              52600019
TDIRSTAT DS    C                   STATUS BYTE                          52700019
TDIRRB   DS    C                   NOT USED                             52800019
TDIRTTR  DS    CL3                       TTR ADDRESS OF TDIR ON DISC    52900019
TDIRFQEB DS    CL4                      ADDR OF 1ST Q ENTRY BLOCK       53000019
TDIRLQEB DS    CL4                       ADDR OF LAST Q ENTRY BLOCK     53100019
TDIRLMEL DS    CL4                       ADDR OF LAST MESSAGE ELEMENT   53200019
TDIRFORM DS    CL4                      PRINTER FORM NUMBER             53300019
TDIRSECB DS    CL4                 'STOP ACK ECB' (FULL WORD BOUNDARY)  53400019
TDIRSWCH DS    CL3                 LINE ANALYSIS SWITCHES AND REMOTE    53500019
*                                    HARDWARE CONFIGURATION             53600019
TDIRPRNT DS    C                   REMOTE PRINTER LINE SIZE             53700019
TDIRDFTM DS    CL16                DEFINE TERMINAL LIST                 53800019
TDIRLCB  DS    CL4                 ADDRESS OF LINE CONTROL BLOCK (LCB)  53900019
IOPARAMS DSECT                                                          54000019
QMNAM    DS    CL8                                                      54100019
QMCAN    EQU   QMNAM                                                    54200019
QMPEB    EQU   QMNAM+4                                                  54300019
QMPOP    DS    CL1                                                      54400019
QMASGS   EQU   0                                                        54500019
QMASGN   EQU   1                                                        54600019
QMWRTA   EQU   2                                                        54700019
QMWRTE   EQU   3                                                        54800019
QMREAD   EQU   4                                                        54900019
QMWREN   EQU   5                                                        55000019
QMDTOP   EQU   6                                                        55100019
QMDTYP   EQU   7                                                        55200019
QMDELE   EQU   8                                                        55300019
QMFLT    DS    CL2                                                      55400019
QMTST    DS    CL1                                                      55500019
QMTLN    DS    CL2                                                      55600019
QMNOT    DS    CL1                                                      55700019
QMTPY    DS    CL1                                                      55800019
QMSTA    DS    CL1                                                      55900019
QMPRI    DS    CL1                                                      56000019
QMLNK    DS    CL2                                                      56100019
QMTID    DS    CL2                                                      56200019
         DS    CL2                                                      56300019
QMWTQ    DS    CL4                                                      56400019
QMEIA    DS    CL4                                                      56500019
QMPCL    DS    CL4                                                      56600019
QMPCM    EQU   QMPCL                                                    56700019
QMPNC    EQU   QMPCL                                                    56800019
         IHKDSECT ,,,,,AVT                                              56900019
BLDM     EQU   IHKZZLDM                                                 57000019
SCH      EQU   IHKZZSCH                                                 57100019
SGN      EQU   IHKZZSGN                                                 57200019
STD      EQU   IHKZZSTD                                                 57300019
SUD      EQU   IHKZZSUD                                                 57400019
FMR      EQU   IHKZZFMR                                                 57500019
JMR      EQU   IHKZZJMR                                                 57600019
CLASWRD  EQU   IHKZZSOC                                                 57700019
         END                                                            57800019
