CHUK     TITLE  '   IHKCHUCK - ECB UNCHAIN AND KLEAN-UP MODULE'         00200017
         SPACE                                                          00400017
IHKCHUCK CSECT                                                          00600017
*2340372000,384000,408000                                          000C 00700018
* 379000,701300                                                   19018 00720019
* 360000,172000-174000                                           A24702 00750019
* 702000                                                         A28929 00760020
* 702000                                                         A26537 00770020
*                                                                A25573 00780020
*D 502000                                                        A35003 00785020
*A 421040-421880,494200-495600,689010-689120                     A35003 00790020
*A 623210                                                        A35886 00795020
*C 623210                                                        A47060 00797021
*C 421480,421800                                                 A53120 00798021
         SPACE 2                                                        00800017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   01000017
*                                                                   *   01200017
*   S T A T U S - -                                                 *   01400017
*        CHANGE LEVEL 2, RELEASE 21.6                                   01600021
*                                                                   *   01800017
*                                                                   *   02000017
*   F U N C T I O N / O P E R A T I O N - -                         *   02200017
*                                                                   *   02400017
*     IHKCHUCK PERFORMS THE NECESSARY RJE CLOSEDOWN FUNCTIONS.      *   02600017
*     THESE FUNCTIONS INCLUDE--                                     *   02800017
*       1. FREEING GOTTEN MAIN STORAGE                              *   03000017
*       4. DELETING LOADED MODULES                                  *   03200017
*       2. UNCHAINING RJE READER AND WRITER SUBTASK QMGR ECBS       *   03400017
*       3. CLOSING TELECOMMUNICATION LINES USED BY RJE              *   03600017
*       6. CHECKING FOR ABNORMAL CENTRAL CLOSEDOWN                  *   03800017
*       7. DISPLAYING MESSAGES FOR ERRORS ENCOUNTERED IN RJE        *   04000017
*          CLOSEDOWN FOR THE CENTRAL OPERATOR                       *   04200017
*       5. CLOSING OPENED RJE DATA SETS                             *   04400017
*                                                                   *   04600017
*     A TOTAL OF 128 BYTES OF MAIN STORAGE IS FREED BY THIS MODULE. *   04800017
*     THESE AREAS ARE OBTAINED BY IHKCHNIP IN ONE BLOCK OF 128 BYTES*   05000017
*     FOR ENTRANCE REQUIREMENTS OF THE R/I USED AS A SUBROUTINE.    *   05200017
*     THESE REQUIREMENTS INCLUDE THE OPTION LIST, EXIT LIST, AND    *   05400017
*     R/I ECB, ALL OF WHOSE ADDRESSES ARE IN THE INTERPRETER        *   05600017
*     ENTRANCE LIST.  EACH AREA IS FREED SEPARATELY SINCE THEY MAY  *   05800017
*     HAVE BEEN RELOCATED BY THE READER INTERPRETER.  THE NEL       *   06000017
*     ADDRESS IS OBTAINED FROM THE RJE COMMUNICATION REGION AND     *   06200017
*     ALL AREAS FREED WITH THE NEL AREA BEING FREED LAST.           *   06400017
*                                                                   *   06600017
*     AFTER ALL R/I PARAMETER AREAS ARE FREED, IEFQMUNC IS LOADED   *   06800017
*     TO PREPARE TO UNCHAIN THE READER AND WRITER SUBTASKS QMGR     *   07000017
*     ECB.  THE ADDRESSES OF THESE ECBS ARE ALSO OBTAINED FROM THE  *   07200017
*     RJE COMMUNICATIONS REGION.  A PRELIMINARY CHECK IS MADE TO SEE*   07400017
*     IF THE ECB WAS CHAINED.  IF NO ECB WAS CHAINED FOR THE READER,*   07600017
*     RJE ENCOUNTERED ERRORS IN STARTUP AND UNCHAINING AND CLOSING  *   07800017
*     COMMUNICATION LINES IS IGNORED.                               *   08000017
*                                                                   *   08200017
*     CHAINED QMGR ECBS MEANS THE COMMUNICATIONS LINES WERE ALSO    *   08400017
*     OPENED.  COMMUNICATION LINE DCB ADDRESS ARE OBTAINED FROM THE *   08600017
*     LINE TABLE WHOSE ADDRESS CAN BE FOUND IN THE RJE COMMUNICATION*   08800017
*     REGION. TELECOMMUNICATION LINES ARE CLOSED ONE AT A TIME UNTIL*   09000017
*     ALL ARE CLOSED.  CLOSES ISSUED FOR LINES IN THE LINE TABLE    *   09200017
*     WHICH ARE NOT REFERENCED IN THE STARTED RJE PROCEDURE ARE     *   09400017
*     TREATED AS NO-OPS BY OS.                                      *   09600017
*                                                                   *   09800017
*     NONRESIDENT MODULES LOADED DURING INITIALIZATION ARE DELETED, *   10200017
*     INCLUDING THE UNCHAIN MODULE LOADED BY IHKCHUCK.  THESE       *   10400017
*     MODULES INCLUDE--                                             *   10600017
*       1.  IEFSD447                                                *   10800017
*       2.  IEFQMSSS                                                *   11000017
*       3.  IEFQMDQ2                                                *   11200017
*       4.  IEFQDELE                                                *   11400017
*       5.  IEFQMUNC                                                *   11600017
*                                                                   *   11800017
*     THE DCBS FOR THE SEVEN RJE DATA SETS ARE CLOSED. THESE DATA   *   12000017
*     INCLUDE --                                                    *   12200017
*       1. THE FAST TABLE                                           *   12400017
*       2. THE JED TABLE                                            *   12600017
*       3. THE USER DIRECTORY                                       *   12800017
*       4. THE TERMINAL DIRECTORY                                   *   13000017
*       5. THE BROADCAST AND MESSAGE SLOT DIRECOTRY                 *   13200017
*       6. THE PENDING MESSAGE DATA SET                             *   13400017
*       7. THE BROADCAST MESSAGE DATA SET                           *   13600017
*                                                                   *   13800017
*     THIS MODULE CHECKS THE CLOSEDOWN STATUS IN THE RJE COMMUNI-   *   14000017
*     CATION SWITCH TO DETERMINE IF THE RJE SUBTASKS ENCOUNTERED    *   14200017
*     AN ERROR REQUIRING ABNORMAL CLOSEDOWN OR CLOSEDOWN IS A RESULT*   14400017
*     OF OPERATOR ACTION.                                           *   14600017
*                                                                   *   14800017
*     MESSAGE HANDLING IS PROVIDED FOR THOSE ERROR CONDITIONS       *   15000017
*     DETECTED WHICH REQUIRE OPERATOR AWARENESS.                    *   15200017
*                                                                   *   15400017
*                                                                   *   15600017
*   E N T R Y   P O I N T S - -                                     *   15800017
*                                                                   *   16000017
*     IHKCHUCK IS THE ONLY ENTRY POINT ASSOCIATED WITH THIS ROUTINE.*   16200017
*                                                                   *   16400017
*                                                                   *   16600017
*   I N P U T - -                                                   *   16800017
*                                                                   *   17000017
*   REGISTER 1 CONTAINS THE ADDRESS OF THE FOLLOWING PARAMETERS  A24702 17080019
         SPACE 1                                                 A25573 17160019
