LRDF     TITLE 'IHKCHLRD - MFT-II LINE ANALYSIS READ'              000C 00060018
IHKCHLRD CSECT                                                          00120018
IHKABLRD DS    0H                                                       00180018
         ENTRY IHKABLRD                                                 00240018
* 019800-027000,112800,231810-231880,473400,598800                19018 00247019
* 649200,660600-661200,744000-765000,773400-774000,775800,        19018 00254019
* 784000-821400,870000                                            19018 00261019
* 742200-743400                                                  A24717 00268019
* 638400-639000                                                  A27468 00275019
* 153000,510000,630600,860400,864600                               000D 00282019
* 326400                                                         A28204 00285019
* 440400-441000,968400                                             000D 00335019
* 467400                                                          M3158 00835019
*197350-197850,397200,467190,467310-573000,861000-864000,888000  A26537 00845020
*                                                                A32862 00855020
*                                                                A32875 00865020
*A642500-642800,796100                                           A35897 00870020
*D520900                                                         A40161 00875020
*A520500-521100,527100,779500-779700                             A40161 00880020
*C343800,701900                                                  A40166 00881020
*A726400                                                          M6294 00882020
*D796100                                                          M6294 00883020
*A112450-112650                                                  A37771 00884021
*A667300-668500                                                  A47439 00894021
*D667400-668400                                                  A47439 00904021
*C639400,657400                                                  A47967 00914021
*A199950-200050,374200-374600,606000-606300,729500-729600        A48402 00924021
*D374400                                                         A48402 00934021
*A237450                                                         A51866 00944021
*                                                                     * 00954021
* STATUS - CHANGE LEVEL 1, RELEASE 21.6                               * 00964021
*                                                                     * 00974021
*FUNCTION/OPERATION - THE BASIC FUNCTIONS OF THIS ROUTINE ARE         * 00985019
*   1. READ THE INPUT DATA USING BTAM                                 * 01035019
*   2. RECOGNIZE THE DATA LINK CONTROL CHARACTERS ON THE INPUT RECORD * 01085019
*   3. SEQUENCE CHECK THE JECL COMMANDS - RJSTART, CONTINUE, LOGON,   * 01135019
*      LOGOFF AND RJEND                                               * 01185019
*   4. CHECK FOR THE INVALID JECL COMMANDS - RJENDF AND RJENDC        * 01235019
*   5. WRITE THE JECL AND JCL RECORDS ON SYS1.SYSJOBQE USING THE OS   * 01285019
*      QUEUE MANAGER                                                  * 01335019
*   6. START A NEW QUEUE ENTRY FOR JECL AND JCL WHEN A JED CARD OR A  * 01385019
*      JOB CARD NOT PRECEDED BY A JED IS FOUND                        * 01435019
*   7. WRITE SYSIN DATA ON A SEQUENTIAL DISK DATA SET WHICH WAS JUST  * 01485019
*      ALLOCATED                                                      * 01535019
*   8. SUPPORT SYSTEM MANAGEMENT FACILITIES (SMF) BY COUNTING     19018 01585019
*      RECORDS SPOOLED TO SYSIN DATA SETS. THE COUNT IS PLACED    19018 01635019
*      IN A SPACE PARAMETER ON THE THIRD GENERATED SYSIN CARD.    19018 01685019
*                                                                     * 01735019
*ENTRY POINTS -                                                       * 01785019
*        IHKABLRD - TO PROCESS THE BTAM INPUT.                        * 01835019
*   CALLING SEQUENCE - LA    1,PARAM                                  * 01885019
*                      LA    13,SAVE AREA FOR THIS LINE               * 01935019
*                      L     15,=V(IHKABLRD)                          * 01985019
*                      BR    15                                       * 02035019
*   WHERE PARAM IS A WORD CONTAINING THE LCB ADDRESS                  * 02085019
*                                                                     * 02135019
*        IHKABCON - TO ENABLE IHKABALC TO GET THE BASE FOR A DSECT OF * 02185019
*   THIS CONSTANT AREA.                                               * 02235019
*                                                                     * 02285019
*        IHKABXCN - TO ENABLE IHKABXMT TO GET THE BASE FOR A DSECT      02335019
*   OF THE CONSTANT AREA.                                               02385019
*                                                                       02435019
*        IHKABRET - TO WRITE A RECORD (JCL) AND RETURN TO LST     19018 02485019
*                                                                 19018 02535019
*INPUT - BTAM PUTS 80-CHARACTER CARD IMAGES AND THE DATA LINK CONTROL * 02585019
*   CHARACTERS IN THE INPUT BUFFER ON EACH READ.  THE READ INITIAL IS * 02635019
*   DONE BY THE LINE SCHEDULER PRIOR TO CALLING THIS ROUTINE WHICH    * 02685019
*   ISSUES THE READ CONTINUE'S.                                       * 02735019
*                                                                     * 02785019
*OUTPUT - THE JECL AND JCL IS ON SYS1.SYSJOBQE, TWO 80-CHARACTER CARD * 02835019
*   IMAGES PER EACH 176-BYTE RECORD.  THE SYSIN DATA SET(S) ARE ON    * 02885019
*   DISK, BLOCKED ACCORDING TO THE BLOCK SIZE SPECIFIED ON THE DD CARD* 02935019
*   IN THE RJE PROCEDURE.  THE MAXIMUM BLOCK SIZE IS 400 BYTES.  IF NO* 02985019
*   BLOCK SIZE WAS SPECIFIED, UNBLOCKED (80-BYTE) RECORDS ARE WRITTEN * 03035019
*                                                                     * 03085019
*EXTERNAL ROUTINES -                                                  * 03135019
*        IHKAADSP - DISPATCHER          TO ALLOW PROCESSING OF OTHER  * 03185019
*                                       LINES WHILE WAITING FOR I/O TO* 03235019
*                                       COMPLETE.                     * 03285019
*        IHKABALC - SYSIN ALLOCATION    TO ALLOCATE A SYSIN DATA SET. * 03335019
*        IHKABXMT - ERR MSG TRANSMITTER TO TRANSMIT AN ERROR            03385019
*                                       MESSAGE TO THE LINE             03435019
*        IHKCAVER - COMMAND INTERPRETER TO CHECK THE SYNTAX OF AN     * 03485019
*                                       RJSTART OR LOGON CARD.        * 03535019
*        IHKCBLDM - BUILD MESSAGE       TO GET A POINTER TO AN ERROR  * 03585019
*                                       MESSAGE.                      * 03635019
*        IHKCCSCN - SCAN                TO FIND THE START OF FIELDS ON* 03685019
*                                       JECL AND JCL CARDS.           * 03735019
*        IHKCDFMR - FAST TABLE MANAGER  TO WRITE UPDATED FAST TABLE   * 03785019
*                                       ENTRY ON DISK.                * 03835019
*        IHKCDSCH - FAST TABLE SEARCH   TO SEARCH FAST TABLE FOR      * 03885019
*                                       AVAILABLE ENTRY OR DUPLICATE  * 03935019
*                                       JOB NAME                      * 03985019
*        IHKCHUPK - UNPACK ROUTINE      TO EXPAND RECORDS FROM     000D 04035019
*                                       A COMPRESSING TERMINAL     000D 04085019
*        BSAM                           TO WRITE THE SYSIN DATA SETS  * 04135019
*                                       ON DISK.                      * 04185019
*        BTAM                           TO READ INPUT FROM THE LINE   * 04235019
*   THE FOLLOWING QUEUE MANAGER ROUTINES -                            * 04285019
*        IEFQMSSS - ASSIGN/START        TO INITIALIZE A JECL AND JCL  * 04335019
*                                       QUEUE ENTRY AND ASSIGN INITIAL* 04385019
*                                       TTR'S FOR WRITING.            * 04435019
*                 - WRITE AND ASSIGN    TO WRITE JECL AND JCL RECORDS * 04485019
*                                       ON SYS1.SYSJOBQE AND ASSIGN   * 04535019
*                                       NEXT TTR                      * 04585019
*                 - WRITE AND ENQUEUE   TO WRITE THE LAST JECL AND JCL* 04635019
*                                       RECORD AND ENQUEUE THE QUEUE  * 04685019
*                                       ENTRY FOR THE READER.         * 04735019
*        IEFQDELE - DELETE              TO DELETE THE LOGICAL TRACK   * 04785019
*                                       ASSIGNED FOR JECL AND JCL IF  * 04835019
*                                       THERE IS NO VALID INPUT.      * 04885019
*                                                                     * 04935019
*EXITS - NORMAL - RETURN IS MADE TO THE LINE SCHEDULER WITH A           04985019
*   RETURN CODE IN REGISTER 15 AS FOLLOWS                               05035019
*    0 - RETURN FOR NON-SWITCHED LINE OR AFTER RJENDC OR RJENDF         05085019
*    8 - ERROR MESSAGE WAS SENT ON SWITCHED LINE SO LINE SCHEDULER      05135019
*        MUST SEND EOT                                                  05185019
*   12 - LINE SCHEDULER SHOULD CALL IHKABLWR BECAUSE AN OUT-OF-         05235019
*        SPACE CONDITION OCCURRED                                       05285019
*   20 - RJENDC OR RJENDF NOT QUEUED BECAUSE SYS1.SYSJOBQE IS           05335019
*        TEMPORARILY OUT OF SPACE                                       05385019
*   24 - NORMAL RETURN FOR SWITCHED LINE                                05435019
*   28 - RETURN TO SEND EOT TO 2780 ON SWITCHED LINE BECAUSE            05485019
*        RJSTART OR LOGON IS REQUIRED.                                  05535019
*                                                                     * 05585019
*EXITS - ERROR - THE LINE ERROR RECOVERY PROCEDURES ARE THOSE SUPPLIED* 05635019
*   BY OS/BTAM/BSCS.  IF AN ERROR OCCURS ON THE LINE, IT IS RETRIED BY* 05685019
*   BTAM SIX TIMES.  IF THE ERROR IS NOT RECOVERABLE, BTAM POSTS A BAD* 05735019
*   RETURN CODE (41).  IF LINE ANALYSIS READ FINDS A BAD RETURN CODE, * 05785019
*   IT EXECUTES THE FOLLOWING PROCEDURE.  THE USER EXIT ROUTINE (OR A * 05835019
*   DUMMY ROUTINE) IS CALLED WITH A POINTER TO THE LINE DECB IN       * 05885019
*   REGISTER 1.  THEN IN THE TERMINAL DIRECTORY ENTRY, THE ENQUEUE    * 05935019
*   JOBS AND ENQUEUE MESSAGES BITS ARE TURNED OFF, THE DEQUEUE          05985019
*   NOTHING BIT IS TURNED ON, THE RJSTART AND LOGON SWITCHES ARE        06035019
*   TURNED OFF.  AN RJENDF CARD WITH THE LINE ERROR MESSAGE ON IT       06085019
*   IS GENERATED AND PUT ON THE JECL AND JCL QUEUE ENTRY.  THE          06135019
*   QUEUE ENTRY IS ENQUEUED FOR THE READER, AND RETURN IS MADE TO       06185019
*   THE LINE SCHEDULER.                                                 06235019
*                                                                     * 06285019
*   IHKABXMT IS CALLED IF ANY OF THE FOLLOWING ERRORS OCCURS            06335019
*   1. RJSTART OR LOGON IS MISSING OR INVALID,                        * 06385019
*   2. RJENDF OR RJENDC IS SUBMITTED FROM THE TERMINAL,               * 06435019
*   3. A JOB CARD IS MISSING OR THE JOB NAME IS MISSING, TOO LONG, OR * 06485019
*      DUPLICATE,                                                     * 06535019
*   4. THE FAST TABLE IS FULL,                                        * 06585019
*   5. THE CENTRAL IS OUT OF SPACE FOR SYSIN OR ON SYS1.SYSJOBQE,       06635019
*   6. THE SYSIN DATA SET IS TOO LONG, OR                               06685019
*   7. A DISK I/O ERROR OCCURS.                                         06735019
*                                                                     * 06785019
*   AN ERROR MESSAGE IS SENT TO THE TERMINAL, AND FOR CASES 4, 5        06835019
*   AND 7 A MESSAGE IS ALSO SENT TO THE CENTRAL OPERATOR.  IF THE       06885019
*   WRITE TO THE TERMINAL IS UNSUCCESSFUL, AN RJENDF CARD WITH THE      06935019
*   ERROR MESSAGE IS GENERATED, IF POSSIBLE, AND PUT ON THE JECL        06985019
*   AND JCL QUEUE ENTRY.  THE QUEUE ENTRY IS ENQUEUED FOR THE           07035019
*   READER, AND RETURN IS MADE TO THE LINE SCHEDULER.                   07085019
*                                                                     * 07135019
*   ABNORMAL CENTRAL CLOSEDOWN IS INITIATED WHEN AN UNRECOVERABLE       07185019
*   ERROR IS ENCOUNTERED.                                               07235019
*                                                                       07285019
*TABLES/WORK AREAS - EACH LINE HAS A LINE CONTROL BLOCK (LCB),        * 07335019
*   SUB-TASK CONTROL BLOCK (STCB), 452-BYTE DISK BUFFER, 18-WORD      * 07385019
*   REGISTER SAVE AREA, A DECB AND DCB FOR LINE I/O, AND A DECB AND   * 07435019
*   DCB FOR DISK I/O ASSOCIATED WITH IT.  WHILE THE LINE IS SENDING   * 07485019
*   INPUT, A BTAM BUFFER IS ALSO USED.  THE FAST TABLE, THE TERMINAL  * 07535019
*   DIRECTORY AND THE AVT TABLE OF ADDRESSES ARE REFERENCED.          * 07585019
*                                                                     * 07635019
*ATTRIBUTES - IT IS REENTRANT.                                        * 07685019
*                                                                     * 07735019
*NOTES - THE OPERATION OF THIS SUBROUTINE DEPENDS UPON AN INTERNAL    * 07785019
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 07835019
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED SO* 07885019
*   THAT REDEFINITION OF CHARACTER-TYPE CONSTANTS, BY REASSEMBLY, WILL* 07935019
*   RESULT IN A CORRECT MODULE FOR THE NEW DEFINITION EXCEPT FOR THE  * 07985019
*   CODE WHICH VERIFIES THAT THE JOB NAME STARTS WITH AN ALPHABETIC   * 08035019
*   CHARACTER.  THE CODE ASSUMES THAT ALL SPECIAL CHARACTERS HAVE A   * 08085019
*   LOWER HEX CODE THAN THE LETTERS, THAT THE NUMBERS HAVE A HIGHER   * 08135019
*   HEX CODE, THAT THE HEX CODE FOR A IS THE LOWEST ALPHABETIC, THAT  * 08185019
*   THE HEX CODE FOR Z IS THE HIGHEST ALPHABETIC, AND THAT THE NUMERIC* 08235019
*   FIELDS OF THE LETTERS RUN FROM 1 THROUGH 9 EXCEPT FOR E1.  THE    * 08285019
*   LAST 5 EQUATES ARE USED FOR THIS CODE.                            * 08335019
*   THE CODE WHICH INSERTS THE SYSIN COUNT INTO THE SPACE PARA-   19018 08385019
*   METER OF THE THIRD GENERATED SYSIN CARD ASSUMES THAT THE      19018 08435019
*   HEXADECIMAL REPRESENTATION OF THE NUMBERS IS 'F0' THROUGH     19018 08485019
*   'F9'. THE EQUATE FOR THE ZONE IS LABELLED 'LRDZONE'.          19018 08535019
*     NOTE                                                       A26537 08540020
*    THE SUB ROUTINE STARTING  STARTING FROM SEQUENCE NUMBER     A26537 08545020
*  467310-537000 HAS BEEN REARRANGED SUCH THAT IT IS A SUB-      A26537 08550020
*  ROUTINE WITH ITS OWN BASE REG . THIS WAS DONE TO MAKE ROOM    A26537 08555020
*  IN THIS MODULE FOR FUTURE FIXES AND MODIFICATIONS .           A26537 08560020
*  ALSO CHARACTER CONSTANTS AND OTHER DEPENDENT CODE WAS EITHER  A26537 08565020
*  DELETED  FROM THE MAIN ROUTINE AND MOVED OR DUPLICATED        A26537 08570020
*  IN THE SUB ROUTINE                                            A26537 08575020
         SPACE 2                                                        08585019
R0       EQU   0                                                        08635019
R1       EQU   1                   QUEUE MANAGER PARAM. AREA POINTER    08685019
R2       EQU   2                   LCB POINTER                          08735019
R3       EQU   3                   BUFFER POINTER                       08785019
R4       EQU   4                   0 OR 80 FOR JECL-JCL BUFFER POINTER  08835019
*                                  END OF BUFFER FOR DISK BUFFER PTR    08885019
R5       EQU   5                   BTAM BUFFER POINTER                  08935019
R6       EQU   6                   END OF BTAM BUFFER POINTER           08985019
R7       EQU   7                   DECB POINTER (LINE OR DISK)          09035019
R8       EQU   8                   DCB POINTER FOR DISK                 09085019
R9       EQU   9                   VARIABLE                             09135019
R10      EQU   10                  VARIABLE                             09185019
R11      EQU   11                  TERMINAL DIRECTORY POINTER           09235019
R12      EQU   12                  BASE REGISTER                        09285019
R13      EQU   13                  SAVE AREA POINTER                    09335019
R14      EQU   14                  RETURN REGISTER                      09385019
R15      EQU   15                  ENTRY POINT REGISTER                 09435019
         SPACE                                                          09485019
         EXTRN IHKCDFLN,IHKCDSOC,IHKCDTDR,IHKCACOM                      09535019
         ENTRY IHKABCON            FOR DSECT IN IHKABALC                09585019
         ENTRY IHKABRET                                           19018 09635019
         ENTRY IHKABXCN            FOR DSECT IN IHKABXMT                09685019
         SPACE                                                          09735019
         BALR  R12,0               INITIALIZE BASE REGISTER             09785019
         USING *,R12                                                    09835019
         USING IOPARAMS,R1                                              09885019
         USING LCBDSECT,R2                                              09935019
         USING IECTDECB,R7                                              09985019
         USING IHADCB,R8                                                10035019
         USING TDIREC,R11                                               10085019
         USING LRDCVT,R14                                               10135019
         USING LRDQMRES,R15                                             10185019
         B     LRDSKIP                                                  10235019
         DC    C'IHKCHLRD'         MODULE IDENTIFIER               000C 10285019
