HSDQ   TITLE   'IHKCHSDQ -- RJE SYSOUT CLASS DEQUEUE MODULE'            00100017
IHKCHSDQ CSECT                                                          00200017
*********************************************************************** 00300017
*                                                                     * 00400017
*STATUS.                                                              * 00500017
*   CHANGE LEVEL 1                                                    * 00600017
*                                                                     * 00700017
*FUNCTION/OPERATION.                                                  * 00800017
*   THIS ROUTINE PROVIDES THE SYSOUT INTERFACE WITH OS QUEUE MANAGER  * 00900017
*   AND INITIATES RJE PROCESSING OF OS EXECUTED JOBS. THE SPECIFIC    * 01000017
*   FUNCTIONS OF SYSOUT DEQUEUER AND ITS INTERFACES WITH OS ARE AS    * 01100017
*   FOLLOWS.                                                          * 01200017
*                                                                     * 01300017
*   1.   AT SYSTEM STARTUP THE ECB FOR THE WRITER SUBTASK IS POSTED   * 01400017
*   COMPLETE BY THE INITIALIZE ROUTINES. AN EXCLUSIVE ENTRY TO THE OS * 01500017
*   QUEUE MANAGER BY THE SYSOUT DEQUEUE ROUTINE IS NECESSARY, IN      * 01600017
*   ORDER TO FURNISH OS WITH THE ADDRESS OF THIS ECB, REGARDLESS      * 01700017
*   OF WHETHER OUTPUT IS AVAILABLE. LASTLY THE COMPLETION BIT OF THE  * 01800017
*   STOP ACKNOWLEDGED ECB FOR IHKCBSDQ IS SET TO ZERO TO PREVENT      * 01900017
*   ROLL-OUT OF THIS ROUTINE BEFORE IT IS COMPLETED.                  * 02000017
*                                                                     * 02100017
*   2. THE STOP BIT IN THE RJE COMMUNICATIONS SWITCH IS TESTED        * 02200017
*   TO DETERMINE WHETHER A STOP RJE SITUATION IS PENDING IN THE       * 02300017
*   SYSTEM ( THAT IS THE OPERATOR ENTERED A STOP RJE COMMAND).  IF    * 02400017
*   SET ON, THE SYSDEQ BUSY BIT IN THE RJE COMMUNICATIONS SWITCH IS   * 02500017
*   SET OFF, THE SYSDEQ STOP ACKNOWLEDGE ECB IS POSTED AND CONTROL    * 02600017
*   IS RETURNED TO THE DISPATCHER WAITING ON A DUMMY UNPOSTED ECB     * 02700017
*                                                                     * 02800017
*   3. IF A STOP RJE IS NOT PENDING, THE OS QUEUE MANAGER PARAMETERS  * 02900017
*   ARE BUILT AND A DEQUEUE REQUEST IS MADE TO DETERMINE IF THERE     * 03000017
*   IS ANY WORK ON THE RJE SYSOUT QUEUE.  THE PARAMETERS ARE AS       * 03100017
*   FOLLOWS                                                           * 03200017
*       A. QUEUE MANAGER PARAMETER AREA (QMPA) IS CLEARED TO ZERO.    * 03300017
*       B. CHAIN SMB/DSB AREA TO QMPAE                                * 03400017
*       C. CHAIN QMPAE TO QMPA                                        * 03500017
*       D. PLACE CLASS CODE IN QMPA                                   * 03600017
*       E. PLACE SYSDEQ'S QMGR ECB ADDRESS IN QMPA (MUST BE ZERO)     * 03700017
*       F. SET DEQUEUE CODE IN QMPA                                   * 03800017
*                                                                     * 03900017
*              CALLING SEQUENCE TO OS QUEUE MANAGER DEQUEUE MODULE    * 04000017
*              LA  1, QUEUE MANAGER PARAMETER                         * 04100017
*              L   15,IEFQMDQ2 ENTRY POINT ADDRESS FROM AVT           * 04200017
*              BALR 14,15                                             * 04300017
*                                                                     * 04400017
*        THE OS QUEUE MANAGER RETURNS A CODE OF 0, 4, OR 12 IN        * 04500017
*        REGISTER 15 INDICATING STATUS OF REQUEST.                    * 04600017
*                                                                     * 04700017
*              ZERO RETURN CODE--WORK ON QUEUE                        * 04800017
*              FOUR RETURN CODE--NO WORK ON QUEUE                     * 04900017
*              TWELVE RETURN CODE--  I/O ERROR READING OR WRITING     * 05000017
*                                    FROM SYS1.SYSJOBQE               * 05100017
*                                                                     * 05200017
*   4.  IF THE QMGR RETURN IS ZERO, SYSDEQ SETS THE SYSDEQ BUSY BIT ON* 05300017
*   IN THE RJE COMMUNICATIONS SWITCH AND SEARCHES THE FASTABLE FOR THE* 05400017
*   JOBNAME. IF THE JOB IS NOT FOUND OR THE JOB FOUND IS MARKED       * 05500017
*   COMPLETE ALREADY, THE JOB IS DELETED IN RJE AND OS. A MESSAGE IS  * 05600017
*   SENT TO THE CENTRAL OPERATOR INFORMING HIM OF THE DELETION.       * 05700017
*      THE JED TABLE FOR THE JOB IS READ IN TO MAIN STORAGE AND       * 05800017
*   UPDATED WITH THE QCR FOR THE DEQUEUED JOB AND WRITTEN BACK TO     * 05900017
*   DISK.  IF WRITING THE JED TABLE TO DISK INCURS AN I/O ERROR, THE  * 06000017
*   JOB IS DELETED IN OS AND RJE AND ERROR MESSAGE IS RETURNED TO THE * 06100017
*   USER SUBMITTING THE JOB.  IF THE JED UPDATE IS SUCCESSFUL, THE    * 06200017
*   USER AND WORK STATION ARE VERIFIED.  IF EITHER THE USER OR WORK   * 06300017
*   STATION IS NOT FOUND IN THEIR RESPECTIVE DIRECTORY THE JOB IS     * 06400017
*   IS DELETED IN OS AND RJE AND THE CENTRAL OPERATOR NOTIFIED OF THE * 06500017
*   DELETION.                                                         * 06600017
*      IF THE USER AND WORK STATION ARE VALIDATED, THE JOB DELETE BIT * 06700017
*   IS CHECKED IN THE FAST TABLE.  IF ON, THE CONTROL IS PASSED TO    * 06800017
*   IHKCGDT2 TO DELETE THE JOB IN RJE AND OS. THIS CONDITION ARISES   * 06900017
*   WHEN A JOB IS DELETED ON THE INPUT QUEUE OR WHILE EXECUTING.      * 07000017
*      IF THE JOB IS NOT TO BE DELETED, CONTROL IS PASSED TO IHKCHNDJ * 07100017
*   TO HANDLE SPECIAL PROCESSING OF COMPLETE JOBS SUCH AS NOTIFYING   * 07200017
*   AND ALERTING SOURCE AND ALTERNATE RECIPIENTS OF COMPLETION.  THE  * 07300017
*   RETURN CODE OF IHKCHNDJ IS CHECKED FOR IMMEDIATE OR DEFERRED      * 07400017
*   OUTPUT.  A NON-ZERO RETURN CODE INDICATES DEFERRED OUTPUT AND     * 07500017
*   COMPLETION OF SYSDEQ PROCESSING OF THE JOB.  A ZERO RETURN CODE   * 07600017
*   INDICATES IMMEDIATE OUTPUT AND IHKCFQOP IS GIVEN CONTROL TO QUEUE * 07700017
*   THE OUTPUT ON THE ASSOCIATED WORK STATION OUTPUT QUEUE.           * 07800017
*      AFTER PROCESSING OF THE DEQUEUED JOB IS COMPLETE, A DEQUEUE    * 07900017
*   REQUEST IS MADE FOR ANOTHER JOB TO PROCESS AFTER CHECKING FOR     * 08000017
*   A PENDING STOP RJE CONDITION.                                     * 08100017
*                                                                     * 08200017
*   5.  IF THE RETURN CODE FROM O S QUEUE MANAGER IS FOUR, NO ENTRIES * 08300017
*   WERE FOUND IN THE RJE SYSOUT CLASS QUEUE.  THE SYSDEQ BUSY BIT    * 08400017
*   SET OFF IN THE RJE COMMUNICATIONS SWITCH AND CONTROL IS PASSED    * 08500017
*   TO THE DISPATCHER WHILE SYSDEQ WAITS FOR WORK ON THE RJE          * 08600017
*   SYSOUT CLASS QUEUE.  SYSDEQ WILL REGAIN CONTROL WHEN WORK BECOMES * 08700017
*   AVAILABLE ON THE QUEUE BECAUSE THE OS QMGR WILL POST THE ECB      * 08800017
*   ON WHICH SYSDEQ IS WAITING  FOR IN THE DISPATCHERS MULTIPLE WAIT. * 08900017
*   IHKCASTP WILL ALSO POST THE SYSDEQ QMGR ECB COMPLETE IN ORDER TO  * 09000017
*   ACCOMPLISH NORMAL RJE SUBTASK CLOSEDOWN IF THE SYSDEQ BUSY BIT    * 09100017
*   IS OFF IN THE RJE COMMUNICATIONS SWITCH WHEN A STOP COMMAND IS    * 09200017
*   ENTERED BY THE CENTRAL OPERATOR.                                  * 09300017
*                                                                     * 09400017
*   6.  IF THE RETURN CODE FROM O S QUEUE MANAGER IS TWELVE, AN I/O   * 09500017
*   ERROR OCCURED. SYSDEQ SETS THE QMGR I/O ERROR INDICATOR IN THE    * 09600017
*   RJE COMMUNICATIONS SWITCH AND INITIATES AN RJE ABNORMAL CLOSEDOWN * 09700017
*   BY RETURNING TO THE RJE SUBTASK EXIT IN THE RJE READER MODULE     * 09800017
*   (IHKCHRDR) WHICH RETURNS TO THE R/I END OF DATA ADDRESS.          * 09900017
*                                                                     * 10000017
*   7. DUMMY WAITS ARE MADE AFTER QMGR PROCESSING, AND COMPLETION OF  * 10100017
*   EACH LOADED PROGRAMS PROCESSING WITH A POSTED ECB IN THE RJE      * 10200017
*   DISPATCHER TO INSURE AMPLE TIME TO PROCESS THE COMMUNICATION LINES* 10300017
*                                                                     * 10400017
*                                                                     * 10500017
*ENTRY POINTS.                                                        * 10600017
*   IHKCHSDQ IS THE ONLY ENTRY POINT. THE CALLING SEQUENCE IS -       * 10700017
*        CALL  IHKCHSDQ                                               * 10800017
*                                                                     * 10900017
*INPUT.                                                               * 11000017
*   QCR OF COMPLETED JOB ON THE RJE SYSOUT CLASS QUEUE                * 11100017
*                                                                     * 11200017
*OUTPUT.                                                              * 11300017
*   UPDATED JED TABLE ENTRIES FOR COMPLETED RJE JOBS                  * 11400017
*   JOB DELETED AND JED TABLE I/O ERROR MESSAGES TO APPROPIATE        * 11500017
*   RECIPIENTS.                                                       * 11600017
*                                                                     * 11700017
*EXTERNAL ROUTINES.                                                   * 11800017
*                                                                     * 11900017
*       IEFQMDQ2- DEQUEUE JOBS FROM SYSOUT QUEUE                      * 12000017
*       IHKCDSCH- SEARCH FAST TABLE FOR DEQUEUED JOB                  * 12100017
*       IHKCDJMR- READ AND WRITE JED TABLE TO AND FROM DISK           * 12200017
*       IHKCHNDJ- RJE PROCESSING OF COMPLETED JOBS                    * 12300017
*       IHKAADSP- DISPATCHER                                          * 12400017
*       IHKCGDT2- DELETE JOBS                                         * 12500017
*       IHKCBLDM- SEND ERROR MESSAGES                                 * 12600017
*       IHKCCSUD- SEARCH USER DIRECTORY FOR USER WHO SUBMITTED THE JOB* 12700017
*       IHKCBSTD- SEARCH TERMINAL DIRECTORY FOR THE WORK STATION WHERE* 12800017
*                 USER IS OR WAS LAST LOGGED ON                       * 12900017
*       IHKCFQOP- QUEUE IMMEDIATE JOB OUTPUT ON WORK STATION OUTPUT   * 13000017
*                 QUEUE                                               * 13100017
*                                                                     * 13200017
*EXITS-NORMAL.                                                        * 13300017
*    RETURN TO DISPATCHER TO WAIT FOR WORK ON THE RJE SYSOUT QUEUE    * 13400017
*                                                                     * 13500017
*EXITS-ERROR.                                                         * 13600017
*   INITIATE ABNORMAL RJE CENTRAL CLOSEDOWN                           * 13700017
*                                                                     * 13800017
*TABLES/WORK AREAS.                                                   * 13900017
*   A THIRTY-SIX BYTE QUEUE MANAGER PARAMETER AREA, AN EIGHT BYTE     * 14000017
*   EXTENDED QUEUE MANAGER PARAMETER AREA, AND A 180 BYTE QCR INPUT   * 14100017
*   AREA ARE NEEDED TO INTERFACE WITH IEFQMDQ2.                       * 14200017
*                                                                     * 14300017
*ATTRIBUTES.                                                          * 14400017
*   NON-REUSABLE.                                                     * 14500017
*                                                                     * 14600017
*NOTES.                                                               * 14700017
*   N/A                                                               * 14800017
*                                                                     * 14900017
*                                                                     * 15000017
*********************************************************************** 15100017
         EJECT                                                          15200017
