JIR      TITLE 'JOB INFORMATION REQUEST PROCESSOR '                     00100017
         SPACE                                                          00200017
IHKCHJIR CSECT                                                          00300017
         SPACE                                                          00400017
         ENTRY IHKCASHJ                                                 00500017
         ENTRY IHKCASHD                                                 00600017
         SPACE 2                                                        00700017
*********************************************************************** 00800017
*---------------------------------------------------------------------* 00900017
*-*******************************************************************-* 01000017
*-*                                                                 *-* 01100017
*-*                                                                 *-* 01200017
*-* M O D U L E   N A M E - -                                       *-* 01300017
*-*                                                                 *-* 01400017
*-*   IHKCHJIR - SHOW PROCESSOR FOR JOB INFORMATION REQUEST         *-* 01500017
*-*                                                                 *-* 01600017
*-*                                                                 *-* 01700017
*-* F U N C T I O N / O P E R A T I O N - -                         *-* 01800017
*-*                                                                 *-* 01900017
*-*   THIS MODULE RESPONDS TO CENTRAL COMMANDS ENTERED BY THE       *-* 02000017
*-*     CENTRAL OPERATOR TO RETRIEVE INFORMATION RELATIVE TO JOBS   *-* 02100017
*-*     IN THE RJE SYSTEM.  HE CAN REQUEST -                        *-* 02200017
*-*     1.  A LIST OF ALL RJE JOBS CURRENTLY RESIDING IN THE        *-* 02300017
*-*         CENTRAL SYSTEM.  *** SHOW JOBS ***                      *-* 02400017
*-*     2.  A LIST OF ALL DEFERRED JOBS CURRENTLY RESIDING IN THE   *-* 02500017
*-*         CENTRAL SYSTEM.  *** SHOW DEFER ***                     *-* 02600017
*-*     3.  A LIST OF ALL DEFERRED JOBS FOR A PARTICULAR USER       *-* 02700017
*-*         CURRENTLY RESIDING IN THE CENTRAL SYSTEM.               *-* 02800017
*-*               *** SHOW DEFER,USERID ***                         *-* 02900017
*-*     4.  THE STATUS OF A PARTICULAR JOB CURRENTLY RESIDING IN    *-* 03000017
*-*         THE CENTRAL SYSTEM.  *** SHOW JOBS,JOBNAME ***          *-* 03100017
*-*                                                                 *-* 03200017
*-*   THE RESPONSE TO THESE REQUESTS INCLUDES THE JOBNAME AND SOURCE*-* 03300017
*-*     USERID -- THE ALTERNATE USERID IS INCLUDED IF APPLICABLE.   *-* 03400017
*-*     IN ADDITION, THE DISPOSITION OF THE OUTPUT, IMMEDIATE OR    *-* 03500017
*-*     DEFERRED IS DISPLAYED ALONG WITH JOB COMPLETION STATUS --   *-* 03600017
*-*     COMPLETE OR INCOMPLETE. IF THE OUTPUT IS DEFERRED, THE      *-* 03700017
*-*     NUMBER OF NORMAL CENTRAL CLOSEDOWNS OCCURRING WHILE THE     *-* 03800017
*-*     JOB WAS IN THE CENTRAL SYSTEMS IS INCLUDED.  ALL JOB STATUS *-* 03900017
*-*     INFORMATION IS RETRIEVED FROM THE FASTABLE ENTRY ASSIGNED   *-* 04000017
*-*     TO THE JOB.                                                 *-* 04100017
*-*                                                                 *-* 04200017
         EJECT                                                          04300017