LRDSKIP  DS    0H                                                       10335019
*                                                                       10385019
*********************************************************************** 10435019
*                                                                       10485019
*                   INITIALIZE REGISTERS AND ASSIGN QUEUE ENTRY         10535019
*                                                                       10585019
*********************************************************************** 10635019
*                                                                       10685019
          L     R2,0(R1)           GET LCB ADDRESS                      10735019
         NI    LCBNSWFL,LCBSWOFF   TURN OFF LCB SWITCHES                10785019
         L     R7,LCBDDECB         GET DISK DECB POINTER FROM LCB       10835019
         L     R8,DECDCBAD         GET ADDRESS FOR DCB                  10885019
         MVC   0(88,R8),LRDSYSDD   MOVE MODEL DCB FOR SYSIN DATA SETS   10935019
         L     R7,LCBLDECB         GET LINE DECB POINTER FROM LCB       10985019
         BAL   R10,LRDBUFPT        GET POINTERS TO START AND END        11035019
*                                  OF BTAM BUFFER                       11085019
         ST    R5,LCBWORKA         SAVE ADDRESS OF BTAM INPUT BUFFER    11135019
         L     R11,LCBTDIR         GET TERMINAL DIRECTORY PTR           11185019
         LA    R10,LRDCHECK        SET RETURN ADDRESS                   11235019
         L     R4,LCBBUFER    CLEAR THE QMPCL SO THAT IF THE JOB A37771 11245021
         XC    LRDXMT32(LRDXMT4,R4),LRDXMT32(R4) Q IS FULL AND   A37771 11255021
*                             THE MSG CAN'T BE SENT - NO ABEND   A37771 11265021
         SR    R4,R4               SET BUFFER INDEX TO 0         A27468 11285019
         SPACE 1                                                        11335019
         CLI   LCBTYPLN,LCBMULPT   CHECK FOR MULTI-POINT LINE           11385019
         BNE   LRDASGST            BRANCH IF NOT MULTI-POINT LINE       11435019
         LA    R5,1(R5)            STEP PAST POLLING CHARACTER          11485019
LRDASGST L     R14,CVTPTR          GET ADDRESS OF CVT                   11535019
         L     R15,CVTJOB          GET ADDRESS OF Q MGR RESIDENT AREA   11585019
         LH    R9,QMNOTM           GET NUMBER OF AVAIL. LOGICAL TRACKS  11635019
         SH    R9,QMTBT            SUBTRACT NUMBER OF LOGICAL TRACKS    11685019
*                                  RESERVED FOR INITIATORS              11735019
         MH    R9,QMLPT            MULTIPLY BY NUMBER OF RECORDS/TRACK  11785019
*                                  R9 NOW HAS NUMBER OF AVAIL. RECORDS  11835019
         CH    R9,LRD200           CHECK THRESHOLD OF 200 RECORDS       11885019
         BNH   LRDQMSPA            BRANCH IF NOT MORE THAN 200 RECORDS  11935019
LRDASGS2 L     R1,LCBBUFER         GET QUEUE MANAGER PARAM. AREA ADDR.  11985019
         MVC   QMNAM(8),LRDTASK    PUT RJETASK AS JOBNAME               12035019
         XC    QMFLT(23),QMFLT     CLEAR NEXT SIX WORDS OF QMPA         12085019
         LA    R9,QMPCA            GET ADDRESS OF EXTERNAL AREA         12135019
         ST    R9,QMPCL            STORE IN LAST WORD OF QMPA           12185019
         MVI   QMPOP,QMASGS        STORE ASSIGN/START CODE              12235019
         MVI   QMTPY,LRDSYSIN      SET FOR SYSIN QUEUE                  12285019
         MVI   QMPCM,LRD2TTRS      TO ASSIGN TWO TTR'S                  12335019
         USING IHKZZAVT,R14        CHANGE REG TO DSECT RJE AVT          12385019
         L     R14,LRDZZAVT        GET BASE FOR RJE COMM AREA           12435019
         L     R15,IHKZZSSS        GET IEFQMSSS ENTRY POINT ADDRESS     12485019
         BALR  R14,R15             LET IT DO ITS BIT                    12535019
         USING LRDCVT,R14          RESTORE REG TO DSECT CVT             12585019
         LTR   R15,R15             TEST RETURN CODE                     12635019
         BC    7,LRDQMIOA          BRANCH IF I/O ERROR                  12685019
         L     R1,LCBBUFER         GET QUEUE MANAGER PARAM. AREA ADDR.  12735019
         L     R9,QMPEX            GET TTR FOR SECOND WRITE             12785019
         ST    R9,QMCHN            STORE AS CHAINING FROM FIRST RECORD  12835019
         L     R9,QMPCA            GET TTR FOR FIRST WRITE              12885019
         ST    R9,QMPEX            STORE AS TTR FOR FIRST WRITE         12935019
         LA    R3,QMCHN            GET JECL AND JCL BUFFER ADDRESS      12985019
         SR    R4,R4               SET BUFFER INDEX TO 0           000D 13035019
         MVI   LRDCDIND(R3),LRDNOCRD INDICATE NO CARDS IN BUFFER        13085019
         NI    LCBNSWFL,LCBNQOFF   INDICATE NO CARDS TO ENQUEUE         13135019
         BR    10                                                       13185019
         SPACE 1                                                        13235019
LRDCHECK BAL   R9,LRDCKEOT         CHECK DATA LINK CONTROL CHARACTERS   13285019
         LTR   R11,R11             TEST FOR TERMINAL DIRECTORY POINTER  13335019
         BZ    LRDRJNEC            BRANCH IF RJSTART REQUIRED           13385019
         TM    TDIRSWCH,TDIRRJSN   ALLOW FOR MULTIPOINT            000C 13435019
         BZ    LRDRJNEC            IF NOT RJSTARTED, NEEDS TO BE   000C 13485019
LRDCKTYP DS    0H                                                  000C 13535019
         BAL   R14,LRDUNPK         UNPACK RECORD INTO OUTPUT BUFFER000C 13585019
         CLC   0(3,R3),LRDDOTS     CHECK FOR JECL                  000C 13635019
         BNE   LRDJCLCK            BRANCH IF NOT A JECL CARD            13685019
*                                                                       13735019
*********************************************************************** 13785019
*                                                                       13835019
*                   CHECK FOR CERTAIN JECL COMMANDS                     13885019
*                                                                       13935019
*********************************************************************** 13985019
*                                                                       14035019
         NI    TDIRSWCH+2,TDIRJCLF TURN OFF JCL SWITCH                  14085019
         TM    TDIRSWCH,TDIRDDAN   TEST DD* SWITCH - SYSIN DATA         14135019
         BC    14,LRDRJS           BRANCH IF DD * SWITCH NOT ON         14185019
         BAL   R10,LRDSYEND        BRANCH IF DD * SWITCH ON             14235019
         B     LRDCKTYP            GO PROCESS RECORD               000C 14285019
LRDRJS   LA    R9,LRDCONTI         SET RETURN ADDRESS                   14335019
         SPACE 1                                                        14385019
LRDRJSTR LA    R10,3(R3)           GET STARTING ADDRESS FOR SCAN   000C 14435019
         ST    R10,LRDSADDR        STORE IN PARAMETER LIST              14485019
         LA    R10,70(R3)          GET STOPPING ADDRESS FOR SCAN   000C 14535019
         ST    R10,LRDSSTOP        STORE IN PARAMETER LIST              14585019
        XC     LRDSCAN(4),LRDSCAN    SET UP PARMS                  000C 14635019
         LA    R1,LRDSCAN          GET ADDRESS OF PARAMETER LIST        14685019
         L     R15,LRDCCSCN        GET ADDRESS OF SCAN ROUTINE          14735019
         BALR  R14,R15             CALL SCAN TO FIND FIRST NON-BLANK    14785019
         LTR   R15,R15             TEST FOR NON-BLANK CHARACTER FOUND   14835019
         BZ    LRDNULL             BRANCH IF NO OPERATION ON CARD       14885019
         CLC   0(8,R1),LRDRJSTT    CHECK FOR RJSTART CARD          000C 14935019
         BE    LRDRJSRT            BRANCH IF FOUND                      14985019
         BR    R9                  BRANCH TO LRDCONTI OR LRDRJMIS       15035019
         SPACE 1                                                        15085019
LRDCONTI CLC   0(9,R1),LRDCONT     CHECK FOR CONTINUE CARD              15135019
         BE    LRDCONTU            BRANCH IF FOUND                      15185019
         CLC   0(6,R1),LRDLOGON    CHECK FOR LOGON CARD                 15235019
         BE    LRDLOGN             BRANCH IF FOUND                      15285019
         CLC   0(4,R1),LRDJED      CHECK FOR JED CARD                   15335019
         BE    LRDJEDCD            BRANCH IF FOUND                      15385019
         CLC   0(7,R1),LRDLOGOF    CHECK FOR LOGOFF CARD                15435019
         BE    LRDLOGF             BRANCH IF FOUND                      15485019
         CLC   0(6,R1),LRDRJEND    CHECK FOR RJEND CARD                 15535019
         BE    LRDRJND             BRANCH IF FOUND                      15585019
         CLC   0(7,R1),LRDRJNDF    CHECK FOR RJENDF CARD                15635019
         BE    LRDRJF              BRANCH IF FOUND - ERROR              15685019
         CLC   0(7,R1),LRDRJNDC    CHECK FOR RJENDC                     15735019
         BE    LRDRJF              BRANCH IF FOUND - ERROR              15785019
LRDSEQCK TM    TDIRSWCH,TDIRRJLG   TEST FOR RJSTART AND LOGON FOUND     15835019
         BO    LRDJCLBF            BRANCH IF BOTH FOUND ALREADY         15885019
         SPACE                                                          15935019
*                                                                       15985019
*********************************************************************** 16035019
*                                                                       16085019
*                   HANDLE ERRORS ON INPUT DATA                         16135019
*                                                                       16185019
*********************************************************************** 16235019
*                                                                       16285019
*                                  MISSING RJSTART OR LOGON             16335019
LRDRJMIS LA    R0,LRDXMT52         GET INPUT CODE FOR IHKABXMT          16385019
         B     LRDCLXMT            CALL IHKABXMT TO ABORT INPUT         16435019
         SPACE 2                                                        16485019
*                                  INVALID RJSTART OR LOGON - SEND      16535019
*                                  COMMAND INTERPRETER'S MESSAGE        16585019
LRDRJINV LA    R0,LRDXMT44         GET INPUT CODE FOR IHKABXMT          16635019
LRDRJLG  STM   R0,R1,LCBPARM1      STORE INPUT CODE AND                 16685019
*                                  POINTER TO MESSAGE                   16735019
         B     LRDXMTCL            CALL IHKABXMT TO SEND MESSAGE        16785019
         SPACE 2                                                        16835019
*                                  RJENDF OR RJENDC IS AN INAVLID       16885019
*                                  OPERATION                            16935019
LRDRJF   TM    TDIRSWCH+2,TDIRMCHN TEST FOR 2780 OR CPU                 16985019
         BZ    LRD2780             BRANCH IF 2780 TO GET NEXT CARD      17035019
         MVI   LRDBOFS+1,LRDOFS20  PUT MESSAGE OFFSET AS PARAMETER      17085019
         LA    R0,LRDXMT48         GET INPUT CODE FOR IHKABXMT          17135019
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        17185019
         SPACE 2                                                        17235019
LRDNULL  LTR   R11,R11             IS THERE A TERMINAL DIRECTORY PTR    17285019
         BZ    LRDRJMIS            BRANCH IF NO POINTER - ERROR         17335019
         B     LRDSEQCK                                                 17385019
         SPACE 2                                                        17435019
LRDRJNEC DS    0H                                                  000C 17485019
         LA    R3,4(R3)            STEP PAST INFO                  000C 17535019
         MVC   0(80,R3),0(R5)      MOVE CARD TO OUTPUT BUFFER      000C 17585019
         CLC   0(3,R3),LRDDOTS     CHECK FOR JECL                  000C 17635019
         BNE   LRDRJMIS            BRANCH IF NOT JECL - MISSING RJSTART 17685019
         BAL   R9,LRDRJSTR         TO TEST FOR RJSTART CARD             17735019
         B     LRDRJMIS            RJSTART MISSING - ERROR              17785019
         SPACE 2                                                        17835019
*                                                                       17885019
*********************************************************************** 17935019
*                                                                       17985019
*                   PROCESS JECL                                        18035019
*                                                                       18085019
*********************************************************************** 18135019
*                                                                       18185019
*                   RJSTART CARD                                        18235019
*                                                                       18285019
LRDRJSRT ST    R1,LRDCDOPR         STORE ADDRESS OF OPERATION AS PARAM  18335019
         MVI   LRDCDOPR,LRDRJSCD   STORE RJSTART CODE AS PARAMETER      18385019
         CLI   LCBTYPLN,LCBPTPT    CHECK FOR POINT-TO-POINT LINE        18435019
         BNE   LRDRJSR             BRANCH IF NOT POINT-TO-POINT         18485019
         SR    R11,R11             CLEAR TDIR POINTER SO IHKCAVER       18535019
*                                  WILL SEARCH TDIR FOR TERMID          18585019
LRDRJSR  EQU   *                                                        18635019
         LA    R10,LRDRJSTA                                             18685019
         SPACE 1                                                        18735019
LRDCALCI ST    R3,LRDCDBEG         STORE START OF CARD IMAGE       000C 18785019
         L     R9,LCBTDIR          SAVE TDIR POINTER               000C 18835019
         ST    R11,LRDCTDIR        STORE TERMINAL DIRECTORY POINTER     18885019
         LA    R1,LRDCDOPR         GET ADDRESS OF PARAMETER LIST        18935019
         O     R1,LRDBLDM          SET HIGH ORDER BIT TO INDICATE THAT  18985019
*                                  THE CALL IS FROM COLLECTOR-EMITTER   19035019
         L     R15,LRDCAINT        GET ADDRESS OF COMMAND INTERPRETER   19085019
         BALR  R14,R15             CHECK RJSTART SYNTAX AND TERMINAL ID 19135019
         LTR   R15,R15             TEST RETURN CODE                     19185019
         BR    R10                                                      19235019
         SPACE 1                                                        19285019
LRDRJSTA DS    0H                                                  000C 19335019
         L     R11,LRDCTDIR        GET TERMINAL DIRECTORY POINTER       19385019
         BZ    LRDRJSOK            RJSTART IS VALID                000C 19435019
         LTR   R11,R9              RESTORE TDIR POINTER            000C 19485019
         BZ    LRDRJINV            ERROR IF FIRST RJSTART BAD      000C 19535019
         TM    TDIRSWCH,TDIRRJSN   SEE IF ALREADY RJSTARTED        000C 19585019
         BZ    LRDRJINV            NO, SEND ERROR MESSAGE          000C 19635019
LRDRJSOK DS    0H                                                  000C 19685019
         CLC   LCBTDIR+1(3),LRDCTDIR+1  SAME TERMID AS ALREADY ON? 1657 19835019
         BE    LRDRJSGD            YES, LET HIM ON               A21657 19885019
         CLC   LCBTDIR+1(3),LRDBLDM+1   TERMINAL ON LINE YET     A21657 19935019
         BNE   LRDRJSBD            NO, SEND ERROR MESSAGE          1657 19985019
LRDRJTST TM    TDIRSWCH+1,TDIRDABN IS ANOTHR LINE RJENDFING      A48402 19995021
         BO    LRDRJWT        THIS TERMINAL - BRANCH IF SO       A48402 20005021
         L     R9,LRDLCBAD         GET FIRST LCB ADDR.           A21657 20035019
         LM    R14,R15,LRDLINES    GET LCB COUNT AND LENGTH ADDR A21657 20085019
         LH    R14,0(R14)          GET LCB COUNT                 A21657 20135019
         LA    R2,0(R2)            INSURE HIGH ORDER BYTE ZERO   A21657 20185019
LRDLLOOP DS    0H                                                A21657 20235019
         CLC   LRDCTDIR+1(3),13(R9) IS THIS TERMID ON LINE       A21657 20285019
         BE    LRDRJSBD            YES, CAN'T GET ON HERE        A21657 20335019
         AH    R9,0(R15)           STEP TO NEXT LCB              A21657 20385019
         BCT   R14,LRDLLOOP        TRY NEXT LCB                  A21657 20435019
LRDRJSGD DS    0H                                                  1657 20485019
         ST    R11,LCBTDIR         STORE IN LCB                         20535019
         OI    TDIRSWCH+2,TDIRSWCN  PRESET FOR SWITCHED            1657 20585019
         CLI   LCBTYPLN,LCBSWTCH   CHECK FOR SWITCHED LINE              20635019
         BE    LRDSETSW            BRANCH IF SWITCHED LINE              20685019
         NI    TDIRSWCH+2,TDIRSWCF SET FOR NON-SWITCHED LINE            20735019
LRDSETSW DS    0H                                                  1657 20785019
         OI    TDIRSWCH,TDIRRJSN   TURN ON RJSTART SWITCH               20835019
         ST    R2,TDIRLCB          STORE LCB ADDR IN TERMINAL DIRECTORY 20885019
         B     LRDJCLBF            BRANCH TO MOVE CARD TO JECL BUFFER   20935019
         SPACE 2                                                        20985019
LRDRJST2 C     R2,TDIRLCB          COMPARE CURRENT LCB WITH LCB IN      21035019
*                                  TERMINAL DIRECTORY ENTRY ALREADY     21085019
         BE    LRDRJSGD            BRANCH IF THE SAME              1657 21135019
*                                  TWO LINES ARE USING THE SAME TERMID  21185019
LRDRJSBD DS    0H                                                  1657 21235019
         LA    R0,LRDXMT40         GET INPUT CODE FOR IHKABXMT          21285019
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        21335019
         SPACE 2                                                        21385019
*                                                                       21435019
*                   CONTINUE CARD                                       21485019
*                                                                       21535019
LRDCONTU TM    TDIRSWCH,TDIRRJSN   TEST FOR RJSTART FOUND ALREADY       21585019
         BO    LRDJCLBF            BRANCH IF FOUND                      21635019
         B     LRDRJMIS            BRANCH ON ERROR                      21685019
         SPACE 2                                                        21735019
*                                                                       21785019
*                   LOGON CARD                                          21835019
*                                                                       21885019
LRDLOGN  TM    TDIRSWCH,TDIRRJSN   TEST FOR RJSTART FOUND ALREADY       21935019
         BZ    LRDRJMIS            BRANCH IF NO PRECEDING RJSTART-ERROR 21985019
         ST    R1,LRDCDOPR         STORE ADDRESS OF OPERATION AS PARAM  22035019
         MVI   LRDCDOPR,LRDLGNCD   STORE LOGON CODE AS PARAMETER        22085019
         BAL   R10,LRDCALCI                                             22135019
         BC    7,LRDRJINV          BRANCH IF ERROR RETURN CODE          22185019
         OI    TDIRSWCH,TDIRLGNN   SET LOGON SWITCH ON                  22235019
         B     LRDJCLBF            BRANCH TO MOVE CARD TO JECL BUFFER   22285019
         SPACE 2                                                        22335019
