JPR2     TITLE  'IHKCHJPR - JED PROCESSOR REVISED'                      00100017
IHKCHJPR CSECT                                                          00200017
*********************************************************************** 00300017
*STATUS - CHANGE LEVEL 0                                              * 00400017
*FUNCTION -                                                           * 00500017
*   THIS ROUTINE BUILDS THE FAST AND JED TABLES FOR AN INPUT JOB BY   * 00600017
*   MODIFYING THE DEFAULT OPTIONS ACCORDING TO THE PARAMETERS ON THE  * 00700017
*   JED AND POSSIBLE CONTINUATION CARDS.  THE FAST TABLE JOB INFORMA- * 00800017
*   TION BYTE IS INITIALIZED TO THE RJE DEFAULTS (IMMEDIATE OUTPUT    * 00900017
*   AND NO ADDITIONAL FEATURES SUCH AS ALERT,NOTIFY, OR CENTRAL       * 01000017
*   OUTPUT).                                                          * 01100017
*                                                                     * 01200017
*   IF THERE ARE NO ERRORS IN THE JED, THE 'JIB' IS ALTERRED TO       * 01300017
*   REFLECT THE OPTIONS SPECIFIED AND, IF NECESSARY, THE ADDITIONAL   * 01400017
*   NOTIFY INFORMATION IS INSERTED IN THE JED TABLE.                  * 01500017
*                                                                     * 01600017
*ENTRY POINT -                                                        * 01700017
*        IHKCHJPR IS THE ONLY ENTRY POINT. THE CALLING SEQUENCE IS    * 01800017
*        LOAD  EP=IHKCHJPR                                            * 01900017
*        LA    R1,PARAMETER LIST                                      * 02000017
*        LR    15,0                                                   * 02100017
*        BALR  14,15                                                  * 02200017
*                                                                     * 02300017
*INPUT -                                                              * 02400017
*   REGISTER ONE WILL CONTAIN THE ADDRESS OF A PARAMETER LIST ON A    * 02500017
*   FULL WORD BOUNDARY AS FOLLOWS:                                    * 02600017
*        1. NOT USED.                                                 * 02700017
*        2. STARTING ADDRESS OF THE CARD IMAGE OR ZERO FOR ERROR.     * 02800017
*        3. TERMINAL DIRECTORY ADDRESS.                               * 02900017
*        4. ADDRESS OF THE ADDRESS VECTOR TABLE.                      * 03000017
*        5. ADDRESS OF IHKCEJDT.                                      * 03100017
*                                                                     * 03200017
*OUTPUT -                                                             * 03300017
*   IF NO ERRORS ARE FOUND, THE FAST TABLE (FASTJIB AND FASTALT) AND  * 03400017
*   THE JED TABLE NOTIFY INFORMATION ARE OUTPUT.  IF THERE WERE ERRORS* 03500017
*   IN THE JED, A MESSAGE DESCRIBING EACH ERROR IS RETURNED TO THE    * 03600017
*   TERMINAL.  IF A CENTRAL PARAMETER IS FOUND, IHKCELST (IN IHKCHRDR)* 03700017
*   WILL CONTAIN THE STEPNAME.DDNAME FOR EACH DATA SET TO BE ROUTED   * 03800017
*   TO CENTRAL.  IHKCELST MAY HAVE UP TO TEN ENTRIES OF 17 BYTES.     * 03900017
*                                                                     * 04000017
*EXTERNAL ROUTINES -                                                  * 04100017
*        IHKCAMSN - SCANS NOTIFY INFORMATION (QUOTE)                  * 04200017
*        IHKCBLDM - ENQUEUES ERROR MESSAGES.                          * 04300017
*        IHKCCSCN - SCANS CARD IMAGE.                                 * 04400017
*        IHKCCSUD - SEARCHES USER DIRECTORY FOR THE ALTERNATE USER.   * 04500017
*                                                                     * 04600017
*EXITS -                                                              * 04700017
*   NORMAL - REGISTER 15 CONTAINS ZERO.                               * 04800017
*   ERROR  - REGISTER 15 CONTAINS FOUR.                               * 04900017
*                                                                     * 05000017
*ATTRIBUTES - SERIALLY REUSABLE AND NON-RESIDENT.                     * 05100017
*                                                                     * 05200017
*NOTES:                                                               * 05300017
*   THE OPERATION OF THIS ROUTINE DEPENDS UPON AN INTERNAL REPRESEN-  * 05400017
*   TATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE   * 05500017
*   ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED SO THAT   * 05600017
*   REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT * 05700017
*   IN A CORRECT MODULE FOR THE NEW DEFINITIONS.                      * 05800017
*                                                                     * 05900017
*********************************************************************** 06000017
*                                                                       06100017
*                   SYMBOLIC REGISTER NOTATION                          06200017
*                                                                       06300017
*********************************************************************** 06400017
R0       EQU   0                                                        06500017
R1       EQU   1                   PARAMETER REGISTER                   06600017
CARDBASE EQU   2                   BASE FOR DSECT OF CARD               06700017
R3       EQU   3                   GENERAL REGISTER                     06800017
VCONBASE EQU   4                   BASE FOR DSECT OF AVT                06900017
JDTBASE  EQU   5                   BASE FOR DSECT OF IHKCEJDT           07000017
R6       EQU   6                   SCAN REGISTER - POINTER TO BYTE     *07100017
                                   BEING INVESTIGATED                   07200017
R7       EQU   7                   START ADDRESS OF KEYWORD FIELD       07300017
R8       EQU   8                   USED IN CALCULATING LENGTHS          07400017
R9       EQU   9                   USED IN CALCULATING LENGTHS          07500017
R10      EQU   10                  POINTER TO PRESENT ENTRY IN IHKCELST 07600017
LINK     EQU   11                  INTERNAL LINK REGISTER               07700017
R12      EQU   12                  BASE OF PROGRAM                      07800017
R13      EQU   13                  SAVE AREA POINTER                    07900017
R14      EQU   14                  RETURN REGISTER                      08000017
R15      EQU   15                  LINK REGISTER TO EXTERNAL ROUTINES   08100017
*                                                                       08200017
*********************************************************************** 08300017
*                                                                       08400017
*                     INITIALIZATION                                    08500017
*                                                                       08600017
*********************************************************************** 08700017
*                                                                       08800017
         STM   R14,R12,12(R13)     SAVE CALLER'S REGISTERS              08900017
         BALR  R12,0               SET UP ADDRESSIBILITY                09000017
         USING *,R12                                                    09100017
         B     AROUND              BRANCH AROUND IDENTIFIER             09200017
         DC    C'IHKCHJPR'                                              09300017
AROUND   DS    0H                                                       09400017
         LA    R3,SAVE             GET ADDRESS OF MY SAVE AREA          09500017
         ST    R3,8(R13)           STORE IT IN CALLER'S SAVE AREA       09600017
         ST    R13,SAVE+4          CHAIN SAVE AREAS                     09700017
         LR    R13,R3              GET ADDRESS OF MY SAVE AREA IN R13   09800017
*                                                                       09900017
         USING IHKZZAVT,VCONBASE                                        10000017
         USING IHKCEJDT,JDTBASE                                         10100017
         USING CARD,CARDBASE                                            10200017
*                                                                       10300017
         LM    CARDBASE,JDTBASE,4(R1)  PICK UP INPUT PARAMETERS         10400017
         ST    R3,TERMINAL         PUT TERMINAL ADDRESS IN MSGLIST      10500017
