NDJ7   TITLE    'JOB END PROCESSOR - IHKCHNDJ '                         00100017
IHKCHNDJ CSECT                                                          00200017
*                                                                A32841 00250020
         SPACE 1                                                        00300017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   00400017
*                                                                   *   00500017
*                J O B   E N D   R O U T I N E                      *   00600017
*                                                                   *   00700017
*                                                                   *   00800017
* F U N C T I O N - -                                               *   00900017
*                                                                   *   01000017
*   THIS ROUTINE HANDLES THE RJE PROCESSING REQUIRED AT COMPLETION  *   01100017
*   OF REMOTELY SUBMITTED JOBS.  THIS PROCESSING INVOLVES --        *   01200017
*                                                                   *   01300017
*   1.  MARKING THE JOB COMPLETE.                                   *   01400017
*                                                                   *   01500017
*         BIT 0 OF THE FAST TABLE DELIVERY STATUS BYTE (FASTDSB)    *   01600017
*           IS SET ON.                                              *   01700017
*                                                                   *   01800017
*   2.  HANDLING THE DELIVERY OF IMMEDIATE OUTPUT                   *   01900017
*                                                                   *   02000017
*       A.  IF THE USER WHO SUBMITTED THE JOB IS OR WAS LAST LOGGED *   02100017
*             ON AT AN ACTIVE WORK STATION, SYSDEQ WILL QUEUE OUTPUT. * 02200017
*       B.  IF THE USER WAS LAST LOGGED ON AT A WORK STATION WHICH  *   02300017
*             IS CURRENTLY INACTIVE, THE JOB OUTPUT IS NOT PLACED   *   02400017
*             ON THE OUTPUT QUEUE BUT IS MARKED AS BYPASSED OUTPUT. *   02500017
*             THIS INDICATION IS MADE IN THE USER AND TERMINAL      *   02600017
*             DIRECTORIES AND THE FAST TABLE ENTRY.  IN ADDITION,   *   02700017
*             IF THE WORK STATION IS CONNECTED VIA A SWITCHED LINE, *   02800017
*             A MESSAGE IS SENT TO THE CENTRAL OPERATOR WHO    *        02900017
*             CAN INFORM THE WORK STATION THAT THERE IS OUTPUT      *   03000017
*             AVAILABLE FOR HIM AT HIS NEXT START UP.                 * 03100017
*                                                                   *   03200017
*   3.  HANDLING NOTIFY REQUESTS FOR DEFERRED OUTPUT.               *   03300017
*                                                                   *   03400017
*       A.  IF THE USER WHO SUBMITTED THE JOB IS OR WAS LAST LOGGED *   03500017
*             ON AT AN ACTIVE WORK STATION AND REQUESTED NOTIFICA-  *   03600017
*             TION OF JOB COMPLETION, IHKBLDM IS CALLED TO BUILD    *   03700017
*             THE NOTIFY MESSAGE AN PLACE IT ON THE OUTPUT QUEUE.   *   03800017
*       B.  IF THE USER WHO SUBMITTED THE JOB WAS LAST LOGGED ON AT *   03900017
*             A WORK STATION CURRENTLY INACTIVE BUT REQUESTED NOTI- *   04000017
*             FICATION OF JOB COMPLETION, PENDING NOTIFY INDICATIONS*   04100017
*             ARE KEDT IN THE USER AND TERMINAL DIRECTORIES AND     *   04200017
*             THE FAST TABLE ENTRY.  THE USER IS NOTIFIED AT HIS    *   04300017
*             PRESENT WORK STATION AT ITS NEXT STARTUP OR IF HE LOGS*   04400017
*             ON AT ANOTHER WORK STATION -- WHICH EVER EVENT OCCURS *   04500017
*             FIRST.  IN ADDITION, IF THE WORK STATION IS CONNECTED *   04600017
*             VIA A SWITCHED LINE, A MESSAGE IS SENT TO THE CENTRAL *   04700017
*             OPERATOR ALERTING HIM OFF THE PENDING NOTIFY.         *   04800017
         EJECT                                                          04900017