*                                                                       22385019
*                   JED CARD                                            22435019
*                                                                       22485019
LRDJEDCD TM    TDIRSWCH,TDIRRJLG   TEST FOR RJSTART AND LOGON FOUND     22535019
         BC    14,LRDRJMIS         BRANCH IF ONE OR BOTH MISSING        22585019
         OI    TDIRSWCH+1,TDIRJEDN TURN ON JED SWITCH                   22635019
         TM    LCBNSWFL,LCBNQBIT   TEST FOR CARDS TO BE ENQUEUED        22685019
         BZ    LRDJCLBF            BR IF NO CARDS IN QUEUE ENTRY        22735019
         BAL   R10,LRDWRJCL        WRITE LAST RECORD AND ENQUEUE        22785019
         BAL   R10,LRDASGST        ASSIGN/START NEW QUEUE ENTRY         22835019
         B     LRDJCLBF                                                 22885019
         SPACE 2                                                        22935019
*                                                                       22985019
*                   LOGOFF CARD                                         23035019
*                                                                       23085019
LRDLOGF  TM    TDIRSWCH,TDIRRJLG   TEST FOR RJSTART AND LOGON FOUND     23135019
         BC    14,LRDRJMIS         BRANCH IF ONE OR BOTH MISSING        23185019
         NI    TDIRSWCH,TDIRLGNF   TURN OFF LOGON SWITCH                23235019
         B     LRDJCLBF            BRANCH TO MOVE CARD TO JECL BUFFER   23285019
         SPACE 2                                                        23335019
*                                                                       23385019
*                   RJEND CARD                                          23435019
*                                                                       23485019
LRDRJND  TM    TDIRSWCH,TDIRRJSN   TEST FOR RJSTART FOUND ALREADY       23535019
         BZ    LRDRJMIS            BRANCH IF NO PRECEDING RJSTART-ERROR 23585019
         NI    TDIRSWCH,TDIRRJLF   TURN OFF RJSTART AND LOGON SWITCHES  23635019
         NI    TDIRSTAT,TDIRNQJF   TURN OFF ENQUEUE JOBS BIT IN TDIR    23685019
         OI    TDIRSTAT,TDIRDQMN   SET DEQUEUE MESSAGES ONLY BIT        23735019
         MVC   3(6,R3),LRDRJEND  PUT 'RJEND' IN COL. 4           A51866 23745021
         B     RJENDR             GO DO SPECIAL RJEND PROCESS    A26537 23755020
         SPACE 1                                                        23785019
*                                                                       23835019
*********************************************************************** 23885019
*                                                                       23935019
*                   PUT CARD IN JECL AND JCL BUFFER                     23985019
*                   WRITE BUFFER IF FULL                                24035019
*                                                                       24085019
*********************************************************************** 24135019
*                                                                       24185019
LRDJCLBF DS    0H                                                  000C 24235019
         L     R1,LCBBUFER         GET QMPA ADDRESS                000C 24285019
         LA    R3,QMCHN            GET DISK BUFFER ADDRESS         000C 24335019
         OI    LCBNSWFL,LCBNQBIT   INDICATE CARDS TO BE ENQUEUED        24385019
         X     R4,LRDDEC80         SET JCL BUFFER INDEX TO 80 OR 0      24435019
         STC   R4,LRDCDIND(R3)     TO INDICATE 1 OR 2 CARDS IN BUFFER   24485019
*                                  (80 MEANS 1 CARD, 0 MEANS 2 CARDS)   24535019
         BZ    LRDFULL             BUFFER FULL                     000C 24585019
         TM    TDIRSWCH,TDIRRJSN   RJEND RECEIVED?                 000C 24635019
         BO    LRDNOTFL            NO, CONTINUE SAME BUFFER        000C 24685019
         X     R4,LRDDEC80         INDICATE NEXT MOVE TO BEG.      000C 24735019
LRDFULL  DS    0H                                                  000C 24785019
         LA    R10,LRDNOTFL                                             24835019
         SPACE 1                                                        24885019
LRDWRASG LR    R9,R11              GET ADDR OF TERMINAL DIRECTORY ENTRY 24935019
         S     R9,LRDCDTDR         SUBTRACT START OF TERM DIREC ENTRIES 24985019
         ST    R9,LRDRELTD(R3)     STORE RELATIVE DISPLACEMENT WITHIN   25035019
*                                  TERMINAL DIRECTORY                   25085019
         L     R1,LCBBUFER         GET QUEUE MANAGER PARAM. AREA ADDR.  25135019
         MVI   QMPOP,QMWRTA        STORE WRITE AND ASSIGN CODE          25185019
         MVI   QMPCM,LRDWR1AS      WRITE ONE RECORD AND ASSIGN ONE TTR  25235019
         ST    R3,QMPCA            STORE ADDR OF BUFFER TO BE WRITTEN   25285019
         USING IHKZZAVT,R14        CHANGE REG TO DSECT RJE AVT          25335019
         L     R14,LRDZZAVT        GET BASE FOR RJE COMM AREA           25385019
         L     R15,IHKZZSSS        GET IEFQMSSS ENTRY POINT ADDRESS     25435019
         BALR  R14,R15             LET IT DO ITS BIT                    25485019
         USING LRDCVT,R14          RESTORE REG TO DSECT CVT             25535019
         LTR   R15,R15             TEST RETURN CODE                     25585019
         BC    7,LRDQMIOE          BRANCH IF I/O ERROR                  25635019
         L     R1,LCBBUFER         GET QUEUE MANAGER PARAM. AREA ADDR.  25685019
         L     R9,QMCHN            GET TTR FOR NEXT WRITE               25735019
         ST    R9,QMPEX            PUT TTR IN PROPER PARAMETER WORD     25785019
         L     R9,QMPCA            GET TTR JUST ASSIGNED                25835019
         ST    R9,QMCHN            SAVE IN CHAINING WORD OF BUFFER      25885019
         MVI   LRDCDIND(R3),LRDNOCRD INDICATE NO CARDS IN BUFFER        25935019
         BR    R10                                                      25985019
         SPACE 2                                                        26035019
LRDNTFUL LA    R3,80(R3)           STEP DISK BUFFER PTR TO NEXT CARD    26085019
*                                                                       26135019
*********************************************************************** 26185019
*                                                                       26235019
*                   TEST IF BTAM BUFFER EMPTY                           26285019
*                   ISSUE READ CONTINUE IF EMPTY                        26335019
*                                                                       26385019
*********************************************************************** 26435019
*                                                                       26485019
LRDNOTFL TM    TDIRSWCH+2,TDIRMCHN TEST FOR CPU OR 2780                 26535019
         BZ    LRD2780             BRANCH IF 2780                       26585019
         TM    TDIRRB,TDIRPNRN     DID WE UNPACK THIS RECORD?      000C 26635019
         BNO   LRDSTP80            NO, STEP BUFFER POINTER BY 80   000C 26685019
         SR    R15,R15             CLEAR REG. FOR IC               000C 26735019
         IC    R15,0(R5)           GET LENGTH OF RECORD            000C 26785019
         AR    R5,R15              STEP TO NEXT RECORD             000C 26835019
         B     LRDBTAM             CHECK FOR END OF BUFFER         000C 26885019
LRDSTP80 LA    R5,80(R5)           STEP BTAM BUFFER PTR TO NEXT CARd00C 26935019
LRDBTAM  OI    TDIRRB,TDIRUNPN     RECORDS WILL BE UNPACKEDIF NEC. 000C 26985019
         CR    R5,R6               CHECK FOR END OF BTAM BUFFER    000C 27035019
         BL    LRDNXTCD            BRANCH IF NOT END OF BUFFER          27085019
LRDREAD  LA    R9,LRDNXTCD         SET RETURN ADDRESS                   27135019
         SPACE 1                                                        27185019
         L     R7,LCBLDECB         GET LINE DECB ADDRESS                27235019
LRDRDTT  L     R5,DECAREA          GET ADDRESS OF BTAM BUFFER           27285019
         SR    R0,R0               CLEAR FIRST WORD OF BTAM BUFFER      27335019
         ST    R0,0(0,R5)          TO PERMIT CHECKING FOR CARD JAM      27385019
         READ  (7),TT,MF=E         READ FROM LINE                       27435019
         BAL   R10,LRDSIO          CHECK FOR SUCCESSFUL READ            27485019
         BNE   LRDBDRD             BRANCH IF NOT SUCCESSFUL             27535019
LRDSRDTP BAL   R10,LRDBUFPT        GET POINTERS TO START AND END        27585019
*                                  OF BTAM BUFFER                       27635019
LRDCKEOT CLI   0(R5),LRDEOTCR      CHECK FOR EOT                        27685019
         BE    LRDEOT              BRANCH IF FOUND                      27735019
         CLC   0(2,R5),LRDSOHD     CHECK FOR SOH D                      27785019
         BE    LRDDISCN            BRANCH IF DISCONTINUED INPUT         27835019
         CLC   0(2,R5),LRDSOHR     CHECK FOR SOH R                      27885019
         BE    LRDRESUM            BRANCH IF RESUMING NORMAL INPUT      27935019
         CLC   0(2,R5),LRDDLSTX    CHECK FOR DLE STX                    27985019
         BNE   LRDBDRD             BRANCH IF NOT FOUND                  28035019
         LA    R5,2(R5)            STEP POINTER PAST DATA LINK CHARS.   28085019
         BR    R9                                                       28135019
         SPACE 1                                                        28185019
LRDNXTCD DS    0H                                                A28204 28235019
         LTR   R11,R11             TDIR POINTER?                 A28204 28285019
         BZ    LRDRJNEC            NO, NEED RJSTART              A28204 28335019
         TM    TDIRSWCH,TDIRDDDN   TEST DD DATA SWITCH           A28204 28385019
         BZ    LRDCKTYP            BRANCH IF NOT PROCESSING DD DATA     28435019
         BAL   R14,LRDUNPK         UNPACK RECORD INTO OUTPUT BUFFER000C 28485019
         B     LRDMVSYS            BRANCH IF PROCESSING DD DATA SYSIN   28535019
         SPACE 2                                                        28585019
LRDBUFPT L     R5,DECAREA          GET ADDRESS OF BTAM BUFFER           28635019
         LH    R6,DECLNGTH         GET LENGTH OF BUFFER                 28685019
         LH    R0,DECCOUNT         GET NUMBER OF UNFILLED BYTES         28735019
         SR    R6,R0               GET NO. OF BYTES OF DATA IN BUF      28785019
         BZ    LRDBDRD             BRANCH TO RJENDF IF NO DATA          28835019
         AR    R6,R5               SET REG 6 TO END OF BUFFER           28885019
         BCTR  R6,0                SUBTRACT NO. DATA LINK CHARS.   000C 28935019
         LR    R15,R8           SAVE DISK DCB POINTER              000D 28985019
         L     R8,DECDCBAD        GET LINE DCB POINTER             000D 29035019
         TM    DCBXMODE,ITBCHAR   TEST IF ITB MODE SET             000D 29085019
         BZ    LRDITB             NO DONT DECREMENT COUNT          000D 29135019
         BCTR  R6,R0              YES DECREMENT COUNT BY ONE       000D 29185019
LRDITB   EQU   *                                                   000D 29235019
         LR    R8,R15             RESTORE DISK DCB POINTER         000D 29285019
         BR    R10                                                      33360018
         SPACE 2                                                        33420018
*                                                                       33480018
*********************************************************************** 33540018
*                                                                       33600018
*                   EOT RECEIVED - CLEAN UP AND CALL LINE SCHEDULER     33660018
*                                                                       33720018
*********************************************************************** 33780018
*                                                                       33840018
LRDEOT   LTR   R11,R11             CHECK FOR TERMINAL DIRECTORY POINTER 33900018
         BZ    LRDDELET            BRANCH IF NO POINTER                 33960018
         TM    TDIRSWCH+1,TDIRDIPN TEST DISCONTINUED INPUT SWITCH       34260018
         BO    LRDDISCT            BRANCH IF ON                         34320018
LRD1130  TM    TDIRSWCH,TDIRSYSN       TEST DD DATA AND DD* SW   A40166 34380020
         BZ    LRDWRTJC            BRANCH IF BOTH SWITCHES OFF          34440018
         BAL   R10,LRDSYEND        WRITE LAST SYSIN RECORD AND CLOSE    34500018
LRDWRTJC LA    R10,LRDRELBF        SET RETURN ADDRESS                   34560018
         SPACE 1                                                        34620018
LRDWRJCL LR    R9,R11              GET ADDR OF TERMINAL DIRECTORY ENTRY 34680018
         S     R9,LRDCDTDR         SUBTRACT START OF TERM DIREC ENTRIES 34740018
         LR    R8,R3               SAVE ADDRESS OF CARD IMAGE      000C 34800018
         L     R1,LCBBUFER         GET QUEUE MANAGER PARAM AREA ADD000C 34860018
         LA    R3,QMCHN            GET ADDRESS OF OUTPUT BUFFER    000C 34920018
         ST    R9,LRDRELTD(R3)     STORE RELATIVE DISPLACEMENT WITHIN   34980018
*                                  TERMINAL DIRECTORY                   35040018
         MVI   QMPOP,QMWREN        STORE ENQUEUE CODE                   35100018
         MVI   QMPNC,LRDWR1        TO WRITE ONE RECORD                  35160018
         TM    LRDCDIND(R3),LRD1CRD TEST FOR NUMBER OF CARDS IN BUFFER  35220018
         BC    9,LRD1CARD          BRANCH IF ONE OR TWO CARDS IN BUFFER 35280018
         MVI   LRDCDIND(R3),LRDNOCRD INDICATE NO CARDS IN BUFFER        35340018
LRD1CARD SR    R9,R9                                                    35400018
         ST    R9,0(R3)            SET CHAINING TTR TO ZERO             35460018
         ST    R3,QMPCA            STORE ADDR OF BUFFER TO BE WRITTEN   35520018
         USING IHKZZAVT,R14        CHANGE REG TO DSECT RJE AVT          35580018
         L     R14,LRDZZAVT        GET BASE FOR RJE COMM AREA           35640018
         L     R15,IHKZZSSS        GET IEFQMSSS ENTRY POINT ADDRESS     35700018
         BALR  R14,R15             LET IT DO ITS BIT                    35760018
         USING LRDCVT,R14          RESTORE REG TO DSECT CVT             35820018
         LTR   R15,R15             TEST RETURN CODE                     35880018
         BC    7,LRDQMIOE          BRANCH IF I/O ERROR                  35940018
         MVC   4(80,R3),0(R8)      MOVE CARD TO BEGINNING OF BUFFER000C 36000018
        L     R7,LCBDDECB          RESTORE DISK DECB POINTER       000C 36060018
         L     R8,DECDCBAD         RESTORE DCB POINTER             000C 36120018
         L     R1,LCBBUFER         GET ADDRESS OF JOB NAME              36180018
         CLC   QMNAM(8),LRDTASK    CHECK FOR JOBNAME                    36240018
         BE    LRDNOFST            BRANCH IF ONLY JECL ON QUEUE ENTRY   36300018
         L     R15,LRDCDSCH        GET ENTRY POINT OF FAST TABLE SEARCH 36360018
         BALR  R14,R15             FIND FAST TABLE ENTRY JUST ASSIGNED  36420018
*                                  UPON RETURN REGISTER 1 CONTAINS THE  36480018
*                                  ADDRESS OF FAST TABLE ENTRY          36540018
         L     R15,LRDCDFMR        GET ENTRY POINT OF FAST TABLE MGR    36600018
         BALR  R14,R15             WRITE FAST TABLE ENTRY ON DISK       36660018
LRDNOFST BR    R10                                                      36720018
         SPACE 1                                                        36780018
LRDRELBF L     R7,LCBLDECB         GET ADDRESS OF LINE DECB             36840018
         L     R8,DECDCBAD         GET ADDRESS OF LINE DCB              36900018
         L     R5,LCBWORKA         GET ADDRESS OF BTAM BUFFER           36960018
         SR    R9,R9               STORE ZERO IN FIRST WORD OF BTAM     37020018
         ST    R9,0(R5)            BUFFER TO INDICATE NO CHAINING       37080018
         RELBUF (8),(5)            RELEASE BTAM'S BUFFER                37140018
         LTR   R11,R11             CHECK FOR TERMINAL DIRECTORY POINTER 37200018
         BZ    LRDCKSWL            BRANCH IF NONE                       37260018
         NI    TDIRSWCH,TDIRDARF   TURN OFF DD DATA, DD *, AND          37320018
*                                  NO RJENDF SWITCHES                   37380018
         NI    TDIRSWCH+1,TDIRJDD  TURN OFF JED, DISABLE, AND    A48402 37420021
TDIRJDD  EQU   X'F8'          DISCONTINUED INPUT SWITCHES        A48402 37460021
         NI    TDIRSWCH+2,TDIRJCLF TURN OFF JCL SWITCH                  37500018
         TM    12(R11),TDIRRJN     TEST RJEND RECEIVED           A26537 37510020
         BO    LRDWAIT            YES RJEND PROCEES GO WAIT      A26537 37520020
LRDRTL   EQU   *                                                 A26537 37530020
         TM    LCBNSWFL,LCBLST28   TEST FOR RETURN 28 TO IHKABLST       37560018
         BO    LRDLST28            BRANCH IF SO                         37620018
         TM    LCBNSWFL,LCBSTRJE   TEST FOR RETURN 0 TO IHKABLST        37680018
         BO    LRDRTLST            BRANCH IF SO                         37740018
         TM    TDIRSWCH+2,TDIRLWRN TEST BRANCH TO LWR SWITCH            37800018
         BO    LRDBRLWR            BRANCH IF ON                         37860018
         CLI   LCBTYPLN,LCBSWTCH   TEST FOR SWITCHED LINE               37920018
         BE    LRDRTOUT            BRANCH IF SWITCHED LINE              37980018
LRDRTLST EQU   *                                                        37990018
         TM     LCBFLG,LCB3977    TEST FOR 3977 MODEM              000D 38000018
         BZ    LRDRTSLT           NO DO NORMAL RETURN              000D 38010018
         LA    R15,LRDSTSLT       SET RETURN CODE TO LST FOR LOPEN 000D 38020018
         B     LRDRETLS           FUNCTION                         000D 38030018
