SUP      TITLE 'SHOW USERS AND SHOW USERS,USERID COMMAND PROCESSOR'     00200017
         SPACE                                                          00400017
IHKCHSUP CSECT                                                          00600017
         ENTRY IHKCASHU                                                 00800017
         SPACE                                                          01000017
*********************************************************************** 01200017
*---------------------------------------------------------------------* 01400017
*-*******************************************************************-* 01600017
*-*                                                                 *-* 01800017
*-* M O D U L E   N A M E                                           *-* 02000017
*-*                                                                 *-* 02200017
*-*   IHKCHSUP -- SHOW USERS(,USERID) PROCESSOR                     *-* 02400017
*-*                                                                 *-* 02600017
*-*                                                                 *-* 02800017
*-* F U N C T I O N / O P E R A T I O N - -                         *-* 03000017
*-*                                                                 *-* 03200017
*-*   THIS MODULE RESPONDS TO THE CENTRAL COMMANDS ENTERED BY THE   *-* 03400017
*-*     CENTRAL OPERATOR TO RETRIEVE INFORMATION RELATIVE TO THE    *-* 03600017
*-*     USERS OF THE RJE SYSTEM. HE CAN REQUEST -                   *-* 03800017
*-*     1.  A LIST OF ALL USERS IN THE RJE SYSTEM AND THEIR STATUS  *-* 04000017
*-*           SHOW USERS                                            *-* 04200017
*-*     2.  THE STATUS OF A PARTICULAR USER IN THE RJE SYSTEM       *-* 04400017
*-*           SHOW USERS,USERID                                     *-* 04600017
*-*                                                                 *-* 04800017
*-*   THE RESPONSE TO THESE REQUESTS CONTAINS THE IDENTIFICATION    *-* 05000017
*-*     OF THE USER AND HIS PROTECTION KEY WITH AN INDICATION OF    *-* 05200017
*-*     WHETHER OR NOT THE USER IS LOGGED ON.  THE TERMID OF THE    *-* 05400017
*-*     WORK STATION WHERE THE USER WAS LAST OR IS LOGGED ON IS     *-* 05600017
*-*     ALSO DISPLAYED.  IF THE USER IS LOGGED ON, THE UNITNAME FOR *-* 05800017
*-*     THE COMMUNICATION LINE ON WHICH IS WORK STATION IS ATTACHED *-* 06000017
*-*     IS DISPLAYED.  THE MESSAGE HAS THE FOLLOWING FORMAT-        *-* 06200017
*-*                                                                 *-* 06400017
*-*     IHK001I USERID KEY STATUS TERMID UNITNAME                   *-* 06600017
*-*                                                                 *-* 06800017
*-*                                                                 *-* 07000017
*-* E N T R Y   P O I N T - -                                       *-* 07200017
*-*                                                                 *-* 07400017
*-*   IHKCASHU IS THE ENTRY POINT ATTRIBUTED TO THIS MODULE AND IS  *-* 07600017
*-*     USED BY IHKCAINT ON RECEIPT OF A SHOW USERS OR SHOW USERS,  *-* 07800017
*-*     USERID COMMAND.  STANDARD SUBROUTINE LINKAGE PREVAILS.      *-* 08000017
*-*                                                                 *-* 08200017
*-*     CALLING SEQUENCE FOR MODULE -                               *-* 08400017
*-*                                                                 *-* 08600017
*-*           LOAD    EP=IHKCASHU                                   *-* 08800017
*-*           LR      15,0                                          *-* 09000017
*-*           L       1,RJE COMMUNICATION REGION ADDRESS            *-* 09200017
*-*           BALR    14,15                                         *-* 09400017
*-*                                                                 *-* 09600017
*-*           DELETE  EP=IHKCASHU                                   *-* 09800017
*-*                                                                 *-* 10000017
         EJECT                                                          10200017