*       C.  IF THE USER WHO SUBMITTED THE JOB REQUESTED NOTIFICATION*   05000017
*             OF AN ALTERNATE RECIPIENT, AND THE ALTERNATE IS       *   05100017
*             CURRENTLY LOGGED ON, HE IS NOTIFIED OF JOB COMPLETION-*   05200017
*             IF HE IS NOT CURRENTLY LOGGED ON, HE IS NOTIFIED AT   *   05300017
*             AT THE BEGINNING OF HIS NEXT SESSION.                 *   05400017
*                                                                   *   05500017
*   4.  HANDLING OF SPECIFIC ALERT REQUESTS FOR SOURCE AND          *   05600017
*         ALTERNATE.                                                *   05700017
*                                                                   *   05800017
*       A.  IF THERE IS A SPECIFIC ALERT PENDING FOR SOURCE (BIT 5  *   05900017
*             ON IN FASTJIB) AND MESSAGES MAY BE SENT TO THE SOURCE *   06000017
*             WORK STATION, HE IS NOTIFIED OF JOB COMPLETION.       *   06100017
*       B.  IF THERE IS A SPECIFIC ALERT PENDING FOR ALTERNATE (BIT *   06200017
*             6 ON IN FASTJIB) AND MESSAGES MAY BE SENT TO THE      *   06300017
*             ALTERNATE WORK STATION, HE IS NOTIFIED OF JOB         *   06400017
*             COMPLETION.                                           *   06500017
*                                                                   *   06600017
*   5.  HANDLING OF MINOR ALERT REQUESTS FOR SOURCE.                *   06700017
*                                                                   *   06800017
*       A.  IF THERE IS A MINOR ALERT REQUEST PENDING FOR SOURCE    *   06900017
*           (BIT 2 ON IN UDIRSTAT) AND MESSAGES MAY BE SENT TO THE  *   07000017
*           SOURCE WORK STATION, HE IS NOTIFIED OF JOB COMPLETION.  *   07100017
*                                                                   *   07200017
*   6.  HANDLING OF MAJOR ALERT REQUESTS FOR SOURCE AND ALTERNATE.  *   07300017
*                                                                   *   07400017
*       A.  IF THERE IS A MAJOR ALERT REQUEST PENDING FOR SOURCE    *   07500017
*             (BIT 1 ON IN UDIRSTAT) AND MESSAGES MAY BE SENT TO    *   07600017
*             THE SOURCE WORK STATION, HE IS NOTIFIED OF JOB        *   07700017
*             COMPLETION.                                           *   07800017
*       B.  IF THERE IS A MAJOR ALERT REQUEST PENDING FOR ALTERNATE *   07900017
*             (BIT 1 ON IN UDIRSTAT) AND MESSAGES MAY BE SENT TO    *   08000017
*             THE ALTERNATE WORK STATION, HE IS NOTIFIED OF JOB     *   08100017
*             COMPLETION.                                           *   08200017
*                                                                   *   08300017
*   7.  REMEMBERING SOURCE RECEIVED NOTIFY OR SPECIFIC ALERT.       *   08400017
*                                                                   *   08500017
*       A.  IF THE SOURCE WAS NOTIFIED DUE TO A NOTIFY OR SPECIFIC  *   08600017
*             ALERT REQUEST,BIT 4 OF FASTDSB IS SET ON.                 08700017
*                                                                   *   08800017
*   8.  REMEMBERING ALTERNATE RECEIVED NOTIFY OR SPECIFIC ALERT.    *   08900017
*                                                                   *   09000017
*       A.  IF THE ALTERNATE WAS NOTIFIED DUE TO A NOTIFY OR        *   09100017
*             SPECIFY ALERT REQUEST, BIT 5 OF FASTDSB IS SET ON.    *   09200017
*                                                                   *   09300017
*   9.  HANDLING NOTIFICATION OF ALTERNATE NOT IN SYSTEM.           *   09400017
*                                                                   *   09500017
*       A.  IF THE SOURCE REQUESTED NOTIFICATION OF AN ALTERNATE    *   09600017
*             WHO WAS REMOVED FROM THE USER DIRECTORY AFTER JOB     *   09700017
*             RECEIPT BUT PRIOR TO JOB COMPLETION, THE NOTIFY       *   09800017
*             REQUEST IS IGNORED.                                   *   09900017
         EJECT                                                          10000017
* E N T R Y   P O I N T S - -                                       *   10100017
*                                                                   *   10200017
*   IHKCHNDJ IS THE ONLY ENTRY POINT.  THE CALLING SEQUENCE IS -    *   10300017
*                                                                   *   10400017
*        LA    13,SAVE AREA                                         *   10500017
*        LOAD  EP=IHKCHNDJ                                          *   10600017
*        LR    15,0                                                 *   10700017
*        LA    1,PARAMETER LIST                                     *   10800017
*        BALR  14,15                                                *   10900017
*                                                                   *   11000017
*                                                                   *   11100017
* T A B L E S / W O R K   A R E A S - -                             *   11200017
*                                                                   *   11300017
*       FAST TABLE                                                  *   11400017
*       USER DIRECTORY                                              *   11500017
*       TERMINAL DIRECTORY                                          *   11600017
*       JED TABLE                                                   *   11700017
*       ADDRESS VECTOR TABLE                                        *   11800017
*                                                                   *   11900017
*                                                                   *   12000017
* I N P U T - -                                                     *   12100017
*                                                                   *   12200017
**      STANDARD SUBROUTINE LINKAGES PREVAIL AT ENTRY FOR THIS      *   12300017
*       ROUTINE.  REGISTER ONE MUST CONTAIN THE ADDRESS OF THE      *   12400017
*       FOLLOWING FOUR WORD PARAMETER LIST ALIGNED ON A FULL-WORD   *   12500017
*       BOUNDARY - -                                                *   12600017
*                                                                   *   12700017
*             1. ADDRESS OF JED TABLE ENTRY.                        *   12800017
*             2. ADDRESS OF TERMINAL DIRECTORY ENTRY.               *   12900017
*             3. ADDRESS OF FAST TABLE ENTRY.                       *   13000017
*             4. ADDRESS OF ADDRESS VECTOR TABLE.                   *   13100017
*                                                                   *   13200017
*                                                                   *   13300017
* O U T P U T - -                                                   *   13400017
*                                                                   *   13500017
*                                                                   *   13600017
*       IHK009I NOTIFY JOBNAME USERID (USER TEXT)                   *   13700017
*             NOTIFICATION OF JOB COMPLETION WITH NORMAL TERMINATION*   13800017
*                                                                   *   13900017
*       IHK010I ABEND NOTIFY JOBNAME USERID (USER TEXT)             *   14000017
*             INDICATION OF JOB COMPLETION WITH ABNORMAL TERMINATION*   14100017
*                                                                   *   14200017
*       IHK037I INFORM INACTIVE WORK STATION JOBNAME USERID TERMID O*   14300017
*             INDICATE TO CENTRAL OPERATOR THAT DELIVERY OF BYPASSED*   14400017
*             - OUTPUT WAITING ON SWITCHED WORK STATION STARTUP.    *   14500017
*                                                                   *   14600017
*       IHK037I INFORM INACTIVE WORK STATION JOBNAME USERID TERMID N*   14700017
*             INDICATE TO CENTRAL OPERATOR THAT DELIVERY OF PENDING *   14800017
*             - NOTIFY WAITING ON SWITCHED WORK STATION STARTUP.    *   14900017
         EJECT                                                          15000017
