         TITLE 'IKACTL FOR IKAGJP'                                      00300016
*                        CONTROL ROUTINE                                00600016
*                                                                       00900016
*                                                                       01200016
*  ROUTINE NAME     IKACTL                                              01500016
*                                                                       01800016
* CHART ID          EB                                                  02100016
*                                                                       02400016
*  FUNCTION:         PERFORM CONTROL FUNCTION FOR COMMAND PROCESSING    02700016
*                    ROUTINES AND FOR THE CONSOLE SUPORT ROUTINES       03000016
*                    BETWEEN USER JOBS                                  03300016
*                                                                       03600016
*  ATTRIBUTES:       RESIDENT, REENTERABLE                              03900016
*                                                                       04200016
* ENTRY POINTS      IKACTL                                              04600016
*                                                                       05100016
*  OPERATION:        GIVES CONTROL TO DGM WHICH WILL GENERATE GRAPHIC   05400016
*                    DISPLAY                                            05700016
*                    SCAN RETURN CODE PASSED BY COMMAND PROCESSORS      06000016
*                    TO DETERMINE WHETHER TO GIVE CONTROL TO COMMAND    06300016
*                    PROCESSOR ROUTINES OR COMMAND SELECT ROUTINE       06600016
*                    TURN ON COMMAND SELECT MODE IN CCT BEFORE DISPLAY  06900016
*                    COMMAND SELECT TABLE AND TURN OFF COMMAND SELECT   07200016
*                    MODE IN CCT BEFORE DISPLAY COMMAND PARAMETER TABLE 07500016
*                    UPDATE COMMAND SELECT MASK IN CCT AFTER RECEIVE    07800016
*                   CONTROL FROM PROCESSORS                             08200016
*                   WHEN RETURN CODE FROM PROCESSOR IS X'08', AND IT IS 08260016
*                   FOREGROUND JOB, INFORM GFX, FREE CCT AND RETURN TO  08320016
*                   OPERATING SYSTEM. IF IT IS BACKGROUND JOB, IT WILL  08380016
*                   REINITIATES JCL DCB, POINT THE FIRST BLOCK OF       08440016
*                   EXTRACT AND DIARY DATA SET, AND TURN OFF BACKGROUND 08500016
*                   SWITCH IN CCT, UPDATE SELECT MASK, AND DISPLAY      08560016
*                   COMMAND SELECT FRAME.                               08620016
*                                                                       08700016
*  EXITS:            RETURN                                             09000016
*                                                                       09300016
* INPUT             REGISTER 1 POINTING TO CONSOLE CONTROL TABLE        09400016
*                                                                       09500016
*                   REGISTER 13 POINTING TO A REGISTER SAVE AREA        10000016
*                                                                       10100016
*                   REGISTER 14 RETURN ADDRESS                          10200016
*                    RETURN CODE COMMAND PROCESSORS.                    10500016
*                    RETURN CODE WILL BE REGISTER 15, AND HAS THE       10800016
*                    FOLLOWINH DEFINITION                               11100016
*                                                                       11400016
*                   *****************************************           11600016
*                   '  CODE  '  MEANING                     '           11800016
*                   *****************************************           12000016
*                   '    0   ' NORMAL COMPLETION            '           12200016
*                   '    4   ' REDISPLAY PREVIOUS PST FRAME '           12400016
*                   '    8   ' RETURN CODE FROM IKASCH      '           12600016
*                   '   12   ' REDISPLAY PREVIOUS CST FRAME '           12800016
*                   '   16   ' RETURN CODE FROM LOF OFF     '           12900016
*                   *****************************************           13000016
*                                                                       13200016
*  OUTPUT:           UPDATED CONSOLE CONTROL TABLE                      14100016
*                                                                       14400016
*  EXTERNAL REFERENCE: COMMAND PROCESSORS                               14700016
*                      COMMAND SELECT ROUTINE                           15000016
*                      DISPLAY GENERATION AND MANIPULATION              15300016
*                                                                       15600016
*  ERROR CONDITION:    RETURN CODE NOT DEFINED                          15900016
*                                                                       16200016
*  TABLE AND WORKAREA: CONSOLE CONTROL TABLE                            16500016
*                      COMMAND SELECT TABLE                             16800016
*                      PARAMETER SELECT TABLE                           17100016
*                                                                       17400016
*                                                                       17700016
*                                                                       18000016
         EJECT                                                          18100016
         SPACE                                                          18200016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         18300016
         SPACE                                                          18400016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    18500016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     18600016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       18700016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             18800016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  18900016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  19000016
*                   SET.                                                19100016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      19200016
*                   SECOND.                                             19300016
         SPACE 2                                                        19400016
CCT      DSECT                                                          19500016
         SPACE 2                                                        19600016
*                             SECTION ONE                               19700016
         SPACE                                                          19800016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     19900016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    20000016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  20100016
         SPACE                                                          20200016
         DS    0F                                                       20300016
