UMB      TITLE 'IHKCRUMB - MESSAGE BUILDER, MCS'                        00200018
IHKCRUMB CSECT                                                          00400018
         ENTRY IHKCBLDM                                                 00600018
IHKCBLDM DS    0H                                                       00800018
*********************************************************************** 01000018
*STATUS.                                                              * 01200018
*   CHANGE LEVEL 0                                                    * 01400018
*                                                                     * 01600018
*FUNCTION/OPERATION.                                                  * 01800018
*   THIS ROUTINE BUILDS RJE SYSTEM MESSAGES BY COMBINING THE MESSAGE  * 02000018
*   PARAMETERS PASSED TO IT FROM THE CALLING ROUTINE WITH 'CANNED'    * 02200018
*   MESSAGE TEXTS OBTAIN FROM THE SYSTEM MESSAGE DATA SET (IHKCBOFS). * 02400018
*   1. A MESSAGE FOR A WORK STATION IS BUILT IN A TERMINAL QUEUE ENTRY* 02600018
*      BLOCK FURNISHED BY IHKCCPLM. THE TQEB IS PASSED TO THE RJE     * 02800018
*      QUEUE MANAGER FOR ENQUEUING.                                   * 03000018
*   2. A MESSAGE FOR THE CENTRAL OPERATOR IS BUILT IN A 60-BYTE BIN   * 03200018
*      AND SENT BY A WRITE TO OPERATOR INSTRUCTION.                   * 03400018
*   3. A MESSAGE TO BE RETURNED TO THE CALLER IS BUILT IN THE 60-BYTE * 03600018
*      BIN AND THE ADDRESS OF THE BIN IS RETURNED TO THE CALLER.      * 03800018
*                                                                     * 04000018
*ENTRY POINTS.                                                        * 04200018
*                                                                     * 04400018
*        IHKCBLDM IS THE ONLY ENTRY POINT. THE CALLING SEQUENCE IS-   * 04600018
*   LA   1,PARAMETER LIST                                             * 04800018
*   CALL IHKCBLDM                                                     * 05000018
*                                                                     * 05200018
*INPUT.                                                               * 05400018
*   STANDARD SUBROUTINE LINKAGE PREVAILS. REGISTER ONE POINTS TO      * 05600018
*   A PARAMETER LIST ALIGNED ON A FULL WORD BOUNDARY. THE LIST        * 05800018
*   CONTAINS-                                                         * 06000018
*                                                                     * 06200018
*        BYTES                                                        * 06400018
*        0-3        ADDRESS OF TERMINAL DIRECTORY ENTRY FOR TERMINAL  * 06600018
*                   TO WHICH MESSAGE IS TO BE SENT. IF ZERO'S MESSAGE * 06800018
*                   WRITTEN TO CENTRAL OPERATOR. IF HIGH ORDER BIT IS * 07000018
*                   ON ,THE ADDRESS OF THE SIXTY BYTE MESSAGE IS      * 07200018
*                   RETURNED IN REGISTER ONE.                         * 07400018
*        4-5        MESSAGE OFFSET                                    * 07600018
*        6          LENGTH INDICATOR                                  * 07800018
*        7-END      MESSAGE PARAMETERS                                * 08000018
*                                                                     * 08200018
*OUTPUT.                                                              * 08400018
*   MESSAGE IS QUEUED ON TERMINAL QUEUE, IS SENT TO THE CENTRAL       * 08600018
*   OPERATOR, OR IS RETURNED.                                         * 08800018
*                                                                     * 09000018
*EXTERNAL ROUTINES.                                                   * 09200018
*                                                                     * 09400018
*        IHKCCPLM - PROVIDE QEB'S FOR IHKCBLDM                        * 09600018
*        IHKCCQMR - ENQUEUE QEB'S ON TERMINAL QUEUES                  * 09800018
*        IHKCHOFS - CSECT CONTAINING CANNED MESSAGE TEXT. THIS ROUTINE* 10000018
*                   IS NOT EXECUTABLE.                                * 10200018
*                                                                     * 10400018
*EXITS-NORMAL.                                                        * 10600018
*                                                                     * 10800018
*   RETURN TO CALLING PROGRAM. REGISTER ONE HAS ADDRESS OF SIXTY BYTE * 11000018
*   MESSAGE IF THIS OPTION WAS TAKEN.                                 * 11200018
*                                                                     * 11400018
*EXITS-ERROR                                                          * 11600018
*   N/A                                                               * 11800018
*                                                                     * 12000018
*TABLES/WORK AREAS.                                                   * 12200018
*        IHKCHOFS- IS A TABLE CONTAINING A SERIES OF POINTERS TO THE  * 12400018
*   MESSAGE TEXTS. IT ALSO HOLDS THE MESSAGE TEXTS.                   * 12600018
*                                                                     * 12800018
*ATTRIBUTES.                                                          * 13000018
*   RE-ENTRANT. THERE IS A LOCKED DOOR ON THE ROUTINE WHICH ALLOWS    * 13200018
*   ONLY ONE USER TO USE THE ROUTINE AT A TIME. THERE IS ONE EXCEPTION* 13400018
*   TO THIS. A CALLER REQUESTING RETURN OF THE MESSAGE CAN ENTER THE  * 13600018
*   ROUTINE AT ANY TIME.                                              * 13800018
*                                                                     * 14000018
*NOTES.                                                               * 14200018
*   N/A                                                               * 14400018
*                                                                     * 14600018
*********************************************************************** 14800018
         EJECT                                                          15000018
