RDR    TITLE   'IHKCHRDR  RJE READER V-2'                               00070018
         SPACE  2                                                       00140018
IHKCHRDR CSECT                                                          00210018
         SPACE                                                          00280018
*2210857500,891100                                                 000C 00350018
*643300,699300-700000,725200-727300                              A35895 00380020
*D667800                                                         A37786 00390020
*A311700-311900,667400-668000                                    A37786 00400020
*D 592200                                                        A53596 00405021
*C 591500                                                        A53596 00410021
*                                                                       00415021
         ENTRY IHKCEJDT                                                 00420018
         SPACE                                                          00490018
         ENTRY IHKCELST                                                 00560018
         SPACE                                                          00630018
         ENTRY IHKCEJBN                                                 00700018
         SPACE                                                          00770018
         ENTRY IHKCHASE                                                 00840018
         SPACE                                                          00910018
         EXTRN     IHKCACOM                                             00980018
         SPACE                                                          01050018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   01120018
*                                                                   *   01190018
*                                                                   *   01260018
* S T A T U S - -                                                   *   01330018
*                                                                   *   01400018
* STATUS: CHANGE LEVEL 2, RELEASE 21.7                              *   01470021
*                                                                   *   01540018
*                                                                   *   01610018
* F U N C T I O N / O P E R A T I O N - -                           *   01680018
*                                                                   *   01750018
*   THE RJE READER MODULE GAINS CONTROL FROM THE O/S READER/INTER-  *   01820018
*     PRETER VIA THE INCORE ACCESS METHOD.  ALTHOUGH THE RJE READER *   01890018
*     INITIALLY GAINS CONTROL FROM THE O/S READER, IT IS THE O/S    *   01960018
*     READER BEING USED AS THE SUBROUTINE -- AS UNUSUAL AS IT SEEMS *   02030018
*     THIS IS MUCH LIKE A MAN GETTING MARRIED.  ONCE THE CEREMONY   *   02100018
*     IS PREFORMED, THE O/S READER ISSUING THE INCORE ACCESS METHOD *   02170018
*     GET, IT IS THE WIFE, (THE RJE READER) WHO CONTROLS THE STATE  *   02240018
*     OF THAT RELATIONSHIP UNTIL THE RELATIONSHIP IS TERMINATED.    *   02310018
*     THIS IS ACCOMPLISHED VIA END OF DAD (EODAD).                  *   02380018
*                                                                   *   02450018
*   ONCE IN CONTROL THE RJE READER'S PRIMARY FUNCTION IS DEQUEUING  *   02520018
*     AND READING LOGICAL RECORDS FROM THE RJE QUEUE (39) OF THE    *   02590018
*     THE BIG DADDY OF QUEUES, THE SYS1.SYSJOBQE.  THESE RECORDS    *   02660018
*     CONSIST  OF THE JCL IN JOB ENTRIES AND WORK STATION COMMANDS. *   02730018
*     THIS DATA HAVING BEEN COLLECTED FROM THE WORK STATIONS AND    *   02800018
*     PLACED ON THE QUEUE BY IHKABLRD WHICH IS PART OF THE COLLECTOR*   02870018
*                                                                   *   02940018
*   THESE ENTRIES ON THE QUEUE HAVE ONE OF THE FOLLOWING FORMATS:   *   03010018
*                                                                   *   03080018
*       1. ONE OR MORE WORK STATION COMMANDS                        *   03150018
*       2. THE JCL OF A JOB ENTRY PRECEDED WITH A JED IF PRESENT    *   03220018
*       3. THE JCL OF A JOB ENTRY PRECEDED WITH A JED IF PRESENT,   *   03290018
*           FOLLOWED BY ONE OR MORE WORK STATION COMMANDS.          *   03360018
*                                                                   *   03430018
*     IF A QUEUE ENTRY CONTAINS BOTH A JOB  FOR PROCESSING AND WORK *   03500018
*     STATION COMMANDS, THE COMMANDS WILL ALWAYS FOLLOW THE JOB IN  *   03570018
*     THE QUEUE ENTRY.                                              *   03640018
         EJECT                                                          03710018
*   PROCESSING OF INPUT IN A QUEUE ENTRY IS AS FOLLOWS:             *   03780018
*                                                                   *   03850018
*       1. THE JCL IN A QUEUE ENTRY IS PASSES TO THE R/I FOR        *   03920018
*           INTERPRETION AND PROCESSING                             *   03990018
*       2. WHEN ALL JCL IN A QUEUE ENTRY HAS BEEN PASSED TO THE     *   04060018
*           R/I, INDICATED BY JECL ON THE QUEUE OR NO MORE DATA     *   04130018
*           IN THE QUEUE ENTRY, A // NULL IS PASSED TO THE R/I      *   04200018
*           TO FORCE ENQUEUING OF THE JOB ON THE DESIRED O/S INPUT  *   04270018
*           QUEUE.                                                  *   04340018
*       3.  JED STATEMENTS ARE PASSED TO THE JED PROCESSOR --       *   04410018
*            IHKCHJPR FOR INTREPRETATION AND PROCESSING OF RJE JOB  *   04480018
*            HANDLING OPTIONS.                                      *   04550018
*       4.  WORK STATION COMMANDS ARE PASSED TO THE COMMAND INTER-  *   04620018
*            PRETER FOR TRANSLATION, WHO IN TURN ROUTES THEM TO THE *   04690018
*            PROPER MODULE FOR PROCESSING.                          *   04760018
*       5.  PARTIALLY COLLECTED JOBS IN A QUEUE ENTRY, INDICATED    *   04830018
*            BY JCL IMMEDIATELY FOLLOWED BY AN INTERNAL RJEND       *   04900018
*            COMMAND (RJENDF), ARE CANCELLED IN O/S AND DELETED IN  *   04970018
*            RJE.                                                   *   05040018
*       6.  JOBS ARE ACKNOWLEDGED ONCE ENQUEUED ON THE O/S INPUT    *   05110018
*            QUEUE.                                                 *   05180018
*       7.  JCL IN A QUEUE ENTRY IS FLUSHED IF A JOB IS MARKED      *   05250018
*            ENQUEUED ON THE O/S INPUT QUEUE BUT NOT DELETED FROM   *   05320018
*            THE RJE INPUT QUEUE. (WARMSTART CONDITION).            *   05390018
*       8.  USERS ARE NOTIFIED OF MISSING CENTRAL DATA SETS         *   05460018
*       9.  THE JOBCARD USER EXIT IS PASSED THE JOB CARD AND ITS    *   05530018
*            CONTINUATION FOR EXAMINATION AND MODIFICATION          *   05600018
*       10. THE JOBACK USER EXIT IS PASSED THE RJE JOB ACKNOWLEDGE- *   05670018
*            MENT MESSAGE FOR EXAMINATION AND MODIFICATION AND IS   *   05740018
*            ALLOWED TO ADD A 59 CHARACTER MESSAGE OF HIS OWN WHICH *   05810018
*            IS SENT FOLLOWING THE RJE ACKNOWLEDGEMENT MESSAGE.     *   05880018
*       11. THE FAST TABLE ENTRY AND JED TABLE FOR THE JOB ARE      *   05950018
*            UPDATED ON THEIR RESPECTIVE DIRECT ACCESS DATA SETS.   *   06020018
*       12. ABNORMAL CLOSEDOWN PROCEDURES ARE INITIATED WHEN THE    *   06090018
*            OS QMGR RETURNS WITH AN I/O ERROR INDICATION ON A      *   06160018
*            DEQUEUE OR DELETE REQUEST                              *   06230018
*       13. ERRORS INCURRED WHILE READING LOGICAL RECORDS FROM A Q  *   06300018
*           ENTRY RESULT IN THE ENTRY AND JOB BEING DELETED.        *   06370018
*                                                                   *   06440018
*                                                                   *   06510018
* E N T R Y   P O I N T S - -                                       *   06580018
*                                                                   *   06650018
*   IHKCHRDR IS THE ENTRY POINT FOR THIS ROUTINE USED BY THE        *   06720018
*     R/I FOR AN INCORE ACCESS METHOD.                              *   06790018
*   IHKCHASE IS THE ENTRY POINT FOR THIS ROUTINE USED BY THE        *   06860018
*     RJE SUBTASKS WHEN SUBTASK CLOSEDOWN IS COMPLETE OR AN ERROR   *   06930018
*     IS ENCOUNTERED WHICH NECESSITATES ABNORMAL RJE CLOSEDOWN.     *   07000018
*     ENTRY AT IHKCHASE RESULTS IN RETURN TO R/I END OF DATA ADDRESS*   07070018
*   IHKCELST IS THE ENTRY POINT FOR THE CENTRAL DATA SET WORK AREA  *   07140018
*     USED BY IHKCEDIT AND IHKCHJPR.                                *   07210018
*   IHKCEJDT IS THE ENTRY POINT FOR THE MAIN STORAGE COPY JED TABLE *   07280018
*     FOR THE JOB USED BY IHKCHJPR TO INSERT THE NOTIFY INFORMATION *   07350018
*     AND IHKCEDIT TO INSERT SYSOUT CLASS INFORMATION.              *   07420018
*   IHKCEJBN IS THE ENTRY POINT TO ACCESS THE NAME OF THE JOB       *   07490018
*     CURRENTLY BEING PROCESSED BY THE RJE READER SUBTASK.          *   07560018
         EJECT                                                          07630018
         SPACE  2                                                       07700018