CCTUNAME DS    5F                  USER'S NAME                          20400016
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         20500016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     20600016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       20700016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    20800016
*                                       AT LAST BEGIN JOB               20900016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   21000016
*                                       LAST BEGIN JOB                  21100016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 21200016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    21300016
*                                       JOB                             21400016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    21500016
*                                       JOB                             21600016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     21700016
*                                       CESSOR                          21800016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         21900016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         22000016
CCTJCTR  DS    H                   JOB COUNTER                          22100016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                22200016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   22300016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  22400016
CCTSSTAT DS    C                   SESSION STATUS                       22500016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              22600016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              22700016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    22800016
         EJECT                                                          22900016
         SPACE 2                                                        23000016
*                             SECTION TWO                               23100016
         SPACE                                                          23200016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   23300016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  23400016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 23500016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              23600016
         SPACE                                                          23700016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     23800016
*                                       FRAME                           23900016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  24000016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     24100016
*                                       MULTIPLE DISPLAY FRAME (ENT)    24200016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   24300016
CCTDISM  DS    C                   DISPLAY MASK                         24400016
CCTCSM   DS    C                   COMMAND SELECT MASK                  24500016
CCTPSTAT DS    CL2                 GJP STATUS                           24600016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              24700016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  24800016
         SPACE 2                                                        24900016
*                             SECTION THREE                             25000016
         SPACE                                                          25100016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    25200016
*                   INTO SECTION ONE OR TWO                             25300016
         SPACE                                                          25400016
CCTDGMP  DS    F                  POINTER TO DGM                        25500016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                25600016
CCTCSTP  DS    F                  POINTER TO CST                        25700016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                25800016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            25900016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 26000016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              26100016
CCTDIARP DS    F                  POINTER TO DIA                        26200016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      26300016
CCTACTP  DS    F                  POINTER TO ACT                        26400016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     26500016
CCTIERRP DS    F                  POINTER TO IERR                       26600016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              26700016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               26800016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                26900016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 27000016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 27100016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   27200016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                27300016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                27400016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               27500016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              27600016
CCTPECB  DS    F                  PROCESSOR'S ECB                       27700016
CCTWECB  DS    F                  WTOR ECB                              27800016
CCTDIAWA DS    CL136               DIARY WORK AREA                      27900016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    28000016
CCTCSAVE DS    CL72                CTL SAVE AREA                        28100016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                28200016
CCTASAVE DS    CL72                DAT SAVE AREA                        28300016
         EJECT                                                          32500016
IKACTL   CSECT                                                          32700016
*0829,795800                                                       PDUM 32800017
*2452,699720,701040,733400                                         IIXX 32900018
*3265,700860-700980                                                EXTR 32920019
*3294,753000                                                       7777 32940019
*                                                                  7777 32960019
RPAR0    EQU   0                   PARAMETER                            33000016
RPAR1    EQU   1                   PARAMETER                            33300016
RCCT     EQU   2                   CCT ADDRESS REGISTER                 33600016
RCANCEL  EQU   3                   CANCEL REGISTER                      33900016
RMSGDLY  EQU   4                                                        34200016
RSADR    EQU   5                                                        34500016
RONE     EQU   6                   REGISTER CONTAINS ONE                34800016
RPOINTER EQU   7                   POINTER PROCESSOR'S ADDRESS          35100016
RCKEY    EQU   8                   COMMAND KEY REGISTER                 35400016
RWORK1   EQU   9                        GENERNAL PURPOSE REGISTER       35700016
RBASE    EQU   10                                                       36000016
RWORK    EQU   11                                                       36300016
RDISPLMT EQU   12                                                       36600016
RSAVE    EQU   13                  SAVE AREA ADDRESS REGISTER           36900016
RRET     EQU   14                  RETURN REGISTER                      37200016
RBR      EQU   15                  BRANCH REGISTER                      37500016
SUPLIST  EQU   336                 SUP-PARAMETER DISPLACEMENT           37800016
PROCADDR EQU   344                PROCESSOR WORK AREA DISPLACEMENT      38100016
JOBCOUNT EQU   8                       RELATIVE ADDR OF JOBCOUNT        38160016
EXTNOTE  EQU   12                       RELATIVE ADDR OF NOTE FIELD     38220016
FBCKGRND EQU   16                       RELATIVE ADDR OF BACK OR FORE   38280016
*                                       GROUND JOB ADDRESS              38340016
D2250    EQU   5                       RELATIVE ADDR OF 2250            38370016
*                                                                       38400016
* HOUSE KEEPING                                                         38700016
*                                                                       39000016
         SAVE  (2,12)                  SAVE REGISTERS                   39300016
         BALR  RBASE,0             SET UP BASE                          39600016
         USING *,RBASE                                                  39900016
         LR    RCCT,RPAR1                                               40200016
         USING CCT,RCCT                                                 40300016
         ST    RSAVE,CCTCSAVE+4         SAVE CALLING SAVE               40560016
         LA    RSADR,CCTCSAVE           LOAD OUR SAVE ADDRESS           40620016
         ST    RSADR,8(0,RSAVE)         AND GIVE IT TO CALLING PROGRAM  40680016
         LA    RSAVE,CCTCSAVE           POINTER TO OUR SAVE ADDRESS     40740016
         LA    RPOINTER,CCTPWKA+PROCADDR LOAD PROCESSOR ADDRESS         40840016
         CLC   CCTCCR(3),LOGN          Q, IS LOGON TIME                 41040016
         BE CCLEAR                      BRANCH TO CCLEAR IF YES         41400016
         CLC   CCTCCR(3),BEG           Q. US BEGIN JOB TIME             41800016
         BE    CSMODE                   BRANCH TO CSMODE IF YES         42300016
