RDR    TITLE   'IHKCHRDR  RJE READER V-2'                               00070018
IHKXHRDR CSECT                                                          00140018
*2210851900,883400,796600,885500                                   000C 00210018
*632100,679700-680400,709100-709800                              A35895 00240020
*D648900                                                         A37786 00250020
*A648500-649100,772300-772500                                    A37786 00260020
*D 576100                                                        A53596 00265021
*C 575400                                                        A53596 00270021
*                                                                       00275021
         ENTRY IHKCHRDR                                                 00280018
         ENTRY IHKCEJDT                                                 00350018
         ENTRY IHKCELST                                                 00420018
         ENTRY IHKCEJBN                                                 00490018
         ENTRY IHKCHASE                                                 00560018
IHKCHRDR DS    0H                                                       00630018
         EXTRN     IHKCACOM                                             00700018
         EJECT                                                          00770018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   00840018
*                                                                   *   00910018
*           P R O L O G U E   FOR THE   R J E   R E A D E R         *   00980018
*                                                                   *   01050018
*                                                                   *   01120018
* S T A T U S - -                                                   *   01190018
*                                                                   *   01260018
* STATUS: CHANGE LEVEL 2, RELEASE 21.7                              *   01330021
*                                                                   *   01400018
*                                                                   *   01470018
* F U N C T I O N / O P E R A T I O N - -                           *   01540018
*                                                                   *   01610018
*   THE RJE READER MODULE GAINS CONTROL FROM IHKRJBGN               *   01680018
*   ONCE IN CONTROL THE RJE READER'S PRIMARY FUNCTION IS DEQUEUING  *   01750018
*     AND READING LOGICAL RECORDS FROM THE RJE QUEUE (39) OF THE    *   01820018
*     THE BIG DADDY OF QUEUES, THE SYS1.SYSJOBQE.  THESE RECORDS    *   01890018
*     CONSIST  OF THE JCL IN JOB ENTRIES AND WORK STATION COMMANDS. *   01960018
*     THIS DATA HAVING BEEN COLLECTED FROM THE WORK STATIONS AND    *   02030018
*     PLACED ON THE QUEUE BY IHKABLRD WHICH IS PART OF THE COLLECTOR*   02100018
*                                                                   *   02170018
*   THESE ENTRIES ON THE QUEUE HAVE ONE OF THE FOLLOWING FORMATS:   *   02240018
*                                                                   *   02310018
*       1. ONE OR MORE WORK STATION COMMANDS                        *   02380018
*       2. THE JCL OF A JOB ENTRY PRECEDED WITH A JED IF PRESENT    *   02450018
*       3. THE JCL OF A JOB ENTRY PRECEDED WITH A JED IF PRESENT,   *   02520018
*           FOLLOWED BY ONE OR MORE WORK STATION COMMANDS.          *   02590018
*                                                                   *   02660018
*     IF A QUEUE ENTRY CONTAINS BOTH A JOB  FOR PROCESSING AND WORK *   02730018
*     STATION COMMANDS, THE COMMANDS WILL ALWAYS FOLLOW THE JOB IN  *   02800018
*     THE QUEUE ENTRY.                                              *   02870018
*                                                                   *   02940018
*   PROCESSING OF INPUT IN A QUEUE ENTRY IS AS FOLLOWS:             *   03010018
*                                                                   *   03080018
*       1. THE JCL IN A QUEUE ENTRY IS PASSES TO THE R/I FOR        *   03150018
*           INTERPRETION AND PROCESSING                             *   03220018
*       2. WHEN ALL JCL IN A QUEUE ENTRY HAS BEEN PASSED TO THE     *   03290018
*           R/I, INDICATED BY JECL ON THE QUEUE OR NO MORE DATA     *   03360018
*           IN THE QUEUE ENTRY, A // NULL IS PASSED TO THE R/I      *   03430018
*           TO FORCE ENQUEUING OF THE JOB ON THE DESIRED O/S INPUT  *   03500018
*           QUEUE.                                                  *   03570018
*       3.  JED STATEMENTS ARE PASSED TO THE JED PROCESSOR --       *   03640018
*            IHKCHJPR FOR INTREPRETATION AND PROCESSING OF RJE JOB  *   03710018
*            HANDLING OPTIONS.                                      *   03780018
*       4.  WORK STATION COMMANDS ARE PASSED TO THE COMMAND INTER-  *   03850018
*            PRETER FOR TRANSLATION, WHO IN TURN ROUTES THEM TO THE *   03920018
*            PROPER MODULE FOR PROCESSING.                          *   03990018
*       5.  PARTIALLY COLLECTED JOBS IN A QUEUE ENTRY, INDICATED    *   04060018
*            BY JCL IMMEDIATELY FOLLOWED BY AN INTERNAL RJEND       *   04130018
*            COMMAND (RJENDF), ARE CANCELLED IN O/S AND DELETED IN  *   04200018
*            RJE.                                                   *   04270018
*       6.  JOBS ARE ACKNOWLEDGED ONCE ENQUEUED ON THE O/S INPUT    *   04340018
*            QUEUE.                                                 *   04410018
*       7.  JCL IN A QUEUE ENTRY IS FLUSHED IF A JOB IS MARKED      *   04480018
*            ENQUEUED ON THE O/S INPUT QUEUE BUT NOT DELETED FROM   *   04550018
*            THE RJE INPUT QUEUE. (WARMSTART CONDITION).            *   04620018
*       8.  USERS ARE NOTIFIED OF MISSING CENTRAL DATA SETS         *   04690018
*       9.  THE JOBCARD USER EXIT IS PASSED THE JOB CARD AND ITS    *   04760018
*            CONTINUATION FOR EXAMINATION AND MODIFICATION          *   04830018
*       10. THE JOBACK USER EXIT IS PASSED THE RJE JOB ACKNOWLEDGE- *   04900018
*            MENT MESSAGE FOR EXAMINATION AND MODIFICATION AND IS   *   04970018
*            ALLOWED TO ADD A 59 CHARACTER MESSAGE OF HIS OWN WHICH *   05040018
*            IS SENT FOLLOWING THE RJE ACKNOWLEDGEMENT MESSAGE.     *   05110018
*       11. THE FAST TABLE ENTRY AND JED TABLE FOR THE JOB ARE      *   05180018
*            UPDATED ON THEIR RESPECTIVE DIRECT ACCESS DATA SETS.   *   05250018
*       12. ABNORMAL CLOSEDOWN PROCEDURES ARE INITIATED WHEN THE    *   05320018
*            OS QMGR RETURNS WITH AN I/O ERROR INDICATION ON A      *   05390018
*            DEQUEUE OR DELETE REQUEST                              *   05460018
*       13. ERRORS INCURRED WHILE READING LOGICAL RECORDS FROM A Q  *   05530018
*           ENTRY RESULT IN THE ENTRY AND JOB BEING DELETED.        *   05600018
*                                                                   *   05670018
*                                                                   *   05740018
* E N T R Y   P O I N T S - -                                       *   05810018
*                                                                   *   05880018
*   IHKCHRDR IS THE ENTRY POINT FOR THIS ROUTINE USED BY IHKRJBGN.  *   05950018
*                                                                   *   06020018
*   IHKCHASE IS THE ENTRY POINT FOR THIS ROUTINE USED BY THE        *   06090018
*     RJE SUBTASKS WHEN SUBTASK CLOSEDOWN IS COMPLETE OR AN ERROR   *   06160018
*     IS ENCOUNTERED WHICH NECESSITATES ABNORMAL RJE CLOSEDOWN.     *   06230018
*     ENTRY AT IHKCHASE RESULTS IN RETURN TO R/I END OF DATA ADDRESS*   06300018
*                                                                   *   06370018
*   IHKCELST IS THE ENTRY POINT FOR THE CENTRAL DATA SET WORK AREA  *   06440018
*     USED BY IHKCEDIT AND IHKCHJPR.                                *   06510018
*                                                                   *   06580018
*   IHKCEJDT IS THE ENTRY POINT FOR THE MAIN STORAGE COPY JED TABLE *   06650018
*     FOR THE JOB USED BY IHKCHJPR TO INSERT THE NOTIFY INFORMATION *   06720018
*     AND IHKCEDIT TO INSERT SYSOUT CLASS INFORMATION.              *   06790018
*                                                                   *   06860018
*   IHKCEJBN IS THE ENTRY POINT TO ACCESS THE NAME OF THE JOB       *   06930018
*     CURRENTLY BEING PROCESSED BY THE RJE READER SUBTASK.          *   07000018
*                                                                   *   07070018
*                                                                   *   07140018
* I N P U T - -                                                     *   07210018
*                                                                   *   07280018
*   INPUT FROM THE RJE QUEUE OF THE SYS1.SYSJOBQE CONSISTS OF 176   *   07350018
*     BYTE RECORDS OF THE FOLLOWING FORMAT -                        *   07420018
*                                                                   *   07490018
*     *--------------------------------------------------------*    *   07560018
*     *      *           *           *  RELATIVE   *  NUMBER   *    *   07630018
*     * TTR0 *   DATA    *  DATA     *  TDIR ENTRY *  OF DATA  *    *   07700018
*     *      *    ENTRY  *   ENTRY   *   OFFSET    *  ENTRIES  *    *   07770018
*     *--------------------------------------------------------*    *   07840018
*                                                                   *   07910018
*   DESCRIPTION --                                                  *   07980018
*                                                                   *   08050018
*    BYTE      USE                                                  *   08120018
*     0-3      TTR0 IS THE TTR OF THE NEXT LOGICAL RECORD IN THE    *   08190018
*                QUEUE ENTRY.  THIS FIELD IS ZERO IF THIS IS THE    *   08260018
*                LAST RECORD IN THE QUEUE ENTRY.                    *   08330018
*     4-83     A DATA ENTRY CONSISTS OF 80 CHARACTER CARD IMAGES    *   08400018
*                OF JCL OR JECL COLLECTED FROM THE COMMUNICATION    *   08470018
*                LINES.                                             *   08540018
*                                                                   *   08610018
*     84-163   A SECOND 80 CHARACTER CARD IMAGE.                    *   08680018
*                                                                   *   08750018
*     164-167  RELATIVE TERMINAL DIRECTORY ENTRY OFFSET FROM THE    *   08820018
*                STARTING ADDRESS OF THE TERMINAL DIRECTORY FOR     *   08890018
*                THE WORK STATION FROM WHICH THE DATA IS COLLECTED. *   08960018
*     168      NUMBER OF DATA ENTRIES IN LOGICAL RECORD.            *   09030018
*                 X'00'  TWO DATA ENTRIES IN LOGICAL RECORD         *   09100018
*                 X'50   ONE DATA ENTRY IN LOGICAL RECORD           *   09170018
*                 X10'  NO DATA ENTRIES IN LOGICAL RECORD. THE     *   09240018
*                        TTR0 FIELD IS ALSO ZERO IN THIS CASE.      *   09310018
*     169-175   RESERVED                                            *   09380018
*                                                                   *   09450018
*                                                                   *   09520018
* O U T P U T - -                                                   *   09590018
*                                                                   *   09660018
*     THE UPDATED JED TABLE FOR THE JOB IS WRITTEN TO THE DIRECT    *   09730018
*     ACCESS DATA SET AND THE USER AND RJE JOB ACCECPTED MESSAGES   *   09800018
*     ARE RETURNED TO THE USER SUBMITTING THE JOB.  ERROR MESSAGES  *   09870018
*     ARE SENT TO THE USER NOTING THE FOLLOWING THREE ERROR         *   09940018
*     CONDITIONS.                                                   *   10010018
*       1.  DATA SETS SPECIFIED IN THE JED CENTRAL PARAMETER BUT    *   10080018
*           NOT SPECIFIED IN THE JCL FOR THE JOB. (MESSAGE-IHK153I) *   10150018
*       2.  ERROR INCURRED READING A LOGICAL RECORD FROM THE QUEUE  *   10220018
*           ENTRY. (MESSAGE-IHK163I DISK ERROR QMGR JOBNAME)        *   10290018
*       3.  ERROR INCURRED WRITING THE UPDATED JED TABLE TO THE     *   10360018
*           DIRECT ACCESS DATA SET. (MESSAGE- IHK163I DISK ERROR    *   10430018
*           JED JOBNAME)                                            *   10500018
*                                                                   *   10570018
*                                                                   *   10640018
* E X T E R N A L   R O U T I N E S - -                             *   10710018
*                                                                   *   10780018
*   IHKCDJMR- WRITE UPDATED JED TABLE TO THE DIRECT ACCESS DATA SET *   10850018
*   IHKCDFMR- WRITE UPDATED FASTABLE ENTRY TO DIRECT ACCESS DATA SET*   10920018
*   IHKAADSP- WAIT FOR WORK ON RJE INPUT QUEUE                      *   10990018
*   IHKCBLDM- CONSTRUCT RJE MESSAGES AND ENQUEUE ON WORK STATION    *   11060018
*             INPUT QUEUE                                           *   11130018
*   IHKCDSCH- SEARCH FASTABLE FOR JOB NAME                          *   11200018
*   IHKCFSTB- FIND POSITION OF JOB ON INPUT QUEUE FOR JOB ACCEPTED  *   11270018
*             MESSAGE                                               *   11340018
*   IHKCHJPR- PROCESS JED STATEMENTS FOUND IN INPUT STREAM          *   11410018
*   IHKCAINT- PROCESS WORK STATION COMMANDS FOUND IN INPUT STREAM   *   11480018
*   IEFSD447- MARK AN ENTRY ON THE RJE QUEUE ENQUEUED ON AN OS INPUT*   11550018
*             QUEUE BUT NOT DELETED FROM THE RJE QUEUE.             *   11620018
*   IHKBBRII- PASS RECORDS TO R/I,PASS EODAD TO R/I, AND LOAD AND   *   11690018
*             DELETE NON-RESIDENT MODULES. INTERFACE IS             *   11760018
*             ACCOMPLISHED BY POSTING ECB OF IHKBBRII AND THEN      *   11830018
*             ISSUEING A WAIT TILL THE REQUEST IS SERVICED.         *   11900018
*                                                                   *   11970018
*                                                                   *   12040018
* E X I T S - -                                                     *   12110018
*                                                                   *   12180018
*   NORMAL - RETURN TO IHKRJBGN.                                    *   12250018
*   ERROR - RETURN TO IHKRJBGN WITH INDICATOR SET IN                *   12320018
*           THE RJE COMMUNICATION SWITCH                            *   12390018
*                                                                   *   12460018
*   USER -                                                          *   12530018
*       JOB CARD USER EXIT ROUTINE.  THE ENTRY POINT OF THIS USER   *   12600018
*         EXIT IS PROVIDED IN THE THIRD WORD OF IHKCDSOC (USER EXIT *   12670018
*         AND SYSOUT INFO TABLE).  THE USER EXIT IS PASSED THE      *   12740018
*         ADDRESS OF THE JOB CARD AND EACH CONTINUATION IN REGISTER *   12810018
*         ONE.  THE USER EXIT IS PASSED 80 CHARACTER RECORDS, ONE   *   12880018
*         PER ENTRY, UNTIL THE JOB STATEMENT HAS BEEN PROCESSED.    *   12950018
*         A // NULL STATEMENT IS PASSED IF CONTINUATION IS EXPECTED *   13020018
*         BUT NOT PRESENT IN THE INPUT STREAM. THE JOBNAME MAY NOT  *   13090018
*         BE CHANGED BY THE USER EXIT. REGISTER 14 CONTAINS THE     *   13160018
*         RETURN ADDRESS.  REGISTER 13 CONTAINS THE ADDRESS OF A    *   13230018
*         STANDARD 18 WORD SAVE AREA.  REGISTERS MUST BE SAVED ON   *   13300018
*         ENTRY AND RESTORED ON RETURN.                             *   13370018
*                                                                   *   13440018
*                                                                   *   13510018
*                                                                   *   13580018
*       JOB ACKNOWLEDGEMENT USER EXIT -  THE ENTRY POINT OF THIS    *   13650018
*         EXIT IS PROVIDED IN THE FOURTH WORD OF IHKCDSOC (USER EXIT*   13720018
*         AND SYSOUT TABLE).  THE USER EXIT IS PASSED THE ADDRESS   *   13790018
*         OF THE RJE JOB ACCEPTED MESSAGE TEXT BEGINNING WITH THE   *   13860018
*         JOBNAME FIELD (31 CHARACTERS OF TEXT ARE CONTAINED IN THIS*   13930018
*         MESSAGE).  REGISTER 14 CONTAINS THE RETURN ADDRESS.       *   14000018
*         REGISTER 13 HAS THE ADDRESS OF A STANDARD 18 WORD SAVE    *   14070018
*         AREA. REGISTERS MUST BE SAVED UPON ENTRY AND RESTORED     *   14140018
*         BEFORE RETURN.  THE USER EXIT HAS THE OPTION OF SENDING   *   14210018
*         A 59 CHARACTER MESSAGE OF HIS OWN.  IF THIS OPTION IS     *   14280018
*         TAKEN REGISTER ONE MUST CONTAIN THE ADDRESS OF THE 59     *   14350018
*         CHARACTER BUFFER CONTAINING THE MESSAGE.  IF THIS OPTION  *   14420018
*         IS NOT EXERCISED, THE CONTENTS OF REGISTER ONE MUST BE    *   14490018
*         ZERO ON RETURN.                                           *   14560018
*                                                                   *   14630018
*                                                                   *   14700018
* T A B L E S / W O R K   A R E A S - -                             *   14770018
*                                                                   *   14840018
*   STANDARD 18-WORD SAVE AREA                                      *   14910018
*   JED TABLE                                                       *   14980018
*   QMGR PARAMETER AREA                                             *   15050018
*   CENTRAL DATA SET WORK AREA                                      *   15120018
*   176 BYTE BUFFER FOR LOGICAL QUEUE RECORDS                       *   15190018
*                                                                   *   15260018
*                                                                   *   15330018
* A T T R I B U T E S - -                                           *   15400018
*                                                                   *   15470018
*   NONREUSABLE                                                     *   15540018
*                                                                   *   15610018
*                                                                   *   15680018
* N O T E S - -                                                     *   15750018
*                                                                   *   15820018
*   COMMENTS KEYED TO PROGRAMMERS FAMILIAR WITH THE MYSTERIES OF    *   15890018
*     OS ASSEMBLER LANGUAGE WHICH DEPENDS UPON AN INTERNAL          *   15960018
*     REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS         *   16030018
*     EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING      *   16100018
*     HAS BEEN ARRANGED SO THAT REDEFINITION OF CHARACTER CONSTANTS *   16170018
*     BY REASSEMBLY WILL RESULT IN A CORRECT MODULE FOR THE NEW     *   16240018
*     DEFINITIONS.  GOOD LUCK WITH REMOTE JOB ENTRY, SPORT.         *   16310018
*                                                                   *   16380018
*                                                                   *   16450018
*                                                                   *   16520018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   16590018
         EJECT                                                          16660018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   16730018