*        FIRST WORD -   AVT ADDRESS                              A24702 17240019
*        SECOND WORD -  OPERATION INDICATOR                      A24702 17320019
*                            ZERO -    NORMAL CLOSEDOWN          A24702 17400019
*                            PLUS -    SUBTASK ABEND PROCESSING  A24702 17480019
*                            MINUS -  STAE PROCESSING            A25573 17540020
*                                                                   *   17600017
*                                                                   *   17800017
*   O U T P U T - -                                                 *   18000017
*                                                                   *   18200017
*     ERROR MESSAGES ARE DISPLAYED TO THE CENTRAL OPERATOR AS       *   18400017
*     REQUIRED AND INCLUDE --                                       *   18600017
*                                                                   *   18800017
*       1.   IHK060I ABNORMAL CENTRAL CLOSEDOWN                     *   19000017
*       2.  IHK063I DISK ERROR Q MGR RJE ABORTED                    *   19200017
      EJECT                                                             19600017
*                                                                   *   19800017
*                                                                   *   20000017
*   E X T E R N A L   R O U T I N E S - -                           *   20200017
*                                                                   *   20400017
*     IHKCBLDM - BUILD ERROR MESSAGES FOR CENTRAL OPERATOR          *   20600017
*     IHKCDCMR - CLOSE RJE DATA SETS                                *   20800017
*     IEFQMUNC - UNCHAIN RJE READER AND WTR SUBTASK QMGR ECBS       *   21000017
*                                                                   *   21200017
*   E X I T S - -                                                   *   21400017
*                                                                   *   21600017
*     NORMAL - RETURN TO IHKCHBGN WITH ZERO RETURN CODE             *   21800017
*     ERROR - RETURN TO IHKCHBGN WITH FOUR RETURN CODE              *   22000017
*                                                                   *   22200017
*                                                                   *   22400017
*   T A B L E S / W O R K   A R E A S                               *   22600017
*                                                                   *   22800017
*     STANDARD 18-WORD SAVE AREA                                    *   23000017
*                                                                   *   23200017
*                                                                   *   23400017
*   A T T R I B U T E S - -                                         *   23600017
*                                                                   *   23800017
*     SERIALLY REUSEABLE AND NONRESIDENT                            *   24000017
*                                                                   *   24200017
*  N O T E S - -                                                    *   24400017
*                                                                   *   24600017
*     N/A                                                           *   24800017
*                                                                   *   25000017
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   25200017
      EJECT                                                             25400017
*     M O D U L E   S Y M B O L I C   R E G I S T E R S                 25600017
        SPACE 2                                                         25800017