*-*                                                                 *-* 04400017
*-* E N T R Y   P O I N T S - -                                     *-* 04500017
*-*                                                                 *-* 04600017
*-*   IHKCASHD AND IHKCASHJ ARE COMMON ENTRY POINTS ATTRIBUTED TO   *-* 04700017
*-*     THIS MODULE.  IHKCASHD IS THE ENTRY POINT USED BY IHKCAINT  *-* 04800017
*-*     ON RECEIPT OF A SHOW DEFER OR A SHOW DEFER,USERID COMMAND.  *-* 04900017
*-*     IHKCASHJ IS THE ENTRY POINT USED BY IHKCAINT ON RECEIPT     *-* 05000017
*-*     OF A SHOW JOBS OR A SHOW JOBS,JOBNAME COMMAND.  STANDARD    *-* 05100017
*-*     SUBROUTINE LINKAGE PREVAILS.  THE CALLING SEQUENCE FOR      *-* 05200017
*-*     EITHER ENTRY POINT IS-                                      *-* 05300017
*-*                                                                 *-* 05400017
*-*            LOAD    EP=IHKCASHD OR IHKCASHJ                      *-* 05500017
*-*            LR      15,0                                         *-* 05600017
*-*            L       1,RJE COMMUNICATION REGION ADDRESS           *-* 05700017
*-*            BALR    14,15                                        *-* 05800017
*-*                                                                 *-* 05900017
*-*            DELETE  EP=IHKCASHD OR IHKCASHJ                      *-* 06000017
*-*                                                                 *-* 06100017
*-*                                                                 *-* 06200017
*-* I N P U T - -                                                   *-* 06300017
*-*                                                                 *-* 06400017
*-*   THE INPUT OF THIS MODULE IS OBTAINED FROM THE SECOND WORD OF  *-* 06500017
*-*     THE RJE COMMUNICATION REGION POINTED TO BY REGISTER ONE.    *-* 06600017
*-*     THIS WORD CONTAINS THE ADDRESS OF A 95 BYTE RJE COMMAND     *-* 06700017
*-*     INPUT RECORD WITH THE FOLLOWING FORMAT.                     *-* 06800017
*-*                                                                 *-* 06900017
*-*     *-------------------------*------------------------*        *-* 07000017
*-*     *                         *                        *        *-* 07100017
*-*     *  80 BYTE COMMAND IMAGE  *  15 BYTE CONDENSATION  *        *-* 07200017
*-*     *                         *                        *        *-* 07300017
*-*     *-------------------------*------------------------*        *-* 07400017
*-*                                                                 *-* 07500017
*-*     DESCRIPTION -                                               *-* 07600017
*-*                                                                 *-* 07700017
*-*       BYTE      USE                                             *-* 07800017
*-*       0-79     COMMAND IMAGE - 80 BYTE IMAGE OF COMMAND WHICH   *-* 07900017
*-*                   WAS RECEIVED AND INTERPRETED BY IHKCAINT      *-* 08000017
*-*      80-94     COMMAND CONDENSATION-                            *-* 08100017
*-*                 BYTE     USE                                    *-* 08200017
*-*                  80     COMMAND TYPE - CONTAINS C'H' TO         *-* 08300017
*-*                           INDICATE SHOW                         *-* 08400017
*-*                  81     OPERAND TYPE - CONTAINS                 *-* 08500017
*-*                          -C'J' FOR SHOW JOBS(,JOBNAME)          *-* 08600017
*-*                          -C'D' FOR SHOW DEFER(,USERID)          *-* 08700017
*-*                 82-89   REQUEST TYPE- CONTAINS                  *-* 08800017
*-*                          -BINARY ZERO FOR MAJOR REQUEST,        *-* 08900017
*-*                            SHOW JOBS OR SHOW DEFER              *-* 09000017
*-*                          -JOBNAME FOR SHOW JOBS, JOBNAME        *-* 09100017
*-*                          -USERID FOR SHOW DEFER,USERID          *-* 09200017
*-*                 90-94   RESERVED                                *-* 09300017
*-*                                                                 *-* 09400017
         EJECT                                                          09500017
*-*                                                                 *-* 09600017
*-* O U T P U T - -                                                 *-* 09700017
*-*                                                                 *-* 09800017
*-*   THE OUTPUT OF THIS MODULE IS A PRINTER/KEYBOARD DISPLAY OF    *-* 09900017
*-*     REQUESTED STATUS OF THE JOBS IN THE RJE SYSTEM.  REPORTING  *-* 10000017
*-*     CONTINUES UNTIL ALL JOBS WHICH SATISY THE REQUEST HAVE BEEN *-* 10100017
*-*     DISPLAYED.                                                  *-* 10200017
*-*                                                                 *-* 10300017
*-*     MESSAGES DISPLAYED HAVE THE FOLLOWING FORMAT -              *-* 10400017
*-*                                                                 *-* 10500017
*-*     IHK028I JJJJJJJJ UUU N/A COMP I                             *-* 10600017
*-*            FOR COMPLETE JOBS WITH IMMEDIATE OUTPUT              *-* 10700017
*-*     IHK028I JJJJJJJJ UUU N/A INCP I                             *-* 10800017
*-*            FOR INCOMPLETE JOBS WITH IMMEDIATE OUTPUT            *-* 10900017
*-*     IHK028I JJJJJJJJ UUU N/A COMP OR INCP D NNN                 *-* 11000017
*-*            FOR JOBS WITH DEFERRED OUTPUT AND NO ALTERNATE USER  *-* 11100017
*-*     IHK028I JJJJJJJJ UUU AAA COMP OR INCP D NNN                 *-* 11200017
*-*            FOR JOBS WITH DEFERRED OUTPUT AND AN ALTERNATE USER  *-* 11300017
*-*                                                                 *-* 11400017
*-*     WHERE -                                                     *-* 11500017
*-*         JJJJJJJJ IS THE JOBNAME.                                *-* 11600017
*-*         UUU IS THE SOURCE USERS USERID.                         *-* 11700017
*-*         AAA IS THE ALTERNATE USERS USERID.                      *-* 11800017
*-*         NNN  IS THE NUMBER OF NORMAL CENTRAL CLOSEDOWNS SINCE   *-* 11900017
*-*            THE JOB WAS RECEIVED.                                *-* 12000017
*-*                                                                 *-* 12100017
*-*   IF THE OPERATOR REQUESTS A DISPLAY OF JOBS WITH DEFERRED      *-* 12200017
*-*     OUTPUT AND THERE IS NO SUCH JOBS IN THE CENTRAL SYSTEM.     *-* 12300017
*-*     THE FOLLOWING MESSAGE IS DISPLAYED.                         *-* 12400017
*-*            IHK028I NO DEFERRED JOB OUTPUT                       *-* 12500017
*-*                                                                 *-* 12600017
*-*   IF THE OPERATOR REQUESTS A DEFERRED JOB OUTPUT DISPLAY FOR    *-* 12700017
*-*     A PARTICULAR USER UNDER THE ABOVE CONDITION, THE FOLLOWING  *-* 12800017
*-*     MESSAGE IS DISPLAYED.                                       *-* 12900017
*-*            IHK028I NO DEFERRED JOB OUTPUT UUU                   *-* 13000017
*-*                                                                 *-* 13100017
*-*   IF A DISPLAY OF ALL JOBS WAS REQUESTED AND THERE ARE NO JOBS  *-* 13200017
*-*     CURRENTLY IN RJE, THE FOLLOWING MESSAGE IS DISPLAYED.       *-* 13300017
*-*            IHK004I NO JOB(S) IN SYSTEM SHOW                     *-* 13400017
*-*                                                                 *-* 13500017
*-*   IF A DISPLAY OF A PARTICULAR JOB WAS REQUESTED BUT THE JOB    *-* 13600017
*-*     COULD NOT BE FOUND, THE FOLLOWING MESSAGE IS DISPLAYED.     *-* 13700017
*-*            IHK004I NO JOB(S) IN SYSTEM SHOW JJJJJJJJ            *-* 13800017
*-*                                                                 *-* 13900017
*-*   IF THE OPERATOR SPECIFIES AN INVALID USERID WHEN ENTERING     *-* 14000017
*-*     SHOW DEFER,USERID, THE FOLLOWING MESSAGE IS DISPLAYED.      *-* 14100017
*-*            IHK040 INVALID USERID SHOW                           *-* 14200017
*-*                                                                 *-* 14300017
         EJECT                                                          14400017
