IHKQMNGR CSECT                                                          00600017
QMR      TITLE 'SUBTASK TO INTERFACE WITH OS QUEUE MANAGER'             01200017
*D 576000                                                        S21945 01500021
*A 574000,578000                                                 S21945 01800021
*                                                                     * 02100021
*  STATUS - CHANGE LEVEL 1, RELEASE 21                                * 02400021
*                                                                     * 02700021
*FUNCTION/OPERATION - THIS ROUTINE PROVIDES AN INTERFACE WITH OS QUEUE* 03000017
*   MANAGER WHICH ENABLES AN RJE SUBTASK TO WAIT IN THE DISPATCHER.   * 03600017
*   THIS ROUTINE IS ATTACHED BY IHKRJBGN.  IT ISSUES A WAIT ON ITS    * 04200017
*   ECBLIST.  WHEN AN RJE SUBTASK NEEDS A QUEUE MANAGER FUNCTION, IT  * 04800017
*   POSTS AN ECB IN THE ECBLIST OF IHKQMNGR WHICH GIVES IHKQMNGR      * 05400017
*   CONTROL.  IT LOADS QUEUE MANAGER, AND WHEN QUEUE MANAGER RETURNS, * 06000017
*   IT DELETES QUEUE MANAGER AND POSTS THE ECB OF THE RJE SUBTASK.    * 06600017
*   IHKQMNGR ISSUES A WAIT AGAIN.  AT CLOSEDOWN, IHKRJBGN POSTS AN ECB* 07200017
*   FOR IHKQMNGR AND PASSES A SPECIAL PARAMETER TO TELL IHKQMNGR TO   * 07800017
*   RETURN.                                                           * 08400017
*                                                                     * 09000017
*ENTRY POINT -                                                        * 09600017
*        IHKQMNGR                                                     * 10200017
*   CALLING SEQUENCE INITIALLY - LA     1,PARMLIST                    * 10800017
*                                ATTACH EP=IHKQMNGR                   * 11400017
*   WHERE PARMLIST HAS ADDRESS OF ECB TO BE POSTED FOR IHKRJBGN AND   * 12000017
*                      ADDRESS OF ECBLIST FOR IHKQMNGR                * 12600017
*                                                                     * 13200017
*   CALLING SEQUENCE WHEN QUEUE MANAGER FUNCTION NEEDED -             * 13800017
*                                LA     0,PARMLIST                    * 14400017
*                                LA     1,QMECB                       * 15000017
*                                POST   (1),(0)                       * 15600017
*   WHERE PARMLIST HAS ADDRESS OF QUEUE MANAGER PARAMETER AREA AND    * 16200017
*                      ADDRESS OF ECB TO BE POSTED WHEN QUEUE MANAGER * 16800017
*                         FUNCTION IS COMPLETE                        * 17400017
*         QMECB IS AN ECB IN THE ECBLIST OF IHKQMNGR                  * 18000017
*                                                                     * 18600017
*INPUT - AS DESCRIBED ABOVE.                                          * 19200017
*                                                                     * 19800017
*OUTPUT - THE QUEUE MANAGER FUNCTION IS DONE, THE RETURN CODE FROM    * 20400017
*   QUEUE MANAGER IS IN THE LOW-ORDER THREE BYTES OF THE ECB OF THE   * 21000017
*   RJE SUBTASK, AND THE ECB IS POSTED.                               * 21600017
*                                                                     * 22200017
*EXTERNAL ROUTINES -                                                  * 22800017
*        WAIT -                         TO WAIT ON ECBLIST            * 23400017
*        IEFQMSSS - ASSIGN/START        TO INITIALIZE A QUEUE ENTRY   * 24000017
*                                       AND ASSIGN INITIAL TTR'S FOR  * 24600017
*                                       WRITING                       * 25200017
*                 - WRITE AND ASSIGN    TO WRITE A RECORD ON          * 25800017
*                                       SYS1.SYSJOBQE AND ASSIGN NEXT * 26400017
*                                       TTR                           * 27000017
*                 - WRITE AND ENQUEUE   TO WRITE LAST RECORD AND      * 27600017
*                                       ENQUEUE THE QUEUE ENTRY       * 28200017
*        IEFQDELE - DELETE              TO DELETE A QUEUE ENTRY       * 28800017
*        IEFQMDQ2 - DEQUEUE             TO DEQUEUE A QUEUE ENTRY   000B 29400017
*                                                                     * 30000017
*EXITS - NORMAL - IT POSTS THE ECB FOR IHKRJBGN AND RETURNS.          * 30600017
*                                                                     * 31200017
*EXITS - ERROR - N/A                                                  * 31800017
*                                                                     * 32400017
*TABLES/WORK AREAS - N/A                                                33000017
*                                                                     * 33600017
*ATTRIBUTES - IT IS ATTACHED AS A SEPARATE TASK.                      * 34200017
*                                                                     * 34800017
*NOTES - THE OPERATION OF THIS SUBROUTINE DEPENDS UPON AN INTERNAL    * 35400017
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 36000017
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED SO* 36600017
*   THAT REDEFINITION OF CHARACTER-TYPE CONSTANTS, BY REASSEMBLY, WILL* 37200017
*   RESULT IN AN CORRECT MODULE FOR THE NEW DEFINITION.               * 37800017
         SPACE 2                                                        38400017