LRDRTSLT LA    R15,LRDCDLST       SET RETURN (NORMAL) FOR IHKABLST 000D 38040018
LRDRETLS L     R14,LRDABLST        GET RETURN ADDRESS OF LINE SCHEDULER 38090020
         BR    R14                 RETURN TO LINE SCHEDULER             38140020
         SPACE 2                                                        38190020
LRDLST28 LA    R15,LRDSW278        RETURN TO SEND EOT TO 2780 ON        38240020
*                                  SWITCHED LINE                        38290020
         B     LRDRETLS            RETURN TO LINE SCHEDULER             38340020
         SPACE 2                                                        38390020
LRDCKSWL CLI   LCBTYPLN,LCBSWTCH   CHECK FOR SWITCHED LINE              38440020
         BNE   LRDRTLST            TO SET RETURN CODE FOR IHKABLST      38490020
         TM    LCBNSWFL,LCBLST28   TEST FOR RETURN 28 TO IHKABLST       38540020
         BO    LRDLST28            BRANCH IF SO                         38590020
         TM    LCBNSWFL,LCBERRSW   TEST ERROR SWITCH                    38640020
         BZ    LRDRTLST            BRANCH IF OFF                        38690020
LRDRTEOT LA    R15,LRDCDEOT        SET RETURN CODE FOR IHKABEOT         38740020
         B     LRDRETLS            RETURN TO LINE SCHEDULER             38790020
         SPACE 2                                                        38840020
LRDRTOUT TM    LCBNSWFL,LCBRJNDF   TEST FOR RJENDF GENERATED            38890020
         BO    LRDRTLST            BRANCH IF SO                         38940020
LRDTSTER TM    LCBNSWFL,LCBERRSW   TEST ERROR SWITCH                    38990020
         BO    LRDRTEOT            BRANCH IF ON                         39040020
         LA    R15,LRDCDSWL        SET RETURN CODE FOR SWITCHED LINE    39090020
         B     LRDRETLS            RETURN TO LINE SCHEDULER             39140020
         SPACE 2                                                        39190020
LRDBRLWR NI    TDIRSWCH+2,TDIRLWRF TURN OFF BRANCH TO LWR SWITCH        39240020
         LA    R15,LRDCDLWR        SET RETURN CODE FOR IHKABLWR         39290020
         B     LRDRETLS            RETURN TO LINE SCHEDULER             39340020
         SPACE 2                                                        39390020
LRD2780  EQU   *                                                        39440020
         LA    R5,84(R5)          STEP BTAM BUFFER PTR TO NEXT CARD     39590020
         B     LRDBTAM                                                  39640020
         SPACE 2                                                        39690020
LRDDISCN LTR   R11,R11             CHECK FOR TDIR POINTER               39740020
         BZ    LRDREAD             BRANCH IF NO TDIR POINTER            39790020
         OI    TDIRSWCH+1,TDIRDIPN TURN ON DISCONTINUED INPUT SW        39840020
         B     LRDREAD             READ MORE INPUT                      39890020
         SPACE 2                                                        39940020
LRDRESUM LTR   R11,R11             CHECK FOR TDIR POINTER               39990020
         BZ    LRDREAD             BRANCH IF NO TDIR POINTER            40040020
         NI    TDIRSWCH+1,TDIRDIPF TURN OFF DISCONTINUED INPUT SW       40090020
         B     LRDREAD                                                  40140020
         SPACE 2                                                        40190020
*                                                                       40240020
*********************************************************************** 40290020
*                                                                       40340020
*                   EOT RECEIVED IN DISCONTINUED INPUT MODE             40390020
*                   ISSUE READ INITIAL FOR NON-SWITCHED LINE            40440020
*                   ISSUE WRITE RESET AND READ CONTINUE FOR SWITCHED LN 40490020
*                                                                       40540020
*********************************************************************** 40590020
*                                                                       40640020
LRDDISCT L     R7,LCBLDECB         GET POINTER TO DECB FOR LINE         40690020
         L     R14,LRDZZAVT        GET BASE OF AVT DSECT                40740020
         USING IHKZZAVT,R14        BASE OF AVT DSECT                    40790020
         L     R15,IHKZZRCS        GET ADDRESS OF WARMSTART AND         40840020
*                                  STOP BITS                            40890020
         TM    0(R15),LRDSTRJE     TEST STOP RJE BIT                    40940020
         BO    LRDSTOP             BRANCH IF ON                         40990020
         CLI   LCBTYPLN,LCBSWTCH   CHECK FOR SWITCHED LINE              41040020
         BE    LRDRDTQ             BRANCH IF SWITCHED LINE              41090020
         CLI   LCBTYPLN,LCBPTPT    CHECK FOR POINT-TO-POINT LINE        41140020
         BE    LRDRDAGN            BRANCH IF POINT-TO-POINT LINE        41190020
         L     R10,LCBDFTRM        GET ADDRESS OF DFTRMLST IN LCB       41240020
         BCTR  R10,0               SUBTRACT ONE TO GET ADDRESS OF       41290020
*                                  ATTRIBUTE CHAR BEFORE DFTRMLST       41340020
         SR    R9,R9               GET ATTRIBUTE CHARACTER IN           41390020
         IC    R9,0(R10)           REGISTER 9                           41440020
         SRL   R9,5                GET LENGTH OF EACH ENTRY IN          41490020
*                                  DFTRMLST                             41540020
         SH    R9,LRD3             IGNORE ENQ AND INDEX AFTER           41590020
*                                  POLLING CHARACTER(S)                 41640020
         L     R10,DECENTRY        GET ADDRESS OF CURRENT POLLING       41690020
*                                  ENTRY                                41740020
CHKSYN   EQU   *                                                   000D 41790020
         CLI   0(R10),LRDSYNC     CHECK FOR SYN CHARACTER          000D 41840020
         BNE   OKAY               NO SYN CHARACTER CONTINUE        000D 41890020
         LA    R10,1(R10)         STEP POINTER FORWARD             2756 41940020
         BCTR  R9,0               DECREMENT COUNT TO DELETE SYNS   000D 41990020
         B     CHKSYN             GO CHECK FOR ANOTHER SYN         000D 42040020
OKAY     EQU   *                                                   000D 42090020
         EX    R9,LRDMVSEL         MOVE POLLING CHARACTER(S) TO         42140020
*                                  DFTRMLST IN TERMINAL DIRECTORY       42190020
         LA    R9,TDIRDFTA+3       GET ADDR OF DEFINE TERMINAL LIST000C 42240020
LRDRDAGN READ  (7),TI,,,,(9),MF=E  READ INPUT DATA                      42290020
         BAL   R10,LRDSIO          CHECK FOR SUCCESSFUL READ            42340020
         BNE   LRDCKRST            BRANCH IF UNSUCCESSFUL               42390020
         TM    DECFLAGS,LRDRTPL    CHECK FOR READ ENDED BY RESETPL      42440020
*                                  ON MULTI-POINT LINE                  42490020
         BO    LRDDISCT            BRANCH IF SO                         42540020
         BAL   R10,LRDBUFPT        GET POINTER TO START AND END         42590020
*                                  OF BTAM BUFFER                       42640020
         CLI   LCBTYPLN,LCBMULPT   CHECK FOR MULTI-POINT LINE           42690020
         BNE   LRDSTP1             BRANCH IF NOT MULTI-POINT LINE       42740020
         LA    R5,1(R5)            STEP PAST POLLING CHARACTER          42790020
LRDSTP1  BAL   R9,LRDCKEOT         CHECK DATA LINK CONTROL CHARS.       42840020
         B     LRDNXTCD                                                 42890020
LRDCKRST CLI   DECSDECB,LRDRSTPL   TEST COMPLETION CODE FOR RESETPL     42940020
*                                  ON POINT-TO-POINT LINE               42990020
         BE    LRDDISCT            BRANCH IF 48 TO READ AGAIN           43040020
         B     LRDBDRD             BRANCH TO RJENDF                     43090020
         SPACE 2                                                        43140020
LRDRDTQ  LA    R9,9                SET LOOP COUNTER FOR READ ENQ        43190020
         OI    DECTYPE,LRDTOFLG    INDICATE NO BTAM ERROR MESSAGE       43240020
*                                  FOR TIME OUT                         43290020
         WRITE (7),TN,MF=E         WRITE RESET AND GET ENQ AS RESPONSE  43340020
         BAL   R10,LRDSIO          CHECK FOR SUCCESSFUL READ            43390020
         BNE   LRDCKTIM            BRANCH IF UNSUCCESSFUL COMPLETION    43440020
         CLI   DECRESPN,LRDENQ     CHECK FOR ENQ IN RESPONSE FIELD      43490020
         BE    LRDREAD             ENQ RECEIVED DO READ CONTINUE   000E 43540020
         CLI   DECRESPN,LRDEOTCR   EOT CHECK                       000E 43590020
         BE    LRDRDTQ             EOT RECEIVED DO WRITE EOT       000E 43640020
         B     LRDBDRD             INVALID CHAR DO RJENDF          000E 43690020
         SPACE 2                                                        43740020
LRDRDTQR EQU   *                                                        43790020
         OI    DECTYPE,LRDTOFLG    INDICATE NO BTAM ERROR MESSAGE       43840020
*                                  FOR TIME OUT                         43890020
         READ  (7),TQ,MF=E         READ ENQ                             43940020
         BAL   R10,LRDSIO          CHECK FOR SUCCESSFUL READ            43990020
         BE    LRDREAD             BRANCH IF SUCCESSFUL COMPLETION      44040020
LRDCKTIM TM    DECSENS0,LRDTMOUT   TEST FOR TIME OUT                    44090020
         BZ    LRDBDRD             BRANCH TO RJENDF IF NOT TIME OUT     44140020
         BCT   R9,LRDRDTQR         REPEAT READ ENQ 7 TIMES              44190020
         B     LRDBDRD             RJENDF AFTER EXECUTING READ ENQ 8    44240020
*                                  TIMES                                44290020
         SPACE 2                                                        44340020
LRDSIO   LTR   R15,R15             TEST FOR SUCCESSFUL START OF READ    44390020
         BC    7,LRDBDRD           BRANCH IF UNSUCCESSFUL START         44440020
         LR    R1,R7               GET ADDRESS OF LINE ECB              44490020
         L     R15,LRDAADSP        GET ADDRESS OF DISPATCHER            44540020
         BALR  R14,R15             HAS MULTIPLE WAIT                    44590020
         NI    DECTYPE,LRDTOOFF    RESET FOR BTAM ERROR MESSAGE         44640020
*                                  FOR TIME OUT                         44690020
         CLI   DECSDECB,LRD7F      TEST FOR SUCCESSFUL COMPLETION       44740020
         BR    R10                                                      44790020
         SPACE 2                                                        44840020
LRDSTOP  OI    LCBNSWFL,LCBSTRJE   INDICATE RETURN OF ZERO              44890020
         NI    TDIRSWCH+1,TDIRDIPF TURN OFF DISCONTINUED INPUT SWITCH   44940020
         XC    0(4,R5),0(R5)       CLEAR EOT STX ENQ FROM BTAM BUF      44990020
         B     LRDEOT              CLEAN UP AND RETURN TO IHKABLST      45040020
         SPACE 2                                                        45090020
LRDJCLCK CLC   0(2,R3),LRDSLASH    CHECK FOR JCL CARD              000C 45140020
         BNE   LRDSYSDT            BRANCH IF NOT JCL - IT IS SYSIN      45190020
*                                                                       45240020
*********************************************************************** 45290020
*                                                                       45340020
*                   PROCESS JCL                                         45390020
*                   CHECK FOR JOB, DD * OR DD DATA CARD                 45440020
*                                                                       45490020
*********************************************************************** 45540020
*                                                                       45590020
         TM    TDIRSWCH,TDIRRJLG   TEST FOR RJSTART AND LOGON FOUND     45640020
         BC    14,LRDRJMIS         BRANCH IF ONE OR BOTH MISSING        45690020
         TM    TDIRSWCH,TDIRDDAN   TEST DD * SWITCH                     45740020
         BC    14,LRDJCL           BRANCH IF DD * SWITCH NOT ON         45790020
         BAL   R10,LRDSYEND        BRANCH IF DD * SWITCH ON             45840020
         B     LRDCKTYP            GO PROCESS RECORD               000C 45890020
LRDJCL   LA    R10,70(R3)          GET STOPPING ADDRESS FOR SCAN  M3158 45940020
         CLI   2(R3),ASTER         CHECK FOR //* (COMMENT)       A22260 45990020
ASTER    EQU   C'*'                                              A22260 46040020
         BNE   LRDNOTC            NO,NOT COMMENTD                A26537 46090020
         TM    TDIRSWCH+2,TDIRJCLN ARE WE IN JCL?                A22260 46140020
         BZ    LRDNOJOB            NO, NO JOB CARD ERROR         A22260 46190020
         B     LRDJCLBF            YES, VALID COMMENT CARD       A22260 46240020
LRDNOTC  EQU   *                                                 A26537 46290020
         L     R12,OTHRBASE       SET BASE FOR SUB ROUTINE       A26537 46340020
         BR    R12                AND GO TO IT                   A26537 46390020
LRDDDATA OI    TDIRSWCH,TDIRDDDN   TURN ON DD DATA SWITCH          000C 46440020
*                                                                       46490020
*********************************************************************** 46540020
*                                                                       46590020
*                   DD * OR DD DATA CARD RECEIVED                       46640020
*                   ALLOCATE AND OPEN SYSIN DATA SET                    46690020
*                   MODIFY DD CARD                                      46740020
*                                                                       46790020
*********************************************************************** 46840020
*                                                                       46890020
LRDDDCRD MVC   DCBDDNAM(8),LCBDDNAM PUT DDNAME OF LINE'S SYSIN DD CARD  46940020
*                                   IN DCB                              46990020
         LA    R11,LRDJFCB         SET RETURN ADDRESS                   47040020
         SPACE 1                                                        47090020
         USING LRDCVT,R14          SET BASE OF CVT                      47140020
LRDGTUCB L     R14,CVTPTR          GET ADDRESS OF CVT                   47190020
         L     R1,CVTTCBP          GET ADDRESS OF TCB ADDRESSES         47240020
         L     R1,4(R1)            GET ADDRESS OF TCB                   47290020
         L     R9,TCBTIO(R1)       GET ADDRESS OF TIOT                  47340020
         USING LRDTIOT1,R9         SET BASE FOR TIOT                    47390020
LRDTIOT  SR    R10,R10             CLEAR REGISTER 10                    47440020
         IC    R10,TIOELNGH        GET LENGTH OF THIS DD ENTRY          47490020
         LTR   R10,R10             TEST FOR END OF DD ENTRIES IN TIOT   47540020
         BNZ   LRDON               BRANCH IF NOT END OF DD ENTRIES 000C 47590020
*                                  BAD RJE PROCEDURE                    47640020
*                                  SYSIN DD CARD FOR LINE MISSING       47690020
LRDAB987 DS    0H                  TAG FOR BRANCHING                    47740020
         USING IHKZZAVT,R14        CHANGE REG TO DSECT RJE AVT          47790020
         L     R14,LRDZZAVT        GET BASE FOR RJE COMM AREA           47840020
         L     R1,IHKZZRCS         GET RJE COMM SWITCH ADDRESS          47890020
         OI    0(R1),LRD17ERR      SET BAD PROCEDURE INDICATOR     000C 47940020
LRD17ERR EQU   X'03'               BAD RJE PROCEDURE INDICATOR     000C 47990020
         L     R15,IHKZZASE        GET RJE EXIT ENTRY POINT             48040020
         BR    R15                 INDICATE ABNORMAL CLOSEDOWN          48090020
         USING LRDCVT,R14          RESTORE REG TO DSECT CVT             48140020
LRDON    DS    0H                  TAG FOR BRANCHING                    48190020
         CLC   TIOEDDNM(8),LCBDDNAM COMPARE DDNAME TO SYSIN DATA DDNAME 48240020
         BE    LRDUCB              BRANCH IF EQUAL                      48290020
         AR    R9,R10              STEP TO NEXT DD ENTRY IN TIOT        48340020
         B     LRDTIOT                                                  48390020
LRDUCB   LA    R10,TIOESTTB        GET ADDRESS OF UCB ADDRESS           48440020
         ST    R10,LRDUCBAD        STORE FOR ALLOCATE ROUTINE           48490020
         BR    R11                                                      48540020
         SPACE 1                                                        48590020
LRDJFCB  DS    0H                                                  000C 48640020
         L     R1,LRDSVBLK         GET ADDR OF BLANK AFTER DDNAME       48690020
         MVC   1(18,R1),0(R1)      PUT BLANKS AFTER DDNAME              48740020
LRDALC   ST    R4,LCBPARM1         STORE JECL-JCL BUFFER INDEX          48790020
         L     R14,LRDZZAVT        GET BASE OF AVT DSECT                48840020
         USING IHKZZAVT,R14        SET BASE OF AVT DSECT                48890020
         ST    R2,IHKZZLCB         STORE LCB ADDRESS                    48940020
         LA    R1,IHKZZLCB         GET ADDRESS OF PARAMETER             48990020
         L     R15,LRDABALC        GET ADDR OF SYSIN ALLOCATION ROUTINE 49040020
         BALR  R14,R15                                                  49090020
         L     R11,LCBTDIR         RESET TERMINAL DIRECTORY ADDR        49140020
         B     *+4(R15)            BRANCH ON RETURN CODE                49190020
         B     LRDSETRG            NORMAL RETURN                        49240020
         B     LRDQMIOE            QUEUE MANAGER I/O ERROR              49290020
         B     LRDSYSSP            OUT OF SPACE FOR SYSIN DATA          49340020
         B     LRDIOALC            I/O ERROR ON ALLOCATE                49390020
         SPACE 2                                                        49440020
LRDSETRG EQU   *                                                        49490020
         SR    R3,R3                    START WITH ZERO COUNT     19018 49540020
         STH   R3,LCBSMFCT              STORE IN COUNTER FIELD    19018 49590020
         L     R3,LCBBUFER         INITIALIZE REGISTER 3 TO START OF    49640020
         LA    R3,LRDDSKBF(R3)     DISK BUFFER                          49690020
         LR    R4,R3               SET REGISTER 4 TO END OF             49740020
         AH    R4,DCBBLKSI         DISK BUFFER                          49790020
         B     LRDNOTFL                                                 49840020
         SPACE 2                                                        49890020
