         TITLE  ' DIARY ROUTINE - CONTROLS THE RECORD DATA SET'         00300016
IKADIA   CSECT                                                          00600016
*0828,235000,699640,724500,732000                                  GJPF 00700017
*                                                                       00900016
*                                                                       01200016
*                                                                       01500016
*  MODULE NAME -    IKADIA                                              01800016
*                                                                       02100016
*  CHART ID    -   FR                                                   02400016
*                                                                       02700016
*  FUNCTION    -    PRODUCE THE RECORD DATA SET IF THE USER CHOSE THE   03000016
*                   'RECORD' FUNCTION. MAINTAIN THE HISTORY AREA OF THE 03300016
*                   CCT.                                                03600016
*                                                                       03900016
*  ATTRIBUTES  -    RESIDENT,REENTERABLE                                04200016
*                                                                       04500016
*  ENTRY POINTS-    ENTERED AT DIA BY PROCESSORS                        04800016
*                                                                       05100016
*  OPERATION   -    INPUT TELLS IF HISTORY OR RECORD OPERATIONS OR BOTH 05400016
*                   ARE REQUIRED.  IF THE HISTORY AREA IS TO BE ADDED   05700016
*                   TO, THE PREFIX NUMBER IS INCREMENTED AND THE FIRST  06000016
*                   31 BYTES OF THE 'RECORD' RECORD ARE USED AS HISTORY 06300016
*                                                                       06600016
*                   IF INPUT IS 'RECORD' MATERIAL AND THE USER CHOSE    06900016
*                   'RECORD' THE INPUT IS PACKED LEAVING TWO BLANKS     07200016
*                   WHERE THE INPUT HAD TWO OR MORE.  THEN THE RECORD   07500016
*                   IS ADDED TO THE 'RECORD' DATA SET.                  07800016
*                                                                       08100016
*  EXITS       -    RETURN TO CALLER                                    08400016
*                                                                       08700016
*  INPUT       -    COMMAND PROCESSOR OUTPUT IN THE PROCESSOR WORKAREA  09000016
*                   IN THE CCT.                                         09300016
*                   SEE PROCESSORS FOR INPUT FORMAT.  THE ADDRESS OF    09600016
*                   THE CONSOLE CONTROL TABLE IS IN REGISTER ONE.  THE  09900016
*                   HIGH ORDER BITS OF REGISTER ONE WILL BE AS FOLLOWS: 10200016
*                                                                       10500016
*                             BIT 0  -  1  MEANS  RECORD ENTRY ONLY     10800016
*                                       0  HISTORY AND RECORD ENTRY     11100016
*                             BIT 1 - 1 MEANS A LARGE SIZE RECORD       11200016
*                                     0 MEANS NORMAL (136) RECORD       11300016
*                                                                       11400016
*  OUTPUT      -    'RECORD' DATA SET AND UPDATED HISTORY AREA          11700016
*                                                                       12000016
*  EXTERNAL REFERENCES -   CONSOLE CONTROL TABLE                        12300016
*                                                                       12600016
*  ERROR CONDITIONS -                                                   12900016
*                                                                       13200016
*  TABLES AND WORKAREAS -                                               13500016
*                                                                       13800016
*  RESTRICTIONS   -                                                     14100016
*                                                                       14400016
*                                                                       14700016
         EJECT                                                          15000016
