BGN2     TITLE    'IHKRJBGN - RJE STARTER MODULE  '                     00400018
IHKXJBGN CSECT                                                          00800018
IHKRJBGN DS    0H                                                       01200018
         ENTRY IHKRJBGN                                                 01600018
         ENTRY IHKCHAS                                           A25573 01650020
* 496000-512000,536000-560000                                      I270 01700019
* 088000,372000,672000                                           A24702 01800019
* 440000-444000                                                  A29513 01860020
* 188000                                                         A25573 01920020
*A 618000                                                        S21945 01940021
*                                                                     * 01960021
*********************************************************************** 02000018
*                                                                     * 02400018
*STATUS-                                                              * 02800018
*           CHANGE LEVEL 1, RELEASE 21                                * 03200021
*                                                                     * 03600018
*FUNCTION/OPERATION-                                                  * 04000018
*   THIS ROUTINE IS GIVEN CONTROL (BY THE L-SHAPED ROUTINE) AT RJE    * 04400018
*   SYSTEM STARTUP. RJBGN ISSUES AN ENQ MACRO TO INSURE THAT ONLY ONE * 04800018
*   RJE IS PRESENT. IT BUILDS THE PARAMETER LIST NEEDED BY IHKCBNIP   * 05200018
*   (NON-RESIDENT INITIALIZATION ROUTINE). RJBGN ATTACHES IHKQMNGR AND* 05600018
*   IHKBBNIT. IT THEN BRANCHES AND LINKS TO THE READER. WHEN THE      * 06000018
*   READER RETURNS AT CLOSEDOWN, RJBGN LINKS TO UIHKCHUCK FOR CLEAN UP* 06400018
*   WHEN IHKCHUCK RETURNS TO RJBGN, A DEQ (TO RELEASE RJE)            * 06800018
*   MACRO IS ISSUED5, A 'RJE'CLOSEDOWN MESSAGE IS SENT TO CENTRAL, AND* 07200018
*   CONTROL IS RETURNED TO THE L-SHAPED ROUTINE.                      * 07600018
*                                                                     * 08000018
*ENTRY POINTS-                                                        * 08400018
*     IHKCHAS IS THE ENTRY POINT USED BY STAE AT ABEND TIME.     A25573 08500020
*   IHKEODAD IS THE ENTRY POINT USED BY IHKCHDSP IF A SUBTASK    A24702 08600019
*        ABENDS AND RJE MUST BE CLOSED DOWN.                     A24702 08800019
*       IHKRJBGN IS ENTERED BY ENTERING THE                      A24702 09000019
*   STATEMENT- START RDR (PROCNAME), WHERE PROCNAME IS THE NAME OF A  * 09200018
*   CATALOGED PROCEDURE IN SYSX.PROCLIB CONTAINING A  //  EXEC        * 09600018
*   PGM=IHKRJBGN  STATEMENT AND ITS ASSOCIATED JCL.                   * 10000018
*                                                                     * 10400018
*INPUT-                                                               * 10800018
*   REGISTER ONE POINTS TO A THREE WORD START PARAMETER LIST. THE     * 11200018
*   FIRST WORD POINTS TO THE PARM FIELD APPEARING ON THE EXEC         * 11600018
*   STATEMENT IN THE PROCEDURE USED TO START RJE. THE SECOND WORD     * 12000018
*   POINTS TO AN ECB FOR COMMUNICATING WITH O S. THE THIRD WORD POINTS* 12400018
*   TO THE COMMAND INPUT BUFFER.                                      * 12800018
*                                                                     * 13200018
*OUTPUT-                                                              * 13600018
*   N/A                                                               * 14000018
*                                                                     * 14400018
*EXTERNAL ROUTINES-                                                   * 14800018
*        IHKCBNIP- INITIALIZE RJE                                     * 15200018
*        IHKCBLDM- GET MESSAGES FOR  THE CENTRAL CONSOLE              * 15600018
*         IHKCHRDR- GET RJE OFF THE GROUND AND RUNNING                * 16000018
*        IHKCHUCK- CLEAN UP RJE AT CLOSEDOWN                          * 16400018
*                                                                     * 16800018
*EXIT-NORMAL-                                                         * 17200018
*   RETURN TO L-SHAPED ROUTINE.                                       * 17600018
*                                                                     * 18000018
*EXIT-ERROR-                                                          * 18400018
*    RETURN TO STAE FOR ABEND.                                   A25573 18800020
*                                                                     * 19200018
*TABLES/WORK AREAS-                                                   * 19600018
*   N/A                                                               * 20000018
*                                                                     * 20400018
*ATTRIBUTES-                                                          * 20800018
*                                                                     * 21200018
*   SERIALLY REUSABLE                                                 * 21600018
*                                                                     * 22000018
*NOTES-                                                               * 22400018
*   N/A                                                               * 22800018
*                                                                     * 23200018
*    S Y M B O L I C   R E G I S T E R S   U S E D   BY   T H I S       23600018
*     M O D U L E                                                       24000018
         SPACE 2                                                        24400018