R0       EQU   0                                                        39000017
R1       EQU   1                   BASE OF QUEUE MANAGER PARAMETER AREA 39600017
R2       EQU   2                   ADDRESS OF CALLER'S ECB              40200017
R3       EQU   3                   ADDRESS OF ECBLIST                   40800017
R4       EQU   4                   ADDRESS OF CURRENT ECBLIST ENTRY     41400017
R5       EQU   5                   ADDRESS OF ECB                       42000017
R6       EQU   6                   ADDRESS OF INPUT PARAMETER LIST      42600017
R7       EQU   7                   TO SAVE ADDRESS OF QMPA              43200017
R8       EQU   8                   SAVE RETURN CODE                     43800017
R9       EQU   9                   NOT USED                             44400017
R10      EQU   10                  NOT USED                             45000017
R11      EQU   11                  WORK REGISTER                        45600017
R12      EQU   12                  BASE REGISTER                        46200017
R13      EQU   13                  REGISTER SAVE AREA                   46800017
R14      EQU   14                                                       47400017
R15      EQU   15                                                       48000017
         SPACE 2                                                        48600017
         SAVE  (14,12),,*          SAVE REGISTERS                       49200017
         BALR  R12,0               INITIALIZE BASE REGISTER             49800017
         USING *,R12                                                    50400017
         USING IOPARAMS,R1         BASE OF QUEUE MANAGER PARAMETER AREA 51000017
         LA    R11,QMRSAVE         CHAIN SAVE AREAS                     51600017
         ST    R11,8(R13)                                               52200017
         ST    R13,4(R11)                                               52800017
         LR    R13,R11                                                  53400017
         LM    R2,R3,0(R1)         GET 2 INPUT PARAMETERS               54000017
*                                  R2 HAS ADDRESS OF CALLER'S ECB       54600017
*                                  R3 HAS ADDRESS OF ECBLIST            55200017
         ST    R3,QMRCRECB         INITIALIZE ADDRESS OF CURRENT ENTRY  55800017
*                                  IN ECBLIST                           56400017
         SR    R0,R0               SET ZERO COMPLETION CODE             57000017
QMRDONE2 LA    R2,0(0,R2)              ZERO HIGH ORDER BYTE      S21945 57400021
         POST  (2),(0)                 POST THE ECB OF CALLER    S21945 57800021
         WAIT  ECBLIST=(3)         WAIT UNTIL AN RJE SUBTAST NEEDS      58200017
*                                  OS QUEUE MANAGER                     58800017
         L     R4,QMRCRECB         GET ADDR OF CURRENT ECBLIST ENTRY    59400017
QMRECBLP L     R5,0(R4)            GET ADDRESS OF ECB                   60000017
         LTR   R5,R5               CHECK FOR LAST ENTRY IN ECBLIST      60600017
         BM    QMRECBND            BRANCH IF LAST ENTRY                 61200017
         LA    R4,4(R4)            STEP TO NEXT ECBLIST ENTRY           61800017
