         TITLE 'DISPLAY  ATTENTION ROUTINE FOR GJP'                     00500016
*                                                                       01000016
*   IKADAT  DISPLAY ATTENTION ROUTINE FOR GJP                           01500016
*                                                                       02000016
*     FUNCTION-HANDLE ATTENTION INTERRUPTS FROM A 2250 GRAPHIC DISPLAY  02500016
*              CONSOLE                                                  03000016
*                                                                       03500016
*         TYPES OF ATTENTIONS HANDLED                                   04000016
*              1. LIGHT PEN                                             04500016
*              2. CONSOLE END KEY                                       05000016
*              3. CONSOLE CANCEL KEY                                    05500016
*                                                                       06000016
*         HANDLING OF ATTENTION TYPES                                   06500016
*              IF LIGHT PEN LOAD ADDRESS OF CCT IN REG.0,ADDRESS OF     07000016
*               COMAREA IN REG.1 BALR TO DGM ROUTINE.                   07500016
*              IF END KEY LOAD ADDRESS OF CCT IN REG.1 BALR TO DIR.     08000016
*              IF CANCEL KEY POST CANCEL CODE IN PROCESSOR ECB AND      08500016
*               RETURN TO CONTROLLING ROUTINE.                          09000016
*              UPON RETURN FROM DGM A TYPE CODE WILL BE PASSED IN REG.  09500016
*               15 INDICATING SIGNIFICANCE OF LIGHT PEN DETECT. IF A    10000016
*               LIGHT PEN END WAS SIGNIFIED CONTROL WILL BE PASSED TO   10500016
*               DIR. IF LIGHT PEN CANCEL WAS SIGNIFIED PROCESSOR ECB    11000016
*               WILL BE POSTED WITH CANCEL CODE.                        11500016
*              UPON RETURN FROM DIR AN END CODE WILL BE POSTED AND A    12000016
*               RETURN ISSUED                                           12500016
*                                                                       13000016
*         OTHER FUNCTIONS                                               13500016
*               AFTER AN INITIAL ATTENTION HAS BEEN HANDLED FOR A       14000016
*                CONTROLLING ROUTINE A BIT WILL BE TURNED ON IN THE     14500016
*                CONSOLE CONTROL TABLE TO IGNORE FURTHER ATTENTION      15000016
*                UNTIL IT IS TURNED OF BY THAT ROUTINE.                 15500016
*                                                                       16000016
*         REQUIREMENTS FOR USE                                          16500016
*               REG. 15 WILL BE USED FOR PASSING CODES FROM DGM.        17000016
*                   RETURN CODES                                        17500016
*                     '00' NO ACTION NECESSARY                          18000016
*                     '04' LIGHT PEN END                                18500016
*                     '08' LIGHT PEN CANCEL                             19000016
*                     '1C' INTERNAL ERROR                          GJPF 19200017
*                                                                       19500016
*         POST CODES ISSUED                                             20000016
*                                                                       20500016
*                     '04' LIGHT PEN END OR END KEY                     21000016
*                     '08' LIGHT PEN CANCEL OR CANCEL KEY               21500016
*                     '1C' INTERNAL ERROR TERMINATE GJP            GJPF 21700017
*                                                                       22000016
*         REGISTERS USED                                                22500016
*               REGISTER 0   PARAMETER REG                              23000016
*                        1   PARAMETER REG                              23500016
*                        2   BASE REG                                   24000016
*                        3   CCT ADDRESS                                24500016
*                        4   COMAREA ADDRESS                            25000016
*                        5   GACB ADDRESS                               25500016
*                        13  REGISTER SAVE AREA ADDRESS                 26000016
*                        14  RETURN ADDRESS                             26500016
*                        15  BRANCH ADDRESS AND RETURN CODES            27000016
*                                                                       27500016
*         TABLE AND WORK AREAS                                          28000016
*                                                                       28500016
*               GRAPHIC ATTENTION CONTROL BLOCK (GACB)                  29000016
*               GRAPHIC COMMUNICATION AREA, (COMAREA)                   29500016
*               CONSOLE CONTROL TABLE (CCT)                             30000016
*                                                                       30500016
*                                                                       31000016
*         EQUATES FOR REGISTERS USED                                    31500016
*                                                                       32000016
RPAR0    EQU   0                        PARAMETER REGISTER 0            32500016
RPAR1    EQU   1                        PARAMETER REGISTER 1            33000016
BASER    EQU   2                        BASE REGISTER 2                 33500016
CCTR     EQU   3                        POINTER TO CCT 3                34000016
COMR     EQU   4                        POINTER TO COMAREA 4            34500016
GACBR    EQU   5                        POINTER TO GACB 5               35000016
RSAVE    EQU   13                       SAVE REGISTER                   35500016
RRET     EQU   14                       RETURN REGISTER                 36000016
RBR      EQU   15                       BRANCH REGISTER                 36500016
         SPACE 2                                                        37000016