*-*                                                                 *-* 14500017
*-* E X T E R N A L  R O U T I N E S                                *-* 14600017
*-*                                                                 *-* 14700017
*-*   IHKCBLDM- CONSTRUCT AND DISPLAY MESSAGES FOR CENTRAL OPERATOR *-* 14800017
*-*   IHKCDSCH- SEARCH FASTABLE FOR JOBNAME ON SHOW JOBS,JOBNAME    *-* 14900017
*-*     IHKCCSUD- SEARCH USER DIRECTORY FOR USERID ON RECEIPT OF    *-* 15000017
*-*               SHOW DEFER,USERID                                 *-* 15100017
*-*                                                                 *-* 15200017
*-*                                                                 *-* 15300017
*-* E X I T S - -                                                   *-* 15400017
*-*                                                                 *-* 15500017
*-*   NORMAL- RETURN TO CALLING ROUTINE WITH ZERO RETURN CODE       *-* 15600017
*-*                                                                 *-* 15700017
*-*   ERROR- N/A                                                    *-* 15800017
*-*                                                                 *-* 15900017
*-*                                                                 *-* 16000017
*-* T A B L E S / W O R K   A R E A S - -                           *-* 16100017
*-*                                                                 *-* 16200017
*-*     STANDARD 18-WORD SAVE AREA                                  *-* 16300017
*-*     28 BYTE MESSAGE TEXT BUFFER                                 *-* 16400017
*-*     FASTABLE (READ ONLY)                                        *-* 16500017
*-*     USER DIRECTORY (READ ONLY)                                  *-* 16600017
*-*                                                                 *-* 16700017
*-*                                                                 *-* 16800017
*-* A T T R I B U T E S - -                                         *-* 16900017
*-*                                                                 *-* 17000017
*-*   SERIALLY REUSEABLE AND NON-RESIDENT                           *-* 17100017
*-*                                                                 *-* 17200017
*-*                                                                 *-* 17300017
*-* N O T E S - -                                                   *-* 17400017
*-*                                                                 *-* 17500017
*-*   COMMENTS ARE KEYED TO PROGRAMMERS FAMILIAR WITH THE MYSTERIES *-* 17600017
*-*     OF OS/360 ASSEMBLER LANGUAGE WHICH DEPENDS UPON AN INTERNAL *-* 17700017
*-*     REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS       *-* 17800017
*-*     EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE PROGRAM    *-* 17900017
*-*     HAS BEEN ARRANGED SO THAT REDEFINITION OF CHARACTER         *-* 18000017
*-*     CONSTANTS BY REASSEMBLY WILL RESULT IN A CORRECT MODULE FOR *-* 18100017
*-*     THE NEW DEFINITIONS.                                        *-* 18200017
*-*                                                                 *-* 18300017
*-*******************************************************************-* 18400017
*---------------------------------------------------------------------* 18500017
*********************************************************************** 18600017
         EJECT                                                          18700017
         SPACE 2                                                        18800017