*********************************************************************** 15200018
*                                                                       15400018
*                             REGISTER EQUATES                          15600018
*                                                                       15800018
*********************************************************************** 16000018
*                                                                       16200018
R0       EQU   0                   MCS CODE                             16400018
R1       EQU   1                   PARM. REG.                           16600018
R2       EQU   2                   BASE FO MCS TABLE & QEB SAVE         16800018
R3       EQU   3                   TERMINAL PTR.                        17000018
R4       EQU   4                   PTR. TO MSG                          17200018
R5       EQU   5                   WORK REG.                            17400018
R6       EQU   6                   ADDR. OF CANNED OR VARIABLE TEXT     17600018
R7       EQU   7                   LENGTH OF TEXT SEGMENT               17800018
LINK     EQU   8                   LINK REG.                            18000018
R9       EQU   9                   TOTAL TEXT LENGTH                    18200018
PARMBASE EQU   10                  BASE OF DSECT FOR PARM. LIST         18400018
AVTBASE  EQU   11                  BASE OF AVT                          18600018
R12      EQU   12                  BASE OF MODULE                       18800018
R13      EQU   13                  SAVE REG.                            19000018
R14      EQU   14                  RETURN REG.                          19200018
R15      EQU   15                  GO REG.                              19400018
         SPACE 3                                                        19600018
*********************************************************************** 19800018
*                                                                       20000018
*                             INITIALIZATION                            20200018
*                                                                       20400018
*********************************************************************** 20600018
*                                                                       20800018
         SAVE  (14,12)             SAVE REGISTERS                       21000018
         BALR  R12,0                                                    21200018
         USING *,R12               SET UP ADDRESSABILITY FOR MODULE     21400018
         USING PARMS,PARMBASE           AND PARM. LIST                  21600018
         USING TDIREC,R3                AND TDR                         21800018
         USING IHKZZAVT,AVTBASE         AND AVT                         22000018
         L     AVTBASE,AVT                                              22200018
         B     AROUNDID                                                 22400018
         DC    C'IHKCRUMB'         IDENTIFY MODULE                      22600018
         SPACE 2                                                        22800018