*                                                                   *   16800018
*                                                                   *   16870018
*        S Y M B O L I C   R E G I S T E R S                        *   16940018
*                                                                   *   17010018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   17080018
         SPACE 2                                                        17150018
ZIP      EQU   0                                                        17220018
PAR      EQU   1                                                        17290018
RECAD    EQU   2                                                        17360018
WOK      EQU   3                                                        17430018
CNT      EQU   4                                                        17500018
FAST     EQU   5                                                        17570018
NAM      EQU   6                                                        17640018
TDIR     EQU   7                                                        17710018
SCAN     EQU   8                                                        17780018
PONT2    EQU   9                                                        17850018
POINT    EQU   10                                                       17920018
AVT      EQU   11                                                       17990018
BAS      EQU  12                                                        18060018
SAV      EQU  13                                                        18130018
BAC      EQU  14                                                        18200018
GO       EQU  15                                                        18270018
         SPACE 2                                                        18340018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   18410018
*                                                                   *   18480018
*    S Y M B O L I C   O F F S E T S ,   D I S P L A C E M E N T S, *   18550018
*     AND   V A L U E S                                             *   18620018
*                                                                   *   18690018
* - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - * - *   18760018
         SPACE 2                                                        18830018
*  DISPLACEMENTS-                                                       18900018
         SPACE                                                          18970018
ZERO     EQU   0                                                        19040018
ONE      EQU   1                                                        19110018
TWO      EQU   2                                                        19180018
TRE      EQU   3                                                        19250018
FOUR     EQU   4                                                        19320018
ATE      EQU   8                                                        19390018
TWLV     EQU  12                                                        19460018
THIR     EQU   13                                                       19530018
SIXT     EQU   16                                                       19600018
D17      EQU   17                                                       19670018
D18      EQU   18                                                       19740018
D24      EQU   24                                                       19810018
D33      EQU  33                                                        19880018
D64      EQU   64                                                       19950018
D71      EQU   71                                                       20020018
D80      EQU   80                                                       20090018
         EJECT                                                          20160018
*  VALUES, LENGTHS,                                                     20230018
         SPACE                                                          20300018