*********************************************************************** 18900017
*---------------------------------------------------------------------* 19000017
*-*******************************************************************-* 19100017
*-*                                                                 *-* 19200017
*-*  S Y M B O L I C   R E G I S T E R   A S S I G N M E N T S      *-* 19300017
*-*                                                                 *-* 19400017
*-*******************************************************************-* 19500017
*---------------------------------------------------------------------* 19600017
*********************************************************************** 19700017
         SPACE 2                                                        19800017
ZIP      EQU   0         WORK REGISTER                                  19900017
         SPACE                                                          20000017
PAR      EQU   1         PARAMETER LIST ADDRESS FOR LINKAGE             20100017
         SPACE                                                          20200017
NU1      EQU   2         NOT USED                                       20300017
         SPACE                                                          20400017
FTE      EQU   3         CURRENT FASTABLE ENTRY ADDRESS (DSECT)         20500017
         SPACE                                                          20600017
LNG      EQU   4         LENGTH OF FASTABLE ENTRY                       20700017
         SPACE                                                          20800017
CNT      EQU   5         NUMBER OF FASTABLE ENTRIES                     20900017
         SPACE                                                          21000017
AVT      EQU   6         RJE COMMUNICATION REGION ADDRESS (DSECT)       21100017
         SPACE                                                          21200017
CIR      EQU   7         COMMAND INPUT RECORD ADDRESS (DSECT)           21300017
         SPACE                                                          21400017
MSG      EQU   8         MSG DISPLAY STATUS, ZERO IF MESSAGE DISPLAYED  21500017
         SPACE                                                          21600017
WOK      EQU   9         WORK REGISTER                                  21700017
         SPACE                                                          21800017
CVD      EQU  10         USED TO CONVERT NUMBER OF CENTRAL CLOSEDOWNS   21900017
         SPACE                                                          22000017
NU0      EQU  11         NOT USED                                       22100017
         SPACE                                                          22200017
BAS      EQU  12         MODULE BASE REGISTER                           22300017
         SPACE                                                          22400017
SAV      EQU  13         SAVE ADDRESS REGISTER FOR LINKAGE              22500017
         SPACE                                                          22600017
BAC      EQU  14         RETURN POINT REGISTER FOR LINKAGE              22700017
         SPACE                                                          22800017
GO       EQU  15         ENTRY POINT AND RETURN CODE REG FOR LINKAGE    22900017
         EJECT                                                          23000017
         SPACE 2                                                        23100017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 23200017
*-*                                                                 *-* 23300017
*-*         S Y M B O L I C   D I S P L A C E M E N T S ,           *-* 23400017
*-*                L E N G T H S ,   AND   V A L U E S              *-* 23500017
*-*                                                                 *-* 23600017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 23700017
         SPACE 2                                                        23800017
* DISPLACEMENTS -                                                       23900017
         SPACE                                                          24000017
ZERO     EQU   0                                                        24100017
ONE      EQU   1                                                        24200017
TWO      EQU   2                                                        24300017
THRE     EQU   3                                                        24400017
FOUR     EQU   4                                                        24500017
ATE      EQU   8                                                        24600017
TWLV     EQU  12                                                        24700017
         SPACE 2                                                        24800017
* LENGTHS -                                                             24900017
         SPACE                                                          25000017
L2       EQU   2                                                        25100017
L3       EQU   3                                                        25200017
L4       EQU   4                                                        25300017
L5       EQU   5                                                        25400017
L8       EQU   8                                                        25500017
L13      EQU  13                                                        25600017
L27      EQU  27                                                        25700017
L28      EQU  28                                                        25800017
         SPACE 2                                                        25900017
* VALUES                                                                26000017
         SPACE                                                          26100017
MO40     EQU   1                                                        26200017
ON       EQU   1                                                        26300017
NE       EQU   7                                                        26400017
EQ       EQU   8                                                        26500017
OFF      EQU   8                                                        26600017
MO04     EQU  22                                                        26700017
MO28     EQU  42                                                        26800017
BLNK     EQU   C' '                                                     26900017
IMMED    EQU   C'I'                                                     27000017
DEFER    EQU   C'D'                                                     27100017
MAJOR    EQU   X'00'                                                    27200017
MINOR    EQU   X'00'                                                    27300017
INE      EQU   X'BF'                                                    27400017
FOX0     EQU   X'F0'                                                    27500017
NAU      EQU   X'00'                                                    27600017
NSU      EQU   X'00'                                                    27700017
         EJECT                                                          27800017
*********************************************************************** 27900017
*---------------------------------------------------------------------* 28000017
*-*******************************************************************-* 28100017
*-*                                                                 *-* 28200017
*-*               E N T R Y   L I N K A G E                         *-* 28300017
*-*                                                                 *-* 28400017
*-*******************************************************************-* 28500017
*---------------------------------------------------------------------* 28600017
*********************************************************************** 28700017
         SPACE 2                                                        28800017