*              REGISTER EQUATES                                         15300016
*                                                                       15600016
RPAR0    EQU   0                                                        15900016
RPAR1    EQU   1                                                        16200016
RBASE    EQU   2                                                        16500016
RPARM    EQU   3                                                        16800016
RWRK0    EQU   4                     RWRK0   MUST BE EVEN               17100016
RWRK1    EQU   5                     RWRK1   MUST FOLLOW RWRK0          17400016
RDCB     EQU   6                                                        17700016
RWKAR    EQU   7                                                        18000016
RNEXT    EQU   8                                                        18300016
RCCT     EQU   9                                                        18600016
RSCAN    EQU   10                                                       18900016
RSTART   EQU   11                                                       19200016
RCNT     EQU   12                                                       19500016
RSAVE    EQU   13                                                       19800016
RRET     EQU   14                                                       20100016
RBR      EQU   15                                                       20400016
*                                                                       20700016
*                                                                       21000016
*                                                                       21300016
*                                                                       21600016
IKADIA   CSECT                                                          21900016
ENTLEN   EQU   31                                                       22200016
NUMENTRY EQU   14                                                       22500016
HSNLEGTH EQU   3                                                        22800016
NUMSPAC  EQU   2                                                        23100016
RECWKLNG EQU   136                                                      23300016
LGLENGTH EQU   RECWKLNG+68              LARGE SIZE RECORD          GJPF 23380017
ONE      EQU   1                        EQUATE                     GJPF 23460017
TWO      EQU   2                        EQUATE                     GJPF 23540017
ONETWOOH EQU   120                      SIZE OF PRINTED RECORD     GJPF 23620017
RECORDOP EQU   X'80'                                                    23700016
*                                                                       24000016
*                                                                       24300016
*                                                                       24600016
*                                                                       24900016
SAVEAREA EQU   0                                                        25200016
WORKWORD EQU   72                                                       25500016
DECB     EQU   80                                                       25800016
DECBDCB  EQU   8                                                        26100016
DECBAREA EQU   12                                                       26400016
         EJECT                                                          26700016
*              DSECT FOR CONSOLE CONTROL TABLE                          27000016
*                                                                       27300016
IKACCT   DSECT                                                          27600016
         SPACE                                                          27700016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         27800016
         SPACE                                                          27900016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    28000016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     28100016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       28200016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             28300016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  28400016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  28500016
*                   SET.                                                28600016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      28700016
*                   SECOND.                                             28800016
         SPACE 2                                                        28900016
         SPACE 2                                                        29000016
*                             SECTION ONE                               29100016
         SPACE                                                          29200016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     29300016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    29400016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  29500016
         SPACE                                                          29600016
         DS    0F                                                       29700016
CCTUNAME DS    5F                  USER'S NAME                          29800016
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         29900016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     30000016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       30100016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    30200016
*                                       AT LAST BEGIN JOB               30300016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   30400016
*                                       LAST BEGIN JOB                  30500016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 30600016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    30700016
*                                       JOB                             30800016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    30900016
*                                       JOB                             31000016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     31100016
*                                       CESSOR                          31200016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         31300016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         31400016
CCTJCTR  DS    H                   JOB COUNTER                          31500016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                31600016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   31700016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  31800016
CCTSSTAT DS    C                   SESSION STATUS                       31900016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              32000016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              32100016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    32200016
         EJECT                                                          32300016
         SPACE 2                                                        32400016
*                             SECTION TWO                               32500016
         SPACE                                                          32600016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   32700016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  32800016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 32900016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              33000016
         SPACE                                                          33100016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     33200016
*                                       FRAME                           33300016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  33400016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     33500016
*                                       MULTIPLE DISPLAY FRAME (ENT)    33600016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   33700016
CCTDISM  DS    C                   DISPLAY MASK                         33800016
CCTCSM   DS    C                   COMMAND SELECT MASK                  33900016
CCTPSTAT DS    CL2                 GJP STATUS                           34000016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              34100016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  34200016
         SPACE 2                                                        34300016
*                             SECTION THREE                             34400016
         SPACE                                                          34500016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    34600016
*                   INTO SECTION ONE OR TWO                             34700016
         SPACE                                                          34800016
CCTDGMP  DS    F                  POINTER TO DGM                        34900016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                35000016
CCTCSTP  DS    F                  POINTER TO CST                        35100016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                35200016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            35300016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 35400016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              35500016
CCTDIARP DS    F                  POINTER TO DIA                        35600016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      35700016
CCTACTP  DS    F                  POINTER TO ACT                        35800016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     35900016
CCTIERRP DS    F                  POINTER TO IERR                       36000016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              36100016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               36200016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                36300016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 36400016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 36500016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   36600016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                36700016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                36800016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               36900016
CCTTIME  DS    F                  POINTER TO TIMER RTN FOR GJP          37000016
CCTPECB  DS    F                  PROCESSOR'S ECB                       37100016
CCTWECB  DS    F                  WTOR ECB                              37200016
CCTDIAWA DS    CL136               DIARY WORK AREA                      37300016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    37400016
CCTCSAVE DS    CL72                CTL SAVE AREA                        37500016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                37600016
CCTASAVE DS    CL72                DAT SAVE AREA                        37700016
*                                                                       41100016
         EJECT                                                          41400016