*                                                                       42360016
* BRANCH TO INTERNAL ERROR ROUTINE  AND TERMINATE JOB                   42420016
*                                                                       42480016
GOIERR   EQU   *                                                        42540016
         LR    1,RCCT                  CCT ADDRESS                      42600016
         LA    0,IERRPAR               MESSAGE PARAMETER TO IERR        42660016
         L     15,CCTIERRP             IERR ADDRESS                     42720016
 BALR    RRET,RBR                       GO TO IERR                      43720016
         LR    RPAR0,RBR               SET TERMINATE GJP CODE IN        44720016
*                                      REGISTER 1                       45720016
         B     FASTSTOP                 BRANCH                          46720016
CCLEAR   MVI   CCTPECB,X'00'                                            51300016
         B     CDGMPST                 BRANCH                           51600016
         EJECT                                                          52000016
*                                                                       52200016
* SCAN CST AND UPDATE COMMAND SELECT MASK IN CCT                        52500016
*                                                                       52800016
CSELMASK CLC   CCTCCR(3),LOGN          Q. IS LOGON SELECTED             52900016
         BNE   BEGSCAN                  BRANCH IF YES                   53000016
         MVI   CCTCSM,X'01'             SET SELECT MASK                 53100016
         B     CSMODE                   BRANCH                          53200016
BEGSCAN  L     RWORK,CCTCSTP            LOAD CST ADDRESS                53300016
CSCAN    CLI   0(RWORK),X'00'     IS LENGTH EQUAL TO ZERO               53400016
         BE    GOIERR                  BRANCH IF YES                    53800016
         CLC   12(3,RWORK),CCTCCR       IS THIS ONE SELECTED            54300016
         BNE   CONTINUE            NO, CONTINUE SCANE                   54900016
         MVC   CCTCSM(1),6(RWORK)       UPDATE COMMAND SELECT MASK -CCT 55500016
         B     CSMODE                                                   56100016
CONTINUE SR    RDISPLMT,RDISPLMT  CLEAR REGISTER                        57000016
         IC    RDISPLMT,0(RWORK)   SET DISPLACEMENT                     57300016
         AR    RWORK,RDISPLMT      UPDATE RWORK                         57600016
         B     CSCAN              CONTINUE  SCAN                        57900016
         EJECT                                                          61900016
*                                                                       62100016
* UPDATE COMMAND SELECT MODE DISPLAY CST AND LINK TO IKAPCSR            62400016
*                                                                       62700016
CSMODE   OI    CCTPSTAT+1,X'80'  COMMAND SELECT MODE                    63000016
         MVC   CCTADISM(1),CCTDISM     UPDATE DISPLAY MASK OF           63100016
*                                      PREVIOUS OPERATION               63200016
         LR    RPAR1,RCCT          LOAD CCT ADDRESS                     63300016
         L     RBR,CCTDGMP              LOADS DGM ADDRESS               63600016
         TM    CCTPSTAT+1,X'40'       Q.MESSAGE SWITCH ON               63900016
         BC    1,CDGMNPLY          YES BRANCH TO CDGMNPLY               64200016
         BALR  RRET,RBR            BRANCH DGM TO DISPLAY CST            64500016
         B     CCSR                                                     64800016
         DC    X'C000'             START GENERATE PST OR CST            65100016
CCSR     EQU   *                                                        65200016
         C     RBR,CODE1C              Q. ENTERRED IERR                 65300016
         LR    RPAR0,RBR               SET TERMINATE GJP CODE IN        65330016
*                                      REGISTER 1                       65360016
         BE    FASTSTOP                BRANCH IF YES                    65400016
         LA    RCKEY,CSR               LOAD CSR ADDRESS                 65500016
         BAL   RSADR,CMODEL       BRANCH TO MODULE LINKED TO            65700016
         NI    CCTPSTAT+1,B'01111111' TURN OFF COMMAND SELECT MODE      66000016
         SR    RONE,RONE                 CLEAR REGISTER                 66300016
         C     RONE,CCTCPSTP             IS AN ADDRESS IN CCTCPSTP      66600016
         BE    CPROCR                    NO LINK TO PROCESSOR           66900016