IHKCASHJ DS    0H             **** ENTRY POINT FOR SHOW JOBS(,JOBNAME)  28900017
IHKCASHD DS    0H             **** ENTRY POINT FOR SHOW DEFER(,USERID)  29000017
         SPACE                                                          29100017
         B     TWLV(ZIP,GO)        BRANCH AROUND IDENTIFIER             29200017
         DC    CL8'IHKCHJIR'       MODULE IDENTIFIER                    29300017
         SPACE                                                          29400017
         STM   BAC,BAS,TWLV(SAV)   SAVE REGISTORS FOR RETURN LINKAGE    29500017
         BALR  BAS,ZIP             SET UP MODULE ADDRESSABILITY         29600017
      USING    *,BAS               TELL ASSEMBLER CHOICE OF BASE REG.   29700017
         SPACE                                                          29800017
         LA    MSG,JIRSAV          GET MODULE SAVE AREA ADDRESS         29900017
         ST    MSG,ATE(SAV)        CHAIN CALLED WITH CALLING SAVE AREA  30000017
         ST    SAV,FOUR(MSG)       CHAIN CALLING WITH CALLED SAVE AREA  30100017
         LR    SAV,MSG             SET UP SAVE REG FOR MODULE LINKAGES  30200017
         SPACE 2                                                        30300017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 30400017
*-*                                                                 *-* 30500017
*-*      I N I T I A L I Z E   AND   R E T R I E V E   P A R M S    *-* 30600017
*-*                                                                 *-* 30700017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 30800017
         SPACE                                                          30900017
         LR    AVT,PAR             GET RJE COMMUNICATION REGION ADDRESS 31000017
      USING    IHKZZAVT,AVT        TELL ASSEMBLER OF DSECT              31100017
         SPACE                                                          31200017
         L     CIR,IHKZZCDE        GET COMMAND INPUT RECORD ADDRESS     31300017
      USING    CIRD,CIR            TELL ASSEMBLER OF DSECT              31400017
         SPACE                                                          31500017
         LM    FTE,CNT,IHKZZFTB    GET FASTABLE DESCRIPTIVE ADDRESSES   31600017
*                               ** FTE- FASTABLE STARTING ADDRESS       31700017
*                               ** LNG- ENTRY LENGTH (IN HALFWORD) ADDR 31800017
*                               ** CNT- ENTRY NUMBER (IN HALFWORD) ADDR 31900017
         LH    LNG,ZERO(LNG)       GET FASTABLE ENTRY LENGTH            32000017
         LH    CNT,ZERO(CNT)       GET NUMBER OF FASTABLE ENTRIES       32100017
         LTR   CNT,CNT             ANY ENTRIES IN FASTABLE              32200017
         BZ    JIRNOJ              NO, TELL OPERATOR HAS NO JOB SYSTEM  32300017
         SPACE 2                                                        32400017
      USING    FASTAB,FTE          TELL ASSEMBLER OF DSECT              32500017
         EJECT                                                          32600017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 32700017
*-*                                                                 *-* 32800017
*-*        D E T E R M I N E   R E Q U E S T   T Y P E              *-* 32900017
*-*                                                                 *-* 33000017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 33100017
         SPACE                                                          33200017
         CLI   RTYPE,MAJOR         IS MAJOR DISPLAY REQUESTED           33300017
         BNE   JIRSPEC             NO, PROCESS SPECIFIC JOBNAME REQUEST 33400017
         SPACE 2                                                        33500017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 33600017
*-*                                                                 *-* 33700017
*-*   P R O C E S S   M A J O R   J O B   I N F O R M A T I O N     *-* 33800017
*-*                          R E Q U E S T                          *-* 33900017
*-*                                                                 *-* 34000017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 34100017
         SPACE                                                          34200017
JIRLOP   DS    0H             **** TAG FOR BRANCHING                    34300017
         BAL   BAC,JIRSUB          HANDLE REPORTING FOR THIS ENTRY      34400017
         SPACE                                                          34500017
         AR    FTE,LNG             STEP TO NEXT FASTABLE ENTRY          34600017
         BCT   CNT,JIRLOP          PROCESS REMAINING ENTRIES            34700017
         SPACE                                                          34800017
         LTR   MSG,MSG             WAS THERE AN ENTRY REPORTED          34900017
         BNZ   JIRNOM              NO, CHECK OUT WHAT TO DO             35000017
         SPACE 2                                                        35100017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 35200017
*-*                                                                 *-* 35300017
*-*                 R E T U R N   L I N K A G E                     *-* 35400017
*-*                                                                 *-* 35500017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 35600017
         SPACE                                                          35700017
JIROUT   DS    0H             **** TAG FOR BRANCHING                    35800017
         XR    GO,GO               SET ZERO RETURN CODE                 35900017
         L     SAV,JIRSAV+FOUR     GET CALLING SAVE AREA ADDRESS        36000017
         SPACE                                                          36100017
      RETURN   (14,12),T,RC=(15)   EXECUTE RETURN LINKAGE               36200017
         SPACE 2                                                        36300017
         EJECT                                                          36400017
