  TITLE  'IKAGCMD  (SVC TYPE 4 IGC1703D) VARY ON/OFFGFX COMMAND'        00100016
IGC1703D START 0                                                        00300016
*0660,519000-522000                                                0527 00400017
*3283,735000,894000                                                IIXX 00500018
*                                                                       00600016
*                                                                       00900016
*  MODULE NAME   -  IKAGCMD                                             01200016
*                                                                       01500016
*  SVC LIBRARY NAME-  IGC1703D                                          01800016
*                                                                       02100016
*  CHART ID - GA                                                        02400016
*                                                                       02700016
*  FUNCTION  -    TO HANDLE THE GVARY COMMAND.  THIS MODULE VALIDITY    03000016
*              CHECKS THE PARAMETERS AND, IF CORRECT, SETS APPROPRIATE  03300016
*              BITS IN THE OVERALL CONTROL TABLE OF FGX READER TASK.    03600016
*              IT THEN POSTS THE ECB IN THE OCT FOR EACH 2250 WHICH IS  03900016
*              GVARIED ON LINE.                                         04200016
*                                                                       04500016
*  ATTRIBUTES -   TYPE IV SVC ROUTINE, TRANSIENT, REENTRANT, ENABLED    04800016
*                                                                       05100016
*  ENTRY POINTS - IGC01703D VIA XCTL FROM IGC0403D                      05400016
*                                                                       05700016
*  EXITS -  RETURN TO SUPERVISOR                                        06000016
*                                                                       06300016
*  INPUT     -    THE EXTENDED SAVE AREA.   XAL POINT TO THE            06600016
*              PARAMETERS OF THE GVARY COMMAND.                         06900016
*                                                                       07200016
*  OUTPUT    -    BITS ARE SET IN THE OVERALL CONTROL TABLE TO REFLECT  07500016
*              THE GVARY PARAMETERS                                     07800016
*                                                                       08100016
*  EXTERNAL REFERENCES  - NONE                                          08400016
*                                                                       08700016
*  ERROR CONDITIONS  -                                                  09000016
*                                                                       09300016
*                                                                       09600016
*  TABLES AND WORKAREAS -    OCT                                        09900016
*                            CVT                                        10200016
*                                                                       10500016
*  RESTRICTIONS  -                                                      10800016
*                                                                       11100016
*                                                                       11400016
         EJECT                                                          11700016
         SPACE 2                                                        12000016
*                             EQUATES FOR REGISTERS                     12300016
         SPACE 2                                                        12600016
