PUP   TITLE  'PACK AND UNPACK SERVICE MODULE'                           00300018
IHKCHPUP CSECT                                                          00600018
         ENTRY IHKCHPCK,IHKCHUPK                                        00900018
*                                                                A63546 01200021
*                                                                     * 01300021
* STATUS: CHANGE LEVEL 1, RELEASE 21.8                                * 01400021
*                                                                     * 01500021
*                                                                     * 01800018
*FUNCTION/OPERATION - THIS ROUTINE PACKS OR UNPACKS A RECORD.  THE    * 02100018
*   FORMAT OF THE PACKED RECORD IS AS FOLLOWS -                       * 02400018
*                                                                     * 02700018
*   ****************************************                          * 03000018
*   *TT*LL*TEXT*BB*LL*TEXT*BB* ... *LL*TEXT*                          * 03300018
*   ****************************************                          * 03600018
*                                                                     * 03900018
*   WHERE TT IS A BYTE CONTAINING THE TOTAL LENGTH OF THE PACKED      * 04200018
*            RECORD (INCLUDING TT ITSELF),                            * 04500018
*         LL IS A BYTE CONTAINING THE LENGTH OF THE FOLLOWING TEXT,   * 04800018
*         BB IS A BYTE CONTAINING THE NUMBER OF BLANKS BETWEEN TEXTS. * 05100018
*                                                                     * 05400018
*                                                                     * 05700018
*ENTRY POINTS -                                                       * 06000018
*                                                                     * 06300018
*        IHKCHPCK - TO PACK A RECORD.                                 * 06600018
*   REGISTER 1 POINTS TO THE LINE CONTROL BLOCK WHICH CONTAINS -      * 06900018
*   LCBPARM1   - ADDRESS OF THE LENGTH OF THE INPUT RECORD            * 07200018
*   LCBPARM2    - ADDRESS OF THE INPUT RECORD                         * 07500018
*   LCBPARM3   - ADDRESS OF THE OUTPUT RECORD (BUFFER)                * 07800018
*                                                                     * 08100018
*        IHKCHUPK - TO UNPACK A RECORD.                               * 08400018
*   REGISTER 1 POINTS TO THE LINE CONTROL BLOCK WHICH CONTAINS -      * 08700018
*   LCBPARM2    - ADDRESS OF THE INPUT RECORD                         * 09000018
*   LCBPARM3   - ADDRESS OF THE OUTPUT RECORD (BUFFER)                * 09300018
*                                                                     * 09600018
*                                                                     * 09900018
*INPUT - PARAMETER LIST DESCRIBED ABOVE.                              * 10200018
*                                                                     * 10500018
*                                                                     * 10800018
*OUTPUT - THE PACKED OR UNPACKED RECORD.                              * 11100018
*                                                                     * 11400018
*                                                                     * 11700018
*EXTERNAL ROUTINES - N/A                                              * 12000018
*                                                                     * 12300018
*                                                                     * 12600018
*EXITS - NORMAL - RETURN IS MADE TO THE CALLING ROUTINE.              * 12900018
*                                                                     * 13200018
*EXITS - ERROR - N/A                                                  * 13500018
*                                                                     * 13800018
*                                                                     * 14100018
*ATTRIBUTES - IT IS REENTRANT.                                        * 14400018
*                                                                     * 14700018
         EJECT                                                          15000018
*                                                                     * 15300018
*NOTES - THE OPERATION OF THIS SUBROUTINE DEPENDS UPON AN INTERNAL    * 15600018
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 15900018
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED SO* 16200018
*   THAT REDEFINITION OF CHARACTER-TYPE CONSTANTS, BY REASSEMBLY, WILL* 16500018
*   RESULT IN A CORRECT MODULE FOR THE NEW DEFINITION.                * 16800018
*                                                                     * 17100018
         EJECT                                                          17400018
*********************************************************************** 17700018
*                                                                     * 18000018
*                      SYMBOLIC CONSTANT NOTATION                     * 18300018
*                                                                     * 18600018
*********************************************************************** 18900018
         SPACE 1                                                        19200018
ZERO     EQU   0                                                        19500018
BLANK    EQU   C' '                                                     19800018
         SPACE 4                                                        20100018
*********************************************************************** 20400018
*                                                                     * 20700018
*                      SYMBOLIC REGISTER NOTATION                     * 21000018
*                                                                     * 21300018
*********************************************************************** 21600018
         SPACE 1                                                        21900018