*                                                                       37500016
*  DSECT LAYOUT OF GRAPHIC'S COMMUNICATION AREA                         38000016
*                                                                       38500016
COMAREA  DSECT                                                          39000016
         USING *,COMR                                                   39500016
ATTNCOM  DS    CL3                      ATTENTION COMMUNICATION AREA    40000016
ATTNTYPE DS    CL1                      ATTENTION TYPE                  40500016
         DS    3F                                                       41000016
CCTADDR  DS    1F                       CCT ADDRESS                     41500016
         EJECT                                                          42000016
*                                                                       42500016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         42700016
         SPACE                                                          42900016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    43100016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     43300016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       43500016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             43700016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  43900016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  44100016
*                   SET.                                                44300016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      44500016
*                   SECOND.                                             44700016
         SPACE 2                                                        44900016
CCT      DSECT                                                          45100016
         USING *,CCTR                                                   45300016
         SPACE                                                          45500016
*                             SECTION ONE                               45700016
         SPACE                                                          45900016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     46100016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    46300016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  46500016
         SPACE                                                          46700016
         DS    0F                                                       46900016
CCTUNAME DS    5F                  USER'S NAME                          47100016
CCTUACCT DS    5F                  USER'S ACCOUNT NUMBER                47300016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     47500016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       47700016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    47900016
*                                       AT LAST BEGIN JOB               48100016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   48300016
*                                       LAST BEGIN JOB                  48500016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 48700016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    48900016
*                                       JOB                             49100016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    49300016
*                                       JOB                             49500016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     49700016
*                                       CESSOR                          49900016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         50100016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         50300016
CCTJCTR  DS    H                   JOB COUNTER                          50500016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                50700016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   50900016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  51100016
CCTSSTAT DS    C                   SESSION STATUS                       51300016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              51500016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              51700016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    51900016
         EJECT                                                          52100016
         SPACE 2                                                        52300016
*                             SECTION TWO                               52500016
         SPACE                                                          52700016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   52900016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  53100016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 53300016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              53500016
         SPACE                                                          53700016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     53900016
*                                       FRAME                           54100016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  54300016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     54500016
*                                       MULTIPLE DISPLAY FRAME (ENT)    54700016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   54900016
CCTDISM  DS    C                   DISPLAY MASK                         55100016
CCTCSM   DS    C                   COMMAND SELECT MASK                  55300016
CCTPSTAT DS    CL2                 GJP STATUS                           55500016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              55700016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  55900016
         SPACE 2                                                        56100016
*                             SECTION THREE                             56300016
         SPACE                                                          56500016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    56700016
*                   INTO SECTION ONE OR TWO                             56900016
         SPACE                                                          57100016
CCTDGMP  DS    F                  POINTER TO DGM                        57300016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                57500016
CCTCSTP  DS    F                  POINTER TO CST                        57700016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                57900016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            58100016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 58300016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              58500016
CCTDIARP DS    F                  POINTER TO DIA                        58700016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      58900016
CCTACTP  DS    F                  POINTER TO ACT                        59100016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     59300016
CCTIERRP DS    F                  POINTER TO IERR                       59500016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              59700016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               59900016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                60100016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 60300016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 60500016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   60700016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                60900016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                61100016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               61300016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              61500016
CCTPECB  DS    F                  PROCESSOR'S ECB                       61700016
CCTWECB  DS    F                  WTOR ECB                              61900016
CCTDIAWA DS    CL136               DIARY WORK AREA                      62100016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    62300016
CCTCSAVE DS    CL72                CTL SAVE AREA                        62500016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                62700016
CCTASAVE DS    CL72                DAT SAVE AREA                        62900016
         EJECT                                                          67000016