* I N P U T - -                                                     *   07770018
*                                                                   *   07840018
*   STANDARD SUBROUTINE LINKAGE PREVAILS. REGISTER ONE CONTAINS     *   07910018
*     THE ADDRESS OF THE R/I INCORE ACCESS METHOD DCB WHEN ENTERED  *   07980018
*     FROM THE R/I                                                  *   08050018
*                                                                   *   08120018
*   INPUT FROM THE RJE QUEUE OF THE SYS1.SYSJOBQE CONSISTS OF 176   *   08190018
*     BYTE RECORDS OF THE FOLLOWING FORMAT -                        *   08260018
*                                                                   *   08330018
*     *--------------------------------------------------------*    *   08400018
*     *      *           *           *  RELATIVE   *  NUMBER   *    *   08470018
*     * TTR0 *   DATA    *  DATA     *  TDIR ENTRY *  OF DATA  *    *   08540018
*     *      *    ENTRY  *   ENTRY   *   OFFSET    *  ENTRIES  *    *   08610018
*     *--------------------------------------------------------*    *   08680018
*                                                                   *   08750018
*   DESCRIPTION --                                                  *   08820018
*                                                                   *   08890018
*    BYTE      USE                                                  *   08960018
*     0-3      TTR0 IS THE TTR OF THE NEXT LOGICAL RECORD IN THE    *   09030018
*                QUEUE ENTRY.  THIS FIELD IS ZERO IF THIS IS THE    *   09100018
*                LAST RECORD IN THE QUEUE ENTRY.                    *   09170018
*     4-83     A DATA ENTRY CONSISTS OF 80 CHARACTER CARD IMAGES    *   09240018
*                OF JCL OR JECL COLLECTED FROM THE COMMUNICATION    *   09310018
*                LINES.                                             *   09380018
*                                                                   *   09450018
*     84-163   A SECOND 80 CHARACTER CARD IMAGE.                    *   09520018
*                                                                   *   09590018
*     164-167  RELATIVE TERMINAL DIRECTORY ENTRY OFFSET FROM THE    *   09660018
*                STARTING ADDRESS OF THE TERMINAL DIRECTORY FOR     *   09730018
*                THE WORK STATION FROM WHICH THE DATA IS COLLECTED. *   09800018
*     168      NUMBER OF DATA ENTRIES IN LOGICAL RECORD.            *   09870018
*                 X'00'  TWO DATA ENTRIES IN LOGICAL RECORD         *   09940018
*                 X'50   ONE DATA ENTRY IN LOGICAL RECORD           *   10010018
*                 X10'  NO DATA ENTRIES IN LOGICAL RECORD. THE     *   10080018
*                        TTR0 FIELD IS ALSO ZERO IN THIS CASE.      *   10150018
*     169-175   RESERVED                                            *   10220018
*                                                                   *   10290018
*                                                                   *   10360018
* O U T P U T - -                                                   *   10430018
*                                                                   *   10500018
*     THE UPDATED JED TABLE FOR THE JOB IS WRITTEN TO THE DIRECT    *   10570018
*     ACCESS DATA SET AND THE USER AND RJE JOB ACCECPTED MESSAGES   *   10640018
*     ARE RETURNED TO THE USER SUBMITTING THE JOB.  ERROR MESSAGES  *   10710018
*     ARE SENT TO THE USER NOTING THE FOLLOWING THREE ERROR         *   10780018
*     CONDITIONS.                                                   *   10850018
*       1.  DATA SETS SPECIFIED IN THE JED CENTRAL PARAMETER BUT    *   10920018
*           NOT SPECIFIED IN THE JCL FOR THE JOB. (MESSAGE-IHK153I) *   10990018
*       2.  ERROR INCURRED READING A LOGICAL RECORD FROM THE QUEUE  *   11060018
*           ENTRY. (MESSAGE-IHK163I DISK ERROR QMGR JOBNAME)        *   11130018
*       3.  ERROR INCURRED WRITING THE UPDATED JED TABLE TO THE     *   11200018
*           DIRECT ACCESS DATA SET. (MESSAGE- IHK163I DISK ERROR    *   11270018
*           JED JOBNAME)                                            *   11340018
         EJECT                                                          11410018
         SPACE  2                                                       11480018
* E X T E R N A L   R O U T I N E S - -                             *   11550018
*                                                                   *   11620018
*   IHKCDJMR- WRITE UPDATED JED TABLE TO THE DIRECT ACCESS DATA SET *   11690018
*   IHKCDFMR- WRITE UPDATED FASTABLE ENTRY TO DIRECT ACCESS DATA SET*   11760018
*   IHKAADSP- WAIT FOR WORK ON RJE INPUT QUEUE                      *   11830018
*   IHKCBLDM- CONSTRUCT RJE MESSAGES AND ENQUEUE ON WORK STATION    *   11900018
*             INPUT QUEUE                                           *   11970018
*   IHKCDSCH- SEARCH FASTABLE FOR JOB NAME                          *   12040018
*   IHKCFSTB- FIND POSITION OF JOB ON INPUT QUEUE FOR JOB ACCEPTED  *   12110018
*             MESSAGE                                               *   12180018
*   IHKCHJPR- PROCESS JED STATEMENTS FOUND IN INPUT STREAM          *   12250018
*   IHKCAINT- PROCESS WORK STATION COMMANDS FOUND IN INPUT STREAM   *   12320018
*   IEFQMSSS- READ LOGICAL RECORDS FROM A QUEUE ENTRY               *   12390018
*   IEFQMDQ2- DEQUEUE A QUEUE ENTRY FROM THE RJE QUEUE              *   12460018
*   IEFQDELE- DELETE AN ENTRY ON THE RJE QUEUE                      *   12530018
*   IEFSD447- MARK AN ENTRY ON THE RJE QUEUE ENQUEUED ON AN OS INPUT*   12600018
*             QUEUE BUT NOT DELETED FROM THE RJE QUEUE.             *   12670018
*                                                                   *   12740018
*                                                                   *   12810018
* E X I T S - -                                                     *   12880018
*                                                                   *   12950018
*   NORMAL - RETURN TO R/I END OF DATA ADDRESS                      *   13020018
*                                                                   *   13090018
*   ERROR - RETURN TO R/I END OF DATA ADDRESS WITH INDICATOR SET IN *   13160018
*           THE RJE COMMUNICATION SWITCH                            *   13230018
*                                                                   *   13300018
*   USER -                                                          *   13370018
*       JOB CARD USER EXIT ROUTINE.  THE ENTRY POINT OF THIS USER   *   13440018
*         EXIT IS PROVIDED IN THE THIRD WORD OF IHKCDSOC (USER EXIT *   13510018
*         AND SYSOUT INFO TABLE).  THE USER EXIT IS PASSED THE      *   13580018
*         ADDRESS OF THE JOB CARD AND EACH CONTINUATION IN REGISTER *   13650018
*         ONE.  THE USER EXIT IS PASSED 80 CHARACTER RECORDS, ONE   *   13720018
*         PER ENTRY, UNTIL THE JOB STATEMENT HAS BEEN PROCESSED.    *   13790018
*         A // NULL STATEMENT IS PASSED IF CONTINUATION IS EXPECTED *   13860018
*         BUT NOT PRESENT IN THE INPUT STREAM. THE JOBNAME MAY NOT  *   13930018
*         BE CHANGED BY THE USER EXIT. REGISTER 14 CONTAINS THE     *   14000018
*         RETURN ADDRESS.  REGISTER 13 CONTAINS THE ADDRESS OF A    *   14070018
*         STANDARD 18 WORD SAVE AREA.  REGISTERS MUST BE SAVED ON   *   14140018
*         ENTRY AND RESTORED ON RETURN.                             *   14210018
*                                                                   *   14280018
*                                                                   *   14350018
*                                                                   *   14420018
         EJECT                                                          14490018
         SPACE  2                                                       14560018
*       JOB ACKNOWLEDGEMENT USER EXIT -  THE ENTRY POINT OF THIS    *   14630018
*         EXIT IS PROVIDED IN THE FOURTH WORD OF IHKCDSOC (USER EXIT*   14700018
*         AND SYSOUT TABLE).  THE USER EXIT IS PASSED THE ADDRESS   *   14770018
*         OF THE RJE JOB ACCEPTED MESSAGE TEXT BEGINNING WITH THE   *   14840018
*         JOBNAME FIELD (31 CHARACTERS OF TEXT ARE CONTAINED IN THIS*   14910018
*         MESSAGE).  REGISTER 14 CONTAINS THE RETURN ADDRESS.       *   14980018
*         REGISTER 13 HAS THE ADDRESS OF A STANDARD 18 WORD SAVE    *   15050018
*         AREA. REGISTERS MUST BE SAVED UPON ENTRY AND RESTORED     *   15120018
*         BEFORE RETURN.  THE USER EXIT HAS THE OPTION OF SENDING   *   15190018
*         A 59 CHARACTER MESSAGE OF HIS OWN.  IF THIS OPTION IS     *   15260018
*         TAKEN REGISTER ONE MUST CONTAIN THE ADDRESS OF THE 59     *   15330018
*         CHARACTER BUFFER CONTAINING THE MESSAGE.  IF THIS OPTION  *   15400018
*         IS NOT EXERCISED, THE CONTENTS OF REGISTER ONE MUST BE    *   15470018
*         ZERO ON RETURN.                                           *   15540018
*                                                                   *   15610018
*                                                                   *   15680018
* T A B L E S / W O R K   A R E A S - -                             *   15750018
*                                                                   *   15820018
*   STANDARD 18-WORD SAVE AREA                                      *   15890018
*   JED TABLE                                                       *   15960018
*   QMGR PARAMETER AREA                                             *   16030018
*   CENTRAL DATA SET WORK AREA                                      *   16100018
*   176 BYTE BUFFER FOR LOGICAL QUEUE RECORDS                       *   16170018
*                                                                   *   16240018
*                                                                   *   16310018
* A T T R I B U T E S - -                                           *   16380018
*                                                                   *   16450018
*   NONREUSABLE                                                     *   16520018
*                                                                   *   16590018
*                                                                   *   16660018
* N O T E S - -                                                     *   16730018
*                                                                   *   16800018
*   COMMENTS KEYED TO PROGRAMMERS FAMILIAR WITH THE MYSTERIES OF    *   16870018
*     OS ASSEMBLER LANGUAGE WHICH DEPENDS UPON AN INTERNAL          *   16940018
*     REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS         *   17010018
*     EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING      *   17080018
*     HAS BEEN ARRANGED SO THAT REDEFINITION OF CHARACTER CONSTANTS *   17150018
*     BY REASSEMBLY WILL RESULT IN A CORRECT MODULE FOR THE NEW     *   17220018
*     DEFINITIONS.  GOOD LUCK WITH REMOTE JOB ENTRY, SPORT.         *   17290018
*                                                                   *   17360018
*                                                                   *   17430018
*                                                                   *   17500018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   17570018
         EJECT                                                          17640018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   17710018
*                                                                   *   17780018
*                                                                   *   17850018
*        S Y M B O L I C   R E G I S T E R S                        *   17920018
*                                                                   *   17990018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   18060018
         SPACE 2                                                        18130018
ZIP      EQU   0                                                        18200018
PAR      EQU   1                                                        18270018
RECAD    EQU   2                                                        18340018
WOK      EQU   3                                                        18410018
CNT      EQU   4                                                        18480018
FAST     EQU   5                                                        18550018
NAM      EQU   6                                                        18620018
TDIR     EQU   7                                                        18690018
SCAN     EQU   8                                                        18760018
PONT2    EQU   9                                                        18830018
POINT    EQU   10                                                       18900018
AVT      EQU   11                                                       18970018
BAS      EQU  12                                                        19040018
SAV      EQU  13                                                        19110018
BAC      EQU  14                                                        19180018
GO       EQU  15                                                        19250018
         SPACE 2                                                        19320018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   19390018
*                                                                   *   19460018
*    S Y M B O L I C   O F F S E T S ,   D I S P L A C E M E N T S, *   19530018
*     AND   V A L U E S                                             *   19600018
*                                                                   *   19670018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   19740018
         SPACE 2                                                        19810018
*  DISPLACEMENTS-                                                       19880018
         SPACE                                                          19950018
ZERO     EQU   0                                                        20020018
ONE      EQU   1                                                        20090018
TWO      EQU   2                                                        20160018
TRE      EQU   3                                                        20230018
FOUR     EQU   4                                                        20300018
ATE      EQU   8                                                        20370018
TWLV     EQU  12                                                        20440018
THIR     EQU   13                                                       20510018
SIXT     EQU   16                                                       20580018
D17      EQU   17                                                       20650018
D18      EQU   18                                                       20720018
D24      EQU   24                                                       20790018
D33      EQU  33                                                        20860018
D64      EQU   64                                                       20930018
D71      EQU   71                                                       21000018
D80      EQU   80                                                       21070018
         EJECT                                                          21140018
*  VALUES, LENGTHS,                                                     21210018
         SPACE                                                          21280018