*     S Y M B O L I C   R E G I S T E R S                               15300017
         SPACE                                                          15400017
ZIP      EQU   0         GENERAL WORK REGISTER                          15500017
PAR      EQU   1         PARAMETER REGISTER                             15600017
RCS      EQU   2         RJE SUBTASK COMMUNICATION SWITCHES             15700017
SOC      EQU   3         RJE SYSOUT CLASS INFORMATION                   15800017
AVT      EQU   4         RJE ADDRESS TABLE ADDRESS (DSECT BASE)         15900017
WOK      EQU   5         WORK REGISTER                                  16000017
ECB      EQU   6         QMGR ECB ADDRESS                               16100017
DUM      EQU   7         SDQDUM ADDRESS- COMMON DUMMY WAIT SUBROUTINE   16200017
MSG      EQU   8         MSG NUMBER ZERO-ONE MSG, OTHER-REMOTE+CENTRAL  16300017
*                        - AND FASTABLE DSECT BASE                      16400017
DES      EQU   9         MESSAGE DESTINATION, ZERO-CENTRAL OTHER- USER  16500017
NUL      EQU  10         NULL REGISTER - SAVE AREA SLOT USED FOR ECB    16600017
RET      EQU  11         RETURN TO SDQ01                                16700017
BAS      EQU  12         MODULE BASE REGISTER                           16800017
SAV      EQU  13         MODULE SAVE REGISTER                           16900017
BAC      EQU  14         RETURN POINT REGISTER FOR LINKAGES             17000017
GO       EQU  15         ENTRY POINT AND RETURN POINT REGISTER          17100017
         SPACE 2                                                        17200017
