IKACKXT  CSECT                                                          00600016
         EJECT                                                          00610016
*********************************************************************** 00620016
*                                                                       00630016
* MODULE NAME           -IKACKXT                                        00640016
*                                                                       00650016
* CHART ID              -DA                                             00660016
*                                                                       00670016
* FUNCTION              - HANDLE INTERRUPTS FROM A 2250                 00680016
*                        LOGICALLY CONNECTED TO THE GRAPHIC JOB         00690016
*                       -PROCESSOR                                      00700016
*                                                                       00710016
* ATTRIBUTES            -SERIALLY REUSABLE                              00720016
*                                                                       00730016
* ENTRY POINTS          -IKACKXT FROM IOS(FLIH)                         00740016
*                                                                       00750016
* OPERATION             -THIS ROUTINE CAN BE ENTERRED FROM IOS WHEN     00760016
*                        AN INTERRUPT IS RECEIVED FROM A 2250 LOGICALLY 00770016
*                        CONNECTED TO GJP ( A USER HITS CANCEL KEY ON   00780016
*                        A 2250 WHICH IS NOT ACTIVE BUT HAS BEEN GVARY  00790016
*                        ON) OR A CANCEL KEY INTERRUPT IS RECEIVED      00800016
*                        FROM A PROBLEM PROGRAM STARTED THROUGH GJP     00810016
*                        (USER IS IN A LOOP ETC.) IN EITHER CASE THE    00820016
*                        OCT ENTRY PCD FOR THE 2250 WILL BE FOUND AND   00830016
*                        THE APPROPRIATE BITS SET IN THE RCD. A POSTING 00840016
*                        OF THE ECB ASSOCIATED WITH THE 2250 WILL TAKE  00850016
*                        CORRECT INPUT. UPON RETURN FROM THE POST RTN   00860016
*                        A RETURN TO IOS IS MADE                        00870016
*                                                                       00880016
* EXITS                 -RETURN                                         00890016
*                                                                       00900016
* INPUT                 -REGISTER 1 CONTAINS THE UCB ADDRESS OF THE     00910016
*                        2250.                                          00920016
*                             BIT 0=0 INITIAL CANCEL                    00930016
*                             BIT 0=1 CANCEL FROM DSER PROGRAM          00940016
*                                                                       00950016
* OUTPUT                -SAME AS INPUT                                  00960016
*                                                                       00970016
* EXTERNAL REFERENCES   -NONE                                           00980016
*                                                                       00990016
* TABLES                -OVERALL CONTROL TABLE                          01000016
*                                                                       01010016
* WORKAREAS             -NONE                                           01020016
*                                                                       01030016
* ERROR CONDITIONS      -NONE                                           01040016
*                                                                       01050016
*********************************************************************** 01060016
         TITLE 'CANCEL EXIT ROUTINE'                                    01200016
* REGISTER EQUATES                                                      01800016
*                                                                       02400016
*                                                                       03000016
RPAR0    EQU   0                                                        03600016
RPAR1    EQU   1                                                        04200016
R2       EQU   2                                                        04800016
R3       EQU   3                                                        05400016
R4       EQU   4                                                        06000016
R5       EQU   5                                                        06600016
R6       EQU   6                                                        07200016
R7       EQU   7                                                        07800016
RBASE    EQU   8                                                        08400016
R9       EQU   9                                                        09000016
R10      EQU   10                                                       09600016
R11      EQU   11                                                       10200016
R12      EQU   12                                                       10800016
RSAVE    EQU   13                                                       11400016
RRET     EQU   14                                                       12000016
RBR      EQU   15                                                       12600016
RUNBOFF  EQU   X'DF'                    TURN JOB RUNNING BIT OFF        12900016
         EJECT                                                          13200016
         USING *,RBR                    USE REG 15 AS A BASE            13800016
         ST    RSAVE,SAVEAREA+4         SAVE ADDRESS OF SAVE AREA       15000016
         LA    RSAVE,SAVEAREA           SET UP THIS SAVE AREA           15600016
         STM   RRET,R12,12(RSAVE)       SAVE INPUT REGISTERS            16200016
         ST    RSAVE,8(RSAVE)           ADDRESS OF THIS SAVE AREA       16800016
         DROP  RBR                                                      17400016
         BALR  RBASE,0                  ESTABLISH NEW BASE              18000016
         USING *,RBASE                       REGISTER                   18600016
         LR    R2,RPAR1                 SAVE INPUT INFO                 19200016
         USING GFXUCB,RPAR1             ADDRESSABILITY FOR UCB          19800016