IKADAT   CSECT                                                          67500016
*0173,905000                                                       GJPF 67700017
BEGIN    SAVE  (14,12)                 SAVE ALL REGISTERS               68000016
         BALR  BASER,0                  SET UP REG.2 AS BASE            68500016
         USING *,BASER                                                  69000016
         L     COMR,ZERO(RPAR1)         LOAD ADDR OF COMAREA            69500016
         L     CCTR,CCTADDR             LOAD ADDR OF CCT                70000016
         LA    RPAR1,CCTASAVE           LOAD ADDR OF ATTN. SAVE AREA    70500016
         ST    RPAR1,EIGHT(ZERO,RSAVE)  STORE ADDR OF SAVE AREA IN      71000016
*                                       HIGHER LEVEL SAVE AREA          71500016
         ST    RSAVE,SAVE13             STORE ADD OF PREVIOUS SAVE AREA 72000016
         LA    RSAVE,CCTASAVE           LOAD ADD OF REG SAVE AREA       72500016
         TM    IGNORBIT,MASKX20         TEST IGNORE ATTN BIT            73000016
         BO    REGEN                   IF ON BRANCH TO REGENERATE FRAME 73500016
         TM    ATTNTYPE,MASKX03         TEST FOR LIGHT PEN              74000016
         BO    TOLPMNIP                                                 74500016
         TM    ATTNTYPE,MASKX05         TEST FOR CANCEL KEY             74600016
         BO    POSTCAN                                                  74700016
         TM    ATTNTYPE,MASKX01         TEST FOR END KEY                75000016
         BO    TODIR                                                    75500016
         B     EXIT                                                     77000016
         SPACE                                                          77500016
TOLPMNIP LR    RPAR1,COMR               LOAD ADDR OF COMAREA INTO REG.1 78000016
         L     RBR,LPADDR               LOAD ADDR OF LPMANIP            78500016
         BALR  RRET,RBR                 BRANCH TO LPMANIP               79000016
         B     CONTINUE                                                 79500016
         DC    X'A000'                                                  80000016
         SPACE                                                          80500016
CONTINUE CH    RBR,CONZERO             IS RETURN CODE ZERO              80900016
         BE    EXIT                    YES GO TO EXIT ROUTINE           81300016
         CH    RBR,CONFOUR             IS RETURN CODE FOUR              81700016
         BE    TODIR                   YES GO TO DIR                    82100016
         CH    RBR,CONEIGHT            IS RETURN CODE EIGHT             82500016
         BE    POSTCAN                 YES GO TO POST CANCEL            82900016
         CH    RBR,CON1C               IS RETURN CODE ONE C        GJPF 83000017
         BE    INTERR                  YES GO TO INTERNAL ERROR RETGJPF 83100017
         B     RCERR                   BRANCH TO RETURN CODE ERROR      83300016
         SPACE                                                          84000016
TODIR    LR    RPAR1,CCTR               LOAD ADDR OF CCT                84500016
         L     RBR,DIRADDR              LOAD ADDR OF DIR                85000016
         BALR  RRET,RBR                 BRANCH TO DIR                   85500016
         SPACE                                                          85600017
         CH    RBR,CON1C               IS RETURN CODE ONE C        GJPF 85700017
         BE    INTERR                  YES GO TO INTERNAL ERROR RETGJPF 85800017
         SPACE                                                          86000016
POSTEND  POST  CCTPECB,ENDCODE          POST END CODE                   86500016
         B     SETIGN                                                   87000016
         SPACE                                                          87100017
INTERR   POST  CCTPECB,ERRCODE         POST ERROR COCE             GJPF 87200017
         B     SETIGN                                              GJPF 87300017
         SPACE                                                          87500016