*     S Y M B O L I C   V A L U E S ,   E T C .                         17300017
         SPACE                                                          17400017
ZERO     EQU   0                                                        17500017
ONE      EQU   1                                                        17600017
TWO      EQU   2                                                        17700017
THRE     EQU   3                                                        17800017
FOUR     EQU   4                                                        17900017
SIX      EQU   6                                                        18000017
SEV      EQU   7                                                        18100017
ATE      EQU   8                                                        18200017
NINE     EQU   9                                                        18300017
TEN      EQU  10                                                        18400017
TWLV     EQU  12                                                        18500017
O47      EQU  47              OFFSET OF JOB DELETED MESSAGE             18600017
FOR8     EQU  48                                                        18700017
O65      EQU  65                                                        18800017
         SPACE                                                          18900017
STOP     EQU   X'80'          STOP CONDITION IN COMMUNICATIONS SWITCH   19000017
BUSY     EQU   X'10'          SYSDQ BUSY INDICATOR                      19100017
QERR     EQU   X'01'          QMGR I/O ERROR INDICATOR                  19200017
BUM      EQU   X'08'          MASK TO TEST JOB TERMINATION IN QMPA      19300017
RDOP     EQU   X'00'          READ OPERATION FOR IHKCDJMR               19400017
WTOP     EQU   X'80'          WRITE OPERATION FOR IHKCDJMR              19500017
DONE     EQU   X'CF'          MASK TO SET SDQ BUSY AND WARMSTART OFF    19600017
POST     EQU   X'40'          USED TO POST SDQ STOP ACK ECB             19700017
BLNK     EQU   X'40'                                                    19800017
         EJECT                                                          19900017
*     E N T R Y   L I N K A G E   AND   A D D R E S S A B I L I T Y     20000017
         SPACE                                                          20100017
         STM   BAC,BAS,TWLV(SAV)   SAVE CALLERS REGISTERS               20200017
         BALR  BAS,ZIP             ESTABLISH MODULE ADDRESSIBILITY      20300017
         USING *,BAS               INFORM ASSEMBLER OF BASE REGISTER    20400017
         SPACE 2                                                        20500017
*     I D E N T I F Y   M O D U L E   AND   C H A I N   S A V E         20600017
*      A R E A S                                                        20700017
         SPACE                                                          20800017
         B     SDQ00               BRANCH AROUND MODULE IDENTIFIER      20900017
         DC    CL8'IHKCHSDQ'       MODULE IDENTIFIER                    21000017
         SPACE                                                          21100017