RPAR0    EQU   0                                                        12900016
RPAR1    EQU   1                                                        13200016
RXSAV    EQU   2                                                        13500016
ROCTHD   EQU   3                                                        13800016
R3       EQU   3                                                   AUTH 13900019
RPOST    EQU   4                                                        14100016
R4       EQU   4                                                   AUTH 14200019
RINC     EQU   5                                                        14400016
R5       EQU   5                                                   AUTH 14500019
RBASE    EQU   6                                                        14700016
ROCT     EQU   7                                                        15000016
RBUF     EQU   8                                                        15300016
RSAVE    EQU   13                                                       15600016
RRET     EQU   14                                                       15900016
RBR      EQU   15                                                       16200016
RCVT     EQU   10                                                       16500016
RNUM     EQU   10                                                       16800016
RXAL   EQU     11                                                       17100016
RPSOK  EQU     9                  SECOND SCAN SWITCH                    17400016
RSET     EQU   12                                                       17700016
NOSUP    EQU   15                                                       18000016
NOTAV    EQU   14                                                       18300016
MISSING  EQU   11                                                       18600016
MISPEL   EQU   9                                                        18900016
AUTHERRC EQU   41        ILLIGAL AUTHORITY ERROR INDICATION        AUTH 19000019
*                                                                       19200016
* THE BASE IS SET AND ADDRESSABILITY IS ESTABLISHED FOR CVT, XSAV,      19500016
* OCTHEADER, OCTENTRY (HAS TO BE RESET FOR EACH ENTRY RECORD            19800016
*                                                                       20100016
         BALR  RBASE,0                                                  20400016
         USING *,RBASE             SET BASE                             20700016
         LR    RSET,RPAR0          SAVE REGISTER ZERO              IIXX 20800018
         USING DCVT,RCVT           ADDRESSABILITY FOR CVT               21000016
         USING EXSA,RXSAV          ADDRESSABILITY FOR EXTENDED SAVE     21300016
         L     RCVT,CVTPTR                                              21600016
         L     ROCT,CVTQOCR                                             21900016
         LTR   ROCT,ROCT           TEST POINTER TO SEE IF OCT HAS BEEN  21940016
*                                  SET UP YET BY GFX                    21980016
         BC    4,GFXOK             GFX SETS ON HI BIT IN CVIQOCR WHEN   22020016
*                                  IT SETS UP OCT                       22060016
         B     ED1                 OCT NOT IN CORE, PUT OUT ERROR MSG   22100016
GFXOK    EQU   *                   OCT IS IN CORE RESUME PROCESSING     22140016
*                                                                  AUTH 22141019
*        VERIFY COMMAND AUTHORITY                                  AUTH 22142019
*                                                                  AUTH 22143019
         L     R3,CVTCUCB          GET UCM PTR                     AUTH 22144019
         USING UCMXECB,R3          UCM ADDRESSABILITY              AUTH 22145019
         TM    UCMMODE,UCMMCS      IS IN MCS ENVIRONMENT           AUTH 22146019
         BZ    GFXOK1              NO. BYPASS AUTH. CHECK          AUTH 22147019
         CLI   XAU,X'00'           CM FROM A SYSTEM TASK           AUTH 22148019
         BE    GFXOK1              YES. BYPASS AUTH. CHECK         AUTH 22149019
         CLI   XAU,X'80'           CM FROM INPUT STREAM            AUTH 22150019
         BL    XCONSL              NO. FROM A CONSOLE              AUTH 22151019
         TM    XAS,X'C0'           IS INPUT STREAM CM AUTH. VALID  AUTH 22152019
         BO    GFXOK1              YES, RESUME PROCESSING          AUTH 22153019
         B     AUTHERR             NO. ERROR                       AUTH 22154019
XCONSL   EQU   *                                                   AUTH 22155019
         SR    R5,R5               CLEAR REG. FOR INSERT CHAR.     AUTH 22156019
         IC    R5,XAU              GET UCMI                        AUTH 22157019
         BCTR  R5,RPAR0            SUBSTRACT ONE                   AUTH 22158019
         M     R4,UCMVEZ           UCMI LESS ONE TIMES...          AUTH 22159019
*                                  ...LENGTH OF UCME               AUTH 22160019
         A     R5,UCMVEA           PLUS FIRST UCME ADDR            AUTH 22161019
         USING UCMLIST,R5          ADDRESS PROPER UCME             AUTH 22162019
         C     R5,UCMVEL           IS COMPUTED UCME ADDR...        AUTH 22163019
*                                  ...GT THAT OF LAST UCME         AUTH 22164019
         BH    AUTHERR             YES. ERROR                      AUTH 22165019
         TM    UCMAUTH,X'C0'       IS CM AUTHORIZATION VALID       AUTH 22166019
         BO    GFXOK1              YES. RESUME PROCESSING          AUTH 22167019
AUTHERR  EQU   *                   ERROR RTN FOR INVALID AUTH      AUTH 22168019
         MVI   XAE,AUTHERRC        GET ERROR MSG CODE              AUTH 22169019
         B     XCTL503D            BRANCH TO EXIT                  AUTH 22170019
GFXOK1   EQU   *                                                   AUTH 22171019
         DROP  R3                                                  AUTH 22172019
         DROP  R5                                                  AUTH 22173019
         L     ROCTHD,0(ROCT)      ADDRESSABILITY FOR OCT HEADER        22200016
         USING GFXOCTHD,ROCTHD                                          22500016
         LA    ROCT,GFXHDSZE(ROCTHD) ADDRESSABILITY FOR OCT ENTRY       22800016
         USING GFXOCTEN,ROCT                                            23100016
         SR    RPSOK,RPSOK         CLEAR END OF SCAN SWITCH             23400016
         SR    RPOST,RPOST        CLEAR COUNTER OF VALID COMMANDS       23700016
*                                                                       24000016
         LH    RNUM,0(RPAR1)       LENGTH OF COMMAND BUFFER             24300016
         L     RBUF,XAL                                                 24600016
         L     RINC,XAL            POINTS TO THE BEGINNING OF THE       24900016
         CLI   0(RBUF),C'('            TEST FOR PARENS                  24960016
         BNE   LOOP                    NO PARENS                        25020016
         LA    RBUF,1(RBUF)            POINT TO FIRST CHARACTER IN BUF  25080016
         LA    RINC,1(RINC)            POINT TO FIRST CHARACTER IN BUF  25140016
*                                  COMMAND BUFFER                       25200016
LOOP     LA    RINC,1(RINC)        POINT TO NEXT CHAR                   25500016
         CLC  0(6,RINC),OFFGFX                                          25800016
*                                  SCANNING FOR 'OOFGFX                 26100016
         BE    LRXAL               BRANCH WHEN FOUND                    26400016
         CLC  0(5,RINC),ONGFX                                           26700016
*                                  SCANNING FOR ONGFX                   27000016
         BE    LRXAL               BRANNCH IF FOUND                     27300016
         CLI   0(RINC),C' '        Q. END OF BUFFER                     27600016
         BNE   LOOP                                                     27900016
         B     ED1                INVALID COMMAND                       28200016
LRXAL    LR    RXAL,RINC           RXAL NOW POINTS TO GFX COMMAND       28500016
RESETALL EQU   *                   COMPLETE INITIALIZATION              28800016
         LR    RINC,RBUF           POINT TO BEGINNING OF COMMAND        29100016
RESETREC EQU   *                                                        29400016
         LA    ROCT,GFXHDSZE(ROCTHD)   PICK UP FIRST OCT ENTRY          29700016
         LH    RNUM,OCTUNBR        NO. OF OCT ENTRIES FOR LOOP          30000016
         CLC   0(4,RINC),0(RXAL)   Q. POINTING TO COMMAND               30300016
         BE    QQ                  A. YES, COMMA NOT EXPECTED           30600016
         CLI   3(RINC),C','        COMMA IN PRPOPER PLACE               30900016
         BE    QQ                                                       31000016
         CLI   3(RINC),C')'            CHECK FOR PARENS                 31100016
         BNE   ERR5                A. NO INVALID DELIMITER              31200016
QQ       EQU   *                                                        31500016
         CLC   0(3,RBUF),CALL      Q. VARY ALL 2250'S                   31800016
         BNE   NOTALL              A. NO, BRANCH                        32100016
         B     MATCH               NO NEED TO SCAN BUFF IF 'ALL'        32400016
NOTALL   EQU   *                   ONE OR MORE 2250'S TO VARY           32700016
         CLC   0(5,RINC),0(RXAL)    Q. END OF BUFFER                    33000016
         BE    DONE                A. YES RETURN                        33300016
         CLC   0(3,RINC),OCTUNIT+1 +1  Q. UNIT ADDR IN BUF MATCH        33600016
*                                  UNIT ADDR IN OCT ENTRY               33900016
         BE    MATCH               A. YES, CORRECT ENTRY HAS BEEN FOUND 34200016
*                                  A. NO, CHECK NEXT ENTRY IN OCT       34500016
         LA    ROCT,GFXENSZE(ROCT) A.  PICK UP NEXT OCTEN               34800016
         BCT   RNUM,NOTALL         LOOP CONTROL, BRANCH IF MORE OCTEN   35100016
         B     EB4                 ERROR, OCTEN NOT FOUND               35400016
MATCH    EQU   *                                                        35700016
         CLC   0(5,RXAL),ONGFX     Q. VARY ON                           36000016
         BNE   VARYOFF             A. NO, SKIP TO VAROFF                36300016
         TM    OCTATTR1,OCTBACTV   Q. IS DESIRED 2250 ACTIVE            36600016
         BZ    VARYON2             A. NO, CAN BE VARIED ON              36700016
         CLC   0(3,RBUF),CALL      Q. CAN IT BE SKIPPED                 36800016
         BNE   ERR4                A. NO, UNIT IS NOT AVAILABLE         36900016
VARYON2  EQU   *                                                        37000016
         C     RPSOK,POSTABLE      Q. SECOND SCAN                       37200016
         BE    POSTON              A. YES, POST COMMAND                 37500016
         B     NOTYET              A. NO RESUME SCAN                    37800016
VARYOFF  EQU   *                                                        38100016
         TM    OCTATTR1,OCTBACTV   Q. 2250 ACTIVE                       38400016
         BO    VARYOFF2            A.YES, IT CAN BE VARIED OFF          38500016
         CLC   0(3,RBUF),CALL      Q. CAN IT BE SKIPPED                 38600016
         BNE   ERR4                A. NO , UNIT IS NOT AVAILABLE        38700016
VARYOFF2 EQU   *                                                        38800016
         C     RPSOK,POSTABLE      Q. END OF SCAN                       39000016
         BE    POSTOFF             A. YES POST COMMAND                  39300016
         B     NOTYET              A. NO RESUME SCAN                    39600016
POSTON   TM    OCTATTR1,OCTBACTV   Q. ALREADY ON                        39700016
         BO    POSTALL             A. YES, DO NOT POST                  39800016
         OI    OCTATTR3,OCTBNEW    A. NO BEGIN TO POST ON               39900016
         STC   RSET,OCTCONSL            SAVE CONSOLE ID            IIXX 39950018
         B     POST                                                     40000016
POSTOFF  TM    OCTATTR1,OCTBACTV   Q. ALREADY OFF                       40100016
         BZ    POSTALL             A. YES, DO NOT POSY                  40200016
         CLI   6(RXAL),C','        Q. COMMA AFTER COMMAND               40300016
         BE    XX                  A. YES, OK CHECK OFF SPEED           40800016
         CLI   6(RXAL),C' '        Q. BLANK AFTER COMMAND               41100016
         BE    CS                  A. YES, ASSUME DEFAULT               41400016
         B     ERR5                                                     41700016
XX       CLI   7(RXAL),C'F'        Q. 'F' STOP                          42000016
         BE    CF                                                       42300016
         CLI   7(RXAL),C'M'        Q. 'M' STOP                          42600016
         BE    CM                                                       42900016
         CLI   7(RXAL),C'S'        Q. 'S' STOP                          43200016
         BE    CS                                                       43500016
         B     EB2                 INVALID KEY WORD                     43800016
CF       OI    OCTATTR3,OCTBFAST   SET FAST BIT                         44100016
         B     POST                                                     44400016
CM       OI    OCTATTR3,OCTBMED    SET MEDIUM BIT                       44700016
         B     POST                                                     45000016
CS       OI    OCTATTR3,OCTBSLOW   SET SLOW BIT                         45300016
         B     POST                                                     45600016
POST     EQU   *                                                        45900016
         OI   OCTATTR3+1,OCTBCMDG  SET 'G COMMAND' BIT IN OCT ENTRY     46200016
POSTOCT  POST  OCTECB                   POST ECB                        46500016
POSTALL  EQU   *                                                        46600016
         BCT   RPOST,NV            BRANCH IF MORE TO POST               46800016
DONE     EQU   *                                                        47100016
         BR    RRET                                                     47400016
NV       CLC   0(3,RBUF),CALL      VARY ALL                             47700016
         BNE   INC                 A. NO INCREMENT POINTER              48000016
         LA    ROCT,GFXENSZE(ROCT) PICK UP NEXT OCTEN                   48300016
         B     MATCH                                                    48600016
INC      LA    RINC,4(RINC)        PICK UP NEXT ADDR IN BUFFER          48900016
         B     RESETREC                                                 49200016
NOTYET   EQU   *                                                        49500016
         CLC   0(3,RBUF),CALL      Q. VARY ALL                          49800016
         BNE   NN                  A. ONE OR ORE TO VARY                50100016
         LA    ROCT,GFXENSZE(ROCT) PICK UP NEXT OCTEN                   50400016
         LA    RPOST,1(RPOST)      ONE MORE ENTRY TO POST               50700016
         CH    RPOST,OCTUNBR       Q. HAVE ALL OCTEN BEEN CHECKED       51000016
         BE    POSTEM              A. YES, POST THEM                    51300016
         B     MATCH               NO                                   51600016
NN       CLI   3(RINC),C')'        Q. RIGHT PAREN                  0527 51700017
         BNE   OO                  NO                              0527 51800017
         CLC   5(5,RINC),0(RXAL)   Q. LAST 2250                    0527 51900017
         LA    RPOST,1(RPOST)         ADD ONE TO TOTAL             0527 52000017
         BE    POSTEM              A. YES POST THEM                0527 52100017
         B     ERR5                INVALID DELIMMETER              0257 52200017
OO       CLC   4(5,RINC),0(RXAL)   Q. LAST 2250                    0257 52300017
         LA    RPOST,1(RPOST)      ONE MORE 2250 HAS BEEN CHECKED       52800016
         BE    POSTEM                  A. YES                           52900016
         LA    RINC,4(RINC)        POINT TO NEXT 2250 ADDR              53100016
         B     RESETREC            CONTINUE SCAN                        53400016
POSTEM   L     RPSOK,POSTABLE      SET 'POSTABLE ' SWITCH, FSCAN OK     53700016
         B     RESETALL            BEGIN SECOND (POSTING) SCAN          54000016
EB2      EQU   *                                                        54300016
ERR1     MVI   XAE,MISPEL                                               54600016
         B     XCTL503D                                                 54900016
XCTLL    EQU   *                                                        55200016
XCTL503D MVC   XAX(8),IGC0503D     PUT NAME IN SAVE AREA                55500016
         OI    XAE,X'80'           TURN ON HIGH BIT OF XAE TO HAVE IIXX 55570018
*                             MSG TO CONSOLE ISSUING THE COMMAND   IIXX 55640018
         LR    RPAR0,RSET          RESTORE REGISTER ZERO           IIXX 55710018
         LA    RBR,XAX             POINT TO NAME                        55800016
         ST    RBR,XAP             FROM XAP                             56100016
         LR    RBR,RXSAV           POINT TO XSAV                        56400016
         XCTL  SF=(E,(15))         BRANCH TO MSG MOD                    56700016
EB3      EQU   *                                                        57000016
ERR2     MVI   XAE,MISSING         CODE FOR MISSING PARM                57300016
         B     XCTL503D                                                 57600016
ERR3     EQU   *                                                        57900016
EB4      EQU   *                                                        58200016
         MVI   XAE,NOSUP                                                58500016
         B     XCTL503D                                                 58800016
EB1      EQU  *                                                         59100016
ERR4     MVI   XAE,NOTAV           SET CODE FOR DEVICE NOT AVAILABLE    59400016
         B     XCTL503D                                                 59700016
ED1      EQU *                                                          60000016
         MVI   XAE,X'05'           INVADUD COMMAND                      60300016
         B     XCTL503D                                                 60600016
ERR5     EQU   *                                                        60900016
         MVI   XAE,X'07'           INVA DELIMITER                       61200016
         B     XCTL503D                                                 61500016
CALL   DC     C'ALL'                                                    61800016
         DS    0F                                                       62100016
POSTABLE DC    X'FF000000'         ALL ADDRS HAVE BEEN CHECKED          62400016
IGC0503D DC    CL8'IGC0503D'                                            62700016
ONGFX    DC    C'ONGFX'                                                 63000016
OFFGFX   DC   C'OFFGFX'                                                 63300016
         SPACE 2                                                        63330000
*********************************************************************** 63360000
*                                                                       63390000
*        MAINTENANCE AREA                                        A33564 63420000
*                                                                       63450000
*********************************************************************** 63480000
PATCH    DC    7F'0'                                             A33564 63510000
         EJECT                                                          63540000
GFXOCTHD DSECT                                                          63600016
GFXHDSTR EQU   *                       START OF HEADER RECORD           63900016
OCTSYS   DS    CL1                     BASE SYSTEM                      64200016
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                64500016
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          64800016
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       65100016
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       65400016
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              65700016
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              66000016
         DS    0H                                                       66300016
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             66600016
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       66900016
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       67200016
         DS    0F                                                       67500016
OCTFGREG DS    CL4                      REGION SIZE GJP                 67800016
OCTFUREG DS    CL4                      REGION SIZE USER FGD            68100016
OCTBUREG DS    CL4                      REGION SIZE USER BGD            68400016
OCTGTCB  DS    CL4                     TCB ADDRESS OF GFX               68700016
OCTHRES  DS    CL4                     RESERVED                         69000016
OCTNAME  DS    CL20                     PROGRAMMER NAME                 69300016
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  69600016
GFXHDEND EQU   *                       END OF HEADER RECORD             69900016
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        70200016
         EJECT                                                          70500016
GFXOCTEN DSECT                                                          70800016
         DS    0F                                                       71100016
GFXENSTR EQU   *                       START OF ENTRY RECORD            71400016
OCTECB   DS    CL4                      ECB                             71700016
OCTUCB   DS    CL4                      UCB ADDRESS                     72000016
OCTUNIT  DS    CL4                      UNIT ADDRESS                    72300016
OCTCOUNT DS    CL4                      JOB COUNT                       72600016
OCTNOTE  DS    CL4                      NOTE                            72900016
OCTABEND DS    A                       ABEND CODE                       73200016
OCTFPART DS    CL2                      PARTITION NUMBER (MFT)     IIXX 73300018
OCTDNOTE DS    CL3                      DIARY DATA SET NOTE FIELD  IIXX 73400018
OCTIERNO DS    CL3                      INTERNAL ERROR NUMBER      IIXX 73500018
**********************************************************************  73800016
****                          ATTRIBUTE 1                          **** 74100016
**********************************************************************  74400016
OCTATTR1 DS    CL2                      ATTRIBUTES                      74700016
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         75000016
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   75300016
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         75600016
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       75900016
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   76200016
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  76500016
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  76800016
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           77100016
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          77400016
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   77700016
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           78000016
OCTBERR1 EQU   X'10'          0-                  1-GJP INTERNAL ERROR  78300016
OCTBERR2 EQU   X'08'          0-                  1-GJP INTERNAL ERR(2) 78600016
**********************************************************************  78900016
****                          ATTRIBUTE 2                          **** 79200016
**********************************************************************  79500016
OCTATTR2 DS    CL2                      ATTRIBUTES                      79800016
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERROR  80100016
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      80400016
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              80700016
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           81000016
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         81300016
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           81600016
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       81900016
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            82200016
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  82500016
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  82800016
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        83100016
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         83400016
**********************************************************************  83700016
****                          ATTRIBUTE 3                          **** 84000016
**********************************************************************  84300016
OCTATTR3 DS    CL2                      ATTRIBUTES                      84600016
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERROR  84900016
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      85200016
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              85500016
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           85800016
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         86100016
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           86400016
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       86700016
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            87000016
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  87300016
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  87600016
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        87900016
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         88200016
**********************************************************************  88500016
****                          ATTRIBUTE 4                          **** 88800016
**********************************************************************  89100016
OCTATTR4 DS    CL1                      ATTRIBUTES                 IIXX 89200018
****                                                               IIXX 89300018
*                             CONSOLE IDENTIFICATION               IIXX 89400018
****                                                               IIXX 89500018
OCTCONSL DS    CL1                      CONSOLE ID                 IIXX 89600018
GFXENEND EQU   *                       END OF ENTRY RECORD              89700016
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             90000016
         EJECT                                                          90100019
EXSA DSECT                                                              90300016
         IEEXSA                                                         90600016
         EJECT                                                          90660019
DSUCM    DSECT                                                          90720019
         IEECUCM                                                        90780019
         EJECT                                                     AUTH 90840019
DCVT     DSECT                                                          90900016
         CVT                                                            91200016
 END                                                                    91500016