*                                                                       67200016
* DISPLAY PST AND LINK TO PROCESSOR                                     67500016
*                                                                       67800016
CDGMPST  EQU   *                                                        67900016
         L     RBR,CCTDGMP              GDM ADDRESS                     68100016
         LR    RPAR1,RCCT         LOAD CCT ADDRESS                      68400016
         BALR  RRET,RBR            BRANCH TO DGM TO GENERATE PST        68700016
         B     CPROCR                                                   69000016
         DC    X'C000'             START GENERATE PST OR CST            69300016
CPROCR   EQU   *                                                        69400016
         C     RBR,CODE1C              Q. ENTERRED IERR                 69500016
         LR    RPAR0,RBR               SET TERMINATE GJP CODE IN        69550016
         BE    FASTSTOP                BRANCH IF YES                    69600016
         LA    RCKEY,CCTCCR            MODULE KEYWORD ADDRESS           69700016
         BAL   RSADR,CMODEL       BRANCH TO MODULE LINKED TO            69900016
         C     RBR,LOGOFF              Q. LOGOFF TIME                   69902016
         BE    CRETURN                 BRANCH IF YES                    69904016
*                                                                       69906016
* CHECK OCT IF OPERATOR ISSUE MEDIUM OR FAST STOP                       69912016
*                                                                       69918016
RCVT     EQU   3                        BASE FOR CVT                    69924016
ROCT     EQU   4                        BASE FOR OCT                    69930016
RGFXLIST EQU   6                        BASE FOR GFXLIST                69936016
ROCTENT  EQU   9                                                        69942016
RENTCTR  EQU   11                      COUNTER                          69948016
CKSTOP   EQU   *                                                        69954016
         L     RCVT,X'10'                CVT ADDR                       69960016
         USING CVT,RCVT                                                 69966016
         L     RGFXLIST,CVTQOCR         OCT POINTER                IIXX 69969018
         LTR   RGFXLIST,RGFXLIST        Q. GFX PRESENT             IIXX 69972018
         BZ    FSTOP                    NO                         IIXX 69975018
         USING GRAPLIST,RGFXLIST                                        69978016
         L     ROCT,GOCT                 OCT ADDRESS                    69984016
         USING GFXOCTHD,ROCT                                            69990016
         MVC   SAVEBPRI(2),OCTBPRI      SAVE ORIGIN BACKGROUND PRIOPDUM 69993017
         LA    ROCTENT,GFXHDSZE+GFXHDSTR OCT RECORD ENTRY               69996016
         USING GFXOCTEN,ROCTENT                                         70002016
         LH    RENTCTR,OCTUNBR           OCT RECORD NUMBER              70008016
ENTSEACH EQU   *                                                        70014016
         CLC   CCTUNIT(3),OCTUNIT+1     Q. THIS OCT NEEDED              70020016
         BE    STOP                       BRANCH IF YES                 70026016
         LA    ROCTENT,GFXENSTR+GFXENSZE  UPDAT ENTRY                   70032016
         BCT   RENTCTR,ENTSEACH           BRANCH                        70038016
NOTFOUND EQU   *                                                        70044016
         LA    RPAR0,MSG11             MSG PARAMETER ADDRESS            70046016
         LR    RPAR1,RCCT               CCT ADDRESS                     70048016
         L     RBR,CCTIERRP             IERR ROUTINE ADDRESS            70050016
         BALR  RRET,RBR                 GO TO IERR                      70051016
         LR    RPAR0,RBR               SET TERMINATE GJP CODE IN        70052016
*                                      REGISTER 1                       70053016
         B     FASTSTOP                 BRANCH                          70054016
STOP     EQU   *                                                        70056016
         TM    OCTATTR2,X'08'          Q. MEDIUM STOP                   70062016
         BO    MSTOP                    BRANCH IF YES                   70068016
         DROP  3,4,6,9                  DROP BASES                      70074016
CKFSTOP  EQU   *                                                        70080016
         L     RONE,CCTTIME             PTR TO COMM. PARM. LIST    EXTR 70086019
         L     RONE,0(RONE)             POINTER TO ECB             EXTR 70092019
         TM    0(RONE),X'10'          Q. FAST STOP                 EXTR 70098019
         BO    FSTOP                    YES                        IIXX 70104018
         B     BRANCHT                 NORMAL PROCESSING IF NO          70110016
MSTOP    LA    15,12                    RESET RETURN CODE               70116016
         MVI   CCTCSM,X'08'             SET LOGOFF DISPLAY MASK         70122016
         MVI   CCTPSTAT+1,X'40'         TURN ON MSG SWITCH              70128016
         LA    3,CCTPWKA+8              *                               70134016
         ST    3,CCTPWKA                * SET LOGOFF                    70140016
         LA    3,CCTPWKA+50             * MESSAGE                       70146016
         ST  3,CCTPWKA+4                *                               70152016
         MVI   CCTPWKA,X'40'            *                               70158016
         MVI   CCTPWKA+4,X'C0'          *                               70164016
         MVC   CCTPWKA+8(15),TITLE      *                               70170016
         MVC   CCTPWKA+50(44),LOGMSG    *                               70176016