UNK      EQU   0                        CODE FOR UNDEFINED OPERATION    20370018
L1       EQU   1                        SYMBOLIC LENGTHS ONE AND TWO    20440018
L2       EQU   2                        - BUCKLE YOUR SHOE              20510018
L3       EQU   3                        SYMBOLIC LENGTHS THREE AND FOUR 20580018
L4       EQU   4                        - SHUT THE DOOR                 20650018
LGN      EQU   4                        CODE FOR LOGON COMMAND          20720018
READ     EQU   4                        CODE TO REQUEST QMGR READ       20790018
*                                       - OPERATION                     20860018
L5       EQU   5                        SYMBOLIC LENGTHS FIVE AND SIX   20930018
L6       EQU   6                        - PICK UP STICKS                21000018
DQ       EQU   6                        CODE TO REQUEST QMGR DEQUEUE    21070018
*                                       - OPERATION                     21140018
L7       EQU   7                        SYMBOLIC LENGTHS SEVEN & EIGHT  21210018
L8       EQU   8                        - DONT BE LATE                  21280018
DELT     EQU   8                        CODE TO REQUEST QMGR DELETE     21350018
*                                       - OPERATION                     21420018
RJS      EQU   8                        CODE FOR RJSTART COMMAND        21490018
L65      EQU   9                        TEXT LENGTH FOR DISK ERROR      21560018
*                                       - WRITING JED TABLE MESSAGE     21630018
L67      EQU   9                        TEXT LENGTH FOR DISK ERROR ON   21700018
*                                       - QMGR READ OPERATION MSG       21770018
L9       EQU   9                        SYMBOLIC LENGTHS NINE AND TEN   21840018
L10      EQU  10                        - A BIG FAT HEN                 21910018
DEL      EQU  12                        CODE FOR DELETE COMMAND         21980018
LGF      EQU  16                        CODE FOR LOGOFF COMMAND         22050018
L17      EQU  17                        LENGTH SEVENTEEN MOTHER GOOSE   22120018
*                                       - IS DEAD                       22190018
BRD      EQU  20                        CODE FOR BRDCSTR COMMAND        22260018
OUT      EQU  24                        CODE FOR OUTPUT COMMAND         22330018
L56      EQU  26                        CONFUSING, BUT TEXT LENGTH FOR  22400018
*                                       - CENTRAL DATA SETS MISSING MSG 22470018
STA      EQU  28                        CODE FOR STATUS COMMAND         22540018
L51      EQU  31                        TEXT LENGTH FOR RJE JOB         22610018
*                                       - ACKNOWLEDGEMENT MSG           22680018
RJD      EQU  32                        CODE FOR RJEND COMMAND          22750018
MGR      EQU  56                        CODE FOR MSGR COMMAND           22820018
LTXT     EQU  58                        MAXIMUM VARIABLE MSG TEXT       22890018
*                                       - LENGTH LESS ONE CHARACTER     22960018
L30      EQU  59                        TEXT LENGTH FOR USER EXIT       23030018
*                                       - ACKNOWLEDGEMENT MSG           23100018
L59      EQU  59                        THIS LENGTH IS ALSO USED        23170018
ALT      EQU  60                        CODE FOR ALERT COMMAND          23240018
CNTU     EQU  64                        CODE FOR CONTINUE COMMAND       23310018
RJF      EQU  68                        CODE FOR RJENDF COMMAND         23380018
RJC      EQU  72                        CODE FOR RJENDC COMMAND         23450018
L80      EQU  80                        LOGICAL RECORD LENGTH FOR THOSE 23520018
*                                       - PROCESSED BY THIS ROUTINE     23590018
         EJECT                                                          23660018
RD1      EQU   X'01'                    INDICATOR TO QMGR TO READ ONE   23730018
*                                       - RECORD                        23800018
ABCLOS   EQU   X'01'                    MASK TO SET ABNORMAL CENTRAL    23870018
*                                       - CLOSE DOWN INDICATOR          23940018
JQUED    EQU   X'10'                    JOB ENQD ON INPUT QUEUE BUT Q   24010018
*                                       - ENTRY ON RJE Q NOT DELETED    24080018
*                                       - IF BIT IS ON                  24150018
DELJOB   EQU   X'10'                    BIT IN JOB INFO BYTE INDICATING 24220018
*                                       - JOB IS TO BE RJE DELETED      24290018
RJEQ     EQU   X'27'                    RJE Q NUMBER MANAGED BY QMGR    24360018
BLNK     EQU   X'40'                                                    24430018
NUM      EQU   X'50'                    MASK TO CHECK NUMBER OF LOGICAL 24500018
*                                       - RECORDS IN Q RECORD           24570018
*                                       - 00 TWO LOGICAL RECORDS        24640018
*                                       - 10 NO LOGICAL RECORDS         24710018
*                                       - 50 ONE LOGICAL RECORD         24780018
DEFOPT   EQU   X'80'                    RJE DEFAULT JOB PROCESSING      24850018
*                                       - OPTIONS (IMMEDIATE OUTPUT)    24920018
LAST     EQU   X'80'                                                    24990018
QEMPTY   EQU   X'F7'                                                    25060018
DONE     EQU   X'FF'                                                    25130018
PRCDS    EQU   X'FF'                    CENTRAL DATA SET PROCESSED      25200018
SLASH    EQU  C'/'                                                      25270018
         SPACE 2                                                        25340018
*  OFFSETS-                                                             25410018
         SPACE                                                          25480018
O30      EQU   30                       OFFSET FOR USER JOB ACK MSG     25550018
O51      EQU   51                       OFFSET FOR RJE JOB ACK MSG      25620018
O56      EQU   56                       OFFSET FOR MISSING DATA SET MSG 25690018
O65      EQU   65                       OFFSET FOR JED WRITE ERROR MSG  25760018
O67      EQU   67                       OFFSET FOR QMGR READ ERROR MSG  25830018
         EJECT                                                          25900018
*    I D E N T I F Y   M O D U L E   AND   E S T A B L I S H            25970018
*     I N I T I A L   A D D R E S S A B I L I T Y                       26040018
         SPACE                                                          26110018
         USING *,GO                     INITIAL ADDRESSABILITY          26180018
         SPACE                                                          26250018
         B     TWLV(GO)                 BRANCH AROUND MODULE IDENTIFIER 26320018
         DC    C'IHKXHRDR'              MODULE IDENTIFIER               26390018
         SPACE 2                                                        26460018
*    E N T R Y   L I N K A G E   AND   A D D R E S S I B I L I T Y      26530018
         SPACE                                                          26600018
         STM   BAC,BAS,TWLV(SAV)        SAVE R/I REGISTERS              26670018
         SPACE                                                          26740018
*  TELL ASSEMBLER ABOUT DSECT BASE REGISTERS                            26810018
         SPACE                                                          26880018
         USING TDIREC,TDIR              TDIR ENTRY DSECT BASE           26950018
         USING FASTAB,FAST              FAST TABLE ENTRY DSECT BASE     27020018
         USING IHKZZAVT,AVT             ADDR VECTDR TABLE DSECT BASE    27090018
         SPACE 2                                                        27160018
*    C H A I N   S A V E   A R E A S   FOR   T R A C I N G              27230018
         SPACE                                                          27300018
         LA    WOK,SAVAR                GET ADDR OF MODULE SAVE AREA    27370018
         ST    WOK,ATE(SAV)             PLACE IT IN R/I'S SAVE AREA     27440018
         ST    SAV,FOUR(WOK)            PLACE R/I SAVE AREA ADDR        27510018
*                                       - IN MODULE SAVE AREA           27580018
         LR    SAV,WOK                  MOVE SAVE AREA ADDRESS FOR      27650018
*                                       - MODULE LINKAGES               27720018
         SPACE 2                                                        27790018
*    S E T / U P   N E W   M O D U L E   B A S E   A D D R E S S        27860018
         SPACE                                                          27930018
         LM    BAC,BAS,TWLV(SAV)        RESTORE RDR REGISTERS AND GET   28000018
*                                       - NEW MODULE BASE               28070018
         USING *,BAS                    TELL ASSEMBLER OF BASREG CHANGE 28140018
BASE     DS    0H                       USE THIS ADDR FOR MODULE BASE   28210018
         SPACE                                                          28280018
         BR    POINT                    CONTINUE WITH RDR WORK          28350018
         EJECT                                                          28420018
*    W A I T   FOR   W O R K   ON THE   R J E   Q U E U E               28490018
         SPACE                                                          28560018
WAIT     L     WOK,IHKZZRCS             GET ADDRESS OF RJE COMM SWITCH  28630018
         NI    ZERO(WOK),QEMPTY         INDICATE NO WORK ON RJE Q       28700018
         SPACE                                                          28770018
         LA    PAR,QMECB                GET ADDRESS OF ECB TO WAIT ON   28840018
         L     GO,IHKZZDSP              GET ENTRY POINT OR RJE DISPATCH 28910018
         BALR  BAC,GO                   WAIT IN DISPATCHER FOR WORK ON  28980018
*                                       - THE RJE Q                     29050018
         SPACE 2                                                        29120018
*    D E Q U E U E   AN   E N T R Y   FROM THE   R J E   I N P U T      29190018
*     Q U E U E   ( N U M B E R   3 9 )                                 29260018
         SPACE 2                                                        29330018
*  SET UP QMPA FOR DEQUEUE OPERATION                                    29400018
         SPACE 1                                                        29470018
DEQ      MVI   QMPOP,DQ                 FUNCTION CODE FOR DEQUEUE       29540018
         XC    QMPEB(L4),QMPEB          ZERO 2ND WORD OF QMPA           29610018
         XC    QMECB(L8),QMECB          ZERO ECB BEING PASSED TO QMGR   29680018
         LA    ZIP,QMECB                GET ADDRESS OF ECB              29750018
         ST    ZIP,QMCAN                PLACE IT IN QMPA                29820018
         ST    ZIP,IHKZZRDE             PLACE IT IN THE AVT ALSO        29890018
         MVI   QMTPY,RJEQ               DEQ FROM RJE'S OWN QMGR Q       29960018
         BAL   WOK,QMNGR               GO TO OS QUEUE MANAGER           30030018
         SPACE 2                                                        30100018
*    C H E C K   Q M G R   R E T U R N   C O D E   AND   S E E          30170018
*     H O W   D E Q U E U E   R E Q U E S T   W E N T                   30240018
         SPACE                                                          30310018
         B     *+4(GO)                  USE RETURN TO SEE WHAT OCCURRED 30380018
         B     PRCREC                   RC=0, WORK ON THE QUEUE         30450018
         B     WAIT                     RC=4  NO WORK ON QUEUE          30520018
B        B     B                        RC=8 NOT USED - FILL UP GAP     30590018
         SPACE                                                          30660018
*  QMGR I/O ERROR , EXECUTE RJE ABNORMAL CLOSEDOWN PROCEDURE RC=12      30730018
         SPACE                                                          30800018
KMASYOYO L     WOK,IHKZZRCS             GET ADDR OF RJE COMM SWITCH     30870018
         OI    ZERO(WOK),ABCLOS         INDICATE ABNORMAL CLOSEDOWN     30940018
GETOUT   LA    ZIP,EODAD               SET EODAD INDICATORFOR           31010018
*                                  IHKBBRII                             31080018
         B     PASSOUT                 EXIT TO READER INTERPRETER       31150018
         EJECT                                                          31220018
*    P R O C E S S   R E C O R D S   IN AN   R J E   Q U E U E          31290018
*     E N T R Y                                                         31360018
         SPACE                                                          31430018
PRCREC   MVC   CANJOB(L8),QMPA          SAVE JOB NAME IN CANCEL         31500018
*                                       - COMMAND BUFFER                31570018
         L    TDIR,IHKZZTDR             GET BASE FOR TERMINAL DIRECTORY 31640018
         A    TDIR,TDIROF               ADD RECORD TDIR OFFSET TO GET   31710018
*                                       - TERMINAL DIRECTORY ENTRY ADDR 31780018
         ST   TDIR,INTLST+ATE           PUT TDIR ENTRY ADDRESS IN JPR   31850018
*                                       - AND CMDPRO PARAMETER LIST     31920018
         MVI   RDRJIB,DEFOPT            REINITIALIZE TO DEFAULT OPTIONS 31990018
         XC    RDRALT(L3),RDRALT        REINITIALIZE FAST TABLE ENTRY   32060018
*                                       - INFORMATION                   32130018
         TM    QMSTA,JQUED              IS THIS JOB ALREADY ENQUED ON   32200018
*                                       - THE OS INPUT QUEUE            32270018
         BO    PROC                     YES, PROGRAM IS INITIALIZE TO   32340018