SDQ00    DS    0H             ***** DEFINE TAG FOR BRANCHING            21200017
         LA    WOK,IHKWTRSV        GET MODULE SAVE AREA ADDRESS         21300017
         ST    WOK,ATE(SAV)        PLACE IN CALLERS SAVE AREA           21400017
         ST    SAV,FOUR(WOK)       PLACE CALLERS SAVE AREA ADDRESS IN   21500017
*                                  - MODULE SAVE AREA                   21600017
         LR    SAV,WOK             GET SAVE AREA ADDRESS IN PROPER REG  21700017
         SPACE 2                                                        21800017
*     M O D U L E   I N I T I A L I Z A T I O N                         21900017
         SPACE                                                          22000017
         L     AVT,SDQCOM          GET AVT ADDRESS IN DSECT BASE        22100017
         USING IHKZZAVT,AVT        TELL ASSEMBLER ABOUT DSECT           22200017
         SPACE                                                          22300017
         L     SOC,IHKZZSOC        GET SYSOUT INFORMATION ADDRESS       22400017
         L     RCS,IHKZZRCS        GET SUBTASK COMMUNICATION SWITCH     22500017
*                                  - ADDRESS                            22600017
         LA    DUM,SDQDUM          GET ADDRESS OD DUMMY WAIT SUBROUTINE 22700017
         XR    NUL,NUL             CLEAR NULL REGISTER TO INSURE ZERO   22800017
*                                  - WORD IN SAVE AREA AVAILABLE FOR    22900017
*                                  - UNPOSTED ECB FOR CLOSEDOWN         23000017
         LA    ECB,QMECB           GET ADDRESS OF QMGR ECB              23100017
         ST    ECB,IHKZZSQE        PLACE IT IN AVT FOR UNCHAIN AT STOP  23200017
         BALR  RET,ZIP             SET UP RETURN TO SDQ01               23300017
         EJECT                                                          23400017
*     C H E C K   FOR   W O R K   ON   R J E   S Y S O U T              23500017
*      C L A S S   IF   C L O S E D O W N   NOT   R E Q U I R E D       23600017
SDQ01    DS    0H             ***** DEFINE TAG FOR BRANCHING            23700017
         LM    MSG,DES,SDQ01       GET REGISTERS NON ZERO               23800017
         TM    ZERO(RCS),STOP      HAS OPERATOR STOPPED RJE OPERATION   23900017
         BO    SDQ08               YES, EXECUTE CLOSEDOWN AND EXIT      24000017
         SPACE                                                          24100017
         OI    ZERO(RCS),BUSY      SET SYSDEQ BUSY BIT IN CASE OPERATOR 24200017
*                                  - DECIDES TO STOP WHILE PROCESSING   24300017
         XC    QMECB(ATE),QMECB    ZERO QMGR ECB                        24400017
         MVI   QMPOP,DEQ           PUT FUNCTION CODE FOR DEQUEUE IN QMP 24500017
         ST    NUL,QMPEB           ZERO SECOND WORD IN QMPA             24600017
         ST    ECB,QMCAN           PUT IT IN QMPA                       24700017
         MVC   QMTYP(ONE),SEV(SOC) PUT RJE SYSOUT QUEUE NUMBER IN QMPA  24800017
         LA    PAR,QMPA            PASS QMGR ITS PARAMETERS             24900017
         L     GO,IHKZZDQ2         GET ENTRY POINT OF IEFQMDQ2          25000017
         BALR  BAC,GO              CHECK RJE SYSOUT QUEUE FOR WORK      25100017
         SPACE 2                                                        25200017
*     C H E C K   Q M G R   R E T U R N   C O D E   AND   S E E         25300017
*      H O W   D E Q U E U E   R E Q U E S T   W E N T                  25400017
         SPACE                                                          25500017
         B     *+FOUR(GO)          USE RETURN CODE TO SEE WHAT OCCURRED 25600017
         B     SDQ02               RC=O, WORK ON QUEUE, PROCESS JOB     25700017
         B     SDQ03               RC=4, NO WORK ON QUEUE, WAIT ON ECB  25800017
*                                  - IN RJE DISPATCHER                  25900017
         B     KMASYOYO            RC=8, NOT USE BUT TREAT AS I/O ERROR 26000017
         SPACE                                                          26100017
*  QMGR I/O ERROR, EXECUTE RJE ABNORMAL CLOSEDOWN PROCEDURE  RC=12      26200017
         SPACE                                                          26300017
KMASYOYO DS    0H             ***** DEFINE TAG FOR BRANCHING            26400017
         OI    ZERO(RCS),QERR      SET QMGR I/O ERROR INDICATOR IN RJE  26500017
*                                  - COMMUNICATION SWITCH               26600017
         L     GO,IHKZZASE         GET RJE EXIT ADDRESS                 26700017
         BR    GO                  GO TO RJE EXIT, LET CLOSEDOWN HANDLE 26800017
*                                  - ERROR                              26900017
         EJECT                                                          27000017
*     H A N D L E   R J E   P R O C E S S I N G   OF                    27100017
*      C O M P L E T E D   J O B S                                      27200017
         SPACE                                                          27300017
*     FIRST CHECK WHETHER RJE HAS RECORD OF THIS JOB                    27400017
         SPACE                                                          27500017
SDQ02    DS    0H             ***** DEFINE TAG FOR BRANCHING            27600017
         BALR  BAC,DUM             EXECUTE DUMMY WAIT FOR C/E TIME      27700017
          SPACE                                                         27800017
         LA    WOK,O47             SELECT JOB DELETED MSG IF ONE SENT   27900017
         MVC   QMPEX(THRE),BUF     MOVE TTR IN EXTERNAL QMGR PARM AREA  28000017
         LA    PAR,QMNAM           GET ADDRESS OF JOBNAME COMPLETING    28100017
         L     GO,IHKZZSCH         GET ENTRY POINT OF FAST TABLE SEARCH 28200017
         BALR  BAC,GO              SEARCH FAST TABLE FOR OUR JOB        28300017
         SPACE                                                          28400017
         LTR   GO,GO               WAS JOB FOUND IN FAST TABLE          28500017
         BNZ   SDQ04               NO, JOB IS NOT RJE JOB- REMOVE FROM  28600017