* E X T E R N A L   R O U T I N E S - -                             *   15100017
*                                                                   *   15200017
*       IHKCCSUD - USED TO SEARCH THE USER DIRECTORY.               *   15300017
*       IHKCBSTD - USED TO SEARCH THE TERMINAL DIRECTORY.           *   15400017
*       IHKCBLDM - USED TO SEND MESSAGES TO CENTRAL OPERATOR AND    *   15500017
*                  WORK STATIONS.                                   *   15600017
*                                                                   *   15700017
*                                                                   *   15800017
*                                                                   *   15900017
* E X I T S - -                                                     *   16000017
*                                                                   *   16100017
*   NORMAL-                                                         *   16200017
*       ONE OF THE FOLLOWING RETURN CODES :                             16300017
*             ZERO - INDICATES JOB OUTPUT SHOULD BE QUEUED.             16400017
*             FOUR - INDICATES JOB OUTPUT SHOULD NOT BE QUEUED.         16500017
*   ERROR-                                                          *   16600017
*       N/A                                                         *   16700017
*                                                                   *   16800017
*                                                                   *   16900017
* A T T R I B U T E S - -                                           *   17000017
*                                                                   *   17100017
*       SERIALLY REUSABLE, NON-RESIDENT.                            *   17200017
*                                                                   *   17300017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   17400017
         EJECT                                                          17500017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   17600017
*                                                                   *   17700017
*              SYMBOLIC REGISTERS                                       17800017
         SPACE 1                                                        17900017
REG0     EQU   0              WORK REGISTER                             18000017
PAREG    EQU   1              PARAMETER LINKAGE REGISTER                18100017
JTBASE   EQU   2                       BASE FOR JED TABLE ENTRY         18200017
TDBASE   EQU   3                   BASE FOR TERMINAL DIRECTORY ENTRY    18300017
FTBASE   EQU   4                       BASE FOR FAST TABLE ENTRY        18400017
AVTBASE  EQU   5              BASE FOR ADDRESS VECTOR TABLE DSECT       18500017
UDBASE   EQU   6                       BASE FOR USER DIRECTORY ENTRY    18600017
SWCH     EQU   7              NOTIFY OR ALERT ALTERNATE SWITCH          18700017
THUMB    EQU   8              INTERNAL BRANCH REGISTER                  18800017
USE      EQU   9              GENERAL USAGE REGISTER                    18900017
LINK     EQU  10              INTERNAL BRANCH REGISTER                  19000017
BASE     EQU  12              BASE REGISTER FOR SUBROUTINE              19100017
SAVE     EQU  13              SAVE REGISTER FOR SUBROUTINE LINKAGE      19200017
BAC      EQU  14              RETURN REGISTER FOR SUBROUTINE LINKAGE    19300017
GO       EQU  15              ENTRY POINT REGISTER FOR SUBROUTINE       19400017
*                               LINKAGE                                 19500017
         SPACE 2                                                        19600017
*              SYMBOLIC DISPLACEMENTS, OFFSETS, AND LENGTHS             19700017
         SPACE 1                                                        19800017
*  DISPLACEMENTS-                                                       19900017
         SPACE 1                                                        20000017
ZERO     EQU   0                   ABSOLUTE DISPLACEMENT OF ZERO        20100017
ONE      EQU   1                   ABSOLUTE DISPLACEMENT OF ONE         20200017
TWO      EQU   2                   ABSOLUTE DISPLACEMENT OF TWO         20300017
FOUR     EQU   4                   ABSOLUTE DISPLACEMENT OF FOUR        20400017
ATE      EQU   8                   ABSOLUTE DISPLACEMENT OF EIGHT       20500017
TWLV     EQU   12                  ABSOLUTE DISPLACEMENT OF TWELVE      20600017
WARM     EQU   X'20'                    WARMSTART IN PROGRESS           20700017
         SPACE 1                                                        20800017