*                                       - FLUSH JCL IN FIRST Q ENTRY    32410018
         SPACE                                                          32480018
         MVI   JCL,INIT                 JOB NOT ENQUEUED ON OS INPUT Q  32550018
*                                       - SO INITIALIZE INPUT PROCESING 32620018
*                                       - STATUS AND PROCESS ENTRY      32690018
         SPACE 2                                                        32760018
*    I N I T I A L I Z E   FOR   P R O C E S S I N G   OF               32830018
*     L O G I C A L   R E C O R D S   IN A   Q   E N T R Y              32900018
         SPACE                                                          32970018
PROC     LA    RECAD,REC-80             INITIALIZE RECORD ADDRESS       33040018
         SPACE                                                          33110018
         TM    COUNT,NUM                GET THE COUNT  OF LOGICAL       33180018
*                                       - RECORDS IN Q RECORD           33250018
         BM    EOQE                     NO RECORDS TO PROCESS IN Q      33320018
*                                       - RECORD, PROCESS END OF ENTRY  33390018
         BO    UNO                      ONE RECORD TO PROCESS IN Q REC  33460018
         SPACE                                                          33530018
*  THERE ARE TWO LOGICAL RECORDS TO PROCESS IN THIS Q RECORD            33600018
         SPACE                                                          33670018
         LA    CNT,TRE                  INITIALIZE TO PROCESS TWO REC   33740018
         SPACE                                                          33810018
PRCAGN   BCT   CNT,CTNPRC              ANY RECORDS LEFT TO PROCESS      33880018
         SPACE                                                          33950018
*  NO MORE LOGICAL RECORDS IN THIS Q RECORD TO PROCESS                  34020018
         SPACE                                                          34090018
         L     WOK,TTR                  GET TTR OF NEXT RECORD IN Q     34160018
*                                       - ENTRY                         34230018
         LTR   WOK,WOK                  SEE IF THERE IS A TTR FOR       34300018
*                                       - ANOTHER Q RECORD TO PROCESS   34370018
         BZ    EOQE                     NO, EXECUTE END OF Q ENTRY      34440018
*                                       - REQUIREMENTS                  34510018
         EJECT                                                          34580018
*    R E A D   THE   N E X T   R E C O R D   IN THIS   Q   E N T R Y    34650018
         SPACE                                                          34720018
         MVI   QMPCM,RD1                MORE RECORDS IN THIS Q ENTRY -- 34790018
*                                       - READ ONE Q RECORD             34860018
         MVI   QMPOP,READ               READ OPERATION REQUESTED        34930018
         ST    WOK,QMPEX                GIVE QMGR TTR OF NEXT Q RECORD  35000018
         BAL   WOK,QMNGR               GO TO OS QUEUE MANAGER           35070018
         SPACE                                                          35140018
         LTR   GO,GO                    WAS IT A GOOD READ              35210018
         BZ    PROC                     YEP, PROCESS RECORDS IF ANY     35280018
         SPACE                                                          35350018
*  QMGR ENCOUNTERED ERROR ON READ - NEED TO CHECK THE BEAUTY OUT        35420018
         SPACE 2                                                        35490018
*    E R R O R   P R O C E S S I N G   ON   Q M G R   R E A D           35560018
*     O P E R A T I O N S                                               35630018
         SPACE                                                          35700018
*  BLANK OUT VARIABLE MESSAGE TEXT BUFFER                               35770018
         SPACE                                                          35840018
         LA    WOK,SNDMSG67             REMBER WHERE WE ARE BE4 BLNKING 35910018
BLANK    MVI   MTXT,BLNK                MOVE INITIAL BLANK IN MSG TXT   35980018
         MVC   MTXT+ONE(LTXT),MTXT      CASCADE BLANK THRUOUT MSG TXT   36050018
         BR    WOK                                                      36120018
         SPACE                                                          36190018
*  SEND MESSAGE FIRST TO REMOTE USER                                    36260018
*    MESSAGE -- IHKX63I DISK ERROR QMGR JOBNAME                         36330018
         SPACE                                                          36400018
SNDMSG67 MVI   MSGLNG,L67               MOVE IN VARIABLE MSG TEXT LEN   36470018
         MVI   MSGOFF+ONE,O67           MOVE IN MSG OFFSET              36540018
         BAL   BAC,GOSEND               SEND BEAUTY TO REMOTE USER      36610018
         SPACE                                                          36680018
*  SEND SAME MESSAGE TO CENTRAL OPERATOR                                36750018
         SPACE                                                          36820018
         XC    DESTIN(L4),DESTIN        INDICATE MSG FOR CENTRAL EYES   36890018
         BAL   BAC,GOSEND1                                              36960018
         SPACE                                                          37030018
         LA    POINT,JOBCAN             SET UP TO CANCEL JOB IF         37100018
*                                       - THIS IS REQUIRED              37170018
         LA    PONT2,DELIT1             SET UP TO DELETE BAD Q ENTRY    37240018
         TM    JCL,HAVJCL               CURRENTLY PROCESSING JCL        37310018
         BO    GENUL1                   YES, ENQUE JOB BEFORE CANCELING 37380018
*                                       - JOB AND DELETING QUEUE ENTRY  37450018
         BR    PONT2                    NO, JUST DELETE Q ENTRY         37520018
         EJECT                                                          37590018
*    P R O C E S S   A   L O G I C A L   R E C O R D   IN   A   Q       37660018
*     R E C O R D                                                       37730018
         SPACE                                                          37800018
CTNPRC   LA    RECAD,D80(RECAD)         GET ADDRESS OF RECORD TO BE     37870018
*                                       - PROCESSED                     37940018
         CLI   ZERO(RECAD),SLASH        IS THIS A JCL STATEMENT         38010018
         BE    PRCJCL                   YES, PROCESS RECORD AS JCL      38080018
         SPACE                                                          38150018
         TM    JCL,HAVJCL               WAS LAST RECORD JCL             38220018
         BO    ENDJCL                   YES, GIVE R/I A // NULL TO ENQ  38290018
*                                       - PREVIOUS JOB                  38360018
         SPACE 2                                                        38430018
*    P R O C E S S   L O G I C A L   R E C O R D   AS AN   R J E        38500018
*     S T A T E M E N T                                                 38570018
         SPACE 1                                                        38640018
DONTSKIP LA    SCAN,TWO(RECAD)          STEP PAST JECL IDENTIFIER       38710018
         LR    PAR,SCAN                                                 38780018
         BAL   WOK,SCANNB               GET FIRST NON-BLANK PAST RECORD 38850018
*                                       - IDENTIFIER                    38920018
         ST    SCAN,INTLST              PLACE OPERATION FIELD ADDRESS   38990018
*                                       - IN IHKCAINT PARAMETER LIST    39060018
         CR SCAN,PAR                    CHECK FOR BLANK AFTER ..        39130018
         BE    NULL                     IF NOT BLANK- INVALID JECL      39200018
         LTR   GO,GO                    CHECK TO SEE IF NON-BLANK WAS   39270018
*                                       - FOUND IN RECORD LIMITS        39340018
         BZ    NULL                     NO BLANK IN RECORD -- PROCESS   39410018
*                                       - ERROR                         39480018
         SPACE 2                                                        39550018
*    C H E C K   R E C O R D   FOR   J E D   O P E R A T I O N          39620018
         SPACE                                                          39690018
         CLC   ZERO(L4,SCAN),JED        DO WE HAVE A JED OPERATION      39760018
         BE    PRCJED                   PROCESS RECORD AS A JED RECORD  39830018
         EJECT                                                          39900018
*    P R O C E S S   R E C O R D   AS A   W O R K   S T A T I O N       39970018
*     C O M M A N D   OR   C O N T I N U E D   J E D  S T A T E M E N T 40040018
         SPACE                                                          40110018
         MVI        INTLST,LGN          NO JED CHEAT AND SAY ITS A      40180018
*                                       - LOGON COMMAND                 40250018
         CLC   ZERO(L6,SCAN),LOGON      WAS IT A GOOD GUESS             40320018
         BE    PRCCMD                   YES, PROCESS COMMAND            40390018
         SPACE                                                          40460018
         MVI   INTLST,RJS               BAD GUESS BUT ODDS WERE 13 TO 1 40530018
*                                       - TRY AN RJSTART                40600018
         CLC   ZERO(L8,SCAN),RJSTART    IS THIS A GOOD QUESS            40670018
         BE    PRCCMD                   YES, 1 FOR 2 ISNT BAD - PROCESS 40740018
         SPACE                                                          40810018
         MVI   INTLST,STA               QUESSED WRONG AGAIN TRY STATUS  40880018
         CLC   ZERO(L7,SCAN),STATUS     CHECK TO SEE IF IT IS A STATUS  40950018
         BE    PRCCMD                   HOW ABOUT THAT SPORT FANS       41020018
*                                       - PROCESS ONE STATUS COMMAND    41090018
         SPACE                                                          41160018
         MVI   INTLST,OUT               WOULD YOU BELIEVE AN OUTPUT CMD 41230018
         CLC   ZERO(L7,SCAN),OUTPUT     NO, CHECK THE BEAUTY ANYHOW     41300018
         BE    PRCCMD                   PROCESS OUTPUT LUCKY QUESS      41370018
         SPACE                                                          41440018
         MVI   INTLST,MGR               SORRY ABOUT THAT QUESS, HOW     41510018
*                                       - ABOUT A MSGR COMMAND          41580018
         CLC   ZERO(L5,SCAN),MSGR       COULD BE, MAYBE PETE IS GETTING 41650018
*                                       - BRAVE                         41720018
         BE    PRCCMD                   SURE ENOUGH, PROCESS HIS MSG    41790018
         SPACE                                                          41860018
         MVI   INTLST,RJD               TIME TO TRY THE OLD RJEND CMDS  41930018
*                                       - START WITH RJEND              42000018
         CLC   ZERO(L6,SCAN),RJEND      THIS QUESSING IS GETTING OLD    42070018
*                                       - ARE WE RIGHT THIS QUESS       42140018
         BE    PRCCMD                   USER IS CALLING IT QUITS        42210018
         SPACE                                                          42280018
         MVI   INTLST,RJF               MAYBE WE HAD A LINE ERROR       42350018
*                                       - WORTH A GUESS                 42420018
         CLC   ZERO(L6,SCAN),RJENDF     STILL YET AND ANOTHER MOMENT OF 42490018
*                                       - TRUTH                         42560018
         BE    PRCCMD                   TELECOMMUNICATIONS ISNT PERFECT 42630018
         EJECT                                                          42700018
         MVI   INTLST,RJC               HEAVEN FORBID BUT QUESS THERE   42770018
*                                       - WAS AN ABNORMAL CENTRAL       42840018
*                                       - CLOSEDOWN                     42910018
         CLC   ZERO(L6,SCAN),RJENDC     CHECK FOR THIS UNFORTUNATE      42980018
*                                       - CONDITION                     43050018
         BE    PRCCMD                   COMPUTERS ARE NOT PERFECT ALSO  43120018
         SPACE                                                          43190018
         MVI   INTLST,LGF               MAYBE USER WANTS TO END HIS     43260018
*                                       - SESSION                       43330018
         CLC   ZERO(L7,SCAN),LOGOFF     DESPARATE GUESSING, CHECK CMD   43400018
         BE    PRCCMD                   LOGS USER OFF                   43470018
         SPACE                                                          43540018
         MVI   INTLST,CNTU              MAYBE HE WANTS TO RESUME        43610018