ZIP      EQU   0              WORK REGISTER                             24800018
PAR      EQU   1              PARAMETER LIST ADDRESS FOR LINKAGE        25200018
WOK      EQU   2              GENERAL WORK REGISTER                     25600018
AVT      EQU   3              RJE ADDRESS TABLE DSECT BASE              26000018
SWH      EQU   4              ERROR MSG SENT ALREADY REMBERER           26400018
NU       EQU   5              NOT USED                                  26800018
RCS      EQU   6                   ADDRESS OF IHKCDRCS                  27200018
NU1      EQU   7              NOT USED                                  27600018
NU2      EQU   8              NOT USED                                  28000018
NU3      EQU   9              NOT USED                                  28400018
NU4      EQU  10              NOT USED                                  28800018
NU5      EQU  11              NOT USED                                  29200018
BAS      EQU  12              MODULE BASE REGISTER                      29600018
SAV      EQU  13              SAVE AREA ADDRESS REGISTER                30000018
BAC      EQU  14              RETURN POINT REGISTER FOR LINKAGE         30400018
GO       EQU  15              ENTRY POINT REGISTER FOR LINKAGE AND      30800018
*                             - RETURN CODE CONTAINER ON RETURN         31200018
ZERO     EQU   0                                                        31600018
L4       EQU   4                                                        32000018
FOUR     EQU   4                                                        32400018
ATE      EQU   8                                                        32800018
TWLV     EQU   12                                                       33200018
O19      EQU   19                                                       33600018
O40      EQU   40                                                       34000018
O66      EQU   66                                                       34400018
O72      EQU   72                                                       34800018
BITS     EQU   X'03'                                                    35200018
         STM   BAC,BAS,TWLV(SAV)   SAVE SYSTEM TASK CONTROL'S REGS      35600018
*                                  - FOR RETURN LINKAGE                 36000018
         BALR  BAS,ZIP             SET UP MODULE ADDRESSABILITY         36400018
         USING *,BAS               TELL ASSEMBLER CHOICE OF BASE        36800018
BASE     EQU   *                                                 A24702 37200019
         B     AROUNDID            BRANCH AROUND IDENTIFIER             37600018
         DC    C'IHKXJBGN'         MODULE IDENTIFIER                    38000018
AROUNDID LA    WOK,BGNSAV          GET BEGIN'S SAVE AREA ADDRESS        38400018
         ST    WOK,ATE(SAV)        PUT IT IN STC SAVE AREA              38800018
         ST    SAV,FOUR(WOK)       PUT STC SAVE AREA ADDRESS IN         39200018
*                                  - BEGIN SAVE AREA                    39600018
         LR    SAV,WOK             SET UP SAVE REG FOR MODULE           40000018
*                                  - LINKAGES                           40400018
         L     AVT,BGNCACOM        GET ADDRESS OF RJE ADDRESSES         40800018
*                                  - AND USE AS DSECT BASE              41200018
         USING IHKZZAVT,AVT        TELL ASSEMBLER ABOUT THIS DSECT      41600018
         ST    PAR,IHKZZSCB        PLACE SPL  IN THE AVT FOR RJE        42000018
*                                  - USE                                42400018
         USING CIB,WOK                                                  42460020
         EXTRACT  CPL,FIELDS=COMM                                       42520020
         L     PAR,CPL             LOAD POINTER TO PARM FIELD           42580020
         L     WOK,FOUR(PAR)      GET CIB POINTER                       42640020
         MVC   IHKZZOFS(1),CIBCONID  PERSERVE CONSOLE ID                42700020