UNK      EQU   0                        CODE FOR UNDEFINED OPERATION    21350018
L1       EQU   1                        SYMBOLIC LENGTHS ONE AND TWO    21420018
L2       EQU   2                        - BUCKLE YOUR SHOE              21490018
L3       EQU   3                        SYMBOLIC LENGTHS THREE AND FOUR 21560018
L4       EQU   4                        - SHUT THE DOOR                 21630018
LGN      EQU   4                        CODE FOR LOGON COMMAND          21700018
READ     EQU   4                        CODE TO REQUEST QMGR READ       21770018
*                                       - OPERATION                     21840018
L5       EQU   5                        SYMBOLIC LENGTHS FIVE AND SIX   21910018
L6       EQU   6                        - PICK UP STICKS                21980018
DQ       EQU   6                        CODE TO REQUEST QMGR DEQUEUE    22050018
*                                       - OPERATION                     22120018
L7       EQU   7                        SYMBOLIC LENGTHS SEVEN & EIGHT  22190018
L8       EQU   8                        - DONT BE LATE                  22260018
DELT     EQU   8                        CODE TO REQUEST QMGR DELETE     22330018
*                                       - OPERATION                     22400018
RJS      EQU   8                        CODE FOR RJSTART COMMAND        22470018
L65      EQU   9                        TEXT LENGTH FOR DISK ERROR      22540018
*                                       - WRITING JED TABLE MESSAGE     22610018
L67      EQU   9                        TEXT LENGTH FOR DISK ERROR ON   22680018
*                                       - QMGR READ OPERATION MSG       22750018
L9       EQU   9                        SYMBOLIC LENGTHS NINE AND TEN   22820018
L10      EQU  10                        - A BIG FAT HEN                 22890018
DEL      EQU  12                        CODE FOR DELETE COMMAND         22960018
LGF      EQU  16                        CODE FOR LOGOFF COMMAND         23030018
L17      EQU  17                        LENGTH SEVENTEEN MOTHER GOOSE   23100018
*                                       - IS DEAD                       23170018
BRD      EQU  20                        CODE FOR BRDCSTR COMMAND        23240018
OUT      EQU  24                        CODE FOR OUTPUT COMMAND         23310018
L56      EQU  26                        CONFUSING, BUT TEXT LENGTH FOR  23380018
*                                       - CENTRAL DATA SETS MISSING MSG 23450018
STA      EQU  28                        CODE FOR STATUS COMMAND         23520018
L51      EQU  31                        TEXT LENGTH FOR RJE JOB         23590018
*                                       - ACKNOWLEDGEMENT MSG           23660018
RJD      EQU  32                        CODE FOR RJEND COMMAND          23730018
MGR      EQU  56                        CODE FOR MSGR COMMAND           23800018
LTXT     EQU  58                        MAXIMUM VARIABLE MSG TEXT       23870018
*                                       - LENGTH LESS ONE CHARACTER     23940018
L30      EQU  59                        TEXT LENGTH FOR USER EXIT       24010018
*                                       - ACKNOWLEDGEMENT MSG           24080018
L59      EQU  59                        THIS LENGTH IS ALSO USED        24150018
ALT      EQU  60                        CODE FOR ALERT COMMAND          24220018
CNTU     EQU  64                        CODE FOR CONTINUE COMMAND       24290018
RJF      EQU  68                        CODE FOR RJENDF COMMAND         24360018
RJC      EQU  72                        CODE FOR RJENDC COMMAND         24430018
L80      EQU  80                        LOGICAL RECORD LENGTH FOR THOSE 24500018
*                                       - PROCESSED BY THIS ROUTINE     24570018
L179     EQU   179                                                      24640018
         EJECT                                                          24710018
RD1      EQU   X'01'                    INDICATOR TO QMGR TO READ ONE   24780018
*                                       - RECORD                        24850018
ABCLOS   EQU   X'01'                    MASK TO SET ABNORMAL CENTRAL    24920018
*                                       - CLOSE DOWN INDICATOR          24990018
JQUED    EQU   X'10'                    JOB ENQD ON INPUT QUEUE BUT Q   25060018
*                                       - ENTRY ON RJE Q NOT DELETED    25130018
*                                       - IF BIT IS ON                  25200018
DELJOB   EQU   X'10'                    BIT IN JOB INFO BYTE INDICATING 25270018
*                                       - JOB IS TO BE RJE DELETED      25340018
RJEQ     EQU   X'27'                    RJE Q NUMBER MANAGED BY QMGR    25410018
BLNK     EQU   X'40'                                                    25480018
NUM      EQU   X'50'                    MASK TO CHECK NUMBER OF LOGICAL 25550018
*                                       - RECORDS IN Q RECORD           25620018
*                                       - 00 TWO LOGICAL RECORDS        25690018
*                                       - 10 NO LOGICAL RECORDS         25760018
*                                       - 50 ONE LOGICAL RECORD         25830018
DEFOPT   EQU   X'80'                    RJE DEFAULT JOB PROCESSING      25900018
*                                       - OPTIONS (IMMEDIATE OUTPUT)    25970018
LAST     EQU   X'80'                                                    26040018
QEMPTY   EQU   X'F7'                                                    26110018
DONE     EQU   X'FF'                                                    26180018
PRCDS    EQU   X'FF'                    CENTRAL DATA SET PROCESSED      26250018
SLASH    EQU  C'/'                                                      26320018
         SPACE 2                                                        26390018
*  OFFSETS-                                                             26460018
         SPACE                                                          26530018
O30      EQU   30                       OFFSET FOR USER JOB ACK MSG     26600018
O51      EQU   51                       OFFSET FOR RJE JOB ACK MSG      26670018
O56      EQU   56                       OFFSET FOR MISSING DATA SET MSG 26740018
O65      EQU   65                       OFFSET FOR JED WRITE ERROR MSG  26810018
O67      EQU   67                       OFFSET FOR QMGR READ ERROR MSG  26880018
         EJECT                                                          26950018
*    I D E N T I F Y   M O D U L E   AND   E S T A B L I S H            27020018
*     I N I T I A L   A D D R E S S A B I L I T Y                       27090018
         SPACE                                                          27160018
         USING *,GO                     INITIAL ADDRESSABILITY          27230018
         SPACE                                                          27300018
         B     TWLV(GO)                 BRANCH AROUND MODULE IDENTIFIER 27370018
         DC    C'IHKCHRDR'              MODULE IDENTIFIER               27440018
         SPACE 2                                                        27510018
*    E N T R Y   L I N K A G E   AND   A D D R E S S I B I L I T Y      27580018
         SPACE                                                          27650018
         STM   BAC,BAS,TWLV(SAV)        SAVE R/I REGISTERS              27720018
         SPACE                                                          27790018
*  TELL ASSEMBLER ABOUT DSECT BASE REGISTERS                            27860018
         SPACE                                                          27930018
         USING TDIREC,TDIR              TDIR ENTRY DSECT BASE           28000018
         USING FASTAB,FAST              FAST TABLE ENTRY DSECT BASE     28070018
         USING IHKZZAVT,AVT             ADDR VECTDR TABLE DSECT BASE    28140018
         SPACE 2                                                        28210018
*    C H A I N   S A V E   A R E A S   FOR   T R A C I N G              28280018
         SPACE                                                          28350018
         LA    WOK,SAVAR                GET ADDR OF MODULE SAVE AREA    28420018
         ST    WOK,ATE(SAV)             PLACE IT IN R/I'S SAVE AREA     28490018
         ST    SAV,FOUR(WOK)            PLACE R/I SAVE AREA ADDR        28560018
*                                       - IN MODULE SAVE AREA           28630018
         LR    SAV,WOK                  MOVE SAVE AREA ADDRESS FOR      28700018
*                                       - MODULE LINKAGES               28770018
         MVC   RIEODAD+ONE(L3),D33(PAR) GET R/I EODAD ADDRESS IN SAFE   28840018
*                                       - PLACE                         28910018
         SPACE 2                                                        28980018
*    S E T / U P   N E W   M O D U L E   B A S E   A D D R E S S        29050018
         SPACE                                                          29120018
         LM    BAC,BAS,TWLV(SAV)        RESTORE RDR REGISTERS AND GET   29190018
*                                       - NEW MODULE BASE               29260018
         USING *,BAS                    TELL ASSEMBLER OF BASREG CHANGE 29330018
BASE     DS    0H                       USE THIS ADDR FOR MODULE BASE   29400018
         SPACE                                                          29470018
         BR    POINT                    CONTINUE WITH RDR WORK          29540018
         EJECT                                                          29610018
*    W A I T   FOR   W O R K   ON THE   R J E   Q U E U E               29680018
         SPACE                                                          29750018
WAIT     L     WOK,IHKZZRCS             GET ADDRESS OF RJE COMM SWITCH  29820018
         NI    ZERO(WOK),QEMPTY         INDICATE NO WORK ON RJE Q       29890018
         SPACE                                                          29960018
         LA    PAR,QMECB                GET ADDRESS OF ECB TO WAIT ON   30030018
         L     GO,IHKZZDSP              GET ENTRY POINT OR RJE DISPATCH 30100018
         BALR  BAC,GO                   WAIT IN DISPATCHER FOR WORK ON  30170018
*                                       - THE RJE Q                     30240018
         SPACE 2                                                        30310018
*    D E Q U E U E   AN   E N T R Y   FROM THE   R J E   I N P U T      30380018
*     Q U E U E   ( N U M B E R   3 9 )                                 30450018
         SPACE 2                                                        30520018
*  SET UP QMPA FOR DEQUEUE OPERATION                                    30590018
         SPACE 1                                                        30660018
DEQ      MVI   QMPOP,DQ                 FUNCTION CODE FOR DEQUEUE       30730018
         XC    QMPEB(L4),QMPEB          ZERO 2ND WORD OF QMPA           30800018
         XC    QMECB(L8),QMECB          ZERO ECB BEING PASSED TO QMGR   30870018
         LA    ZIP,QMECB                GET ADDRESS OF ECB              30940018
         ST    ZIP,QMCAN                PLACE IT IN QMPA                31010018
         ST    ZIP,IHKZZRDE             PLACE IT IN THE AVT ALSO        31080018
         MVI   QMTPY,RJEQ               DEQ FROM RJE'S OWN QMGR Q       31150018
         MVI   SLASNULL,SLASH          CLEAN UP MESS LEFT BY     A37786 31170020
         MVI   SLASNULL+2,BLNK          OS READER INTERPRETER    A37786 31190020
         LA    PAR,QMPA                 GET ADDRESS OF QMPA FOR QMGR    31220018
         L     GO,IHKZZDQ2              GET ENTRY POINT TO DEQ          31290018
         BALR  BAC,GO                   CHECK RJE Q FOR WORK            31360018
         SPACE 2                                                        31430018
*    C H E C K   Q M G R   R E T U R N   C O D E   AND   S E E          31500018
*     H O W   D E Q U E U E   R E Q U E S T   W E N T                   31570018
         SPACE                                                          31640018
         B     *+4(GO)                  USE RETURN TO SEE WHAT OCCURRED 31710018
         B     PRCREC                   RC=0, WORK ON THE QUEUE         31780018
         B     WAIT                     RC=4  NO WORK ON QUEUE          31850018
B        B     B                        RC=8 NOT USED - FILL UP GAP     31920018
         SPACE                                                          31990018
*  QMGR I/O ERROR , EXECUTE RJE ABNORMAL CLOSEDOWN PROCEDURE RC=12      32060018
         SPACE                                                          32130018
KMASYOYO L     WOK,IHKZZRCS             GET ADDR OF RJE COMM SWITCH     32200018
         OI    ZERO(WOK),ABCLOS         INDICATE ABNORMAL CLOSEDOWN     32270018