*                                       - RECEIVING OUTPUT              43680018
         CLC   ZERO(L9,SCAN),CONTINUE   CHECK FOR A CONTINUE COMMAND    43750018
         BE    PRCCMD                   PROCESS A CONTINUE              43820018
         SPACE                                                          43890018
         MVI   INTLST,DEL               IT STILL COULD BE A DELETE CMD  43960018
         CLC   ZERO(L7,SCAN),DELETE     CANT BE SURE SO CHECK IT        44030018
         BE    PRCCMD                   GET RID OF UNWANTED JOB         44100018
         SPACE                                                          44170018
         MVI   INTLST,BRD               MAYBE THE USER WANTS THE        44240018
*                                       - BROADCAST MESSAGES            44310018
         CLC   ZERO(L8,SCAN),BRDCSTR    ODDS ARE REALLY LOOKING UP,     44380018
*                                       - CHECK FOR BRDCSTR COMMAND     44450018
         BE    PRCCMD                   ITS A BRDCSTR, WHAT EVER THAT   44520018
*                                       - MEANS                         44590018
         SPACE                                                          44660018
         MVI   INTLST,ALT               IF ITS A COMMAND ITS AN ALERT   44730018
         CLC   ZERO(L6,SCAN),ALERT      IS IT A COMMAND                 44800018
         BE    PRCCMD                   WHY YES IT IS AN ALERT COMMAND  44870018
         EJECT                                                          44940018
         SPACE 2                                                        45010018
*    N O   C O M M A N D   R E C O G N I Z E D   BY   R J E             45080018
*     P R E S E N T   IN THE   I N P U T   S T R E A M                  45150018
         SPACE                                                          45220018
NULL     TM    JPR,JEDCTN               IS JED CONTINUATION OUTSTANDING 45290018
         BO    PRCJED1                  YES, PROCESS CONTINUED JED      45360018
         SPACE                                                          45430018
         MVI   INTLST,UNK               NO, HAVE UNDEFINED OPERATION    45500018
         SPACE                                                          45570018
GOCMD    LA    PAR,INTLST               GET IHKCAINT PARAMETER LIST AD  45640018
         ST    RECAD,INTLST+FOUR        GIVE CMD INT ADDR OF RECORD     45710018
         NI    JPR,VOIDJED              CANCEL JED OPTIONS              45780018
         L     GO,RDRCAINT              GET IHKCAINT ENTRY POINT        45850018
         LA    BAC,PRCAGN               PROCESS THE NEXT RECORD ON RETN 45920018
         BR    GO                       GO LET IHKCAINT HAVE A CRACK AT 45990018
*                                       - PROCESSING THE RECORD         46060018
               SPACE 2                                                  46130018
*    P R O C E S S   R J E   W O R K   S T A T I O N   C O M M A N D S  46200018
         SPACE                                                          46270018
PRCCMD   TM    JPR,JEDCTN               FIRST CHECK IF A CONTINUED JED  46340018
*                                       - IS  OUTSTANDING               46410018
         BZ    GOCMD                    NO, PROCESS RECORD WITH A CLEAR 46480018
*                                       - CONSCIOUS                     46550018
         SPACE                                                          46620018
         LA    WOK,GOCMD                GO PROCESS CMD WHEN HOUSE IS    46690018
*                                       - AGAIN IN ORDER                46760018
*    H A N D L E   J E D   C O N T I N U A T I O N   N O T              46830018
*     C O N C E I V E D   BUT   E X P E C T E D                         46900018
         SPACE                                                          46970018
NOJED    XC    INTLST+FOUR(L4),INTLST+FOUR ZERO RECORD ADDRESS TO SHOW  47040018
*                                       - NO EXPECTED CONTINUATION      47110018
         LA    PAR,INTLST               GET PARM LIST ADDRESS           47180018
         L     GO,RDRCHJPR              GET JPR ENTRY POINT             47250018
         BALR  BAC,GO                   GIVE JPR CONTROL                47320018
         SPACE                                                          47390018
         NI    JPR,VOIDJED              GET JED OUT OF SYSTEM           47460018
         SPACE                                                          47530018
         ST    POINT,PTSAVE        SAVE REG POINT                       47600018
         LA    ZIP,JEDRES                                               47670018
         BAL   POINT,PASSOUT       DELETE IHKCHJPR                      47740018
         L     POINT,PTSAVE        RESTORE REG POINT                    47810018
         SPACE                                                          47880018
         BR    WOK                      RETURN TO MAINLINE              47950018
         EJECT                                                          48020018
*    P R O C E S S   J C L   S T A T E M E N T S   IN   Q   E N T R Y   48090018
         SPACE 2                                                        48160018
PRCJCL   TM    JPR,JEDCTN               IS JED PROCESSOR WAITING ON     48230018
*                                       - CONTINUATION                  48300018
         BZ    PRCJCL1                  NO, PROCESS RECORD WITH A CLEAR 48370018
*                                       - CONSCIOUS AND FAINT HEART     48440018
         BAL   WOK,NOJED                CLEAR UP ERROR IN INPUT STREAM  48510018
*                                       - AND LET JED PROCESSOR IN ON   48580018
*                                       - THE ACTION                    48650018
         SPACE                                                          48720018
PRCJCL1  TM    JCL,FLUSH                IS THERE A FLUSH JCL CONDITION  48790018
*                                       - IN EFFECT                     48860018
         BO    PRCAGN                   YES, IGNORE THE BEAUTY AND SEE  48930018
*                                       - IF THERE IS JECL IN Q ENTRY   49000018
         SPACE                                                          49070018
         OI    JCL,HAVJCLJO             REMBER NEXT TIME THAT THIS TIME 49140018
*                                       - A JCL RECORD WAS PROCESSED    49210018
*                                       - AND SET HAVE JOB INDICATOR ON 49280018
         SPACE                                                          49350018
SCANB    LA    GO,D71(RECAD)            INITIALIZE END OF SCAN          49420018
         LR    SCAN,RECAD                                               49490018
MORE     LA    SCAN,ONE(SCAN)           INITIALIZE OR STEP TO NEXT CHAR 49560018
         CR    SCAN,GO                  SHOULD SCAN BE STOPED           49630018
         BNL   TSTCTN                   YES,CONTINUE WITH PROCESSING    49700018
         SPACE                                                          49770018
         CLI   ZERO(SCAN),BLNK          CHECK FOR BLANK                 49840018
         BNE   MORE                     LOOK SOME MORE IF NONBLANK      49910018
         SPACE                                                          49980018
         LR    NAM,SCAN                 KEEP ADDR TO COMPUTE JOBNAME    50050018
         BAL   WOK,SCANNB               SCAN FOR FIRST NON-BLANK IN     50120018
*                                       - RECORD                        50190018
         SPACE                                                          50260018
         LTR   GO,GO                    NONBLANK FOUND IN RECORD LIMITS 50330018
         BZ    TSTCTN                   NO, HAVE A POSSIBLE 11 NULL     50400018
         EJECT                                                          50470018
*    C H E C K   FOR A   J O B   S T A T E M E N T                      50540018
         SPACE                                                          50610018
         CLC   ZERO(L3,SCAN),JOBOP      DOES OPERATION INDICATE RECORD  50680018
*                                       - IS A JOB CARD                 50750018
         BE    GOTJOB                   DO SPECIAL JOB CARD PROCESSING  50820018
         SPACE 2                                                        50890018
*    T E S T   J O B C A R D   U S E R  E X I T                         50960018
*     R E Q U I R E M E N T S                                           51030018
MABCTN   NI    JOB,NOJBCAR              NOT PROCESSING JOB CARD         51100018
         TM    JOB,JOBCTN               DOES USER EXIT EXPECT JOB CARD  51170018
*                                       - CONTINUATION                  51240018
         BO    JOBEX                    GIVE USER EXIT SOMETHING        51310018
         SPACE 2                                                        51380018
*    P A S S   R / I   J C L   R E C O R D   TO   P R O C E S S         51450018
         SPACE                                                          51520018
PASS1    LA    POINT,PRCAGN             REMEMBER TO PROCESS NEXT RECORD 51590018
PASS2    LR    PAR,RECAD                GET ADDRESS OF RECORD FOR R/I   51660018
         SPACE                                                          51730018
PASS     ST    PAR,RIPARM          ADDRESS OF RECORD PASSING TO R/I     51800018
         LA    ZIP,RIPARM          POST CODE FOR R/I                    51870018
PASSOUT  L     PAR,RIPOST              ECB TO BE POSTED TO GIVE         51940018
*                                      R/I CONTROL                      52010018
POST     POST  (1),(0)                 POST R/I TASK                    52080018
          L    GO,IHKZZDSP             ADRESS OF RJE DISPATCHER         52150018
         L     PAR,RIWAIT                                               52220018
         TM    3(PAR),CLOSE            HAS R/I TERMINATED               52290018
         BO    EXIT                    IF YES, GET OUT                  52360018
         XC    0(4,PAR),0(PAR)         CLEAR ECB                        52430018
         L     BAC,IHKZZRCS        GET POINTER TO STOP SWITCH      000D 52450019
         TM    0(BAC),LAST         ARE WE IN STOP ?                000D 52470019
         BO    STOP                YES, WAIT IN RDR                000D 52490019
         BALR  BAC,GO              NO, WAIT IN DISPATCHER          000D 52510019
BACK     EQU   *                                                   000D 52530019
         TM    3(PAR),CLOSE            IS THIS RETURN FROM EODAD        52570018
         BO    EXIT                    IF YES, GET OUT                  52640018
         BR    POINT                   RESUME PROCESSIMG                52710018
STOP     EQU   *                                                   000D 52720019
         WAIT  ECB=(1)                                             000D 52730019
         B     BACK                                                000D 52740019
         EJECT                                                          52780018
*    P R O C E S S   J O B   C A R D                                    52850018
         SPACE                                                          52920018
GOTJOB   LA    PAR,QMPA                 GET ADDRESS OF THE JOBNAME      52990018
         L     GO,IHKZZSCH              GET ENTRY POINT FOR SEARCH      53060018
         BALR  BAC,GO                   GO AND FIND FAST TABLE ENTRY    53130018
*                                       - FOR THIS JOB                  53200018
         SPACE                                                          53270018
         LTR   GO,GO                    JOB NAME FOUND IN FAST TABLE    53340018
         BNZ   FLUSHIT                  FLUSH JCL IN THIS Q ENTRY       53410018
         SPACE                                                          53480018
         LR    FAST,PAR                 SET UP FAST TABLE ENTRY DSECT   53550018
*                                       - BASE                          53620018
         MVC   FASTUSE(L3),TDIRUSID     PLACE USER ID IN FAST TABLE     53690018
*                                       - ENTRY                         53760018
         SPACE                                                          53830018
PASREC   LR    PAR,RECAD                GET RECORD ADDR FOR USER EXIT   53900018
PASLAS   LA    BAC,VALENT               REMBER WHERE TO GO DONT SAY IT  53970018
         SPACE                                                          54040018
PASLAS1  NI    JOB,NOJOBC               SET JOB CARD CONTINUATION OFF   54110018
*                                       - UNTIL STATUS IS DETERMINED    54180018
         L     GO,IHKZZSOC              GET ADDRESS OF USER EXIT ENTRY  54250018