*  OFFSETS                                                              20900017
        SPACE 1                                                         21000017
OUID     EQU   9                   OFFSET OF USERID FIELD IN UDIR ENTRY 21100017
O31      EQU  31                   OFFSET OF MESSAGE IHK009I CONTEXT    21200017
O38      EQU  38                   OFFSET OF MESSAGE IHK010I CONTEXT    21300017
O41      EQU  41                   OFFSET OF MESSAGE IHK037I CONTEXT    21400017
O47      EQU  47                   OFFSET OF MESSAGE IHK007I CONTEXT    21500017
         SPACE 1                                                        21600017
*  LENGTHS                                                              21700017
         SPACE 1                                                        21800017
LUID     EQU   3                   LENGTH OF USERID                     21900017
LTID     EQU   8                   LENGTH OF TERMID                     22000017
LJOB     EQU   8                   LENGTH OF JOBNAME                    22100017
L3       EQU   3                   LENGTH OF THREE                      22200017
L4       EQU   4                   LENGTH OF FOUR                       22300017
L12      EQU  12                   LENGTH OF TWELVE                     22400017
L23      EQU  23                   LENGTH OF TWENTY-THREE               22500017
L25      EQU  25                   LENGTH OF TWENTY-FIVE                22600017
L37      EQU  37                   LENGTH OF THIRTY-SEVEN               22700017
L38      EQU  38                   LENGTH OF THIRTY-EIGHT               22800017
         EJECT                                                          22900017
*              IDENTIFY MODULE                                          23000017
         SPACE 1                                                        23100017
         B     TWLV(GO)                 BRANCH AROUND MODULE IDENTIFIER 23200017
         DC    C'IHKCHNDJ'                                              23300017
         SPACE 1                                                        23400017
*              SET UP ADDRESSIBILITY                                    23500017
         SPACE 1                                                        23600017
         STM   BAC,BASE,TWLV(SAVE)      SAVE CALLING ROUTINE REGISTERS  23700017
         BALR  BASE,REG0                ESTABLISH MODULE ADDRESSIBILITY 23800017
         USING *,BASE                   MODULE BASE                     23900017
         USING JEDTAB,JTBASE            JED TABLE ENTRY DSECT BASE      24000017
         USING FASTAB,FTBASE            FAST TABLE ENTRY DSECT BASE     24100017
         USING UDIREC,UDBASE            USER DIR ENTRY DSECT BASE       24200017
         USING TDIREC,TDBASE            TERMINAL DIR ENTRY DSECT BASE   24300017
         USING IHKZZAVT,AVTBASE         ADDR VECTOR TABLE DSECT BASE    24400017
         SPACE 1                                                        24500017
*              CHAIN SAVE AREAS                                         24600017
         SPACE 1                                                        24700017
         LA    USE,SAREA                GET ADDR OF MODULE SAVE AREA    24800017
         ST    USE,ATE(SAVE)            PLACE IT IN CALLING SAVE AREA   24900017
         ST    SAVE,FOUR(USE)           PLACE CALLING SAVE AREA ADDR    25000017
*                                       - IN MODULE SAVE AREA           25100017
         LR    SAVE,USE                 MOVE SAVE AREA ADDRESS FOR      25200017
*                                       - MODULE LINKAGES               25300017
         SPACE 2                                                        25400017
*              GET INFORMATION FROM PARAMETER LIST                      25500017
         SPACE 1                                                        25600017
         LM    JTBASE,AVTBASE,0(PAREG) PICK UP INPUT PARMS              25700017
         LA    USE,4               SET RETURN CODE FOR NORMAL RETURN    25800017
         SPACE 2                                                        25900017
*              MARK JOB COMPLETE IN FAST TABLE                          26000017
         SPACE 1                                                        26100017
         OI    FASTDSB,FASTJOBC         SET JOB COMPLETE BIT ON (BIT 0) 26200017
         SPACE                                                          26300017
*              SEARCH USER DIRECTORY FOR USERID                         26400017
         SPACE 1                                                        26500017
         MVC   USERIDD,FASTUSE         MOVE USERID TO FULLWORD          26600017
         BAL   LINK,SEARCHUD           SEARCH USER DIRECTORY            26700017
         SPACE 1                                                        26800017
*              DETERMINE DISPOSITION OF OUTPUT                          26900017
         SPACE 1                                                        27000017
         TM    FASTJIB,FASTIOUT          IS THIS IMMEDIATE JOB OUTPUT   27100017
         BZ    DEFER                    NO, GO PROCESS DEFERRED OUTPUT  27200017
         SPACE 1                                                        27300017
         L     LINK,IHKZZRCS            GET ADDRESS OF SWITCHES         27400017
         TM    0(LINK),WARM             TEST FOR WARMSTART IN PROGRESS  27500017
         BO    TERMDOWN                 TREAT TERMINAL AS DOWN          27600017
          SPACE 1                                                       27700017
         TM    TDIRSTAT,TDIRNQJN        MAY JOBS BE PLACED ON OUTPUT    27800017
*                                       -THE OUTPUT QUEUE               27900017
         BZ    TERMDOWN                 NO, HANDLE BYPASSED OUTPUT      28000017
         SPACE 2                                                        28100017
         XR    USE,USE                 SET RETURN CODE=0                28200017
         SPACE 2                                                        28300017