GETOUT   L     BAC,RIEODAD              GET R/I END OF FILE ADDRESS     32340018
         L     SAV,SAVAR+FOUR           GET R/I SAVE AREA ADDRESSS      32410018
         LM    GO,BAS,SIXT(SAV)         RESTORE R/I REGISTERS           32480018
         XR    GO,GO                    PASS ZERO RETURN CODE           32550018
         BR    BAC                      BRANCH TO R/I END OF FILE       32620018
         EJECT                                                          32690018
*    P R O C E S S   R E C O R D S   IN AN   R J E   Q U E U E          32760018
*     E N T R Y                                                         32830018
         SPACE                                                          32900018
PRCREC   MVC   CANJOB(L8),QMPA          SAVE JOB NAME IN CANCEL         32970018
*                                       - COMMAND BUFFER                33040018
         L    TDIR,IHKZZTDR             GET BASE FOR TERMINAL DIRECTORY 33110018
         A    TDIR,TDIROF               ADD RECORD TDIR OFFSET TO GET   33180018
*                                       - TERMINAL DIRECTORY ENTRY ADDR 33250018
         ST   TDIR,INTLST+ATE           PUT TDIR ENTRY ADDRESS IN JPR   33320018
*                                       - AND CMDPRO PARAMETER LIST     33390018
         MVI   RDRJIB,DEFOPT            REINITIALIZE TO DEFAULT OPTIONS 33460018
         XC    RDRALT(L4),RDRALT        REINITIALIZE FAST TABLE ENTRY   33530018
*                                       - INFORMATION                   33600018
         TM    QMSTA,JQUED              IS THIS JOB ALREADY ENQUED ON   33670018
*                                       - THE OS INPUT QUEUE            33740018
         BO    PROC                     YES, PROGRAM IS INITIALIZE TO   33810018
*                                       - FLUSH JCL IN FIRST Q ENTRY    33880018
         SPACE                                                          33950018
         MVI   JCL,INIT                 JOB NOT ENQUEUED ON OS INPUT Q  34020018
*                                       - SO INITIALIZE INPUT PROCESING 34090018
*                                       - STATUS AND PROCESS ENTRY      34160018
         SPACE 2                                                        34230018
*    I N I T I A L I Z E   FOR   P R O C E S S I N G   OF               34300018
*     L O G I C A L   R E C O R D S   IN A   Q   E N T R Y              34370018
         SPACE                                                          34440018
PROC     LA    RECAD,REC-80             INITIALIZE RECORD ADDRESS       34510018
         BAL   BAC,DUMWAT               GIVE C/E CHANCE TO SERVICE LINE 34580018
         SPACE                                                          34650018
         TM    COUNT,NUM                GET THE COUNT  OF LOGICAL       34720018
*                                       - RECORDS IN Q RECORD           34790018
         BM    EOQE                     NO RECORDS TO PROCESS IN Q      34860018
*                                       - RECORD, PROCESS END OF ENTRY  34930018
         BO    UNO                      ONE RECORD TO PROCESS IN Q REC  35000018
         SPACE                                                          35070018
*  THERE ARE TWO LOGICAL RECORDS TO PROCESS IN THIS Q RECORD            35140018
         SPACE                                                          35210018
         LA    CNT,TRE                  INITIALIZE TO PROCESS TWO REC   35280018
         SPACE                                                          35350018
PRCAGN   BAL   BAC,DUMWAT               GIVE C/E CHANCE TO SERVICE LINE 35420018
         SPACE                                                          35490018
         BCT   CNT,CTNPRC               ANY RECORDS LEFT TO PROCESS     35560018
         SPACE                                                          35630018
*  NO MORE LOGICAL RECORDS IN THIS Q RECORD TO PROCESS                  35700018
         SPACE                                                          35770018
         L     WOK,TTR                  GET TTR OF NEXT RECORD IN Q     35840018
*                                       - ENTRY                         35910018
         LTR   WOK,WOK                  SEE IF THERE IS A TTR FOR       35980018
*                                       - ANOTHER Q RECORD TO PROCESS   36050018
         BZ    EOQE                     NO, EXECUTE END OF Q ENTRY      36120018
*                                       - REQUIREMENTS                  36190018
         EJECT                                                          36260018
*    R E A D   THE   N E X T   R E C O R D   IN THIS   Q   E N T R Y    36330018
         SPACE                                                          36400018
         MVI   QMPCM,RD1                MORE RECORDS IN THIS Q ENTRY -- 36470018
*                                       - READ ONE Q RECORD             36540018
         MVI   QMPOP,READ               READ OPERATION REQUESTED        36610018
         ST    WOK,QMPEX                GIVE QMGR TTR OF NEXT Q RECORD  36680018
         L     GO,IHKZZSSS              GET DESIRED QMGR ENTRY POINT    36750018
         LA    PAR,QMPA                 PASS QMGR ITS PARMS             36820018
         BALR  BAC,GO                   GO AND READ A RECORD FROM Q     36890018
         SPACE                                                          36960018
         LTR   GO,GO                    WAS IT A GOOD READ              37030018
         BZ    PROC                     YEP, PROCESS RECORDS IF ANY     37100018
         SPACE                                                          37170018
*  QMGR ENCOUNTERED ERROR ON READ - NEED TO CHECK THE BEAUTY OUT        37240018
         SPACE 2                                                        37310018
*    E R R O R   P R O C E S S I N G   ON   Q M G R   R E A D           37380018
*     O P E R A T I O N S                                               37450018
         SPACE                                                          37520018
         BAL   BAC,DUMWAT               GIVE C/E CHANCE TO SERVICE LINE 37590018
         SPACE                                                          37660018
*  BLANK OUT VARIABLE MESSAGE TEXT BUFFER                               37730018
         SPACE                                                          37800018
         LA    WOK,SNDMSG67             REMBER WHERE WE ARE BE4 BLNKING 37870018
BLANK    MVI   MTXT,BLNK                MOVE INITIAL BLANK IN MSG TXT   37940018
         MVC   MTXT+ONE(LTXT),MTXT      CASCADE BLANK THRUOUT MSG TXT   38010018
         BR    WOK                                                      38080018
         SPACE                                                          38150018
*  SEND MESSAGE FIRST TO REMOTE USER                                    38220018
*    MESSAGE -- IHKX63I DISK ERROR QMGR JOBNAME                         38290018
         SPACE                                                          38360018
SNDMSG67 MVI   MSGLNG,L67               MOVE IN VARIABLE MSG TEXT LEN   38430018
         MVI   MSGOFF+ONE,O67           MOVE IN MSG OFFSET              38500018
         BAL   BAC,GOSEND               SEND BEAUTY TO REMOTE USER      38570018
         SPACE                                                          38640018
*  SEND SAME MESSAGE TO CENTRAL OPERATOR                                38710018
         SPACE                                                          38780018
         XC    DESTIN(L4),DESTIN        INDICATE MSG FOR CENTRAL EYES   38850018
         BAL   BAC,GOSEND1                                              38920018
         SPACE                                                          38990018
         LA    POINT,JOBCAN             SET UP TO CANCEL JOB IF         39060018
*                                       - THIS IS REQUIRED              39130018
         LA    PONT2,DELIT1             SET UP TO DELETE BAD Q ENTRY    39200018
         TM    JCL,HAVJCL               CURRENTLY PROCESSING JCL        39270018
         BO    GENUL1                   YES, ENQUE JOB BEFORE CANCELING 39340018
*                                       - JOB AND DELETING QUEUE ENTRY  39410018
         BR    PONT2                    NO, JUST DELETE Q ENTRY         39480018
         EJECT                                                          39550018
*    P R O C E S S   A   L O G I C A L   R E C O R D   IN   A   Q       39620018
*     R E C O R D                                                       39690018
         SPACE                                                          39760018
CTNPRC   LA    RECAD,D80(RECAD)         GET ADDRESS OF RECORD TO BE     39830018
*                                       - PROCESSED                     39900018
         CLC   ZERO(TWO,RECAD),SLASNULL IS THIS A JCL STATEMENT         39970018
         BE    PRCJCL                   YES, PROCESS RECORD AS JCL      40040018
         SPACE                                                          40110018
         TM    JCL,HAVJCL               WAS LAST RECORD JCL             40180018
         BO    ENDJCL                   YES, GIVE R/I A // NULL TO ENQ  40250018
*                                       - PREVIOUS JOB                  40320018
         SPACE 2                                                        40390018
*    P R O C E S S   L O G I C A L   R E C O R D   AS AN   R J E        40460018
*     S T A T E M E N T                                                 40530018
         SPACE 1                                                        40600018
DONTSKIP ST    RECAD,INTLST             SET UP PARM LIST                40670018
         CLC   ZERO(TRE,RECAD),BADJOB   CHECK FOR JECL IDENTIFIER       40740018
         BNE   NULL                     NOT JECL TELL USER ABOUT ERROR  40810018
         SPACE                                                          40880018
         LA    SCAN,TRE(RECAD)          STEP PAST JECL IDENTIFIER       40950018
         BAL   WOK,SCANNB               GET FIRST NON-BLANK PAST RECORD 41020018
*                                       - IDENTIFIER                    41090018
         ST    SCAN,INTLST              PLACE OPERATION FIELD ADDRESS   41160018
*                                       - IN IHKCAINT PARAMETER LIST    41230018
         LTR   GO,GO                    CHECK TO SEE IF NON-BLANK WAS   41300018
*                                       - FOUND IN RECORD LIMITS        41370018
         BZ    NULL                     NO BLANK IN RECORD -- PROCESS   41440018
*                                       - ERROR                         41510018
         SPACE 2                                                        41580018
*    C H E C K   R E C O R D   FOR   J E D   O P E R A T I O N          41650018
         SPACE                                                          41720018
         CLC   ZERO(L4,SCAN),JED        DO WE HAVE A JED OPERATION      41790018
         BE    PRCJED                   PROCESS RECORD AS A JED RECORD  41860018
         EJECT                                                          41930018
*    P R O C E S S   R E C O R D   AS A   W O R K   S T A T I O N       42000018
*     C O M M A N D   OR   C O N T I N U E D   J E D  S T A T E M E N T 42070018
         SPACE                                                          42140018
         MVI        INTLST,LGN          NO JED CHEAT AND SAY ITS A      42210018
*                                       - LOGON COMMAND                 42280018
         CLC   ZERO(L6,SCAN),LOGON      WAS IT A GOOD GUESS             42350018
         BE    PRCCMD                   YES, PROCESS COMMAND            42420018
         SPACE                                                          42490018
         MVI   INTLST,RJS               BAD GUESS BUT ODDS WERE 13 TO 1 42560018
*                                       - TRY AN RJSTART                42630018
         CLC   ZERO(L8,SCAN),RJSTART    IS THIS A GOOD QUESS            42700018
         BE    PRCCMD                   YES, 1 FOR 2 ISNT BAD - PROCESS 42770018
         SPACE                                                          42840018
         MVI   INTLST,STA               QUESSED WRONG AGAIN TRY STATUS  42910018
         CLC   ZERO(L7,SCAN),STATUS     CHECK TO SEE IF IT IS A STATUS  42980018
         BE    PRCCMD                   HOW ABOUT THAT SPORT FANS       43050018