BRANCHT  EQU   *                                                        70182016
         B     CRETABLE(RBR)      BRANCH TO RETURN CODE TABLE           70200016
CDGMPST1 EQU   *                                                        70250016
         CLC   CCTCCR(3),ENT           Q. ENTER DATA                    70300016
         BNE   CDGMPST                  BRANCH IF NO                    70350016
         MVI   CCTCSM,X'26'             UPDATE SELECT MASK IF YES       70400016
         B     CDGMPST                  BRANCH                          70450016
FSTOP    L     RPAR0,CODE1C             INDICATE TERMINATION       IIXX 70451018
FASTSTOP EQU   *                                                        70453016
         MVC   0(8,RPOINTER),SCHMOD    MODULE NAME                      70456016
         LR    RPAR1,RCCT              CCT ADDRESS                      70459016
         O     RPAR1,HBITON            SINGNAL LOGOFF TIME              70462016
         BAL   RSADR,LKSCH             LINK TO IKASCH                   70465016
         SR    RWORK,RWORK             ZERO REGISTER TO TEST IF THERE   70468016
         C     RWORK,CCTCPSTP          A PST IN CORE                    70471016
         BE    CRETURN                 NO, PLEASE BRANCH                70474016
         LA    RWORK1,CCTPWKA+8        A ADDRESS IN WORKAREA            70477016
         MVC   0(8,RWORK1),PSTABLE     MOVE TABLE MODEL IN WORKAREA     70480016
         MVC   4(3,RWORK1),CCTCCR      YES, MOVE MODULE'S KEY WORD      70483016
         DELETE EPLOC=(RWORK1)         DELETE THIS TABLE                70486016
         B     CRETURN                 BRANCH                           70489016
*                                                                       70500016
* RETURN CODES FROM PROCESSOR                                           70800016
*                                                                       71100016
CRETABLE EQU   *                                                        71400016
         B     CSELMASK           NORMAL CONDITION                      71700016
         B     CDGMPST1            REDISPLAY LAST PARAMETER TABLE       71900016
         B     FRORBACK                 BRANCH TO FRORBACK TO TEXT IF   72200016
*                                       FOREGROUND OR BACKGROUND JOB    72400016
         B     CSMODE              DISPLAY LAST SELECT TABLE            72600016
         B     CRETURN                 LOG OFF TIME                     73000016
         B     CSMODE                  DISPLAY LAST SELECT FRAME        73200016
         DS    XL4'0'                  DUMMY                            73270016
         B     FSTOP                    MUST TERMINATE CONDITION   IIXX 73340018
*                                      CLEAR CORE AND RETURN TO 0/S     73410016
CDGMNPLY BALR  RRET,RBR            BRANCH TO DGM                        73500016
         B     CMSG                                                     73800016
         DC    X'4000'                  GENERATE BUT DO NOT DISPLAY     74100016
         EJECT                                                          74200016
*                                                                       74400016
* BRANCH TO MESSAGE ROUTINE AND DISPLAY MESSAGE                         74700016
*                                                                       75000016
CMSG     EQU   *                                                   7777 75100019
         C     RBR,CODE1C            Q. IERR ENTERED               7777 75200019
         BE    FSTOP                    BRANCH IF YES              7777 75300019
         L     RBR,CCTDMRP              POINTER TO MSG             7777 75400019
         LR    RPAR1,RCCT         LOAD CCT ADDRESS                      75600016
         LA    RPAR0,CCTPWKA      LOAD PROCESSOR'S WORKAREA ADDRESS     75900016
         BALR  RRET,RBR                                                 76200016
         C     RBR,CODE1C              Q. IERR ENTERRED                 76300016
         LR    RPAR0,RBR               SET TERMINATE GJP CODE IN        76330016
*                                      REGISTER 1                       76360016
         BE    FASTSTOP                BRANCH IF YES                    76400016
         NI    CCTPSTAT+1,B'10111111' TURN MESSAGE SWICTH OFF           76500016
         B     CCSR                                                     76800016
CMODEL   MVC   0(8,RPOINTER),PROMODEL  MOVE MODEL IN CCTPWKA            77100016
         MVC  4(3,RPOINTER),0(RCKEY)   MOVE COMMAND KEY IN CCTPWKA      77400016
         LR    RPAR1,RCCT          LOAD CCT ADDRESS                     77700016