*              RETURN LINKAGE                                           28400017
         SPACE 1                                                        28500017
QUIT     DS    0H                                                       28600017
EXIT     DS    0H                                                       28700017
STOP     L     SAVE,SAREA+FOUR          GET CALLING SAVE AREA ADDRESS   28800017
         LR    GO,USE                  GET RETURN CODE INTO (15)        28900017
         RETURN (14,12),T,RC=(15)                                       29000017
          SPACE 1                                                       29100017
*              HANDLE BYPASSED IMMEDIATE JOB OUTPUT                     29200017
         SPACE 1                                                        29300017
TERMDOWN OI    FASTDSBE,FASTBYPN        SET BYPASSED OUTPUT BIT IN FTBL 29400017
         OI    UDIRSTAT,UDIRBYPN        SET BYPASSED OUTPUT BIT IN UDIR 29500017
         OI    TDIRSTAT,TDIRBYPN        SET BYPASSED OUTPUT BIT IN TDIR 29600017
         LR    PAREG,FTBASE        RECORD ENTRY                  A32841 29610020
         L     GO,IHKZZFMR         ON FAST TABLE                 A32841 29620020
         BALR  BAC,GO              DATA SET                      A32841 29630020
         LR    PAREG,UDBASE        RECORD ENTRY                  A32841 29640020
         L     GO,IHKZZUMR         ON USER DIRECTORY             A32841 29650020
         BALR  BAC,GO              DATA SET                      A32841 29660020
         LR    PAREG,TDBASE        RECORD ENTRY                  A32841 29670020
         L     GO,IHKZZTMR         ON TERMINAL DIRECTORY         A32841 29680020
         BALR  BAC,GO              DATA SET                      A32841 29690020
         SPACE 1                                                        29700017
         TM    TDIRSWCH,TDIRRJSN        IS TERMINAL ACTIVE?             29800017
         BO    EXIT                     OUTPUT MUST BE DISCONTINUED     29900017
         TM    TDIRSWCH+TWO,TDIRSWCN      SEE IF SWITCHED LINE          30000017
         BZ    EXIT                     NOT SWITCHED EXIT               30100017
*                                       - SWITCHED LINES                30200017
         SPACE 1                                                        30300017
         SPACE                                                          30400017
         SPACE 1                                                        30500017
         SPACE                                                          30600017
SWITCH   DS    0H                                                       30700017
         BAL   THUMB,CLEAR             CLEAR MESSAGE AREA               30800017
         SPACE 2                                                        30900017
*        TELL CENTRAL OPERATOR THERE IS BYPASSED OUTPUT PENDING STARTUP 31000017
         SPACE 1                                                        31100017
* BUILD- IHK037I INFORM INACTIVE WORK STATION JOBNAME USERID TERMID O   31200017
         SPACE 1                                                        31300017
BUILD37O DS    0H                                                       31400017
         MVI   CENTRAL,OUTPUT           INDICATE OUTPUT AVAILABLE       31500017
OUTPUT   EQU   C'O'                INDICATION OF BYPASSED OUTPUT        31600017
         BAL   LINK,BUILD37            BUILD MESSAGE 37                 31700017
         LA    USE,4                   SET RETURN CODE                  31800017
         B     EXIT                    RETURN                           31900017
         SPACE 2                                                        32000017
         SPACE 2                                                        32100017
*              HANDLE DEFERRED OUTPUT                                   32200017
         SPACE 1                                                        32300017
DEFER    TM    FASTJIB,FASTNOTS         SOURCE DESIRE NOTIFICATION      32400017
         BO    NOTSOR                   YES, NOTIFY HIM OF JOB COMPL.   32500017
         TM    FASTJIB,FASTSALT          SOURCE DESIRE SPECIFIC ALERT   32600017
         BO    ALTSOR                   YES, ALERT HIM OF JOB COMPL.    32700017
         TM    UDIRSTAT,UDIRMILT       SOURCE DESIRE MINOR ALERT        32800017
         BO    ALTSOR                   YES, ALERT HIM OF JOB COMPL.    32900017
         TM    UDIRSTAT,UDIRMALT        SOURCE DESIRE MAJOR ALERT       33000017
         BO    ALTSOR                   YES, ALERT HIM OF JOB COMPL.    33100017
         B     ALTUSER                  HOW ABOUT AN ALTERNATE USER     33200017
         SPACE 2                                                        33300017
*              NOTIFY OR ALERT SOURCE OF JOB COMPLETION                 33400017
         SPACE 1                                                        33500017
NOTSOR   XR    USE,USE                  INDICATE NOTIFY REQUIRED        33600017
ALTSOR   TM    TDIRSTAT,TDIRNQMN        CAN MESSAGES BE SENT TO SOURCE  33700017
*                                       - WORK STATION                  33800017
         BO    NOTALTS                  YES, NOTIFY OR ALERT SOURCE OF  33900017
*                                       - JOB COMPLETION                34000017
         LTR   USE,USE                  HAVE A PENDING NOTIFY CONDITION 34100017
         BNZ   ALTUSER                  NO, JUST AN ALERT, FORGET IT    34200017
         SPACE 2                                                        34300017