*                                       - PROCESS ONE STATUS COMMAND    43120018
         SPACE                                                          43190018
         MVI   INTLST,OUT               WOULD YOU BELIEVE AN OUTPUT CMD 43260018
         CLC   ZERO(L7,SCAN),OUTPUT     NO, CHECK THE BEAUTY ANYHOW     43330018
         BE    PRCCMD                   PROCESS OUTPUT LUCKY QUESS      43400018
         SPACE                                                          43470018
         MVI   INTLST,MGR               SORRY ABOUT THAT QUESS, HOW     43540018
*                                       - ABOUT A MSGR COMMAND          43610018
         CLC   ZERO(L5,SCAN),MSGR       COULD BE, MAYBE PETE IS GETTING 43680018
*                                       - BRAVE                         43750018
         BE    PRCCMD                   SURE ENOUGH, PROCESS HIS MSG    43820018
         SPACE                                                          43890018
         MVI   INTLST,RJD               TIME TO TRY THE OLD RJEND CMDS  43960018
*                                       - START WITH RJEND              44030018
         CLC   ZERO(L6,SCAN),RJEND      THIS QUESSING IS GETTING OLD    44100018
*                                       - ARE WE RIGHT THIS QUESS       44170018
         BE    PRCCMD                   USER IS CALLING IT QUITS        44240018
         SPACE                                                          44310018
         MVI   INTLST,RJF               MAYBE WE HAD A LINE ERROR       44380018
*                                       - WORTH A GUESS                 44450018
         CLC   ZERO(L6,SCAN),RJENDF     STILL YET AND ANOTHER MOMENT OF 44520018
*                                       - TRUTH                         44590018
         BE    PRCCMD                   TELECOMMUNICATIONS ISNT PERFECT 44660018
         EJECT                                                          44730018
         MVI   INTLST,RJC               HEAVEN FORBID BUT QUESS THERE   44800018
*                                       - WAS AN ABNORMAL CENTRAL       44870018
*                                       - CLOSEDOWN                     44940018
         CLC   ZERO(L6,SCAN),RJENDC     CHECK FOR THIS UNFORTUNATE      45010018
*                                       - CONDITION                     45080018
         BE    PRCCMD                   COMPUTERS ARE NOT PERFECT ALSO  45150018
         SPACE                                                          45220018
         MVI   INTLST,LGF               MAYBE USER WANTS TO END HIS     45290018
*                                       - SESSION                       45360018
         CLC   ZERO(L7,SCAN),LOGOFF     DESPARATE GUESSING, CHECK CMD   45430018
         BE    PRCCMD                   LOGS USER OFF                   45500018
         SPACE                                                          45570018
         MVI   INTLST,CNTU              MAYBE HE WANTS TO RESUME        45640018
*                                       - RECEIVING OUTPUT              45710018
         CLC   ZERO(L9,SCAN),CONTINUE   CHECK FOR A CONTINUE COMMAND    45780018
         BE    PRCCMD                   PROCESS A CONTINUE              45850018
         SPACE                                                          45920018
         MVI   INTLST,DEL               IT STILL COULD BE A DELETE CMD  45990018
         CLC   ZERO(L7,SCAN),DELETE     CANT BE SURE SO CHECK IT        46060018
         BE    PRCCMD                   GET RID OF UNWANTED JOB         46130018
         SPACE                                                          46200018
         MVI   INTLST,BRD               MAYBE THE USER WANTS THE        46270018
*                                       - BROADCAST MESSAGES            46340018
         CLC   ZERO(L8,SCAN),BRDCSTR    ODDS ARE REALLY LOOKING UP,     46410018
*                                       - CHECK FOR BRDCSTR COMMAND     46480018
         BE    PRCCMD                   ITS A BRDCSTR, WHAT EVER THAT   46550018
*                                       - MEANS                         46620018
         SPACE                                                          46690018
         MVI   INTLST,ALT               IF ITS A COMMAND ITS AN ALERT   46760018
         CLC   ZERO(L6,SCAN),ALERT      IS IT A COMMAND                 46830018
         BE    PRCCMD                   WHY YES IT IS AN ALERT COMMAND  46900018
         EJECT                                                          46970018
         SPACE 2                                                        47040018
*    N O   C O M M A N D   R E C O G N I Z E D   BY   R J E             47110018
*     P R E S E N T   IN THE   I N P U T   S T R E A M                  47180018
         SPACE                                                          47250018
NULL     TM    JPR,JEDCTN               IS JED CONTINUATION OUTSTANDING 47320018
         BO    PRCJED1                  YES, PROCESS CONTINUED JED      47390018
         SPACE                                                          47460018
         MVI   INTLST,UNK               NO, HAVE UNDEFINED OPERATION    47530018
         SPACE                                                          47600018
GOCMD    LA    PAR,INTLST               GET IHKCAINT PARAMETER LIST AD  47670018
         ST    RECAD,INTLST+FOUR        GIVE CMD INT ADDR OF RECORD     47740018
         NI    JPR,VOIDJED              CLEAR RESIDUAL JED OPTIONS      47810018
         L     GO,RDRCAINT              GET IHKCAINT ENTRY POINT        47880018
         LA    BAC,PRCAGN               PROCESS THE NEXT RECORD ON RETN 47950018
         BR    GO                       GO LET IHKCAINT HAVE A CRACK AT 48020018
*                                       - PROCESSING THE RECORD         48090018
               SPACE 2                                                  48160018
*    P R O C E S S   R J E   W O R K   S T A T I O N   C O M M A N D S  48230018
         SPACE                                                          48300018
PRCCMD   TM    JPR,JEDCTN               FIRST CHECK IF A CONTINUED JED  48370018
*                                       - IS  OUTSTANDING               48440018
         BZ    GOCMD                    NO, PROCESS RECORD WITH A CLEAR 48510018
*                                       - CONSCIOUS                     48580018
         SPACE                                                          48650018
         LA    WOK,GOCMD                GO PROCESS CMD WHEN HOUSE IS    48720018
*                                       - AGAIN IN ORDER                48790018
         SPACE 2                                                        48860018
*    H A N D L E   J E D   C O N T I N U A T I O N   N O T              48930018
*     C O N C E I V E D   BUT   E X P E C T E D                         49000018
         SPACE                                                          49070018
NOJED    XC    INTLST+FOUR(L4),INTLST+FOUR ZERO RECORD ADDRESS TO SHOW  49140018
*                                       - NO EXPECTED CONTINUATION      49210018
         LA    PAR,INTLST               GET PARM LIST ADDRESS           49280018
         L     GO,RDRCHJPR              GET JPR ENTRY POINT             49350018
         BALR  BAC,GO                   GIVE JPR CONTROL                49420018
         SPACE                                                          49490018
         NI    JPR,VOIDJED              GET JED OUT OF SYSTEM           49560018
         SPACE                                                          49630018
         DELETE EPLOC=RDRZZJPR          GET JED PROCESSOR OUT OF SYSTEM 49700018
         SPACE                                                          49770018
         BR    WOK                      RETURN TO MAINLINE              49840018
         EJECT                                                          49910018
*    P R O C E S S   J C L   S T A T E M E N T S   IN   Q   E N T R Y   49980018
         SPACE 2                                                        50050018
PRCJCL   TM    JPR,JEDCTN               IS JED PROCESSOR WAITING ON     50120018
*                                       - CONTINUATION                  50190018
         BZ    PRCJCL1                  NO, PROCESS RECORD WITH A CLEAR 50260018
*                                       - CONSCIOUS AND FAINT HEART     50330018
         BAL   WOK,NOJED                CLEAR UP ERROR IN INPUT STREAM  50400018
*                                       - AND LET JED PROCESSOR IN ON   50470018
*                                       - THE ACTION                    50540018
         SPACE                                                          50610018
PRCJCL1  TM    JCL,FLUSH                IS THERE A FLUSH JCL CONDITION  50680018
*                                       - IN EFFECT                     50750018
         BO    PRCAGN                   YES, IGNORE THE BEAUTY AND SEE  50820018
*                                       - IF THERE IS JECL IN Q ENTRY   50890018
         SPACE                                                          50960018
         OI    JCL,HAVJCLJO             REMBER NEXT TIME THAT THIS TIME 51030018
*                                       - A JCL RECORD WAS PROCESSED    51100018
*                                       - AND SET HAVE JOB INDICATOR ON 51170018
         SPACE                                                          51240018
SCANB    LA    GO,D71(RECAD)            INITIALIZE END OF SCAN          51310018
         LR    SCAN,RECAD                                               51380018
MORE     LA    SCAN,ONE(SCAN)           INITIALIZE OR STEP TO NEXT CHAR 51450018
         CR    SCAN,GO                  SHOULD SCAN BE STOPED           51520018
         BNL   TSTCTN                   YES,CONTINUE WITH PROCESSING    51590018
         SPACE                                                          51660018
         CLI   ZERO(SCAN),BLNK          CHECK FOR BLANK                 51730018
         BNE   MORE                     LOOK SOME MORE IF NONBLANK      51800018
         SPACE                                                          51870018
         LR    NAM,SCAN                 KEEP ADDR TO COMPUTE JOBNAME    51940018
         BAL   WOK,SCANNB               SCAN FOR FIRST NON-BLANK IN     52010018
*                                       - RECORD                        52080018
         SPACE                                                          52150018
         LTR   GO,GO                    NONBLANK FOUND IN RECORD LIMITS 52220018
         BZ    TSTCTN                   NO, HAVE A POSSIBLE 11 NULL     52290018
         EJECT                                                          52360018
*    C H E C K   FOR A   J O B   S T A T E M E N T                      52430018
         SPACE                                                          52500018
         CLC   ZERO(L3,SCAN),JOBOP      DOES OPERATION INDICATE RECORD  52570018
*                                       - IS A JOB CARD                 52640018
         BE    GOTJOB                   DO SPECIAL JOB CARD PROCESSING  52710018
         SPACE 2                                                        52780018
*    T E S T   J O B C A R D   U S E R  E X I T                         52850018
*     R E Q U I R E M E N T S                                           52920018
         SPACE                                                          52990018
MABCTN   NI    JOB,NOJBCAR              NOT PROCESSING JOB CARD         53060018
         TM    JOB,JOBCTN               DOES USER EXIT EXPECT JOB CARD  53130018
*                                       - CONTINUATION                  53200018
         BO    JOBEX                    GIVE USER EXIT SOMETHING        53270018
         SPACE 2                                                        53340018
*    P A S S   R / I   J C L   R E C O R D   TO   P R O C E S S         53410018
         SPACE                                                          53480018
PASS1    LA    POINT,PRCAGN             REMEMBER TO PROCESS NEXT RECORD 53550018
PASS2    LR    PAR,RECAD                GET ADDRESS OF RECORD FOR R/I   53620018
         SPACE                                                          53690018
PASS     STM   BAC,BAS,SAVAR+TWLV       SAVE RDR REG TO PICK UP         53760018
*                                       - PROCESSING AT NEXT R/I GET    53830018
         L     SAV,SAVAR+FOUR           GET R/I SAVE ARE ADDRESS        53900018
         ST    PAR,D24(SAV)             GIVE RECORD ADDRESS TO R/I      53970018
         LM    BAC,BAS,TWLV(SAV)        RESTORE R/I REGISTERS           54040018
         SPACE                                                          54110018
         MVI   TWLV(SAV),DONE           SET RETURN INDICATOR            54180018
         XR    GO,GO                    PASS ZERO RETURN CODE           54250018
         BR    BAC                      RETURN TO R/I WITH RECORD       54320018
         EJECT                                                          54390018