*                                  - RJE SYSOUT QUEUE                   28700017
         SPACE                                                          28800017
         LR    MSG,PAR             HAVE RJE JOB, SET UP DSECT BASE FOR  28900017
*                                  - FAST TABLE ENTRY                   29000017
      USING    FASTAB,MSG          TELL ASSEMBLER ABOUT DSECT BASE      29100017
         SPACE                                                          29200017
*   IHKCDSCH RETURNS ADDRESS OF FAST TABLE ENTRY IN REG 1 IF JOB FOUND  29300017
         SPACE                                                          29400017
         TM    FASTDSB,FASTJOBC    HAS SDQ ALREADY PROCESSED JOB WITH   29500017
*                                  - THIS NAME                          29600017
         BO    SDQ04               YES, REMOVE JOB FROM RJE SYSOUT QUE  29700017
         SPACE                                                          29800017
         TM    QMSTA,BUM           DID JOB COMPLETE NORMALLY            29900017
         BZ    SDQ05               YES, DONT INDICATE BAD COMPLETION    30000017
         SPACE                                                          30100017
         OI    FASTDSB,FASTJOBT                                         30200017
         SPACE                                                          30300017
SDQ05    DS    0H             ***** DEFINE TAG FOR BRANCHING            30400017
         ST    PAR,SDQFAST         PUT FAST TABLE ENTRY ADDRESS IN PARM 30500017
*                                  - LIST FOR IHKCDJMR                  30600017
         ST    PAR,SDQFST          DO IT AGAIN FOR IHKCHNDJ, IHKCFQOP,  30700017
*                                  - AND IHKCGDT2                       30800017
        EJECT                                                           30900017
*     H A N D L E   J E D   T A B L E   M A N A G E M E N T   FOR       31000017
*      T H I S   R J E   J O B                                          31100017
         SPACE                                                          31200017
         LA    PAR,SDQFAST         GET IHKCDJMR PARAMETER LIST ADDRESS  31300017
         L     GO,IHKZZJMR         GET IHKCDJMR ENTRY POINT ADDRESS     31400017
         MVI   SDQJEDTB,RDOP       TELL JED TABLE MGR READ IS DESIRED   31500017
         BALR  BAC,GO              READ IN JED TABLE FOR THIS JOB       31600017
         SPACE                                                          31700017
*        LTR   GO,GO               HOW DID READ GO                      31800017
*        BNZ   SDQ09               BAD SHOW, HANDLE ERROR BY DEVIOUS    31900017
*                                  - MEANS- TRY WAITING                 32000017
         MVC   SDQJQMPA(FOR8),QMPA MOVE QMPA,EXTERNAL QMPA, AND TTR OF  32100017
*                                  - FIRST RECORD FOR THIS JOB INTO JED 32200017
*                                  - TABLE WITH INFO ALREADY RECORDED   32300017
         L     GO,IHKZZJMR         GET IHKCDJMR ENTRY POINT ADDRESS     32400017
         MVI   SDQJEDTB,WTOP       INDICATE JED TABLE WRITE IS DESIRED  32500017
         BALR  BAC,GO              WRITE OUT JED TABLE FOR THIS JOB     32600017
         SPACE                                                          32700017
         LTR   GO,GO               HOW DID WRITE GO                     32800017
         BZ    SDQ11               NO ERROR, CONTINUE                   32900017
         SPACE                                                          33000017
         LR    MSG,NUL             HAD ERROR, KEEP THIS IN BACK OF MIND 33100017
         EJECT                                                          33200017
*     V E R I F Y   U S E R   AND   F I N D   H I S   W O R K           33300017
*      S T A T I O N                                                    33400017
         SPACE                                                          33500017
SDQ11    DS    0H             ***** DEFINE TAG FOR BRANCHING            33600017
         MVC   UID(THRE),FASTUSE   PUT SOURCE IN MSG TEXT BUFFER        33700017
         L     PAR,UID             GET PARAMETER FOR IHKCCSUD           33800017
         L     GO,IHKZZSUD         GET ENTRY POINT OF USER DIRECTORY    33900017
*                                  - SEARCH ROUTINE                     34000017
         BALR  BAC,GO              SEARCH USER DIRECTORY FOR SOURCE     34100017
*                                  - USER                               34200017
         SPACE                                                          34300017
         LTR   PAR,PAR             DOES SOURCE USER STILL EXIST         34400017
         BZ    SDQ06               NO, DELETE JOB - USER MUST HAVE BEEN 34500017
*                                  - REMOVED BY CENTRAL OPERATOR        34600017
         SPACE                                                          34700017
*   IHKCCSUD RETURNS USERS TERMID ADDRESS IN REG 1 IF USER FOUND        34800017
         SPACE                                                          34900017
         L     GO,IHKZZSTD         GET IHKCBSTD ENTRY POINT ADDRESS     35000017
         BALR  BAC,GO              SEARCH TERMINAL DIRECTORY FOR TERMID 35100017
         SPACE                                                          35200017
         LTR   GO,GO               IS USER ASSOCIATED WITH TERMINAL     35300017
         BNZ   SDQ06               NO, CONDITION UNEXPLAINABLE          35400017
         SPACE                                                          35500017
*   IHKCBSTD RETURNS T.D. ENTRY ADDRESS IN REG 1 IF ONE IS FOUND        35600017
         SPACE                                                          35700017
         ST    PAR,SDQQOP          PUT T.D. ENTRY ADDRESS IN PARAMETER  35800017