ZIP      EQU   0              GENERAL PURPOSE EXCEPT INDEXING           26000017
PAR      EQU   1              PARAMETER REGISTER                        26200017
NEL      EQU   2              ADDRESS OF R/I ENTRANCE LIST              26400017
ECB      EQU   3              POINTER TO ECB FOR UNCHAIN                26600017
AVT      EQU   4              ADDRESS OF RJE ADDRESS TABLE              26800017
SWH      EQU   5              ERROR EXIT INDICATOR                      27000017
WOK      EQU   6              GENERAL WORK REGISTER                     27200017
CNT      EQU   7              NUMBER OF LINE TABLE ENTRIES              27400017
NAM      EQU   8              LENGTH OF LINE TABLE ENTRIES              27600017
UNC      EQU   9              IEFQNUNC ENTRY POINT                      27800017
STAE     EQU   10                  PARAMETER REG FOR OP TYPE     A24702 27900019
LWRWORK  EQU   11                 BASE FOR LWR WORK AREA         A28929 27950020
BAS      EQU   12             MODULE BASE REGISTER                      28000017
SAV      EQU   13             MODULE SAVE ADDRESS REGISTER              28200017
BAC      EQU   14             RETURN POINT REG                          28400017
GO       EQU   15             ENTRY POINT AND RETURN CODE               28600017
         SPACE                                                          28800017
         SPACE 2                                                        29000017
*     M O D U L E   S Y M B O L I C   D I S P L A C E M E N T S         29200017
*      AND   V A L U E S                                                29400017
         SPACE                                                          29600017
ZERO     EQU   0                                                        29800017
FOUR     EQU   4                                                        30000017
ATE      EQU   8                                                        30200017
TWLV     EQU  12                                                        30400017
TWTY     EQU  20                                                        30600017
RJEQ     EQU  X'27'                                                     30800017
SEV      EQU   7                                                        31000017
LAST     EQU   X'80'                                                    31200017
O19      EQU   19                                                       31400017
O66      EQU   66                                                       31600017
BITS     EQU   X'03'                                                    31800017
LWRTCB   EQU   X'30'              OFFSET IN LWR WORK AREA FOR    A28929 31810020
*                                 TCB POINTER                    A28929 31820020
TCBTIO   EQU   X'0C'              OFFSET IN TCB FOR TIOT PTR     A28929 31830020
LWKTIOTO EQU   X'24'              OFFSET IN LWR WORK AREA FOR    A28929 31840020
*                                 OLD TIOT POINTER               A28929 31850020
LWKTIOTN EQU   X'28'              OFFSET IN LWR WORK AREA FOR    A28929 31860020
*                                 NEW TIOT POINTER               A28929 31870020
DCBPRT   EQU   X'08'              OFFSET IN DECB FOR DCB PTR     A28929 31880020
DATAOPEN EQU   X'80'              FLAG FOR OPEN SYSOUT DATA SET  A28929 31890020
EIGHT    EQU   8                   OFFSET INTO PARM LIST         A28929 31900020
TWELVE   EQU   12                  OFFSET INTO PARM LIST         A28929 31910020
SIXTEEN  EQU   16                  OFFSET INTO PARM LIST         A28929 31920020
         SPACE 2                                                        32000017
*     S A V E   C A L L E R ' S   R E G I S T E R S ,   C H I A N       32200017
*      S A V E   A R E A S,   AND   S E T   U P   A D D R E S S I N G   32400017
         SPACE                                                          32600017
         B     TWLV(GO,ZIP)             BRANCH AROUND MODULE IDENTIFIER 32800017
         DC    CL8'IHKCHUCK'            MODULE IDENTIFIER               33000017
         STM   BAC,BAS,TWLV(SAV)   SAVE CALLERS REGISTERS               33200017
         BALR  BAS,ZIP             SET UP BASE ADDRESS FOR MODULE       33400017
    USING      *,BAS               TELL ASSEMBLER ABOUT BASE REG        33600017
         SPACE                                                          33800017
         LA    WOK,SAVAR           GET MODULE SAVE AREA ADDRESS         34000017
         ST    SAV,FOUR(WOK)       PLACE CALLER SAVE AREA ADDR IN IT    34200017
         ST    WOK,ATE(SAV)        PLACE IT IN CALLER SAVE AREA         34400017
         LR    SAV,WOK             FIX UP DUM-DUM'S ERROR               34600017
         SPACE                                                          34800017
    USING      IHKZZAVT,AVT        TELL ASM ABOUT DSECT                 35000017
      EJECT                                                             35200017
*     R E T R I E V E   N E L   A D D R E S S   AND   O T H E R         35400017
*      G O O D I E S   FROM   P A S S E D   P A R A M E T E R           35600017
         ST    PAR,SAVPARM        SAVE POINTER TO PARM LIST      A28929 35700020
         SPACE                                                          35800017
         L     AVT,ZERO(PAR)       GET AVT BASE                  A24702 35880019
         L     STAE,FOUR(PAR)      GET OPERATION WANTED          A24702 35960019
         LTR   STAE,STAE           NORMAL CLOSEDOWN?             A24702 36040019
         BNZ   UNCHAIN             NO, DON'T FREEMAIN            A24702 36120019
         L     NEL,IHKZZNEL        GET NEL ADDRESS FOR FREEMAIN         36200017
         USING IEFNEL,NEL                                          000C 36300018
         SPACE 2                                                        36400017
*     F R E E   U P   O P T I O N   L I S T                             36600017
         SPACE                                                          36800017
         LA    ZIP,NELOPTLN        GET LENGTH OF OPTION LIST       000C 36900018
         L     PAR,ZERO(NEL)       GET OPTION LIST ADDRESS FROM NEL     37000017
     FREEMAIN  R,LV=(0),A=(1)      FREE OPTION LIST                000C 37200018
         SPACE 2                                                        37400017