*                                       - POINT TABLE                   54320018
         L     GO,ATE(GO)               GET ENTRY POINT OF JOBCARD      54390018
*                                       - USER EXIT                     54460018
         BR    GO                       PASS RECORD TO USER EXIT        54530018
         SPACE                                                          54600018
VALENT   CLI   D71(RECAD),BLNK          IS THIS STATEMENT CONTINUED     54670018
         BE    NOCTN1                   NO, DONT HAVE TO WORRY WITH     54740018
*                                       - USER EXIT END OF FILE         54810018
         SPACE                                                          54880018
         OI    JOB,JOBCTN               REMEMBER USER EXIT NEED OF      54950018
*                                       - CONTINUATION                  55020018
NOCTN1   TM    JOB,HAVJOB               NEED TO DO SPECIAL PROCESSING   55090018
*                                       - FOR JOBNAME                   55160018
         BZ    PASS1                    NO, THIS IS ONLY JOB CONTINUED  55230018
         EJECT                                                          55300018
*    M O V E   J O B N A M E   B A C K   INTO   J O B   C A R D         55370018
         SPACE                                                          55440018
         LA    SCAN,FOUR(RECAD)         GET ADDRESS OFF 2ND CHARACTER   55510018
         SR    NAM,SCAN                 GET LENGTH OF JOBNAME LESS ONE  55580018
*                                       - TO EXECUTE A MOVE             55650018
         EX    NAM,MOVJOB               MOVE THE JOBNAME FROM THE       55720018
*                                       - CANCEL BUFFER BACK TO RECORD  55790018
         B     PASS1                    GIVE RECORD TO R/I              55860018
         SPACE 2                                                        55930018
*    P R O C E S S   R E C O R D   O T H E R   T H A N   J O B          56000018
*     C A R D   FOR   J O B   C A R D   U S E R   E X I T               56070018
         SPACE                                                          56140018
JOBEX    CLC   ZERO(L4,SCAN),EXEC       IS THIS AN EXEC  OPERATION      56210018
         LA    PAR,SLASNULL             PASS USER // NULL               56280018
         BE    PASLAS                   GIVE IT TO HIM FOR END OF JOB   56350018
*                                       - STATEMENT                     56420018
         SPACE                                                          56490018
         CLC   ZERO(L2,SCAN),DD         IS IT A DD OPERATION            56560018
         BE    PASLAS                   YES, GIVE USER // NULL          56630018
         SPACE                                                          56700018
         B     PASREC                   NO, GIVE USER THIS RECORD AS    56770018
*                                       - JOB CONTINUATION              56840018
         SPACE                                                          56910018
*   PROCESS DISTURBING RESULTS OF RECORD SCANS                          56980018
         SPACE                                                          57050018
TSTCTN   LR    SCAN,RECAD               RESTORE SCAN TO POINT TO //     57120018
         CLC   ZERO(L80,RECAD),SLASNULL TEST THIS UNKNOWN AGAINST A     57190018
*                                       - // NULL                       57260018
         BNE   MABCTN                   SEE IF USER EXIT WANTS CONTINUE 57330018
*                                       - JOB STATEMENT OR PROCESS      57400018
*                                       - AS REGULAR JCL                57470018
         LA    PONT2,FLUSHIT  ENQUEUE JOB - FLUSH REST OF STREAM A53596 57540021
         SPACE 2                                                        57680018
*    G E N E R A T E   A   / /   N U L L   S T A T E M E N T            57750018
         SPACE                                                          57820018
GENNUL2  LA    POINT,ACKJOB             SET UP TO ACKNOWLEDGE JOB       57890018
GENUL1   NI    JCL,HAVJECL              TURN OFF JCL AND JOB INDICATORS 57960018
         SPACE                                                          58030018
*    MARK JOB AS AT LEAST ENQUEUED ON OS INPUT QUEUE                    58100018
         SPACE                                                          58170018
         L     GO,IHKZZ447              GET ENTRY POINT                 58240018
         LA    PAR,QMPA                                                 58310018
         BALR  BAC,GO                                                   58380018
         SPACE                                                          58450018
         LA    PAR,SLASNULL             GET // NULL FOR USER EXIT       58520018
CHEKJUX  TM    JOB,JOBCTN               USER EXIT EXPECT CONTINUATION   58590018
         BZ    PASS                                                     58660018
         SPACE                                                          58730018
         BAL   BAC,PASLAS1              GIVE THE BEAUTY TO USER EXIT    58800018
         SPACE                                                          58870018
OVERIT   LA    PAR,SLASNULL             GET // NULL FOR R/I             58940018
         B     PASS                                                     59010018
         EJECT                                                          59080018
*    P R O C E S S   J E D   AND   I T S   C O N T I N U A T I O N      59150018
         SPACE                                                          59220018
PRCJED   ST    POINT,PTSAVE        SAVE REGISTER POINT                  59290018
         MVI   JEDRES,LOAD         INDICATE THIS IS LOAD IN PARM        59360018
         LA    ZIP,JEDRES          ADDRESS OF PARM IN REG 0             59430018
         BAL   POINT,PASSOUT       LOAD JED PROCESSOR                   59500018
         MVI   JEDRES,DELET        SET PARM FOR COMMING DELETE          59570018
         L     PAR,0(PAR)                                               59640018
         ST    PAR,RDRCHJPR        SAVE THE ADDRESS FOR CONTINUED       59710018
*                                       - LINKAGE                       59780018
         OI    JPR,HAVJED               REMBER JED PROCESSOR IN CORE    59850018
         SPACE                                                          59920018
PRCJED1  NI    JPR,NOJEDC               GED RID OF CONTINUED JED STATUS 59990018
         CLI   D71(RECAD),BLNK           IS RECORD CONTINUED            60060018
         BE    JEDNOTC                  NO,REMBER JED NOT CONTINUED     60130018
         SPACE                                                          60200018
         OI    JPR,JEDCTN               REMEMBER JED CONTINUED          60270018
         SPACE 2                                                        60340018
*    S E T   U P   J E D   P R O C E S S O R   P A R A M E T E R        60410018
*     L I S T   AND   P R O C E S S   S T A T E M E N T                 60480018
         SPACE 2                                                        60550018
JEDNOTC  ST    RECAD,INTLST+FOUR        GIVE IT ADDR OF RECORD TO PROC  60620018
         LA    PAR,INTLST               GIVE IT ADDR OF PARM LIST       60690018
         L     GO,RDRCHJPR              GET ENTRY POINT OF JPR          60760018
         BALR  BAC,GO                   GIVE JPR CONTROL                60830018
         SPACE                                                          60900018
         LR    NAM,GO                   SAVE RETURN CODE                60970018
         TM    JPR,JEDCTN               MORE JED TO COME                61040018
         BO    TSTMOR                   YES,CHECK RETURN CODE           61110018
         SPACE                                                          61180018
         LA    ZIP,JEDRES                                               61250018
         BAL   POINT,PASSOUT       DELETE IHKCHJPR                      61320018
         SPACE                                                          61390018
TSTMOR   L     POINT,PTSAVE        RESTORE REG POINT                    61460018
         LTR   NAM,NAM                  TEST JPR RETURN CODE            61530018
         BZ    PRCAGN                   GOOD PROCESS NEXT RECORD        61600018
         SPACE                                                          61670018
         NI    JPR,HAVDEF               VOID ANY SELECTED JED           61740018
*                                       - OPTIONS                       61810018
         B     PRCAGN                   PROCESS NEXT RECORD             61880018
         SPACE 2                                                        61950018
*    P R O C E S S   E N D   OF   Q   E N T R Y                         62020018
         SPACE                                                          62090018
EOQE     TM    JCL,HAVJCL               WAS LAST RECORD PROCESSED JCL   62160018
         LA    PONT2,DELIT              SET UP TO DELETE Q ENTRY        62230018
         BO    GENNUL2                  GIVE R/I // NULL BEFORE         62300018
*                                       - CONTINUING WITH END OF Q      62370018
*                                       - PROCESSING                    62440018
         SPACE                                                          62510018
DELIT1   TM    JPR,JEDCTN               IS JED PROCESSOR HANGING AROUND 62580018
*                                       - FOR JED CONTINUATION          62650018
         BZ    DELIT                    NO, GO DELETE Q ENTRY           62720018
         SPACE                                                          62790018
         BAL   WOK,NOJED                CLEAR UP ERROR IN INPUT STREAM  62860018
         EJECT                                                          62930018
*    D E L E T E   P R O C E S S E D   Q   E N T R Y   FROM THE         63000018
*     R J E   Q U E U E   ( 3 9 )                                       63070018
         SPACE                                                          63140018
DELIT    EQU   *                                                 A35895 63160020
         MVI   IHKCELST,BLNK      CLEAR FIRST BYTE OH IHKCEDIT   A35895 63180020
*                                 -WORK AREA FOR CENTRAL DATA    A35895 63200020
*                                 SETS TO USE FOR FUTURE JOBS    A35895 63220020
         MVC   IHKCELST+1(179),IHKCELST      CLEAR INPUT BUFFER  A35895 63240020
         MVI   QMPOP,DELT         INDICATE TO QMGR DELETE REQUESTA35895 63260020
         MVI   JCL,FLUSH                GET READY TO PROCESS NEXT Q ENT 63280018
         BAL   WOK,QMNGR               GO TO OS QUEUE MANAGER           63350018
         SPACE                                                          63420018
         LTR   GO,GO                    TEST SUCCESS OF DELETE REQUEST  63490018
         BNZ   KMASYOYO                 ERROR WILL NOT BE TOLERATED,    63560018
*                                       - INDICATE ABNORMAL CLOSE DOWN  63630018
         SPACE                                                          63700018
         B     DEQ                     TRY ANOTHER RECORD               63770018
         SPACE                                                          63840018
         SPACE 2                                                        63910018
*    H A N D L E   A B R U P T E N D   TO   J C L   IN THE              63980018
*     I N P U T   S T R E A M                                           64050018
         SPACE                                                          64120018
ENDJCL   CLC   ZERO(L9,RECAD),BADJOB    WAS JCL FOLLOWED BY RJENDF      64190018
         LA    PONT2,DONTSKIP           SET UP TO REPROCESS THIS RECORD 64260018
*                                       - ON R/I RETURN                 64330018
         BNE   GENNUL2                                                  64400018
*                                       GENERATE // NULL FOR R/I        64470018
         SPACE                                                          64540018
         BAL   POINT,GENUL1                                             64610018
         SPACE 2                                                        64680018
*    C A N C E L   J O B   ON   R E T U R N   FROM   R/I                64750018
         SPACE                                                          64820018
JOBCAN   MVI   SLASNULL,SLASH          CLEAN UP MESS LEFT BY     A37786 64850020
         MVI   SLASNULL+2,BLNK          OS READER INTERPRETER    A37786 64880020
         LA    PAR,CANCMD               GET ADDRESS OF CANCEL    A37786 64910020
         SR    ZIP,ZIP                                             000C 64960018
         SVC   34                       CANCEL JOB WITH SUPERVISOR AID  65030018
         SPACE                                                          65100018
         MVI   FASTJIB,DELJOB           INDICATE JOB DELETED            65170018
         B     HANDFAST                 UPDATE FAST TABLE ENTRY FOR JOB 65240018
         SPACE 2                                                        65310018