AROUNDID DS    0H                                                       23000018
         LR    PARMBASE,R1         GET BASE FOR PARM. LIST              23200018
         LA    R5,SAVE2            GET ADDR. OF REENTRANT SAVE AREA     23400018
         L     R3,TERM             GET TERMINAL PTR.                    23600018
         LTR   R3,R3               IS MSG. TO BE RETURNED               23800018
         BM    CHAIN               YES, USE REENTRANT SAVE AREA         24000018
         EJECT                                                          24200018
         SR    R14,R14             SET UP FOR LOCKED DOOR               24400018
         L     R15,IHKZZDSP        GET DISPATCHER ADDR.                 24600018
         TS    LOCK                SET LOCKED DOOR                      24800018
         BCR   7,R15               IF LOCKED, GO WAIT                   25000018
         LA    R5,SAVE1            GET ADDRESS OF SAVE AREA             25200018
         SPACE                                                          25400018
CHAIN    DS    0H                  CHAIN SAVE AREAS                     25600018
         ST    R5,8(R13)                                                25800018
         ST    R13,4(R5)                                                26000018
         LR    R13,R5                                                   26200018
         SPACE 2                                                        26400018
         LTR   R3,R3               REMOTE MSG.                          26600018
         BP    REMOTE              YES, HANDLE REMOTE                   26800018
         SPACE 2                                                        27000018
*********************************************************************** 27200018
*                                                                       27400018
*                             CENTRAL MESSAGE                           27600018
*                                                                       27800018
*********************************************************************** 28000018
         SPACE                                                          28200018
         LA    R4,WTOPARM          GET ADDR. OF WTO LIST                28400018
         BAL   LINK,SUBVAR         MOVE VARIABLE TEXT                   28600018
         SPACE 1                                                        28800018
         LA    R15,ENDWTO           GET ADDRESS OF END OF LIST - 1      29000018
LOOP     CLI   0(R15),BLANK        IS THIS A BLANK                      29200018
         BNE   END                 NO, THIS IS END OF MESSAGE           29400018
         BCT   R15,LOOP            YES, KEEP LOOPING                    29600018
         SPACE 1                                                        29800018
END      DS    0H                                                       30000018
         IC    R7,0(R9)            GET MCS CODE OFFSET                  30200018
         LA    R2,MCSTAB                                                30400018
         USING  MCSTAB,R2               AND MCSTAB                      30600018
         AR    R2,R7               GET ADDRESS OF PROPER CODES          30800018
         MVC   1(4,R15),MCSTAB     MOVE CODES TO END OF MESSAGE         31000018
         OI    MCSFLAGS,RCN        INDICATE ID IN R0                    31200018
         CLC   RC,3(R15)           CHECK FOR RC ROUTING CODE            31400018
         BE    RCON                IF RC, DO NOT TURN OFF BIT           31600018
         NI    MCSFLAGS,RCF        TURN OFF BIT FOR ID IN R0            31800018
RCON     DS    0H                                                       32000018
         LA    R1,WTOPARM          GET ADDR. OF WTO LIST                32200018
         SR    R15,R1              GET LENGTH - 1                       32400018
         LA    R15,1(R15)          GET LENGTH+4                         32600018
         STH   R15,WTOLEN          PUT LENGTH IN WTO PARM LIST          32800018
         SR    R0,R0               ZERO FOR IC                          33000018
         IC    R0,IHKZZOFS         PICK UP MCS CODE FROM AVT            33200018
         SPACE 1                                                        33400018
         LTR   R3,R3               SHOULD WTO BE DONE                   33600018
         BM    NOWTO               NO, SET UP RETURN                    33800018
         EJECT                                                          34000018
         WTO   ,MF=(E,(1))         ISSUE WTO                            34200018
         LA    R1,DUMECB           SET UP FOR DUMMY WAIT                34400018
         L     R15,IHKZZDSP        GO TO DISPATCHER                     34600018
         BALR  R14,R15                                                  34800018
         B     RETURN              RETURN TO CALLER                     35000018
         SPACE 1                                                        35200018
NOWTO    DS    0H                                                       35400018
         L     R13,SAVE2+4         GET HIS SAVE PTR.                    35600018
         ST    R1,24(R13)          SET UP RETURN                        35800018
         B     RTRN                RETURN                               36000018
         SPACE 4                                                        36200018