*    I N S U R E   T H A T   R J E   IS NOT   A L R E A D Y             42800018
*     A C T I V E   IN THE   S Y S T E M                                43200018
    ENQ      (IHKRJE,R$,,2,SYSTEM),RET=USE                              43600018
         LR    SWH,SAV             REMBER NO MSG SENT YET               44800018
         LTR   GO,GO               IS RJE ALREADY ACTIVE                45200018
         BNZ   ONLYONE             YES, SORRY ABOUT THAT CHIEF --       45600018
*                                  - ONLY ONE RJE TASK AT A TIME        46000018
         LA    PAR,BGNCACOM        PARAMETER LIST FOR IHKCBNIP          46400018
    LINK       EPLOC=BGNCBNIP      GIVE OLD NIP A GO AT IT              46800018
         LTR   GO,GO               WAS INITIALIZE SUCCESSFUL            47200018
         BNZ   BADSHOW1            NO FORGET ABOUT RUNNING RJE          47600018
         STAE  IHKCHAS,CT,PURGE=HALT   TO GET CONTROL AT ABEND   A25573 47800020
         SPACE 2                                                        48000018
*        ATTACH READER/INTERPRETER                                      48400018
         SPACE 2                                                        48800018
         LA    PAR,BGNCACOM        PARAMETER LIST FOR IHKBBNIT          49200018
         ATTACH EP=IHKBBNIT,LPMOD=1,SM=PROB,ROLL=(NO,NO),          I270X49800019
               ECB=VH1ECB,KEY=SZERO,JSTCB=NO,SZERO=YES,            I270X50400019
               GIVEJPQ=NO                                          I270 51000019
         ST    PAR,VH1TCB          SAVE ADDRESS OF R/I TCB              51600018
         SPACE 2                                                        52000018
* ATTACH O S QUEUE MANAGER AS A SEPERATE TASK                           52400018
         SPACE 2                                                        52800018
         LA    PAR,BGNQMPRM        ADDRESS OF PARAMETER LIST            53200018
         ATTACH EP=IHKQMNGR,ECB=BGNQMECB,SM=PROB,ROLL=(NO,NO),     I270X54200019
               KEY=ZERO,JSTCB=NO,SZERO=YES,SVAREA=YES,GIVEJPQ=NO   I270 55200019
         ST    PAR,BGNTCB          SAVE TCB ADDRESS FOR IHKQMNGR        56400018
         LA    PAR,BGNECB          ECB TO BE POSTED BY IHKQMNGR         56800018
         WAIT  ECB=(1)                                                  57200018
         L     PAR,RDRECB          ADDRESS OF ECB POSTED BY IHKBBRII    57600018
         WAIT  ECB=(1)             WAIT FOR IHKBBRII INITIALIZATION     58000018
         SR    NU4,NU4             SET NORMAL PARM FOR CHUCK     A24702 58200019
         ST    NU4,0(PAR)          CLEAR ECB                     A24702 58400019
         SPACE 2                                                        58800018
         L     GO,IHKZZRDR         ADDRESS OF IHKCERDR                  59200018
         BALR  BAC,GO              GET RJE SYSTEM OFF THE GROUND        59600018
         B     BGNRTRN             BRANCH TO CLOSE DOWN          A24702 59630019
         SPACE 1                                                 A24702 59660019
         ENTRY IHKEODAD                                          A24702 59690019
IHKEODAD DS    0H                  ENTRY FOR SUBTASK ABEND       A24702 59720019
         USING *,GO                SET UP TEMP. ADDRESSABILITY   A24702 59750019
         L     BAS,STAEBASE        GET MODULE BASE               A24702 59780019
         DROP  GO                  DROP TEMP. BASE               A24702 59810019
         LA    SAV,BGNSAV          SET UP SAVE AREA REGISTER     A24702 59840019
         LA    NU4,0(BAS)          SET POSITIVE PARM FOR CHUCK   A24702 59870019
         L     AVT,UCKPARMS        GET POINTER TO AVT            A24702 59880019
         SPACE 1                                                 A24702 59900019
BGNRTRN  DS    0H                                                A24702 59930019
         SPACE 2                                                        60000018