*                                  - LIST FOR IHKCHNDJ AND IHKCEQOP     35900017
         ST    PAR,DESTIN          PUT IT IN MSG PERM LIST IN CASE MSG  36000017
         LR    DES,NUL             REMEMBER WE HAVE A USER IN CASE MSG  36100017
          SPACE                                                         36200017
         LTR   MSG,MSG             WAS THERE A JED TABLE WRITE ERROR    36300017
         BZ    SDQ09               YES, DELETE THE JOB AND SEND MSG     36400017
         SPACE                                                          36500017
         TM    FASTJIB,FASTDLTJ    IS JOB TO BE DELETED                 36600017
         BO    SDQ14               YES, USER MUST HAVE ENTERED DELETE   36700017
*                                  - OR HAD LINE ERROR WHILE COLLECTING 36800017
         EJECT                                                          36900017
*     B R I N G   IN   I H K C H N D J   TO   H A N D L E               37000017
*      D I S P O S I T I O N   OF   J O B   O U T P U T                 37100017
         SPACE                                                          37200017
         LOAD  EPLOC=SDQADNDJ      BRING IN MODULE WITH SUPER ASSIST    37300017
         SPACE                                                          37400017
         LR    GO,ZIP              GET ENTRY POINT FOR LINKAGE          37500017
         LA    PAR,SDQJEDTB        GET IHKCHNDJ PARAMETER LIST ADDRESS  37600017
         BALR  BAC,GO              HANDLE JOB OUTPUT DISPOSITION        37700017
         SPACE                                                          37800017
         LR    WOK,GO              SAVE RETURN CODE                     37900017
         SPACE                                                          38000017
      DELETE   EPLOC=SDQADNDJ      FREE UP NDJS SPACE WITH SUPER ASSIST 38100017
         SPACE                                                          38200017
         BALR  BAC,DUM             EXECUTE DUMMY WAIT FOR C/E TIME      38300017
          SPACE                                                         38400017
         LTR   WOK,WOK             WHAT DOES NDJ SAY DO WITH OUTPUT     38500017
         BCR   SEV,RET             SAYS, FORGET IT BECAUSE ITS DEFERED  38600017
         SPACE 2                                                        38700017
*     B R I N G   IN   I H K C F Q O P   TO   P U T   O U T P U T       38800017
*      ON   W O R K   S T A T I O N   O U T P U T   Q U E U E           38900017
         SPACE                                                          39000017
         LOAD  EPLOC=SDQADQOP      BRING IN MODULE WITH SUPER ASSIST    39100017
         SPACE                                                          39200017
         LR    GO,ZIP              GET ENTRY POINT FOR LINKAGE          39300017
         LA    PAR,SDQQOP          GET IHKCFQOP PARAMETER LIST ADDRESS  39400017
         BALR  BAC,GO              PLACE OUTPUT ON W.S. OUTPUT QUEUE    39500017
         SPACE                                                          39600017
      DELETE   EPLOC=SDQADQOP      FREE UP QOPS SPACE WITH SUPER ASSIST 39700017
        SPACE                                                           39800017
         MVI   ZERO(ECB),POST      POST QMGR ECB FOR DUMMY WAIT         39900017
         SPACE 2                                                        40000017
*     E X E C U T E   D I S P A T C H E R   W A I T   FOR   W O R K     40100017
*      ON   R J E   S Y S O U T   Q U E U E                             40200017
         SPACE                                                          40300017
SDQ03    DS    0H             ***** DEFINE TAG FOR BRANCHING            40400017
         LR    BAC,RET             GET RETURN FOR DISPATCHER            40500017
         LR    PAR,ECB             GET ECB ADDRESS ON WHICH TO WAIT     40600017
         SPACE                                                          40700017
SDQSTP   DS    0H             ***** DEFINE TAG FOR BRANCHING            40800017
         NI    ZERO(RCS),DONE      INDICATE SYSDQ NOT BUSY, WARMSTART   40900017
*                                  - COMPLETE                           41000017
         L     GO,IHKZZDSP         GET IHKAADSP ENTRY POINT ADDRESS     41100017
         BR    GO                  WAIT FOR ECB TO BE POSTED            41200017
         EJECT                                                          41300017
*     C L O S E   O U T   W R I T E R   S U B T A S K                   41400017
         SPACE                                                          41500017
SDQ08    DS    0H             ***** DEFINE TAG FOR BRANCHING            41600017
         LA    PAR,DUMECB          USE REG 10 SLOT IN SAVE AREA FOR     41700017
*                                  - UNPOSTED ECB                       41800017
         MVI   IHKCBSAE,POST       POST WRITER SUBTASK AS READY TO STOP 41900017
         B     SDQSTP              FINISH UP CLOSEDOWN ACTIVITIES       42000017
         SPACE 2                                                        42100017
*     H A N D L E   J O B   D E L E T I O N - - AT   U S E R            42200017
*      R E Q U E S T   OR   D E T E C T E D   E R R O R                 42300017
         SPACE                                                          42400017
SDQ06    DS    0H             ***** DEFINE TAG FOR BRANCHING            42500017
         SPACE                                                          42600017
         LTR   MSG,MSG             WAS THERE A JED ERROR BEFORE THIS    42700017
         BNZ   SDQ14               NO, PROCESS NO USER OR TERMINAL ERR  42800017
         SPACE                                                          42900017
SDQ09    DS    0H             ***** DEFINE TAG FOR BRANCHING            43000017
         LA    WOK,O65             SELECT I/O ERROR FROM JED MANAGER    43100017
         SPACE                                                          43200017
SDQ04    DS    0H             ***** DEFINE TAG FOR BRANCHING            43300017
         MVC   SDQFST(FOUR),NOFT   TELL IHKCGDT2 NO FAST TABLE ENTRY    43400017
*                                  - FOR THIS DELETE REQUEST            43500017
         B     SDQ07               GO AND DELETE TROUBLESOME JOB        43600017
          SPACE                                                         43700017
SDQ14    DS    0H             ***** DEFINE TAG FOR BRANCHING            43800017
         MVI   FASTDSB,FASTJOBC    TELL IHKCGDT2 HAVE COMPLETE JOB WITH 43900017
         MVI   FASTJIB,FASTDLTJ    - DEFERRED OUTPUT TO BE DELETED      44000017
         SPACE                                                          44100017