*     F R E E   U P   E X I T   L I S T                                 37600017
         SPACE                                                          37800017
         LA    ZIP,NELEXTLN       LENGTH OF EXIT LIST              000C 37900019
         L     PAR,TWTY(NEL)       GET EXIT LIST ADDRESS FROM NEL       38000017
         SPACE                                                          38200017
     FREEMAIN  R,LV=(0),A=(1)      FREE EXIT LIST                  000C 38400018
         SPACE 2                                                        38600017
*     F R E E   U P   R / I   E C B                                     38800017
         SPACE                                                          39000017
         L     PAR,FOUR(NEL)       GET THE R/I ECB ADDRESS FROM NEL     39200017
         SPACE                                                          39400017
    FREEMAIN   R,LV=8,A=(1)        FREE R/I ECB WITH SUPER ASSIST       39600017
         SPACE 2                                                        39800017
*     F R E E   U P   R / I   E N T R A N C E   L I S T                 40000017
         SPACE                                                          40200017
         LR    PAR,NEL             GET NEL ADDRESS IN PROPER REG        40400017
         SPACE                                                          40600017
         LA    ZIP,NELLEN          LENGTH OF NEL                   000C 40700018
     FREEMAIN  R,LV=(0),A=(1)      FREE NEL                        000C 40800018
         SPACE 2                                                        41000017
         XR    SWH,SWH             REMEMBER NO MESSAGES SENT            41200017
      EJECT                                                             41400017
*     U N C H A I N   R J E   Q M G R   E C B S   FOR   F U T U R E     41600017
*      S T A R T   R J E   H A P P E N I N G S                          41800017
         SPACE 1                                                        42000017
UNCHAIN  EQU   *                                                 A24702 42100019
**************************************************************** A35003 42104020
*  THIS SUBROUTINE IS USED TO TURN OFF THE NON-DISPATCHABLE    * A35003 42108020
*  FLAG IN THE TCB IN CASE A QMNGR FUNCTION IS PENDING         * A35003 42112020
*  IN THE QMNGR ATTACHED TASK. THIS FIX RESOLVES THE PROBLEM   * A35003 42116020
*  OF A HARD WAIT IN UNCHAIN BECAUSE OF A PREVIOUS QMNGR       * A35003 42120020
*  FUNCTION THAT COULDN'T COMPLETE BECAUSE OF AN ABEND.  THIS  * A35003 42124020
*  ALLOWS THE ATTACHED TASK TO BECOME DISPATCHABLE AND FREE UP * A35003 42128020
*  THE BLOCKED PATH TO THE QMNGR FOR UNCHAIN.                  * A35003 42132020
**************************************************************** A35003 42136020
         L     PAR,CVTPTR          GET ADDRESS OF THE CVT        A35003 42140020
         L     PAR,0(PAR)          GET CVTTCBP, PTR TO TCB PTRS  A35003 42144020
         L     PAR,4(PAR)              GET CUR TCB PTR (RJE)     A53120 42148021
         L     PAR,TCBNTCB(PAR)    GET LAST ATTACHED TCB PTR     A35003 42152020
         LA    PAR,NODSPFLG(PAR)   GET PTR TO NON-DISPTACHABLE   A35003 42156020
*                                  BYTE OF QMNGR'S TCB           A35003 42160020
         ST    PAR,SAVNODSP        SAVE PTR,TO RESTORE IT LATER  A35003 42164020
         OC    SAVNODSP,0(PAR)     SAVE THE 'TO BE ABENDED BIT'  A35003 42168020
*                                  OF QMNGR'S TCB, WHILE QMNGR   A35003 42172020
*                                  COMPLETES ITS PENDING FNCTION A35003 42176020
         NI    0(PAR),MARKDSP          MARK TCB AS DISPATCHABLE  A53120 42180021
*                                  BY TURNING OF THE             A35003 42184020
*                                  'TO BE ABENDED' BIT           A35003 42188020
    LOAD       EPLOC=CHUCKUNC      GET IEFQMUNC INTO MAIN STORAGE WITH *42200017
                                   - SUPER ASSIST                       42400017
         SPACE 1                                                        42600017
         LR    UNC,ZIP             KEEP IEFQMUNC ENTRY POINT HANGING    42800017
         L     PAR,IHKZZRDE        GET RJE RDR QMGR ECB ADDRESS         43000017
         LTR   PAR,PAR             HAS RDR PINNED ECB ON QMGR (SWEET)   43200017
         SPACE 1                                                        43400017
         BZ    EXIT                NO, FORGET THIS ECB UNCHAINING BIT   43600017
*                                  - AND HANG IT UP                     43800017
         SPACE 1                                                        44000017
         MVI   ZERO(PAR),ZERO      INSURE UNC UNCHAINING UNPOSTED ECB   44200017
         MVI   FOUR(PAR),RJEQ      PUT Q NUMBER ON WHICH ECB IS CHAINED 44400017