*                                                                       10600017
         LA    R6,CONTINUE         KEEP ADDRESS OF COL 72               10700017
         ST    R6,COL72                                                 10800017
         BCTR  R6,0                STOP SCANS AT COL 71                 10900017
         ST    R6,STOP                                                  11000017
         ST    R6,MSNSTOP                                               11100017
*                                                                       11200017
*********************************************************************** 11300017
*                                                                       11400017
*              DETERMINATION OF REASON FOR ENTERING IHKCEJPR            11500017
*                                                                       11600017
*********************************************************************** 11700017
*                                                                       11800017
         LTR   CARDBASE,CARDBASE   TEST FOR NO JOB CARD                 11900017
         BZ    CONTERRA            GIVE ERROR MESSAGE                   12000017
         MVC   SEQUENCE,SEQNCE     SAVE SEQUENCE NUMBER OF CARD         12100017
*                                                                       12200017
*********************************************************************** 12300017
*                                                                       12400017
*              SCAN TO OBTAIN ADDRESS OF FIRST KEYWORD                  12500017
*                                                                       12600017
*********************************************************************** 12700017
*                                                                       12800017
         LA    R6,NOTUSED          STARTING ADDRESS OF SCAN             12900017
         BAL   LINK,SUBSCAN        GO TO SCAN SUBROUTINE                13000017
*                                                                       13100017
         CLC   JED,0(R6)           CHECK FOR JED                        13200017
         BNE   GETCD01             NO, CONTINUE PROCESSING              13300017
*                                                                       13400017
         MVI   JEDTNMSG,BLANK           BLANK OUT NOTIFY MSG            13500017
         MVC   JEDTNMSG+1(24),JEDTNMSG                                  13600017
         LA    R6,3(R6)            GET NEW STARTING ADDRESS (AFTER JED) 13700017
         BAL   LINK,SUBSCAN        GO TO SCAN                           13800017
*                                                                       13900017
         BZ    ALLBLANK            BRANCH IF NO NON-BLANK               14000017
*                                                                       14100017
         CLI   0(R6),COMMA         CHECK FOR COMMENTS                   14200017
         BE    COMMENTS            BRANCH TO VERIFY                     14300017
*                                                                       14400017
*********************************************************************** 14500017
*                                                                       14600017
*              KEYWORD PROCESSING ROUTINE                               14700017
*                                                                       14800017
*********************************************************************** 14900017
*                                                                       15000017
KEYWORD  MVI   NOCHAR+1,X3         THREE CHARS FOR SCAN                 15100017
         MVC   CHARS(3),CHARSET1   SCAN FOR BLANK =                     15200017
         LR    R7,R6               KEEP START ADDRESS                   15300017
         BAL   LINK,SUBSCAN        GO TO SCAN                           15400017
*                                                                       15500017
         BZ    INVKEYA             NONE FOUND, CHECK ON CONT.           15600017
         CH    R15,H12             WAS = FOUND?                         15700017
         BL    INVKEY                                                   15800017
*                                                                       15900017
*                                  EQUAL - ANOTHER KEYWORD              16000017
         CLC   CENTRAL,0(R7)       CENTRAL?                             16100017
         BE    SETCEN              YES, GO TO CENTRAL PROCESSING        16200017
*                                                                       16300017
         CLC   OUTPUT,0(R7)        OUTPUT?                              16400017
         BE    SETOUT              YES, GO TO OUTPUT PROCESSING         16500017
*                                                                       16600017
         CLC   NOTIFY,0(R7)        NOTIFY?                              16700017
         BE    SETNOT              YES, GO TO NOTIFY PROCESSING         16800017
*                                                                       16900017
         B     INVKEYB             INVALID KEYWORD ERROR                17000017
*                                                                       17100017
*********************************************************************** 17200017
*                                                                       17300017
*              SUBROUTINE - COMMON ATTRIBUTES OF SCANS                  17400017
*                                                                       17500017
*********************************************************************** 17600017
*                                                                       17700017
SUBSCANA DS    0H                                                       17800017
         MVC   CHARS(2),CHARSET4   SCAN FOR SET 4                       17900017
SUBSCANB DS    0H                                                       18000017
         MVI   NOCHAR+1,X2         TWO CHARACTER SCAN                   18100017
SUBSCAN  ST    R6,START            PUT START ADDRESS IN INPUT PARM      18200017
         LA    R1,SCAN             GET PARM ADDRESS                     18300017
         L     R15,IHKZZSCN        GET ADDRESS OF SCAN ROUTINE          18400017
         BALR  R14,R15             SCAN                                 18500017
         LTR   R15,R15             CHECK RETURN CODE                    18600017
         BCR   8,LINK              IF NOT FOUND,DO NOT CHANGE R6        18700017
         LR    R6,R1               GET ADDRESS OF FOUND VALUE IN R6     18800017
         BR    LINK                RETURN                               18900017
*                                                                       19000017
*********************************************************************** 19100017
*                                                                       19200017
*        SUBROUTINE - COMMON TESTS FOR EACH KEYWORD                     19300017
*                                                                       19400017
*********************************************************************** 19500017
*                                                                       19600017
SUBSET   BZ    SUBSETA             NOT DUPLICATE - BYPASS ERROR MSG     19700017
         BAL   R3,MANYKEY          DUPLICATE - SEND ERROR               19800017
SUBSETA  DS    0H                                                       19900017
         LA    R6,1(R6)            STEP PAST =                          20000017
         CLI   0(R6),LTPAREN       IS OPERAND COMPLEX                   20100017
         BE    COMPLEX             YES, GO TO COMPLEX PROCESS           20200017
         NI    SWITCH,SIMPLE       TURN OFF COMPLEX SWITCH              20300017
         BR    LINK                RETURN                               20400017
*                                                                       20500017
*********************************************************************** 20600017
*                                                                       20700017
*                   SIMPLE NOTIFY PARAMETER PROCESSING                  20800017
*                                                                       20900017
*********************************************************************** 21000017
*                                                                       21100017
SETNOT   MVI   NOW,NOWNOT          SET NOTIFY BEING PROCESSED           21200017
         TS    NOTSW               CHECK IF NOTIFY DONE ALREADY         21300017
         BAL   LINK,SUBSET         FINISH CHECKING                      21400017
         BAL   LINK,SUBNOT         HANDLE FOR COMMON SUBPARMS           21500017
         B     SUBEND              CHECK DELIMITER                      21600017
*                                                                       21700017
*********************************************************************** 21800017
*                                                                       21900017
*              SUBROUTINE - THINGS COMMON TO SIMPLE AND COMPLEX NOTIFY  22000017
*                                                                       22100017
*********************************************************************** 22200017
*                                                                       22300017
SUBNOT   CLC   BOTH,0(R6)          CHECK FOR BOTH SUBPARM               22400017
         BE    NOTBOTH             HANDLE BOTH                          22500017
*                                                                       22600017
         CLC   SOURCE,0(R6)        CHECK FOR SOURCE SUBPARM             22700017
         BNE   NOTERR              NO, KEYWORD VALUE ERROR              22800017
*                                                                       22900017
         LA    R6,6(R6)            STEP PAST SOURCE                     23000017
         B     NOTSRCE             HANDLE SOURCE                        23100017
*                                                                       23200017
NOTBOTH  OI    MYFJIB,NOTALT       SET NOTIFY ALTERNATE BIT IN JIB      23300017
         LA    R6,4(R6)            STEP PAST BOTH                       23400017