IKADIA   CSECT                                                          41700016
         SAVE  (14,12)                                                  42000016
         BALR  RBASE,0                                                  42300016
         USING *,RBASE                                                  42600016
         LR    RPARM,RPAR1              SAVE INPUT REGISTER             42900016
         GETMAIN R,LV=80+DECBEND-WRITDECB                               43200016
         ST    RSAVE,4(RPAR1)           SET UP SAVE AREA                43500016
         ST    RPAR1,8(RSAVE)                                           43800016
         LR    RSAVE,RPAR1                                              44100016
         LR    RWKAR,RPAR1                                              44400016
         LR    RCCT,RPARM               SET UP CCT                      44700016
         USING IKACCT,RCCT                                              45000016
         LTR   RPARM,RPARM              SEE IF HISTORY IS REQUIRED      45300016
         BC    4,RECORD                 SIGN BIT IS ON - RECORD ONLY    45600016
         SR    RWRK0,RWRK0                                              45900016
         IC    RWRK0,CCTHSN             GET THE NEXT ENTRY POINTER      46200016
         C     RWRK0,NUMHIST            SEE IF HISTORY AREA IS FULL     46500016
         BE    PUSHDOWN                 BRANCH IF HISTORY AREA IS FULL  46800016
         LA    RWRK1,1(RWRK0)           INCREMENT NEXT ENTRY POINTER    47100016
         STC   RWRK1,CCTHSN             STORE NEW NUMBER IN CCT         47400016
         B     INSERT                   GO TO INSERT NEW ENTRY          47700016
PUSHDOWN EQU   *                                                        48000016
*                             THESE MOVE INSTRUCTIONS MOVE ALL THE      48300016
*                             HISTORY ENTRIES  DOWN ONE ENTRY LENGTH.   48600016
*                             THEREBY LOSING THE FIRST ENTRY AND MAKING 48900016
*                             ROOM FOR A NEW LAST ENTRY.                49200016
         MVC   CCTHIST(NUMENTRY/2*ENTLEN),CCTHIST+ENTLEN                49500016
         MVC   CCTHIST+(NUMENTRY/2*ENTLEN)((NUMENTRY/2-1)*ENTLEN),CCTHI*49800016
               ST+(NUMENTRY/2+1)*ENTLEN                                 50100016
         LA    RWRK0,NUMENTRY-1         POINT NEXT ENTRY POINTER AT     50400016
*                                            LAST ENTRY                 50700016
         EJECT                                                          51000016
INSERT   LA    RWRK1,ENTLEN                                             51300016
         MR    RWRK0,RWRK0              RWRK1 WILL CONTAIN RELATIVE     51600016
*                                            ADDR OF INSERTION          51900016
         LA    RWRK1,CCTHIST(RWRK1)     GET ABSOLUTE ADDR OF INSERTION  52200016
         MVC   0(ENTLEN,RWRK1),CCTDIAWA MOVE NEW ENTRY TO HISTORY AREA  52500016
         L     RWRK0,CCTHSN             GET HISTORY SEQUENCE NUMBER     52800016
         LA    RWRK0,0(RWRK0)           CLEAR HIGH ORDER BYTE           53100016
         CVD   RWRK0,WORKWORD(RWKAR)    CONVERT HISTORY SEQUENCE NUMBER 53400016
*                                            TO DECIMAL                 53700016
         UNPK  0(HSNLEGTH,RWRK1),WORKWORD+8-HSNLEGTH(HSNLEGTH,RWKAR)    54000016
*                                UNPACK THE NEW HISTORY NUMBER          54300016
         OI    HSNLEGTH-1(RWRK1),X'F0'  CHANGE SIGN TO ZONE             54600016
         MVC   CCTDIAWA(HSNLEGTH),0(RWRK1)  MOVE HSN TO DIA WORK AREA   55800016
         B     RECORD                                                   56100016
RECORD   EQU   *                                                        56400016
         TM    CCTSSTAT,RECORDOP        DOES USER WANT RECORD           56700016
         BZ    RETURN                                                   57000016
         SLL   RPARM,1          PUT RECORD SIZE BIT IN HIGH ORDER       57070016
         LTR   RPARM,RPARM        IS IT LARGE RECORD                    57140016
         BM    LARGERCD       BRANCH IF YES                             57210016
         EJECT                                                          57300016
         LA    RCNT,RECWKLNG+CCTDIAWA                                   57600016