*              MARK NOTIFY PENDING FOR SOURCE                           34400017
         SPACE 1                                                        34500017
         OI    UDIRSTAT,UDIRNPLS        INDICATE NOTIFY PENDING SOURCE  34600017
*                                       - LOGON OR WORK STATION STARTUP 34700017
         OI    TDIRSTAT,TDIRNPDN        INDICATE NOTIFY PENDING RJSTART 34800017
         OI    FASTDSB,FASTNPDN         INDICATE NOTIFY PENDING RJSTART 34900017
         SPACE 2                                                        35000017
*           NEDD TO TELL CENTRAL OPERATOR OF NOTIFY PENDING ON SOURCE   35100017
         SPACE 1                                                        35200017
         TM    TDIRSWCH+TWO,TDIRSWCN    IS THIS A SWITCHED LINE         35300017
         BZ    INTREM                   NO, WRITE OUT SOURCE UDIR AND   35400017
*                                       - TDIR ENTRIES AND PROCESS      35500017
*                                       - ALTERNATE RECIPIENT IF ANY    35600017
         SPACE 1                                                        35700017
*        SWITCHED LINE PROCESSING FOR NOTIFY PENDING SOURCE             35800017
         SPACE 1                                                        35900017
* BUILD- IHK037I INFORM INACTIVE WORK STATION JOBNAME-USERID-TERMID-N   36000017
*  AND SEND TO CENTRAL OPERATOR                                         36100017
         SPACE 1                                                        36200017
         BAL   THUMB,CLEAR              CLEAR VARIABLE MSG TEXT AREA    36300017
         MVI   CENTRAL,NOTIFY           INDICATE NOTIFY PENDING STARTUP 36400017
NOTIFY   EQU   C'N'                INDICATION OF PENDING NOTIFICATION   36500017
         BAL   LINK,BUILD37             FINISH BUILDING MSG AND SEND IT 36600017
*                                       - (IHK037I) TO CENTRAL OPERATOR 36700017
         SPACE 1                                                        36800017
*              HANDLE ALERT AND NOTIFY FOR ALTERNATE                    36900017
         SPACE 1                                                        37000017
INTREM   DS    0H                                                       37100017
ALTUSER  DS    0H                                                       37200017
         BAL   LINK,SCHUD              SEARCH USER DIRECTORY FOR ALT    37300017
         LA    USE,4                   SET RETURN CODE                  37400017
         BZ    QUIT                    NO, RETURN                       37500017
         LR    SWCH,UDBASE              INDICATE NOTIFY NOT YET         37600017
*                                       - REQUIRED                      37700017
         SPACE 2                                                        37800017
*        CHECK FOR ALTERNATE NOTIFY OR ALERT REQUIREMENTS               37900017
         SPACE 1                                                        38000017
         TM    FASTJIB,FASTNOTA         DOES SOURCE DESIRE TO NOTIFY    38100017
*                                       - ALTERNATE OF JOB COMPLETION   38200017
         BO    NOTALT                   YES, SEE IF ALTERNATE CAN BE    38300017
*                                       - NOTIFIED                      38400017
         TM    FASTJIB,FASTSAA          DOES ALTERNATE HAVE A SPECIFIC  38500017
*                                       - ALERT PENDING JOB COMPLETION  38600017
         BO    ALTALT                   YES, SEE IF THE MSG CAN BE SENT 38700017
         TM    UDIRSTAT,UDIRMALT        DOES ALTERNATE HAVE A MAJOR     38800017
*                                       - ALERT REQUEST OUTSTANDING     38900017
         BO    ALTALT                   YES, SEE IF THE MSG CAN BE SENT 39000017
         B     QUIT                     NOTHING HAPPENING - GO HOME     39100017
         SPACE 2                                                        39200017
*        NOTIFY ALTERNATE RECIPIENT AFTER OBTAINING HIS TDIR ENTRY      39300017
         SPACE 1                                                        39400017
NOTALT   XR    SWCH,SWCH                INDICATE SOURCE DESIRES         39500017
*                                       - ALTERNATE NOTIFIED            39600017
ALTALT   DS    0H                                                       39700017
         BAL   LINK,SEARCHTD           GET ALT TDIR ENTRY ADDRESS       39800017
         BNZ   LETIMNO                  NO, BUT INDICATE HE HAS A       39900017
*                                       - NOTIFY PENDING HIS LOGON      40000017
         TM    TDIRSTAT,TDIRNQMN        CAN MESSAGES BE SENT TO HIS     40100017
*                                       - WORK STATION                  40200017
         BO    SENDIT                   WHY SURE, SEND THE BEAUTY       40300017
         SPACE 1                                                        40400017
         SPACE                                                          40500017
*              MARK NOTIFY PENDING ALTERNATE LOGON                      40600017
         SPACE 1                                                        40700017
LETIMNO  LTR   SWCH,SWCH                IS NOTIFIED REQUIRED            40800017
         LA    USE,4                   SET RETURN CODE                  40900017
         BNZ   QUIT                     NO, MUST HAVE BEEN AN ALERT     41000017
         SPACE 1                                                        41100017