*                                  - IN THE ECB                         44600017
         LR    GO,UNC              GET ENTRY POINT OF UNC IN E.P. REG   44800017
         BALR  BAC,GO              LET QMGR UNCHAIN ONE QMGR ECB        45000017
         SPACE                                                          45200017
         LTR   GO,GO               DID UNCHAINING GO WITHOUT A HITCH    45400017
         BNZ   CHER                NO, BETTER LET THE OPERATER IN ON    45600017
*                                  - THE ACTION                         45800017
         SPACE                                                          46000017
*  TRY TO UNCHAIN THE RJE SYSOUT QMGR ECB                               46200017
         SPACE                                                          46400017
WTR      L     PAR,IHKZZSQE        GET SDQ QMGR ECB ADDRESS             46600017
         LTR   PAR,PAR             HAS THIS ECB BEEN CHAINED BY QMGR    46800017
         BZ    EXIT1               NO, FORGET THIS ECB UNCHAINING BIT   47000017
         SPACE                                                          47200017
         L     WOK,IHKZZSOC        GET ADDRESS OF RJE OUTPUT CLASSES    47400017
         IC    ECB,SEV(WOK)        GET SYSOUT CLASS ASSIGNED FOR RJE    47600017
*                                  - OUTPUT                             47800017
         STC   ECB,FOUR(PAR)       PUT Q NUMBER ON WHICH ECB CHAINED    48000017
         MVI   ZERO(PAR),ZERO      INSURE UNC UNCHAINING UNPOSTED ECB   48200017
         LR    GO,UNC              GET ENTRY POINT OF UNC IN E.P. REG   48400017
         BALR  BAC,GO              LET QMGR UNCHAIN ECB                 48600017
         SPACE                                                          48800017
         LTR   GO,GO               WAS UNCHAIN SUCCESSFUL               49000017
         BZ    EXIT1               YES, CLOSE COMMUNICATIONS LINES      49200017
         BAL   WOK,SNDMSG          NO, SEND MSG TO CENTRAL OPERATOR     49400017
EXIT1    EQU   *                   UNCHAINING HAS FINISHED       A35003 49420020
         L     PAR,SAVNODSP        GET PTR TO QMNGR'S            A35003 49440020
*                                  NON-DISPATCHABLE BYTE         A35003 49460020
*                                  OF IT'S TCB                   A35003 49480020
         OC    0(1,PAR),SAVNODSP   RESTORE THE 'TO BE ABENDED'   A35003 49500020
*                                  BIT, NOW THAT QMNGR ISN'T     A35003 49520020
*                                  BLOCKING THE UNCHAIN'S PATH   A35003 49540020
*                                  TO THE JOBQE                  A35003 49560020
      EJECT                                                             49600017
*    C L O S E   T E L E C O M M U N I C A T I O N   L I N E S          49800017
         SPACE                                                          50000017
         LTR   STAE,STAE                IS STAE PROCESSING ?     A25573 50250020
         LA    GO,FOUR                  SET RETURN CODE          A25573 50300020
         BNZ   CLOSEDSK            GO FLAG OUTPUT AS BYPASSED    A26537 50350020
         USING LINETAB,WOK              TELL ASSEMBLER ABOUT LINE TABLE 50400017
*                                       - DSECT BASE                    50600017
         SPACE                                                          50800017
         L     WOK,IHKZZLNT             GET ADDRESS OF LINE TABLE       51000017
         L     NAM,IHKZZLLN             GET POINTER TO ENTRY LENGHT     51200017
         L     CNT,IHKZZLNB             GET POINTER TO NUMBER OF ENTRY  51400017
         LH    NAM,ZERO(NAM)            GET LENGTH OF EACH ENTRY        51600017
         LH    CNT,ZERO(CNT)            GET NUMBER OF ENTRIES           51800017
         LTR   CNT,CNT                  ARE THERE ANY LINES IN THIS RJE 52000017
*                                       - APPLICATION                   52200017
         BZ    EXIT                     NO, OH REALLY - QUIT WITH       52400017
*                                       - PUZZLED EXPRESSION            52600017
         SPACE                                                          52800017
LOOP     LA    PAR,LINEDCB              GOT SOME, GET ADDR OF DCB ADDR  53000017
         MVI   ZERO(PAR),LAST           TELL OS THERE'S ONLY ONE SUCH   53200017
*                                       - FOR THE PRESENT               53400017
         SPACE                                                          53600017
         CLOSE ,MF=(E,(1))              CLOSE ONE TP LINE               53800017
         SPACE                                                          54000017
         AR    WOK,NAM                  STEP UP TO NEXT LINE ENTRY      54200017
         BCT   CNT,LOOP                 WAS THERE ANOTHER ENTRY TO STEP 54400017
*                                       - UP TO THERE WHAT              54600017
         L     PAR,SAVPARM        RELOAD PARM POINTER            A28929 54604020
         L     STAE,FOUR(PAR)     MAKE SURE CONDITION IS CORRECT A28929 54608020
         LTR   STAE,STAE          NORMAL CLOSEDOWN               A28929 54612020
         BZ    EXIT               YES GO TO EXIT                 A28929 54616020