*-* I N P U T - -                                                   *-* 10400017
*-*                                                                 *-* 10600017
*-*   THE INPUT OF THIS MODULE IS OBTAINED AT THE ADDRESS CONTAINED *-* 10800017
*-*     IN THE SECOND WORD OF THE RJE COMMUNICATIONS REGION.  THIS  *-* 11000017
*-*     ADDRESS POINTS TO 95 BYTE RJE COMMAND INPUT RECORD WITH     *-* 11200017
*-*     THE FOLLOWING FORMAT-                                       *-* 11400017
*-*                                                                 *-* 11600017
*-*     *-------------------------*------------------------*        *-* 11800017
*-*     *                         *                        *        *-* 12000017
*-*     *  80 BYTE COMMAND IMAGE  *  15 BYTE CONDENSATION  *        *-* 12200017
*-*     *                         *                        *        *-* 12400017
*-*     *-------------------------*------------------------*        *-* 12600017
*-*                                                                 *-* 12800017
*-*     DESCRIPTION -                                               *-* 13000017
*-*                                                                 *-* 13200017
*-*       BYTE      USE                                             *-* 13400017
*-*      0-79      COMMAND IMAGE - 80 BYTE IMAGE OF COMMAND WHICH   *-* 13600017
*-*                      WAS RECEIVED AND INTERPRETED BY THE COMMAND*-* 13800017
*-*                      INTERPRETER (IHKCAINT)                     *-* 14000017
*-*     80-94      COMMAND CONDENSATION -                           *-* 14200017
*-*                 BYTE      USE                                   *-* 14400017
*-*                  80      COMMAND TYPE - CONTAINS C'H' TO        *-* 14600017
*-*                               INDICATE SHOW                     *-* 14800017
*-*                  81      OPERAND TYPE - CONTAINS C'U' TO        *-* 15000017
*-*                               INDICATE USERS OR USERS, USERID   *-* 15200017
*-*                 82-84    REQUEST TYPE - CONTAINS                *-* 15400017
*-*                             - BINARY ZERO FOR MAJOR REQUEST,    *-* 15600017
*-*                               SHOW USERS                        *-* 15800017
*-*                             - EBCDIC USERID FOR SPECIFIC        *-* 16000017
*-*                               REQUEST, SHOW USERS,USERID        *-* 16200017
*-*                 85-94      NOT USED                             *-* 16400017
*-*                                                                 *-* 16600017
*-*                                                                 *-* 16800017
*-* O U T P U T - -                                                 *-* 17000017
*-*                                                                 *-* 17200017
*-*   THE OUTPUT OF THIS MODULE IS A PRINTER/KEYBOARD DISPLAY OF    *-* 17400017
*-*     THE STATUS OF THE RJE USERS.  REPORTING CONTINUES UNTIL ALL *-* 17600017
*-*     ALL ENTRIES IN THE USER DIRECTORY HAVE BEEN CHECKED WHICH   *-* 17800017
*-*     COULD SATIFY THE REQUEST MADE ON THE ROUTINE.               *-* 18000017
*-*                                                                 *-* 18200017
*-*   MESSAGES HAVE THE FOLLOWING FORMAT -                          *-* 18400017
*-*                                                                 *-* 18600017
*-*     IHK001I USERID KEY OFF                                      *-* 18800017
*-*            WHEN THE USER IS LOGGED OFF NEVER HAVING LOGGED ON   *-* 19000017
*-*     IHK001I USERID KEY OFF TERMID                               *-* 19200017
*-*            WHEN THE USER IS LOGGED OFF BUT PREVIOUSLY LOGGED ON *-* 19400017
*-*     IHK001I USERID KEY ON TERMID UNITNAME                       *-* 19600017
*-*            WHEN THE USER IS CURRENTLY LOGGED ON                 *-* 19800017
*-*     IHK001I NO USERS IN DIRECTORY                               *-* 20000017
*-*            WHEN THERE ARE NO USERS IN THE USER DIRECTORY        *-* 20200017
*-*                                                                 *-* 20400017
*-*                                                                 *-* 20600017
*-*   IN THE EVENT THE OPERATOR SUBMITS A SHOW USERS,USERID COMMAND *-* 20800017
*-*     WITH AN INVALID USERID, THE FOLLOWING MESSAGE IS DISPLAYED. *-* 21000017
*-*           IHK040I INVALID USERID SHOW                           *-* 21200017
         EJECT                                                          21400017