LKSCH    EQU   *                                                        77800016
         LA    RBR,CCTPWKA+SUPLIST LOAD ADDR OF SUPERVISOR PARM-LIST    78000016
         MVI   0(RBR),X'00'        CLEAR THE AREA BEFOR LINK            78300016
         MVC   1(7,RBR),0(RBR)                                          78600016
         NI    CCTPSTAT+1,B'11011111' TURN OFF ATTENTION BITS           78900016
         L     0,CODE1C                                            PDUM 79000017
         LINK  EPLOC=(RPOINTER),MF=(E,(1)),SF=(E,(15))                  79200016
         BR RSADR                 GO BACK AND CONTINUE PROCESS          79500016
         EJECT                                                          79501016
FRORBACK EQU   *                                                        79506016
         MVC   CCTPWKA(LPARM),SVCPARM   MOVE PARM-LIST TO WORKAREA      79511016
         MVC   CCTPWKA+D2250(3),CCTUNIT *                               79511516
         LA    RWORK,CCTPWKA+200        A NUMBER                        79511716
         N     RWORK,DOUBLE             MAKE DOUBLE WORK BOJNDRY        79511916
         LH    RWORK1,CCTJCTR           JOB COUNTER IN BIARY            79512116
         CVD   RWORK1,0(RWORK)          CONVERT TO DECIMAL              79512316
         UNPK  CCTPWKA+72(5),5(3,RWORK) CONVERT TO EBDIC                79512516
         OI    CCTPWKA+76,X'F0'         CHANGE LOW ORDER ZONE           79512716
         MVC   CCTPWKA+JOBCOUNT(4),CCTPWKA+73 MOVE IN SVC PAR-LIST      79512916
         MVC   CCTPWKA+EXTNOTE(4),CCTENOTE * LIST                       79513116
         TM    CCTPSTAT,X'10'          Q. BACK GROUND JOB               79513416
         BC    1,BACKGRND              BRANCH IF YES                    79513716
         MVI   CCTPWKA+FBCKGRND,X'00'      * FOREGROUND JOB             79514016
SVC80    EQU   *                                                        79514116
         TM    CCTSSTAT,X'40'          Q. GJPEXT1 CURRENT EXT D. SET    79514216
         BZ    LDCCTADD                NO GO LOAD CCT ADDR              79514416
         OI    CCTPWKA+EXTNOTE+3,X'F0'  INFORM INIT WHICH D.S. TO READ  79514616
LDCCTADD LR    RPAR1,RCCT              LOAD CCT ADDRESS                 79514816
         LA    RPAR0,CCTPWKA            SVC PARAMETER LIST ADDRESS      79516016
         SVC   80                      ISSUE SVC                        79517016
         TM    CCTPSTAT,X'10'          Q. BACK GROUND JOB               79517316
         BC    1,BACKGD                BRANCH IF YES                    79517616
CRETURN  EQU   *                                                        79518016
         L     RSAVE,CCTCSAVE+4        LOAD CALLING PROGRAM SAVE ADDR   79519016
         LR    RPAR1,RCCT               CCT ADDRESS                     79520016
         SH    RPAR1,EIGHT              GETMAIN ADDRSS                  79521016
         L     RPAR0,0(RPAR1)           GETMAIN LENGTH                  79522016
         FREEMAIN R,LV=(0),A=(1)        FREE CORE                       79523016
CRETURN1 EQU   *                                                        79523516
         RETURN (14,12),RC=0            RETURN TO O/S                   79524016
BACKGRND EQU   *                                                        79524216
         MVI   CCTPWKA+FBCKGRND,X'FF'    CODE FOR BACKGROUND            79524416
         B     SVC80                   BRANCH                           79524616
         EJECT                                                          79525016
*                                                                       79526016
* THIS ROUTINE HANDLES USER'S BACKGROUND JOB                            79527016
*                                                                       79528016
BACKGD   EQU   *                                                        79529016
         MVI   CCTJDCBP,X'80'           OPTION BYTE FOR CLOSE           79530016
         LA    RPAR1,CCTJDCBP           LOAD PARAMETER ADDRESS          79531016
         CLOSE MF=(E,(1))               ISSUE CLOSE MACRO               79532016
         MVI   CCTJDCBP,X'83'           OPTION BYTE FOR OPEN            79533016
         LA    RPAR1,CCTJDCBP           LOAD PARAMETER ADDRESS          79534016
         OPEN  MF=(E,(1))               ISSUE OPEN MACRO                79535016
         MVI   CCTJDCBP,X'00'           CLEAR OPTION BYTE               79536016
         LA    RPAR0,NOTE1              NOTE NUMBER ADDRESS             79538016
         L     RPAR1,CCTEDCBP           DCB ADDRESS                     79540016
         POINT (1),(0)                  POINT TO FIRST RECORD           79541016