*    P R O C E S S   O N E   L O G I C A L   R E C O R D                65380018
*     IN A   Q   E N T R Y   R E C O R D                                65450018
         SPACE                                                          65520018
UNO      LA    CNT,TWO                  INITIALIZE TO PROCESS ONE       65590018
*                                       - RECORD                        65660018
         B     PRCAGN                   RESUME PROCESSING               65730018
         EJECT                                                          65800018
*    C H E C K   P R O C E S S I N G   OF   C E N T R A L   D A T A     65870018
*     S E T S                                                           65940018
         SPACE                                                          66010018
ACKJOB   EQU   *                                                        66080018
         MVI   SLASNULL,SLASH                                      000C 66150018
         MVI   SLASNULL+2,BLNK                                     000C 66220018
         MVC   FASTJIB(L1),RDRJIB       MOVE JOB INFO INTO FAST TABLE   66290018
*                                       - ENTRY FOR THIS JOB            66360018
         MVC   FASTALT(L3),RDRALT       MOVE USER INFO INFO FAST TABLE  66430018
*                                       - ENTRY FOR THIS JOB            66500018
         LA    SCAN,IHKCELST            GET ADDRESS OF CENTRAL DATA SET 66570018
*                                       - LIST                          66640018
         LA    NAM,ENDCELST             GET END OF CENTRAL DATA SET     66710018
*                                       - TABLE                         66780018
ACKJOB1  CLI   ZERO(SCAN),BLNK          WAS THIS ENTRY USED             66850018
         BE    ACKJOB2                  FINISHED WITH THIS JAZZ WRITE   66920018
*                                       - OUT JED TABLE FOR THIS JOB    66990018
         SPACE                                                          67060018
         CLI   D17(SCAN),PRCDS          WAS THIS DATA SET PROCESSED BY  67130018
*                                       - THE RJE JCL EDIT ROUTINE      67200018
         BNE   SNDMSG53                 NO, DD STATEMENT MISSING IN     67270018
*                                       - INPUT STREAM -- TELL USER     67340018
         SPACE                                                          67410018
PICUP    LA    SCAN,D18(SCAN)           STEP TO NEXT ENTRY IN DATA SET  67480018
         CR    SCAN,NAM                 ARE WE AT THE END OF THE TABLE  67550018
         BL    ACKJOB1                  CHECK THIS ENTRY IN THE TABLE   67620018
*                                       - IF NOT AT THE END             67690018
         SPACE 2                                                        67760018
*    W R I T E   O U T   J E D   T A B L E   FOR THIS   J O B           67830018
         SPACE                                                          67900018
ACKJOB2  EQU   *                                                 A35895 67920020
         MVI   IHKCELST,BLNK      CLEAR FIRST BYTE OH IHKCEDIT   A35895 67940020
*                                 -WORK AREA FOR CENTRAL DATA    A35895 67960020
*                                 SETS TO USE FOR FUTURE JOBS    A35895 67980020
         MVC   IHKCELST+1(179),IHKCELST      CLEAR INPUT BUFFER  A35895 68000020
         ST    FAST,JEDLST        SET UP PARM LIST FOR JED       A35895 68020020
*                                 TABLE MANAGER                  A35895 68040020
         L     GO,IHKZZJMR              GET ENTRY POINT OF THIS ROUTINE 68110018
         LA    PAR,JEDLST               GET ADDRESS OF PARAMETER LIST   68180018
         BALR  BAC,GO                   WRITE OUT ONE JED TABLE FOR JOB 68250018
         SPACE                                                          68320018
         LTR   GO,GO                    WAS THERE AN ERROR ON THIS I/O  68390018
*                                       - OPERATION                     68460018
         BNZ   SNDMSG65                 TELL THE USER HE HAS TROUBLES   68530018
         SPACE 2                                                        68600018
*    S E N D   U S E R   J O B   A C K N O W L E G E M E N T            68670018
*     M E S S A G E                                                     68740018
         SPACE                                                          68810018
ACKJOB3  ST    POINT,PTSAVE        SAVE REG POINT                       68880018
         MVI   STATRES,LOAD        SET PARM FOR LOAD                    68950018
         LA    ZIP,STATRES         ADDRESS OF PARM IN REG 0             69020018
         BAL   POINT,PASSOUT       LOAD IHKCFSB                         69090018
         ST    FAST,STBLST              GIVE IT A PARAMETER             69160018
         SPACE 2                                                        69230018
*    A C K N O W L E D G E   A C C E P T E D   J O B                    69300018
         SPACE                                                          69370018
         L     GO,0(PAR)           GET ENTRY POINT OF STATUS            69440018
         LA    PAR,STBLST               PASS ROUTINES PARM LIST         69510018
         BALR  BAC,GO                   GO GET JOB STATUS               69580018
         SPACE                                                          69650018
         BAL   WOK,BLANK                BLANK OUT VARIABLE MESSAGE TEXT 69720018
         SPACE                                                          69790018
         MVC   MSTA(L10),ZERO(PAR)      MOVE JOB STATUSINTO MESSAGE     69860018
         MVI   STATRES,DELET       SET PARM FOR DELETE                  69930018
         LA    ZIP,STATRES         ADDRESS OF PARM IN REG 0             70000018
         BAL   POINT,PASSOUT       DELETE IHKCFSTB                      70070018
         L     POINT,PTSAVE        RESTORE REG POINT                    70140018
         SPACE                                                          70210018
         ST    TDIR,INTLST+ATE          RESTORE CMD INT AND JPR PARM    70280018
*                                       - LIST                          70350018
         MVI   MSGOFF+ONE,O51           MOVE MSG OFFSET INTO PARM AREA  70420018
         MVI   MSGLNG,L51               MOVE VARIALE TEXT LENGTH INTO   70490018
*                                       - PARAMETER AREA                70560018
         MVC   MUSER(L3),TDIRUSID       MOVE USErID INTO MSG PARM AREA  70630018
         TM    JPR,HAVJED               JOB ACCEPTED WITH JED OR DEFAUL 70700018
         BZ    MOVDEF                   NO JED FOR THIS JOB USE DEFAULT 70770018
         SPACE                                                          70840018
         MVC   MOPT(L3),JED             MOVE JED INTO MESSAGE           71050018
         B     CONSTIT                  FINISHED UP                     71120018
         SPACE                                                          71190018
MOVDEF   MVC   MOPT(L7),DEFAULT         MOVE DEFAULT INTO MSG           71260018
CONSTIT  MVC   MJOB(L8),QMPA            MOVE JOBNAME INTO MSG           71330018
SENDIT   L     GO,IHKZZSOC              GET TABLE ADDRESS FOR USER EXIT 71400018
         L     GO,TWLV(GO)              GET JOBACK USER EXIT ADDRESS    71470018
         LA    PAR,MTXT                 GET ADDRESS OF ACK MSG          71540018
         BALR  BAC,GO                   LET EXIT EXAMINE MSG            71610018
         SPACE                                                          71680018
         LR    NAM,PAR                  SAVE USERS DESIRES              71750018
         BAL   BAC,GOSEND0              SEND RJE JOB ACK MESSAGE        71820018
         SPACE                                                          71890018
NEXTENT  LTR   NAM,NAM                  TEST USERS DESIRES              71960018
         BZ    HANDFAST                 NO ADDITION TO ACK REQUESTED    72030018
         SPACE                                                          72100018
         LA    PAR,MTXT                 GET ADDRESS PASSED TO USER EXIT 72170018
         CR    NAM,PAR                  ADDR RETURNED SAME AS PASSED    72240018
         BE    HANDFAST                 YES, HAVE DUMB RJE USER EXIT    72310018
         SPACE                                                          72380018
         MVI   MSGOFF+ONE,O30           HAVE ADDITION, SET UP MSG PARM  72450018
         MVI   MSGLNG,L30               SET MSGLNG                      72520018
         MVC   MTXT(L59),ZERO(NAM)      MOVE USERS MSG INTO BUFFER      72590018
         BAL   BAC,GOSEND1              SEND USERS MESSAGE              72660018
         SPACE 2                                                        72730018
*    U P D A T E   F A S T A B L E   E N T R Y   FOR THIS   J O B       72800018
*     TO   R E F L E C T   P R O C E S S I N G                          72870018
         SPACE                                                          72940018
HANDFAST EQU   *                                                        73010018
         LR    PAR,FAST                 SET PARAMETERS FOR FAST TABLE   73080018
*                                       - MANAGER                       73150018
         L     GO,IHKZZFMR              GET ENTRY POINT OF FAST TABLE   73220018
*                                       - MANAGER                       73290018
         LR    BAC,PONT2                GET RETURN POINT FOR IHKCDFMR   73360018
         BR    GO                       UPDATE FAST TABLE ENTRY OF JOB  73430018
*                                       - ON DISK                       73500018
         SPACE 2                                                        73570018
SCANNB   LA    GO,D71(RECAD)            INITIALIZE END OF SCAN          73640018
OVERAGN  CLI   ZERO(SCAN),BLNK          TEST FOR BLANK                  73710018
         BCR   7,WOK                    NONBLANK FOUND RETURN WITH NEWS 73780018
         SPACE                                                          73850018
         LA    SCAN,ONE(SCAN)           STEP TO LOOK AT NEXT CHARACTER  73920018
         CR    SCAN,GO                  SEE IF SCANNING SHOULD CEASE    73990018
         BL    OVERAGN                  NO LOOK SOME MORE               74060018
         SPACE                                                          74130018
         XR    GO,GO                    INDICATE NO NONBLANK FOUND      74200018
         BR    WOK                      RETURN WITH INFO                74270018
         SPACE 2                                                        74340018
FLUSHIT  MVI   JCL,FLUSH                INDICATE JCL TO BE FLUSH IN     74410018
*                                       - Q ENTRY                       74480018
         B     PRCAGN                   GET NEXT RECORD TO PROCESS      74550018
         SPACE 2                                                        74620018
SNDMSG53 BAL   WOK,BLANK                                                74690018
         MVC   MDAS(L17),ZERO(SCAN)                                     74760018
         MVI   MSGOFF+ONE,O56                                           74830018
         MVI   MSGLNG,L56                                               74900018
         LA    BAC,PICUP                                                74970018
         B     GOSEND                                                   75040018
         SPACE 2                                                        75110018
SNDMSG65 MVI   MSGLNG,L65                                               75180018
         MVI   MSGOFF+ONE,O65                                           75250018
         LA    PAR,CANCMD               GET SVC 34 PARM TO CANCEL JOB   75320018
         SVC   34                       CANCEL JOB WITH CANCEL CMD      75390018
         SPACE                                                          75460018
         LR    BAC,PONT2                CONTINUE PROCESSING AFTER MSG   75530018
*                                       - IS SENT TO USER               75600018
         SPACE                                                          75670018
GOSEND   MVC   MJOB(L8),QMPA                                            75740018
GOSEND0  ST    TDIR,DESTIN                                              75810018
GOSEND1  LA    PAR,RDRMSG                                               75880018
         L     GO,IHKZZLDM                                              75950018
         BR    GO                                                       76020018
         EJECT                                                          76090018
*    F I N A L   S T E P S   OF   R J E   C L O S E D O W N             76160018
*     O H   R E A L L Y   - -    T H A T ' S   T E R R I F I C          76230018
         SPACE 2                                                        76300018