***                                                                     21000016
*        CHECK  CVT FIELD TO SEE IF GFX IS ACTIVE                       21600016
***                                                                     22200016
         L     R6,16(0,0)               ADDRESS OF CVT                  22800016
         USING GFXCVT,R6                ESTABLISH ADDRESSABILITY        23400016
         L     R3,CVTQOCR               GFX PARAM LIST ADDRESS          24000016
         LTR   R3,R3                  Q.WAS GFX INITIALIZED             24600016
         BZ    EXITOUT                  NO,BRANCH                       25200016
         L     R3,0(R3)                 ADDRESS OF OCT                  25800016
         LR    R4,R3                   SAVE HEADER ADDRESS              26100016
         USING GFXOCTHD,R3              ADDRESSABILITY FOR OCT HDR RCD  26400016
         L     R7,OCTUNBR               NUMBER OF SYSGENED 2250'S       27000016
         LA    R3,GFXHDSZE(R3)          INCREMENT TO FIRST 2250 RECOR   27600016
         USING GFXOCTEN,R3              ADDRESSABILITY FOR IT           28200016
         N     RPAR1,MASK1              SET HIGH ORDER BYTE OFF         28800016
UCBLOOP  CL    RPAR1,OCTUCB           Q.IS THIS THE 2250 RECORD         29400016
         BE    SETBITS                  YES,BRANCH                      30000016
         LA    R3,GFXENSZE(R3)          NO,BUMP TO NEXT ENTRY RECORD    30600016
         BCT   R7,UCBLOOP               BRANCH IF MORE TO CHECK         31200016
         B     EXITOUT                       PREPARE TO LEAVE           32400016
SETBITS  LTR   R2,R2                  Q.IS THIS A INITIAL CANCEL(PLUS)  33000016
         BM    USERPGM                  NO,BRANCH                       33600016
         TM    OCTATTR1+1,OCTBCANC    Q. WAS INIT. CANCEL RECEIVED      33800016
         BO    EXITOUT                                                  34000016
         OI    OCTATTR3+1,OCTBCANI      YES,TURN ON INITIAL CANC POST   34200016
         B     POSTECB                  SET TO POST ECB                 34800016
USERPGM  TM    OCTATTR1,OCTBACTV      Q.THIS 2250 STARTED(GVARY)        35400016
         BZ    EXITOUT                  NO,RETURN                       37400016
         NI    OCTATTR1,RUNBOFF         SET JOB NOT RUNNING             39400016
SETPOST  OI    OCTATTR3+1,OCTBCANP      TURN ON USER PGM CANCEL BIT     41400016
***                                                                     41480016
* SET UP REGISTERS FOR A BRANCH TO THE POST ROUTINE                     41560016
***                                                                     41640016
POSTECB  EQU   *                                                        41720016
         SR    R10,R10                 ZERO OUT COMPLETION CODE         41800016
         LA    R11,OCTECB              ECB TO BE POSTED ADDRESS         41880016
         USING  GFXOCTHD,R4                                             41960016
         L     R12,OCTGTCB             TCB ADDRESS OF GFX               42040016
         DROP  R4                                                       42120016
         LR    R5,RSAVE                SAVE SAVE AREA ADDRESS           42200016
         L     RBR,CVT0PT01             ADDRESS OF POST ROUTINE         42280016
         BALR  RRET,RBR                EXECUTE POST                     42360016
         LR    RSAVE,R5                RESTORE SAVE AREA ADDRESS        42440016