*                                                                       23500017
NOTSRCE  OI    MYFJIB,NOTSRC       SET NOTIFY SOURCE BIT IN JIB         23600017
         BR    LINK                RETURN                               23700017
*                                                                       23800017
*********************************************************************** 23900017
*                                                                       24000017
*                  COMPLEX NOTIFY PARAMETER PROCESSING                  24100017
*                                                                       24200017
*********************************************************************** 24300017
*                                                                       24400017
COMNOT   BAL   LINK,SUBNOT         HANDLE COMMON SUBPARMS               24500017
         BAL   LINK,SUBPAREN       CHECK FOR COMMA OR PAREN             24600017
         CLI   0(R6),QUOTE         CHECK FOR QUOTE                      24700017
         BNE   NOTERR              NO QUOTE = ERROR                     24800017
*                                                                       24900017
*                                                                       25000017
         ST    R6,MSNLIST          PUT ADDRESS OF LEADING QUOTE IN MSN  25100017
         LA    R1,MSNLIST          GET ADDRESS OF PARM LIST             25200017
         L     R15,IHKZZMSN        GET ADDRESS OF MSN                   25300017
         BALR  R14,R15             CHECK TEXT                           25400017
*                                                                       25500017
         LTR   R15,R15                  TEST RETURN CODE                25600017
         BNZ   NOTERR                   RETURN NOT 0 = ERROR            25700017
*                                                                       25800017
         LM    R8,R10,0(R1)        GET PARMS FROM MSN                   25900017
         SR    R9,R8               GET LENGTH OF QUOTE +1               26000017
         BCTR  R9,0                GET LENGTH OF QUOTE                  26100017
         LTR   R9,R9               CHECK FOR ZERO LENGTH                26200017
         BZ    NOTEXT              HANDLE NO TEXT                       26300017
*                                                                       26400017
         BCTR  R9,0                DECREMENT FOR EXECUTE                26500017
         EX    R9,TEXT             MOVE TEXT TO JEDTNMSG                26600017
         OI    MYFJIB,TEXTBIT      SET TEXT BIT IN JIB                  26700017
*                                                                       26800017
NOTEXT   DS    0H                                                       26900017
         LA    R6,1(R10)           STEP PAST TRAILING QOUTE             27000017
         CLI   0(R6),RTPAREN       CHECK FOR PAREN AFTER QUOTE          27100017
         BNE   NOTERRA             NO ) = ERROR                         27200017
*                                                                       27300017
         LA    R6,1(R6)            STEP PAST PAREN                      27400017
         B     NEXTKEYW            NOW GO TO NEXT KEYWORD               27500017
*                                                                       27600017
*********************************************************************** 27700017
*                                                                       27800017
*        SUBROUTINE - COMMON CHECKS FOR COMMA OR PARENTHESIS            27900017
*                                                                       28000017
*********************************************************************** 28100017
*                                                                       28200017
SUBPAREN CLI   0(R6),RTPAREN       CHECK FOR SINGLE PARM IN PARENS      28300017
         BE    PRENEXT             YES, STEP TO NEXT KEYWORD            28400017
         CLI   0(R6),COMMA         COMMA?                               28500017
         LA    R6,1(R6)            STEP PAST                            28600017
         BCR   8,LINK              RETURN IF COMMA                      28700017
ERR      DS    0H                                                       28800017
         CLI    NOW,NOWNOT         SEE WHICH KEYWORD BEING PROCESSED    28900017
         BE    NOTERR              NOTIFY                               29000017
         B     OUTERR              OUTPUT                               29100017
*                                                                       29200017
*********************************************************************** 29300017
*                                                                       29400017
*                   SIMPLE OUTPUT PARAMETER PROCESSING                  29500017
*                                                                       29600017
*********************************************************************** 29700017
*                                                                       29800017
SETOUT   MVI   NOW,NOWOUT          SET FOR OUTPUT BEING PROCESSED       29900017
         TS    OUTSW               SEE IF OUTPUT ALREADY DONE           30000017
         BAL   LINK,SUBSET         FINISH CHECKING                      30100017
         BAL   LINK,SUBOUT         HANDLE COMMON SUBPARMS               30200017
SUBEND   DS    0H                                                       30300017
         LA    LINK,ERR            SET TO RETURN TO ERROR IF NO COMMA   30400017
*                                  OR BLANK FOUND                       30500017
         B     NEXTKEY             GO CHECK FOR COMMA OR BLANK          30600017
*                                                                       30700017
*********************************************************************** 30800017
*                                                                       30900017
*              SUBROUTINE - THINGS COMMON TO SIMPLE AND COMPLEX OUTPUT  31000017
*                                                                       31100017
*********************************************************************** 31200017
*                                                                       31300017
SUBOUT   CLC   IMMED,0(R6)         IMMED?                               31400017
         BE    OUTIMMED            YES, PROCESS IMMED                   31500017
*                                                                       31600017
         CLC   DEFER,0(R6)         DEFER?                               31700017
         BNE   OUTERR              NO, KEYWORD VALUE ERROR              31800017
*                                                                       31900017
         NI    MYFJIB,DEFERRED     SET JIB FOR DEFERRED OUTPUT          32000017
*                                                                       32100017
OUTIMMED LA    R6,5(R6)            STEP PAST SUBPARM                    32200017
         BR    LINK                RETURN                               32300017
*                                                                       32400017
*********************************************************************** 32500017
*                                                                       32600017
*                  COMPLEX OUTPUT PARAMETER PROCESSING                  32700017
*                                                                       32800017
*********************************************************************** 32900017
*                                                                       33000017
COMOUT   BAL   LINK,SUBOUT         HANDLE COMMON SUBPARMS               33100017
         BAL   LINK,SUBPAREN       CHECK FOR COMMA OR PAREN             33200017
         CLI   3(R6),RTPAREN       CHECK FOR CLOSING PAREN              33300017
         BNE   OUTERR              NO PAREN = ERROR                     33400017
*                                                                       33500017
         LA    R3,NOALT            SET FOR RETURN FROM ERROR            33600017
         TM    MYFJIB,IMMEDON      CHECK ON IMMED OUTPUT                33700017
         BO    IGNALT              IF IMMED, IGNORE ALTERNATE           33800017
*                                                                       33900017
         MVC   USER(3),0(R6)       MOVE USERID TO FULL WORD             34000017
         L     R1,USER             LOAD USERID INTO R1                  34100017
         L     R15,IHKZZSUD        GET ADDRESS OF SEARCH ROUTINE        34200017
         BALR  R14,R15             FOR SEARCH OF USER DIRECTORY         34300017
         LTR   R1,R1               SEE IF USERID VALID                  34400017
         BZ    IGNALT              INVALID USER = IGNORE                34500017
*                                                                       34600017
         MVC   MYFALT,USER         MOVE USERID TO MY FAST TABLE         34700017
NOALT    DS    0H                                                       34800017
         NI    SWITCH,ALTERRF      TURN OFF ALTERNATE WARNING SWITCH    34900017
         LA    R6,4(R6)            STEP PAST PAREN                      35000017
         B     NEXTKEYW            GO TO NEXT KEYWORD                   35100017