*    P R O C E S S   J O B   C A R D                                    54460018
         SPACE                                                          54530018
GOTJOB   LA    PAR,QMPA                 GET ADDRESS OF THE JOBNAME      54600018
         L     GO,IHKZZSCH              GET ENTRY POINT FOR SEARCH      54670018
         BALR  BAC,GO                   GO AND FIND FAST TABLE ENTRY    54740018
*                                       - FOR THIS JOB                  54810018
         SPACE                                                          54880018
         LTR   GO,GO                    JOB NAME FOUND IN FAST TABLE    54950018
         BNZ   FLUSHIT                  FLUSH JCL IN THIS Q ENTRY       55020018
         SPACE                                                          55090018
         LR    FAST,PAR                 SET UP FAST TABLE ENTRY DSECT   55160018
*                                       - BASE                          55230018
         MVC   FASTUSE(L3),TDIRUSID     PLACE USER ID IN FAST TABLE     55300018
*                                       - ENTRY                         55370018
         SPACE                                                          55440018
PASREC   LR    PAR,RECAD                GET RECORD ADDR FOR USER EXIT   55510018
PASLAS   LA    BAC,VALENT               REMBER WHERE TO GO DONT SAY IT  55580018
         SPACE                                                          55650018
PASLAS1  NI    JOB,NOJOBC               SET JOB CARD CONTINUATION OFF   55720018
*                                       - UNTIL STATUS IS DETERMINED    55790018
         L     GO,IHKZZSOC              GET ADDRESS OF USER EXIT ENTRY  55860018
*                                       - POINT TABLE                   55930018
         L     GO,ATE(GO)               GET ENTRY POINT OF JOBCARD      56000018
*                                       - USER EXIT                     56070018
         BR    GO                       PASS RECORD TO USER EXIT        56140018
         SPACE                                                          56210018
VALENT   CLI   D71(RECAD),BLNK          IS THIS STATEMENT CONTINUED     56280018
         BE    NOCTN1                   NO, DONT HAVE TO WORRY WITH     56350018
*                                       - USER EXIT END OF FILE         56420018
         SPACE                                                          56490018
         OI    JOB,JOBCTN               REMEMBER USER EXIT NEED OF      56560018
*                                       - CONTINUATION                  56630018
NOCTN1   TM    JOB,HAVJOB               NEED TO DO SPECIAL PROCESSING   56700018
*                                       - FOR JOBNAME                   56770018
         BZ    PASS1                    NO, THIS IS ONLY JOB CONTINUED  56840018
         EJECT                                                          56910018
*    M O V E   J O B N A M E   B A C K   INTO   J O B   C A R D         56980018
         SPACE                                                          57050018
         LA    SCAN,FOUR(RECAD)         GET ADDRESS OFF 2ND CHARACTER   57120018
         SR    NAM,SCAN                 GET LENGTH OF JOBNAME LESS ONE  57190018
*                                       - TO EXECUTE A MOVE             57260018
         EX    NAM,MOVJOB               MOVE THE JOBNAME FROM THE       57330018
*                                       - CANCEL BUFFER BACK TO RECORD  57400018
         B     PASS1                    GIVE RECORD TO R/I              57470018
         SPACE 2                                                        57540018
*    P R O C E S S   R E C O R D   O T H E R   T H A N   J O B          57610018
*     C A R D   FOR   J O B   C A R D   U S E R   E X I T               57680018
         SPACE                                                          57750018
JOBEX    CLC   ZERO(L4,SCAN),EXEC       IS THIS AN EXEC  OPERATION      57820018
         LA    PAR,SLASNULL             PASS USER // NULL               57890018
         BE    PASLAS                   GIVE IT TO HIM FOR END OF JOB   57960018
*                                       - STATEMENT                     58030018
         SPACE                                                          58100018
         CLC   ZERO(L2,SCAN),DD         IS IT A DD OPERATION            58170018
         BE    PASLAS                   YES, GIVE USER // NULL          58240018
         SPACE                                                          58310018
         B     PASREC                   NO, GIVE USER THIS RECORD AS    58380018
*                                       - JOB CONTINUATION              58450018
         SPACE                                                          58520018
*   PROCESS DISTURBING RESULTS OF RECORD SCANS                          58590018
         SPACE                                                          58660018
TSTCTN   LR    SCAN,RECAD               RESTORE SCAN TO POINT TO //     58730018
         CLC   ZERO(L80,RECAD),SLASNULL TEST THIS UNKNOWN AGAINST A     58800018
*                                       - // NULL                       58870018
         BNE   MABCTN                   SEE IF USER EXIT WANTS CONTINUE 58940018
*                                       - JOB STATEMENT OR PROCESS      59010018
*                                       - AS REGULAR JCL                59080018
         LA    PONT2,FLUSHIT  ENQUEUE JOB - FLUSH REST OF STREAM A53596 59150021
         SPACE 2                                                        59290018
*    G E N E R A T E   A   / /   N U L L   S T A T E M E N T            59360018
         SPACE                                                          59430018
GENNUL2  LA    POINT,ACKJOB             SET UP TO ACKNOWLEDGE JOB       59500018
GENUL1   NI    JCL,HAVJECL              TURN OFF JCL AND JOB INDICATORS 59570018
         SPACE                                                          59640018
*    MARK JOB AS AT LEAST ENQUEUED ON OS INPUT QUEUE                    59710018
         SPACE                                                          59780018
         L     GO,IHKZZ447              GET ENTRY POINT                 59850018
         LA    PAR,QMPA                                                 59920018
         BALR  BAC,GO                                                   59990018
         SPACE                                                          60060018
         LA    PAR,SLASNULL             GET // NULL FOR USER EXIT       60130018
CHEKJUX  TM    JOB,JOBCTN               USER EXIT EXPECT CONTINUATION   60200018
         BZ    PASS                                                     60270018
         SPACE                                                          60340018
         BAL   BAC,PASLAS1              GIVE THE BEAUTY TO USER EXIT    60410018
         SPACE                                                          60480018
OVERIT   LA    PAR,SLASNULL             GET // NULL FOR R/I             60550018
         B     PASS                                                     60620018
         EJECT                                                          60690018
*    P R O C E S S   J E D   AND   I T S   C O N T I N U A T I O N      60760018
         SPACE                                                          60830018
PRCJED   LOAD  EPLOC=RDRZZJPR           GET THE JED PROCESSOR IN CORE   60900018
         ST    ZIP,RDRCHJPR             SAVE THE ADDRESS FOR CONTINUED  60970018
*                                       - LINKAGE                       61040018
         OI    JPR,HAVJED               REMBER JED PROCESSOR IN CORE    61110018
         SPACE                                                          61180018
PRCJED1  NI    JPR,NOJEDC               GED RID OF CONTINUED JED STATUS 61250018
         CLI   D71(RECAD),BLNK           IS RECORD CONTINUED            61320018
         BE    JEDNOTC                  NO,REMBER JED NOT CONTINUED     61390018
         SPACE                                                          61460018
         OI    JPR,JEDCTN               REMEMBER JED CONTINUED          61530018
         SPACE 2                                                        61600018
*    S E T   U P   J E D   P R O C E S S O R   P A R A M E T E R        61670018
*     L I S T   AND   P R O C E S S   S T A T E M E N T                 61740018
         SPACE 2                                                        61810018
JEDNOTC  ST    RECAD,INTLST+FOUR        GIVE IT ADDR OF RECORD TO PROC  61880018
         LA    PAR,INTLST               GIVE IT ADDR OF PARM LIST       61950018
         L     GO,RDRCHJPR              GET ENTRY POINT OF JPR          62020018
         BALR  BAC,GO                   GIVE JPR CONTROL                62090018
         SPACE                                                          62160018
         LR    NAM,GO                   SAVE RETURN CODE                62230018
         TM    JPR,JEDCTN               MORE JED TO COME                62300018
         BO    TSTMOR                   YES,CHECK RETURN CODE           62370018
         SPACE                                                          62440018
         DELETE EPLOC=RDRZZJPR          GET RID OF JED PROCESSOR        62510018
         SPACE                                                          62580018
TSTMOR   LTR   NAM,NAM                  TEST JPR RETURN CODE            62650018
         BZ    PRCAGN                   GOOD PROCESS NEXT RECORD        62720018
         SPACE                                                          62790018
         NI    JPR,HAVDEF               VOID ANY SELECTED JED           62860018
*                                       - OPTIONS                       62930018
         B     PRCAGN                   PROCESS NEXT RECORD             63000018
         EJECT                                                          63070018
*    P R O C E S S   E N D   OF   Q   E N T R Y                         63140018
         SPACE                                                          63210018
EOQE     TM    JCL,HAVJCL               WAS LAST RECORD PROCESSED JCL   63280018
         LA    PONT2,DELIT              SET UP TO DELETE Q ENTRY        63350018
         BO    GENNUL2                  GIVE R/I // NULL BEFORE         63420018
*                                       - CONTINUING WITH END OF Q      63490018
*                                       - PROCESSING                    63560018
         SPACE                                                          63630018
DELIT1   TM    JPR,JEDCTN               IS JED PROCESSOR HANGING AROUND 63700018
*                                       - FOR JED CONTINUATION          63770018
         BZ    DELIT                    NO, GO DELETE Q ENTRY           63840018
         SPACE                                                          63910018
         BAL   WOK,NOJED                CLEAR UP ERROR IN INPUT STREAM  63980018
         SPACE 2                                                        64050018
*    D E L E T E   P R O C E S S E D   Q   E N T R Y   FROM THE         64120018
*     R J E   Q U E U E   ( 3 9 )                                       64190018
         SPACE                                                          64260018
DELIT    EQU   *                                                 A35895 64280020
         MVI   IHKCELST,BLNK      CLEAR FIRST BYTE OH IHKCEDIT   A35895 64300020
*                                 -WORK AREA FOR CENTRAL DATA    A35895 64320020
*                                 SETS TO USE FOR FUTURE JOBS    A35895 64340020
         MVC   IHKCELST+ONE(L179),IHKCELST  CLEAR REMAINING AREA A35895 64360020
         MVI   QMPOP,DELT         INDICATE TO QMGR DELETE REQUESTA35895 64380020
         MVI   JCL,FLUSH                GET READY TO PROCESS NEXT Q ENT 64400018
         LA    PAR,QMPA                 GET ADDRESS OF PARAMETER LIST   64470018
         L     GO,IHKZZELE              GET ENTRY POINT OF DELETE       64540018
         BALR  BAC,GO                   PASS CONTROL TO IEFQDELE        64610018
         SPACE                                                          64680018
         LTR   GO,GO                    TEST SUCCESS OF DELETE REQUEST  64750018
         BNZ   KMASYOYO                 ERROR WILL NOT BE TOLERATED,    64820018
*                                       - INDICATE ABNORMAL CLOSE DOWN  64890018
         SPACE                                                          64960018
         LA    BAC,DEQ                  REMBER WERE TO GO AFTER WAIT    65030018
         SPACE                                                          65100018
*  DUMMY WAIT TO ALLOW AMPLE TIME TO SERVICE TELECOMMUNICATIONS LINES   65170018
         SPACE                                                          65240018
