 TITLE 'IHKCEDIT     JCL EDIT'                                          00200017
IHKXEDIT CSECT                                                          00400017
IHKCEDIT DS    0H                                                       00600017
         ENTRY IHKCEDIT                                                 00800017
* 790000                                                           000D 00900020
*                                                                A32855 00950020
*D652000                                                         A53069 01000021
*A440800-441200,652400-653600,680600-681200                      A53069 01060021
*C436000                                                         A53069 01120021
*                                                                     * 01180021
* STATUS: CHANGE LEVEL 1, RELEASE 21.7                                * 01240021
*                                                                     * 01300021
*FUNCTION-                                                            * 01400017
*   THIS ROUTINE IS RESPONSIBLE FOR CHANGING THE SYSOUT CLASS AND     * 01600017
*   MSGCLASS CLASSNAME SPECIFIED ON THE JCL ENTERED WITH A REMOTE JOB * 01800017
*   TO THE RJE SYSOUT CLASS WHICH IS DEFINED BY THE RJETABL MACRO.    * 02000017
*   THE CHANGE OF SYSOUT CLASS WILL NOT BE MADE FOR ANY DATA SET WHICH* 02200017
*   IS TO BE DIRECTED TO THE CENTRAL AND IS SPECIFIED IN THE CENTRAL  * 02400017
*   PARAMETER OF THE JED STATEMENT.  THE ORIGINAL MSGCLASS CLASSNAME  * 02600017
*   AND ANY SYSOUT CLASSNAMES FOR DATA SETS NOT ROUTED TO CENTRAL ARE * 02800017
*   STORED IN THE JED TABLE JEDTSOUT.                                 * 03000017
*ENTRY POINT-                                                         * 03200017
*        IHKCEDIT IS THE ONLY ENTRY POINT.                            * 03400017
*   IHKCEDIT RECEIVES CONTROL FROM THE OS INTERPRETER, AFTER IEFVFA   * 03600017
*   (THE OS JCL SCAN ROUTINE) HAS ACCUMULATED AND CONVERTED TO        * 03800017
*   INTERNAL TEXT ONE COMPLETE JCL STATEMENT (INCLUDING CONTINUATION  * 04000017
*   AND OVERRIDES).                                                   * 04200017
*TABLES/WORK AREAS-                                                   * 04400017
*   IHKCEJDT, THE IN-CORE DUMMY JED TABLE PROVIDED BY IHKCEJPR, IS    * 04600017
*   USED FOR STORING SYSOUT AND MSGCLASS CLASSNAMES.                  * 04800017
*   IHKCELST, THE CENTRAL PARAMETER AREA BUILT BY IHKCEJPR, IS        * 05000017
*   REFERENCED TO DETERMINE WHICH OUTPUT DATA SETS ARE TO BE ROUTED   * 05200017
*   TO CENTRAL.                                                       * 05400017
*INPUT-                                                               * 05600017
*      AT ENTRY TO IHKCEDIT, REGISTER 13 CONTAINS A POINTER TO A SAVE * 05800017
*   AREA AND REGISTER 1 CONTAINS A POINTER TO THE FOLLOWING THREE     * 06000017
*   WORD PARAMETER LIST-                                              * 06200017
*      FIRST WORD-  TEXT BUFFER POINTER                               * 06400017
*      SECOND-      QMPA POINTER                                      * 06600017
*      THIRD-       QUEUE MANAGER ENTRY POINT                         * 06800017
*   THE TEXT BUFFER POINTER POINTS TO THE FIRST TEXT BUFFER FOR A     * 07000017
*   STATEMENT.  THE ACTUAL TEXT BEGINS IN THE SECOND WORD OF THE      * 07200017
*   BUFFER.  THE FIRST WORD IS A BINARY ZERO UNLESS THE INTERNAL      * 07400017
*   TEXT FOR THIS STATEMENT IS CONTINUED IN ANOTHER BUFFER.   (THIS   * 07600017
*   IS NOT THE USUAL CASE.(  IF  THE TEXT IS CONTINUED, THE FIRST     * 07800017
*   WORD CONTAINS THE 3 BYTE RIGHT-ADJUSTED TTR OF THE NEXT BUFFER,   * 08000017
*   AND AN IDENTIFIER OF X'0B'.  THE QMPA AND QUEUE MANAGER ENTRY     * 08200017
*   POINT ARE PROVIDED IN CASE THE INTERNAL TEXT IS CONTINUED.  THE   * 08400017
*   CONTINUATION BUFFER RESIDES ON QUEUE MANAGER SPACE ON DISK.  IT   * 08600017
*   MAY BE READ INTO CORE AND RE-WRITTEN TO DISK USING THE QUEUE      * 08800017
*   MANAGER ROUTINES.                                                 * 09000017
*OUTPUT-                                                              * 09200017
*      THE INTERNAL TEXT BUFFER IS LEFT,IN CORE (OR RE-WRITTEN TO     * 09400017
*   DISK IF IT IS A CONTINUATION BUFFER( WITH THE NECESSARY           * 09600017
*   CLASSNAME CHANGES MADE.                                           * 09800017
*EXTERNAL REFERENCES-                                                 * 10000017
*        IHKCEJDT-DUMMY IN-CORE JED TABLE                             * 10200017
*        IHKCELST-CENTRAL PARAMETER AREA                              * 10400017
*        IHKCDSOC-SYSOUT CLASS CLASSNAMES DEFINED IN RJETABL MACRO    * 10600017
*EXITS-                                                               * 10800017
*      RETURN VIA REGISTER 14 TO IEFVFA.                              * 11000017
*ATTRIBUTES-                                                          * 11200017
*      SERIALLY REUSABLE                                              * 11400017
*NOTES- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR* 11600017
*    INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.           * 11800017
*                                                                       12000017
*            REGISTERS                                                  12200017
*                                                                       12400017
ZERO     EQU   0                                                        12600017
PAREG    EQU   1                                                        12800017
EXLENGTH EQU   2                                                        13000017
RECORDAD EQU   3                                                        13200017
DDNAMEAD EQU   4                                                        13400017
POINTER  EQU   5                                                        13600017
COUNT    EQU   6                                                        13800017
WORK     EQU   7                                                        14000017
THUMB    EQU   8                                                        14200017
MARKER   EQU   9                                                        14400017
NUMBER   EQU   10                                                       14600017
TEMP     EQU   11                                                       14800017
BASE     EQU   12                                                       15000017
SAVE     EQU   13                                                       15200017
RETURN   EQU   14                                                       15400017
EXIT     EQU   15                                                       15600017
TWENT8 EQU     28                                                       15800017
         SAVE  (14,12),,*                                               16000017
         BALR  BASE,0              ESTABLISH BASE REGISTER              16200017
         USING *,BASE                                                   16400017
         USING IOPARAMS,PAREG                                           16600017
         LA    TEMP,SAREA                                               16800017
         ST    TEMP,8(SAVE)                                             17000017
         ST    SAVE,SAREA+4                                             17200017
         LR    SAVE,TEMP                                                17400017
         LM    2,11,SAREA+TWENT8                                        17600017
         L     RECORDAD,0(PAREG)   ADDRESS OF INTERNAL TEXT BUFFER      17800017
         MVC   ADQMPA(4),4(PAREG)  KEEP ADDRESS OF QMPA                 18000017
         MVC   ADQMGR(4),8(PAREG)  QMGR ENTRY POINT                     18200017
         L     PAREG,ADQMPA                                             18400017
         MVC   SAVEQMPA(36),QMNAM  SAVE CALLER'S QMPA                   18600017
         NI    EDITSW,X'7F'        OFF FOR CURRENT BUFFER IS THE FIRST  18800017
         CLI   4(RECORDAD),JOBK    IS IT A JOB STATEMENT - IF SO        19000017
         BE    PROCJOB               BRANCH TO PROCESS JOB STATEMENT    19200017
         CLI   4(RECORDAD),DDK     IS IT A DD STATEMENT-IF SO           19400017
         BE    PROCDD                  BRANCH TO PROCESS DD STATEMENT   19600017
****************************************************************        19800017
*                                                                       20000017
*            PROCESS EXEC STATEMENT                                     20200017
*                                                                       20400017
****************************************************************        20600017
         MVI   SARG,C' '                                                20800017
         MVC   SARG+1(16),SARG     BLANK AREA FOR STEP.DDNAME           21000017
         SR    EXLENGTH,EXLENGTH                                        21200017
         IC    EXLENGTH,6(RECORDAD) LENGTH OF STEPNAME                  21400017
         LTR   EXLENGTH,EXLENGTH   CHECK FOR NO STEP NAME               21600017
         BZ    PROCEX1                                                  21800017
         CLI   6(RECORDAD),X'08'  STEPNAME OVER 8 CHARS          A32855 21820020
         BC    12,EXOK   NO BRANCH                               A32855 21840020
         IC    EXLENGTH,EIGHT                                    A32855 21870020
EXOK     EQU   *                                                 A32855 21900020
         EX    EXLENGTH,STEPMOVE                                        22000017
         LA    DDNAMEAD,SARG(EXLENGTH)   POINTS TO SPACE FOR PERIOD     22200017
         MVI   0(DDNAMEAD),C'.'        PERIOD BETWEEN STEP AND DDNAME   22400017
         LA    DDNAMEAD,SARG+1(EXLENGTH) POINTS TO SPACE FOR DDNAME     22600017
EDITEXIT STM   2,11,SAREA+TWENT8   SAVE EDIT'S REGS                     22800017
         L     PAREG,ADQMPA                                             23000017
         MVC   QMNAM(36),SAVEQMPA  RESTORE CALLER'S QMPA                23200017
         L     SAVE,SAREA+4        ADDRESS OF OS'S SAVE AREA            23400017
         RETURN (14,12),T,RC=0                                          23600017
PROCEX1  MVI   SARG+8,C'.'                                              23800017
         LA    DDNAMEAD,SARG+9     NO STEP NAME                         24000017
         B     EDITEXIT            RETURN                               24200017
****************************************************************        24400017
*                                                                       24600017
*            PROCESS JOB STATEMENT                                      24800017
*                                                                       25000017
****************************************************************        25200017
PROCJOB  CLC   7(8,RECORDAD),ERRORNM CHECK FOR ERROR JOBNAME            25400017
         BNE   PROCJOBA            BRANCH IF NORMAL CASE                25600017
         L     WORK,ADJOBNM        ADDRESS OF JOBNAME IN IHKCERDR       25800017
         MVC   7(8,RECORDAD),0(WORK) MOVE JOBNAME TO TEXT BUFFER        26000017
PROCJOBA MVI   KEYSARG,MSGCLAJK    BRANCH TO INTERNAL SUBROUTINE TO     26200017
         BAL   THUMB,SCANBUFF        SEARCH FOR MSGCLASS KEYWORD        26400017
         L     WORK,ADSOC          POINTER TO SYSOUT CLASSES            26600017
         MVI   DUMMYMC,MSGCLAJK    MSGCLASS KEY TO DUMMY MSGCLASS       26800017
         MVC   DUMMYMC+3(1),3(WORK) SET DUMMY MSGCLASS EQUAL TO SYSRJE  27000017
         L     THUMB,ADJEDTAB      POINTER TO JEDTSOUT                  27200017
         MVI   0(THUMB),X'00'      ZERO JED TABLE SYSOUT CLASSES        27400017
         MVC   1(24,THUMB),0(THUMB)                                     27600017
         CLI   0(POINTER),MSGCLAJK TEST FOR MSGCLASS KEYWORD FOUND      27800017
         BNE   PROCJOB5                                                 28000017
         CLC   3(1,POINTER),0(WORK)  CHECK FOR SYSPRINT SPECIFIED       28200017
         BNE   PROCJOB1                                                 28400017
         MVC   0(1,THUMB),0(WORK)    STORE MSGCLASS IN JED TAB          28600017
         B     PROCJOB4                                                 28800017
PROCJOB1 CLC   3(1,POINTER),1(WORK)  CHECK FOR SYSPUNCH                 29000017
         BNE   PROCJOB2                                                 29200017
         MVC   0(1,THUMB),1(WORK)    STORE MSGCLASS                     29400017
         B     PROCJOB4                                                 29600017
PROCJOB2 CLC   3(1,POINTER),2(WORK)  CHECK FOR SYSUSER                  29800017
         BNE   PROCJOB3                                                 30000017
         MVC   0(1,THUMB),2(WORK)  STORE MSGCLASS                       30200017
         B     PROCJOB4                                                 30400017
PROCJOB3 MVC   0(1,THUMB),0(WORK)    STORE SYSPRINT IN JCDTAB MSGCLASS  30600017
PROCJOB4 MVC   3(1,POINTER),3(WORK)  STORE SYSRJE IN INTERNAL TEXT      30800017
PROCJOB6 TM    EDITSW,X'80'        MUST THIS BUFFER BE RE-WRITTEN       31000017
         BZ    PROCJB6                                                  31200017
         L     PAREG,ADQMPA                                             31400017
         MVI   QMPOP,QMWRTE        FUNCTION CODE FOR WRITE              31600017
         L     EXIT,ADQMGR                                              31800017
         CALL  (15)                                                     32000017
PROCJB6  LA    THUMB,1(THUMB)      STORE BEGINNING ADDRESS OF JEDTSOUT  32200017
         ST    THUMB,AJEDSOUT        FOR NEXT DD STATEMENT              32400017
         SR    DDNAMEAD,DDNAMEAD                                        32600017
         B     EDITEXIT            BRANCH TO RETURN                     32800017
PROCJOB5 MVC   0(1,THUMB),0(WORK)  STORE SYSPRT IN JEDTAB MSGCLASS      33000017
         LA    WORK,171(RECORDAD)                                       33200017
         CR    POINTER,WORK        IS THERE ROOM TO ADD MSGCLASS TO     33400017
         BH    PROCJOB7                CURRENT BUFFER                   33600017
         MVC   0(5,POINTER),DUMMYMC  ADD MSGCLASS TO BUFFER             33800017
         B     PROCJOB6                                                 34000017
PROCJOB7 L     PAREG,ADQMPA                                             34200017
         MVI   QMPOP,QMASGN        FUNCTION CODE FOR ASSIGN             34400017
         MVI   QMPCM,X'10'         ASSIGN ONE RECORD                    34600017
         TM    EDITSW,X'80'        DOES CURRENT RECORD NEED TO BE       34800017
         BZ    PROCJOB8              REWRITTEN                          35000017
         MVC   KEEPTTR(4),QMPEX    KEEP TTR OF CURRENT RECORD           35200017
PROCJOB8 L     EXIT,ADQMGR         CALL QUEUE MANAGER TO ASSIGN NEW     35400017
         CALL  (15)                  BUFFER                             35600017
         MVC   0(4,RECORDAD),QMPCA   PUT TTR OF NEW RCC IN OLD REC      35800017
         MVI   3(RECORDAD),X'0B'   IDENTIFIER USED BY CALLING ROUTINE   36000017
         MVI   0(POINTER),KCONT    INDICATE OVERFLOW- KEY CONTINUATION  36200017
         TM    EDITSW,X'80'        MUST CURRENT RECORD BE WRITTEN       36400017
         BZ    PROCJOB9                                                 36600017
         L     PAREG,ADQMPA                                             36800017
         MVC   QMPEX(4),KEEPTTR    TTR0 OF CURRENT RECORD               37000017
         MVI   QMPEX+3,X'00'                                            37200017
         MVC   QMPCA(4),ADEXTRN                                         37400017
         MVI   QMPOP,QMWRTE        FUNCTION CODE FOR WRITE              37600017
         MVI   QMPNC,X'01'         WRITE ONE RECORD                     37800017
         L     EXIT,ADQMGR         REWRITE BUFFER RECORD TO DISK        38000017
         CALL  (15)                                                     38200017
PROCJOB9 MVC   QMPEX(4),0(RECORDAD)  WRITE NEW RECORD                   38400017
         L     PAREG,ADQMPA                                             38600017
         MVI   QMPEX+3,X'00'       TTR0                                 38800017
         MVC   QMPCA(4),ADDUMMY    ADDRESS OF DUMMY RECORD              39000017
         MVI   QMPOP,QMWRTE                                             39200017
         MVI   QMPNC,X'01'                                              39400017
         L     EXIT,ADQMGR         WRITE DUMMY RECORD TO DISK           39600017
         CALL  (15)                                                     39800017
         SR    DDNAMEAD,DDNAMEAD                                        40000017
         B     EDITEXIT            BRANCH TO RETURN                     40200017
****************************************************************        40400017
*                                                                       40600017
*            PROCESS DD STATEMENT                                       40800017
*                                                                       41000017
****************************************************************        41200017
PROCDD   ST    DDNAMEAD,KEEP                                            41400017
         LTR   DDNAMEAD,DDNAMEAD   CHECK FOR NO STEP NAME               41600017
         BZ    EDITEXIT            RETURN FOR NEXT STATEMENT            41800017
PROCDD1  MVI   0(DDNAMEAD),C' '    BLANK OUT AREA FOR DDNAMEAD          42000017
         LA    DDNAMEAD,1(DDNAMEAD)                                     42200017
         C     DDNAMEAD,ADEND      CHECK FOR END OF AREA                42400017
         BL    PROCDD1                                                  42600017
         L     DDNAMEAD,KEEP                                            42800017
         SR    EXLENGTH,EXLENGTH                                        43000017
         IC    EXLENGTH,6(RECORDAD) DDNAME LENGTH                       43200017
        LTR   EXLENGTH,EXLENGTH    CHECK FOR NO DDNAME                  43400017
         BZ    PRCDD0                                            A53069 43600021
         CLI   6(RECORDAD),X'08'   DDNSME OVER 8 CHARS           A32855 43630020
         BC    12,EXOK1     NO BRANCH                            A32855 43660020
         IC    EXLENGTH,EIGHT                                    A32855 43700020
EXOK1    EQU   *                                                 A32855 43750020
         BCTR  EXLENGTH,ZERO       MINUS ONE FOR MOVE                   43800017
         EX    EXLENGTH,DDMOVE     MOVE DDNAME TO SARG                  44000017
         SPACE                                                          44040021
PRCDD0   MVI   KEYSARG,DUMMK  IS THIS A DD DUMMY CARD            A53069 44080021
         BAL   THUMB,SCANBUFF      IF SO, DONT LOOK FOR SYSOUT   A53069 44120021
         SPACE                                                          44160021
PRCDD1   MVI   KEYSARG,SYSOUTK     BRANCH TO INTERNAL SUBROUTINE TO     44200017
*                                      SEARCH FOR SYSOUT KEYWORD        44400017
         BAL   THUMB,SCANBUFF                                           44600017
         CLI   0(POINTER),SYSOUTK  WAS KEYWORD FOUND                    44800017
         BNE   EDITEXIT            EXIT IF NOT                          45000017
         CLI   2(POINTER),X'00'    WAS VALUE SPECIFIED?            1658 45060000
         BE    EDITEXIT            NO, DO NOT PROCESS KEYWORD      1658 45120000
         L     MARKER,ADCELST      ADDRESS OF CENTRAL PARAMETER LIST    45200017
         CLC   0(4,MARKER),CENALL  CHECK FOR CENTRAL=ALL                45400017
         BE    PROCDD7                                                  45600017
PROCDD2  CLI   0(MARKER),C' '      UNUSED ENTRY                         45800017
         BE    PROCDD4             EXIT UNFOUND                         46000017
         CLI   17(MARKER),X'FF'    FLAGGED ENTRY                        46200017
         BE    PROCDD3                                                  46400017
         CLC   0(17,MARKER),SARG   MATCHING ENTRY                       46600017
         BE    PROCDD7               FOUND                              46800017
PROCDD3  LA    MARKER,18(MARKER)   BUMP TO NEXT ENTRY                   47000017
         C     MARKER,ENDCELST     CHECK FOR END OF LIST                47200017
         BL    PROCDD2                                                  47400017
PROCDD4  L     THUMB,ADSOC         NO MATCHING ENTRY FOUND              47600017
         LA    WORK,171(RECORDAD)  SARG NOT IN CENTRAL PARAMETER LIST   47800017
         CR    POINTER,WORK        SOES CLASSNAME PARAMETER APPEAR IN   48000017
         BL    PRCDD4                                                   48200017
         BAL   WORK,NEWREC         CONTINUATION BUFFER-BRANCH IF SO     48400017
PRCDD4   LA    POINTER,3(POINTER)  POSITION TO CLASSNAME                48600017
PROCDD5  L     MARKER,AJEDSOUT                                          48800017
         C     MARKER,ENDSOUT      IS JEDTSOUT FULL                     49000017
         BNL   PROCDD6             BRANCH IF FULL                       49200017
         LA    WORK,1(MARKER)      SUMP TO NEXT SPOT IN JEDTSOUT        49400017
         ST    WORK,AJEDSOUT                                            49600017
         CLC   0(1,POINTER),0(THUMB)    SYSPRNT                         49800017
         BNE   PROCDDB                                                  50000017
         MVC   0(1,MARKER),0(POINTER)   STORE CLASSNAME IN JEDTSOUT     50200017
         B     PROCDD6                                                  50400017
PROCDDB  CLC   0(1,POINTER),1(THUMB)    SYSPNCH                         50600017
         BNE   PROCDDC                                                  50800017
         MVC   0(1,MARKER),0(POINTER)   STORE CLASSNAME                 51000017
         B     PROCDD6                                                  51200017
PROCDDC  CLC   0(1,POINTER),2(THUMB)    SYSUSER                         51400017
         BNE   PROCDDD             WAS NOT PRT,PNCH, OR USER            51600017
         MVC   0(1,MARKER),0(POINTER)   STORE CLASSNAME                 51800017
PROCDD6  MVC   0(1,POINTER),3(THUMB)    SUBSTITUTE SYSRJE               52000017
PROCDD8  TM    EDITSW,X'80'        MUST THIS RECORD BE REWRITTEN        52200017
         BO    PROCDD9             BRANCH TO WRITE IF SO                52400017
         B     EDITEXIT                                                 52600017
PROCDDD  MVC   0(1,MARKER),0(THUMB)  STORE SYSPRNT IN JEDTSOUT          52800017
         B     PROCDD6                                                  53000017
PROCDD7  MVI   17(MARKER),X'FF'    FLAG ENTRY USED                      53200017
         LA    WORK,171(RECORDAD)   IS CLASSNAME IN CONTINUATION BUFFER 53400017
         CR    POINTER,WORK                                             53600017
         BL    PRCDD7                                                   53800017
         BAL   WORK,NEWREC          BRANCH TO READ NEXT BUFFER IF SO    54000017
PRCDD7   L     WORK,ADSOC                                               54200017
         CLC   3(1,POINTER),3(WORK) SYSRJE SPECIFIED                    54400017
         BNE   PROCDD8             BRANCH TO EXIT                       54600017
         MVC   3(1,POINTER),0(WORK) PUT SYSPRT IN STATEMENT             54800017
         B     PROCDD8                                                  55000017
PROCDD9  L     PAREG,ADQMPA                                             55200017
         MVI   QMPOP,QMWRTE                                             55400017
         L     EXIT,ADQMGR                                              55600017
         CALL  (15)                                                     55800017
         B     EDITEXIT                                                 56000017
NEWREC   TM    EDITSW,X'80'        MUST CURRENT BUFFER BE RE-WRITTEN    56200017
         BZ    NEWREC2             BRANCH IF NOT                        56400017
         L     PAREG,ADQMPA                                             56600017
         MVI   QMPOP,QMWRTE                                             56800017
         L     EXIT,ADQMGR                                              57000017
         CALL  (15)                RE-WRITE CURRENT BUFFER TO DISK      57200017
NEWREC2  L     PAREG,ADQMPA                                             57400017
         MVC   QMPCL(4),ADEXTRN    ADDRESS EXTERNAL AREA                57600017
         MVC   QMPEX(4),0(RECORDAD) TTR OF NEXT BUFFER                  57800017
         MVI   QMPEX+3,X'00'                                            58000017
         MVI   QMPNC,X'01'         READ ONE RECORD                      58200017
         MVC   QMPCA(4),ADOVERF    ADDRESS TO READ INTO                 58400017
         MVI   QMPOP,QMREAD        FUNCTION CODE FOR READ               58600017
         L     EXIT,ADQMGR         READ NEXT BUFFER                     58800017
         CALL  (15)                                                     59000017
         L     RECORDAD,QMPCA                                           59200017
         LA    POINTER,2(RECORDAD)                                      59400017
         BR    WORK                RETURN TO PROCESS                    59600017
*                                                                       59800017
*            INTERNAL SUBROUTINE TO SCAN TEXT BUFFER FOR A              60000017
*               PARTICULAR KEYWORD                                      60200017
*                                                                       60400017
SCANBUFF LA    POINTER,4(RECORDAD) INIT TO FIRST KEYWORD                60600017
SCANB5   LA    POINTER,1(POINTER)  INCREMENT PAST KEYWORD               60800017
         SR    NUMBER,NUMBER                                            61000017
         IC    NUMBER,0(POINTER)   NUMBER OF POSITIONAL PARAMETERS      61200017
SCANB1   LA    POINTER,1(POINTER)  BUMP TO NEXT BYTE                    61400017
         LTR   NUMBER,NUMBER       NO (MORE) PARAMETERS                 61600017
         BE    SCANB2                                                   61800017
         TM    0(POINTER),X'80'    IS THIS A COUNT FIELD - HIGH ORDER   62000017
         BO    SCANSUB                BIT ON-BRANCH IF SO               62200017
         CLI   0(POINTER),LCONT    CHECK FOR LENGTH CONTINUATION        62400017
         BNE   SCANB1A                                                  62600017
         BAL   MARKER,NEWBUFF      BRANCH TO READ NEXT BUFFER           62800017
SCANB1A  SR    WORK,WORK                                                63000017
         IC    WORK,0(POINTER)     PICK UP LENGTH                       63200017
         AR    POINTER,WORK        INCREMENT TO END OF PARAMETER        63400017
SCANB4   BCTR  NUMBER,ZERO         DECREMENT NO. OF PARAMETERS          63600017
         B     SCANB1              BRANCH TO CONTINUE PROCESSING        63800017
SCANB2   CLI   0(POINTER),ENDK     CHECK FOR END KEY                    64000017
         BNE   SCANB3                                                   64200017
         BR    THUMB               EXIT WITH KEYWORD UNFOUND            64400017
SCANB3   CLI   0(POINTER),KCONT    CHECK FOR OVERFLOW BUFFER            64600017
         BNE   SCANB3A                                                  64800017
         BAL   MARKER,NEWBUFF      BRANCH TO READ NEXT BUFFER           65000017
         SPACE                                                          65200021
SCANB3A  CLI   KEYSARG,DUMMK  IS THIS THE DD DUMMY TEST          A53069 65240021
         BE    DUMTST         YES - BRANCH                       A53069 65280021
         SPACE                                                          65320021
         CLC   0(1,POINTER),KEYSARG NO,TEST FOR (OTHER) KEYWD    A53069 65360021
         BNE   SCANB5                                                   65400017
         BR    THUMB               EXIT   WITH KEYWORD FOUND            65600017
SCANSUB  SR    COUNT,COUNT                                              65800017
         IC    COUNT,0(POINTER)                                         66000017
         N     COUNT,HIGHOFF       OFF HIGH ORDER BIT OF LOW ORDER BYTE 66200017
SCANSUB1 LA    POINTER,1(POINTER)  BUMP TO LENGTH FIELD                 66400017
         CLI   0(POINTER),LCONT    CHECK FOR OVERFLOW BUFFER            66600017
         BNE   SCANSUB2                                                 66800017
         BAL   MARKER,NEWBUFF      BRANCH TO READ IN NEXT BUFFER        67000017
SCANSUB2 SR    WORK,WORK                                                67200017
         IC    WORK,0(POINTER)     PICK UP LENGTH                       67400017
         AR    POINTER,WORK        INCREMENT TO END OF PARAMETER        67600017
         BCT   COUNT,SCANSUB1                                           67800017
         B     SCANB4                                                   68000017
         SPACE                                                          68030021
DUMTST   CLI   0(POINTER),DUMMK    IS 1ST DD ATTR DUMMY          A53069 68060021
         BE    EDITEXIT  YES - DONT LOOK FOR SYSOUT - EXIT       A53069 68090021
         BR    THUMB          NO - RETURN TO LOOK FOR SYSOUT     A53069 68120021
         SPACE                                                          68150021
NEWBUFF  L     PAREG,ADQMPA        BASE REG FOR QMPA DSECT              68200017
         TM    EDITSW,X'80'        DOES CURRENT BUFFER NEED TO BE       68400017
         BZ    NEWBUFF2              RE-WRITTEN- BRANCH IF NOT          68600017
         MVI   QMPOP,QMWRTE        SET UP TO REWRITE THE CURRENT BUFFER 68800017
         L     EXIT,ADQMGR                                              69000017
         CALL  (15)                CALL QUEUE MANAGER WRITE             69200017
         L     PAREG,ADQMPA                                             69400017
NEWBUFF1 MVI   QMPOP,QMREAD        FUNCTION CODE FOR READ               69600017
         L     EXIT,ADQMGR                                              69800017
         CALL  (15)                                                     70000017
         L     RECORDAD,QMPCA                                           70200017
         LA    POINTER,4(RECORDAD)                                      70400017
         BR    MARKER                                                   70600017
NEWBUFF2 OI    EDITSW,X'80'        SHOWS NEED TO REWRITE THIS BUFFER    70800017
         L     PAREG,ADQMPA                                             71000017
         MVC   QMPCL(4),ADEXTRN                                         71200017
         MVC   QMPCA(4),ADOVERF                                         71400017
         MVI   QMPNC,X'01'         READ ONE RECORD                      71600017
         MVC   QMPEX(4),0(RECORDAD) MOVE IN TTR                         71800017
         MVI   QMPEX+3,X'00'       TTR0                                 72000017
         B     NEWBUFF1                                                 72200017
*                                                                       72400017
STEPMOVE MVC   SARG(0),7(RECORDAD) MOVE STEPNAME TO SARG                72600017
DDMOVE   MVC   0(0,DDNAMEAD),7(RECORDAD) MOVE DDNAME TO SARG            72800017
*                                                                       73000017
*            CONSTANTS AND WORK AREAS                                   73200017
*                                                                       73400017
SAREA    DS    18F                                                      73600017
SAVEQMPA DS    CL36                FOR CALLER'S QMPA                    73800017
ADQMPA   DS    F                                                        74000017
ADQMGR   DS    F                                                        74200017
KEEP     DS    F                                                        74400017
KEEPTTR  DS    F                                                        74600017
HIGHOFF  DC    X'FFFFFF7F'                                              74800017
CENALL   DC    CL4'ALL'                                                 75000017
ADDUMMY  DC    A(DUMMYMC)                                               75200017
ERRORNM  DC    CL8'JOBFAIL'        ERROR JOBNAME GIVEN BY O/S           75400017
         EXTRN IHKCEJBN                                                 75600017
ADJOBNM  DC    A(IHKCEJBN)         ADDRESS OF JOBNAME IN IHKCERDR       75800017
         EXTRN IHKCEJDT                                                 76000017
ADJEDTAB DC    A(IHKCEJDT+25)                                           76200017
ENDSOUT  DC    A(IHKCEJDT+50)                                           76400017
         EXTRN IHKCDSOC                                                 76600017
ADSOC    DC    A(IHKCDSOC)                                              76800017
AJEDSOUT DS    F                                                        77000017
         EXTRN IHKCELST                                                 77200017
ADCELST  DC    A(IHKCELST)                                              77400017
ENDCELST DC    A(IHKCELST+180)                                          77600017
ADEND    DC    A(ENDSARG)                                               77800017
QMPCA    DS    F                                                        78000017
QMPEX    DS    F                                                        78200017
ADEXTRN  DC    A(QMPCA)                                                 78400017
ADOVERF  DC    A(OVERFLOW)                                              78600017
OVERFLOW DS    CL176                                                    78800017
DUMMYMC  DC    X'40010140FE'       MSGCLASS = SYSRJE               000D 79000020
EIGHT    DC    X'08'               MAX DDNAME LENGTH ALLOWED     A32855 79100020
EDITSW   DC    X'00'                                                    79200017
KEYSARG  DC    X'00'               KEYWORD FOR SEARCH SUBROUTINE        79400017
SARG     DC    CL17' '                                                  79600017
ENDSARG  EQU   *                                                        79800017
*                                                                       80000017
         IEFVKEYS                  MACRO FOR KEYWORD CODES              80200017
*                                                                       80400017
*                                                                       80600017
         IEFQMNGR                  QUEUE MANAGER PARAMETER AREA         80800017
*                                                                       81000017
*                                                                       81200017
         END                                                            81400017