LRDSCJCL LA    R1,LRDSCAN          GET ADDRESS OF PARAMETER LIST        49940020
         L     R15,LRDCCSCN        GET ADDRESS OF SCAN ROUTINE          49990020
         BALR  R14,R15             CALL SCAN TO FIND CHARACTER          50040020
         LTR   R15,R15             TEST RETURN CODE                     50090020
         BCR   7,R9                IF FOUND, RETURN                1654 50140020
         TM    TDIRSWCH+2,TDIRJCLN IS JCL SWITCH ON                1654 50190020
         BZ    LRDNOJOB            NO, STATEMENT INVALID           1654 50240020
         B     LRDJCLBF            IF ON, IT'S OK                  1654 50290020
         SPACE 2                                                        50340020
LRDDDAST OI    TDIRSWCH,TDIRDDAN   TURN ON DD * SWITCH                  50390020
         B     LRDDDCRD                                                 50440020
         SPACE 2                                                        50490020
LRDJEDSW NI    TDIRSWCH+1,TDIRJEDF TURN OFF JED SWITCH                  50540020
*                                  NO JOB CARD                          50590020
LRDNOJOB LA    R0,LRDXMT8          GET INPUT CODE FOR IHKABXMT          50640020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        50690020
         SPACE 2                                                        50740020
*                                                                       50790020
*********************************************************************** 50840020
*                                                                       50890020
*                   PROCESS JOB CARD                                    50940020
*                   START NEW QUEUE ENTRY IF NO JED BEFORE JOB          50990020
*                   GET FAST TABLE ENTRY FOR JOB                        51040020
*                                                                       51090020
*********************************************************************** 51140020
*                                                                       51190020
LRDJOBCD OI    TDIRSWCH+2,TDIRJCLN TURN ON JCL SWITCH                   51240020
         TM    TDIRSWCH+1,TDIRJEDN TEST JED SWITCH                      51290020
         BO    LRDJEDFD            BRANCH IF ON                         51340020
         TM    LCBNSWFL,LCBNQBIT   TEST FOR CARDS TO BE ENQUEUED        51390020
         BZ    LRDJEDFD            BR IF NO CARDS IN QUEUE ENTRY        51440020
         BAL   R10,LRDWRJCL        WRITE LAST RECORD AND ENQUEUE        51490020
         BAL   R10,LRDASGST        ASSIGN/START NEW QUEUE ENTRY         51540020
         LA    R3,4(R3)            SET POINTER TO BUFFER           000C 51590020
LRDJEDFD NI    TDIRSWCH+1,TDIRJEDF TURN OFF JED SWITCH                  51640020
         L     R1,LCBBUFER         GET QUEUE MANAGER PARAM AREA ADDRESS 51690020
         LH    R9,LCBCHARS         GET NO. OF CHARS. IN JOBNAME  A22268 51740020
         STH   R9,LRDJOBCH(R1)     SAVE NO. OF CHARS. IN JOBNAME        51790020
         LTR   R9,R9               TEST FOR NO JOB NAME                 51840020
         BZ    LRDINVNM            BRANCH IF NO JOB NAME                51890020
         CH    R9,LRD8             TEST FOR JOBNAME TOO LONG            51940020
         BH    LRDINVNM            BRANCH IF MORE THAN 8 CHARACTERS     51990020
*                                  VERIFY THAT JOB NAME STARTS WITH AN  52040020
*                                  NATIONAL OR ALPHABETIC CHAR.  A40161 52050020
         CLI   2(R3),LRD$          IS 1ST CHAR OF JOBNAME A $    A40161 52060020
         BE    GOODNAME            YES, THE JOBNAME IS VALID     A40161 52070020
         CLI   2(R3),LRD#          IS 1ST CHAR OF JOBNAME A #    A40161 52080020
         BE    GOODNAME            YES, THE JOBNAME IS VALID     A40161 52090020
         CLI   2(R3),LRD@          IS 1ST CHAR OF JOBNAME A @    A40161 52100020
         BE    GOODNAME            YES, THE JOBNAME IS VALID     A40161 52110020
         CLI   2(R3),LRDA          CHECK FOR LOWEST ALPHABETIC     000C 52140020
         BL    LRDINVNM            BRANCH IF NOT ALPHABETIC OR NUMERIC  52190020
         CLI   2(R3),LRDZ          CHECK FOR HIGHEST ALPHABETIC    000C 52240020
         BH    LRDINVNM            BRANCH IF NUMERIC                    52290020
         MVC   LRDCHAR(1),2(R3)    MOVE FIRST CHARACTER OF JOBNAME 000C 52340020
         NI    LRDCHAR,LRDCLRHI    ZERO HIGH ORDER 4 BITS OF CHARACTER  52390020
         CLI   LRDCHAR,LRDZERO     CHECK FOR ZERO NUMERIC FIELD         52440020
         BE    LRDINVNM            BRANCH IF ZERO                       52490020
         CLI   LRDCHAR,LRDNINE     CHECK NUMERIC FIELD                  52540020
         BH    LRDINVNM            BRANCH IF HIGHER THAN 9              52590020
         CLI   2(R3),LRDINVCR      CHECK FOR X'E1' (INVALID)       000C 52640020
         BE    LRDINVNM            BRANCH IF EQUAL                      52690020
GOODNAME EQU   *                   THE JOBNAME IS VALID          A40161 52710020
         MVI   QMNAM,LRDBLANK      PUT BLANKS AS JOB NAME IN QUEUE      52740020
         MVC   QMNAM+1(7),QMNAM    MANAGER PARAMETER AREA               52790020
         BCTR  R9,0                SUBTRACT ONE FROM CHARACTER COUNT    52840020
         EX    R9,LRDMVJOB         MOVE JOB NAME INTO QMPA              52890020
         L     R15,LRDCDSCH        GET ENTRY POINT OF FAST TABLE SEARCH 52940020
         BALR  R14,R15             CHECK FOR EMPTY ENTRY                52990020
         SH    R15,LRD4            TEST RETURN CODE                     53040020
         BZ    LRDJOBNM            BRANCH IF EMPTY SLOT AVAILABLE       53090020
         BM    LRDDUPJB            BRANCH IF DUPLICATE JOB NAME         53140020
*                                  FAST TABLE IS FULL                   53190020
         LA    R0,LRDXMT16         GET INPUT CODE FOR IHKABXMT          53240020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        53290020
         SPACE 2                                                        53340020
         USING FASTAB,R1           SET BASE FOR FAST TABLE              53390020
LRDJOBNM L     R15,LCBBUFER        GET ADDRESS OF JOBNAME               53440020
         MVC   FASTNAME(8),0(R15)  PUT JOB NAME IN FAST TABLE TO        53490020
*                                  RESERVE ENTRY AND CLEAR REST OF      53540020
*                                  ENTRY EXCEPT TWO TTRS                53590020
         MVI   FASTJIB,FASTIOUT    CLEAR JOB INFORMATION BYTE           53640020
         XC    FASTDSB(2),FASTDSB  CLEAR FASTDSB AND FASTDSBE           53690020
         L     R9,LRDCDFLN         GET ADDRESS OF FAST TABLE LENGTH     53740020
         LH    R9,0(R9)            GET FAST TABLE LENGTH                53790020
         SH    R9,LRD18            TO SKIP CLEARING FIRST               53840020
*                                  17 BYTES OF FAST TABLE ENTRY         53890020
         EX    R9,LRDCLFST         CLEAR REST OF FAST TABLE ENTRY       53940020
         B     LRDJCLBF                                                 53990020
         USING IOPARAMS,R1         RESTORE QMPA BASE                    54040020
         SPACE 2                                                        54090020
*                                  DUPLICATE JOB NAME                   54140020
LRDDUPJB LA    R0,LRDXMT4          GET INPUT CODE FOR IHKABXMT          54190020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        54240020
         SPACE 2                                                        54290020
*                                  NO JOB NAME                          54340020
LRDINVNM SR    R0,R0               INPUT CODE FOR IHKABXMT         000D 54390020
LRDCLXMT ST    R0,LCBPARM1         STORE AS PARAMETER                   54440020
         ST    R3,LCBPARM2         STORE POINTER TO CARD           000C 54490020
LRDXMTCL ST    R6,LCBPARM3         STORE PTR TO END OF BTAM BUFFER      54540020
         L     R14,LRDZZAVT        GET BASE OF AVT DSECT                54590020
         USING IHKZZAVT,R14        BASE OF AVT DSECT                    54640020
         ST    R2,IHKZZLCB         STORE LCB ADDRESS                    54690020
         LA    R1,IHKZZLCB         GET ADDRESS OF PARAMETER             54740020
         L     R15,LRDABXMT        CALL ROUTINE WHICH TRANSMITS         54790020
         BALR  R14,R15             AN ERROR MESSAGE                     54840020
IHKABRET DS    0H                                                 19018 54890020
         B     *+4(R15)            BRANCH ON RETURN CODE                54940020
         B     LRDEOT                                                   54990020
         B     LRDRELBF                                                 55040020
         B     LRDEBDWT            RJENDF WITH ERROR MSG.        A27468 55090020
         B     LRDEBDRD            RJENDF WITH LINE ERROR        A27468 55140020
         B      LRDWRTJC            WRITE JCL BUFFER              19018 55190020
         B     LRDDELET            DELETE QUEUE ENTRY             19018 55240020
         B     LRDSTRET           GO SET RETURN CODE               000E 55290020
         B     LRDDISCT            BRANCH TO DISCONTINUE FUNCTION  000E 55340020
         B     LRDRDTQ             BRANCH TO READ ENQ FUNCTION     000E 55390020
LRDSTRET EQU   *                                                   000E 55440020
         LA    R10,LRDRTLST        SET TO RETURN TO IHKABLST      19018 55490020
         B     LRDWRJCL            WRITE JCL                      19018 55540020
         SPACE 2                                                        55590020
LRDSYSDT TM    TDIRSWCH,TDIRDDAN   TEST DD * SWITCH                     55640020
         BC    12,LRDBLKCK         BRANCH IF NOT READING DD* INPUT      55690020