*                                 NO THEN WE HAD BEST CLOSE ANY  A28929 54620020
*                                 OPEN SYSOUT DATA SETS          A28929 54624020
CLOSEDSK EQU   *                   GO FLAG OUTPUT AS BYPASSED    A26537 54628020
         BAL   UNC,BYPASSO         FLAG IMMEDIATE OUTPUT AS      A26537 54632020
*                                  BYPASSED IMMEDIATE.  TO SAVE  A26537 54636020
*                                  AT THIS TIME OF ABNORMAL CLOSEA26537 54640020
*                                  OR OF RJE ABENDED.            A26537 54644020
         USING LCBDSECT,WOK                                      A28929 54648020
         L     PAR,SAVPARM         RELOAD PARM POINTER           A28929 54652020
         L     WOK,EIGHT(PAR)     LOADS FIRST LCB POINTER        A28929 54656020
         L     CNT,TWELVE(PAR)    LOADS PTR TO NUMBER OF LCBS    A28929 54660020
         LH    CNT,0(CNT)         LOADS NUMBER OF LCBS           A28929 54664020
         L     NAM,SIXTEEN(PAR)   LOADS PTR TO LENGTH OF LCBS    A28929 54668020
         LH    NAM,0(NAM)         LOADS LENGTH OF LCBS           A28929 54672020
CHECKLCB EQU   *                                                 A28929 54676020
         TM    LCBWORKA,DATAOPEN  CHECK IF THIS LINE STILL HAS   A28929 54680020
*                                 A OPEN DATA  SET               A28929 54684020
         BZ    LCBINK             NO, SKIP CLOSE                 A28929 54688020
         L     LWRWORK,LCBWORKA   GET POINTER TO LWR WORKAREA    A28929 54692020
         L     GO,LWRTCB(LWRWORK) GET TCB POINTER FROM WORKAREA  A28929 54696020
         MVC   TCBTIO(FOUR,GO),LWKTIOTN(LWRWORK) MOVE DATA       A28929 54700020
*                                 SETS TIOT INTO TCBS TIOT WORD  A28929 54704020
*                                 FOR CLOSE OF SYSOUT DATA SET   A28929 54708020
         L     PAR,LCBDDECB       LOADS DISK DECB POINTER        A28929 54712020
         L     BAC,DCBPRT(PAR)    LOADS DISK DCB POINTER         A28929 54716020
         CLOSE ((14))             CLOSE DATA SET                 A28929 54720020
         L     GO,LWRTCB(LWRWORK) GET TCB POINTER                A28929 54724020
         MVC   TCBTIO(FOUR,GO),LWKTIOTO(LWRWORK) MOVE IN OLD     A28929 54728020
*                                  TIOT PTR                      A28929 54732020
LCBINK   EQU   *                                                 A28929 54736020
         LA    WOK,0(NAM,WOK)     STEP PTR TO NEXT LCB           A28929 54740020
         BCT   CNT,CHECKLCB       CHECK IF ANYMORE LCBS          A28929 54744020
         LTR   STAE,STAE           TEST FOR ABNORMAL CLOSEDOWN   A26537 54748020
         LA    GO,FOUR             SET RETURN CODE               A26537 54752020
         BM    OUT2                DONT DELETE THESE MODULES.    A26537 54756020
*                                  IF RJE HAS ABENDED,ABDUMP WILLA26537 54760020
*                                  DELETE THEM.                  A26537 54764020
         SPACE 2                                                        54800017
*     G E T   R I D   OF   R J E   L O A D E D   M O D U L E S          55000017
         SPACE                                                          55200017
EXIT     DS    0H                                                       55400017
         SPACE 1                                                        55600017
    DELETE     EPLOC=CHUCK447      SCRATCH ONE USE COUNT ON IEFSD447    55800017
         SPACE 2                                                        56000017
    DELETE     EPLOC=CHUCKSSS      SCRATCH ONE USE COUNT ON IEFQMSSS    56200017
         SPACE 2                                                        56400017
    DELETE     EPLOC=CHUCKDQ2      SCRATCH ONE USE COUNT ON IEFQMDQ2    56600017
         SPACE 2                                                        56800017
    DELETE     EPLOC=CHUCKELE      SCRATCH ONE USE COUNT ON IEFQDELE    57000017
         SPACE 2                                                        57200017
    DELETE     EPLOC=CHUCKUNC      SCRATCH ONE FROM IEFQMUNC USAGE CNT  57400017
      EJECT                                                             57600017
*   C L O S E   R J E   D A T A   S E T S                               57800017
          SPACE                                                         58000017
         L     GO,IHKZZCMR              GET CLOSE MANAGER ENTRY POINT   58200017
         BALR  BAC,GO                   CLOSE OUT RJE DATA SETS         58400017
         SPACE  2                                                       58600017
*      C H E C K   R J E   S U B T A S K   C L O S E D O W N            58800017
         SPACE                                                          59000017
         MVI   CHOFF,O66           SELECT QMGR ERROR MESSAGE            59200017
         L     WOK,IHKZZRCS        GET ADDR OF RJE COMMUNICATIONS       59400017
*                                  - SWITCH                             59600017
         TM    ZERO(WOK),BITS      CHECK FOR QMGR AND PROCEDURE         59800017