EXITOUT  LM    RRET,R12,12(RSAVE)       RESTORE INPUT REGISTERS         42600016
         L     RSAVE,4(RSAVE)           RESTORE ORIGINAL SAVE AREA PNTR 43200016
         DROP  RBASE                                                    43800016
         USING IKACKXT,RBR              NEW BASE                        44400016
         BR    RRET                     RETURN TO GRAPHIC IOS           45600016
         EJECT                                                          46200016
         DS    0D                                                       46800016
SAVEAREA DC    18F'0'                   SAVE AREA                       47400016
MASK1    DC    X'00FFFFFF'                                              48000016
         EJECT                                                          49800016
GFXUCB   DSECT                                                          50400016
FILL1    DS    CL13                                                     51000016
UCBNAME  DS    CL3                                                      51600016
FILL2    DS    CL11                                                     52200016
GCB      DS    CL1                                                      52800016
FILL3    DS    CL12                                                     53400016
         EJECT                                                          54000016
GFXCVT   DSECT                                                          54600016
         CVT                                                            55200016
         EJECT                                                          55800016
GFXOCTHD DSECT                                                          56200016
GFXHDSTR EQU   *                       START OF HEADER RECORD           56600016
OCTSYS   DS    CL1                     BASE SYSTEM                      57000016
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                57400016
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          57800016
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       58200016
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       58600016
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              59000016
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              59400016
         DS    0H                                                       59800016
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             60200016
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       60600016
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       61000016
         DS    0F                                                       61400016
OCTFGREG DS    CL4                      REGION SIZE GJP                 61800016
OCTFUREG DS    CL4                      REGION SIZE USER FGD            62200016
OCTBUREG DS    CL4                      REGION SIZE USER BGD            62600016
OCTGTCB  DS    CL4                     TCB ADDRESS OF GFX               63000016
OCTHRES  DS    CL4                     RESERVED                         63400016
OCTNAME  DS    CL20                     PROGRAMMER NAME                 63800016
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  64200016
GFXHDEND EQU   *                       END OF HEADER RECORD             64600016
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        65000016
         EJECT                                                          65400016
GFXOCTEN DSECT                                                          65800016
         DS    0F                                                       66200016
GFXENSTR EQU   *                       START OF ENTRY RECORD            66600016
OCTECB   DS    CL4                      ECB                             67000016
OCTUCB   DS    CL4                      UCB ADDRESS                     67400016
OCTUNIT  DS    CL4                      UNIT ADDRESS                    67800016
OCTCOUNT DS    CL4                      JOB COUNT                       68200016
OCTNOTE  DS    CL4                      NOTE                            68600016
OCTABEND DS    A                       ABEND CODE                       69000016
OCTRESD  DS    CL8                      RESERVED                        69400016
**********************************************************************  69800016
****                          ATTRIBUTE 1                          **** 70200016
**********************************************************************  70600016
OCTATTR1 DS    CL2                      ATTRIBUTES                      71000016
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         71400016
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   71800016
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         72200016
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       72600016
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   73000016
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  73400016
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  73800016
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           74200016
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          74600016
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   75000016
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           75400016
**********************************************************************  75800016
****                          ATTRIBUTE 2                          **** 76200016
**********************************************************************  76600016
OCTATTR2 DS    CL2                      ATTRIBUTES                      77000016
OCTNUSED EQU   X'80'          0-                  1-                    77400016
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      77800016
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              78200016
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           78600016
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         79000016
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           79400016
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       79800016
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            80200016
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  80600016
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  81000016
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        81400016
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         81800016
**********************************************************************  82200016
****                          ATTRIBUTE 3                          **** 82600016
**********************************************************************  83000016
OCTATTR3 DS    CL2                      ATTRIBUTES                      83400016
OCTBCANM EQU   X'80'          0-                  1-                    83800016
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      84200016
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              84600016
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           85000016
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         85400016
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           85800016
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       86200016
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            86600016
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  87000016
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  87400016
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        87800016
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         88200016
**********************************************************************  88600016
****                          ATTRIBUTE 4                          **** 89000016
**********************************************************************  89400016
OCTATTR4 DS    CL2                      ATTRIBUTES                      89800016
GFXENEND EQU   *                       END OF ENTRY RECORD              90200016
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             90600016
         END                                                            94800016