SDQ07    DS    0H             ***** DEFINE TAG FOR BRANCHING            44200017
         SPACE                                                          44300017
         LOAD  EPLOC=SDQADDT2      BRING IN IHKCGDT2 WITH SUPER ASSIST  44400017
         SPACE                                                          44500017
         LR    GO,ZIP              GET ENTRY POINT FOR LINKAGE          44600017
         LA    PAR,SDQFST          GET IHKCGDT2 PARAMETER LIST ADDRESS  44700017
         BALR  BAC,GO              DELETE JOB AND ASSOCIATED OUTPUT     44800017
         SPACE                                                          44900017
      DELETE   EPLOC=SDQADDT2      FREE UP DT25 SPACE WITH SUPER ASSIST 45000017
          SPACE                                                         45100017
         BALR  BAC,DUM             EXECUTE DUMMY WAIT FOR C/E TIME      45200017
         EJECT                                                          45300017
*     S Y S O U T   D E Q U E U E R   M E S S A G E   H A N D L E R     45400017
         SPACE                                                          45500017
         MVI   MSGLNG,TWLV         SAY MESSAGE CONTAINS SOURCE USERID   45600017
         LTR   DES,DES             IS MESSAGE GOING TO REMOTE USER      45700017
         BZ    SDQ13               YES, SEND IT TO REMOTE USER          45800017
         SPACE                                                          45900017
         LTR   MSG,MSG             WAS IT A JED TABLE I/O ERROR MSG     46000017
         BCR   ATE,RET             YES, CHECK FOR MORE WORK ON DA QUEUE 46100017
*                                  - NO MSG REQUIRED                    46200017
         SPACE                                                          46300017
         MVI   MSGLNG,ATE          ONLY JOB NAME IN MESSAGE TEXT        46400017
         ST    NUL,DESTIN          SHOW CENTRAL OPERATOR AS DESTINATION 46500017
         SPACE                                                          46600017
SDQ13    DS    0H             ***** DEFINE TAG FOR BRANCHING            46700017
         SPACE                                                          46800017
         LR    BAC,RET             CHECK RJE SYSOUT QUEUE FOR WORK WHEN 46900017
*                                  - MESSAGE SENT                       47000017
         MVC   MSGTXT(ATE),QMNAM   MOVE JOBNAME INTO MESSAGE TEXT       47100017
         MVI   MSGTXT+ATE,BLNK     SEPARATE JOBNAME AND USERID          47200017
         STH   WOK,MSGOFF          SELECT MESSAGE TO SEND               47300017
         LA    PAR,SDQMSG          GET IHKCBLDM PARAMETER LIST ADDRESS  47400017
         L     GO,IHKZZLDM         GET IHKCBLDM ENTRY POINT ADDRESS     47500017
         BR    GO                  BUILD AND SEND MESSAGE               47600017
          SPACE  2                                                      47700017
*     E X E C U T E   D U M M Y   W A I T   TO   S E R V I C E          47800017
*      C O M M U N I C A T I O N   L I N E S                            47900017
          SPACE                                                         48000017
SDQDUM   DS    0H             ***** DEFINE TAG FOR BRANCHING            48100017
         LA    PAR,SDQWAT          GET ADDRESS OF POSTED ECB            48200017
         L     GO,IHKZZDSP         GET RJE DISPATCHER'S ENTRY POINT     48300017
         BR    GO                  EXECUTE DUMMY WAIT                   48400017
         EJECT                                                          48500017
*     C O N S T A N T S   AND   W O R K   A R E A S                     48600017
         SPACE                                                          48700017
*    NONRESIDENT MODULE NAMES USED BY THIS MODULE                       48800017
         SPACE                                                          48900017
         DS    0F                                                       49000017
SDQADNDJ DC    CL8'IHKCHNDJ'     *                                      49100017
SDQADQOP DC    CL8'IHKCFQOP'    *** NON-RESIDENT MODULE NAMES           49200017
SDQADDT2 DC    CL8'IHKCGDT2'     *                                      49300017
         SPACE                                                          49400017
*    MODULE SAVE AREA                                                   49500017
         SPACE                                                          49600017
IHKWTRSV DC    3F'0'          FIRST THREE WORDS OF SAVE AREA            49700017
         DC    A(IHKCHSDQ)    REG 14 - ENTRY POINT FOR INITIAL          49800017
*                             - DISPATCHER ENTRY                        49900017
         DC    11F'0'         SAVE AREA SLOTS FOR REGS 15 THRU 9        50000017
DUMECB   DC    F'0'           REGISTER 10 SLOT, ALSO USED FOR UNPOSTED  50100017
*                             - ECB AT ABNORMAL STOP                    50200017
         DC    2F'0'          SAVE AREA SLOTS FOR REGS 11 AND 12        50300017
         SPACE                                                          50400017
IHKCBSAE DC    F'0'           WRITER SUBTASK STOP ACKNOWLEDGE ECB       50500017
         SPACE                                                          50600017
QMECB    DC    2F'0'          QUEUE MANAGER ECB FOR DEQUEUE OPERATIONS  50700017
          SPACE                                                         50800017
SDQWAT   DC    X'40000000'         POSTET ECB FOR DUMMY WAIT            50900017
         SPACE 2                                                        51000017
*     Q U E U E   M A N A G E R   P A R A M E T E R   A R E A           51100017
         SPACE                                                          51200017