*                                                                       35200017
*********************************************************************** 35300017
*                                                                       35400017
*                   SIMPLE CENTRAL PARAMETER PROCESSING                 35500017
*                                                                       35600017
*********************************************************************** 35700017
*                                                                       35800017
SETCEN   MVI   NOW,NOWCEN          SET CENTRAL BEING PROCESSED          35900017
         OI    MYFJIB,CENOP        SET CENTRAL OPERAND IN JIB           36000017
         TS    CENSW               CHECK IF CENTRAL OPD ALREADY DONE    36100017
         LA    R9,IHKCELST         GET ADDRESS OF START OF IHKCELST     36200017
         LA    R10,IHKCELST+180    GET ADDRESS OF END OF IHKCELST       36300017
*                                                                       36400017
         BAL   LINK,SUBSET         FINISH CHECKING                      36500017
         CLI   3(R6),BLANK         CHECK ON BLANK                       36600017
         BE    GOALL               YES, SEE IF ALL BLANK                36700017
         CLI   3(R6),COMMA         SEE IF COMMA                         36800017
         BNE   TRYSTEP             NO, TRY FOR STEP.DD                  36900017
GOALL    DS    0H                                                       37000017
         BAL   LINK,SUBALL         GO CHECK ALL                         37100017
         B     NEXTKEYW            CONTINUE TO NEXT KEYWORD             37200017
TRYSTEP  DS    0H                                                       37300017
         BAL   R7,SUBCENT          START-PROCESSING STEP.DD             37400017
         BZ    SUBCENA             NO DELIM = SPECIAL HANDLING          37500017
         LA    R7,NEXTKEYW         SET TO RETURN TO NEXTKEYWORD         37600017
         B     SUBCENB             PROCESS STEP.DD                      37700017
*                                                                       37800017
*********************************************************************** 37900017
*                                                                       38000017
*              SUBROUTINE - PROCESSES 'ALL' IN CENTRAL OPERAND          38100017
*                                                                       38200017
*********************************************************************** 38300017
*                                                                       38400017
SUBALL   DS    0H                                                       38500017
         CLC   ALL,0(R6)           CHECK FOR ALL SPECIFIED              38600017
         BNE   4(LINK)             ALL NOT FOUND                        38700017
*                                                                       38800017
         MVC   IHKCELST(3),ALL     MOVE ALL TO IHKCELST                 38900017
         LA    R6,3(R6)            STEP PAST ALL                        39000017
         BR    LINK                RETURN                               39100017
*                                                                       39200017
*********************************************************************** 39300017
*                                                                       39400017
*              SUBROUTINE - STARTS PROCESSING STEPNAME.DDNAME           39500017
*                                                                       39600017
*********************************************************************** 39700017
*                                                                       39800017
SUBCENT  DS    0H                                                       39900017
COMCEN   ST    R6,BEGIN            SAVE BEGINNING OF STEP.DDNAME        40000017
         MVI   NOCHAR+1,X1         SET FOR ONE CHAR SCAN                40100017
         MVI   CHARS,DOT           SCAN FOR .                           40200017
         BAL   LINK,SUBSCAN        GO TO SCAN                           40300017
         BZ    CENERRA             DOT NOT FOUND = ERROR                40400017
*                                                                       40500017
         BAL   LINK,CHECKLEN                                            40600017
         LA    R6,1(R6)            STEP PAST DOT                        40700017
         MVI   NOCHAR+1,X3         SET FOR THREE CHAR SCAN              40800017
         MVC   CHARS,CHARSET2      SCAN FOR BLANK ) ,                   40900017
         BAL   LINK,SUBSCAN        GO TO SCAN                           41000017
*                                                                       41100017
         BR    R7                  RETURN                               41200017
*                                                                       41300017
*********************************************************************** 41400017
*                                                                       41500017
*              SUBROUTINE - CHECKS TOTAL LENGTH AND MOVES STEP.DD       41600017
*                                                                       41700017
*********************************************************************** 41800017
*                                                                       41900017
SUBCENA  DS    0H                                                       42000017
         L     R6,COL72            SET FOR DELIMITER IN 72              42100017
         LA    R7,BLANK72          SET TO RETURN TO BLANK72             42200017
SUBCENB  DS    0H                                                       42300017
         BAL   LINK,CHECKLEN       CHECK LENGTH                         42400017
*                                                                       42500017
         LR    R8,R6               TEST TOTAL LENGTH                    42600017
         L     R1,BEGIN            GET ADDRESS OF BEGINNING IN R1       42700017
         SR    R8,R1               GET LENGTH                           42800017
         C     R8,ENTLEN           SEE IF TOTAL LENGTH IS VALID         42900017
         BCR   11,R7               BAD LENGTH, DO NOT MOVE              43000017
*                                                                       43100017
         BCTR  R8,0                DECREMENT FOR EXECUTE                43200017
         EX    R8,STEPDD           MOVE STEPNAME.DDNAME TO IHKCELST     43300017
*                                                                       43400017
         BR    R7                  RETURN                               43500017