*********************************************************************** 36500017
*---------------------------------------------------------------------* 36600017
*-*******************************************************************-* 36700017
*-*                                                                 *-* 36800017
*-*        J O B   I N F O R M A T I O N   R E P O R T I N G        *-* 36900017
*-*                     S U B R O U T I N E                         *-* 37000017
*-*                                                                 *-* 37100017
*-*******************************************************************-* 37200017
*---------------------------------------------------------------------* 37300017
*********************************************************************** 37400017
         SPACE                                                          37500017
JIRSUB   DS    0H             **** SUBROUTINE ENTRY POINT               37600017
         TM    FASTNAME,INE        IS THIS ENTRY ACTIVE                 37700017
         BCR   OFF,BAC             NO, PROCESS NEXT ENTRY               37800017
         SPACE                                                          37900017
         CLI   FASTUSE,NSU         HAS RJE READER PROCESSED IT YET      38000017
         BCR   EQ,BAC              NO PROCESS NEXT ENTRY                38100017
         SPACE                                                          38200017
         CLI   OTYPE,DEFER         IS THIS A SHOW DEFER REQUEST         38300017
         BNE   JIRJOB              NO, PROCESS SHOW JOBS REQUEST        38400017
         SPACE                                                          38500017
         TM    FASTJIB,FASTIOUT    IS OUTPUT FOR JOB DEFERRED           38600017
         BCR   ON,BAC              NO,IMMEDIATE OUTPUT- DO NEXT ENTRY   38700017
         SPACE                                                          38800017
         CLI   RTYPE,MAJOR         IS THIS MAJOR SHOW DEFER REQUEST     38900017
         BE    JIRJOB              YES, PROCESS THIS ENTRY              39000017
         SPACE                                                          39100017
         CLC   RTYPE(L3),FASTUSE   IS SPECIFIED USER THE SOURCE USER    39200017
         BE    JIRJOB              YES, PROCESS ENTRY                   39300017
         SPACE                                                          39400017
         CLC   RTYPE(L3),FASTALT   IS SPECIFIED USER THE ALTERNATE USER 39500017
         BCR   NE,BAC              NO, PROCESS NEXT ENTRY               39600017
         SPACE                                                          39700017
* CONSTRUCT MESSAGE TEXT FOR FASTABLE ENTRY                             39800017
         SPACE                                                          39900017
JIRJOB   DS    0H             **** TAG FOR BRANCHING                    40000017
         MVI   JIRTXT,BLNK         CLEAR FIRST BYTE OF MSG TEXT BUFFER  40100017
         MVC   JIRTEX(L27),JIRTXT  CASCADE BLANK THROUGH REST OF BUFFER 40200017
         SPACE                                                          40300017
         MVI   JIRTYP,IMMED        ASSUME IMMEDIATE JOB OUTPUT          40400017
         MVC   JIRSTA(L4),INCP     ASSUME JOB EXECUTION NOT COMPLETE    40500017
         MVC   JIRAID(L3),NAR      ASSUME NO ALTERNATE RECIPIENT        40600017
         SPACE                                                          40700017
         MVC   JIRNAM(L8),FASTNAME MOVE JOBNAME INTO MSG TEXT BUFFER    40800017
         MVC   JIRUID(L3),FASTUSE  MOVE SOURCE USERID INTO TEXT BUFFER  40900017
         SPACE                                                          41000017
         TM    FASTDSB,FASTJOBC    HAS JOB COMPLETED EXECUTION          41100017
         BZ    JIRON               NO, CONTINUE WITH INCOMPLETE JOB     41200017
         SPACE                                                          41300017
         MVC   JIRSTA(L4),COMP     MARK JOB COMPLETE IN MESSAGE         41400017
         SPACE                                                          41500017
         EJECT                                                          41600017
JIRON    DS    0H             **** TAG FOR BRANCHING                    41700017
         TM    FASTJIB,FASTIOUT    IS JOB OUTPUT DEFERRED               41800017
         BO    JIRLAY              NO, JOB OUTPUT IS IMMEDIATE          41900017
         SPACE                                                          42000017
         MVI   JIRTYP,DEFER        MARK JOB OUTPUT DEFERRED IN MSG      42100017
         XR    CVD,CVD             ZERO REGISTER                        42200017
         IC    CVD,FASTCNT         GET NUMBER OF CLOSEDOWNS FOR JOB     42300017
         CVD   CVD,JIRCVD          CONVERT IT TO PACKED DECIMAL.        42400017
         UNPK  JIRNUM(L3),JIRUPK+TWO(L2)  GET IT IN EBCDIC              42500017
         OI    JIRNUM+TWO,FOX0     RECTIFY SIGN BIT IN UNPACKED NUMBER  42600017
         SPACE                                                          42700017
         CLI   FASTALT,NAU         IS THERE AN ALTERNATE FOR OUTPUT     42800017
         BE    JIRLAY              NO, DISPLAY MESSAGE FOR ENTRY        42900017
         SPACE                                                          43000017
         MVC   JIRAID(L3),FASTALT  MOVE ALTERNATE USERID INTO MSG TEXT  43100017
         SPACE                                                          43200017