* RETURN FROM RJE FOR CLOSEDOWN                                         60400018
         LA    ZIP,BGNF            GET ADDRESS OF PARAMETER LIST        60800018
         L     PAR,BGNCDQMG        GET ADDRESS OF ECBLIST               61200018
         L     PAR,0(PAR)          GET ADDRESS OF ECB OF IHKQMNGR       61600018
         LA    PAR,0(0,PAR)            ZERO HIGH ORDER BYTE      S21945 61800021
         POST  (1),(0)             POST ECB OF IHKQMNGR                 62000018
         LA    PAR,VH1ECB                                               62400018
         WAIT  ECB=(1)             WAIT FOR R0I TO COMPLETE             62800018
         DETACH VH1TCB             DETACH IHKCBNIT                      63200018
         LA    PAR,BGNQMECB                                             63600018
         WAIT  ECB=(1)             WAIT FOR IHKQMNGR TO COMPLETE        64000018
         DETACH BGNTCB             DETACH IHKQMNGR                      64400018
         L  RCS,IHKZZRCS           ADDRESS OF COMM. SWITCHES            64800018
         TM    0(RCS),CLOSE        TEST FOR NORMAL RETURN               65200018
         BZ    BADSHOW             CONTRARY TO POPULAR OPINION          65600018
*                                  - EVERYTHING FINE SO FAR             66000018
BADSHOW1 XR    SWH,SWH             REMBER ERROR MSG SENT                66400018
         L     NU4,UCKPARMS       INSURE CHUCK KNOWS OF ABNORMAL A28929 66420020
*                           CLOSEDOWN SO CLEAN UP IS COMPLETE    A28929 66440020
         B     UNCHAIN             BRANCH AROUND STAE PROCESSING A25573 66460020
IHKCHAS  EQU   *                   ENTRY POINT FOR STAE AT ABEND A25573 66480020
        USING *,GO                SET UP TEMPORARY BASE          A25573 66500020
         STM   BAC,BAS,TWLV(SAV)   SAVE REGS FOR STAE            A25573 66520020
         L    BAS,STAEBASE        PICK UP BGN'S BASE REG         A25573 66540020
         DROP  GO                                                A25573 66560020
         LA    WOK,BGNSAV          GET BGN'S SAVE AREA ADDRESS   A25573 66580020
         ST    WOK,ATE(SAV)        PUT IN STAE SAVE AREA         A25573 66600020
         ST    SAV,FOUR(WOK)                                     A25573 66620020
         LR    SAV,WOK             SET UP NEW SAVE REG           A25573 66640020
         LNR   NU4,BAS             SET NEGATIVE PARM FOR CHUCK   A25573 66660020
UNCHAIN  EQU   *                                                 A25573 66680020
*     B R I N G   IN   C H U C K   TO   C L E A N - U P                 66800018
BADSHOW  LA    PAR,UCKPARMS        GET ADDRESS OF CHUCK PARMS    A24702 67000019
         ST    NU4,UCKTYPE         GET TYPE OF OPERATION WANTED  A24702 67200019
    LINK       EPLOC=BGNCHUCK      GET CHUCK IN AND PASS CONTROL        67600018
         LTR   GO,GO               HOW DID THINGS GO WITH CHUCK         68000018
         BNZ   DEQ                 CHUCK HAD TROUBLES, DUCK OUT         68400018
*    CHUCK CHECKED OUT OK, BUT DID RJE HAVE AN EARLIER PROBLEM          68800018
         LTR   SWH,SWH             HAS ERROR MSG ALREADY BEEN SENT      69200018
         BZ    DEQ                 HANG IT UP, MSG SENT                 69600018
         MVI   MSGOFF,O40          SELECT CLOSEDOWN MESSAGE             70000018
*                          IHK016I RJE CLOSED DOWN                      70400018
         BAL   BAC,SNDMSG          GO BUILD A MESSAGE                   70800018
DEQNEXT  DS    0H                                                       71200018
    WTO        ,MF=(E,(1))         SEND GREETINGS TO OPERATOR           71600018
*    R E L E A S E   R J E   FOR   S U B S E Q U E N T                  72000018
*     S T A R T S                                                       72400018
DEQ      DS    0H                                                       72800018
    DEQ         (IHKRJE,R$,2,SYSTEM),RET=HAVE   FREE RJE RESOURCE       73200018
         L     SAV,BGNSAV+FOUR     GET STC SAVE AREA ADDRESS            73600018
         XR    GO,GO               SET RETURN CODE                      74000018
    RETURN     (14,12),T,RC=(15)   RETURN TO STC                        74400018