DUMWAT   LA    PAR,WAITECB              GET ADDRESS OF POSTED ECB TO    65310018
*                                       - WAIT ON                       65380018
         L     GO,IHKZZDSP              GET ENTRY POINT OF              65450018
*                                       - THE RJE DISPATCHER            65520018
         BR    GO                       WAIT IN LINE FOR NEXT TURN      65590018
*                                       - TO  PROCESS                   65660018
         EJECT                                                          65730018
*    H A N D L E   A B R U P T E N D   TO   J C L   IN THE              65800018
*     I N P U T   S T R E A M                                           65870018
         SPACE                                                          65940018
ENDJCL   CLC   ZERO(L9,RECAD),BADJOB    WAS JCL FOLLOWED BY RJENDF      66010018
         LA    PONT2,DONTSKIP           SET UP TO REPROCESS THIS RECORD 66080018
*                                       - ON R/I RETURN                 66150018
         BNE   GENNUL2                                                  66220018
*                                       GENERATE // NULL FOR R/I        66290018
         SPACE                                                          66360018
         BAL   POINT,GENUL1             CANCEL JOB ON RETURN FROM R/I   66430018
*                                       GENERATE // NULL FOR R/I        66500018
         SPACE 2                                                        66570018
*    C A N C E L   J O B   ON   R E T U R N   FROM   R/I                66640018
         SPACE                                                          66710018
JOBCAN   MVI   SLASNULL,SLASH          CLEAN UP MESS LEFT BY     A37786 66740020
         MVI   SLASNULL+2,BLNK          OS READER INTERPRETER    A37786 66770020
         LA    PAR,CANCMD               GET ADDRESS OF CANCEL    A37786 66800020
         SR    ZIP,ZIP                                             000C 66850018
         SVC   34                       CANCEL JOB WITH SUPERVISOR AID  66920018
         SPACE                                                          66990018
         MVI   FASTJIB,FASTDLTJ         TELL SDQ TO DELETE JOB          67060018
*                                       - WHEN IT COMPLETES             67130018
         B     HANDFAST                 UPDATE FAST TABLE ENTRY FOR JOB 67200018
         SPACE 2                                                        67270018
*    P R O C E S S   O N E   L O G I C A L   R E C O R D                67340018
*     IN A   Q   E N T R Y   R E C O R D                                67410018
         SPACE                                                          67480018
UNO      LA    CNT,TWO                  INITIALIZE TO PROCESS ONE       67550018
*                                       - RECORD                        67620018
         B     PRCAGN                   RESUME PROCESSING               67690018
         EJECT                                                          67760018
*    C H E C K   P R O C E S S I N G   OF   C E N T R A L   D A T A     67830018
*     S E T S                                                           67900018
         SPACE                                                          67970018
ACKJOB   DS    0H                                                       68040018
         MVI   SLASNULL,SLASH                                      000C 68110018
         MVI   SLASNULL+2,BLNK                                     000C 68180018
         MVC   FASTJIB(L1),RDRJIB       MOVE JOB INFO INTO FAST TABLE   68250018
*                                       - ENTRY FOR THIS JOB            68320018
         MVC   FASTALT(L4),RDRALT       MOVE USER INFO INFO FAST TABLE  68390018
*                                       - ENTRY FOR THIS JOB            68460018
         LA    SCAN,IHKCELST            GET ADDRESS OF CENTRAL DATA SET 68530018
*                                       - LIST                          68600018
         LA    NAM,ENDCELST             GET END OF CENTRAL DATA SET     68670018
*                                       - TABLE                         68740018
ACKJOB1  CLI   ZERO(SCAN),BLNK          WAS THIS ENTRY USED             68810018
         BE    ACKJOB2                  FINISHED WITH THIS JAZZ WRITE   68880018
*                                       - OUT JED TABLE FOR THIS JOB    68950018
         SPACE                                                          69020018
         CLI   D17(SCAN),PRCDS          WAS THIS DATA SET PROCESSED BY  69090018
*                                       - THE RJE JCL EDIT ROUTINE      69160018
         BNE   SNDMSG53                 NO, DD STATEMENT MISSING IN     69230018
*                                       - INPUT STREAM -- TELL USER     69300018
         SPACE                                                          69370018
PICUP    LA    SCAN,D18(SCAN)           STEP TO NEXT ENTRY IN DATA SET  69440018
         CR    SCAN,NAM                 ARE WE AT THE END OF THE TABLE  69510018
         BL    ACKJOB1                  CHECK THIS ENTRY IN THE TABLE   69580018
*                                       - IF NOT AT THE END             69650018
         SPACE 2                                                        69720018
*    W R I T E   O U T   J E D   T A B L E   FOR THIS   J O B           69790018
         SPACE                                                          69860018
ACKJOB2  EQU   *                                                 A35895 69880020
         MVI   IHKCELST,BLNK      CLEAR FIRST BYTE OH IHKCEDIT   A35895 69900020
*                                 -WORK AREA FOR CENTRAL DATA    A35895 69920020
*                                 SETS TO USE FOR FUTURE JOBS    A35895 69940020
         MVC   IHKCELST+ONE(L179),IHKCELST  CLEAR REMAINING AREA A35895 69960020
         ST    FAST,JEDLST        SET UP PARM LIST FOR JED       A35895 69980020
*                                 TABLE MANAGER                  A35895 70000020
         L     GO,IHKZZJMR              GET ENTRY POINT OF THIS ROUTINE 70070018
         LA    PAR,JEDLST               GET ADDRESS OF PARAMETER LIST   70140018
         BALR  BAC,GO                   WRITE OUT ONE JED TABLE FOR JOB 70210018
         SPACE                                                          70280018
         LTR   GO,GO                    WAS THERE AN ERROR ON THIS I/O  70350018
*                                       - OPERATION                     70420018
         BNZ   SNDMSG65                 TELL THE USER HE HAS TROUBLES   70490018
         SPACE 2                                                        70560018
*    S E N D   U S E R   J O B   A C K N O W L E G E M E N T            70630018
*     M E S S A G E                                                     70700018
         SPACE                                                          70770018
ACKJOB3  LOAD  EPLOC=RDRZZSTB           BRING IN STATUS PROCESSOR       70840018
         ST    FAST,STBLST              GIVE IT A PARAMETER             70910018
         EJECT                                                          70980018
*    A C K N O W L E D G E   A C C E P T E D   J O B                    71050018
         SPACE                                                          71120018
         LR    GO,ZIP                   GET ENTRY POINT OF STATUS       71190018
         LA    PAR,STBLST               PASS ROUTINES PARM LIST         71260018
         BALR  BAC,GO                   GO GET JOB STATUS               71330018
         SPACE                                                          71400018
         BAL   WOK,BLANK                BLANK OUT VARIABLE MESSAGE TEXT 71470018
         SPACE                                                          71540018
         MVC   MSTA(L10),ZERO(PAR)      MOVE JOB STATUSINTO MESSAGE     71610018
         DELETE EPLOC=RDRZZSTB          GET STATUS OUT OF MAIN STORAGE  71680018
         SPACE                                                          71750018
         ST    TDIR,INTLST+ATE          RESTORE CMD INT AND JPR PARM    71820018
*                                       - LIST                          71890018
         MVI   MSGOFF+ONE,O51           MOVE MSG OFFSET INTO PARM AREA  71960018
         MVI   MSGLNG,L51               MOVE VARIALE TEXT LENGTH INTO   72030018
*                                       - PARAMETER AREA                72100018
         MVC   MUSER(L3),TDIRUSID       MOVE USErID INTO MSG PARM AREA  72170018
         TM    JPR,HAVJED               JOB ACCEPTED WITH JED OR DEFAUL 72240018
         BZ    MOVDEF                   NO JED FOR THIS JOB USE DEFAULT 72310018
         SPACE                                                          72380018
         MVC   MOPT(L3),JED             MOVE JED INTO MESSAGE           72450018
         B     CONSTIT                  FINISHED UP                     72800018
         SPACE                                                          72870018
MOVDEF   MVC   MOPT(L7),DEFAULT         MOVE DEFAULT INTO MSG           72940018
CONSTIT  MVC   MJOB(L8),QMPA            MOVE JOBNAME INTO MSG           73010018
SENDIT   L     GO,IHKZZSOC              GET TABLE ADDRESS FOR USER EXIT 73080018
         L     GO,TWLV(GO)              GET JOBACK USER EXIT ADDRESS    73150018
         LA    PAR,MTXT                 GET ADDRESS OF ACK MSG          73220018
         BALR  BAC,GO                   LET EXIT EXAMINE MSG            73290018
         SPACE                                                          73360018
         LR    NAM,PAR                  SAVE USERS DESIRES              73430018
         BAL   BAC,GOSEND0              SEND RJE JOB ACK MESSAGE        73500018
         SPACE                                                          73570018
NEXTENT  LTR   NAM,NAM                  TEST USERS DESIRES              73640018
         BZ    HANDFAST                 NO ADDITION TO ACK REQUESTED    73710018
         SPACE                                                          73780018
         LA    PAR,MTXT                 GET ADDRESS PASSED TO USER EXIT 73850018
         CR    NAM,PAR                  ADDR RETURNED SAME AS PASSED    73920018
         BE    HANDFAST                 YES, HAVE DUMB RJE USER EXIT    73990018
         SPACE                                                          74060018
         MVI   MSGOFF+ONE,O30           HAVE ADDITION, SET UP MSG PARM  74130018
         MVI   MSGLNG,L30               SET MSGLNG                      74200018
         MVC   MTXT(L59),ZERO(NAM)      MOVE USERS MSG INTO BUFFER      74270018
         BAL   BAC,GOSEND1              SEND USERS MESSAGE              74340018
         EJECT                                                          74410018
         SPACE 2                                                        74480018
*    U P D A T E   F A S T A B L E   E N T R Y   FOR THIS   J O B       74550018
*     TO   R E F L E C T   P R O C E S S I N G                          74620018
         SPACE                                                          74690018
HANDFAST DS    0H                                                       74760018
         LR    PAR,FAST                 SET PARAMETERS FOR FAST TABLE   74830018
*                                       - MANAGER                       74900018
         L     GO,IHKZZFMR              GET ENTRY POINT OF FAST TABLE   74970018
*                                       - MANAGER                       75040018
         LR    BAC,PONT2                GET RETURN POINT FOR IHKCDFMR   75110018
         BR    GO                       UPDATE FAST TABLE ENTRY OF JOB  75180018
*                                       - ON DISK                       75250018
         SPACE 2                                                        75320018
         SPACE 2                                                        75390018
*     S C A N   F O R   N O N - B L A N K                               75460018
         SPACE                                                          75530018
SCANNB   LA    GO,D71(RECAD)            INITIALIZE END OF SCAN          75600018
OVERAGN  CLI   ZERO(SCAN),BLNK          TEST FOR BLANK                  75670018
         BCR   7,WOK                    NONBLANK FOUND RETURN WITH NEWS 75740018
         SPACE                                                          75810018
         LA    SCAN,ONE(SCAN)           STEP TO LOOK AT NEXT CHARACTER  75880018
         CR    SCAN,GO                  SEE IF SCANNING SHOULD CEASE    75950018
         BL    OVERAGN                  NO LOOK SOME MORE               76020018
         SPACE                                                          76090018
         XR    GO,GO                    INDICATE NO NONBLANK FOUND      76160018
         BR    WOK                      RETURN WITH INFO                76230018
         SPACE 2                                                        76300018
         SPACE    2                                                     76370018