*********************************************************************** 36400018
*                                                                       36600018
*                             REMOTE MESSAGE                            36800018
*                                                                       37000018
*********************************************************************** 37200018
         SPACE 1                                                        37400018
REMOTE   DS    0H                                                       37600018
         XC    PLMLIST,PLMLIST     SET UP PARMLIST TO GET MSG. QEB      37800018
         BAL   LINK,SUBPLM         GO TO POOL MANAGER                   38000018
         LR    R4,R2               GET  QEB ADDR.                       38200018
         BAL   LINK,SUBVAR         MOVE VARIABLE TEXT                   38400018
         LR    R4,R2               RESTORE QEB PTR.                     38600018
         SPACE 1                                                        38800018
         MVI   0(R4),MSGQEB        INDICATE MSG QEB                     39000018
         CLC   4(3,R4),IHK         IHK MSG                              39200018
         BNE   AROUND                                                   39400018
         MVI   7(R4),ONE           INSERT 1 INTO TEXT                   39600018
         SPACE 1                                                        39800018
AROUND   DS    0H                                                       40000018
         TM    TDIRSTAT,TDIRNQMN   CAN MSG BE ENQUD                     40200018
         BO    QMGR                YES, GO TO Q MGR                     40400018
         EJECT                                                          40600018
*********************************************************************** 40800018
*                                                                       41000018
*                        PUT MESSAGE ON DELAYED DATA SET                41200018
*                                                                       41400018
*********************************************************************** 41600018
         SPACE 1                                                        41800018
         ST    R3,MEQTDE           PUT TDE IN MEQ LIST                  42000018
         LA    R5,4(R4)            GET ADDR OF MSG                      42200018
         ST    R5,MEQMSG           PUT IT IN MEQ LIST                   42400018
         SPACE 1                                                        42600018
         LOAD  EPLOC=ADMEQ         GET IHKCDMEQ INTO CORE               42800018
         LA    R1,MEQLIST          GET PARM. ADDR.                      43000018
         LR    R15,0                                                    43200018
         BALR  R14,R15             GO TO MEQ                            43400018
         DELETE EPLOC=ADMEQ        REMOVE IHKCDMEQ                      43600018
         LA    LINK,RETURN         RETURN QEB TO POOL AND RETURN        43800018
         SPACE 3                                                        44000018
*********************************************************************** 44200018
*                                                                       44400018
*                   SUBROUTINE - GET OR RETURN QEB                      44600018
*                                                                       44800018
*********************************************************************** 45000018
         SPACE 2                                                        45200018
SUBPLMA  ST    R4,PLMQEB           STORE QEB ADDR.                      45400018
SUBPLM   LA    R1,PLMLIST                                               45600018
         L     R15,IHKZZPLM        GO TO IHKCCPLM                       45800018
         BALR  R14,R15                                                  46000018
         LR    R2,R1               SAVE QEB POINTER                     46200018
         BR    LINK                                                     46400018
         SPACE 4                                                        46600018
*********************************************************************** 46800018
*                                                                       47000018
*                   SUBROUTINE - MOVE CANNED AND VARIABLE TEXT          47200018
*                                                                       47400018
*********************************************************************** 47600018
         SPACE 2                                                        47800018
SUBVAR   DS    0H                                                       48000018
         MVI   4(R4),BLANK         BLANK OUT MSG. AREA                  48200018
         MVC   5(59,R4),4(R4)                                           48400018
         SPACE 1                                                        48600018
         LH    R5,OFFSET           GET OFFSET OF CANNED TEXT            48800018
         SLA   R5,1                MULTIPLY BY 2                        49000018
         A     R5,IHKZZOFS         ADD TO BEGINNING OF MSG. CSECT       49200018
         SPACE 2                                                        49400018
         SR    R7,R7               ZERO FOR IC                          49600018
         IC    R7,1(R5)            GET DISPLACEMENT WITHIN CSECT        49800018
         L     R6,IHKZZUM0         DEFAULT TO RESIDENT CSECT            50000018
         CLI   0(R5),DEFAULT       IS MSG IN RESIDENT CSECT?            50200018
         BE    ARDLOAD             YES, DO NOT LOAD NON-RESIDENT        50400018
         MVC   EPLOC+7(1),0(R5)    GET LOAD MODULE INDEX TO NAME        50600018
         LOAD  EPLOC=EPLOC         LOAD PROPER MSG CSECT                50800018
         LR    R6,R0               SAVE ADDRESS OF CSECT                51000018
         SPACE 2                                                        51200018