*                                                                       43600017
*********************************************************************** 43700017
*                                                                       43800017
*              DETERMINATION OF WHICH COMPLEX KEYWORD TO PROCESS        43900017
*                                                                       44000017
*********************************************************************** 44100017
*                                                                       44200017
COMPLEX  LA    R6,1(R6)            STEP PAST (                          44300017
         OI    SWITCH,COMPLX       SET COMPLEX SWITCH                   44400017
         CLI   NOW,NOWNOT          CHECK FOR KEYWORD BEING PROCESSED    44500017
         BL    COMOUT              GO TO OUTPUT                         44600017
         BZ    COMNOT              GO TO NOTIFY                         44700017
*                                                                       44800017
*********************************************************************** 44900017
*                                                                       45000017
*                  COMPLEX CENTRAL PARAMETER PROCESSING                 45100017
*                                                                       45200017
*********************************************************************** 45300017
*                                                                       45400017
         CLI   3(R6),RTPAREN       CHECK FOR (ALL)                      45500017
         BNE   SUBCEN              NO, GO TO PROCESS STEP.DD            45600017
         BAL   LINK,SUBALL         GO CHECK FOR ALL                     45700017
         B     PRENEXT             GO ON TO NEXT KEYWORD                45800017
SUBCEN   DS    0H                                                       45900017
         BAL   R7,SUBCENT          PROCESS PART OF STEP.DD              46000017
         B     *+4(R15)            BRANCH ON RETURN CODE                46100017
         B     CENERRBA            NONE FOUND (DELIMITERS)              46200017
         B     CENERRB             BLANK = ERROR                        46300017
         OI    SWITCH,PAREN        SET SWITCH FOR PARENTHESIS           46400017
         BAL   R7,SUBCENB          PROCESS STEP.DD                      46500017
*                                                                       46600017
         LA    R6,1(R6)            STEP PAST COMMA OR PAREN             46700017
         TM    SWITCH,PAREN        SEE IF PAREN ENCOUNTERED             46800017
         BO    NEXTKEYW            YES, GO TO NEXT KEYWORD              46900017
*                                                                       47000017
         A     R9,ENTLEN           BUMP TO NEXT SLOT                    47100017
         CLR   R9,R10              TEST FOR END OF IHKCELST             47200017
         BL    LENOK               STILL SLOTS - DO NOT SEND MSG        47300017
         BAL   R3,CENERR           NO SLOTS = ERROR                     47400017
         S     R9,ENTLEN           STEP BACK TO PREVIOUS ENTRY          47500017
LENOK    DS    0H                                                       47600017
         C     R6,COL72            SEE IF COMMA IN 71                   47700017
         BH    CONTERR             PAST = ERROR                         47800017
         BE    CENCD               YES = NEED NEW CARD IF CONT.         47900017
         CLI   0(R6),BLANK         SEE IF BLANK AFTER COMMA             48000017
         BNE   SUBCEN              GO PROCESS STEP.DD                   48100017
*                                                                       48200017
CENCD    CLI   CONTINUE,BLANK      CHECK FOR CONT.                      48300017
         BE    BADELIMA            NO,BAD DELIMITER                     48400017
         BAL   LINK,GETCD          YES,GET ANOTHER CARD                 48500017
         LA    R6,OPERAND          POSITION AT START OF OP'D FIELD      48600017
         B     SUBCEN              CONTINUE PROCESSING                  48700017
*                                                                       48800017
*                                                                       48900017
*********************************************************************** 49000017
*                                                                       49100017
*              SUBROUTINE - CHECKS LENGTH OF STEPNAME OR DDNAME         49200017
*                                                                       49300017
*********************************************************************** 49400017
*                                                                       49500017
CHECKLEN DS    0H                                                       49600017
         LR    R8,R6               START TO FIND LENGTH OF STEPNAME     49700017
         S     R8,START            FIND LENGTH                          49800017
         LTR   R8,R8               CHECK FOR ZERO                       49900017
         BZ    ERRCEN              ZERO = ERROR                         50000017
         CL    R8,MAXNAME          CHECK LENGTH                         50100017
         BCR   12,LINK             GOOD = RETURN                        50200017
ERRCEN   BAL   R3,CENERR           LENGTH BAD = ERROR                   50300017
         BR    LINK                GOOD RETURN                          50400017
*                                                                       50500017
*********************************************************************** 50600017
*                                                                       50700017
*              SETUP FOR NEXT KEYWORD PROCESSING                        50800017
*                                                                       50900017
*********************************************************************** 51000017
*                                                                       51100017
PRENEXT  LA    R6,1(R6)                                                 51200017
NEXTKEYW DS    0H                                                       51300017
         LA    LINK,BADELIMB       SET TO RETURN TO DELIM. ERROR        51400017
NEXTKEY  DS    0H                                                       51500017
         CLI   0(R6),BLANK         SEE IF OP'D FOL BY COMMA             51600017
         BNE   TRYCOMMA            NO,TRY COMMA                         51700017
*                                                                       51800017
         C     R6,COL72            SEE IF IN COL 72                     51900017
         BH    CONTERR             PAST =ERROR                          52000017
         BE    DONE                YES = DONE                           52100017
         B     COMMENT             LOW = START COMMENTS                 52200017
*                                                                       52300017
TRYCOMMA CLI   0(R6),COMMA         SEE IF COMMA                         52400017
         BCR   7,LINK                   RETURN IF NO COMMA OR BLANK     52500017
         C     R6,STOP             SEE IF IN COL 71                     52600017
         BH    CONTERR             PAST = ERROR                         52700017
         BE    CHECKCON            YES = NEW CARD IF CONT.              52800017
*                                                                       52900017
RESET    CLI   1(R6),BLANK         BLANK AFTER COMMA?                   53000017
         BE    CHECKCON            SEE IF CONTINUED OP'D                53100017
*                                                                       53200017
         LA    R6,1(R6)            STEP PAST COMMA                      53300017
         B     KEYWORD             GO TO PROCESS KEYWORD                53400017
*                                                                       53500017
*                                                                       53600017
*********************************************************************** 53700017
*                                                                       53800017
*              SUBROUTINE - GETS ANOTHER CARD FROM THE READER           53900017
*                                                                       54000017
*********************************************************************** 54100017
*                                                                       54200017
GETCD    DS    0H                                                       54300017
         STM   R9,LINK,SAVELINK                                         54400017
         B     NORMEXIT            RETURN WITH CODE 0                   54500017
*                                                                       54600017
GETCD01  DS    0H                                                       54700017
         LM    R9,LINK,SAVELINK                                         54800017
*                                                                       54900017
         CLC   NOTUSED,BLANKS      CHECK FOR BLANKS IN 3 - 15           55000017
         BNE   CONTERR             NO BLANKS = ERROR                    55100017
*                                                                       55200017
         TM    SWITCH,CONTCOMM     CHECK FOR CONTINUED COMMENTS         55300017
         BO    CONTCOM             YES, GO PROCESS                      55400017
*                                                                       55500017
         CLI   OPERAND,BLANK       CHECK FOR BLANK IN 16                55600017
         BE    CONTERR             BLANK = ERROR                        55700017
*                                                                       55800017
         BR    LINK                RETURN                               55900017
*                                                                       56000017
*********************************************************************** 56100017
*                                                                       56200017
*              ERROR HANDLING ROUTINES                                  56300017
*                                                                       56400017
*********************************************************************** 56500017
*                                                                       56600017
*                                                                       56700017
*              CONTINUATION ERROR                                       56800017
*                                                                       56900017
CONTERR  OI    SWITCH,CONTPRF           DO NOT CONTINUE PROCESSING      57000017
CONTERRA MVI   OFFSET,O12          OFFSET 12                            57100017
         LA    R3,DONE             SET FOR EXIT ON READER'S MESSAGE     57200017
         B     GENERR                                                   57300017
*                                                                       57400017
*              INVALID KEYWORD ERROR                                    57500017
*                                                                       57600017
INVKEYA  OI    SWITCHA,END71       INVALID KEYWORD ENDS IN 71           57700017
INVKEYB  OI    SWITCHA,MISPL       INVALID KEYWORD PROBABLY MISSPELLED  57800017
INVKEY   MVI   OFFSET,O16          OFFSET 16                            57900017
         BAL   R3,GENERR           SEND ERROR MSG                       58000017
         CLI   SWITCHA,MISPL       DETERMINE REPOSITIONING              58100017
         MVI   SWITCHA,X0          RESET SWITCHES                       58200017
         BL    NEXTKEYW            INVKEY = GO TO MEXT KEYWROD          58300017
         BH    BLANK72             INVKEYA = CHECK CONTINUATION         58400017
         CLI   1(R6),LTPAREN       INVKEYB = CHECK COMPLEXITY           58500017
         BNE   CONTPR1             SIMPLE, CONTINUE                     58600017
SCANPRN  DS    0H                                                       58700017
         MVC   CHARS(2),CHARSET3   SCAN FOR ) BLANK                     58800017
         BAL   LINK,SUBSCANB       GO SCAN                              58900017
         BZ    BLANK72             NONE = CHECK CONT.                   59000017
         C     R15,FOUR            SEE IF PAREN                         59100017
         BE    PRENEXT             PAREN = STEP TO NEXT KEYWORD         59200017
         B     COMMENT             NO, START COMMENTS                   59300017
*                                                                       59400017
*              ILLEGAL DELIMITER ERROR                                  59500017
*                                                                       59600017
BADELIMB DS    0H                                                       59700017
         LA    R3,CONTPR1          SET TO GO TO CONTINUE PROCESSING     59800017
         B     BADELIM             GO SEND ERROR MESSAGE FOR DELIMITER  59900017
BADELIMA LA    R3,DONE                                                  60000017
BADELIM  MVI   OFFSET,O8                OFFSET 8                        60100017
         B     GENERR              FINISH CREATING MESSAGE              60200017