*                                  - ERRORS CAUSING RJE TO HANG         60000017
*                                  - IT UP                              60200017
         BM    QMGRERR             QMGR ASSIGN/START OR DELETE ERR      60400017
         BO    PROCERR             PROCEDURE ERROR ON SYSIN             60600017
*                                  - ALLOCATION                         60800017
         SPACE 2                                                        61000017
*     R E T U R N   TO   H E   W H O   S U M M O N E D   C H U C K      61200017
         SPACE                                                          61400017
GETOUT   DS    0H                                                       61600017
         LR    GO,SWH              GET RETURN CODE                      61800017
OUT2     EQU   *                                                 A25573 61900020
         L     SAV,SAVAR+FOUR      GET CALLER SAVE AREA ADDRESS         62000017
    RETURN     (14,12),T,RC=(15)   RETURN TO BEGIN FOR THE END          62200017
         SPACE 1                                                        62203020
*    S A V E   I M M E D I A T E   O U T P U T   A T   A B E N D A26537 62206020
         SPACE 1                                                        62209020
BYPASSO  EQU   *                                                 A26537 62212020
         L     GO,IHKZZDSP        LOAD DSP ADDRESS               A26537 62215020
         ST    GO,SAVEIT          SAVE ADDRESS POINTER           A26537 62218020
         LA    GO,WAITFOR         PUT POINTER TO SPECIAL WAIT    A26537 62221020
*                                 THIS IS DONE SO RJE DOESNT GET A26537 62224020
*                                 CONTROL AGAIN                  A26537 62227020
         ST    GO,IHKZZDSP        PUT IN NEW WAIT PTR            A26537 62230020
         LOAD  EP=IHKCHIRP         BRING IN RJEND PROCESSING MOD A26537 62233020
         ST    ZIP,SAVEADDR        SAVE ENTRY POINT TO IHKCHIRP  A26537 62236020
         L     NAM,IHKZZTDR        GET ADDR OF TERM DIR ENTRY TBLA26537 62239020
         USING TDIREC,NAM          SET BASE FOR TERM DIR ENTRY   A26537 62242020
         L     CNT,IHKZZTNB        GET ADDR OF COUNT             A26537 62245020
        LH    CNT,ZERO(CNT)       GET NUM OF ENTRYS IN TDIR      A26537 62248020
         L     WOK,IHKZZTLN        GET ADDR OF LENGTH            A26537 62251020
         LH    WOK,ZERO(WOK)       GET LENGTH OF ONE TDIR        A26537 62254020
         SPACE 1                                                        62257020
SRCHTDIR EQU   *                   FIND IF RJSTARTED OR IMM OUTPTA26537 62260020
         TM    TDIRSWCH,TDIRRJSN   IS TERM STILL RJSTARTED       A26537 62263020
         BO    SAVEOUTA            YES GO TO SAVE OUTPUT         A26537 62266020
         TM    TDIRSTAT,TDIRNQMN   CAN MESSAGES BE ENQUEUED      A26537 62269020
         BO    SAVEOUT             YES GO TO SAVE OUTPUT         A26537 62272020
         CLC   TDIRFQEB+1(3),ZEROS ARE OUTPUT MESSAGES ENQUEUED  A26537 62275020
         BNE   SAVEOUT             YES GO TO SAVE OUTPUT         A26537 62278020
NXTTDE   EQU   *                   INCREMENT TO CHECK NEXT TDIR  A26537 62281020
         LA    NAM,ZERO(WOK,NAM)   PT TDIR BASE TO NEXT ENTRY    A26537 62284020
         BCT   CNT,SRCHTDIR        CHECK NEXT TDIR ENTRY         A26537 62287020
         DELETE EP=IHKCHIRP        CHIRP HAS FINISHED ITS FUNCT A26537 62290020
         L     GO,SAVEIT          RELOAD DSP ADDRESS AND PUT IT  A26537 62293020
         ST    GO,IHKZZDSP        BACK                           A26537 62296020
         BR    UNC                 ALL OUTPUT HAS BEEN SAVED     A26537 62299020
         SPACE 1                                                        62302020
SAVEOUTA EQU   *                   ASSURE SWITCH OFF BEFORE      A26537 62305020
         NI    TDIRSWCH,TDIRRJSF   CALLING RJEND PROCESSOR       A26537 62308020
SAVEOUT  EQU   *                   SAVE OUTPUT ASSGND TO THIS TDIA26537 62311020
         LA    BAC,RJSTABND        GET ADR OF BLNK CARD IMAGE PTRA26537 62314020
         ST    BAC,IHKZZCDE        SET PTR TO CARD IMAGE         A26537 62317020
         ST    NAM,IHKZZTDE        PUT IN AVT ADR OF CURRENT TDIRA26537 62320020
         OI    IHKZZDSP,X'40'          SET ABEND FLAG            A47060 62321021
         LR    PAR,AVT             PT PARM REG W/AVT ADDR        A26537 62323020
         L     GO,SAVEADDR         GET ADR OF RJEND PROCESSOR MODA26537 62326020
         BALR  BAC,GO              CALL RJEND PROCESSOR          A26537 62329020
         B     NXTTDE              PREPARE TO CHECK NEXT TDIR    A26537 62332020
         SPACE 1                                                        62335020