ARDLOAD  DS    0H                                                       51400018
         LA    R9,0(R6,R7)         GET ADDRESSES OF MSG                 51600018
         LM    R6,R7,0(R9)         GET ADDR. OF THIS & NEXT MSG.        51800018
         BCTR  R7,0                DECREMENT TO MOVE                    52000018
         LR    R9,R7               SAVE ADDRESS OF MCS CODE             52200018
         SPACE 1                                                        52400018
         SR    R7,R6               SUBT. TO GET LENGTH                  52600018
         EX    R7,MOVE             MOVE CANNED TEXT                     52800018
         CLI   0(R5),DEFAULT       WAS MODULE LOADED?                   53000018
         BE    ARDELETE            NO, BRANCH AROUND DELETE             53200018
         DELETE EPLOC=EPLOC        DELETE LOAD MODULE                   53400018
ARDELETE DS    0H                                                       53600018
         LA    R4,1(R7,R4)         STEP PTR.                            53800018
         MVI   3(R4),BLANK         BLANK OUT MCS CODE                   54000018
         IC    R7,LENGTH           GET LENGTH OF VARIABLE INFO.         54200018
         LTR   R7,R7               IS LENGTH ZERO                       54400018
         BCR   8,LINK              YES, NO MOVE NECESSARY               54600018
         SPACE 2                                                        54800018
         LA    R6,MESSAGE          GET ADDR. OF VARIABLE TEXT           55000018
         BCTR  R7,0                DECREMENT FOR MOVE                   55200018
         EX    R7,MOVE             MOVE VARIABLE TEXT                   55400018
         BR    LINK                RETURN                               55600018
         SPACE 4                                                        55800018
*********************************************************************** 56000018
*                                                                       56200018
*                        PUT QEB ON TERMINAL QUEUE                      56400018
*                                                                       56600018
*********************************************************************** 56800018
         SPACE 1                                                        57000018
QMGR     DS    0H                                                       57200018
         STM   R3,R4,QMGLIST       SET UP TO PUT QEB ON TERM. Q         57400018
         LA    R1,QMGLIST                                               57600018
         L     R15,IHKZZQMG        GO TO IHKCCQMG                       57800018
         BALR  R14,R15                                                  58000018
         SPACE 4                                                        58200018
*********************************************************************** 58400018
*                                                                       58600018
*                             RETURN TO CALLER                          58800018
*                                                                       59000018
*********************************************************************** 59200018
*                                                                       59400018
RETURN   DS    0H                                                       59600018
         L     R13,SAVE1+4         GET SAVE AREA PTR.                   59800018
         NI    LOCK,UNLOCK         UNLOCK DOOR                          60000018
RTRN     DS    0H                                                       60200018
         RETURN (14,12),T          RETURN TO CALLER                     60400018
         EJECT                                                          60600018
*********************************************************************** 60800018
*                                                                       61000018
*                             EQUATES                                   61200018
*                                                                       61400018
*********************************************************************** 61600018
*                                                                       61800018
DEFAULT  EQU   X'FF'               DEFAULT MSG CSECT IS RESIDENT        62000018
ONE      EQU   C'1'                ID OF REMOTE MSG                     62200018
BLANK    EQU   C' '                                                     62400018
MSGQEB   EQU   X'80'               ID OF MSG QEB                        62600018
UNLOCK   EQU   0                   UNLOCK DOOR                          62800018
RCN      EQU   X'40'               INDICATE CONSOLE ID IN R0            63000018
RCF      EQU   X'BF'               TURN OFF BIT FOR ID IN R0            63200018
         SPACE 2                                                        63400018