R0       EQU   0               NOT USED                                 22200018
R1       EQU   1               PARAMETER LIST ADDRESS                   22500018
R2       EQU   2               BASE FOR DSECT PCKIN                     22800018
R3       EQU   3               BASE FOR PCKOUT                          23100018
LEN      EQU   3                                                        23400018
R4       EQU   4               LOOP ON PCKIN SIZE                       23700018
REC      EQU   4                                                        24000018
BUF      EQU   5                   POINTER TO OUTPUT BUFFER             24300018
SCAN     EQU   6                   POINTER TO OUTPUT POSITION           24600018
TT       EQU   7                   ACCUMULATOR TO FIND TT               24900018
LINK     EQU   8                   LINK REGISTER                        25200018
BB       EQU   9                   REGISTER TO SAVE BB                  25500018
R10      EQU   10              TEMP - LENGTH OF CURRENT FIELD           25800018
TEMP     EQU   10                  TEMPORARY SAVE FOR INPUT POINTER     26100018
R11      EQU   11             LINK REGISTER                             26400018
R12      EQU   12              BASE FOR MAIN CODING                     26700018
R13      EQU   13              POINTER TO CALLER'S SAVE AREA            27000018
R14      EQU   14              RETURN                                   27300018
R15      EQU   15              ENTRY POINT                              27600018
         TITLE 'PACK ROUTINE'                                           27900018
*********************************************************************** 28200018
*                                                                     * 28500018
*                            INITIALIZATION                           * 28800018
*                                                                     * 29100018
*********************************************************************** 29400018
         SPACE 1                                                        29700018
IHKCHPCK DS    0H                                                       30000018
         STM   R14,R12,12(R13) SAVE REGISTERS                           30300018
         BALR  R12,R0                                                   30600018
         USING *,R12           ESTABLISH ADDRESSIBILITY                 30900018
PCKINIT  DS    0H                                                       31200018
         SPACE 4                                                        31500018
         B     ARDID                                                    31800018
         DC    C'IHKCHPCK'                                              32100018
ARDID    DS    0H                                                       32400018
         SPACE 4                                                        32700018
         USING LCBDSECT,R1                                              33000018
         LM    LEN,BUF,LCBPARM1                                         33300018
         SPACE 1                                                        33600018
         LR    R1,REC              ENSURE R1 HAS VALID PTR.             33900018
         LR    TEMP,REC            SAVE INPUT POINTER                   34200018
         LR    SCAN,BUF            SAVE OUTPUT POINTER                  34500018
         SR    TT,TT               ZERO TT COUNTER                      34800018
         BCTR  LEN,0               DECREASE LENGTH FOR EXECUTED TRT     35100018
         SPACE 4                                                        35400018
*********************************************************************** 35700018
*                                                                     * 36000018
*                                 SCAN                                * 36300018
*                                                                     * 36600018
*********************************************************************** 36900018
         SPACE 1                                                        37200018
         CLC   0(2,REC),BLANKS     CHECK FOR LEADING BLANKS             37500018
         BNE   CHARFLD             NO, START WITH CHARACTER PROCESSING  37800018
         MVI   1(SCAN),ZERO        SET INITIAL LL=0                     38100018
         LA    SCAN,2(SCAN)        STEP SCAN POINTER                    38400018
         LA    TT,2(TT)            STEP TT                              38700018
         EJECT                                                          39000018
*********************************************************************** 39300018
*                                                                     * 39600018
*                           BLANK PROCESSING                          * 39900018
*                                                                     * 40200018
*********************************************************************** 40500018
         SPACE 1                                                        40800018
         SPACE 1                                                        41100018
BLANKFLD DS    0H                                                       41400018
         EX    LEN,TRTCHAR         FIND NON-BLANK                       41700018
         BC    8,ENDBLK            NONE FOUND = FINISHED                42000018
         SPACE 1                                                        42300018
         LR    TEMP,R1             STEP INPUT POINTER                   42600018
         SR    R1,REC              GET BB                               42900018
         LR    BB,R1               SAVE BB                              43200018
         SR    LEN,R1              FIX UP LENGTH TO BE PROCESSED        43500018
         SPACE 1                                                        43800018
         LTR   LEN,LEN             ARE WE THROUGH?                      44100018
         BZ    ENDCH               YES, GO FINISH UP                    44400018
         LR    REC,TEMP            STEP INPUT POINTER                   44700018
         SPACE 4                                                        45000018