*                                                                       55740020
*********************************************************************** 55790020
*                                                                       55840020
*                   PROCESS SYSIN DATA                                  55890020
*                                                                       55940020
*********************************************************************** 55990020
*                                                                       56040020
LRDMVSYS CLC   0(3,R3),LRDENDDT    TEST FOR /*                     000C 56090020
         LA    R10,LRDNOTFL        SET RETURN ADDRESS                   56140020
         BE    LRDSYEND            BRANCH IF FOUND                      56190020
         LH    R7,LCBSMFCT              GET NO. OF SYSIN RECORDS  19018 56240020
         LA    R7,1(R7)                 ADD ONE                   19018 56290020
         STH   R7,LCBSMFCT              STORE NEW TOTAL           19018 56340020
         LA    R9,80(R3)           STEP DISK BUFFER POINTER             56390020
         CR    R9,R4               TEST FOR END OF DISK BUFFER          56440020
         BL    LRDNTFUL            BRANCH IF BUFFER NOT FULL            56490020
         SPACE 1                                                        56540020
         L     R7,LCBDDECB         GET DISK DECB ADDRESS FROM LCB       56590020
         L     R9,LCBBUFER         GET ADDRESS OF BEGINNING OF          56640020
         LA    R9,LRDDSKBF(R9)     OUTPUT BUFFER                        56690020
LRDSYSWR WRITE (7),SF,,(9),MF=E    WRITE BUFFER TO SYSIN DATA SET       56740020
         LA    R1,0(R7)            GET DISK ECB ADDRESS                 56790020
         L     R15,LRDAADSP        GET ADDRESS OF  DISPATCHER           56840020
         BALR  R14,R15             GO TO MULTIPLE WAIT                  56890020
         CHECK (1)                                                      56940020
         TM    TDIRSWCH,TDIREOSN   TEST FOR END OF SYSIN                56990020
         L     R3,LCBBUFER         RESET REGISTER 3 TO START OF         57040020
         LA    R3,LRDDSKBF(R3)     DISK BUFFER                          57090020
         BZ    LRDNOTFL            BRANCH IF NOT END OF SYSIN           57140020
         NI    TDIRSWCH,TDIREOSF   TURN OFF END OF SYSIN SWITCH         57190020
LRDCLOSE CLOSE ((8))               CLOSE SYSIN DATA SET                 57240020
         NI    TDIRSWCH,TDIRSYSF   TURN OFF DD DATA AND DD * SWITCHES   57290020
         L     R3,LCBBUFER         SET REGISTER 3 TO BEGINNING OF       57340020
         LA    R3,LRDQMCHN(R3)     JECL AND JCL BUFFER                  57390020
         LH    R4,LCBSMFCT              GET TOTAL SYSIN COUNT     19018 57440020
         CVD   R4,LRDDECNO              CONVERT TO DECIMAL        19018 57490020
         UNPK  LRDUPDEC(8),LRDDECNO+4(4) UNPACK COUNT             19018 57540020
         OI    LRDUPDEC+7,LRDZONE       PUT 'F' IN SIGN POSITION  19018 57590020
         MVC   LRDSMFCD+11(6),LRDUPDEC+2 MOVE COUNT TO CARD       19018 57640020
         MVI   4(R3),LRDBLANK           BLANK OUT BUFFER          19018 57690020
         MVC   5(79,R3),4(R3)           ...                       19018 57740020
         MVC   19(19,R3),LRDSMFCD       MOVE TO JCL BUFFER        19018 57790020
         MVC   4(2,R3),LRDSLASH         MOVE //                   19018 57840020
         L     R4,LRDDEC80         INDEX FOR JCL BUFFER           19018 57890020
         MVI   LRDCDIND(R3),LRD1CRD INDICATE ONE CARD IN BUFFER   19018 57940020
         BR    R10                                                      57990020
         SPACE 2                                                        58040020
LRDSYEND L     R9,LCBBUFER         SET REGISTER 9 TO START OF DISK      58090020
         LA    R9,LRDDSKBF(R9)     BUFFER                               58140020
         L     R7,LCBDDECB         GET DISK DECB POINTER FROM LCB       58190020
         SR    R3,R9               GET NUMBER OF BYTES IN DISK BUFFER   58240020
         LTR   R3,R3               TEST FOR NO DATA IN DISK BUFFER      58290020
         BZ    LRDCLOSE            BRANCH AROUND WRITE IF NO DATA       58340020
         STH   R3,DCBBLKSI         SET BLOCK SIZE FOR SHORT RECORD      58390020
         OI    TDIRSWCH,TDIREOSN   TURN ON END OF SYSIN SWITCH          58440020
         B     LRDSYSWR                                                 58490020
         SPACE 2                                                        58540020
LRDBLKCK CLI   0(R3),LRDBLANK      CHECK FOR BLANK IN COL. 1       000C 58590020
         BNE   LRDGENSY            BRANCH IF NOT BLANK                  58640020
         CLC   1(79,R3),0(R3)      CHECK FOR BLANKS IN 2-80        000C 58690020
         BE    LRDRJF              UNDEFINED OPERATION             000C 58740020
         SPACE 2                                                        58790020
LRDGENSY CLC   0(3,R3),LRDENDDT    TEST FOR /*                     000C 58840020
         BE    LRDNOTFL            BR IF FOUND TO GET NEXT CARD         58890020
         CLC   0(2,R3),LRDDOTS     CHECK FOR .. IN COLS. 1 AND 2   000C 58940020
         BE    LRDSEQCK            QUEUE JECL CARD SO READER CAN        58990020
*                                  GENERATE UNDEFINED OPERATION         59040020
*                                  MESSAGE BECAUSE COL 3 NOT BLANK      59090020
         TM    TDIRSWCH+2,TDIRJCLN TEST JCL SWITCH                      59140020
         BNO   LRDRJF              BRANCH IF NOT ON BECAUSE        000C 59190020
*                                  NOT PROCESSING JOB                   59240020
         OI    TDIRSWCH,TDIRDDAN   TURN ON DD * SWITCH                  59290020
         BAL   R15,LRDFIXR3        GET CORRECT DISK BUFFER POINTER 000C 59340020
         MVC   4(8,R10),LRDGNSYS   PUT '//SYSIN ' IN JECL-JCL BUF       59390020
         MVC   12(72,R10),11(R10)  PUT BLANKS IN COLUMNS 9-80           59440020
         TM    TDIRSWCH+2,TDIRMCHN TEST FOR CPU OR 2780                 59490020
         BZ    LRDSYS27            BRANCH IF 2780                       59540020
         TM    TDIRRB,TDIRPNRN    COMPRESSING TERMINAL?            000C 59590020
         BNO   LRDNOTCE           NO, USE REGULAR STEPPING BACK    000C 59640020
         BCTR  R5,0               JUST BACK UP ONE BYTE TO AVOID   000C 59690020
*                                 BOTH STEPPING BEYOND BEGINNING   000C 59740020
*                                 OF BUFFER AND OVERLAYING INFO    000C 59790020
         MVI   0(R5),X'01'        INDICATE THAT WE STEPPED BACK 1  000C 59840020
         B     LRDGNSY2           CONTINUE                         000C 59890020
LRDNOTCE DS    0H                                                  000C 59940020
         SH    R5,EIGHTY           BACK UP BTAM BUFFER POINTER BY  000C 59990020
*                                  ONE CARD SO FIRST SYSIN CARD IS      60040020
*                                  NOT SKIPPED                          60090020
LRDGNSY2 MVC   DCBDDNAM(8),LCBDDNAM PUT DDNAME OF LINE'S SYSIN          60140020
*                                   DD CARD IN DCB                      60190020
         BAL   R11,LRDGTUCB        GET ADDRESS OF UCB ADDRESS           60240020
         SR    R11,R11                                                  60290020
         STH   R11,LCBPARM3+2                                      000C 60340020
         B     LRDALC              GO TO ALLOCATE ROUTINE               60390020
LRDSYS27 SH    R5,LRD84            BACK UP BTAM BUFFER POINTER BY       60440020
*                                  ONE CARD SO FIRST SYSIN CARD IS      60490020
*                                  NOT SKIPPED                          60540020
         B     LRDGNSY2                                                 60590020
LRDRJWT  LA    R1,DUMECB      LOOP TO WAIT FOR OTHER LINES       A48402 60600021
         L     R15,LRDAADSP   RJENDF TO BE QUEUED                A48402 60610021
         BALR  R14,R15                                           A48402 60620021
         B     LRDRJTST                                          A48402 60630021
         SPACE 2                                                        60640020
*                                                                       60690020
*********************************************************************** 60740020
*                                                                       60790020
*                   ERROR HANDLING SECTION                              60840020
*                                                                       60890020
*********************************************************************** 60940020
*                                                                       60990020
*                                  EXLST ROUTINE                        61040020
LRDOUTSP OI    TDIRRB,TDIREXLN     TURN ON EXLST SWITCH                 61090020
         LA    R15,1               SET RETURN CODE FOR EOV ROUTINE      61140020
         BR    R14                 RETURN TO EOV ROUTINE WHICH THEN     61190020
*                                  COMES TO MY SYNAD EXIT               61240020
         SPACE 2                                                        61290020
*                                  OUT OF SPACE FOR SYSIN               61340020
LRDSYSSP NI    TDIRSWCH,TDIRSYSF   TURN OFF DD DATA AND DD * SWITCHES   61390020
LRDSYSP2 LA    R0,LRDXMT20         GET INPUT CODE FOR IHKABXMT          61440020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        61490020
         SPACE 2                                                        61540020
*                                  OUT OF SPACE FOR SYSIN OR            61590020
*                                  SYSIN LIMIT EXCEEDED OR              61640020
*                                  I/O ERROR ON SYSIN DATA SET          61690020
LRDSYNAD TM    TDIRRB,TDIREXLN     TEST EXLST SWITCH                    61740020
         BO    LRDSYSP2            BRANCH IF ON - OUT OF SPACE          61790020
         L     R9,DCBDEBAD         GET ADDRESS OF DEB FOR SYSIN         61840020
         CLI   DEBNMEXT(R9),LRDNMEXT TEST NUMBER OF EXTENTS IN DEB      61890020
         BL    LRDDSKER            BRANCH IF REALLY DISK I/O ERROR      61940020
*                                  SYSIN LIMIT EXCEEDED                 61990020
         LA    R0,LRDXMT12         GET INPUT CODE FOR IHKABXMT          62040020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        62090020
         SPACE 2                                                        62140020
*                                  OUT OF SPACE FOR QUEUE ENTRY         62190020
LRDQMSPA LA    R0,LRDXMT24         GET INPUT CODE FOR IHKABXMT          62240020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        62290020
         SPACE 2                                                        62340020
*                                  I/O ERROR ON ASSIGN/START            62390020
LRDQMIOA LA    R0,LRDXMT28         GET INPUT CODE FOR IHKABXMT          62440020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        62490020
         SPACE 2                                                        62540020
*                                  I/O ERROR ON Q MGR NOT ASSIGN/START  62590020
LRDQMIOE CLC   LCBWORKA,LRDSPENT   CHECK FOR ENTRY AT IHKABRJF INSTEAD  62640020
*                                  OF AT IHKABLRD                       62690020
         BE    LRDNOTQD            BRANCH IF ENTERED AT IHKABRJF        62740020
         LA    R0,LRDXMT32         GET INPUT CODE FOR IHKABXMT          62790020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        62840020
         SPACE 2                                                        62890020
*                                  I/O ERROR ON ALLOCATE                62940020
LRDIOALC NI    TDIRSWCH,TDIRSYSF   TURN OFF DD DATA AND DD * SWITCHES   62990020
LRDIOSYS LA    R0,LRDXMT36         GET INPUT CODE FOR IHKABXMT          63040020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE        63090020
         SPACE 2                                                        63140020
*                                  I/O ERROR ON SYSIN DATA SET          63190020
LRDDSKER L     R3,LCBBUFER         RESET REGISTER 3 TO START OF         63240020
         LA    R3,LRDDSKBF(R3)     DISK BUFFER                          63290020
         BAL   R11,LRDGTUCB        GET ADDRESS OF UCB ADDRESS           63340020
         L     R11,LCBTDIR         RESET WITH TERMINAL DIRECTORY ADDR   63390020
         B     LRDIOSYS            WRITE MESSAGE TO CENTRAL AND REMOTE  63440020
         SPACE 2                                                   000C 63490020
*                                  UNPACKED RECORD REC'D FOR PACKED000C 63540020
LRDGOOF2 L     R7,LCBLDECB         GET DECB ADDRESS                000C 63590020
         WRITE (7),TN,MF=E         WRITE EOT                       000C 63640020
         BAL   R10,LRDSIO          GO TO CHECK ON I/O              000C 63690020
         LA    R10,LRDCKSYS        SET TO RETURN TO CHECK SYSIN    000C 63740020
         B     LRDWMSRT            BRANCH TO RJENDF                000C 63790020
         SPACE 2                                                        63840020
*                                  BTAM READ FAILED                     63890020
LRDEBDRD DS    0H                                                A47967 63940021
LRDBDRD  LTR   R11,R11             TEST FOR TERMINAL DIRECTORY POINTER  63990020
         BZ    LRDDELET            BRANCH IF NO POINTER                 64040020
         LA    R10,LRDCKSYS        SET RETURN ADDRESS                   64090020
         SPACE 1                                                        64140020
*                                  LINE FAILURE                         64190020
         L     R5,DECAREA         LOAD BUFF POINTER              A24704 64240020
         CLC   0(3,R5),LRDSTKUN    HAS 2770 STACKER UNLOAD BUTON A35897 64250020
*                                  BEEN PRESSED.                 A35897 64260020
         BE    LRDDISCT            YES, ALLOW TIME FOR THE       A35897 64270020
*                                  STACKER TO BE UNLOADED        A35897 64280020
         CLC   0(3,R5),LRDCDJAM   CHECK FOR EOT STX ENQ AFTER    A24704 64290020
*                                 ERROR WHICH MEANS CARD JAM AT  A24704 64340020
*                               2780                             A24704 64390020
         ST    R5,0(R5)            PREVENT LOOP IF TERM. OFFLINE A24712 64440020
         BE    LRDDISCT           BRANCH IF SO TO GIVE TIME FOR  A24704 64490020
*                                 JAM TO BE CORRECTED            A24704 64540020
LRDUSER  L     R9,LRDCDSOC         GET RJETABLE ADDRESS                 64590020
         L     R1,LCBLDECB         GET DECB ADDRESS FOR USER            64640020
         L     R15,LRDUSREX(R9)    GET LINE ERROR USER EXIT ADDRESS     64690020
         BALR  R14,R15             BRANCH TO USER EXIT OR DUMMY         64740020
LRDWMSRT NI    TDIRSTAT,TDIRNQJM   TURN OFF ENQUEUE JOBS AND ENQUEUE    64790020
*                                  MESSAGES BITS                        64840020
         OI    TDIRSTAT,TDIRDQNN   SET DEQUEUE NOTHING BIT              64890020
         OI    LCBNSWFL,LCBRJNDF   INDICATE RJENDF GENERATED            64940020
         NI    TDIRSWCH,TDIRRJLF   TURN OFF RJSTART AND LOGON SWITCHES  64990020
         NI    TDIRSWCH+2,TDIRLWRF TURN OFF BRANCH TO LWR SWITCH        65040020
         L     R14,LRDZZAVT        GET BASE OF AVT DSECT                65090020
         L     R15,IHKZZECB        GET ADDRESS OF ECBLIST OF IHKCCPLM   65140020
         MVI   0(R15),LRDPOST      POST THE MESSAGE ECB                 65190020
         MVI   4(R15),LRDPOST      POST THE JOB ECB                     65240020
         USING LRDCVT,R14          RESET BASE OF CVT                    65290020
         BR    R10                                                      65340020
         SPACE 1                                                        65390020
LRDCKSYS DS    0H                  GENERATE RJENDF                19018 65440020
         LA    R0,LRDXMT64         OFFSET FOR IHKABXMT            19018 65490020
         SR    R4,R4                    INITIALIZE REG 4         19018  65540020
         B     LRDCLXMT            CALL IHKABXMT                  19018 65590020
         SPACE 2                                                        65640020
*                                  WRITE WAS UNSUCCESSFUL               65690020
LRDEBDWT DS    0H                                                A47967 65740021
LRDBADWT LTR   R11,R11             CHECK FOR TERMINAL DIRECTORY POINTER 65790020
         BZ    LRDNOTRM            BRANCH IF NO TDIR POINTER            65840020
         TM    TDIRSWCH,TDIRRJFN   TEST NO RJENDF SWITCH                65890020
         BO    LRDNORJF            BRANCH IF ON                         65940020
         L     R9,LCBBUFER         GET ADDRESS OF LAST 79 BYTES OF      65990020
         LA    R9,LRDMSGBF(R9)     THE OUTPUT BUFFER                    66040020
         BAL   R15,LRDFIXR3        GET CORRECT DISK BUFFER POINTER 000C 66090020
         MVC   4(10,R10),LRDDOTS   PUT '.. RJENDF ' ON CARD             66140020
         MVC   14(60,R10),11(R9)   PUT MESSAGE ON RJENDF CARD           66190020
         BAL   R10,LRDUSER         GO TO USER EXIT AND SET RJENDF BITS  66240020
         LR    R9,R3               GET ADDRESS OF JECL AND JCL BUFFER   66290020
         LA    R0,LRDXMT68         OFFSET FOR IHKABXMT            19018 66340020
         B     LRDCLXMT            CALL IHKABXMT                  19018 66390020
LRDNORJF NI    TDIRSWCH,TDIRRJFF   TURN OFF NO RJENDF SWITCH            66440020
         B     LRDRELBF                                                 66490020
LRDNOTRM DS    0H                  NO TDIR POINTER                19018 66540020
         LA    R0,LRDXMT72         OFFSET FOR IHKABXMT            19018 66590020
         B     LRDCLXMT            CALL IHKABXMT                  19018 66640020
LRDDELET L     R1,LCBBUFER         GET QMPA ADDRESS                     66690020
         SR    R15,R15        IS ADDRESS OF EXTENSION            A47439 66730021
         C     R15,QMPCL      OF QMPA ZERO                       A47439 66770021
         BE    LRDRELBF       YES - SKIP DELETE                  A47439 66810021
         ST    R15,QMPCL      NO - ZERO IT FOR THE NEXT TIME     A47439 66850021
         MVI   QMPOP,QMDELE        STORE DELETE CODE                    66890020
         L     R14,LRDZZAVT        GET BASE FOR RJE COMM AREA           66940020
         USING IHKZZAVT,R14        CHANGE REG TO DSECT RJE AVT          66990020
         L     R15,IHKZZELE        GET IEFQDELE ENTRY POINT             67040020
         BALR  R14,R15             LET IT DO ITS BIT                    67090020
         USING LRDCVT,R14          RESTORE REG TO DSECT CVT             67140020
         LTR   R15,R15             TEST RETURN CODE                     67190020
         BC    7,LRDQMIOE          BRANCH IF I/O ERROR                  67240020
         B     LRDRELBF                                                 67290020
         SPACE 2                                                        67340020
LRDNOTQD LA    R15,LRDCDNRC        SET RETURN CODE FOR RJENDC OR RJENDF 67390020
*                                  NOT QUEUED                           67440020
         B     LRDRETLS            RETURN TO LINE SCHEDULER             67490020
         SPACE 4                                                   000C 67540020
LRDUNPK  DS    0H                  SUBROUTINE TO UNPACK INPUT      000C 67590020
         TM    TDIRSWCH,TDIRSYSN   ARE WE IN SYSIN?                000C 67640020
         BNZ   LRDINSYS            YES, DON'T CHANGE R3            000C 67690020
         L     R1,LCBBUFER         GET QMPA ADDRESS                000C 67740020
         LA    R3,QMCHN            GET DISK BUFFER POINTER         000C 67790020
         LA    R3,4(R3,R4)         GET ADDRESS OF CORRECT RECORD   000C 67840020
LRDINSYS DS    0H                                                  000C 67890020
         TM    TDIRRB,TDIRPUPN     WAS UNPACK SELECTED?            000C 67940020
         BO    LRDUNP              BRANCH IF SO                    000C 67990020
         MVC   0(80,R3),0(R5)      MOVE RECORD TO OUTPUT BUFFER    000C 68040020
         BR    R14                 RETURN                          000C 68090020
LRDUNP   DS    0H                                                  000C 68140020
         CLC   0(2,R5),LRDDOTS     HAS REMOTE SENT AN UNPACKED CARD000C 68190020
         BE    LRDGOOF2            YES, RJENDF THE TERMINAL        000C 68240020
         ST    R5,LCBPARM2         STORE INPUT ADDRESS             000C 68290020
         ST    R3,LCBPARM3         STORE OUTPUT ADDRESS            000C 68340020
         LR    R1,R2               GET LCB ADDRESS                 000C 68390020
         L     R15,LRDADUPK        GET UNPACK ENTRY POINT ADDRESS  000C 68440020
         L     R15,0(R15)          GET UNPACK ENTRY POINT          000C 68490020
         BR    R15                 GO UNPACK RECORD                000C 68540020
         SPACE 4                                                   000C 68590020
LRDFIXR3 DS    0H                                                  000C 68640020
         L     R1,LCBBUFER         GET QMPA ADDRESS                000C 68690020
         LA    R3,QMCHN            GET DISK BUUFER ADDRESS         000C 68740020
         LR    R10,R3              SAVE ADDRESS                    000C 68790020
         AR    R10,R4              ADD BUFFER INDEX (0 OR 80)      000C 68840020
         BR    R15                 RETURN                          000C 68890020
*****************************************************************A26537 68940020
*  THIS ROUTINE READS UNITIL AN EOT IS RECEIVED.                *A26537 68990020
*  IT THEN HOLDS UP LINE I/O OPERATION UNTIL THE RJEND IS       *A26537 69040020
*  PROCESSED.  AFTER THE RJEND MESSAGE IS SENT THE LINE IS      *A26537 69090020
*  AGAIN CONDITIONED TO PROCESS MORE INPUT                      *A26537 69140020
*****************************************************************A26537 69190020
RJENDR   EQU   *                                                 A26537 69240020
         L     R7,LCBLDECB        LOADS LINE DECB POINTER        A26537 69290020
         L     R5,DECAREA          LOADS POINTER TO BUFFER       A26537 69340020
         SR    R0,R0                                             A26537 69390020
         ST    R0,0(0,R5)          STORE ZERO IN FIRST WORD OF   A26537 69440020
*                                  BUFFER SO CHECK FOR EOT CAN BEA26537 69490020
*                                  MADE                          A26537 69540020
         READ  (7),TRV,MF=E                                      A26537 69590020
         BAL   R10,LRDSIO          CHECK COMPLETION CODE         A26537 69640020
         BNE   SKFLUSH             DONT FLUSH TO EOT ON ERROR    A26537 69690020
         CLI   0(R5),LRDEOTCR      CHECK IF EOT RECEIVED         A26537 69740020
         BNE   RJENDR              NO READ TILL WE GET IT        A26537 69790020
SKFLUSH  EQU   *                                                 A26537 69840020
         MVC   LRDXMT12(4,R3),LCBDDECB   MOVE IN ECB TO BE POSTEDA26537 69890020
         X     R4,LRDDEC80        SET JCL BUFFER INDEX TO 80 OR 0A26537 69940020
         L     R1,LCBBUFER        GET QMPA ADDRESS               A26537 69990020
         LA    R15,QMCHN          SET POINTER TO DISK BUFFER     A26537 70040020
         STC   R4,LRDCDIND(R15)   INDICATE 1 OR 2 CARDS IN BUFF  A26537 70090020
         OI    12(R11),TDIRRJN    SET RJEND RECEIVED FLAG        A26537 70140020
         B     LRD1130                 QUEUE RJEND COMMAND       A40166 70190020
LRDWAIT  EQU   *                                                 A26537 70240020
         NI    12(R11),TDIROFF     TURN OFF RJEND RECEIVED       A26537 70290020
         L     R1,LCBDDECB        LOAD DISK ECB POINTER          A26537 70340020
         MVI   0(R1),LRDZERO       SET OFF COMP BIT IN ECB       A26537 70390020
         ST    R1,16(R3)          PUT POINTER IN BUFFER          A26537 70440020
         L     R15,LRDAADSP       GET POINTER TO DISPATCHER      A26537 70490020
         BALR  R14,R15                                           A26537 70540020
         B     LRDRTL             RETURN TO IHKABLST             A26537 70590020
         SPACE 4                                                   000C 70640020
*********************************************************************** 70690020
*                                                                       70740020
*                   EXECUTED INSTRUCTIONS                               70790020
*                                                                       70840020
*********************************************************************** 70890020
*                                                                       70940020
LRDMVJOB MVC   QMNAM(0),2(R3)      MOVE JOBNAME INTO QMPA          000C 70990020
LRDMVSEL MVC   TDIRDFTA+3(0),0(R10) TO MOVE POLLING CHARACTERS TO  000C 71040020
*                                  DFTRMLST IN TERMINAL DIRECTORY       71090020
         USING FASTAB,R1           SET BASE FOR FAST TABLE ENTRY        71140020
LRDCLFST XC    FASTALT(0),FASTALT  CLEAR END OF FAST TABLE ENTRY        71190020
         SPACE 2                                                        71240020
*                                                                       71290020
*********************************************************************** 71340020
*                                                                       71390020
*                   READ ONLY MODEL DCB FOR SYSIN DATA SETS             71440020
*                   IN REAL DCB, DDNAME AND BLKSIZE ARE FILLED IN       71490020
*                   FROM LINE SYSIN DD CARD                             71540020
*                                                                       71590020
*********************************************************************** 71640020
*                                                                       71690020
LRDSYSDD DCB   DSORG=PS,MACRF=(W),DEVD=DA,LRECL=80,RECFM=FB,           X71740020
               EXLST=LRDEXLST,SYNAD=LRDSYNAD,                          X71790020
               DDNAME=LRDAPR03                                          71840020
         SPACE 2                                                        71890020
*                                                                       71940020
*********************************************************************** 71990020
*                                                                       72040020
*                   CONSTANTS AND DSECTS                                72090020
*                                                                       72140020
*********************************************************************** 72190020
LRDSMFCD DC    C'SPACE=(80,(000000))'   SPACE PARM. FOR SMF COUN  19018 72240020
*                                                                       72290020
*                                  PARAMETER LIST FOR IHKCAVER          72340020
*                                  (COMMAND INTERPRETER)                72390020
LRDCDOPR DS    F                   CODE AND ADDRESS OF OPERATION        72440020
LRDCDBEG DS    F                   BEGINNING ADDRESS OF CARD IMAGE      72490020
LRDCTDIR DS    F                   TERMINAL DIRECTORY POINTER           72540020
LRDADUPK DC    V(IHKADUPK)         ADDRESS OF ADDRESS  OF UNPACK   000C 72590020
LRDSTKUN DC    X'10022D'           DLE,STX,ENQ-2770 STCKR UNLOAD  M6294 72640020
LRDLCBAD DC    A(IHKCDLCB)         ADDR. OF FIRST LCB            A21657 72690020
* THESE NEXT TWO ADDRESSES MUST BE CONTIGUOUS.                   A21657 72740020
LRDLINES DC    A(IHKCDNOL)         ADDR. OF NO. OF LINES         A21657 72790020
         DC    A(IHKCDLGL)         ADDR. OF LCB LENGTH           A21657 72840020
         EXTRN IHKCDLCB,IHKCDNOL,IHKCDLGL                        A21657 72890020
         SPACE 2                                                        72940020
DUMECB   DS    0F                                                A48402 72950021
         DC    X'40000000'                                       A48402 72960021
         SPACE 3                                                  19018 72990020
*   NOTE: ALL THE FOLLOWING CONSTANTS ARE DSECTED IN EITHER       19018 73040020
*        IHKABXMT, IHKABALC, OR IHKCHALC.  THEREFORE, IF ANY      19018 73090020
*        CHANGES ARE MADE, THESE DSECTS MUST ALSO BE CHANGED.     19018 73140020
         SPACE 1                                                  19018 73190020
IHKABXCN DS    0D                  START OF DSECT IN IHKABXMT     19018 73240020
*                                  PARAMETER LIST FOR IHKCBLDM (BLDMSG) 73290020
LRDBLDM  DC    X'80000000'         BUILD BUT DO NOT ENQUEUE MESSAGE     73340020
LRDBOFS  DC    X'0000'             MESSAGE OFFSET                       73390020
LRDBPMNO DS    C                   NUMBER OF MESSAGE PARAMETER CHARS.   73440020
LRDBPARM DS    CL24                MESSAGE PARAMETER CHARACTERS         73490020
         SPACE 2                                                        73540020
         CNOP  0,4                                                      73590020
*                                  PARAMETER LIST FOR IHKCCSCN (SCAN)   73640020
LRDSCAN  DC    H'0'                MAXIMUM SCAN LENGTH OR ZERO          73690020
LRDSBLNK DC    H'0'                TO SEARCH FOR FIRST NON-BLANK CHAR.  73740020
LRDSADDR DS    F                   STARTING ADDRESS FOR SCAN            73790020
LRDSSTOP DS    F                   STOPPING ADDRESS FOR SCAN            73840020
LRDSCHAR DC    C' '                TO STOP ON FIRST BLANK CHARACTER     73890020
         DC    C'),'               OR RIGHT PAREN OR COMMA         000C 73940020
         SPACE 2                                                        73990020
LRDSYSIN EQU   39                  SYSIN QUEUE NUMBER                   74040020
LRD2TTRS EQU   X'20'               TO ASSIGN TWO TTR'S                  74090020
LRDWR1AS EQU   X'11'               WRITE ONE RECORD AND ASSIGN ONE TTR  74140020
LRDWR1   EQU   X'01'               TO WRITE ONE RECORD                  74190020
LRD1CRD  EQU   80                  TO INDICATE ONE CARD IN JCL BUFFER   74240020
LRDNOCRD EQU   X'10'               INDICATE NO CARDS IN JCL BUFFER      74290020
TCBTIO   EQU   12                  DISPLACEMENT FOR TIOT ADDRESS        74340020
*                                  IN TCB                               74390020
DEBNMEXT EQU   16                  BYTE IN DEB FOR NUMBER OF EXTENTS    74440020
DEBUCBAD EQU   32                  DISPLACEMENT FOR UCB ADDRESS IN DEB  74490020
LRDNMEXT EQU   16                  MAXIMUM NUMBER OF EXTENTS            74540020
LRDUSREX EQU   16                  LINE ERROR USER EXIT DISPLACEMENT    74590020
LRDEOTCR EQU   X'37'               EOT                                  74640020
LRDENQ   EQU   X'2D'               ENQ                                  74690020
LRDSYNC  EQU   X'32'              CLOCK SYNC CHARACTER             000D 74740020
LRDBLANK EQU   C' '                TO PUT BLANKS IN A FIELD             74790020
LRDCHAR1 EQU   C'1'                TO INDICATE REMOTE MESSAGE           74840020
LRD7F    EQU   X'7F'               GOOD COMPLETION CODE FOR I/O         74890020
LRDRSTPL EQU   X'48'               COMPLETION CODE AFTER RESETPL        74940020
LRDRTPL  EQU   X'04'               DECB STATUS FLAG AFTER RESETPL       74990020
LRDTOFLG EQU   X'40'               TO INDICATE IN DECTYPE NO BTAM       75040020
*                                  ERROR MESSAGE FOR TIME OUT           75090020
LRDTOOFF EQU   X'BF'               TO RESET DECTYPE FOR BTAM ERROR      75140020
*                                  MESSAGE FOR TIME OUT                 75190020
LRDTMOUT EQU   X'01'               TO CHECK FOR TIME OUT IN DECSENS0    75240020
LRDRJSCD EQU   8                   RJSTART CODE FOR IHKCAVER            75290020
LRDLGNCD EQU   4                   LOGON CODE FOR IHKCAVER              75340020
LRDZERO  EQU   0                                                        75390020
LRDOFS13 EQU   13                  LINE ERROR                           75440020
LRDOFS20 EQU   20                  INVALID OPERATION - RJENDC OR RJENDF 75490020
LRD15CHR EQU   15                  15 MESSAGE PARAMETERS                75540020
LRDCDLST EQU   0                   RETURN CODE FOR IHKABLST             75590020
LRDCDEOT EQU   8                   RETURN CODE FOR IHKABEOT             75640020
LRDCDLWR EQU   12                  RETURN CODE FOR IHKABLWR             75690020
LRDCDNRC EQU   20                  RETURN CODE FOR RJENDC OR RJENDF     75740020
*                                  NOT QUEUED                           75790020
LRDSTSLT EQU   32                 RETURN CODE FOR LOPEN FUNCTION   000D 75840020
LRDCDSWL EQU   24                  RETURN CODE FOR SWITCHED LINE        75890020
LRDSW278 EQU   28                  RETURN TO IHKABLST TO SEND EOT       75940020
*                                  TO 2780 ON SWITCHED LINE             75990020
LRDXMT0  EQU   0                   INVALID JOBNAME                      76040020
LRDXMT4  EQU   4                   DUPLICATE JOBNAME                    76090020
LRDXMT8  EQU   8                   NO JOB CARD                          76140020
LRDXMT12 EQU   12                  SYSIN LIMIT EXCEEDED                 76190020
LRDXMT16 EQU   16                  MAX JOBS EXCEEDED                    76240020
LRDXMT20 EQU   20                  OUT OF SPACE - SYSIN                 76290020
LRDXMT24 EQU   24                  OUT OF SPACE - SYS1.SYSJOBQE         76340020
LRDXMT28 EQU   28                  I/O ERROR ON ASSIGN/START            76390020
LRDXMT32 EQU   32                  I/O ERROR ON Q MGR NOT A/S           76440020
LRDXMT36 EQU   36                  I/O ERROR ON ALLOCATE OR SYSIN       76490020
LRDXMT40 EQU   40                  INVALID TERMID                       76540020
LRDXMT44 EQU   44                  INVALID RJSTART OR LOGON             76590020
LRDXMT48 EQU   48                  INVALID OPERATION - RJENDC OR F      76640020
LRDXMT52 EQU   52                  RJSTART OR LOGON REQUIRED            76690020
LRDXMT56 EQU   56                  UNDEFINED KEYWORD               000C 76740020
LRDXMT60 EQU   60                  ILLEGAL KEYWORD PARAMETER       000C 76790020
LRDXMT64 EQU   64                  OFFSET 64 - LRDGENJF           19018 76840020
LRDXMT68 EQU   68                  OFFSET FOR IHKABXMT - LRDGNRF  19018 76890020
LRDXMT72 EQU   72                  OFFSET 72 - LRDWRTD            19018 76940020
ITBCHAR  EQU   X'40'               BIT SET FOR ITB MODE            000E 76990020
LRDQMCHN EQU   44                  DISPLACEMENT OF JECL-JCL BUFFER      77040020
LRDDSKBF EQU   48                  DISPLACEMENT FOR DISK BUFFER         77090020
LRDRELTD EQU   164                 DISPLACEMENT FOR RELATIVE TDIR PTR   77140020
LRDCDIND EQU   168                 DISPLACEMENT FOR CARD INDICATOR      77190020
LRDSCDHF EQU   200                 DISPLACEMENT FOR SECOND HALF OF BUF  77240020
LRDMSGBF EQU   373                 DISPLACEMENT FOR MESSAGE IN BUFFER   77290020
LRDJOBCH EQU   448                 DISPLACEMENT FOR NUMBER OF           77340020
*                                  CHARACTERS IN JOBNAME                77390020
LRDPOST  EQU   X'40'               TO POST THE ECB'S OF IHKCCPLM        77440020
LRDABCLS EQU   19                  TO CHECK FOR RJENDF WITH ABNORMAL    77490020
*                                  CENTRAL CLOSEDOWN MESSAGE            77540020
LRDNOMSG EQU   X'FF'               FOR RJENDF WITH NO MESSAGE           77590020
LRDSTRJE EQU   X'80'               TO TEST STOP RJE BIT                 77640020
LRDZONE  EQU   X'F0'               ZONE FOR NUMBERS               19018 77690020
LRDA     EQU   C'A'                LOWEST ALPHABETIC CHARACTER          77740020
LRDZ     EQU   C'Z'                HIGHEST ALPHABETIC CHARACTER         77790020
LRDCLRHI EQU   X'0F'               TO ZERO HIGH ORDER 4 BITS            77840020
LRDNINE  EQU   X'09'               TO CHECK NUMERIC FIELD               77890020
LRDINVCR EQU   X'E1'               TO CHECK FOR INVALID CHARACTER       77940020
LRD#     EQU   C'#'                VALID CHAR IN JOBNAME         A40161 77950020
LRD$     EQU   C'$'                VALID CHAR IN JOBNAME         A40161 77960020
LRD@     EQU   C'@'                VALID CHAR IN JOBNAME         A40161 77970020
         SPACE 2                                                        77990020
LRDENDDT DC    CL3'/*'             /* CARD FOR END OF SYSIN DATA        78040020
LRDDOTS  DC    CL3'..'             TO CHECK FOR JECL CARD               78090020
LRDRJNDF DC    C'RJENDF '                                               78140020
LRDRJSTT DC    C'RJSTART '                                              78190020
LRDLOGON DC    C'LOGON '                                                78240020
LRDCONT  DC    C'CONTINUE '                                             78290020
LRDJED   DC    C'JED '                                                  78340020
LRDLOGOF DC    C'LOGOFF '                                               78390020
LRDRJEND DC    C'RJEND '                                                78440020
LRDDOTRC DC    CL3'..'             TO BUILD RJENDC CARD                 78490020
LRDRJNDC DC    C'RJENDC '                                               78540020
LRDJOB   DC    C'JOB '                                                  78590020
LRDDATA  DC    C'DATA '            TO TEST FOR DD DATA CARD             78640020
LRDDD    DC    C'DD '              TO TEST FOR DD CARD                  78690020
LRDGNSYS DC    C'//SYSIN '         TO GENERATE DD * CARD                78740020
LRDCHAR  DS    C                   TO VERIFY ALPHABETIC CHARACTER       78790020
         SPACE                                                          78840020
IHKABCON DS    0F                  START OF DSECT IN IHKABALC           78890020
LRDSPENT DC    F'0'                TO TEST FOR SPECIAL ENTRY - IHKABRJF 78940020
LRDSLASH DC    CL3'//'             TO CHECK FOR JCL CARD AND            78990020
*                                  TO HELP BUILD SYSIN DD CARD          79040020
LRDTASK  DC    C'RJETASK '         JOB NAME FOR QMPA IF ONLY JECL       79090020
         SPACE 1                                                        79140020
LRDHEADR DC    X'01'               SOH                                  79190020
         DC    C'3310060'          HEADER FOR CPU                       79240020
         DC    X'26'               ETB                                  79290020
LRDDLSTX DC    X'1002'             DLE STX                              79340020
LRDSOHD  DC    X'01'               SOH                                  79390020
         DC    C'D'                MEANS DISCONTINUED INPUT             79440020
LRDSOHR  DC    X'01'               SOH                                  79490020
         DC    C'R'                MEANS RESUME NORMAL INPUT            79540020
LRDCDJAM DC    X'37022D'          EOT STX ENQ CHECK FOR CARD JAM A24704 79590020
         SPACE 1                                                        79640020
LRDCHARS DS    H                   NO. OF CHARS IN JOBNAME/DDNAME       79690020
LRD3     DC    H'3'                TO IGNORE ENQ AND INDEX AFTER        79740020
*                                  POLLING CHARACTER(S)                 79790020
LRD4     DC    H'4'                                                     79840020
LRD8     DC    H'8'                TO TEST LENGTH OF JOBNAME            79890020
LRD18    DC    H'18'                                                    79940020
LRD84    DC    H'84'               TO BACK UP BTAM BUFFER POINTER       79990020
LRD200   DC    H'200'              THRESHOLD FOR AVAIL Q MGR REC.       80040020
LRDUCBAD DS    F                   WILL HAVE ADDRESS OF UCB ADDRESS     80090020
LRDDEC80 DC    F'80'               TO INDEX JECL-JCL BUFFER             80140020
TDIROFF  EQU   X'BF'              FLAG TO TURN OFF RJEND RECEIVEDA26537 80190020
TDIRRJN  EQU   X'40'              SET ON RJEND RECEIVED FLAG     A26537 80240020
EIGHTY   EQU   LRDDEC80+2          HALFWORD OF 80                  000D 80290020
LRDSVBLK DS    F                   TO SAVE ADDR OF BLANK AFTER DDNAME   80340020
         SPACE                                                          80390020
LRDCCSCN DC    V(IHKCCSCN)         ENTRY POINT OF SCAN                  80440020
LRDAADSP DC    V(IHKAADSP)         ENTRY POINT OF DISPATCHER            80490020
LRDCAINT DC    V(IHKCAVER)         ENTRY POINT OF COMMAND INTERPRETER   80540020
LRDCBLDM DC    V(IHKCBLDM)         ENTRY POINT OF BUILD MESSAGE         80590020
LRDCDFMR DC    V(IHKCDFMR)         ENTRY POINT OF FAST TABLE MANAGER    80640020
LRDCDSCH DC    V(IHKCDSCH)         ENTRY POINT OF FAST TABLE SEARCH     80690020
LRDABALC DC    V(IHKABALC)         ENTRY POINT OF SYSIN ALLOCATION RTN  80740020
LRDABLST DC    V(IHKABLST)         ENTRY POINT OF LINE SCHEDULER        80790020
LRDABXMT DC    V(IHKABXMT)         ENTRY POINT OF ROUTINE WHICH         80840020
*                                  TRANSMITS AN ERROR MESSAGE           80890020
LRDABLRD DC    A(IHKABLRD+2)       TO SET BASE REGISTER                 80940020
LRDCDFLN DC    A(IHKCDFLN)         ADDRESS OF LENGTH OF FAST TABLE      80990020
LRDCDSOC DC    A(IHKCDSOC)         RJETABLE ADDRESS                     81040020
LRDCDTDR DC    A(IHKCDTDR)         START OF TERMINAL DIRECTORY ENTRIES  81090020
LRDZZAVT DC    A(IHKCACOM)         ADDRESS OF AVT CONSTANTS             81140020
         SPACE 2                                                        81190020
LRDEXLST DC    X'88'                                                    81240020
         DC    AL3(LRDOUTSP)       OUT OF SPACE ROUTINE                 81290020
         CNOP  0,8                                                19018 81340020
LRDUPDEC DS    2F                  FOR UNPACKED DECIMAL           19018 81390020
LRDDECNO DS    2F                  FOR PACKED DECIMAL             19018 81440020
OTHRBASE DC    A(LRDNOTCM)        BASE FOR FOR DD CARD PROCESSINGA26537 81490020
         DROP  12                                                       81540020
SUBASE   EQU   12                                                A26537 81590020
         USING *,SUBASE                                          A26537 81640020
LRDNOTCM DS    0H                                                A26537 81690020
         ST    R10,LRDSSTO         STORE IN PARAMETER LIST       A26537 81740020
         LA    R10,2(R3)           GET STARTING ADDRESS FOR SCAN A26537 81790020
         ST    R10,LRDSADD         STORE IN PARAMETER LIST       A26537 81840020
         MVI   LRDSBLN+1,LRDFSTB   TO SEARCH FOR FIRST BLANK CHARA26537 81890020
         BAL   R9,LRDSCJC          SCAN TO BLANK CHARACTER       A26537 81940020
         ST    R1,LRDSADD          STORE STARTING ADDRESS FOR    A26537 81990020
*                                  SCAN                          A26537 82040020
         L     R14,LRDSVBL        LOAD ADDRESS OF PTR TO BLANK   A26537 82090020
         ST    R1,0(R14)          PUT ADDRESS IN THAT AREA       A26537 82140020
         SR    R1,R10              SUBTRACT STARTING ADDRESS OF  A26537 82190020
*                                  NAME                          A26537 82240020
*                                  FROM END TO GET NUMBER OF     A26537 82290020
*                                  CHARACTERS                    A26537 82340020
         STH   R1,LCBCHARS         SAVE NUMBER OF CHARACTERS     A22268 82390020
         MVI   LRDSBLN+1,X'00'    SEARCH FOR NON BLANK CHARACTER A26537 82440020
         BAL   R9,LRDSCJC          SCAN TO NON-BLANK CHARACTER   A26537 82490020
         CLC   0(4,R1),LRDJO       TEST FOR JOB CARD             A26537 82540020
         LA    R14,FOURT          SET FOR ENTRY TO BRANCH TBL    A26537 82590020
         BE    BRNTABL            BRANCH IF FOUND                A26537 82640020
         TM    TDIRSWCH+1,TDIRJEDN TEST JED SWITCH               A26537 82690020
         LA    R14,EIGHTT         SET FOR ENTRY TO BRANCH TBL    A26537 82740020
         BO    BRNTABL            BRANCH IF ON                   A26537 82790020
         TM    TDIRSWCH+2,TDIRJCLN TEST JCL SWITCH               A26537 82840020
         LA    R14,TWELV          SET FOR ENTRY TO BRANCH TABL   A26537 82890020
         BC    14,BRNTABL         IF NOT ON MISSING JOB CARD     A26537 82940020
         CLC   0(3,R1),LRDD        TEST FOR DD CARD              A26537 82990020
         LA    R14,SIXTEEH        SET FOR ENTRY TO BRANCH TABL   A26537 83040020
         BC    7,BRNTABL          IF NOT DD  CARD                A26537 83090020
         LA    R10,2(R1)           GET ADDRESS OF BLANK AFTER DD A26537 83140020
         ST    R10,LRDSADD         STORE AS STARTING ADDRESS FOR A26537 83190020
*                                  SCAN                          A26537 83240020
         BAL   R9,LRDSCJC          SCAN TO NON-BLANK CHARACTER   A26537 83290020
         SR    R9,R9               CLEAR REGISTER 9              A26537 83340020
         STH   R9,LCBPARM3+2       PUT 0 IN LCBPARM3 FOR ALC     A26537 83390020
         CLC   0(2,R1),LRDASTB     CHECK FOR BLANK AFTER DD *    A26537 83440020
         LA    R14,TWENT          SET FOR ENTRY TO BRANCH TABL   A26537 83490020
         BE    BRNTABL            YES IGNORE DCB PARAM ROUNTINE  A26537 83540020
         CLC   0(5,R1),LRDDAT      CHECK FOR BLANK AFTER DD DATA A26537 83590020
         LA    R14,THIRTY36       SET ENTRY TO BRANCH TABLE      A26537 83640020
         BE    BRNTABL             IF THERE IGNORE DCB PARAM ROUTA26537 83690020
         CLC  0(2,R1),LRDASTCM     CHECK FOR COMMA AFTER DD *    A26537 83740020
         BE    LRDACOMA            BRANCH AROUND CHECK FOR DD    A26537 83790020
*                                  DATA                          A26537 83840020
         CLC   0(5,R1),LRDATACM    CHECK FOR COMMA AFTER DD DATA A26537 83890020
         LA    R14,SIXTEEH        SET FOR ENTRY TO BRANCH TABL   A26537 83940020
         BNE   BRNTABL            IF NOT DD DATA OR * BRANCH     A26537 83990020
         OI    TDIRSWCH,TDIRDDDN   TURN ON DD DATA SWITCH        A26537 84040020
         LA    R1,5(R1)            GET ADDRESS OF BYTE AFTER DATAA26537 84090020
         B     LRDONECM                                          A26537 84140020
WORK     DS    D                                                 A26537 84190020
LRDPACK  PACK  WORK(8),0(0,R10)                                  A26537 84240020
LRDACOMA OI    TDIRSWCH,TDIRDDAN   TURN ON DD * SWITCH           A26537 84290020
         LA    R1,2(R1)            GET ADDRESS OF BYTE AFTER DD *A26537 84340020
LRDONECM CLC   0(4,R1),LRDCBPRM    CHECK FOR DCB=                A26537 84390020
         BNE   LRDUNDEF            IF NOT THERE GO TO ERROR      A26537 84440020
*                                  ROUTINE                       A26537 84490020
         LA    R1,4(R1)            UPDATE COUNTER TO SUBPARAMETERA26537 84540020
         CLI   0(R1),C'('          CHECK FOR ( BEFORE            A26537 84590020
*                                  SUBPARAMETER                  A26537 84640020
         BNE   LRDBUFCK            IF NOT THERE BRANCH           A26537 84690020
         OI    LCBPARM3,TIOSDSP2   SET PARENTHESIS SWITCH        A26537 84740020
         LA    R1,1(R1)            IF THERE IGNORE IT            A26537 84790020
         BAL   R9,LRDTOCOM         CHECK FOR MULTIPLE COMMAS     A26537 84840020
LRDBUFCK CLC   0(6,R1),LRDBUFNO    CHECK FOR BUFNO PARAMETER     A26537 84890020
         BNE   LRDBLKSI            IF NOT THERE BRANCH           A26537 84940020
         MVI   LRDSBLN+1,X'03'     SET UP PARAMETER FOR SCAN     A26537 84990020
         ST    R1,LRDSADD          STARTING POINT FOR SCAN       A26537 85040020
         LA    R1,20(R1)           STOPPING POINT FOR SCAN       A26537 85090020
         ST    R1,LRDSSTO          STORE IN PARAMETER LIST       A26537 85140020
         BAL   R9,LRDSCJC          SCAN TO BLANK, COMMA OR R     A26537 85190020
*                                  PARENTHESIS                   A26537 85240020
         CLI   0(R1),C','          IS IT A COMMA?                A26537 85290020
         BNE   LRDFRMAT            IF NOT BLKSIZE WAS NOT        A26537 85340020
*                                  SPECIFIED                     A26537 85390020
         LA    R1,1(R1)            GO TO ADDRESS AFTER COMMA     A26537 85440020
         BAL   R9,LRDTOCOM         CHECK FOR MULTIPLE COMMAS     A26537 85490020
LRDBLKSI CLC   0(8,R1),LRDBLOCK    CHECK FOR BLKSIZE PARAMETER   A26537 85540020
         BNE   LRDUNDEF            IF NOT GO TO ERROR ROUTINE    A26537 85590020
         LA    R1,8(R1)            GET ADDRESS OF BLKSIZE PARAM  A26537 85640020
         ST    R1,LRDSADD          STORE STARTING POINT FOR SCAN A26537 85690020
         LR    R10,R1              SAVE ADDRESS OF BLKSIZE PARAM A26537 85740020
         LA    R1,10(R1)           SET STOPPING POINT FOR SCAN   A26537 85790020
         ST    R1,LRDSSTO          STORE IT IN PARAMETER LIST    A26537 85840020
         MVI   LRDSBLN+1,X'03'  NUMBER OF CHARACTERS SCANNED FOR A26537 85890020
         BAL   R9,LRDSCJC          SCAN TO BLANK,COMMA, OR )     A26537 85940020
         LR    R9,R1               SAVE ADDRESS OF DELIMETER     A26537 85990020
         SR    R1,R10              DETERMINE LENGTH OF PARAMETER A26537 86040020
         LTR   R1,R1               IS BLKSIZE = BLANK ?          A26537 86090020
         BZ    LRDINVAL            IF SO, LET HIM KNOW           A26537 86140020
         LR    R14,R1              GET LENGTH OF PARAM FOR BCT   A32862 86190020
LRDHARVD TM    0(R10),X'F0'        IS THIS BYTE NUMERIC ?        A32862 86240020
         BNO   LRDINVAL            NO? THST'S A BADIE            A32862 86290020
         LA    R10,1(R10)          POINT TO THE NEXT BYTE AND    A32862 86340020
         BCT   R14,LRDHARVD        CHECK IT THE SAME WAY         A32862 86390020
         SR    R10,R1              RESTORE POINTER TO BLKSIZE    A32862 86440020
         BCTR  R1,0                                              A27468 96160020
         EX    R1,LRDPACK          PACK THE BLKSIZE WITH THEM    A26537 96160120
         CVB   R1,WORK             CONVERT BLKSIZE TO BINARY     A26537 96160220
         LTR   R1,R1               CHECK FOR BLKSIZE OF ZERO     A26537 96160320
         BC    12,LRDINVAL         IF SO GO TO ERROR ROUTINE     A26537 96160420
         LA    R14,400             CHECK TO SEE THAT BLKSIZE IS  A26537 96160520
*                                  NOT                           A26537 96160620
         CR    R1,R14              GREATER THAN 400              A26537 96160720
         BH    LRDFORMT            IF SO, USE BLKSIZE IN PROC    A26537 96160820
         SR    R14,R14             CLEAR REG 14 FOR DIVIDE       A26537 96160920
         LR    R15,R1              PUT PARAM IN REG 15 FOR DIVIDEA26537 96161020
         LA    R1,80               CHECK TO SEE THAT THE BLKSIZE A26537 96161120
*                                  IS                            A26537 96161220
         DR    R14,R1              A MULTIPLE OF 80 BY DIVIDING  A26537 96161320
*                                  AND                           A26537 96161420
         LTR   R14,R14             TESTING FOR REMAINDER         A26537 96161520
         BC    7,LRDINVAL          IF NOT GO TO ERROR ROUTINE    A26537 96161620
         MH    R15,EIGHTTY         MULTIPLY TO GET PARAMETER BACKA26537 96161720
         STH   R15,LCBPARM3+2      STORE BLKSIZE FOR ALLOCATION  A26537 96161820
LRDFORMT LR    R1,R9               CHECK FORMAT OF CARD          A26537 96161920
LRDFRMAT CLI   0(R1),C' '          IS IT A BLANK ?               A26537 96162020
         BE    LRDSWHON            IF SO, SEE IF PAREN SWITCH IS A26537 96162120
*                                  ON                            A26537 96162220
         CLI   0(R1),C','          IS IT A COMMA ?               A26537 96162320
         BNE   LRDSWHOF            IF NOT, SEE IF PAREN SWITCH ONA26537 96162420
         BAL   R9,LRDTOCOM         CHECK FOR MULTIPLE COMMAS     A26537 96162520
LRDPARAM CLC   0(6,R1),LRDBUFNO    CHECK FOR BUFNO PARAMETER     A26537 96162620
         BNE   LRDUNDEF            IF NO, GO TO ERROR ROUTINE    A26537 96162720
         ST    R1,LRDSADD          STARTING POINT FOR SCAN       A26537 96162820
         LA    R1,10(R1)           GET STOPPING POINT FOR SCAN   A26537 96162920
         ST    R1,LRDSSTO          STORE IN PARAMETER LIST       A26537 96163020
         MVI   LRDSBLN+1,X'02'     NUMBER OF CHARACTERS SCANNED  A26537 96163120
         BAL   R9,LRDSCJC          SCAN FOR BLANK OR RIGHT PAREN A26537 96163220
         CLI   0(R1),C' '          IS IT A BLANK ?               A26537 96163320
         BE    LRDSWHON            IF SO, SEE IF PAREN SWITCH IS A26537 96163420
*                                  ON                            A26537 96163520
LRDSWHOF TM    LCBPARM3,TIOSDSP2   IS PAREN SWITCH ON ?          A26537 96163620
         BC    12,LRDUNDEF         IF NOT SEND ERROR MESSAGE     A26537 96163720
         B     LRDOFFSW                                          A26537 96163820
LRDSWHON TM    LCBPARM3,TIOSDSP2   IS PAREN SWITCH ON ?          A26537 96163920
         BO    LRDUNDEF            IF SO, SEND ERROR MESSAGE     A26537 96164020
LRDOFFSW NI    LCBPARM3,X'00'      TURN OFF PAREN SWTCH          A26537 96164120
         LA    R14,TWENT28        SET FOR ENTRY TO BRANCH TABL   A26537 96164220
         B     BRNTABL            RETURN TO MAIN ROUNTINE        A26537 96164320
LRDTOCOM CLI   0(R1),C','          CHECK FOR MULTIPLE COMMAS     A26537 96164420
         BCR    7,R9               IF NOT A COMMA BRANCH         A26537 96164520
         LA    R1,1(R1)            IF IT IS A COMMA, IGNORE IT   A26537 96164620
         B     LRDTOCOM            CHECK FOR MORE MULTIPLE COMMASA26537 96164720
LRDUNDEF LA    R0,LRDXM56         GET PARAMTER FOR XMT           A26537 96164820
         LA    R14,THIRTY32       SET FOR ENTRY TO BRANCH TABL   A26537 96164920
         B     BRNTABL            TRANSMIT ERROR MESSAGE         A26537 96165020
LRDINVAL LA    R0,LRDXM60         GET PARAMETER FOR XNT          A26537 96165120
         LA    R14,THIRTY32       SET FOR ENTRY TO BRANCH TABL   A26537 96165220
         B     BRNTABL            TRANSMIT ERROR MESSAGE         A26537 96165320
LRDSCJC  LA    R1,LRDSCA           GET ADDRESS OF PARAMETER LIST A26537 96165420
         L     R15,LRDCCSC         GET ADDRESS OF SCAN ROUTINE   A26537 96165520
         BALR  R14,R15             CALL SCAN TO FIND CHARACTER   A26537 96165620
         LTR   R15,R15             TEST RETURN CODE              A26537 96165720
         BCR   7,R9                IF FOUND, RETURN              A26537 96165820
         TM    TDIRSWCH+2,TDIRJCLN IS JCL SWITCH ON              A26537 96165920
         LA    R14,TWELV          SET FOR ENTRY TO BRANCH TABL   A26537 96166020
         BZ    BRNTABL            NO,STATEMENT INVALID           A26537 96166120
         LA    R14,SIXTEEH        SET FOR ENTRY TO BRANCH TABL   A26537 96166220
         B     BRNTABL            IF ON IT'S OK                  A26537 96166320
BRNTABL  EQU   *                                                 A26537 96166420
         LR    R15,R12            SET NEW BASE                   A26537 96166520
         DROP  12                                                A26537 96166620
         USING LRDNOTCM,R15                                      A26537 96166720
         L     R12,LRDBASE        SET BASE FOR MAIN ROUTINE      A26537 96166820
         B     *+4(14)            BRANCH INTO BRANCH TABLE       A26537 96166920
         DROP  15                                                A26537 96167020
         USING IHKABLRD+2,R12                                    A26537 96167120
         B     LRDJOBCD                                          A26537 96167220
         B     LRDJEDSW                                          A26537 96167320
         B     LRDNOJOB                                          A26537 96167420
         B     LRDJCLBF                                          A26537 96167520
         B     LRDDDAST                                          A26537 96167620
         B     LRDDDCRD                                          A26537 96167720
         B     LRDCLXMT                                          A26537 96167820
         B     LRDDDATA                                          A25637 96167920
LRDCCSC  DC    V(IHKCCSCN)        ENTRY OF SCAN ROUTINE          A26537 96168020
LRDSCA   DC    H'0'                                              A26537 96168120
LRDSBLN  DC    H'0'                                              A26537 96168220
LRDSADD  DC    F'0'               STARTING ADDRESS OF SCAN       A26537 96168320
LRDSSTO  DC    F'0'               STOPPING ADDRESS OF SCAN       A26537 96168420
LRDCHA   DC    C' '                                              A26537 96168520
         DC    C'),'               ON RIGHT PAREN OR COMMA       A26537 96168620
LRDJO    DC    C'JOB '                                           A26537 96168720
LRDD     DC    C'DD '             TEST FOR DD CARD               A26537 96168820
LRDASTB  DC    C'* '              TEST FOR * BLANK               A26537 96168920
LRDDAT   DC    C'DATA '           TEST FOR DD DATA CARD          A26537 96169020
LRDASTCM DC    C'*,'                                             A26537 96169120
LRDATACM DC    C'DATA,'                                          A26537 96169220
LRDCBPRM DC    C'DCB='                                           A26537 96169320
LRDBUFNO DC    C'BUFNO='                                         A26537 96169420
LRDBLOCK DC    C'BLKSIZE='                                       A26537 96169520
EIGHTTY  DC    H'0080'                                           A26537 96169620
LRDXM56  EQU   56                 CODE FOR IMPROPER DD CARD      A26537 96169720
LRDXM60  EQU   60                 CODE FOR IMPROPER DD CARD      A26537 96169820
LRDSVBL  DC    A(LRDSVBLK)                                       A26537 96169920
LRDBASE  DC    A(IHKABLRD+2)      BASE FOR MAIN ROUTINE          A26537 96170020
FOURT    EQU   0                  INDEX INTO BRANCH TABLE        A26537 96170120
EIGHTT   EQU   4                  INDEX INTO BRANCH TABLE        A26537 96170220
TWELV    EQU   8                  INDEX INTO BRANCH TABLE        A26537 96170320
SIXTEEH  EQU   12                 INDEX INTO BRANCH TABLE        A26537 96170420
TWENT    EQU   16                 INDEX INTO BRANCH TABLE        A26537 96170520
TWENT28  EQU   20                 INDEX INTO BRANCH TABLE        A26537 96170620
THIRTY32 EQU   24                 INDEX INTO BRANCH TABLE        A26537 96170720
THIRTY36 EQU   28                 INDEX TO BRANCH TABLE          A26537 96170820
LRDFSTB  EQU   X'01'              SCAN FOR FIRST BLANK CHARACTER A26537 96170920
         EJECT                                                          96180018
         IEFQMNGR                  QUEUE MANAGER PARAMETER AREA         96240018
QMPCA    DS    CL4                 BUFFER ADDRESS OR TTR FROM ASSIGN    96300018
QMPEX    DS    CL4                 TTR FOR WRITE                        96360018
QMCHN    DS    CL4                 TTR FOR NEXT WRITE                   96420018
         EJECT                                                          96480018
LRDQMRES DSECT                                                          96540018
         IEFQMRES                  QUEUE MANAGER RESIDENT AREA          96600018
         EJECT                                                          96660018
         IECTDECB                                                       96720018
         EJECT                                                          96780018
         DCBD   DSORG=(BS,BX),DEVD=(DA,BS)                         000E 96840019
         EJECT                                                          96900018
LRDTIOT1 DSECT                                                          96960018
         IEFTIOT1                                                       97020018
         EJECT                                                          97080018
LRDCVT   DSECT                                                          97140018
         CVT                                                            97200018
         IHKDSECT TDIR                                                  97260018
TDIRNQJM EQU   X'CF'               TURN OFF ENQUEUE JOBS AND ENQUEUE    97320018
*                                  MESSAGES BITS                        97380018
TDIRSYSF EQU   X'3F'               TURN OFF DD DATA AND DD * SWITCHES   97440018
TDIRSYSN EQU   X'C0'               TEST DD DATA AND DD * SWITCHES       97500018
TDIRRJLF EQU   X'E7'               TURN OFF RJSTART AND LOGON SWITCHES  97560018
TDIRRJLG EQU   X'18'               TEST RJSTART AND LOGON SWITCHES      97620018
TDIRDARF EQU   X'3E'               TURN OFF DD DATA, DD *, NO RJENDF    97680018
TDIRJDIP EQU   X'FA'               TURN OFF JED AND DISCONTINUED INPUT  97740018
         IHKDSECT ,,FASTAB                                              97800018
         IHKDSECT ,,,,,AVT                                              97860018
         IHKDSECT ,,,,LCB                                               97920018
LCBSWOFF EQU   X'00'               TO TURN OFF LCB SWITCHES             97980018
LCBNQBIT EQU   X'80'               INDICATE CARDS TO ENQUEUE            98040018
LCBNQOFF EQU   X'7F'               INDICATE NO CARDS TO ENQUEUE         98100018
LCBERRSW EQU   X'40'               INDICATE RETURN 8 TO IHKABLST        98160018
LCBSTRJE EQU   X'20'               INDICATE RETURN OF ZERO TO LST       98220018
LCBRJNDF EQU   X'10'               INDICATE RJENDF GENERATED            98280018
LCBLST28 EQU   X'08'               INDICATE RETURN 28 TO IHKABLST       98340018
         END                                                            98400018