*                                                                       60300017
*              IGNORE ALTERNATE ERROR                                   60400017
*                                                                       60500017
IGNALT   MVI   OFFSET,O43          OFFSET 43                            60600017
         OI    SWITCH,ALTERRN      TURN ON ALT IGNORED SWIYCH           60700017
         B     GENERR                                                   60800017
*                                                                       60900017
*              MULTIPLE USE OF KEYWORD ERROR                            61000017
*                                                                       61100017
MANYKEY  MVI   OFFSET,O18          OFFSET 18                            61200017
GENERR   MVI   LENGTH,L12          LENGTH=12                            61300017
         MVC   TYPE,SEQUENCE       MOVE SEQUENCE                        61400017
         B     ERROUT              GO TO ERROR EXIT                     61500017
*                                                                       61600017
*              OUTPUT KEYWORD ERROR                                     61700017
*                                                                       61800017
OUTERR   MVC   TYPE(6),OUTPUT      MOVE OUTPUT TO MSG                   61900017
         B     COMRR               GO TO FINISH ERROR HANDLING          62000017
*                                                                       62100017
*              NOTIFY KEYWORD ERROR                                     62200017
*                                                                       62300017
NOTERRA  OI    SWITCHA,NOPRN       DO NOT SCAN FOR )                    62400017
NOTERR   MVC   TYPE(6),NOTIFY      MOVE NOTIFY TO MSG                   62500017
COMRR    DS    0H                                                       62600017
         MVI   TYPE+6,BLANK        BLANK OUT REST OF TYPE               62700017
         BAL   R3,KEYERR           SEND MSG                             62800017
         TM    SWITCH,COMPLX       COMPLEX KEYWORD?                     62900017
         BZ    CONTPR1             NO, CONTINUE                         63000017
         TM    SWITCHA,NOPRN       DO WE SCAN FOR )                     63100017
         BZ    SCANPRN             YES, GO SCAN FOR )                   63200017
         NI    SWITCHA,NOPRNF      TURN OFF SWITCH                      63300017
         LA    LINK,KEYWORD             SET TO GO TO NEXT KEYWORD       63400017
         B     NEXTKEY                  GO TO NEXT KEYWORD              63500017
*                                                                       63600017
*              CENTRAL KEYWORD ERROR                                    63700017
*                                                                       63800017
CENERRA  BAL   R3,CENERR                                                63900017
         B     CONTPR1             SCAN FOR , BLANK                     64000017
CENERRB  BAL   R3,CENERR                                                64100017
         B     COMMENT             COMMENTS                             64200017
CENERRBA BAL   R3,CENERR                                                64300017
         B     BLANK72             CHECK CONT.                          64400017
CENERR   MVC   TYPE(7),CENTRAL     MOVE CENTRAL TO MSG                  64500017
KEYERR   MVI   OFFSET,O4           OFFSET 4                             64600017
         MVI   LENGTH,L21          LENGTH 21                            64700017
         MVI   TYPE+7,BLANK        FINISH BLANKING                      64800017
         MVC   VSEQ,SEQUENCE            MOVE SEQUENCE TO MESSAGE        64900017
*                                                                       65000017
*********************************************************************** 65100017
*                                                                       65200017
*              EXIT FOR ERRORS                                          65300017
*                                                                       65400017
*********************************************************************** 65500017
*                                                                       65600017
ERROUT   LA    R1,MSGLIST               GET PARM LIST                   65700017
         L     R15,IHKZZLDM             GET ADDRESS OF BUILD MESSAGE    65800017
         BALR  R14,R15                  BUILD MESSAGE                   65900017
*                                                                       66000017
         TM    SWITCH,ALTERRN      SEE IF ALT IGNORED WARNING           66100017
         BCR   1,R3                YES, RETURN                          66200017
         OI    SWITCH,ERRORS       SETT ERROR SWITCH                    66300017
         TM    SWITCH,CONTPRF           SEE IF SHOULD CONTINUE PROCESS  66400017
         BCR   8,R3                CONTINUE PROCESSING                  66500017
*                                                                       66600017
         NI    SWITCH,CONTPRN           RESET SWITCH                    66700017
*                                                                       66800017
         B     AFTCONTR            SEE WHAT TO DO NEXT                  66900017
*                                                                       67000017
ERREXIT  EQU   *                                                        67100017
         MVI   IHKCELST,BLANK      CLEAR OUT CENTRAL LIST               67200017
         MVC   IHKCELST+1(179),IHKCELST                                 67300017
         MVI   MYFJIB,DEFAULT      RE-INITIALIZE ON ERROR               67400017
         XC    MYFALT,MYFALT                                            67500017
         LA    R15,4                    SET RETURN CODE = 4             67600017
         B     EXIT                     RETURN                          67700017
*                                                                       67800017
*                                                                       67900017
*********************************************************************** 68000017
*                                                                       68100017
*              SETUP FOR ATTEMPT TO CONTINUE AFTER ERROR                68200017
*                                                                       68300017
*********************************************************************** 68400017
*                                                                       68500017
CONTPR1  DS    0H                                                       68600017
         BAL   LINK,SUBSCANA       SCAN FOR COMMA OR BLANK              68700017
*                                                                       68800017
         C     R15,FOUR            CHECK RETURN CODE                    68900017
         BE    COMMENT             BLANK- START COMMENTS                69000017
         BH    RESET               COMMA - SET UP NEXT KEYW             69100017
BLANK72  CLI   CONTINUE,BLANK      NONE - CHECK CONT.                   69200017
         BE    DONE                NO = DONE                            69300017
         B     CONTERR             YES = ERROR                          69400017
*                                                                       69500017
*********************************************************************** 69600017
*                                                                       69700017
*              BLANK (POSSIBLE COMMENTS) HANDLER                        69800017
*                                                                       69900017
*********************************************************************** 70000017
*                                                                       70100017
AFTCONTR DS    0H                                                       70200017
ALLBLANK CLI   CONTINUE,BLANK           SEE IF CONTINUATION ALSO BLANK  70300017
         BE    DONE                     YES, DONE                       70400017
*                                                                       70500017
MOREJED  BAL   LINK,GETCD               GET ANOTHER CARD                70600017
         LA    R6,OPERAND               RESET R6                        70700017
         B     KEYWORD                  PROCESS NEXT KEYWORD            70800017
*                                                                       70900017
COMMENTS CLI   1(R6),BLANK              VERIFY THAT , FOL BY BLANK      71000017
         BNE   INVKEY                   NO = ERROR                      71100017
*                                                                       71200017
COMMENT  CLI   CONTINUE,BLANK           SEE IF CONTINUATION             71300017
         BE    DONE                     NO, DONE                        71400017
*                                                                       71500017
         OI    SWITCH,CONTCOMM          SET FOR CONTINUED COMMENTS      71600017
         B     MOREJED                  GET ANOTHER CARD                71700017
*                                                                       71800017
CHECKCON CLI   CONTINUE,BLANK           SEE IF CONTINUATION             71900017
         BE    BADELIMA                 NO = ERROR                      72000017
         B     MOREJED                  YES = GET ANOTHER CARD          72100017
*                                                                       72200017
CONTCOM  CLI   CONTINUE,BLANK      CHECK FOR CONTINUATION PUNCH         72300017
         BNE   MOREJED             YES, GET ANOTHER CARD                72400017
*                                                                       72500017
         NI    SWITCH,CONTCOMF     TURN OFF CONTINUED COMMENTS          72600017