JIRLAY   DS    0H             **** TAG FOR BRANCHING                    43300017
         XR    MSG,MSG             REMBER MESSAGE SENT                  43400017
         LA    PAR,JIRMSG          GET PARMS FOR IHKCBLDM               43500017
         L     GO,IHKZZLDM         GET IHKCBLDM ENTRY POINT             43600017
         BR    GO                  BUILD MSG AND RATTLE OPERATORS BALL  43700017
         SPACE 2                                                        43800017
         EJECT                                                          43900017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 44000017
*-*                                                                 *-* 44100017
*-*        H A N D L E   S P E C I F I C    R E Q U E S T           *-* 44200017
*-*                                                                 *-* 44300017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 44400017
         SPACE                                                          44500017
JIRSPEC  DS    0H             **** TAG FOR BRANCHING                    44600017
         CLI   OTYPE,DEFER         WAS THIS A SHOW DEFER,USERID REQUEST 44700017
         BE    JIRMIN              YES, PROCESS MINOR REQUEST           44800017
         SPACE                                                          44900017
         LA    PAR,RTYPE           GET PARMS FOR IHKCDSCH               45000017
         L     GO,IHKZZSCH         GET IHKCDSCH ENTRY POINT             45100017
         BALR  BAC,GO              SEARCH FASTABLE FOR JOBNAME          45200017
         SPACE                                                          45300017
         LTR   GO,GO               WAS JOBNAME FOUND IN FASTABLE        45400017
         BNZ   JIRNOJ              NO, TELL OPERATOR NO SUCH RJE JOB    45500017
         SPACE                                                          45600017
         LR    FTE,PAR             SET UP FASTABLE DSECT FOR THIS ENTRY 45700017
         LA    BAC,JIROUT          EXIT WHEN ENTRY REPORTING COMPLETE   45800017
         B     JIRJOB              HANDLE REPORTING FOR ENTRY           45900017
         SPACE 2                                                        46000017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 46100017
*-*                                                                 *-* 46200017
*-*           H A N D L E   M I N O R   R E Q U E S T               *-* 46300017
*-*                                                                 *-* 46400017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 46500017
         SPACE                                                          46600017
JIRMIN   DS    0H             **** TAG FOR BRANCHING                    46700017
         MVC   DIP(L3),RTYPE       LEFT JUSTIFY USERID IN FULL WORD     46800017
         L     PAR,DIP             PASS IHKCCSUD ITS PARMS              46900017
         L     GO,IHKZZSUD         GET IHKCCSUD ENTRY POINT             47000017
         BALR  BAC,GO              SEARCH USER DIRECTORY FOR USERID     47100017
         SPACE                                                          47200017
         LTR   PAR,PAR             WAS USER DIRECTORY FOUND             47300017
         BNZ   JIRLOP              YES, PROCESS COMMAND                 47400017
         SPACE                                                          47500017
         MVI   JIROFF,MO40         MOVE PROPER MSG OFFSET INTO PARM LST 47600017
JIRERR   DS    0H             **** TAG FOR BRANCHING                    47700017
         MVI   JIRLNG,L4           MOVE LENGTH INTO PARM LIST           47800017
JIRUP    DS    0H             **** TAG FOR BRANCHING                    47900017
         MVC   JIROP(L5),SHOW      MOVE OPERATION INTO TEXT BUFFER      48000017
         SPACE                                                          48100017
JIRSND   DS    0H             **** TAG FOR BRANCHING                    48200017
         LA    PAR,JIRMSG          GIVE IHKCBLDM ITS PARMS              48300017
         LA    BAC,JIROUT          EXIT WHEN MESSAGE DISPLAYED          48400017
         L     GO,IHKZZLDM         GET IHKCBLDM ENTRY POINT             48500017
         BR    GO                  BUILD MSG AND RATTLE OPERATORS BALL  48600017
         SPACE 2                                                        48700017
         EJECT                                                          48800017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 48900017
*-*                                                                 *-* 49000017
*-*      H A N D L E   N O   J O B S   FOR                          *-* 49100017
*-*             S H O W   J O B S ( , J O B N A M E )               *-* 49200017
*-*                                                                 *-* 49300017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 49400017
         SPACE                                                          49500017
JIRNOJ   DS    0H             **** TAG FOR BRANCHING                    49600017
         MVI   JIROFF,MO04         PLACE PROPER MSG OFFSET IN PARM LIST 49700017
         CLI   RTYPE,MAJOR         IS THIS A MAJOR REQUEST              49800017
         BE    JIRERR              YES, FINISH UP AND SEND MSG          49900017
         MVC   JIRSAM(L8),RTYPE    MOVE NAME OF UNFOUND JOB INTO TEXT   50000017
         SPACE                                                          50100017
         MVI   JIRLNG,L13          MOVE PROPER LENGTH INTO PARM LIST    50200017
         B     JIRUP               FINISH UP AND SEND MSG               50300017
         SPACE 2                                                        50400017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 50500017