ONLYONE  MVI   MSGOFF,O72          SELECT REJECTED MSG                  74800018
SNDMSG1  LA    BAC,DEQNEXT         GET RETURN POINT                     75200018
SNDMSG   LA    PAR,BGNMSG          GET BLDM PARM LIST ADDR              75600018
         L     GO,IHKZZLDM         GET ENTRY POINT FOR BLDM             76000018
         BR    GO                  GO GET MSG BUILT                     76400018
*    C O N S T A N T S   AND   W O R K   A R E A S                      76800018
BGNSAV   DC    18F'0'                                                   77200018
STAEBASE DC    A(BASE)             SO STAE CAN USE BASE REG      A24702 77240019
         SPACE 1                                                 A25573 77280019
*   NOTE: THE PARAMETER LIST FOR IHKCHUCK IS NOW THE FOLLOWING   A24702 77320019
*        TWO WORDS.                                              A24702 77360019
UCKPARMS DC    A(IHKCACOM)         AVT ADDRESS                   A24702 77400019
UCKTYPE  DC    F'0'                INDICATOR OF OPERATION WANTED A24702 77440019
*                       ZERO - NORMAL CLOSEDOWN                  A24702 77480019
*                       PLUS - SUBTASK ABEND PROCESSING          A24702 77520019
*                       MINUS - STAE PROCESSING                  A25573 77528020
         DC    V(IHKCDLCB)        POINTER TO FIRST LCB           A28929 77536020
         DC    V(IHKCDNOL)        POINTER TO NUMBER OF LCBS      A28929 77544020
         DC    V(IHKCDLGL)        POINTER TO LENGTH OF LCBS      A28929 77552020
         SPACE 1                                                 A25573 77560019
BGNCACOM DC    A(IHKCACOM)         ADDRESS OF RJE AVT                   77600018
         DC    A(IHKBBRII)         ADDRESS OF R/I INTERFACE MOD         78000018
RDRECB   DC    A(IHKCBRDP)         ADDRESS OF READER'S ECB FOR          78400018
*                                  R/I INTERFACE                        78800018
BGNMSG   DC    X'FFFFFFFF'         INDICATE RETURN                      79200018
         DC    X'00'               PAD                                  79600018
MSGOFF   DC    X'00'               OFFSET OF MSG IN DIRECTORY           80000018
MSGLNG   DC    X'00'               LENGTH OF VARIABLE TEXT              80400018
IHKRJE   DC    CL8'IHKRJE'                                              80800018
R$       DC    CL2'R$'                                                  81200018
BGNCHUCK DC    CL8'IHKCHUCK'                                            81600018
BGNCBNIP DC    CL8'IHKCHNIP'                                            82000018
CLOSE    EQU   X'05'               MASK FOR RETURN FROM READER          82400018
SUPRMODE EQU   X'1F'                                                    82800018
PPMODE   EQU   X'7F'                                                    83200018
BGNQMPRM DC    A(BGNECB)                                                83600018
BGNCDQMG DC    A(IHKCDQMG)         ECBLIST FOR QMNGR                    84000018
BGNECB   DC    F'0'                ECB POSTED BY QMNGR                  84400018
IHKBGNIN DS    0F                  THE NEXT 2 ECBS ARE DSECTED   A24702 84500019
         ENTRY IHKBGNIN              IN THE RJE DISPATCHER       A24702 84600019
BGNTCB   DC    F'0'                TCB FOR QMNGR                        84800018
BGNF     DC    X'FFFFFFFF'         INICATE RETURN TO IHKQMNGR           85200018
BGNQMECB DC    F'0'                ECB POSTED WHEN IHKQMNGR             85600018
*                                  COMPLETES                            86000018
VH1ECB   DC    F'0'                ECB POSTED WHEN R/I COMPLETES        86400018
VH1TCB   DC    F'0'                TCB FOR R/I                          86800018
         EXTRN      IHKCACOM                                            87200018
         EXTRN IHKCDQMG                                                 87600018
         EXTRN IHKBBRII                                                 88000018
         EXTRN IHKCBRDP                                                 88400018
CPL      EQU   *                                                        88460020
ECB      DC    A(0)                                                     88520020
ACIB     DC    A(0)                                                     88580020
CIB      DSECT                                                          88640020
         IEZCIB                                                         88700020
     IHKDSECT  ,,,,,AVT                                                 88800018
         END                                                            89200018