TELLIM   OI    UDIRSTAT,UDIRNPLO        INDICATE USER HAS NOTIFY        41200017
*                                       - PENDING LOGON                 41300017
         OI    FASTDSB,FASTNALT         INDICATE NOTIFY PENDING         41400017
*                                       - ALTERNATE LOGON               41500017
         B     QUIT                    RETURN                           41600017
         SPACE 2                                                        41700017
*              SEND ALTERNATE NOTIFY OR ALERT                           41800017
         SPACE 1                                                        41900017
SENDIT   LTR   SWCH,SWCH                IS THIS A NOTIFY FOR ALTERNATE  42000017
         BNZ   SEND                     NO, SEND MSG EVEN THOUGH HE IS  42100017
*                                       - NOT LOGGED ON                 42200017
        SPACE 1                                                         42300017
         CLC   FASTALT(L3),TDIRUSID     IS HE CURRENTLY LOGGED ON AT    42400017
*                                       - THIS WORK STATION             42500017
         BNE   TELLIM                   NO, BUT INDICATE HE HAS A       42600017
*                                       - NOTIFY PENDING HIS NEXT LOGON 42700017
SEND     BAL   LINK,NOTALTA             BUILD AND SEND MSG              42800017
         OI    FASTDSB,FASTANOA         INDICATE ALTERNATE WAS NOTIFIED 42900017
*                                       - OR ALERTED AS THE CASE MAY BE 43000017
         B     QUIT                     LEAVE                           43100017
         SPACE 2                                                        43200017
*              BUILD AND SEND ALERT/NOTIFY MESSAGES                     43300017
         SPACE 1                                                        43400017
NOTALTA  BAL   THUMB,CLEAR              CLEAR VARIABLE MSG TEXT AREA    43500017
         TM    FASTJIB,FASTINFO         IS THERE USER INFO IN JED TABLE 43600017
         BO    UINFO                    YEP, GO GET IT                  43700017
         MVI   MSGTLNG,L12          INDICATE NO USER INFO PRESENT       43800017
CONTIN   TM    FASTDSB,FASTJOBT         HOW DID THIS JOB COMPLETE       43900017
         BO    ABSTOP                   BAD NEWS, ABNORMAL. GO INDICATE 44000017
*                                       - THIS TO USER                  44100017
         SPACE 1                                                        44200017
* BUILD- IHK009I NOTIFY JOBNAME USERID (USER TEXT) INDICATING NORMAL    44300017
*  JOB COMPLETION                                                       44400017
         SPACE 1                                                        44500017
         MVI   MSGOFSET+ONE,O31         PROVIDE IHKCBOFS FOR MSG        44600017
ONWAD    BAL   THUMB,SENDMSGR           GO SEND MSG                     44700017
         BR    LINK                     CONTINUE PROCESSING             44800017
         SPACE 1                                                        44900017
* INSERT USER SUPPLIED TEXT INTO NOTIFY/ALERT MESSAGE BE IT NORMAL OR   45000017
*  ABNORMAL COMPLETION                                                  45100017
         SPACE 1                                                        45200017
UINFO    MVC   USERTEXT(L25),JEDTNMSG    MOVE USER INFO INTO VARIABLE   45300017
*                                       - TEXT                          45400017
         MVI   MSGTLNG,L38          INDICATE LENGTH OF VARIALE          45500017
*                                       - TEXT, USER INFO PRESENT       45600017
         B     CONTIN                   FINISH UP AND SEND              45700017
         SPACE 1                                                        45800017
* BUILD- IHK010I NOTIFY ABEND JOBNME USERID (USER TEXT)  INDICATING     45900017
*  ABNORMAL JOB COMPLETION                                              46000017
         SPACE 1                                                        46100017
ABSTOP   MVI   MSGOFSET+ONE,O38         PROVIDE IHKCBOFS FOR ABNORMAL   46200017
*                                       - STOP MSG                      46300017
         B     ONWAD                   FINISH UP AND SEND               46400017
         SPACE 2                                                        46500017
NOTALTS  DS    0H                                                       46600017
         BAL   LINK,NOTALTA                                             46700017
INDSENT  OI    FASTDSB,FASTNAST         INDICATE SOURCE NOTIFIED OR     46800017
*                                       - ALERTED                       46900017
         B     ALTUSER                  CHECK ALTERNATE                 47000017
*              FINISH BUILDING MESSAGE AND SEND                         47100017
SENDMSGR ST    TDBASE,DESTIN            INDICATE MSG DESTINATION        47200017
SENDMSG  MVC   JOBNAME(LJOB),FASTNAME      INDICATE JOB INVOLVED        47300017
         MVC   USERID(LUID),UDIRUSID       INDICATE USER INVOLVED       47400017
         LA    PAREG,DESTIN             GET ADDRESS OF PARAMETER LIST   47500017
*                                       - FOR IHKCBLDM                  47600017
         L     GO,IHKZZLDM              GET ENTRY POINT OF BUILD        47700017
*                                       - MESSAGE ROUTINE               47800017
         BALR  BAC,GO                   GO AND SEND THE MESSAGE         47900017
         BR    THUMB                    GO BACK AND CONTINUE PROCESSING 48000017
         SPACE 2                                                        48100017