*-*                                                                 *-* 50600017
*-*    H A N D L E   N O   R E P O R T E D   E N T R I E S          *-* 50700017
*-*                                                                 *-* 50800017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 50900017
         SPACE                                                          51000017
JIRNOM   DS    0H             **** TAG FOR BRANCHING                    51100017
         CLI   OTYPE,DEFER         REPORT OF DEFERRED OUTPUT REQUESTED  51200017
         BNE   JIRNOJ              SEND OPERATOR FORM OF IHK004I MSG    51300017
         SPACE                                                          51400017
         CLI   RTYPE,MAJOR         WERE ALL DEFERRED JOBS REQUESTED     51500017
         BE    JIRSND              YES, TELL OPERATOR NO DEFERRED JOBS  51600017
         SPACE                                                          51700017
         MVC   JIRBUID(L3),RTYPE   MOVE REQUESTED USERID INTO MSG TEXT  51800017
         B     JIRSND              TELL OPERATOR NO DEFERRED JOBS FOR   51900017
*                                  - SPECIFIED USERID                   52000017
         EJECT                                                          52100017
*********************************************************************** 52200017
*---------------------------------------------------------------------* 52300017
*-*******************************************************************-* 52400017
*-*                                                                 *-* 52500017
*-*  C O N S T A N T S ,   W O R K   A R E A S   AND   D S E C T S  *-* 52600017
*-*                                                                 *-* 52700017
*-*******************************************************************-* 52800017
*---------------------------------------------------------------------* 52900017
*********************************************************************** 53000017
         SPACE 2                                                        53100017
JIRSAV   DC    18F'0'                                                   53200017
         SPACE                                                          53300017
         DS    0D                                                       53400017
JIRCVD   DC    F'0'                                                     53500017
JIRUPK   DC    F'0'                                                     53600017
DIP      DC    1F'0'                                                    53700017
         SPACE                                                          53800017
* IHKCBLDM PARAMETER LIST                                               53900017
         SPACE                                                          54000017
JIRMSG   DC    1F'0'          DESTINATION- CENTRAL OPERATOR             54100017
         DC    X'00'          PAD                                       54200017
JIROFF   DC    X'2A'          IHK028I MESSAGE OFFSET (42)               54300017
JIRLNG   DC    X'1C'          VARIABLE MESSAGE TEXT LENGTH  (28)        54400017
JIRTXT   DS    0CL28          VARIABLE MESSAGE TEXT                     54500017
JIRNAM   DS    0CL9                                                     54600017
JIROP    DC    CL1'N'                                                   54700017
JIRTEX   DS    0CL27                                                    54800017
         DC    CL4'O DE'                                                54900017
JIRSAM   DS    0CL8                                                     55000017
         DC    CL4'FERR'                                                55100017
JIRUID   DC    CL4'ED J'                                                55200017
JIRAID   DC    CL4'OB O'                                                55300017
JIRSTA   DC    CL5'UTPUT'                                               55400017
JIRTYP   DS    0CL2                                                     55500017
         DC    CL1' '                                                   55600017
JIRBUID  DS    0CL3                                                     55700017
         DC    CL1' '                                                   55800017
JIRNUM   DC    CL4' '                                                   55900017
         SPACE                                                          56000017
SHOW     DC    CL5'SHOW '                                               56100017
INCP     DC    CL4'INCP'                                                56200017
COMP     DC    CL4'COMP'                                                56300017
NAR      DC    CL3'N/A'                                                 56400017
         EJECT                                                          56500017
*********************************************************************** 56600017
*---------------------------------------------------------------------* 56700017
*-*******************************************************************-* 56800017
*-*                                                                 *-* 56900017
*-*      C O M M A N D   I N P U T   R E C O R D   D S E C T        *-* 57000017
*-*                                                                 *-* 57100017
*-*******************************************************************-* 57200017
*---------------------------------------------------------------------* 57300017
*********************************************************************** 57400017
         SPACE 2                                                        57500017
         SPACE                                                          57600017
CIRD     DSECT                                                          57700017
CIMAGE   DS    CL80           COMMAND IMAGE                             57800017
CTYPE    DS    CL1            COMMAND OPERATION TYPE                    57900017
OTYPE    DS    CL1            COMMAND OPERAND TYPE                      58000017
RTYPE    DS    CL8            COMMAND REQUEST TYPE                      58100017
*                             - BINARY ZERO IF MAJOR REQUEST            58200017
RESV     DS    CL5            RESERVED                                  58300017
         SPACE 2                                                        58400017
      IHKDSECT ,,FASTAB,,,AVT                                           58500017
         SPACE 2                                                        58600017
         END                                                            58700017