*                                                                       72700017
*********************************************************************** 72800017
*                                                                       72900017
*              SETUP TO RETURN TO READER                                73000017
*                                                                       73100017
*********************************************************************** 73200017
*                                                                       73300017
DONE     TM    SWITCH,ERRORS       TEST FOR ERRORS FOUND                73400017
         BO    ERREXIT             YES, GO OUT ERROR EXIT               73500017
*                                                                       73600017
*                                                                       73700017
         TM    MYFJIB,NOTALT       SEE IF NOTIFY FOR ALT REQUESTED      73800017
         BZ    UPDATE              NO, DO NOT CHECK ALT                 73900017
         CLC   MYFALT(3),ZERO      SEE IF ALT ID IS ZERO                74000017
         BNE   UPDATE              NO, UPDATE                           74100017
*                                                                       74200017
         NI    MYFJIB,NOTALTF      TURN ALT NOTIFY OFF                  74300017
*                                                                       74400017
UPDATE   DS    0H                                                       74500017
*                                                                       74600017
NORMEXIT XR    R15,R15             SET ZERO RETURN CODE                 74700017
*                                                                       74800017
EXIT     DS    0H                                                       74900017
*                                                                       75000017
         L     R13,SAVE+4          RELOAD SAVE AREA ADDRESS             75100017
*                                                                       75200017
         RETURN (14,12),T,RC=(15)                                       75300017