*********************************************************************** 45300018
*                                                                     * 45600018
*                         CHARACTER PROCESSING                        * 45900018
*                                                                     * 46200018
*********************************************************************** 46500018
         SPACE 1                                                        46800018
CHARFLD  DS    0H                                                       47100018
         EX    LEN,TRTBLK          FIND BLANK                           47400018
         BC    8,ENDCHAR           NONE FOUND = FINISHED                47700018
         BC    2,ENDCHR            LAST BYTE BLANK=FINISHED             48000018
         SPACE 1                                                        48300018
         SR    LEN,R1              FIX UP LENGTH TO BE PROCESSED        48600018
         AR    LEN,REC                WITHOUT DESTROYING R1             48900018
         LR    REC,R1              SAVE R1                              49200018
         SPACE 1                                                        49500018
         CLI   1(R1),BLANK         WAS BLANK FOUND SIGNIFICANT          49800018
         BE    DBLANK              YES, START BLANKS AFTER MOVE         50100018
         SPACE 1                                                        50400018
         LA    REC,1(REC)          NO, CONTINUE SEARCH                  50700018
         LR    R1,REC              FIX UP REC AND R1 TO CONTINUE        51000018
         BCTR  LEN,0               FIX BYTES TO BE PROCESSED            51300018
         B     CHARFLD                                                  51600018
         SPACE 1                                                        51900018
DBLANK   DS    0H                                                       52200018
         LA    LINK,BLANKFLD       SET TO RETURN TO BLANK PROC.         52500018
         EJECT                                                          52800018
*********************************************************************** 53100018
*                                                                     * 53400018
*             SUBROUTINE - STORE BBLL AND MOVE TEXT                   * 53700018
*                                                                     * 54000018
*********************************************************************** 54300018
         SPACE 1                                                        54600018
SUB      DS    0H                                                       54900018
         SR    R1,TEMP             GET LL                               55200018
         STC   R1,1(SCAN)          STORE LL                             55500018
         STC   BB,0(SCAN)          STORE BB                             55800018
         SPACE 1                                                        56100018
         BCTR  R1,0                DECREMENT FOR MOVE                   56400018
         EX    R1,MVC              MOVE CHARACTERS                      56700018
         LA    SCAN,3(R1,SCAN)     STEP SCAN POINTER                    57000018
         LA    TT,3(R1,TT)         STEP TT                              57300018
         BR    LINK                                                     57600018
         SPACE 4                                                        57900018
*********************************************************************** 58200018
*                                                                     * 58500018
*                         END OF INPUT RECORD                         * 58800018
*                                                                     * 59100018
*********************************************************************** 59400018
         SPACE 1                                                        59700018
ENDCHR   DS    0H                                                       60000018
         LA    R1,1(R1)           STEP PAST BLANK                       60300018
         LA    LINK,ENDBLK         SET TO RETURN                        60600018
         B     SUB                 DO MOVES AND STORES                  60900018
         SPACE 4                                                        61200018
ENDCH    DS    0H                                                       61500018
         LR    REC,TEMP                                                 61800018
ENDCHAR  DS    0H                                                       62100018
         LR    R1,REC                                                   62400018
         LA    R1,1(R1,LEN)        FIX R1                               62700018
         BAL LINK,SUB              DO MOVES AND STORES                  63000018
ENDBLK   DS    0H                                                       63300018
         STC   TT,0(BUF)           STORE TT                             63600018
         B     PCKRTRN             RETURN                               63900018
         TITLE 'UNPACK ROUTINE'                                         64200018
*********************************************************************** 64500018
*                                                                     * 64800018
*                            INITIALIZATION                           * 65100018
*                                                                     * 65400018
*********************************************************************** 65700018
         SPACE 1                                                        66000018
         USING *,R15                                                    66300018
         USING PCKIN,R2        SET UP BASES FOR INPUT AND OUTPUT AREAS  66600018
         USING PCKOUT,R3                                                66900018
IHKCHUPK STM   R14,R12,12(R13) SAVE REGISTERS                           67200018
         L     R12,PCKADIN     ESTABLISH ADDRESSIBILITY                 67500018
         DROP  R15                                                      67800018
         SPACE 1                                                        68100018
         LM    R2,R3,LCBPARM2      GET INPUT AND OUTPUT PTR.            68400018
         MVI   PCKOUT,BLANK                                             68700018
         MVC   PCKOUT+1(79),PCKOUT BLANK OUTPUT BUFFER                  69000018
         SR    R10,R10         ZERO FOR INSERT CHARACTERS (R4 AND R10)  69300018
         SR    R4,R4                                                    69600018
         SPACE 4                                                        69900018