COFSWICH LOAD  EP=IKANUC                                                79552016
         LR    RDISPLMT,RPAR0           PASS PARAMETER                  79554016
         MVC   CCTDGMP(4),0(RDISPLMT)   DGM ADDRESS IN CCT              79556016
         L     RWORK1,CCTGACBP          GACB ADDR                       79558016
         MVC   CCTPWKA(LSPAR),SPAR      MAKE SPAR REENTERABLE           79558416
         LA    RPAR1,CCTPWKA            PARAMETER ADDRESS               79558816
         L     6,CCTGACBP               GACB ADDRESS                    79559216
         SPAR  ((6)),MF=(E,(1))         ISSUE SPAR MACR0                79559616
         MVC   16(4,RWORK1),4(RDISPLMT) DAT ADDR IN GACB                79560016
         MVC   CCTDMRP(4),8(RDISPLMT)   DMSG ADDR IN CCT                79562016
         MVC   CCTJCLGP(4),12(RDISPLMT) JCL GENERATOR ADDR IN CCT       79564016
         MVC   CCTDIARP(4),16(RDISPLMT) DIA ADDR IN CCT                 79566016
         MVC   CCTPKYM(4),20(RDISPLMT)  KYMANIP ADDR IN CCT             79568016
         MVC   CCTGEND(4),24(RDISPLMT)  SYSGEND ADDR IN CCT             79570016
         MVC   CCTDORP(4),28(RDISPLMT)  DOR ADDR IN CCT                 79572016
         MVC   CCTDIRP(4),32(RDISPLMT)  DIR ADDR IN CCT                 79574016
         LOAD  EP=IKAIERR              LOAD IERR IN CORE                79574616
         ST    RPAR0,CCTIERRP           STORE IN CCT                    79575216
         OI    CCTPSTAT,X'C0'          * REINTIALIZE CCTPSTAT           79576016
         NI    CCTPSTAT,X'CF'          *                                79578016
         NI    CCTDISM,X'10'           SAVE MASK FOR MFT SYSTEM    PDUM 79580017
         MVI   CCTCSM,X'21'                                             79582016
         MVC   CCTBRPRI(2),SAVEBPRI     RESET BACKGROUND PRIORITY  PDUM 79587017
         B     CSMODE                  BRANCH                           79592016
         EJECT                                                          79600016
*                                                                       79800016
* CONSTANT AREA                                                         80100016
*                                                                       80400016
         DS    0F                                                       80700016
PROMODEL DC    C'IKAP   0'                                              81000016
SCHMOD   DC    CL8'IKASCH  '           MODULE NAME                      81070016
PSTABLE  DC    CL8'IKAT   0'           TABLE MODEL                      81140016
HBITON   DC    X'80000000'             A SWITCH                         81210016
LOGOFF   DC    X'00000010'             MASK FOR SCH RETURN CODE         81250016
CSR      DC    C'CSR'                                                   81300016
LOGN     DC    C'LON'                                                   81600016
BEG      DC    C'BEG'                  KEY WORD OF BEHIN JOB            81650016
ENT      DC    C'ENT'                  KEY WORD OF ENTER DATA           81670016
         DS    0F                                                       81700016
NOTE1    DC    X'00000001'              NOTE NUMBER                     81750016
DOUBLE   DC    X'FFFFFFF8'                                              81770016
CODE1C   DC    XL4'0000001C'           IERR RETURN CODE                 81780016
EIGHT    DC    H'8'                     CONSTANT 8                      81800016
SAVEBPRI DS    H                        FOR BACKGROUND JOB PRIORITYPDUM 81805017
         SPACE 2                                                        81805500
*********************************************************************** 81806000
*                                                                       81806500
*        MAINTENANCE AREA                                        A33564 81807000
*                                                                       81807500
*********************************************************************** 81808000
PATCH    DC    13F'0'                                            A33564 81808500
         SPACE 2                                                        81809000
*                                                                       81810016
* SPAR MACRO IN MF=L                                                    81820016
*                                                                       81830016
SPAR     SPAR  (DUMMY),MF=L             SPAR MACRO                      81840016
SPARE    EQU   *                                                        81850016
LSPAR    EQU   SPARE-SPAR               MACRO LENGTH                    81860016
DUMMY    EQU   *                                                        81870016
*                                                                       81880016
* THIS IS A PARAMETER LIST PAST TO SVC ROUTINE                          81960016
*                                                                       82040016
SVCPARM  DS    0F                                                       82120016
SVCCODE  DC    C'PBEG'                  CODE FOR BEGIN JOB              82200016
SVCINFTN EQU   *                                                        82280016
SVC2250  DC    F'0'                     2250 ADDRESS                    82360016
SVCJBCNT DC    F'0'                     JOB COUNTER                     82440016
SVCENOTE DC    F'0'                     NOTE NUMBER                     82520016
SVCFBCK  DC    X'00'                   FORE OR BACK GROUND JOB          82600016
SVCEND   EQU   *                                                        82680016
LPARM    EQU   SVCEND-SVCPARM           LENGTH OF SVC PARAMETER LIST    82760016
*                                                                       82770016
* THIS IS  A PARAMETER LIST PAST TO INTERNAL ERROR ROUTINE              82780016
*                                                                       82790016
         DS    0F                                                       82800016