QMPA     DS    0F                                                       51300017
QMNAM    DS    0F        JOB NAME                                       51400017
QMCAN    DC    F'0'      ECB ADDRESS TO WAIT ON IF NO WORK ON QUEUE     51500017
QMPEB    DC    F'0'      NOT USED, MUST BE ZERO HOWEVER                 51600017
QMPOP    DC    X'00'     OPERATION CODE PARAMETER                       51700017
DEQ      EQU   X'06'     OPERATION CODE, DEQUEUE BY TYPE                51800017
QMFLT    DC    2X'00'    FIRST LOGICAL TRACK ASSIGNED TO JOB            51900017
QMTST    DC    X'00'     NUMBER OF RECORDS USED IN LOGICAL TRACK        52000017
QMTLN    DC    2X'00'    RELATIVE ADDRESS OF NEXT LOGICAL TRACK         52100017
QMNOT    DC    X'00'     NUMBER LOGICAL TRACKS ASSIGNED TO JOB          52200017
QMTYP    DC    X'00'     QUEUE NUMBER ON WHICH WORK IS TO BE FOUND      52300017
QMSTA    DC    X'00'     JOB STATUS                                     52400017
QMPRI    DC    X'00'     JOB PRIORITY                                   52500017
QMLNK    DC    2X'00'    RELATIVE ADDRESS OF NEXT QUEUE ENTRY           52600017
QMTID    DC    2X'00'    QUEUE ENTRY IDENTIFICATION                     52700017
RESV     DC    2X'00'    RESERVED                                       52800017
QMWTQ    DC    F'0'      COUNT AND ADDRESS POINTER FOR TRACK STACKING   52900017
QMELA    DC    F'0'      ADDRESS OF USERS ECB/IOB                       53000017
QMPNC    DC    X'00'     NUMBER OF RECORDS TO READ                      53100017
QMPLC    DC    AL3(QMPCA) ADDRESS OF EXTERNAL PARAMETER AREA            53200017
QMPCA    DC    A(BUF)    CORE ADDRESS INTO WHICH RECORD TO BE READ      53300017
QMPEX    DC    F'0'      TTR0                                           53400017
         EJECT                                                          53500017
*    COMMON AREA FOR QMGR RECORD, IHKCBLDM PARAMETER LIST, AND INCORE   53600017
*     JED TABLE                                                         53700017
         SPACE                                                          53800017
         DS    0F             ALIGN TO FULL WORD                        53900017
BUF      DS    0CL176         DEFINE TAG FOR 176 BYTE AREA FOR QMGR     54000017
*                             - TO READ IN DEQUEUED RECORD              54100017
SDQMSG   DS    0F             IHKCBLDM PARAMETER LIST                   54200017
DESTIN   DC    F'0'           MESSAGE DESTINATION                       54300017
MSGOFF   DC    H'0'           MESSAGE OFFSET                            54400017
MSGLNG   DC    X'00'     LENGTH OF VARIABLE MESSAGE TEXT                54500017
MSGTXT   DC    CL9' '         ADDED MSG TEXT BUFFER                     54600017
UID      DC    CL4' '                                                   54700017
PAD      DC    H'0'           ALIGN JED TABLE TO ONLY HALFWORD BOUNDARY 54800017
*                             - SO THAT CONTAINED QMPA WILL BE ON FULL  54900017
*                             - WORD BOUNDARY FOR IHKCGDT2              55000017
SDQJED   DS    0H             DEFINE TAG                                55100017
SDQJMSG  DC    CL25' '        JED NOTIFY MESSAGE                        55200017
SDQJSOC  DC    CL25' '        SYSOUT CLASS AS DEFINE ON JCL DD STATMETS 55300017
SDQJQMPA DC    CL36' '        QMPA FOR JOB CONTAINED IN JED TABLE       55400017
SDQJQPCA DC    2F'0'          EXTERNAL PARAMETER AREA FOR QMPA          55500017
SDQJTTR  DC    F'0'           TTR OF FIRST RECORD FOR WTR               55600017
BUFPAD   DC    CL56' '        PADDING TO FILL OUT 176 BYTE BUFFER       55700017
         SPACE 2                                                        55800017
*     P A R A M E T E R   L I S T S   FOR   N O N R E S I D E N T       55900017
*      M O D U L E S                                                    56000017
         SPACE                                                          56100017
*    START OF IHKCDJMR PARAMETER LIST                                   56200017
         SPACE                                                          56300017
SDQFAST  DC    F'0'      ADDRESS OF FAST TABLE ENTRY FOR DEQUEUED JOB   56400017
         SPACE                                                          56500017
*    START OF IHKCHNDJ PARAMETER LIST                                   56600017
         SPACE                                                          56700017
SDQJEDTB DC    A(SDQJED) ADDRESS OF INCORE JED TABLE ENTRY FOR JOB      56800017
         SPACE                                                          56900017
*    START OF IHKCFQOP PARAMETER LIST - END OF IHKCDJMR PARAMETER LIST  57000017
         SPACE                                                          57100017
SDQQOP   DC    F'0'      ADDRESS OF TERMINAL DIRECTORY ENTRY RETURNED   57200017
*                        - BY IHKCHNDJ                                  57300017
         SPACE                                                          57400017
*    START OF IHKCGDT2 PARAMETER LIST                                   57500017
         SPACE                                                          57600017
SDQFST   DC    F'0'      ADDRESS OF FAST TABLE ENTRY FOR QOP, NDJ, AND  57700017
*                        - DT2, OR THE JED TABLE ADDRESS FOR DT2 IF NO  57800017
*                        - FAST TABLE ENTRY EXISTS FOR THE JOB          57900017
SDQCOM   DC    A(IHKCACOM) ADDRESS OF RJE ADDRESS TABLE                 58000017
         SPACE                                                          58100017
*    END OF PARAMETER LIST FOR IHKCHNDJ, IHKGCDT2, AND IHKCFQOP         58200017
         SPACE                                                          58300017
NOFT     DC    X'80'     NO FAST TABLE INDICATOR TO IHKCGDT2            58400017
         DC    AL3(QMPA-50)   JED TABLE ADDR FOR SPECIAL DT2 ENTRY      58500017
         SPACE                                                          58600017
         IHKDSECT  ,,FASTAB,JEDTAB,,AVT                                 58700017
         SPACE                                                          58800017
     EXTRN   IHKCACOM                                                   58900017
     ENTRY   IHKCBSAE,IHKWTRSV                                          59000017
         END                                                            59100017