*-* E X T E R N A L   R O U T I N E S - -                           *-* 21600017
*-*                                                                 *-* 21800017
*-*   IHKCCSUD - SEARCH USER DIRECTORY FOR USERID ON A SPECIFIC     *-* 22000017
*-*              REQUEST                                            *-* 22200017
*-*   IHKCBSTD - SEARCH TERMINAL DIRECTORY FOR TERMID TO SEE IF     *-* 22400017
*-*              USER IS CURRENTLY LOGGED ON                        *-* 22600017
*-*                                                                 *-* 22800017
*-*   IHKCBLDM - CONSTRUCT AND DISPLAY MESSAGES FOR CENTRAL OPERATOR*-* 23000017
*-*                                                                 *-* 23200017
*-*                                                                 *-* 23400017
*-* E X I T S - -                                                   *-* 23600017
*-*                                                                 *-* 23800017
*-*   NORMAL- RETURN TO CALLING ROUTINE WITH ZERO RETURN CODE       *-* 24000017
*-*   ERROR- N/A                                                    *-* 24200017
*-*                                                                 *-* 24400017
*-*                                                                 *-* 24600017
*-* T A B L E S / W O R K   A R E A S                               *-* 24800017
*-*                                                                 *-* 25000017
*-*                                                                 *-* 25200017
*-*   STANDARD 18-WORD SAVE AREA                                    *-* 25400017
*-*   21 BYTE MESSAGE TEXT BUFFER                                   *-* 25600017
*-*   TERMINAL DIRECTORY                                            *-* 25800017
*-*   USER DIRECTORY                                                *-* 26000017
*-*   LINE CONTROL BLOCK                                            *-* 26200017
*-*   DATA CONTROL BLOCK FOR LINE                                   *-* 26400017
*-*   DATA EVENT CONTROL BLOCK FOR LINE                             *-* 26600017
*-*   DATA EXTENT BLOCK FOR LINE                                    *-* 26800017
*-*   UNIT CONTROL BLOCK FOR LINE                                   *-* 27000017
*-*                                                                 *-* 27200017
*-*                                                                 *-* 27400017
*-* A T T R I B U T E S - -                                         *-* 27600017
*-*                                                                 *-* 27800017
*-*   SERIALLY REUSEABLE AND NON-RESIDENT                           *-* 28000017
*-*                                                                 *-* 28200017
*-*                                                                 *-* 28400017
*-* N O T E S - -                                                   *-* 28600017
*-*                                                                 *-* 28800017
*-*   COMMENTS ARE KEYED TO PROGRAMMERS FAMILIAR WITH THE MYSTERIES *-* 29000017
*-*     OF OS/360 ASSEMBLER LANGUAGE WHICH DEPENDS UPON AN INTERNAL *-* 29200017
*-*     REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS       *-* 29400017
*-*     EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE PROGRAM    *-* 29600017
*-*     HAS BEEN ARRANGED SO THAT REDEFINITION OF CHARACTER         *-* 29800017
*-*     CONSTANTS BY REASSEMBLY WILL RESULT IN A CORRECT MODULE     *-* 30000017
*-*     FOR THE NEW DEFINITIONS.                                    *-* 30200017
*-*                                                                 *-* 30400017
*-*                                                                 *-* 30600017
*-*******************************************************************-* 30800017
*---------------------------------------------------------------------* 31000017
*********************************************************************** 31200017
         EJECT                                                          31400017