SAVELNG  EQU   *                                                        57700016
         ST    RCNT,DECB(RWKAR)                                         57900016
         LA    RSCAN,CCTDIAWA           START AT BEGINNING OF WORKAREA  58200016
         MVI   WORKWORD(RWKAR),0        ZERO FOR FIRST TIME SWITCH      58500016
QBLANKS  CLC   0(NUMSPAC,RSCAN),BLANKS  ARE  THERE ENOUGH BLANKS HERE   58800016
         BE    COMPRESS                 NUMBER OF BLANKS IS NUMBER RE-  59100016
*                                            QUIRED                     59400016
         LA    RSCAN,1(RSCAN)          INCREMENT TO NEXT POSITION       59700016
         C     RSCAN,DECB(RWKAR)        ARE WE OVER LIMIT               60000016
         BNL   WRITE                                                    60300016
         B     QBLANKS                                                  60600016
COMPRESS EQU   *                                                        60900016
         TM    WORKWORD(RWKAR),X'FF'    IS THIS THE FIRST TIME THRU     61200016
         BO    SKIP                     BRANCH IF NO                    61500016
         LA    RNEXT,2(RSCAN)           POINT RNEXT TO AVAILABLE POS    61800016
         MVI   WORKWORD(RWKAR),X'FF'    SHOW FIRST TIME THROUGH         62100016
SKIP     LA    RSCAN,2(RSCAN)           INCREMENT TO NEXT POSITION      62400016
         C     RSCAN,DECB(RWKAR)        ARE WE OVER LIMIT               62700016
         BNL   WRITE                                                    63000016
SCAN     CLI   0(RSCAN),C' '            IS THIS POSITION BLANK          63300016
         BNE   NEWFIND                  BRANCH IF BLANK NOT FOUND       63600016
         LA    RSCAN,1(RSCAN)           GO TO NEXT POSITION             63900016
         B     SCAN                                                     64200016
NEWFIND  EQU   *                                                        64500016
         LR    RSTART,RSCAN                                             64800016
         LA    RCNT,1                   START NUMBER OF CHARS           65100016
STILLGO  LA    RSCAN,1(RSCAN)           LOOK AT NEXT POSITION           65400016
         C     RSCAN,DECB(RWKAR)        ARE OVER LIMIT                  65700016
         BNL   WRITE                    BRANCH IF YES                   66000016
         CLC   0(NUMSPAC,RSCAN),BLANKS  ARE TWO BLANKS THERE            66300016
         BE    MOVEDOWN                 BRANCH IF YES                   66600016
         LA    RCNT,1(RCNT)             UP COUNT OF CHARS BY ONE        66900016
         B     STILLGO                                                  67200016
MOVEDOWN EQU   *                                                        67500016
         BCTR  RCNT,0                   SUBTRACT ONE FOR MOVE INSTRUCT  67800016
         EX    RCNT,MOVEINS             MOVE CHARS DOWN TO NEXT AVAIL   68100016
         LA    RNEXT,1(RNEXT,RCNT)         SET RNEXT TO NEXT AVAIL POS  68400016
         MVC   0(NUMSPAC,RNEXT),BLANKS  FILL IN BLANKS                  68700016
         LA    RNEXT,NUMSPAC(RNEXT)     SKIP OVER BLANKS TO NEXT AVAIL  69000016
         B     QBLANKS                                                  69300016
LARGERCD LA   RCNT,LGLENGTH+CCTDIAWA                                    69400016
         B     SAVELNG                                                  69500016
         EJECT                                                          69600016
WRITE    EQU   *                                                        69900016
         LA    RCNT,RECWKLNG+CCTDIAWA   GET ADDR OF END OF AREA         69940016
         CLR   RCNT,RNEXT    IS RECORD MORE THAN PRINT LINE             69948016
         BH    ONERCD        BRANCH IF NO                               69956016
         LA    RCNT,LGLENGTH+CCTDIAWA   FOR OVER-SIZED RECORDS     GJPF 69964017