WAITFOR  EQU   *                   WAIT FOR CHIRP TO COPY        A26537 62338020
*                                  IMMEDIATE OUTPUT TO DISK.     A26537 62341020
         STM   BAC,BAS,TWLV(SAV)      SAVE REGS                  A26537 62344020
         WAIT  ECB=(PAR)                                         A26537 62347020
         LM    BAC,BAS,TWLV(SAV)          RESTORE REGS           A26537 62350020
         BR    BAC                RETURN TO CHIRP, SO IT CAN     A26537 62353020
*                                  RETURN TO CHUCK AT PT OF DEPTRA26537 62356020
         SPACE 1                                                        62359020
         SPACE 2                                                        62400017
*     S E N D   M E S S A G E   TO   C E N T R A L   O P E R A T O R    62600017
         SPACE                                                          62800017
*   TRY --  IHK063I DISK ERROR IN CLOSEDOWN                             63000017
         SPACE                                                          63200017
CHER     LA    WOK,WTR             TRY UNCHAIN OF SYSOUT QMGR ECB AFTER 63400017
*                                  - MSG FOR RDR CATASTROPHE            63600017
         SPACE 1                                                        63800017
SNDMSG   LA    PAR,CHMSG           GET BUILDING BLOCKS FOR MSG MODULE   64000017
         L     GO,IHKZZLDM         GET ENTRY POINT                      64200017
         BALR  BAC,GO              EXIT TO GET MESSAGE BUILT            64400017
         SPACE                                                          64600017
    WTO        ,MF=(E,(1))         RATTLE OPERATOR'S BALL               64800017
         SPACE 1                                                        65000017
         LA    SWH,FOUR            REMEMBER MSG SENT AND SET RETURN FOR 65200017
*                                  * BEGIN NOW AT ITS WIT'S END         65400017
         BR    WOK                 RETURN TO MORE SERIOUS PROCESSING    65600017
PROCERR  MVI   CHOFF,O19           SELECT ABNORMAL CLOSEDOWN MSG        65800017
QMGRERR   LA    WOK,GETOUT          REMBER WHERE TO GO WHEN MSG SENT    66000017
         B     SNDMSG              BUILD AND SEND OPERATOR MESSAGE      66200017
         EJECT                                                          66400017
*     C O N S T A N T S   R E Q U I R E D   FOR   O P E R A T I O N     66600017
         SPACE                                                          66800017
SAVAR    DC    18F'0'                                                   67000017
CHUCK447 DC    CL8'IEFSD447'                                            67200017
CHUCKSSS DC    CL8'IEFQMSSS'                                            67400017
CHUCKDQ2 DC    CL8'IEFQMDQ2'                                            67600017
CHUCKELE DC    CL8'IEFQDELE'                                            67800017
CHUCKUNC DC    C'IEFQMUNC'                                              68000017
CHMSG    DC    F'-1'                                                    68200017
         DC    X'00'                                                    68400017
CHOFF    DC    X'45'               SELECT DISK ERROR IN CLOSEDOWN       68600017
         DC    X'00'                                                    68800017
RJSTABND DC  CL80'          IHK160I  ABNORMAL CENTRAL CLOSEDOWN' A26537 68820020
         DC    C'F'                                              A26537 68840020
ZEROS    DC    XL3'0'              ZEROS TO COMPARE TO NO ADDRESSA26537 68860020
SAVPARM  DC    F'0'               PARM SAVE AREA                 A28929 68880020
SAVEIT   DC    F'0'                ADDR POINTER SAVE AREA        A26537 68900020
CVTPTR   EQU   X'10'               ADDRESS OF THE CVT            A35003 68901020
TCBNTCB  EQU   X'88'               ATTACHED TASK TCB PTR         A35003 68902020
NODSPFLG EQU   X'21'               DISPLACEMENT INTO TCB OF      A35003 68903020
*                                  NON-DISPATCHABLE FLAGS        A35003 68904020
MARKDSP  EQU   X'BF'               USED TO TURN OFF, IN TCB FOR  A35003 68905020
*                                  QMNGR, A NON-DISPATCHABLE BIT A35003 68906020
SAVNODSP DC    AL1(0)              SAVES QMNGR'S 'TO BE ABENDED' A35003 68907020
*                                  BIT FROM THE NON-DISPATCHABLE A35003 68908020
*                                  FLAGS FETCHED FROM QMNGR'S    A35003 68909020
*                                  TCB, WHILE EXIT DURING STAE   A35003 68910020
         DC    AL3(0)              PTR TO NON-DISPATCHABLE BYTE  A35003 68911020
*                                  OF QMNGR'S TCB                A35003 68912020
SAVEADDR DC    F'0'                SAVE AREA FOR IHKCHIRP'S EPA  A26537 68920020
        SPACE 2                                                         69000017
LINETAB  DSECT                                                          69200017
LINENAME DS    CL8                                                      69400017
LINEDCB  DS    CL4                                                      69600017
LINERLN  DS    CL4                                                      69800017
        SPACE 2                                                         70000017
IEFNEL   DSECT                                                          70060018
         IEFNEL EXITS=(TXT,RTN,SMF,IAM)                           19018 70130019
         IHKDSECT    TDIR,,FASTAB,,LCB,AVT                       A26537 70230020
         END                                                            70400017