*********************************************************************** 63600018
*                                                                       63800018
*                             CONSTANTS                                 64000018
*                                                                       64200018
*********************************************************************** 64400018
         SPACE 1                                                        64600018
LOCK     DC    X'00'               LOCKED DOOR INDICATOR                64800018
RC       DC    H'0'                TEST FOR RC CODES                    65000018
MOVE     MVC   4(0,R4),0(R6)       EXECUTED MOVE FOR TEXT               65200018
EPLOC    DC    C'IHKCHUM '         NAME OF MODULE TO BE LOADED          65400018
SAVE1    DC    18F'0'              REGULAR SAVE AREA                    65600018
         SPACE 1                                                        65800018
SAVE2    DC     3F'0'              REENTRANT SAVE AREA                  66000018
DUMECB   DC    X'40000000'         DUMMY POSTED ECB                     66200018
AVT      DC    V(IHKCACOM)         ADDR. OF AVT                         66400018
QMGLIST  DS    0F                  TWO-WORD PARM. LIST FOR PLM & QMG    66600018
PLMLIST  DS    0XL8                                                     66800018
         DC    F'0'                                                     67000018
PLMQEB   DC    F'0'                                                     67200018
MEQLIST  DS    0F                  SIX-WORD PARM. LIST FOR MEQ          67400018
         DC    V(IHKCDCBS)              ADDR. OF RESIDENT DCB'S         67600018
         DC    V(IHKAADSP)              ADDR. OF DISPATCHER             67800018
MEQTDE   DC    A(0)                     ADDR. OF TDR ENTRY              68000018
         DC    V(IHKCDTDR)              ADDR. OF TDR                    68200018
         DC    V(IHKCDTMR)              ADDR. OF TDR MANAGER            68400018
MEQMSG   DC    A(0)                     ADDR. OF MSG                    68600018
ADMEQ    DC    C'IHKCDMEQ'         MSG ENQUEUE ROUTINE                  68800018
IHK      EQU   ADMEQ               TEST FOR RJE MSG                     69000018
         SPACE 2                                                        69200018
WTOPARM  DS    0F                  17-WORD PARM. LIST FOR WTO           69400018
WTOLEN   DC    H'0'                LENGTH OF MESSAGE + CODES            69600018
MCSFLAGS DC    X'8000'             INDICATE USING MCS                   69800018
WTOMSG   DC    CL64' '                                                  70000018
ENDWTO   EQU   *-5                                                      70200018
         EJECT                                                          70400018
*********************************************************************** 70600018
*                                                                       70800018
*                             TABLE OF CODES FOR MCS                    71000018
*                                                                       71200018
*********************************************************************** 71400018
MCSTAB   DS    0C                                                       71600018
         DC    CL4' '                   REMOTE MESSAGE                  71800018
         DC    X'08000000'              RC, ICR                         72000018
         DC    X'04004000'              COI, JS                         72200018
         DC    X'10004000'              COI, SS                         72400018
         DC    X'10005040'              DP,COI,ER, SS                   72600018
         SPACE 2                                                        72800018
*********************************************************************** 73000018
*                                                                       73200018
*                             DSECT OF PARAMETER LIST                   73400018
*                                                                       73600018
*********************************************************************** 73800018
PARMS    DSECT                                                          74000018
TERM     DS    F                   ZERO= WTO                            74200018
*                                  NEGATIVE= RETURN TEXT                74400018
*                                  POSITIVE= PUT ON TERMINAL Q          74600018
OFFSET   DS    H                   OFFSET OF CANNED TEXT                74800018
LENGTH   DS    C                   LENGTH OF VARIABLE TEXT              75000018
MESSAGE  DS    C                   VARIABLE TEXT                        75200018
         SPACE 4                                                        75400018
         IHKDSECT TDIR,,,,,AVT                                          75600018
         END                                                            75800018