QMRCKPST CLI   0(R5),QMRPOST       CHECK FOR POSTED ECB                 62400017
         BE    QMRLINK             BRANCH IF POSTED                     63000017
         B     QMRECBLP            CONTINUE SEARCH FOR POSTED ECB       63600017
QMRECBND LR    R4,R3               SET POINTER TO FIRST ECBLIST ENTRY   64200017
         B     QMRCKPST                                                 64800017
         SPACE 2                                                        65400017
QMRLINK  ST    R4,QMRCRECB         SAVE ADDR OF CURRENT ECBLIST ENTRY   66000017
         MVI   0(R5),QMRWTBYT      RESET ECB TO WAIT STATUS             66600017
         L     R6,0(R5)            GET ADDRESS OF INPUT PARAMETER LIST  67200017
         CLC   0(4,R6),QMRF        CHECK FOR WORD OF F'S           000A 67800017
         BE    QMRRET              BRANCH IF SO TO RETURN               68400017
         LM    R1,R2,0(R6)         GET INPUT PARAMETERS                 69000017
*                                  R1 HAS ADDRESS OF QMPA               69600017
*                                  R2 HAS ADDRESS OF CALLER'S ECB       70200017
         CLI   QMPOP,QMDELE        CHECK FOR DELETE REQUEST             70800017
         BE    QMRDELET            BRANCH IF DELETE REQUEST             71400017
         TM    QMPOP,QMDTOP        CHECK FOR DEQUEUE REQUEST       000B 72000017
         BO    QMRDEQ              BRANCH IF IT IS A DEQUEUE       000B 72600017
         MVC   QMRQM+4(4),QMRMSSS  SET FOR IEFQMSSS                     73200017
QMRLOAD  LR    R7,R1               SAVE ADDRESS OF QMPA                 73800017
         LOAD  EPLOC=QMRQM         LOAD QUEUE MANAGER ROUTINE           74400017
         LR    R15,R0              GET ENTRY POINT OF QUEUE MANAGER     75000017
         LR    R1,R7               RESTORE ADDRESS OF QMPA              75600017
         BALR  R14,R15             CALL QUEUE MANAGER ROUTINE           76200017
         LA    R8,0(R15)           GET RETURN CODE FOR CALLER'S ECB     76800017
         DELETE EPLOC=QMRQM        DELETE QUEUE MANAGER ROUTINE         77400017
         LR    R0,R8               SET COMPLETION CODE FOR POST         78000017
         B     QMRDONE2                                                 78600017
         SPACE 2                                                        79200017
QMRDELET MVC   QMRQM+4(4),QMRDELE  SET FOR IEFQDELE                     79800017
         B     QMRLOAD                                                  80400017
QMRDEQ   MVC   QMRQM+4(4),QMRMDQ2  PREPARE TO LOAD IEFQMDQ2        000B 81000017
         B     QMRLOAD                                             000B 81600017
         SPACE 2                                                        82200017
         SPACE 2                                                        82800017
QMRRET   EQU   *                                                   000A 83400017
         L     R13,QMRSAVE+4                                            84000017
         RETURN (14,12),T,RC=0                                          84600017
         SPACE 2                                                        85200017
QMRPOST  EQU   X'40'               TO POST CALLER'S ECB                 85800017
QMRWTBYT EQU   X'00'               TO RESET OWN ECB TO WAIT STATUS      86400017
QMRCRECB DC    F'0'                ADDRESS OF CURRENT ENTRY IN ECBLIST  87000017
QMRSAVE  DC    18F'0'              SAVE AREA                            87600017
QMRQM    DC    CL8'IEFQ'           FOR IEFQMSSS OR IEFQDELE             88200017
QMRMSSS  DC    C'MSSS'                                                  88800017
QMRDELE  DC    C'DELE'                                                  89400017
QMRMDQ2  DC    C'MDQ2'                                             000B 90000017
QMRF     DC    X'FFFFFFFF'                                              90600017
         SPACE 2                                                        91200017
         IEFQMNGR                                                       91800017
         END                                                            92400017