*        ALERT CENTRAL OPERATOR THAT OUTPUT OR NOTIFY IS PENDING START  48200017
         SPACE 1                                                        48300017
BUILD37  MVI   MSGOFSET+ONE,O41         PROVIDE IHKCBOFS OFFSET FOR MSG 48400017
         MVI   MSGTLNG,L23          PROVIDE IHKCBOFS OFFSET FOR MSG     48500017
         XC    DESTIN(L4),DESTIN        INDICATE MSG FOR CENTRAL OP.    48600017
         MVC   TERMID(8),TDIRTERM       INDICATE WORK STATION INVOLVED  48700017
         BAL   THUMB,SENDMSG            GO FINISH PARAMETER LIST AND    48800017
*                                       - CALL IHKCBLDM                 48900017
         BR    LINK                     CONTINUE PROCESSING             49000017
         SPACE 2                                                        49100017
*              CLEAR VARIABLE TEXT AREA OF MESSAGE PARAMETER AREA       49200017
CLEAR    MVI   VTEXT,BLANK              MOVE INITIAL BLANK INTO AREA    49300017
BLANK    EQU   C' '                                                     49400017
         MVC   VTEXT+ONE(L37),VTEXT     CASCADE BLANK THRU REST OF      49500017
*                                       - VARIABLE MSG AREA             49600017
         BR    THUMB                    BUILD THE DESIRED MSG           49700017
         SPACE 2                                                        49800017
*              SEARCH USER DIRECTORY                                    49900017
         SPACE 1                                                        50000017
SCHUD    MVC   USERIDD(3),FASTALT      GET USERID ON FULLWORD           50100017
SEARCHUD L     PAREG,USERIDD           GET USERID IN (1)                50200017
         L     GO,IHKZZSUD             ADDRESS OF SEARCH ROUTINE        50300017
         BALR  BAC,GO                                                   50400017
         LR    UDBASE,PAREG            GET UDIR ENTRY ADDRESS           50500017
         LTR   PAREG,PAREG             TEST RETURN CODE                 50600017
         BR    LINK                    GO BACK TO MAINLINE CODE         50700017
         SPACE 1                                                        50800017
         SPACE 1                                                        50900017
*              SEARCH OF TERMINAL DIRECTORY                             51000017
         SPACE 1                                                        51100017
SEARCHTD DS    0H                                                       51200017
         L     GO,IHKZZSTD             ADRESS OF SEARCH ROUTINE         51300017
         BALR  BAC,GO                                                   51400017
         LR    TDBASE,PAREG            GET ADDRESS OF TDIR ENTRY        51500017
         LTR   GO,GO                   CHECK RETURN CODE                51600017
         BR    LINK                    GO BACK TO MAINLINE CODE         51700017
         SPACE 1                                                        51800017
       SPACE 1                                                          51900017
*    C O N S T A N T S   AND   P A R A M E T E R   L I S T S            52000017
          SPACE 1                                                       52100017
SAREA    DC    18F'0'         SAVE AREA                                 52200017
          SPACE 1                                                       52300017
USERIDD  DS    F                                                        52400017
         SPACE 1                                                        52500017
*    PARAMETER LIST FOR MESSAGES GENERATED BY THIS MODULE               52600017
         SPACE 1                                                        52700017
DESTIN   DC    A(0)                DESTINATION OF MESSAGE - CONTAINS    52800017
*                                  - ADDR OF TDIR ENTRY OR ZERO IF TO   52900017
*                                  - CENTRAL OPERATOR                   53000017
MSGOFSET DC    H'0'                MESSAGE OFFSET OF CONSTANT TEXT IN   53100017
*                                  -IHKCBOFS                            53200017
MSGTLNG  DC    X'00'               LENGTH OF VARIABLE MESSAGE TEST TO   53300017
*                                  - BE ADDED TO CONSTANT TEXT          53400017
VTEXT    DS    0CL38               VARIABLE TEXT TO BE ADDRD TO         53500017
*                                  - CONSTANT TEXT                      53600017
JOBNAME  DS    CL9                 NAME OF JOB FOR WHICH MSG APPLIES    53700017
USERID   DS    CL4                 NAME OF USER FOR WHICH MSG APPLIES   53800017
USERTEXT DS    0CL25               NOTIFY TEXT DESIRED BY USER          53900017
TERMID   DS    CL9                 NAME OF WORK STATION TO WHICH MSG    54000017
*                                  - APPLIES                            54100017
CENTRAL  DS    CL1                 CENTRAL OPERATOR INFO N-NOTIFY       54200017
*                                  - O-OUTPUT                           54300017
REMAIN   DS    CL15                REMAINING REQUIRMENT FOR USER TEXT   54400017
*   F A S T   T A B L E   E Q U A T E S                                 54500017
         SPACE 1                                                        54600017
FASTDOUT EQU   X'7F'               DEFERRED  JOB OUTPUT IF PIT OFF      54700017
          SPACE 1                                                       54800017
         IHKDSECT      TDIR,UDIR,FASTAB,JEDTAB,,AVT                     54900017
        END                                                             55000017