MSG11    DC    CL3'011'                MESSAGE NUMBER                   82801016
         DC    CL5'CTL  '               MODULE'S KEY WORD               82802016
         DC    X'C0'                    INSERT + RETURN                 82803016
         DC    AL3(OCTMESG)            POINTER TO INSERT DATA           82804016
*                                                                       82805016
OCTMESG  DC    H'6'                     LENGTH                          82806016
         DC    C'UNIT'                 INSERT DATA                      82807016
IERRPAR  EQU   *                                                        82810016
MSGNO   DC     CL3'039'                MSG NUMBER                       82820016
         DC    CL5'CTL  '              MODULE NAME                      82830016
         DC    X'80'                    RETURN                          82840016
         DC    XL4'00000000'                                            82850016
TITLE    DC    X'0E'                                                    82850416
         DC    C'SYSTEM MESSAGE '                                       82850816
LOGMSG   DC    X'2B'                   MSG LENGTH                       82851216
         DC    C'-SYSTEM OPERATOR REQUESTS THAT YOU LOG OFF  '          82851616
         EJECT                                                          82852016
CVT      DSECT                                                          82852416
         CVT   SYS=VMS                                                  82852816
         EJECT                                                          82853216
*                                                                       82853616
*  GFX LIST POINTED TO BY CVT                                           82854016
*                                                                       82854416
GRAPLIST DSECT                                                          82854816
GOCT     DS    1F                      POINTER TO THE OCT               82855216
GGAPR    DS    1F                      POINTER TO GAPR                  82855616
GCANC    DS    1F                      POINTER TO CANCEL RTN            82856016
GFXOCTHD DSECT                                                          82856416
GFXHDSTR EQU   *                       START OF HEADER RECORD           82856816
OCTSYS   DS    CL1                     BASE SYSTEM                      82857216
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                82857616
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          82858016
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       82858416
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       82858816
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              82859216
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              82859616
         DS    0H                                                       82860016
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             82860416
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       82860816
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       82861216
         DS    0F                                                       82861616
OCTFGREG DS    CL4                      REGION SIZE GJP                 82862016
OCTFUREG DS    CL4                      REGION SIZE USER FGD            82862416
OCTBUREG DS    CL4                      REGION SIZE USER BGD            82862816
OCTGTCB  DS    CL4                     TCB ADDRESS OF GFX               82863216
OCTHRES  DS    CL4                     RESERVED                         82863616
OCTNAME  DS    CL20                     PROGRAMMER NAME                 82864016
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  82864416
GFXHDEND EQU   *                       END OF HEADER RECORD             82864816
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        82865216
         EJECT                                                          82865616
GFXOCTEN DSECT                                                          82866016
         DS    0F                                                       82866416
GFXENSTR EQU   *                       START OF ENTRY RECORD            82866816
OCTECB   DS    CL4                      ECB                             82867216
OCTUCB   DS    CL4                      UCB ADDRESS                     82867616
OCTUNIT  DS    CL4                      UNIT ADDRESS                    82868016
OCTCOUNT DS    CL4                      JOB COUNT                       82868416
OCTNOTE  DS    CL4                      NOTE                            82868816
OCTABEND DS    A                       ABEND CODE                       82869216
OCTRESD  DS    CL8                      RESERVED                        82869616
**********************************************************************  82870016
****                          ATTRIBUTE 1                          **** 82870416
**********************************************************************  82870816
OCTATTR1 DS    CL2                      ATTRIBUTES                      82871216
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         82871616
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   82872016
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         82872416
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       82872816
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   82873216
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  82873616
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  82874016
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           82874416
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          82874816
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   82875216
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           82875616
OCTBERR1 EQU   X'10'          0-                  1-GJP INTERNAL ERROR  82876016
OCTBERR2 EQU   X'08'          0-                  1-GJP INTERNAL ERR(2) 82876416
**********************************************************************  82876816
****                          ATTRIBUTE 2                          **** 82877216
**********************************************************************  82877616
OCTATTR2 DS    CL2                      ATTRIBUTES                      82878016
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERROR  82878416
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      82878816
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              82879216
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           82879616
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         82880016
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           82880416
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       82880816
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            82881216
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  82881616
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  82882016
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        82882416
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         82882816
**********************************************************************  82883216
****                          ATTRIBUTE 3                          **** 82883616
**********************************************************************  82884016
OCTATTR3 DS    CL2                      ATTRIBUTES                      82884416
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERROR  82884816
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      82885216
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              82885616
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           82886016
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         82886416
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           82886816
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       82887216
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            82887616
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  82888016
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  82888416
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        82888816
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         82889216
**********************************************************************  82889616
****                          ATTRIBUTE 4                          **** 82890016
**********************************************************************  82890416
OCTATTR4 DS    CL2                      ATTRIBUTES                      82890816
GFXENEND EQU   *                       END OF ENTRY RECORD              82891216
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             82891616
         EJECT                                                          82900016
         END                                                            91000016