*     D I S C A R D   U N D E S I R A B L E   J C L                     76440018
         SPACE                                                          76510018
FLUSHIT  MVI   JCL,FLUSH                INDICATE JCL TO BE FLUSH IN     76580018
*                                       - Q ENTRY                       76650018
         B     PRCAGN                   GET NEXT RECORD TO PROCESS      76720018
         EJECT                                                          76790018
         SPACE 2                                                        76860018
*     E R R O R   M E S S A G E   S U B R O U T I N E S                 76930018
         SPACE                                                          77000018
SNDMSG53 BAL   WOK,BLANK                CLEAR MSG TEXT AREA             77070018
         MVC   MDAS(L17),ZERO(SCAN)     MOVE DSNAME INTO MSG TEXT       77140018
         MVI   MSGOFF+ONE,O56           7OVE OFFSET INTO PARM LIST      77210018
         MVI   MSGLNG,L56              7OVE LENGTH INTO PARM LIST       77280018
         LA    BAC,PICUP               ET RETURN POINT                 77350018
         B     GOSEND                  >END MSG TO USER                 77420018
         SPACE 2                                                        77490018
SNDMSG65 MVI   MSGLNG,L65              7OVE MSG LENGTH INTO PARM LIST   77560018
         MVI   MSGOFF+ONE,O65          7OVE MSG OFFSET INTO PARM LIST   77630018
         LA    PAR,CANCMD               GET SVC 34 PARM TO CANCEL JOB   77700018
         SVC   34                       CANCEL JOB WITH CANCEL CMD      77770018
         SPACE                                                          77840018
         LR    BAC,PONT2                CONTINUE PROCESSING AFTER MSG   77910018
*                                       - IS SENT TO USER               77980018
         SPACE                                                          78050018
GOSEND   MVC   MJOB(L8),QMPA           7OVE JOBNAME INTO MSG TEXT       78120018
GOSEND0  ST    TDIR,DESTIN             &LACE TDIR ENTRY IN PARM LIST    78190018
GOSEND1  LA    PAR,RDRMSG              ET PARM LIST ADDRESS            78260018
         L     GO,IHKZZLDM             ET IHKCBLDM ENTRY POINT ADDR    78330018
         BR    GO                      BUILD AND PLACE MSG ON QUEUE     78400018
         SPACE 2                                                        78470018
*    F I N A L   S T E P S   OF   R J E   C L O S E D O W N             78540018
*     O H   R E A L L Y   - -    T H A T ' S   T E R R I F I C          78610018
         SPACE 2                                                        78680018
IHKCHASE DS    0H                                                       78750018
         USING *,GO                     SET UP A TEMPORARY BASE         78820018
         LM    AVT,BAS,SAVAR+D64        GET MODULE AND AVT BASE         78890018
         DROP  GO                       LET GO OF TEMPORARY BASE        78960018
         SPACE                                                          79030018
         B     GETOUT                   NO, APOLOGIZE AND REST UP AFTER 79100018
*                                       - A JOB WELL DONE               79170018
         EJECT                                                          79240018
         SPACE 2                                                        79310018
*        C O N S T A N T S   AND   W O R K   A R E A S                  79380018
         SPACE                                                          79450018
RJSTART  DC    CL8'RJSTART '                                            79520018
SAVAR    DC    15F'0'                   MODUULE SAVE AREA LESS 10 & 12  79590018
         SPACE                                                          79660018
         DC    A(DEQ)                   INITIAL VALUE FOR POINT         79730018
         DC    A(IHKCACOM)                                              79800018
         DC    A(BASE)                  MODULE BASE ADDR AFTER ENTRY    79870018
         SPACE                                                          79940018
RIEODAD  DC    F'0'                     ADDRESS OF R/I END OF FILE      80010018
RDRCAINT DC    V(IHKCAINT)                                              80080018
RDRCHJPR DC    F'0'                                                     80150018
         SPACE                                                          80220018
WAITECB  DC    X'40000000'              POSTED ECB FOR DUMMY WAIT       80290018
JEDLST   DC    F'0'                                                     80360018
         DC    X'80'                                                    80430018
         DC    AL3(IHKCEJDT)                                            80500018
         SPACE                                                          80570018
INTLST   DC    F'0'                                                     80640018
         DC    F'0'                                                     80710018
         SPACE                                                          80780018
STBLST   DC    F'0'                                                     80850018
         DC    A(IHKCACOM)                                              80920018
         DC    A(IHKCEJDT)                                              80990018
         SPACE                                                          81060018
QMECB    DC    2F'0'                                                    81130018
         SPACE                                                          81200018
BUF      DS    0CL176                                                   81270018
TTR      DC    F'0'                                                     81340018
REC      DC    CL160' '                                                 81410018
TDIROF   DC    F'0'                                                     81480018
COUNT    DC    C' '                                                     81550018
PAD      DC    CL7' '                                                   81620018
         SPACE                                                          81690018
SLASNULL DC    CL80'//'                                                 81760018
DD       DC    CL2'DD'                                                  81830018
         EJECT                                                          81900018
         SPACE                                                          81970018
IHKCEJDT DS    0CL98                                                    82040018
JEDMSG   DC    CL25' '                                                  82110018
JEDOUT   DC    CL25' '                                                  82180018
         SPACE                                                          82250018
         DS    0F                                                       82320018
QMPA     DS    0CL36                                                    82390018
QMCAN    DC    F'0'                                                     82460018
QMPEB    DC    F'0'                                                     82530018
QMPOP    DC    X'00'                                                    82600018
QMFLT    DC    X'0000'                                                  82670018
QMTST    DC    X'00'                                                    82740018
QMTLN    DC    H'0'                                                     82810018
QMNOT    DC    X'00'                                                    82880018
QMTPY    DC    X'27'                                                    82950018
QMSTA    DC    X'00'                                                    83020018
QMPRI    DC    X'00'                                                    83090018
QMLNK    DC    H'0'                                                     83160018
QMTID    DC    H'0'                                                     83230018
RESV     DC    H'0'                                                     83300018
QMWTQ    DC    F'0'                                                     83370018
QMELA    DC    F'0'                                                     83440018
QMPCM    DC    X'00'                                                    83510018
QMPCL    DC    AL3(QMPCA)                                               83580018
         SPACE                                                          83650018
QMPCA    DC    A(BUF)                                                   83720018
QMPEX    DC    F'0'                                                     83790018
PADD     DC    4X'00'                                                   83860018
         SPACE                                                          83930018
IHKCELST DC    CL180' '                                                 84000018
ENDCELST DS    0C                                                       84070018
RDRJIB   DC    X'80'                                                    84140018
RDRALT   DC    4X'00'                                                   84210018
         SPACE                                                          84280018
LOGOFF   DC    CL7'LOGOFF '                                             84350018
         SPACE                                                          84420018
         DS    0F                                                       84490018
RDRMSG   DS    0CL66                                                    84560018
DESTIN   DC    F'0'                                                     84630018
MSGOFF   DC    H'0'                                                     84700018
MSGLNG   DC    X'00'                                                    84770018
MTXT     DS    0CL59                                                    84840018
MJOB     DS    CL9                                                      84910018
MDAS     DS    0CL17                                                    84980018
MUSER    DS    CL4                                                      85050018
MSTA     DS    CL11                                                     85120018
MOPT     DS    CL7                                                      85190018
MSGPAD   DC    CL28' '                                                  85260018
         EJECT                                                          85330018
         SPACE                                                          85400018
RDRZZSTB DC    C'IHKCFSTB'                                              85470018
RDRZZJPR DC    C'IHKCHJPR'                                              85540018
         SPACE                                                          85610018
         DS    0F                                                       85680018
CANCMD   DC    H'19'                                                    85750018
         DC    H'0'                                                     85820018
         DC    C'CANCEL '                                               85890018
IHKCEJBN DS    0C                                                       85960018
CANJOB   DC    CL9' '                                              000C 86030018
         SPACE                                                          86100018
EXEC     DC    CL4'EXEC'                                           000C 86170018
MOVJOB   CLC   TWO(L2,RECAD),CANJOB                                     86240018
*                                                                       86310018
         SPACE                                                          86380018
JCL      DS    0C                                                       86450018
JOB      DS    0C                                                       86520018
JPR      DC    X'01'                                                    86590018
         SPACE                                                          86660018
*  READER INPUT PROCESSING STATUS INDICATORS                            86730018
         SPACE                                                          86800018
INIT     EQU   X'00'                    MASK TO INITIALIZE RDR INPUT    86870018
*                                       - STATUS, NO INPUT RESIDUE      86940018
FLUSH    EQU   X'01'                    FLUSH JCL BIT ON                87010018
*                                       - PROCESS JCL IF BIT OFF        87080018
JOBCTN   EQU   X'02'                    JOB CONTINUATION BIT ON         87150018
*                                       - NO CONTINUED JOB STATEMENT IF 87220018
*                                       - BIT OFF                       87290018
HAVJCL   EQU   X'04'                    PROCESSING JCL BIT ON           87360018
HAVJED   EQU   X'08'                    PROCESSING JED BIT ON           87430018
*                                       - PROCESSING JECL IF BIT OFF    87500018
*                                       - NO JED PROCESSING IF BIT OFF  87570018
JEDCTN   EQU   X'10'                    JED CONTINUATION BIT ON         87640018
*                                       - NO CONTINUED JED IF BIT OFF   87710018
HAVJOB   EQU   X'20'                    PROCESSING JOB IF ON            87780018
HAVJCLJO EQU   X'24'                    PROCESSING JCL AND JOB IF ON    87850018
NOJBCAR  EQU   X'DF'                    MASK TO SET HAVE JOB OFF        87920018
VOIDJED  EQU   X'E7'                    MASK USED TO REMOVE JED PRESENT 87990018
NOJEDC   EQU   X'EF'                    MASK TO SET CONTINUED JED OFF   88060018
HAVDEF   EQU   X'F7'                    MASK TO SET GOOD JED OFF        88130018
HAVJECL  EQU   X'DB'                    MASK TO SET PROCESSING JCL OFF  88200018
NOJOBC   EQU   X'FD'                    MASK TO SET CONTINUED JOB OFF   88270018
NOFLUSH  EQU   X'FE'                    MASK USED TO SET FLUSH BIT OFF  88340018
LOGON    DC    CL6'LOGON '                                              88410018
RJEND    DC    CL6'RJEND '                                              88480018
ALERT    DC    CL6'ALERT '                                              88550018
RJENDC   DC    CL6'RJENDC'                                              88620018
CONTINUE DC    CL9'CONTINUE '                                           88690018
DELETE   DC    CL7'DELETE '                                             88760018
MSGR     DC    CL5'MSGR '                                               88830018
BADJOB   DC    C'.. '                                                   88900018
RJENDF   DC    CL6'RJENDF'                                              88970018
JED      DC    CL4'JED '                                                89040018
OUTPUT   DC    CL7'OUTPUT '                                             89110018
BRDCSTR  DC    CL8'BRDCSTR '                                            89180018
JOBOP    DC    CL3'JOB'                                                 89250018
STATUS   DC    CL7'STATUS '                                        000C 89320018
DEFAULT  DC    CL7'DEFAULT'                                             89390018
         SPACE                                                          89460018
      IHKDSECT     TDIR,,FASTAB,JEDTAB,,AVT                             89530018
   END                                                                  89600018