IHKCHASE DS    0H                                                       76370018
         USING *,GO                     SET UP A TEMPORARY BASE         76440018
         LM    AVT,BAS,SAVAR+D64        GET MODULE AND AVT BASE         76510018
         DROP  GO                       LET GO OF TEMPORARY BASE        76580018
         SPACE                                                          76650018
         B     GETOUT                   NO, APOLOGIZE AND REST UP AFTER 76720018
*                                       - A JOB WELL DONE               76790018
EXIT     L     SAV,SAVAR+4                                              76860018
         RETURN (14,12),T                                               76930018
    SPACE                                                               77000018
*         INTERFACE TO O/S QUEUE MANAGER                                77070018
    SPACE                                                               77140018
QMNGR    LA    ZIP,RDRQMPA             ADDRESS OF PARAMETER AREA        77210018
         MVI   SLASNULL,SLASH          CLEAN UP MESS LEFT BY     A37786 77230020
         MVI   SLASNULL+2,BLNK          OS READER INTERPRETER    A37786 77250020
         XC    ECBWAIT,ECBWAIT         CLEAR ECB                        77280018
          L    PAR,ADPECB              ADDRESS OF ECB IN IHKQMNGR       77350018
          POST (1),(0)                 REQUEST PROCESSING BY IHKQMNGR   77420018
         L     GO,IHKZZDSP             ADDRESS OF RJE DISPATCHER        77490018
         LA    PAR,ECBWAIT             ECB POSTED BY IHKQMNGR           77560018
         BALR  BAC,GO                  WAIT IN DISPATCHER               77630018
         LH    GO,2(PAR)               PUT RETURN CODE IN REG15         77700018
          BR   WOK                     RETURN TO MAINLINE CODE          77770018
         EJECT                                                          77840018
*        C O N S T A N T S   AND   W O R K   A R E A S                  77910018
         SPACE                                                          77980018
LOAD     EQU   4                                                        78050018
DELET    EQU   8                                                        78120018
JEDRES   DC    F'76'               PARM FOR LOADING OD DELETING JED     78190018
*                                  PROCESSOR                            78260018
STATRES  DC    F'80'               PARM FOR STATUS LOAD OR DELETE       78330018
RIPARM   DC    F'0'                ADDRESS OF RECORD FOR R/I            78400018
PTSAVE   DC    F'0'                SAVE REGISTER POINT                  78470018
SAVAR    DC    15F'0'                   MODUULE SAVE AREA LESS 10 & 12  78540018
         SPACE                                                          78610018
         DC    A(DEQ)                   INITIAL VALUE FOR POINT         78680018
         DC    A(IHKCACOM)                                              78750018
         DC    A(BASE)                  MODULE BASE ADDR AFTER ENTRY    78820018
         SPACE                                                          78890018
CLOSE    EQU   X'01'                                                    78960018
RDRQMPA  DC    A(QMPA)                 PARMLIST FOR IHKQMNGR            79030018
ADWECB   DC    A(ECBWAIT)                                               79100018
ECBWAIT DC F'0'                        ECB POSTED BY IHKQMNGR           79170018
ADPECB    DC   A(IHKRIECB)             ECB POSTED TO GIVE CONTROL TO    79240018
*                                      IHKQMNGR                         79310018
RIWAIT    DC   A(IHKCBRDP)             ADDRESS OF ECB WAITED ON         79380018
*                                  FOR R/I PROCESSING                   79450018
RIPOST   DC    A(IHKCBRDE)             ECB POSTED TO GIVE R/I           79520018
*                                  CONTROL                              79590018
RDRCAINT DC    V(IHKCAINT)                                              79660018
RDRCHJPR DC    F'0'                                                     79730018
         SPACE                                                          79800018
         DS    0H                  EODAD CONSTANTS                 000C 79830018
EODAD    DC    X'0C'               CODE FOR EODAD                  000C 79860018
         DC    XL3'00'             FILLER                          000C 79890018
JEDLST   DC    F'0'                                                     79940018
         DC    X'80'                                                    80010018
         DC    AL3(IHKCEJDT)                                            80080018
         SPACE                                                          80150018
INTLST   DC    F'0'                                                     80220018
         DC    F'0'                                                     80290018
         SPACE                                                          80360018
STBLST   DC    F'0'                                                     80430018
         DC    A(IHKCACOM)                                              80500018
         DC    A(IHKCEJDT)                                              80570018
         SPACE                                                          80640018
QMECB    DC    2F'0'                                                    80710018
         SPACE                                                          80780018
BUF      DS    0CL176                                                   80850018
TTR      DC    F'0'                                                     80920018
REC      DC    CL160' '                                                 80990018
TDIROF   DC    F'0'                                                     81060018
COUNT    DC    C' '                                                     81130018
PAD      DC    CL7' '                                                   81200018
         SPACE                                                          81270018
SLASNULL DC    CL80'//'                                                 81340018
DD       DC    CL2'DD'                                                  81410018
         SPACE                                                          81480018
IHKCEJDT DS    0CL98                                                    81550018
JEDMSG   DC    CL25' '                                                  81620018
JEDOUT   DC    CL25' '                                                  81690018
         DS    0F                                                       81760018
         SPACE                                                          81830018
QMPA     DS    0CL36                                                    81900018
QMCAN    DC    F'0'                                                     81970018
QMPEB    DC    F'0'                                                     82040018
QMPOP    DC    X'00'                                                    82110018
QMFLT    DC    X'0000'                                                  82180018
QMTST    DC    X'00'                                                    82250018
QMTLN    DC    H'0'                                                     82320018
QMNOT    DC    X'00'                                                    82390018
QMTPY    DC    X'27'                                                    82460018
QMSTA    DC    X'00'                                                    82530018
QMPRI    DC    X'00'                                                    82600018
QMLNK    DC    H'0'                                                     82670018
QMTID    DC    H'0'                                                     82740018
RESV     DC    H'0'                                                     82810018
QMWTQ    DC    F'0'                                                     82880018
QMELA    DC    F'0'                                                     82950018
QMPCM    DC    X'00'                                                    83020018
QMPCL    DC    AL3(QMPCA)                                               83090018
         SPACE                                                          83160018
QMPCA    DC    A(BUF)                                                   83230018
QMPEX    DC    F'0'                                                     83300018
PADD     DC    4X'00'                                                   83370018
         SPACE                                                          83440018
IHKCELST DC    CL180' '                                                 83510018
ENDCELST DS    0C                                                       83580018
RDRJIB   DC    X'80'                                                    83650018
RDRALT   DC    3X'00'                                                   83720018
         SPACE                                                          83790018
         DS    0F                                                       83860018
         SPACE                                                          83930018
RDRMSG   DS    0CL66                                                    84000018
DESTIN   DC    F'0'                                                     84070018
MSGOFF   DC    H'0'                                                     84140018
MSGLNG   DC    X'00'                                                    84210018
MTXT     DS    0CL59                                                    84280018
MJOB     DS    CL9                                                      84350018
MDAS     DS    0CL17                                                    84420018
MUSER    DS    CL4                                                      84490018
MSTA     DS    CL11                                                     84560018
MOPT     DS    CL7                                                      84630018
MSGPAD   DC    CL28' '                                                  84700018
         SPACE                                                          84770018
         DS    0F                                                       84840018
         SPACE                                                          84910018
CANCMD   DC    H'19'                                                    84980018
         DC    H'0'                                                     85050018
         DC    C'CANCEL '                                               85120018
IHKCEJBN DS    0C                                                       85190018
CANJOB   DC    CL9' '                                              000C 85260018
         SPACE                                                          85330018
EXEC     DC    CL4'EXEC'                                           000C 85400018
MOVJOB   CLC   TWO(L2,RECAD),CANJOB                                     85470018
*                                                                       85540018
         SPACE                                                          85610018
JCL      DS    0C                                                       85680018
JOB      DS    0C                                                       85750018
JPR      DC    X'01'                                                    85820018
         SPACE                                                          85890018
*  READER INPUT PROCESSING STATUS INDICATORS                            85960018
         SPACE                                                          86030018
INIT     EQU   X'00'                    MASK TO INITIALIZE RDR INPUT    86100018
*                                       - STATUS, NO INPUT RESIDUE      86170018
FLUSH    EQU   X'01'                    FLUSH JCL BIT ON                86240018
*                                       - PROCESS JCL IF BIT OFF        86310018
JOBCTN   EQU   X'02'                    JOB CONTINUATION BIT ON         86380018
*                                       - NO CONTINUED JOB STATEMENT IF 86450018
*                                       - BIT OFF                       86520018
HAVJCL   EQU   X'04'                    PROCESSING JCL BIT ON           86590018
HAVJED   EQU   X'08'                    PROCESSING JED BIT ON           86660018
*                                       - PROCESSING JECL IF BIT OFF    86730018
*                                       - NO JED PROCESSING IF BIT OFF  86800018
JEDCTN   EQU   X'10'                    JED CONTINUATION BIT ON         86870018
*                                       - NO CONTINUED JED IF BIT OFF   86940018
HAVJOB   EQU   X'20'                    PROCESSING JOB IF ON            87010018
HAVJCLJO EQU   X'24'                    PROCESSING JCL AND JOB IF ON    87080018
NOJBCAR  EQU   X'DF'                    MASK TO SET HAVE JOB OFF        87150018
VOIDJED  EQU   X'E7'                    MASK USED TO REMOVE JED PRESENT 87220018
NOJEDC   EQU   X'EF'                    MASK TO SET CONTINUED JED OFF   87290018
HAVDEF   EQU   X'F7'                    MASK TO SET GOOD JED OFF        87360018
HAVJECL  EQU   X'DB'                    MASK TO SET PROCESSING JCL OFF  87430018
NOJOBC   EQU   X'FD'                    MASK TO SET CONTINUED JOB OFF   87500018
NOFLUSH  EQU   X'FE'                    MASK USED TO SET FLUSH BIT OFF  87570018
RJSTART  DC    CL8'RJSTART '                                            87640018
LOGOFF   DC    CL7'LOGOFF '                                             87710018
RJEND    DC    CL6'RJEND '                                              87780018
ALERT    DC    CL6'ALERT '                                              87850018
RJENDC   DC    CL6'RJENDC'                                              87920018
CONTINUE DC    CL9'CONTINUE '                                           87990018
DELETE   DC    CL7'DELETE '                                             88060018
BADJOB   DC    C'.. '                                                   88130018
RJENDF   DC    CL6'RJENDF'                                              88200018
JED      DC    CL4'JED '                                                88270018
OUTPUT   DC    CL7'OUTPUT '                                             88340018
BRDCSTR  DC    CL8'BRDCSTR '                                            88410018
JOBOP    DC    CL3'JOB'                                                 88480018
STATUS   DC    CL7'STATUS '                                        000C 88550018
DEFAULT  DC    CL7'DEFAULT'                                             88620018
LOGON    DC    CL6'LOGON '                                              88690018
MSGR     DC    CL5'MSGR '                                               88830018
         EXTRN IHKCBRDE,IHKCBRDP                                        88900018
         EXTRN IHKRIECB                                                 88970018
         EJECT                                                          89040018
     IHKDSECT   TDIR,,FASTAB,JEDTAB,,AVT                           000C 89110018
   END                                                                  89180018