PBLANKS  EQU   *                                                        69972016
         SR    RCNT,RNEXT               GET NUMBER OF BYTES TO BLANK    69980016
         BCTR  RCNT,0                   SUBTRACT TWO FOR MOVE           70020016
         BCTR  RCNT,0                                                   70060016
         MVC   0(1,RNEXT),BLANKS        MOVE IN FIRST BLANK             70100016
         EX    RCNT,BLNKMOVE            PROPAGATE BLANKS                70140016
         MVC   DECB(DECBEND-WRITDECB,RWKAR),WRITDECB   MOVE DECB TO     70200016
*                                       WORKAREA                        70500016
         L     RDCB,CCTRDCBP            GET ADDR OF DIARY DCB           70800016
         ST    RDCB,DECB+DECBDCB(RWKAR) SET UP DECB                     71100016
         LA    RWRK0,CCTDIAWA                                           71400016
SECREC   EQU   *                                                        71500016
         ST    RWRK0,DECB+DECBAREA(RWKAR)  PUT IN AREA ADDR             71700016
         WRITE   DECB(RWKAR),SF,MF=E                                    72000016
         CHECK   DECB(RWKAR)                                            72300016
         LTR RPARM,RPARM    DO WE NEED SECOND RECORD                    72350016
         BP    RETURN       BRANCH IF NO                                72400016
         MVC   CCTDIAWA(LGLENGTH-ONETWOOH),CCTDIAWA+ONETWOOH       GJPF 72420017
         MVC   CCTDIAWA+LGLENGTH-ONETWOOH(ONE),BLANKS              GJPF 72440017
         MVC   CCTDIAWA+ONE+LGLENGTH-ONETWOOH((TWO*ONETWOOH)-LGLENGTH),*72460017
               CCTDIAWA+LGLENGTH-ONETWOOH   BLANK OUT THE REMAINDERGJPF 72480017
         LA    RPARM,0(RPARM)   CLEAR HIGH ORDER BYTE                   72500016
         B     SECREC                                                   72550016
RETURN   EQU   *              RETURN TO PROCESSOR                       72600016
         MVC   CCTDIAWA(4),BLANKS       CLEAR AREA TO BLANKS            72900016
         MVC   CCTDIAWA+ONE(LGLENGTH-ONE),CCTDIAWA                 GJPF 73200017
         L     RSAVE,4(RSAVE)                                           73500016
         LR    RPAR1,RWKAR                                              73800016
         LR    RWKAR,RBR               SAVE 15 AROUND FREEMAIN          73900016
         FREEMAIN  R,LV=80+DECBEND-WRITDECB,A=(RPAR1)                   74100016
         LR    RBR,RWKAR               RESTORE 15                       74160016
         CH    RBR,=H'28'            SHOULD GJP-MUST-END BE PASSED      74220016
         BE    RETURN28                YES - PASS RC TO NEXT HIGHER LEV 74280016
*                                      NO  - DO NORMAL RESTORATION      74340016
         RETURN  (14,12)                                                74400016
         SPACE                                                          74410016
RETURN28 RETURN (14,12),RC=(15)                                         74420016
         SPACE                                                          74430016
ONERCD   EQU   *                                                        74470016
         LA    RPARM,0(RPARM)    CLEAR HIGH ORDER BYTE                  74540016
         B     PBLANKS                                                  74610016
         SPACE 2                                                        74620000
*********************************************************************** 74630000
*                                                                       74640000
*        MAINTENANCE AREA                                        A33564 74650000
*                                                                       74660000
*********************************************************************** 74670000
PATCH    DC    6F'0'                                             A33564 74680000
         EJECT                                                          74700016
*            ****** CONSTANTS  ******                                   75000016
*                                                                       75300016
*                                                                       75600016
         DS    0F                                                       75900016
NUMHIST  DC    AL4(NUMENTRY)            NUMBER OF HISTORY ENTRIES       76200016
BLANKS   DC    CL4' '                                                   76500016
MOVEINS  MVC   0(0,RNEXT),0(RSTART)                                     76800016
BLNKMOVE MVC   1(0,RNEXT),0(RNEXT)      USED TO BLANK RECORD AFTER PACK 76900016
         WRITE  WRITDECB,SF,,,'S',,,MF=L                                77100016
DECBEND  EQU   *                                                        77400016
         SPACE                                                          77500016
         LTORG                                                          77600016
         END                                                            77700016