*********************************************************************** 31600017
*---------------------------------------------------------------------* 31800017
*-*******************************************************************-* 32000017
*-*                                                                 *-* 32200017
*-*   S Y M B O L I C   R E G I S T E R   A S S I G N M E N T S     *-* 32400017
*-*                                                                 *-* 32600017
*-*******************************************************************-* 32800017
*---------------------------------------------------------------------* 33000017
*********************************************************************** 33200017
         SPACE 2                                                        33400017
ZIP      EQU   0         WORK REGISTER                                  33600017
         SPACE                                                          33800017
PAR      EQU   1         PARAMETER LIST ADDRESS FOR LINKAGE             34000017
         SPACE                                                          34200017
TDE      EQU   1         TERMINAL DIRECTORY ENTRY ADDRESS (DSECT)       34400017
         SPACE                                                          34600017
UDE      EQU   2         CURRENT USER DIRECTOR ENTRY ADDRESS (DSECT)    34800017
         SPACE                                                          35000017
LNG      EQU   3         LENGTH OF USER DIRECTORY ENTRY                 35200017
         SPACE                                                          35400017
CNT      EQU   4         NUMBER OF USER DIRECTORY ENTRIES               35600017
         SPACE                                                          35800017
AVT      EQU   5         RJE COMMUNICATION REGION ADDRESS (DSECT        36000017
         SPACE                                                          36200017
CIR      EQU   6         COMMAND INPUT RECORD ADDRESS (DSECT            36400017
         SPACE                                                          36600017
MSG      EQU   7         MESSAGE SENT INDICATOR                         36800017
         SPACE                                                          37000017
WOK      EQU   8         WORK REGISTER                                  37200017
         SPACE                                                          37400017
BAL      EQU   9         INTERNAL SUBROUTINE LINKAGE REGISTER           37600017
         SPACE                                                          37800017
NU0      EQU  10         NOT USED                                       38000017
         SPACE                                                          38200017
RLN      EQU  11         RELATIVE LINE NUMBER                           38400017
         SPACE                                                          38600017
BAS      EQU  12         MODULE BASE REGISTER                           38800017
         SPACE                                                          39000017
SAV      EQU  13         SAVE AREA ADDRESS REGISTER                     39200017
         SPACE                                                          39400017
BAC      EQU  14         RETURN POINT REGISTER FOR LINKAGE              39600017
         SPACE                                                          39800017
GO       EQU  15         ENTRY POINT AND RETURN CODE REG FOR LINKAGE    40000017
         EJECT                                                          40200017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 40400017
*-*                                                                 *-* 40600017
*-*   S Y M B O L I C   L E N G T H S ,   D I S P L A C E M E N T S *-* 40800017
*-*                       AND   V A L U E S                         *-* 41000017
*-*                                                                 *-* 41200017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 41400017
         SPACE 2                                                        41600017
* DISPLACEMENTS -                                                       41800017
ZERO     EQU   0                                                        42000017
ONE      EQU   1                                                        42200017
TWO      EQU   2                                                        42400017
THRE     EQU   3                                                        42600017
FOUR     EQU   4                                                        42800017
ATE      EQU   8                                                        43000017
TWLV     EQU  12                                                        43200017
UCB      EQU  13                                                        43400017
UCBAD    EQU  28                                                        43600017
         SPACE                                                          43800017
* LENGTHS -                                                             44000017
         SPACE                                                          44200017
L3       EQU   3                                                        44400017
L4       EQU   4                                                        44600017
L8       EQU   8                                                        44800017
L23      EQU  23                                                        45000017
L40      EQU   4                                                        45200017
         SPACE                                                          45400017
* VALUES -                                                              45600017
         SPACE                                                          45800017
BADUID   EQU   1                                                        46000017
BLNK     EQU   C' '                                                     46200017
MAJOR    EQU   X'00'                                                    46400017
         EJECT                                                          46600017
         SPACE 2                                                        46800017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 47000017
*-*                                                                 *-* 47200017
*-*              E N T R Y   L I N K A G E                          *-* 47400017
*-*                                                                 *-* 47600017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 47800017
         SPACE                                                          48000017
IHKCASHU DS    0H             **** MODULE ENTRY POINT                   48200017
         SPACE                                                          48400017
         B     TWLV(ZIP,GO)        BRANCH AROUND IDENTIFIER             48600017
         SPACE                                                          48800017
         DC    CL8'IHKCHSUP'       MODULE IDENTIFIER                    49000017
         SPACE                                                          49200017
         STM   BAC,BAS,TWLV(SAV)   SAVE REGISTERS FOR RETURN LINKAGE    49400017
         BALR  BAS,ZIP             SET UP MODULE ADDRESSABILITY         49600017
         SPACE                                                          49800017
      USING    *,BAS               TELL ASSEMBLER CHOICE OF BASE REG.   50000017
         LA    MSG,SUPSAV          GET MODULE SAVE AREA ADDRESS         50200017
         ST    MSG,ATE(SAV)        CHAIN CALLED WITH CALLING SAVE AREA  50400017
         ST    SAV,FOUR(MSG)       CHAIN CALLING WITH CALLED SAVE AREA  50600017
         LR    SAV,MSG             SET UP SAVE REG FOR MODULE LINKAGES  50800017
         SPACE 2                                                        51000017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 51200017
*-*                                                                 *-* 51400017
*-*   I N I T I A L I Z E   AND   R E T R I E V E   P A R M S       *-* 51600017
*-*                                                                 *-* 51800017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 52000017
         SPACE                                                          52200017
         LR    AVT,PAR             GET RJE COMMUNICATION REGION ADDRESS 52400017
      USING    IHKZZAVT,AVT        TELL ASSEMBLER OF DSECT              52600017
         SPACE                                                          52800017
         L     CIR,IHKZZCDE        GET COMMAND INPUT RECORD ADDRESS     53000017
      USING    CIRD,CIR            TELL ASSEMBLER OF DSECT              53200017
         SPACE                                                          53400017
         LM    UDE,CNT,IHKZZUDR    GET USER DIRECTORY DESCRIPTIVE       53600017
*                                  - ADDRESSES                          53800017
*                                **** UDE- USER DIRECTORY START ADDRESS 54000017
*                                **** LNG- ENTRY LENGTH ADDR (HALFWORD) 54200017
*                                **** CNT- ENTRY NUMBER ADDR (HALFWORD) 54400017
         LH    LNG,ZERO(LNG)       GET UDIR ENTRY LENGTH                54600017
         LH    CNT,ZERO(CNT)       GET UDIR ENTRY NUMBER                54800017
         LTR   CNT,CNT             ANY ENTRIES IN UDIR                  55000017
         BZ    SUPNOU              NO, TELL OPERATOR NO ACTIVE USERS    55200017
         SPACE 2                                                        55400017
      USING    UDIREC,UDE          TELL ASSEMBLER OF DSECT              55600017
         EJECT                                                          55800017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 56000017
*-*                                                                 *-* 56200017
*-*   D E T E R M I N E   R E Q U E S T   T Y P E                   *-* 56400017
*-*                                                                 *-* 56600017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 56800017
         SPACE                                                          57000017
         CLI   RTYPE,MAJOR         IS DISPLAY OF ALL USERS DESIRED      57200017
         BNE   SUPSPEC             NO, PROCESS SPECIFIC REQUEST         57400017
         SPACE 3                                                        57600017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 57800017
*-*                                                                 *-* 58000017
*-*   P R O C E S S   M A J O R   U S E R   D I S P L A Y           *-* 58200017
*-*     R E Q U E S T                                               *-* 58400017
*-*                                                                 *-* 58600017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 58800017
         SPACE 1                                                        59000017
SUPLOP   DS    0H             **** TAG FOR BRANCHING                    59200017
         BAL   BAC,SUPSUB          HANDLE REPORTING FOR THIS ENTRY      59400017
         SPACE                                                          59600017
         SPACE                                                          59800017
SUPLUP   DS    0H             **** TAG FOR BRANCHING                    60000017
         AR    UDE,LNG             STEP TO NEXT UDIR ENTRY              60200017
         BCT   CNT,SUPLOP          PROCESS REMAINING ENTRIES            60400017
         SPACE                                                          60600017
         LTR   MSG,MSG             WAS THERE AN ENTRY REPORTED          60800017
         BNZ   SUPNOU              NO, TELL OPERATOR NO ACTIVE ENTRIES  61000017
         SPACE 2                                                        61200017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 61400017
*-*                                                                 *-* 61600017
*-*              R E T U R N   L I N K A G E                        *-* 61800017
*-*                                                                 *-* 62000017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 62200017
         SPACE                                                          62400017
SUPOUT   DS    0H             **** TAG FOR BRANCHING                    62600017
         XR    GO,GO               SET ZERO RETURN CODE                 62800017
         L     SAV,SUPSAV+FOUR     GET CALLING SAVE AREA ADDRESS        63000017
         SPACE                                                          63200017
      RETURN   (14,12),T,RC=(15)   EXECUTE RETURN LINKAGE               63400017
         EJECT                                                          63600017
         SPACE                                                          63800017
*********************************************************************** 64000017
*---------------------------------------------------------------------* 64200017
*-*******************************************************************-* 64400017
*-*                                                                 *-* 64600017
*-*             U S E R   S T A T U S   R E P O R T I N G           *-* 64800017
*-*                        S U B R O U T I N E                      *-* 65000017
*-*                                                                 *-* 65200017
*-*******************************************************************-* 65400017
*---------------------------------------------------------------------* 65600017
*********************************************************************** 65800017
         SPACE 2                                                        66000017
SUPSUB   DS    0H             **** TAG FOR BRANCHING                    66200017
         CLI   UDIRUSID,BLNK       IS THIS ENTRY ACTIVE                 66400017
         BE    SUPLUP              NO, CHECK OUT NEXT ENTRY             66600017
         SPACE                                                          66800017
         MVI   SUPTXT,BLNK         BLANK MSG TEXT BUFFER FIRST BYTE     67000017
         MVC   SUPTEX(L23),SUPTXT  CASCADE BLANK THROUGH REST OF BUFFER 67200017
         SPACE                                                          67400017
         MVC   STATUS(L3),OFF      ASSUME USER IS LOGGED OFF            67600017
         LA    PAR,UDIRTERM        GET TERMID ADDRESS                   67800017
         L     GO,IHKZZSTD         GET IHKCBSTD ENTRY POINT             68000017
         LR    BAL,BAC             SAVE RETURN POINT FOR IHKCBLBM       68200017
         BALR  BAC,GO              SEARCH TERMINAL DIRECTORY FOR TERMID 68400017
         SPACE                                                          68600017
         LR    BAC,BAL             RESTORE RETURN POINT FOR IHKCBLDM    68800017
         LTR   GO,GO               WAS TERMID FOUND                     69000017
         BNZ   SUPNON              NO, USER NOT LOGGED ON AS YET        69200017
         SPACE 2                                                        69400017
      USING    TDIREC,TDE          TELL ASSEMBLER OF DSECT              69600017
         SPACE                                                          69800017
         MVC   TERM(L8),TDIRTERM   MOVE USERS TERMID INTO MSG TEXT      70000017
         SPACE                                                          70200017
         CLC   UDIRUSID(L3),TDIRUSID IS THIS USER LOGGED ON             70400017
         BNE   SUPNON              NO, HE WAS BUT IS NOT NOW LOGGED ON  70600017
         SPACE                                                          70800017
         MVC   STATUS(L3),ON       INDICATE USER CURRENTLY LOGGED ON    71000017
         EJECT                                                          71200017
* GET EBCDIC UNITNAME FOR LINE NOW USED BY USERS WORK STATION           71400017
         SPACE                                                          71600017
         L     WOK,TDIRLCB         GET LINE CONTROL BLOCK ADDRESS       71800017
         LTR   WOK,WOK             IS WORK STATION REALLY ACTIVE        72000017
         BZ    SUPNON              NO, FIGMENT OF IMAGINATION-FORGET IT 72200017
         SPACE                                                          72400017
      USING    LCBDSECT,WOK        TELL ASSEMBLER OF DSECT              72600017
         SPACE                                                          72800017
         L     WOK,LCBLDECB        GET DATA EVENT CONTROL BLOCK ADDR    73000017
      USING    IECTDECB,WOK        TELL ASSEMBLER OF DSECT              73200017
         SPACE                                                          73400017
         LR    RLN,GO              CLEAR REG FOR NEXT INSTRUCTION       73600017
         IC    RLN,DECRLN          GET RELATIVE LINE NUMBER OF LINE     73800017
         SLL   RLN,TWO             MULTIPLY IT TIMES FOUR               74000017
         SPACE                                                          74200017
         L     WOK,DECDCBAD        GET DATA CONTROL BLOCK ADDR          74400017
      USING    IHADCB,WOK          TELL ASSEMBLER OF DSECT              74600017
         SPACE                                                          74800017
         L     WOK,DCBDEBAD        GET DATA EXTENT BLOCK ADDR           75000017
      DROP     WOK                 FORGET ALL DSECTS FOR REG            75200017
         SPACE                                                          75400017
         L     WOK,UCBAD(RLN,WOK)  GET UNIT CONTROL BLOCK ADDR FOR LINE 75600017
         MVC   UNIT(L3),UCB(WOK)   MOVE EBCDIC UNITNAME INTO MSG TEXT   75800017
         SPACE                                                          76000017
SUPNON   DS    0H             **** TAG FOR BRANCHING                    76200017
         MVC   UID(L3),UDIRUSID    MOVE USERID INTO MSG TEXT            76400017
         MVC   KEY(L3),UDIRUKEY    MOVE PROTECTION KEY INTO MSG TEXT    76600017
         XR    MSG,MSG             REMBER USER WAS REPORTED             76800017
         LA    PAR,SUPMSG          GET PARMS FOR IHKCBLDM               77000017
         L     GO,IHKZZLDM         GET IHKCBLDM ENTRY POINT             77200017
         BR    GO                  BUILD MSG AND RATTLE OPERATORS BALL  77400017
         EJECT                                                          77600017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 77800017
*-*                                                                 *-* 78000017
*-*        H A N D L E   S P E C I F I C   R E Q U E S T            *-* 78200017
*-*                                                                 *-* 78400017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 78600017
         SPACE 1                                                        78800017
SUPSPEC  DS    0H             **** TAG FOR BRANCHING                    79000017
         MVC   DIP(L3),RTYPE       LEFT JUSTIFY USERID IN FULL WORD     79200017
         L     PAR,DIP             PASS IHKCCSUD ITS PARMS              79400017
         L     GO,IHKZZSUD         GET IHKCCSUD ENTRY POINT             79600017
         BALR  BAC,GO              SEARCH USER DIRECTORY FOR USERID     79800017
         SPACE                                                          80000017
         LTR   PAR,PAR             WAS USERID FOUND IN DIRECTORY        80200017
         BZ    SUPBID              NO, MUST BE A BAD USERID             80400017
         SPACE                                                          80600017
         LR    UDE,PAR             SET UP USER DIRECTORY DSECT REG      80800017
         LA    BAC,SUPOUT          EXIT WHEN ENTRY REPORTING COMPLETE   81000017
         B     SUPSUB              HANDLE REPORTING FOR ENTRY           81200017
         SPACE 2                                                        81400017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 81600017
*-*                                                                 *-* 81800017
*-*            H O N O R   N U L L   AND   I N V A L I D            *-* 82000017
*-*                   U S E R I D   R E Q U E S T                   *-* 82200017
*-*                                                                 *-* 82400017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 82600017
         SPACE                                                          82800017
SUPBID   DS    0H             **** TAG FOR BRANCHING                    83000017
         MVI   SUPLNG,L40          MOVE MSG TEXT LENGTH INTO PARM LIST  83200017
         MVI   SUPOFF,BADUID       SELECT IHK040I MESSAGE               83400017
         MVC   SUPTXT(L4),SHOW     MOVE COMMAND OPERATION INTO MSG TEXT 83600017
         SPACE                                                          83800017
SUPNOU   DS    0H             **** TAG FOR BRANCHING                    84000017
         LA    PAR,SUPMSG          GIVE IHKCBLDM ITS PARMS              84200017
         LA    BAC,SUPOUT          EXIT WHEN MESSAGE DISPLAYED          84400017
         L     GO,IHKZZLDM         GET IHKCBLDM ENTRY POINT             84600017
         BR    GO                  CONSTRUCT AND SEND MESSAGE           84800017
         EJECT                                                          85000017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 85200017
*-*                                                                 *-* 85400017
*-*  C O N S T A N T S ,  W O R K / A R E A S ,  AND   D S E C T S  *-* 85600017
*-*                                                                 *-* 85800017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 86000017
         SPACE                                                          86200017
SUPSAV   DC    18F'0'              MODULE SAVE AREA                     86400017
DIP      DC    F'0'                                                     86600017
         SPACE                                                          86800017
* IHKCBLDM PARAMETER LIST                                               87000017
         SPACE                                                          87200017
SUPMSG   DC    F'0'                MESSAGE DESTINATION -CENTRAL OPERATR 87400017
         DC    X'00'                                                    87600017
SUPOFF   DC    X'03'          MESSAGE OFFSET                            87800017
SUPLNG   DC    X'18'          MESSAGE VARIABLE TEXT LENGTH (24)         88000017
SUPTXT   DS    0CL24          VARIABLE MESSAGE TEXT                     88200017
UID      DC    CL1'N'                                                   88400017
SUPTEX   DS    0CL23                                                    88600017
         DC    CL3'O U'                                                 88800017
KEY      DC    CL4'SERS'                                                89000017
STATUS   DC    CL4' IN '                                                89200017
TERM     DC    CL9'DIRECTORY'                                           89400017
UNIT     DC    CL3'   '                                                 89600017
         SPACE                                                          89800017
SHOW     DC    CL4'SHOW'                                                90000017
OFF      DC    CL3'OFF'                                                 90200017
ON       DC    CL3'ON '                                                 90400017
         SPACE 2                                                        90600017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 90800017
*-*                                                                 *-* 91000017
*-*      C O M M A N D   I N P U T   R E C O R D   D S E C T        *-* 91200017
*-*                                                                 *-* 91400017
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 91600017
         SPACE                                                          91800017
CIRD     DSECT                                                          92000017
CIMAGE   DS    CL80           COMMAND IMAGE                             92200017
CTYPE    DS    CL1            COMMAND OPERATION TYPE                    92400017
OTYPE    DS    CL1            COMMAND OPERAND TYPE                      92600017
RTYPE    DS    CL3            COMMAND REQUEST TYPE                      92800017
*                             - NON-ZERO IF SPECIFIC                    93000017
RESV     DS    CL10           RESERVED                                  93200017
         SPACE 2                                                        93400017
      IHKDSECT TDIR,UDIR,,,LCB,AVT                                      93600017
         EJECT                                                          93800017
      IECTDECB                                                          94000017
         EJECT                                                          94200017
      DCBD     DSORG=BX,DEVD=BS                                         94400017
         SPACE 2                                                        94600017
         END                                                            94800017