*********************************************************************** 70200018
*                                                                     * 70500018
*                                 SCAN                                * 70800018
*                                                                     * 71100018
*********************************************************************** 71400018
         SPACE 1                                                        71700018
         IC    R4,PCKIN        GET TT                                   72000018
         BCTR  R4,R0           STEP DOWN BTBP                           72300018
         LA    R2,1(R2)        STEP INPUT PTR.                          72600018
         SPACE 4                                                        72900018
PCKMVCHR IC    R10,PCKIN       GET LL                                   73200018
         LTR   R10,R10         TEST LL FOR ZERO                         73500018
         BP    PCKMVCHT           NO - PROCESS NORMALLY                 73800018
         LA    R2,1(R2)           YES - STEP INPUT PTR.                 74100018
         BCT   R4,PCKBLKS      IF MORE BTBP, GO TO BLANK PROCESS        74400018
         B     PCKRTRN         OTHERWISE, RETURN                        74700018
         EJECT                                                          75000018
*********************************************************************** 75300018
*                                                                     * 75600018
*                           BLANK INSERTION                           * 75900018
*                                                                     * 76200018
*********************************************************************** 76500018
         SPACE 1                                                        76800018
PCKBLKS  IC    R10,PCKIN       GET BB                                   77100018
         AR    R3,R10          STEP OUTPUT PTR. BY BB                   77400018
         LA    R2,1(R2)        STEP INPUT PTR.                          77700018
         BCT   R4,PCKMVCHR     BRANCH TO PROCESS CHARACTERS             78000018
         SPACE 4                                                        78300018
*********************************************************************** 78600018
*                                                                     * 78900018
*                         CHARACTER INSERTION                         * 79200018
*                                                                     * 79500018
*********************************************************************** 79800018
PCKMVCHT SR    R4,R10          STEP DOWN BTBP BY LL                     80100018
         BM    PCKRTRN             ERROR DETECTED IN PACKED RECORD      80400018
         BCTR  R10,R0          DECREASE LL BY 1 FOR EX MVC              80700018
         EX    R10,PCKMOVE     MOVE TEXT TO OUTPUT AREA                 81000018
         LA    R10,2(R10)      INCREASE LL BY 2 FOR STEPPING PTRS.      81300018
         AR    R2,R10          STEP INPUT PTR.                          81600018
         AR    R3,R10          STEP OUTPUT PTR.                         81900018
         BCTR  R3,R0           DECREASE OUTPUT PTR. BY 1                82200018
*                              N.B. EX MVC NEEDS ORIGINAL VALUE IN R3   82500018
         BCT   R4,PCKBLKS      STEP DOWN BTBP AND PROCESS BLANKS        82800018
         SPACE 4                                                        83100018
*********************************************************************** 83400018
*                                                                     * 83700018
*                                RETURN                               * 84000018
*                                                                     * 84300018
*********************************************************************** 84600018
         SPACE 1                                                        84900018
PCKRTRN  DS    0H                                                       85200018
         RETURN (14,12),T                                               85500018
         TITLE 'CONSTANTS'                                              85800018
*********************************************************************** 86100018
*                                                                     * 86400018
*                              CONSTANTS                              * 86700018
*                                                                     * 87000018
*********************************************************************** 87300018
PCKADIN  DC    A(PCKINIT)      ADDRESS OF FIRST BYTE OF PROGRAM         87600018
BLANKS   DC    CL2' '              BLANKS USED FOR COMPARE              87900018
PCKMOVE  MVC   0(0,R3),1(R2)   VARIABLE MVC FOR UNPACK                  88200018
MVC      MVC   2(0,SCAN),0(TEMP)   EXECUTED MOVE                        88500018
TRTCHAR  TRT   0(0,REC),CHARTBL    EXECUTED TRT FOR CHARACTER           88800018
TRTBLK   TRT   0(0,REC),BLKTBL     EXECUTED TRT FOR BLANK               89100018
CHARTBL  DC    64X'FF',X'00',191X'FF'                                   89400018
BLKTBL   DC    64X'00',X'FF',191X'00'                                   89700018
         IHKDSECT ,,,,LCB                                               90000018
PCKIN    DSECT                 DSECT FOR INPUT RECORD                   90300018
         DS    CL144                                                    90600018
PCKOUT   DSECT                                                          90900018
         END                                                            91200018