POSTCAN  TM    CCTPSTAT+1,X'02'        RECALL MODE                      87600016
         BO    POST                YES GO TO POST PROCESSOR             87700016
         OI    CCTPSTAT,X'01'      TURN ON CANCEL MODE BIT              87800016
         SPACE                                                          87900016
POST     POST  CCTPECB,CANCODE     POST CANCEL CODE                     88000016
         SPACE                                                          88500016
SETIGN   OI    IGNORBIT,MASKX20         SET IGNORE BIT ON               89000016
         SPACE                                                          89500016
EXIT     L     RSAVE,SAVE13             LOAD ADD OF REG. SAVE AREA      90000016
         RETURN (14,12),RC=(15)                                    GJPF 90500017
         SPACE                                                          91000016
*                                                                       91020016
*  IGNORE ATTENTION BIT WAS ON REGENERATE THE FRAME                     91040016
*                                                                       91060016
         SPACE                                                          91080016
REGEN    TM    ATTNTYPE,MASKX03        WAS IT A LIGHT PEN ATTN          91100016
         BZ    EXIT                    NO BRANCH TO EXIT ROUTINE        91120016
         SPACE                                                          91140016
         LA    RPAR1,CCTLPWRK          LOAD ADDR OF WORK AREA           91160016
         XC    ZERO(16,RPAR1),ZERO(RPAR1)    ZERO CALLING SEQ. AREA     91180016
         MVI   ZERO(RPAR1),X'08'       MOVE CONTROL BITS TO CALL SEQ.   91200016
         ST    CCTR,12(RPAR1)          STORE CCT ADDR IN CALLING SEQ.   91220016
         LA    RPAR0,16(RPAR1)         LOAD ADDR OF DOR WORK AREA       91240016
         L     RBR,CCTDORP             LOAD ADDR OF DOR                 91260016
         BALR  RRET,RBR                BRANCH TO IKADOR                 91280016
         SPACE                                                          91300016
         B     EXIT                    GO TO EXIT ROUTINE               91320016
         SPACE                                                          91340016
*                                                                       91346016
*  RETURN CODE ERROR GO TO INTERNAL ERROR ROUTINE                       91352016
*                                                                       91358016
         SPACE                                                          91364016
RCERR    LA   RPAR0,IRMSG52            LOAD ADDR OF ERROR MESSAGE       91370016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT                 91376016
         L     RBR,CCTIERRP            LOAD ADDR OF IKAIERR             91382016
         BR    RBR                     BRANCH TO IKAIERR                91388016
 SPACE                                                                  91400016
CONZERO  DC    AL2(0)                  CONSTANT OF ZERO                 91420016
CONFOUR  DC    AL2(4)                  CONSTANT OF FOUR                 91440016
CONEIGHT DC    AL2(8)                  CONSTANT OF EIGHT                91460016
CON1C    DC    AL2(28)                 CONSTANT OF 28              GJPF 91480017
DIRADDR  DC    V(IKADIR)                ADD OF DIR                      91500016
LPADDR   DC    V(IKALPM)                ADDR OF LIGHT PEN MANIP         92000016
IRMSG52  DC    C'052DAT  '             CALLING SEQ TO IERR FOR          92100016
         DC    F'0'                    ERROR MSG 52                     92200016
ZERO     EQU   0                                                        92500016
EIGHT    EQU   8                                                        93000016
MASKX01  EQU   X'01'                                                    93500016
MASKX03  EQU   X'03'                                                    94000016
MASKX05  EQU   X'05'                                                    94500016
MASKX20  EQU   X'20'                                                    95000016
SAVE13   EQU   CCTASAVE+4                                               95500016
IGNORBIT EQU   CCTPSTAT+1                                               96000016
ENDCODE  EQU   4                                                        96500016
CANCODE  EQU   8                                                        97000016
ERRCODE  EQU   28                                                  GJPF 97200017
         SPACE 2                                                        97230000
*********************************************************************** 97260000
*                                                                       97290000
*        MAINTENANCE AREA                                        A33564 97320000
*                                                                       97350000
*********************************************************************** 97380000
PATCH    DC    4F'0'                                             A33564 97410000
         SPACE 2                                                        97440000
         END                                                            97500016