*                                                                       75400017
*                                                                       75500017
*                                                                       75600017
*********************************************************************** 75700017
*                                                                       75800017
*                             CONSTANTS                                 75900017
*                                                                       76000017
*********************************************************************** 76100017
*                                                                       76200017
*                   CHARACTER EQUATES                                   76300017
*                                                                       76400017
BLANK    EQU   C' '                BLANK                                76500017
COMMA    EQU   C','                                                     76600017
DOT      EQU   C'.'                DOT FOR SCAN                         76700017
LTPAREN  EQU   C'('                                                     76800017
RTPAREN  EQU   C')'                CLOSING PARENTHESIS                  76900017
QUOTE    EQU   C''''               QOUTE                                77000017
*                                                                       77100017
*                   EXECUTED INSTRUCTIONS                               77200017
*                                                                       77300017
STEPDD   MVC   0(0,R9),0(R1)       MOVE STEP.DDNAME TO IHKCELST         77400017
TEXT     MVC   JEDTNMSG(0),1(R6)        MOVE NOTIFY MSG TO JED TABLE    77500017
*                                                                       77600017
*              PARAMETER LIST FOR IHKCBLDM                              77700017
*                                                                       77800017
MSGLIST  DS    0F                       PARAMETER LIST FOR IHKCBLDM     77900017
TERMINAL DS    F                        TERMINAL TO RECEIVE MSG         78000017
OFF      DC    X'00'                                                    78100017
OFFSET   DC    X'00'                                                    78200017
LENGTH   DC    X'00'                    LENGTH OF VARIABLE MESSAGE      78300017
VTEXT    DC    CL4'JED '                ALL MESSAGES ARE ON JED         78400017
TYPE     DC    CL8' '                                                   78500017
         DC    C' '                                                     78600017
VSEQ     DC    CL8' '                   SEQUENCE ON LONG MSG            78700017
*                                                                       78800017
*                   OFFSETS FOR IHKCBLDM                                78900017
*                                                                       79000017
*              OFFSET=4  - INVALID KEYWORD ERROR                        79100017
O4       EQU   4                   OFFSET 4                             79200017
*              OFFSET=8  - ILLEGAL DELIMITER ERROR                      79300017
O8       EQU   8                        OFFSET 8                        79400017
*              OFFSET=12 - INVALID CONTINUATION ERROR                   79500017
O12      EQU   12                  OFFSET 12                            79600017
*              OFFSET=16 - UNDEFINED KEYWORD ERROR                      79700017
O16      EQU   16                  OFFSET 16                            79800017
*              OFFSET = 18 - MULTIPLE USE OF KEYWORD ERROR              79900017
O18      EQU   18                  OFFSET 18                            80000017
*              OFFSET=43 - ALTERNATE IGNORED WARNING                    80100017
O43      EQU   43                  OFFSET 43                            80200017
*                                                                       80300017
*                   LENGTHS FOR IHKCBLDM                                80400017
*                                                                       80500017
*              LENGTH=0  - FOR JOB CARD MISSING ERROR                   80600017
L0       EQU   0                   LENGTH SET AT ZERO                   80700017
*              LENGTH=12 - FOR ALL GENERAL MESSAGES                     80800017
L12      EQU   12                  LENGTH 12                            80900017
*              LENGTH=21 - FOR KEYWORD ERROR MESSAGES                   81000017
L21      EQU   21                  LENGTH 21                            81100017
*                                                                       81200017
*                   PARAMETER LIST FOR IHKCAMSN                         81300017
*                                                                       81400017
MSNLIST  DS    F                        PARAMETER LIST FOR IHKCAMSN     81500017
MSNSTOP  DS    F                        STOPPING ADDRESS                81600017
         DC    F'25'                    PERMISSIBLE LENGTH OF TEXT      81700017
*                                                                       81800017
*                   PARAMETER LIST FOR IHKCCSCN                         81900017
*                                                                       82000017
SCAN     DS    0F                       PARAMETER LIST FOR IHKCCSCN     82100017
MAXLEN   DC    X'0000'                                                  82200017
NOCHAR   DC    H'0'                     NUMBER OF SCAN CHARACTERS       82300017
START    DS    F                        STARTING ADDRESS FOR SCAN       82400017
STOP     DS    F                        STOPPING ADDRESS FOR SCAN       82500017
CHARS    DS    CL4                      CHARACTERS FOR WHICH TO SCAN    82600017
*                                                                       82700017
*                   BLANKS NEEDED FOR COMPARE ON CONTINUATION           82800017
*                                                                       82900017
BLANKS   DC    CL13' '                                                  83000017
         ORG   *-1                                                      83100017
*                                                                       83200017
*                                                                       83300017
*                   NUMBER OF CHARACTERS FOR WHICH TO SCAN              83400017
*                                                                       83500017
X0       EQU   X'00'                                                    83600017
X1       EQU   X'01'               ONE CHARACTER SCAN                   83700017
X2       EQU   X'02'               TWO CHARACTER SCAN                   83800017
X3       EQU   X'03'               THREE CHARACTERS TO SCAN             83900017
*                                                                       84000017
*                   CHARACTERS FOR WHICH TO SCAN                        84100017
*                                                                       84200017
CHARSET2 DC    C' ),'              SCAN CHARACTER SET 2                 84300017
         ORG   *-1                                                      84400017
CHARSET1 DC    C', ='              SCAN CHARACTER SET 1                 84500017
CHARSET3 DC    C') '               SCAN CHARACTER SET 3                 84600017
         ORG   *-1                                                      84700017
CHARSET4 DC    C' ,'               SCAN CHARACTER SET 4                 84800017
*                                                                       84900017
*                                                                       85000017
*                   CONSTANTS TO IDENTIFY KEYWORDS AND SUB-PARAMETERS   85100017
*                                                                       85200017
CENTRAL  DC    C'CENTRAL='                                              85300017
NOTIFY   DC    C'NOTIFY='                                               85400017
OUTPUT   DC    C'OUTPUT='                                               85500017
ALL      DC    C'ALL'                                                   85600017
IMMED    DC    C'IMMED'                                                 85700017
         ORG   *-1                                                      85800017
DEFER    DC    C'DEFER'                                                 85900017
SOURCE   DC    C'SOURCE'                                                86000017
BOTH     DC    C'BOTH'                                                  86100017
*                                                                       86200017
*                   SAVE AREA                                           86300017
*                                                                       86400017
SAVE     DC    18F'0'                                                   86500017
*                                                                       86600017
*                   NUMBER CONSTANTS                                    86700017
*                                                                       86800017
H12      DC    H'12'               HALF WORD OF TWELVE                  86900017
ZERO     DC    H'0'                                                     87000017
FOUR     DC    F'4'                                                     87100017
MAXNAME  DC    F'8'                MAXIMUM LENGTH OF STEP OR DD NAME    87200017
ENTLEN   DC    F'18'               LENGTH OF ENTRY IN IHKCELST          87300017
BEGIN    DC    F'0'                                                     87400017
SAVELINK DC    F'0'                     SAVE ADDRESS TO WHICH TO RETURN 87500017
         DC    F'0'                                                     87600017
USER     DC    F'0'                     USERID ON FULL WORD             87700017
COL72    DC    F'0'                     ADDRESS OF COL 72               87800017
SEQUENCE DC    CL8' '                                                   87900017
*                                                                       88000017
*                   BYTE OF SWITCHES                                    88100017
*        BIT 0 - CONTINUED COMMENTS                                     88200017
*        BIT 1 - ERRORS FOUND IN JED                                    88300017
*        BIT 3 - DO NOT CONTINUE PROCESSING AFTER ERROR                 88400017
*        BIT 5 - PARENTHESIS ENCOUNTERED (RIGHT) IN CENTRAL OPERAND     88500017
*        BIT 6 - ALTERNATE IGNORED WARNING ONLY SWITCH                  88600017
*        BIT 7 - COMPLEX OR SIMPLE TYPE KEYWORD INDICATOR               88700017
*                                                                       88800017
SWITCH   DC    X'00'                    BYTE OF SWITCHES                88900017
*                                                                       89000017
*                   EQUATES FOR SWITCHES                                89100017
*                                                                       89200017
COMPLX   EQU   X'01'               SAET COMPLEX SWITCH                  89300017
SIMPLE   EQU   X'FE'               TURN OFF COMPLEX SWITCH              89400017
ALTERRN  EQU   X'02'               TURN ON ALT IGNORED WARNING ONLY     89500017
ALTERRF  EQU   X'FD'               TURN OFF ALT IGNORED WARNING ONLY    89600017
PAREN    EQU   X'04'               SETS FOR PAREN (END OF CENTRAL OP)   89700017
CONTPRF  EQU   X'10'                    DO NOT CONTINUE PROCESS         89800017
CONTPRN  EQU   X'EF'                    CONTINUE PROCESSING             89900017
ERRORS   EQU   X'40'               SETS ERRORS FOUND BIT                90000017
CONTCOMM EQU   X'80'               CONTINUED COMMENTS ON                90100017
CONTCOMF EQU   X'7F'               TURNS OFF CONTINUED COMMENTS BIT     90200017
*                                                                       90300017
*                   BYTE OF SWITCHES EXTENDED                           90400017
*        BIT 0 - INVALID KEYWORD ENDS IN 71                             90500017
*        BIT 1 - INVALID KEYWORD PROBABLY MISSPELLED                    90600017
*        BIT 2 - DO NOT SCAN FOR ) AFTER ERROR                          90700017
*                                                                       90800017
SWITCHA  DC    X'00'               SWITCHES EXTENDED                    90900017
*                                                                       91000017
*                   EQUATES FOR EXTENDED SWITCHES                       91100017
*                                                                       91200017
NOPRN    EQU   X'20'               DO NOT SCAN FOR PARENTHSIS           91300017
NOPRNF   EQU   X'DF'               TURN OFF NO PAREN SCAN               91400017
MISPL    EQU   X'40'               SET FOR KEYWORD MISSPELLED           91500017
END71    EQU   X'80'               SET INVALID KEYWORD ENDS IN 71       91600017
ENDMISF  EQU   X'3F'               TURN OFF ERROR SWITCHES (KEYWORD)    91700017
*                                                                       91800017
*                   SWITCHES FOR DUPLICATE KEYWORDS                     91900017
*                                                                       92000017
CENSW    DC    X'00'               SET ON FIRST CENTRAL ENCOUNTERED     92100017
NOTSW    DC    X'00'               SET ON FIRST NOTIFY ENCOUNTERED      92200017
OUTSW    DC    X'00'               SET ON FIRST OUTPUT ENCOUNTERED      92300017
*                                                                       92400017
*                   BYTE INDICATING OPERAND NOW BEING PROCESSED         92500017
*                                                                       92600017
NOW      DC    X'00'                    INDICATES PRESENT KEYWORD       92700017
*                                                                       92800017
*                   POSSIBLE CONTENTS OF NOW                            92900017
*                                                                       93000017
NOWOUT   EQU   X'20'               OUTPUT NOW BEING PROCESSED           93100017
NOWNOT   EQU   X'40'               NOTIFY NOW BEING PROCESSED           93200017
NOWCEN   EQU   X'80'               CENTRAL NOW BEING PROCESSED          93300017
*                                                                       93400017
*                                                                       93500017
*                   DSECT FOR IHKCEJDT AND IHKCELST                     93600017
*                                                                       93700017
IHKCEJDT DSECT                                                          93800017
JEDTNMSG DS    CL25                     NOTIFY MESSAGE                  93900017
JEDTAB2  DS    CL73                                                     94000017
IHKCELST DS    CL180                                                    94100017
*                                                                       94200017
*                   DUMMY FAST TABLE                                    94300017
*                                                                       94400017
MYFJIB   DS   XL1                                                       94500017
MYFALT   DS    XL3                                                      94600017
*                                                                       94700017
*                   FASTJIB EQUATES                                     94800017
*                                                                       94900017
CENOP    EQU   X'01'               CENTRAL OPERAND ENCOUNTERED          95000017
TEXTBIT  EQU   X'08'               SETS TEXT BIT IN JIB                 95100017
NOTALT   EQU   X'20'               SETS NOTIFY ALTERNATE BIT IN FASTJIB 95200017
NOTALTF  EQU   X'DF'               TURNS NOTIFY ALT OFF                 95300017
NOTSRC   EQU   X'40'               SET NOTIFY SOURCE BIT IN FASTJIB     95400017
DEFAULT  EQU   X'80'               DEFAULT FOR FASTJIB                  95500017
IMMEDON  EQU   X'80'               IMMEDIATE OUTPUT IN JIB              95600017
DEFERRED EQU   X'7F'               SET DEFERRED OUTPUT BIT IN JIB       95700017
*                                                                       95800017
*                   DSECT FOR CARD IMAGE                                95900017
*                                                                       96000017
CARD     DSECT                          DSECT FOR CARD IMAGE            96100017
IDEN     DS    CL2                      IDENTIFIER                      96200017
NOTUSED  DS    CL13                     SHOULD BE BLANK                 96300017
OPERAND  DS    CL56                     OPERAND FIELD                   96400017
CONTINUE DS    CL1                      CONTINUATION COLUMN             96500017
SEQNCE   DS    CL8                                                      96600017
         IHKDSECT ,,,,,AVT                                              96700017
JED      EQU   VTEXT                                                    96800017
         END                                                            96900017
