         TITLE 'IKAIERR   INTERNAL ERROR ROUTINE'                  IIXX 00100018
IKAIERR0 CSECT                                                          00200016
*   MODULE NAME  -  IKAIERR0                                            00400016
*                                                                       00600016
*    CHART ID    -  FT                                                  00800016
*                                                                       01000016
*   FUNCTION -  HANDLE INTERNAL ERROR MESSAGES FOR GJP AND SGJP    PDUM 01200017
*                                                                       01400016
*   ATTRIBUTES - RESIDENT, REENTRABLE                                   01600016
*                                                                       01800016
*   ENTRY POINTS - IKAIERR0                                             02000016
*                                                                       02200016
*   INPUT    -      REGISTER ONE HAS THE ADDRESS OF THE CONSOLE CONTROL 02400016
*                             TABLE                                     02600016
*                                                                       02800016
*                   REGISTER ZERO POINTS TO A PARAMETER LIST AS FOLLOWS 03000016
*                                                                       03200016
*                                                                       03400016
*          0   ************************************                     03600016
*              *                                  *                     03800016
*              *    MESSAGE NUMBER IN EBCDIC      *                     04000016
*              *                                  *                     04200016
*          3   ***************************************************      04400016
*              *                                                 *      04600016
*              *    MODULE IDENTIFIER                            *      04800016
*              *                                                 *      05000016
*          8   ***************************************************      05200016
*              *  CONTROL *                              *              05400016
*              *   BITS   * ADDRESS OF/OR INSERTION      *              05600016
*              *          *                              *              05800016
*              *******************************************              06000016
*         12   *  REPLY   *                              *         PDUM 06040017
*              *  LENGTH  *   REPLY  ADDRESS  (WTOR)     *         PDUM 06080017
*              *          *                              *         PDUM 06120017
*              *******************************************         PDUM 06160017
*                                                                       06200016
*   DISP                EXPLANATION                                     06400016
*                                                                       06600016
*     0             THIS IS THE NUMBER ASSIGNED TO AND ASSOCIATED WITH  06800016
*                   THE MESSAGE.  THIS NUMBER MUST BE IN EBCDIC, THREE  07000016
*                   CHARACTERS.                                         07200016
*                                                                       07400016
*     3             THIS IS THE MODULE IDENTIFIER, IN EBCDIC.  FOR      07600016
*                   EXAMPLE - THE MODULE IDENTIFIER FOR IKAPSPE0 IS     07800016
*                   PSPE0 - FOR IKAPLON0 IS PLON0.  FIVE CHARACTERS     08000016
*                   ARE ALLOWED.  LESS THE FIVE MOST BE LEFT ADJUSTED   08200016
*                   WITH TRAILING BLANKS.                               08400016
*                                                                       08600016
*     8             CONTROL BITS                                        08800016
*                   BIT 0  -  UNUSED                               PDUM 09100017
*                   BIT 1  -  ON IF THERE IS AN INSERTION FOR THE       09400016
*                             MESSAGE                                   09600016
*                   BIT 2-5-  UNUSED                               PDUM 09680017
*                   BIT 6  -  REPLY EXPECTED                       PDUM 09760017
*                   BIT 7  -  ON FOR SGJP (IKD... MODULES)         PDUM 09840017
*                             OFF FOR GJP AND GFX                  PDUM 09920017
*                                                                       10000016
*     9             ADDRESS OF INSERTION.  THIS FIELD IS ONE OF TWO     10200016
*                   THINGS OR IS ZERO.                                  10400016
*                                                                       10600016
*                        A)   THE ADDR OF AN EBCDIC INSERTION IN THE    10800016
*                             FOLLOWING FORMAT:                         11000016
*                             ***************************************   11200016
*                             *0       *                            *   11400016
*                             * LENGTH * CHARACTERS TO BE INSERTED  *   11600016
*                             *        *                            *   11800016
*                             ***************************************   12000016
*                                                                       12200016
*                             NOTE- THE LENGTH INCLUDES THE 2 BYTE      12400016
*                                   LENGTH FIELD                        12600016
*                                                                       12800016
*                        B)   THE CHARACTER 'R' LEFT ADJUSTED AND, IN   13000016
*                             THE NEXT TWO BYTES, THE CODE, IN BINARY,  13200016
*                             WHICH THE CALLER WISHES INSERTED.         13400016
*                                                                       13600016
*    12             LENGTH OF THE REPLY FOR WTOR       1 BYTE      PDUM 13630017
*                                                                  PDUM 13660017
*    13             ADDRESS OF THE REPLY FOR WTOR      3 BYTES     PDUM 13690017
*                                                                  PDUM 13720017
*                                                                  PDUM 13750017
*   OPERATION  -  A TABLE, IKAMERR0, IS LOADED BY IKAIERR0. THIS TABLE  13800016
*                 IS A SERIES OF MESSAGES IN THE FOLLOWING FORMAT.      14000016
*                                                                       14200016
*                 0           1            2                            14400016
*                 ***************************************************** 14600016
*                 *           *            *                          * 14800016
*                 * ATTRIBUTE * RESERVED   * RE2 ADDR OF INSERTION    * 15000016
*                 *           *            *                          * 15200016
*                 ***************************************************** 15400016
*                 *                        *                          * 15600016
*                 * LENGTH OF MESSAGE IN-  *    MESSAGE               * 15800016
*                 *  CLUDING PREAMBLE      *                          * 16000016
*                 ***************************************************** 16200016
*                 *                                                   * 16400016
*                 *      MESSAGE CONTINUED                            * 16600016
*                 *                                                   * 16800016
*                 ***************************************************** 17000016
*                                                                       17200016
*                 ATTRIBUTES-                                           17400016
*              DISP. 0  -   BIT  0 -  MESSAGE IS ONLY FOR INFORMATIPDUM 17600017
*                           BIT  1 -  THIS MESSAGE DEMANDS AN INSERTION 17800016
*                           BIT  2 - ISSUE WTO                          18000016
*                          BIT  3 -  PRINTED MESSAGE (SMB)         PDUM 18080017
*                          BIT  4-5-  UNUSED                       PDUM 18160017
*                          BIT  6 -  REPLY ALLOWED (WTOR)          PDUM 18240017
*                         BIT 7 MCSCODES ARE INCLUDED AFTER TEXT   IIXX 18320018
*                    1  -   RESERVED                                    18400016
*                    2  -   RELATIVE ADDRESS OF INSERTION FROM START OF 18600016
*                           MESSAGE                                     18800016
*                    4  -   LENGTH FROM BEGINNING OF ATTRIBUTES TO END  19000016
*                           OF MESSAGE                                  19200016
*                    6  -   MESSAGE                                     19400016
         SPACE 2                                                        19600016
*                        EQUATES FOR REGISTERS                          19800016
         SPACE 2                                                        20000016
*              -  THE MESSAGE'S ATTRIBUTES ARE TESTED TO PERFORM   PDUM 20060017
*                 EITHER WRITE TO OPERATOR OR PRINT ON THE RPINTER PDUM 20120017
*                 OR DISPLAY 'GJP MUST RESTART' OR 'GJP MUST TERMINPDUM 20180017
*                 MESSAGES                                         PDUM 20240017
*     MCS CODES OF ROUTE=COI  DISPOSITION=4 WILL BE ASSIGNED       IIXX 20260018
*   UNLESS THE MCSCODES BIT IS SET IN THE ATTRIBUTES FIELD         IIXX 20280018
         SPACE 2                                                   PDUM 20300017
*                        EQUATES FOR REGISTERS                     PDUM 20360017
         SPACE 2                                                   PDUM 20420017
RPAR0    EQU   0                                                   PDUM 20480017
RPAR1    EQU   1                                                   PDUM 20540017
RCCT     EQU   2                                                   PDUM 20600017
RBASE    EQU   3                                                   PDUM 20660017
RPARM    EQU   4                                                   PDUM 20720017
RMSG     EQU   5                                                   PDUM 20780017
RWORK    EQU   6                                                   PDUM 20840017
RWRK1    EQU   7                                                   PDUM 20900017
RWRK2    EQU   8                                                   PDUM 20960017
RWRK3    EQU   9                                                   PDUM 21020017
RENTCTR  EQU   10                                                  PDUM 21080017
RCVT     EQU   10                                                  PDUM 21140017
ROCT     EQU   11                                                  PDUM 21200017
ROCTENT  EQU   12                                                  PDUM 21260017
RGFXLIST EQU   12                                                  PDUM 21320017
RSAVE    EQU   13                                                  PDUM 21380017
RRET     EQU   14                                                  PDUM 21440017
RBR      EQU   15                                                  PDUM 21500017
DCB      EQU   *                                                   PDUM 21560017
DUMMY    EQU   *                                                   PDUM 21620017
OCBP1    EQU   *                                                   PDUM 21680017
NORMAL   EQU   X'7F'                                               PDUM 21740017
MCSCODES EQU   X'01'               MCSCODES ARE INCLUDED AFTER TEXTIIXX 21770018
MCSFLAGS EQU   128                 MCSFLAGS FIELD EXISTS           IIXX 21780018
         SPACE 2                                                   PDUM 21800017
IKAIERR0 CSECT                                                     PDUM 21860017
*0830,012000,090000-092000,176000,182000,202000-734000             PDUM 21920017
*0830,396800-398600,525200                                         0200 21940017
*0830,436400,441200,443600                                         9739 21960017
*0830,358400,360200                                                PDUM 21970017
*0830,390800                                                       PDUM 21975000
*0437,183200,369200,397200-397700,398700,431000,444200-444800,     IIXX 21976018
*     455000,456200,504800-505400,525400                           IIXX 21977018
*2030,431000,432200                                              A26972 21978000
* 444370-444440                                                  A29779 21978519
         SPACE 2                                                        21979019
         SAVE  (14,12)                                             PDUM 21980017
         BALR  RBASE,0                                             PDUM 22040017
         USING *,RBASE                                             PDUM 22100017
         LR    RCCT,RPAR1                                          PDUM 22160017
         USING CCT,RCCT                                            PDUM 22220017
         LR    RPARM,RPAR0                                         PDUM 22280017
         MVC   CCTPWKA+200(50),0(4)    MOVE PARAMETER IN A FULLWORDPDUM 22340017
         LA    RPARM,CCTPWKA+200       BOUNDRY AND GET THIS ADDRESSPDUM 22400017
         USING PARALIST,RPARM                                      PDUM 22460017
         GETMAIN  R,LV=DEND-SAVEAREA                               PDUM 22520017
         ST    RPAR1,8(RSAVE)                                      PDUM 22580017
         ST    RSAVE,4(RPAR1)                                      PDUM 22640017
         LR    RSAVE,RPAR1                                         PDUM 22700017
         LR    RWORK,RSAVE                                         PDUM 22760017
         USING WORK,RWORK                                          PDUM 22820017
         LA    10,SAVE14                START ADDRESS FOR CLEARUP  PDUM 22880017
         LA    7,DEND-SAVE14            THE LENGTH                 PDUM 22940017
         LA    9,0(10,7)               END OF WORKAREA             PDUM 23000017
         LA    8,8                     A NUMBER OF 8               PDUM 23060017
         SR    9,8                     SUBTRACT 8                  PDUM 23120017
CLEAR1   XC    0(8,10),0(10)            CLEAR 8 BYTES              PDUM 23180017
         BXLE  10,8,CLEAR1             KEEP WORK UNTILE FINISH     PDUM 23240017
         MVI   BUFFER,64                CLEAR OUT                  PDUM 23300017
         MVC   BUFFER+1(125),BUFFER     THE BUFFER                 PDUM 23360017
         LOAD  EP=IKAMERR0                                         PDUM 23420017
         LR    RMSG,RPAR0                                          PDUM 23480017
         USING MESSAGES,RMSG                                       PDUM 23540017
         SPACE 2                                                   PDUM 23600017
*                        OPEN SYSOUT DCB                           PDUM 23660017
         SPACE 2                                                   PDUM 23720017
         MVC   OPENCLS(OPENEND-OPENSOUT),OPENSOUT   MOVE L FORM TO PDUM 23780017
         MVC   SYSDCB(DCBEND-SYOUTDCB),SYOUTDCB  MOVE DCB TO GETMAIPDUM 23840017
         MVC   READDIA(LREAD),READDIAL  MAKE READ REENTERABLE      PDUM 23900017
         MVC   WRITEOUT(LWRITE),WRITEL1                            PDUM 23960017
         OPEN  (SYSDCB,(OUTPUT)),MF=(E,OPENCLS)                    PDUM 24020017
         SPACE 2                                                   PDUM 24080017
MSGLOOP  CLC   LNG(2),ZEROS        IS THIS END OF TABLE            PDUM 24140017
         BE    NOTFND              BRANCH IF YES                   PDUM 24200017
         CLC   MSG+3(3),MSGNO      IS THIS MSG REQUESTED           PDUM 24260017
         BE    FOUND               BRANCH IF YES                   PDUM 24320017
         AH    RMSG,LNG            INCREMENT TO NEXT MESSAGE       PDUM 24380017
         B     MSGLOOP                                             PDUM 24440017
         SPACE 2                                                   PDUM 24500017
MOVEMSG  MVC   BUFFER(0),MSG                                       PDUM 24560017
         SPACE 3                                                   PDUM 24620017
NOTFND   LA    RMSG,DEFAULT        GET STANDARD MSG                PDUM 24680017
FOUND    EQU   *                                                   PDUM 24740017
         LH    RWRK1,LNG           GET REAL LENGTH OF MESSAGE      PDUM 24800017
         SH    RWRK1,PREAM                                         PDUM 24860017
         BCTR  RWRK1,0             SUBTRACT ONE FOR MOVE           PDUM 24920017
         EX    RWRK1,MOVEMSG       MOVE MESSAGE TO BUFFER          PDUM 24980017
         CLI   BUFFER+2,C'D'            Q. SGJP MESSAGE            PDUM 25040017
         BNE   GJP                      NO                         PDUM 25100017
         MVI   BUFFER+3,240             ZERO HIGH ORDER DIGIT      PDUM 25160017
GJP      EQU   *                                                   PDUM 25220017
         CLC   BUFFER(L'MSG999),MSG999  Q. DEFAULT MESSAGE         PDUM 25280017
         BNE   FILLIN                   NO                         PDUM 25340017
         MVC   BUFFER+L'MSG999(3),MSGNO  ERRONEOUS MSG NO.         PDUM 25400017
FILLIN   LA    RWRK2,BUFFER(RWRK1)      GET ADDR OF END OF BUFFER  PDUM 25460017
         CLC   MODNM(8),0(RWRK2)       DOES IT REQUIRE MODULE NAME PDUM 25520017
         BE    INSMODNM                                            PDUM 25580017
DDDTEST  CLC   DDD(3),0(RWRK2)     DOES IT REQUIRE 2250 ADDR       PDUM 25640017
         BE    INSDDD                                              PDUM 25700017
GONEXT   BCT   RWRK1,FILLIN                                        PDUM 25760017
         TM    ATTR,INS            DOES MSG REQUIRE INSERT         PDUM 25820017
         BO    INSERT              BRANCH IF YES                   PDUM 25880017
QWTO     EQU   *                                                   PDUM 25940017
         TM    ATTR,X'20'              Q. DO WE WRITE TO OPERATOR  PDUM 26000017
         BO    WTO                      BRANCH IF YES              PDUM 26060017
QINF     EQU   *                                                   PDUM 26120017
         TM    ATTR,INF               Q. IS THIS MESSAGE FOR       PDUM 26180017
*                                      INFORMATION ONLY            PDUM 26240017
         BO    FCLOSE                  BRANCH IF YES               PDUM 26300017
QRECORD  EQU   *                                                   PDUM 26360017
         TM    CCTSSTAT,X'80'          Q. RECORD OPTION            PDUM 26420017
         BO    WRITEDIA                 BRANCH IF YES              PDUM 26480017
QPRINT   EQU   *                                                   PDUM 26540017
         TM    ATTR,SMB                Q. WRITE TO PRINTER         PDUM 26600017
         BO    QENDGJP                  BRANCH IF YES              PDUM 26660017
         B     QENDGJP1                                            PDUM 26720017
         SPACE 2                                                   PDUM 26780017
*                   SETUP BASE FOR OCT                             PDUM 26840017
         SPACE 2                                                   PDUM 26900017
QTERMINT L     RCVT,X'10'               CVT ADDRESS                PDUM 26960017
         USING CVT,RCVT                                            PDUM 27020017
         L     RGFXLIST,CVTQOCR         PARAMETER ADDRESS          PDUM 27080017
         USING GRAPLIST,RGFXLIST                                   PDUM 27140017
         L     ROCT,GOCT                OCT ADDRESS                PDUM 27200017
         USING GFXOCTHD,ROCT                                       PDUM 27260017
         DROP  12                                                  PDUM 27320017
         LA    ROCTENT,GFXHDSZE+GFXHDSTR OCT RECORD ENTRY          PDUM 27380017
         USING GFXOCTEN,ROCTENT                                    PDUM 27440017
         DROP  10                       DROP BASE 10               PDUM 27500017
         LH    RENTCTR,OCTUNBR          OCT RECORD NUMBER          PDUM 27560017
ENTSEACH EQU   *                                                   PDUM 27620017
         CLC   CCTUNIT(3),OCTUNIT+1        NEED THIS RECORD        PDUM 27680017
         BE    COMPNO                    BRANCH IF YES             PDUM 27740017
         LA    ROCTENT,GFXENSTR+GFXENSZE UPDATE ENTRY              PDUM 27800017
         BCT   RENTCTR,ENTSEACH          BRANCH                    PDUM 27860017
COMPNO   EQU   *                                                   PDUM 27920017
         LTR   4,4                     Q. IS THIS MESSAGE FROM INITPDUM 27980017
         BM    INIT                     BRANCH IF YES              PDUM 28040017
         CLI   MSG+2,C'D'               Q. IF SGJP MSG,            PDUM 28100017
         BE    INIT                     THEN DON'T RESTART         PDUM 28160017
         CLC   OCTIERNO(3),MSGNO       Q. THIIS ERROR HAPPENED BEFOPDUM 28220017
         BNE   RESTART                  NO DISPLAY RESTART MESSAGE PDUM 28280017
INIT     EQU   *                                                   PDUM 28340017
         XC    OCTIERNO(3),OCTIERNO    CLEAR OLD NUMBER            PDUM 28400017
         TM    CCTSSTAT,X'80'          Q. RECORD OPTION            PDUM 28460017
         BZ    PREDISP                  BRANCH IF NO               PDUM 28520017
         LA    8,SYSDCB                 PUT SYSOUT DCB ADDRESS IN  PDUM 28580017
         ST    8,WDCBADDR               WRITE DCB ADDRESS FIELD    PDUM 28640017
         LA    8,PRECORD                PRINTED RECORD ADDRESS     PDUM 28700017
         LA    9,5                      RECORD NUMBER              PDUM 28760017
         LA    10,RECORD                CONSTANT RECORD ADDRESS    PDUM 28820017
MOVERD   EQU   *                                                   PDUM 28880017
         MVC   0(120,8),0(10)           MOVE ONE RECORD            PDUM 28940017
         LA    8,120(8)                 UPDATE POINTER             PDUM 29000017
         LA    10,120(10)               UPDATE CONSTANT RECORD ADDRPDUM 29060017
         BCT   9,MOVERD                 MOVE CONTROL               PDUM 29120017
         LA    8,PRECORD                RESET POINTER              PDUM 29180017
         MVC   175(3,8),CCTUNIT         SET UNIT ADDRESS           PDUM 29240017
         ST    8,WAREADDR              BUFFER ADDRESS FOR WRITE    PDUM 29300017
         SR    9,9                      CLEAR COUNTER              PDUM 29360017
WRITE1   WRITE WRITEOUT,SF,MF=E         WRITE A RECORD ONTO SYSOUT PDUM 29420017
         CHECK WRITEOUT                 CHECK FOR COMPLETION       PDUM 29480017
         LA    9,1(9)                   UPDATE COUNTER             PDUM 29540017
         C     9,FIVE                  Q. HAVE MOVED FIVE RECORD   PDUM 29600017
         BE    COPY                     BRANCH IF YES              PDUM 29660017
         LA    8,120(8)                 UPDATE RECORD POINTER AND  PDUM 29720017
         ST    8,WAREADDR               PUT IN WRITE BUFFER FIELD  PDUM 29780017
         B     WRITE1                   CONTINUE WRITE             PDUM 29840017
         SPACE 2                                                   PDUM 29900017
*                   THIS SECTION COPY DIARY DATA SET TO SYSOUT DAT PDUM 29960017
         SPACE 2                                                   PDUM 30020017
COPY     EQU   *                                                   PDUM 30080017
         CLC   CCTRDCBP(3),ZEROS       Q. IS DIARY DCB ADDRESS THERPDUM 30140017
         BE    PREDISP                  BRANCH IF NO               PDUM 30200017
         MVI   CCTRDCBP,X'80'           SET CLOSE OPTION BYTE      PDUM 30260017
         LA    RPAR1,CCTRDCBP           GET CLOSE PARAMETER LIST   PDUM 30320017
         CLOSE MF=(E,(1))               ISSUE CLOSE                PDUM 30380017
         MVI   CCTRDCBP,X'83'          SET OPTION BYTE             PDUM 30440017
         LA    RPAR1,CCTRDCBP           GET OPEN PARAMETER LIST    PDUM 30500017
         OPEN  ,MF=(E,(1))             OPEN DIARY DATA SET         PDUM 30560017
         MVI   CCTRDCBP,X'00'            RESET HIGH ORDER BYTE     PDUM 30620017
         L     RWRK3,CCTRDCBP           DIARY DCB ADDRESS          PDUM 30680017
         ST    RWRK3,DCBADDR            STORE IN READ DCB FIELD    PDUM 30740017
         LA    RWRK2,PREDISP            END OF DATA ROUTINE ADDRESSPDUM 30800017
         ST    RWRK2,CCTPWKA            * MOVE THIS ADDRESS IN DIARPDUM 30860017
         MVC   33(3,RWRK3),CCTPWKA+1    * DATA CONTROL BLOCK       PDUM 30920017
         LA    RWRK3,BUFFER             BUFFER ADDRESS FOR READ    PDUM 30980017
         ST    RWRK3,AREAADDR           FUNCTION                   PDUM 31040017
         ST    RWRK3,WAREADDR           BUFFER ADDRESS FOR WRITE   PDUM 31100017
         LA    RWRK3,SYSDCB             SYSOUT DCB ADDRESS         PDUM 31160017
         ST    RWRK3,WDCBADDR           PUT IN WRITE MACRO         PDUM 31220017
READFM   EQU   *                                                   PDUM 31280017
         READ  READDIA,SF,MF=E          READ A READ FROM DIARY DATAPDUM 31340017
         CHECK READDIA                  CHECK FOR COMPLETION       PDUM 31400017
         WRITE WRITEOUT,SF,MF=E         WRITE THIS RECORD TO SYSOUTPDUM 31460017
         CHECK WRITEOUT                 CHECK FOR COMPLETION       PDUM 31520017
         B     READFM                  CONTINUE READ/WRITE         PDUM 31580017
         SPACE 2                                                   PDUM 31640017
*                   SET PARAMETER FOR DISPLAY ROUTINE              PDUM 31700017
         SPACE 2                                                   PDUM 31760017
RESTART  EQU   *                                                   PDUM 31820017
         MVC   CCTPWKA(48),RESTMSG      MOVE MESSAGE INTO WORKAREA PDUM 31880017
         MVC   OCTIERNO(3),MSGNO        SAVE MESSAGE NUMBER        PDUM 31940017
         BAL   14,DISPLAY               BRANCH TO DISPLAY ROUTINE  PDUM 32000017
         TM    CCTSSTAT,X'80'          Q. RECORD OPTION            PDUM 32060017
         BZ    SVC80IR                  BRANCH IF NO               PDUM 32120017
         L     1,CCTRDCBP               DIARY DCB ADDRESS          PDUM 32180017
         NOTE  (1)                      GET RECORD POSITION IN DATAPDUM 32240017
         ST    1,CCTPWKA                * SAVE NOTE POSITION OF DIAPDUM 32300017
         MVC   OCTDNOTE(3),CCTPWKA      * DATA SET IN OCT          PDUM 32360017
SVC80IR  MVC   OPENCLS(8),SVCPARM       MOVE SVCPARMS TO GETMAIN   PDUM 32420017
SVC80    EQU   *                                                   PDUM 32480017
         MVC   OPENCLS+5(3),CCTUNIT     MOVE IN UNIT ADDRESS       PDUM 32540017
         LA    0,OPENCLS                SVC PARAMETER ADDRESS      PDUM 32600017
         LR    1,RCCT                   CCT ADDRESS                PDUM 32660017
         SVC   80                                                  PDUM 32720017
         DROP  11                                                  PDUM 32780017
         B     FCLOSE                   BRANCH                     PDUM 32840017
PREDISP  EQU   *                                                   PDUM 32900017
         MVC   CCTPWKA(48),TERMMSG      MOVE MESSAGE INTO WORKAREA PDUM 32960017
*                                       WORKAREA                   PDUM 33020017
         BAL   14,DISPLAY               BRANCH TO DISPLAY ROUTINE  PDUM 33080017
SVC80I   EQU   *                                                   PDUM 33140017
         MVC   OPENCLS(8),SVCPARM1      MOVE SVC PARAMEER IN WORKARPDUM 33200017
*                                       IT INDICATES LOGOFF        PDUM 33260017
         B     SVC80                    BRANCH TO SVC80            PDUM 33320017
         SPACE 2                                                   PDUM 33380017
*                   WRITE INTERNAL ERROR MESSAGE ON DIARY          PDUM 33440017
         SPACE 2                                                   PDUM 33500017
WRITEDIA EQU   *                                                   PDUM 33560017
         CLC   CCTRDCBP(3),ZEROS       Q. IS DIARY DCB ADDRESS THERPDUM 33620017
         BE    QPRINT                   BRANCH IF NO               PDUM 33680017
         L     RWRK3,CCTRDCBP           DIARY DCB ADDRESS          PDUM 33740017
         ST    RWRK3,WDCBADDR           PUT IN WRITE DCB ADDRESS FIPDUM 33800017
         LA    RWRK3,BUFFER             MESSAGE BUFFER ADDRESS     PDUM 33860017
         ST    RWRK3,WAREADDR           PUT IN WRITE MACRO         PDUM 33920017
         WRITE WRITEOUT,SF,,,MF=E       WRITE                      PDUM 33980017
         CHECK WRITEOUT                 CHECK FOR COMPLETION       PDUM 34040017
         B     QPRINT                   BRANCH                     PDUM 34100017
         SPACE 2                                                   PDUM 34160017
*                   CHECK IF CALLER WANTS CONTINUING TO PROCESS    PDUM 34220017
         SPACE 2                                                   PDUM 34280017
QENDGJP  EQU   *                                                   PDUM 34340017
         TM    CCTSSTAT,X'80'          Q. RECORD OPTION            PDUM 34400017
         BZ    WRITESYS                 BRANCH IF NO               PDUM 34460017
         B     QENDGJP1                 MORE TESTING               PDUM 34520017
         SPACE 2                                                   PDUM 34580017
*                   WRITE ERROR MESSAGE ON SYSOUT DATA SET         PDUM 34640017
         SPACE 2                                                   PDUM 34700017
WRITESYS EQU   *                                                   PDUM 34760017
         LA    RWRK3,SYSDCB             SYSOUT DCB ADDRESS         PDUM 34820017
         ST    RWRK3,WDCBADDR           PUT IT IN WRITE MACRO      PDUM 34880017
         LA    RWRK3,BUFFER             WRITE BUFFER ADDRESS       PDUM 34940017
         ST    RWRK3,WAREADDR           PUT IN IN WRITE MACRO      PDUM 35000017
         WRITE WRITEOUT,SF,MF=E         WRITE OPERATION            PDUM 35060017
         CHECK WRITEOUT                 CHECK COMPLETION           PDUM 35120017
QENDGJP1  TM   ATTR,END                Q. GJP END                  PDUM 35180017
         BO    QTERMINT                 BRANCH FOR FURTHER TEST IF PDUM 35240017
         B     FCLOSE                                              PDUM 35300017
         SPACE 2                                                   PDUM 35360017
FCLOSE   EQU   *                                                   PDUM 35420017
         LA    RWRK1,0             NORMAL RET CODE                 PDUM 35430017
         TM    ATTR,END            IS MSG 'END' TYPE               PDUM 35440017
         BZ    NOTEND              NO                              PDUM 35450017
         LA    RWRK1,X'1C'         YES, SET UP 'END' RET CODE      PDUM 35460017
NOTEND   EQU   *                                                   PDUM 35470017
         DELETE EP=IKAMERR0            DELETE MESSAGE MODULE       PDUM 35480017
         MVC   OPENCLS(CLOSEND-CLOSEOUT),CLOSEOUT  MOVE L FORM TO GPDUM 35540017
         CLOSE (SYSDCB),MF=(E,OPENCLS)                             PDUM 35600017
         L     RSAVE,4(RSAVE)                                      PDUM 35660017
         LA    RPAR1,SAVEAREA                                      PDUM 35720017
         FREEMAIN  R,LV=DEND-SAVEAREA,A=(1)                        PDUM 35780017
         LR    RBR,RWRK1           SET UP RET CODE                 PDUM 35880017
         RETURN (14,12),RC=(15)                                    PDUM 36140017
         EJECT                                                     PDUM 36200017
*                                                                  PDUM 36260017
**   EXTRA PROCESSING FOR THE 1130 SUBSYSTEM IN SGJP               PDUM 36320017
*                                                                  PDUM 36380017
         SPACE 3                                                   PDUM 36440017
SGJP     ST    14,SAVE14                SAVE RETURN ADDRESS        PDUM 36500017
         L     RPAR1,CCTBUFFP           AND THE DATA               PDUM 36560017
         MVI   0(RPAR1),64              BLANK OUT                  PDUM 36620017
         MVC   1(147,RPAR1),0(RPAR1)    148 BYTES                  PDUM 36680017
         MVC   0(74,RPAR1),BUFFER       GET ERROR MSG,             PDUM 36740017
         MVC   74(4,RPAR1),CCTPWKA      FIRST 4 BYTES,             PDUM 36800017
         MVC   78(10,RPAR1),SGJPCON     IDENT FOR SGJP, AND        PDUM 36860017
         MVC   88(44,RPAR1),CCTPWKA+4   RESTART/TERMINATE MSG.     IIXX 36920018
         LA    RPAR1,148                LENGTH TO TRANSMIT         PDUM 36980017
         ST    RPAR1,CCTRECLN                                      PDUM 37040017
         CLI   MSG+2,C'D'               TEST IF SGJP MESSAGE       PDUM 37100017
         BE    SGJPXT                   IKDIOR WILL XMIT MSG       PDUM 37160017
*    TRANSMIT THE MESSAGE TO THE SUBSYSTEM                         PDUM 37220017
         LA    RPAR0,X'20'              RESTART CODE FOR IKDIOR    PDUM 37280017
         OC    OCTIERNO,OCTIERNO        Q. RESTART MSG             PDUM 37340017
         BNZ   SGJPRS                   NO                         PDUM 37400017
         LA    RPAR0,X'24'              TERMINATE CODE FOR IKDIOR  PDUM 37460017
SGJPRS   EQU   *                                                   PDUM 37520017
         LR    RPAR1,RCCT               ADDR OF CCT                PDUM 37580017
         L     RBR,CCTIORP              ADDR OF IKDIOR             PDUM 37640017
         BALR  RRET,RBR                                            PDUM 37700017
SGJPXT   L     14,SAVE14                GET RETURN ADDRESS         PDUM 37760017
         BR    14                       RETURN TO CALLER           PDUM 37820017
         EJECT                                                     PDUM 37880017
INSMODNM EQU   *                                                   PDUM 37940017
         MVC   3(5,RWRK2),MODID        MOVE MODULE ID TO MESSAGE   PDUM 38000017
         TM    CCTSSTAT,32              Q. REMOTE GRAPHIC DEVICE   PDUM 38060017
         BZ    DDDTEST                  NO - CONTINUE              PDUM 38120017
         TM    CONTBIT,IKDMOD           Q. IKD... MODULE           PDUM 38180017
         BZ    DDDTEST                  NO - CONTINUE              PDUM 38240017
         MVI   2(RWRK2),D               INDICATION OF SGJP         PDUM 38300017
         B     DDDTEST                  CONTINUE                   PDUM 38360017
INSDDD   EQU   *                                                   PDUM 38420017
         MVC   0(3,RWRK2),CCTUNIT      MOVE CCTUNIT TO MESSAGE     PDUM 38480017
         B     GONEXT                                              PDUM 38540017
INSERT   EQU   *                                                   PDUM 38600017
         TM    CONTBIT,X'40'       DOES USER HAVE INSERTION        PDUM 38660017
         BZ    QWTO                     BRANCH IF NO               PDUM 38720017
         CLC   INSADDR(3),ZEROS    IS ADDR THERE                   PDUM 38780017
         BZ    QWTO                     BRANCH IF NO               PDUM 38840017
         CLI   INSADDR,C'R'        IS IT IN BINARY                 PDUM 38900017
         BE    CONVERT            BRANCH IF YES                    PDUM 38960017
         L     RWRK1,INSADDR-1     GET ADDR OF INS.                PDUM 39020017
         SR    RWRK2,RWRK2         CLEAR REG                       GJPF 39040000
         IC    RWRK2,0(RWRK1)      PICK UP FIRST BYTE LENGTH       GJPF 39060000
         SLL   RWRK2,8             SHIFT LEFT                      GJPF 39080000
         IC    RWRK2,1(RWRK1)      PICK UP SECOND HALF OF LENGTH   GJPF 39100000
         BCTR  RWRK2,0                 SUTRACT ONE                 PDUM 39140017
INSRT    LA    RWRK3,BUFFER        GET ADDR OF BUFFER              PDUM 39200017
         AH    RWRK3,INSRELA       ADD RELATIVE ADDR OF INSERT     PDUM 39260017
         BCTR  RWRK2,0                                             PDUM 39320017
         BCTR  RWRK2,0                 DIMINISH BY 1               PDUM 39380017
         EX    RWRK2,MOVEINS       MOVE INSERT TO MSG              PDUM 39440017
         B     QWTO                     BRANCH                     PDUM 39500017
CONVERT  EQU   *                                                   PDUM 39560017
         LH    RWRK3,INSADDR+1     GET INSERTION (IN BINARY)       PDUM 39620017
         CVD   RWRK3,DEC               CONVERT TO DECIMAL NUMBER   0200 39670017
         UNPK  DEC(2),DEC+6(2)          CONVERT TO EBCDIC          IIXX 39720018
         OI    DEC+1,X'F0'              REMOVE ZONE                IIXX 39770018
         LA    RWRK2,3                 LOAD LENGTH OF MOVE         0200 39820017
         LA    RWRK1,DEC-2              ADDR OF DATA               IIXX 39870018
         B     INSRT               GO TO INSERT                    PDUM 39920017
         SPACE 5                                                   PDUM 39980017
WTO      EQU   *                                                   PDUM 40040017
         LH    RWRK1,LNG                                           PDUM 40100017
         SH    RWRK1,PREAM         SUBTRACT LENGTH OF PREAMBLE FROMPDUM 40160017
*                                  MESSAGE                         PDUM 40220017
         TM    ATTR,MCSCODES            Q. LENGTH INCLUDE CODES    IIXX 40240018
         BO    MCSINC                   YES                        IIXX 40260018
         LA    RWRK1,4(RWRK1)          AUGMENT BY 4                PDUM 40280017
         LA    RPAR1,BUFFER-4(RWRK1)    GET END OF MSG TEXT        IIXX 40290018
         MVC   0(L'CODES,RPAR1),CODES   MOVE IN DESCRIPTOR AND     IIXX 40300018
*                                       ROUTING CODES              IIXX 40310018
MCSINC   EQU   *                                                   IIXX 40320018
         SLL   RWRK1,16            PUT IN WTO FORMAT               PDUM 40340017
         ST    RWRK1,BUFFER-4                                      PDUM 40400017
         OI    BUFFER-2,MCSFLAGS        INDICATE MCSFLAGS EXIST    IIXX 40430018
         TM    CONTBIT,REPLY            Q. PROGRAM EXPECT REPLY    PDUM 40460017
         BZ    WTOA                     NO                         PDUM 40520017
         TM    ATTR,REPLY               Q. MESSAGE ALLOW REPLY     PDUM 40580017
         BZ    WTOA                     NO                         PDUM 40640017
         LA    RWRK1,CCTIOECB           GET ADDR OF ECB            PDUM 40700017
         ST    RWRK1,BUFFER-8           FOR WTOR I/O,              PDUM 40760017
         XC    CCTIOECB(4),CCTIOECB     ZERO IT OUT                PDUM 40820017
         MVC   BUFFER-12(4),RPLYPTR     MOVE IN LENGTH, ADDRESS    PDUM 40880017
         WTOR  ,MF=(E,BUFFER-12)                                   PDUM 40940017
         WAIT  ECB=CCTIOECB             WAIT FOR A REPLY           PDUM 41000017
         B     QINF                     CONTINUE                   PDUM 41060017
WTOA     WTO   MF=(E,BUFFER-4)                                     PDUM 41120017
         B     QINF                    BRANCH                      PDUM 41180017
         SPACE 2                                                   PDUM 41240017
*                   THIS ROUTINE DISPLAY ERROR MESSAGE             PDUM 41300017
         SPACE 2                                                   PDUM 41360017
DISPLAY  EQU   *                                                   PDUM 41420017
         TM    CCTSSTAT,32              Q. REMOTE GRAPHIC DEVICE   PDUM 41480017
         BO    SGJP                     YES - TRANSMIT             PDUM 41540017
         CLC   CCTDDCBP(3),ZEROS       Q. IS 2250 DCB ADDRESS THEREPDUM 41600017
         BE    SVC80I                   BRANCH IF NO               PDUM 41660017
         ST    14,SAVE14                SAVE RETURN ADDRESS        PDUM 41720017
         MVC   GRAORDER(ORDERL),START   MOVE GRAPHIC ORDER INTO    PDUM 41780017
*                                       WORKAREA                   PDUM 41840017
         L     RWRK2,CCTDDCBP           2250 DCB ADDRESS           PDUM 41900017
         MVC   GTRU+2(2),16(RWRK2)      SET BUFFER LOAD POINT FOR  PDUM 41960017
*                                       UNCONDITIONAL BRANCH       PDUM 42020017
         MVC   SAVEBLP(2),16(RWRK2)     SAVE BUFFER LOAD POINT     PDUM 42080017
         LA    RWRK2,GRAORDER           GRAPHIC ORDER ADDRESS      PDUM 42140017
         MVC   NODISPM(74,RWRK2),BUFFER     SET UP MESSAGES IN THE PDUM 42200017
         MVC   MSGDISPM(48,RWRK2),CCTPWKA   GRAPHIC ORDER AREA     PDUM 42260017
         MVC   GWRITE(LGWRITE),GWRITEL  MOVE GWRITE INTO WORKAREA  PDUM 42320017
         L     RWRK2,CCTDDCBP           2250 DCB ADDRESS           PDUM 42380017
         ST    RWRK2,GWRITE+8           PUT IT IN GWRITE MACRO     PDUM 42440017
         LA    RWRK2,GRAORDER           GRAPHIC DISPLAY ORDER ADDREPDUM 42500017
         ST    RWRK2,GWRITE+12          SAVE IT IN GWRITE          PDUM 42560017
         LA    RWRK2,SAVEBLP            POINTER OF BLP             PDUM 42620017
         ST    RWRK2,GWRITE+24          PUT IN                     PDUM 42680017
         ST    RWRK2,GWRITE+28          GWRITE                     PDUM 42740017
         LA    1,GWRITE                 GWRITE ADDRESS             PDUM 42800017
         GWRITE (1),MF=E                EXECUTE GWRITE             PDUM 42860017
         LTR   15,15                   Q. NORMAL RETURN            PDUM 42920017
         BNE   GFAIL                    BRANCH IF NO               PDUM 42980017
         WAIT  ECB=GWRITE               WAIT                       PDUM 43040017
         TM    GWRITE,NORMAL           Q. ANY I/O ERROR            PDUM 43160017
         BM    GFAIL1              BRANCH IF YES                 A26972 43220000
         L     14,SAVE14                GET RETURN ADDRESS         PDUM 43280017
         BR    14                       RETURN TO CALLER           PDUM 43340017
         SPACE 2                                                   PDUM 43400017
*                        WRITE TO OPERATOR - DISPLAY FAILED        PDUM 43460017
         SPACE 2                                                   PDUM 43520017
GFAIL    EQU   *                                                   PDUM 43580017
         LA    RWRK2,MSG001E-MSG001-1   MSG LENGTH FOR EXECUTE INS 9739 43640017
         LA    RWRK3,MSG001             MESSAGE ADDRESS            PDUM 43700017
         XC    CCTPWKA(8),CCTPWKA  CLEAR DOUBLE WORD               IIXX 43710018
         CVD   RBR,CCTPWKA         CONVERT INTO WKA                IIXX 43720018
         UNPK    CCTPWKA+06(2),CCTPWKA+6(2)  UNPACK                IIXX 43730018
         OI    CCTPWKA+7,X'F0'     TURN ON SIGN BITS               IIXX 43740018
         LH    RBR,CCTPWKA+6       LOAD EBCDIC RETURN CODE         IIXX 43750018
         B     WTOB                                                PDUM 43760017
GFAIL1   EQU   *                                                 A26972 43770000
         LA    RWRK2,MSG068E-MSG068-1   MSG LENGTH FOR EX INST.  A26972 43780000
         LA    RWRK3,MSG068             MESSAGE ADDRESS          A26972 43790000
         B     WTOB                                              A26972 43800000
         SPACE 2                                                   PDUM 43820017
         SPACE 2                                                   PDUM 43880017
*                   THIS IS GRAPHIC OVERFLOW ROUTINE               PDUM 43940017
         SPACE 2                                                   PDUM 44000017
OVERFL   EQU   *                                                   PDUM 44060017
         LA    RWRK2,MSG006E-MSG006-1   MSG LENGTH FOR EXECUTE INST9739 44120017
         LA    RWRK3,MSG006              MESSAGE ADDRESS           PDUM 44180017
WTOB     EQU   *                                                   PDUM 44240017
         XC    CCTPWKA(50),CCTPWKA       CLEAR WORK AREA           PDUM 44300017
         EX    RWRK2,MVWTO         MOVE MSG TO BUFFER              9739 44320017
         CLC   CCTPWKA+9(1),MSGNO+2     IS NUM OF THIS MSG SAME AS 9739 44340017
*                                       THE LAST ONE               9739 44360017
         BE    SVC80I                   YES, DO NOT SEND DUPLICATE 9739 44380017
*                                        TO BE WRITTEN OUT         9739 44400017
         MVC   CCTPWKA+12(3),CCTUNIT    SET UNIT ADDRESS           IIXX 44430018
         CLC   MSG068(MSG068L),0(RWRK3) Q. IS MSG 68             A29779 44440019
         BE    BYPASS                A. BRANCH IF YES            A26972 44451000
         STH   RBR,CCTPWKA+36           SET ERROR CODE             IIXX 44460018
         MVC   CCTPWKA+33(3),CCTPWKA+36 INTO MESSAGE               IIXX 44490018
BYPASS   EQU   *                                                 A26972 44510000
         LA    RPAR1,4(RWRK2)            GET WTO LENGTH AND PUT WTOPDUM 44540017
         LA    RPAR1,1(RPAR1)      AND ONE FOR THE ONE SUBTRACTED  IIXX 44560018
*                                  FOR THE EXECUTE INTO MOVE       IIXX 44580018
         STH   RPAR1,CCTPWKA             PARAMETER LENGTH FIELD    PDUM 44600017
         MVC   CCTPWKA+2(2),MCSFLAG  MOVE  MCSFLAGS IN WTO         IIXX 44630018
         LA    RPAR1,CCTPWKA             WTO PARAMETER ADDRESS     PDUM 44660017
         AH    RPAR1,CCTPWKA       END OF MSG                      IIXX 44670018
         CLC   MSG068(MSG068L),0(RWRK3) Q. IS MSG 68             A29779 44673019
         BE    BYPASS1                  A. YES, BRANCH           A29779 44676019
         MVC   0(4,RPAR1),CODES    MOVE ROUTE + DISP CODES TO WTO  IIXX 44680018
ADDRWTO  EQU   *                                                 A29779 44685019
         LA    RPAR1,CCTPWKA       ADDR WTO                        IIXX 44690018
         SVC   35                        WTO                       PDUM 44720017
         B     SVC80I                                              PDUM 44780017
BYPASS1  EQU   *                                                 A29779 44790019
         MVC   0(4,RPAR1),CODES1   MOVE ROUTE + DISP CODES       A29779 44800019
         B     ADDRWTO                                           A29779 44810019
*                             CONSTANTS                            PDUM 44840017
CODES    DC    X'10004000'              DESC=4,ROUTCDE=2           IIXX 44846018
CODES1   DC    X'10004040'              DESC=4,ROUTCDE=2,10      A29779 44849019
         DS    0H                                                  IIXX 44852018
MCSFLAG  DC    X'8000'             MCS FLAG FOR ROUTE CODE         IIXX 44858018
MVWTO    MVC   CCTPWKA+4(0),0(RWRK3)   EXECUTABLE INSTRUCTION      9739 44870017
         SPACE 2                                                   PDUM 44900017
ZEROS    DC    XL4'0'                                              PDUM 44960017
FIVE     DC    F'5'                     A CONSTANT NUMBER          PDUM 45020017
MODNM    DC    C'IKA     '                                         PDUM 45080017
DDD      DC    C'DDD'                                              PDUM 45140017
**********THE NEXT CARD HAS BEEN ADDED PDUM PDUM PDUM              PDUM 45200017
RESTMSG  DC    CL48'THE GRAPHIC JOB PROCESSOR MUST RESTART          '   45260017
**********THE NEXT CARD HAS BEEN ADDED PDUM PDUM PDUM              PDUM 45320017
TERMMSG  DC    CL48'THE GRAPHIC JOB PROCESSOR MUST TERMINATE        '   45380017
SGJPCON  DC    C'SATELLITE '                                       PDUM 45440017
MSG001   DC    C'IKA001I DDD - GWRITE REG 15 =   '                 IIXX 45500018
MSG001E  EQU   *                                                   PDUM 45560017
MSG006   DC    C'IKA006I DDD - BUF SEG OVFL'                       IIXX 45620018
MSG006E  EQU   *                                                   PDUM 45680017
MSG068   DC    C'IKA068I DDD - I/O ERR - GWRITE'                 A26972 45700000
MSG068E  EQU   *                                                 A26972 45720000
MSG068L  EQU   MSG068E-MSG068                                    A29779 45730019
*                                                                  PDUM 45740017
* CONSTANT RECORDS FOR DIARY DATA SET                              PDUM 45800017
*                                                                  PDUM 45860017
RECORD   EQU   *                                                   PDUM 45920017
**********THE NEXT CARD HAS BEEN ADDED PDUM PDUM PDUM              PDUM 45980017
RECORD1  DC    CL50'**************************************************' 46040017
         DC    CL20'********************'                          PDUM 46100017
         DC    CL50' '                                             PDUM 46160017
**********THE NEXT CARD HAS BEEN ADDED PDUM PDUM PDUM              PDUM 46220017
RECORD2  DC    CL50'**   PRINTED RECORD OF SESSION AT CONSOLE         ' 46280017
         DC    CL20'UNIT=             **'                          PDUM 46340017
         DC    CL50' '                                             PDUM 46400017
**********THE NEXT CARD HAS BEEN ADDED PDUM PDUM PDUM              PDUM 46460017
RECORD3  DC    CL50'**************************************************' 46520017
         DC    CL20'********************'                          PDUM 46580017
         DC    CL50' '                                             PDUM 46640017
R4AND5   DC    CL240' '                                            PDUM 46700017
RECORDE  EQU   *                                                   PDUM 46760017
         DS    0H                                                  PDUM 46820017
PREAM    DC    AL2(MSG-ATTR)                                       PDUM 46880017
SYOUTDCB DCB   DSORG=PS,MACRF=(WP),DDNAME=GJPOUT,DEVD=DA,OPTCD=W,  PDUMX46940017
               RECFM=FBS,LRECL=120,BLKSIZE=120,EODAD=FCLOSE,       PDUMX47000017
               SYNAD=FCLOSE                                        PDUM 47060017
DCBEND   EQU   *                                                   PDUM 47120017
OPENSOUT OPEN  (SYOUTDCB,(OUTPUT)),MF=L                            PDUM 47180017
OPENEND  EQU   *                                                   PDUM 47240017
CLOSEOUT CLOSE (SYOUTDCB),MF=L                                     PDUM 47300017
CLOSEND  EQU   *                                                   PDUM 47360017
         WRITE  WRITE,SF,,,'S',,,MF=L                              PDUM 47420017
WRITEND  EQU   *                                                   PDUM 47480017
         SPACE 2                                                   PDUM 47540017
*                   READ AND WRITE IN L FORM                       PDUM 47600017
         SPACE 2                                                   PDUM 47660017
READDIAL READ  DECBR,SF,,,120,MF=L                                 PDUM 47720017
READEND  EQU   *                                                   PDUM 47780017
*                                                                  PDUM 47840017
LREAD    EQU   READEND-READDIAL                                    PDUM 47900017
*                                                                  PDUM 47960017
WRITEL1  WRITE DECBW,SF,,,120,MF=L                                 PDUM 48020017
WRITEND1 EQU   *                                                   PDUM 48080017
*                                                                  PDUM 48140017
LWRITE   EQU   WRITEND1-WRITEL1                                    PDUM 48200017
*                                                                  PDUM 48260017
         SPACE 2                                                   PDUM 48320017
*                   GWRITE MF=L FORM                               PDUM 48380017
         SPACE 2                                                   PDUM 48440017
         DS    0F                                                  PDUM 48500017
GWRITEL  GWRITE DECB,STR,DCB,1000,START,DUMMY,MF=L                 PDUM 48560017
GWRITELE EQU   *                                                   PDUM 48620017
LGWRITE  EQU   GWRITELE-GWRITEL         LENGTH OF GWRITE           PDUM 48680017
         DS    0F                                                  PDUM 48740017
START    EQU   *                                                   PDUM 48800017
         GINIT                                                          48860017
BSTAT    GSRT                                                      PDUM 48920017
         GEVM                                                           48980017
         GDV   0,2168,B                                            PDUM 49040017
         GECP  B                                                   PDUM 49100017
MSGNOI   DC    CL74' '                                             PDUM 49160017
         GEVM                                                           49220017
         GDV   0,1988,B                                            PDUM 49280017
         GECP  L                                                   PDUM 49340017
MESSAGE  DC    CL48' '                                             PDUM 49400017
         GTRU  BSTAT                                               PDUM 49460017
ORDEREND EQU   *                                                   PDUM 49520017
*                                                                  PDUM 49580017
ORDERL   EQU   ORDEREND-START                                      PDUM 49640017
NODISPM  EQU   MSGNOI-START                                        PDUM 49700017
MSGDISPM EQU   MESSAGE-START                                       PDUM 49760017
         DS    0F                                                  PDUM 49820017
SVCPARM  DC    C'IERR'                                             PDUM 49880017
         DC    AL4(0)                                              PDUM 49940017
SVCPARM1 DC    C'PLOG'                  SVC PARAMETER              PDUM 50000017
         DC    XL4'0'                                              PDUM 50060017
MOVEINS  MVC   0(0,RWRK3),2(RWRK1)                                 PDUM 50120017
         DS    0F                                                  PDUM 50180017
DEFAULT  DC    X'38'                   CONTROL MASK FOR DEFAULT    PDUM 50240017
         DC    XL1'00'                                             PDUM 50300017
         DC    XL2'00'                                             PDUM 50360017
         DC    AL2(MSGEND-DEFAULT)                                 PDUM 50420017
MSG999   DC    C'IKA999I DDD IKA      ' UNIT, MODULE NAME,         IIXX 50480018
         DC    C'XXX'                   MESSAGE NO.                IIXX 50540018
MSGEND   EQU   *                                                   PDUM 50600017
         DS    0F                                                  PDUM 50660017
SETSIGN  DC    X'80000000'             SET SIGN MINUS              PDUM 50720017
         SPACE 2                                                        50726000
*********************************************************************** 50732000
*                                                                       50738000
*        MAINTENANCE AREA                                        A33564 50744000
*                                                                       50750000
*********************************************************************** 50756000
PATCH    DC    37F'0'                                            A33564 50762000
         EJECT                                                          50768000
PARALIST DSECT                                                     PDUM 50780017
MSGNO    DS    CL3                                                 PDUM 50840017
MODID    DS    CL5                                                 PDUM 50900017
CONTBIT  DS    C                                                   PDUM 50960017
INSADDR  DS    XL3                                                 PDUM 51020017
RPLYPTR  DS    F                        LENGTH AND ADDRESS         PDUM 51080017
         SPACE 2                                                   PDUM 51140017
MESSAGES DSECT                                                     PDUM 51200017
ATTR     DS    C                                                   PDUM 51260017
RESERVED DS    C                                                   PDUM 51320017
INSRELA  DS    XL2                                                 PDUM 51380017
LNG      DS    XL2                                                 PDUM 51440017
MSG      EQU   *                                                   PDUM 51500017
INS      EQU   X'40'                                               PDUM 51560017
SMB      EQU   X'10'                                               PDUM 51620017
INF      EQU   X'80'                   MASK FOR INFORMATION        PDUM 51680017
END      EQU   X'08'                                               PDUM 51740017
REPLY    EQU   X'02'                    REPLY EXPECTED (WTOR)      PDUM 51800017
IKDMOD   EQU   X'01'                    INDICATION OF SGJP         PDUM 51860017
D        EQU   C'D'                     INDICATOR FOR SGJP         PDUM 51920017
         SPACE 2                                                   PDUM 51980017
WORK     DSECT                                                     PDUM 52040017
SAVEAREA DS    XL72                                                PDUM 52100017
SAVE14   DS    F                        SAVE AREA FOR REGISTER 14  PDUM 52160017
         DS    0F                                                  PDUM 52220017
PRECORD  DS    XL(RECORDE-RECORD)                                  PDUM 52280017
         DS    D                        SPACE FOR WTOR             PDUM 52340017
         DS    F                                                   PDUM 52400017
BUFFER   DS    XL126                                               PDUM 52460017
DEC      DS    D                       SPACE TO CONVERT FROM       0200 52500017
OPENCLS  DS    CL(OPENEND-OPENSOUT)                                PDUM 52580017
SYSDCB   DS    CL(DCBEND-SYOUTDCB)                                 PDUM 52640017
WRITEL   DS    CL(WRITEND-WRITE)                                   PDUM 52700017
         SPACE 2                                                   PDUM 52760017
*                        SPACE FOR READ WRITE FUNCTION             PDUM 52820017
         SPACE 2                                                   PDUM 52880017
READDIA  DC    F'0'                     EVENT CONTROL BLOCK        PDUM 52940017
         DC    X'00'                    TYPE FIELD                 PDUM 53000017
         DC    X'80'                    TYPE FIELD                 PDUM 53060017
RLENGTH  DC    AL2(120)                 LENGTH                     PDUM 53120017
DCBADDR  DC    A(0)                     DCB ADDRESS                PDUM 53180017
AREAADDR DC    A(0)                     AREA ADDRESS               PDUM 53240017
         DC    A(0)                     RECORD POINTER WORD        PDUM 53300017
*                                                                  PDUM 53360017
WRITEOUT DC    F'0'                     EVENT CONTROL BLOCK        PDUM 53420017
         DC    X'00'                    TYPE FIELD                 PDUM 53480017
         DC    X'20'                    TYPE FIELD                 PDUM 53540017
WLENGTH  DC    AL2(120)                 LENGTH                     PDUM 53600017
WDCBADDR DC    A(0)                     DCB ADDRESS                PDUM 53660017
WAREADDR DC    A(0)                     AREA ADDRESS               PDUM 53720017
         DC    A(0)                     RECORD POINTER WORD        PDUM 53780017
SAVEBLP  DS    H                                                   PDUM 53840017
         SPACE 2                                                   PDUM 53900017
*              FOLLOWING SPACE IS FOR GRAPHIC ORDERS               PDUM 53960017
         SPACE 2                                                   PDUM 54020017
GRAORDER EQU   *                                                   PDUM 54080017
         DS    0H                      * GINIT                     PDUM 54140017
BSTAT1   DS    H                       * GSRT                      PDUM 54200017
         DS    H                       * GEVM                      PDUM 54260017
         DS    H                       * GDV                       PDUM 54320017
         DS    H                       * GDV                       PDUM 54380017
         DS    H                       * GECP                      PDUM 54440017
NUMBER   DS    CL74               * GTXT                           PDUM 54500017
         DS    H                  * GEVM                           PDUM 54560017
         DS    H                  * GDV                            PDUM 54620017
         DS    H                  * GDV                            PDUM 54680017
         DS    H                  * GECP                           PDUM 54740017
         DS    CL48                                                PDUM 54800017
GTRU     DS    H                                                   PDUM 54860017
         DS    H                       *                           PDUM 54920017
         SPACE 2                                                   PDUM 54980017
*                   WORKAREA FOR GWRITE                            PDUM 55040017
         SPACE 2                                                   PDUM 55100017
         DS    0F                                                  PDUM 55160017
GWRITE   DS    XL32                                                PDUM 55220017
         DS    0D                                                  IIXX 55250018
DEND     EQU   *                                                   PDUM 55280017
CCT      DSECT                                                     PDUM 55340017
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR    PDUM 55400017
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGPDUM 55460017
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-PDUM 55520017
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.  PDUM 55580017
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .        PDUM 55640017
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR PDUM 55700017
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DPDUM 55760017
*                   SET.                                           PDUM 55820017
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND PDUM 55880017
*                   SECOND.                                        PDUM 55940017
         SPACE 2                                                   PDUM 56000017
         SPACE 2                                                   PDUM 56060017
*                             SECTION ONE                          PDUM 56120017
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THEPDUM 56180017
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERMPDUM 56240017
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATIPDUM 56300017
         DS    0F                                                  PDUM 56360017
CCTUNAME DS    5F                  USER'S NAME                     PDUM 56420017
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION    PDUM 56480017
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBERPDUM 56540017
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA  PDUM 56600017
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SEPDUM 56660017
*                                       AT LAST BEGIN JOB          PDUM 56720017
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET PDUM 56780017
*                                       LAST BEGIN JOB             PDUM 56840017
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'SPDUM 56900017
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUNPDUM 56960017
*                                       JOB                        PDUM 57020017
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUNPDUM 57080017
*                                       JOB                        PDUM 57140017
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-PDUM 57200017
*                                       CESSOR                     PDUM 57260017
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY    PDUM 57320017
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY    PDUM 57380017
CCTJCTR  DS    H                   JOB COUNTER                     PDUM 57440017
CCTHIST  DS    109F                HISTORY OF OPERATIONS           PDUM 57500017
*                             THE FOLLOWING FIELDS OF SECTION ONE APDUM 57560017
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMEPDUM 57620017
CCTSSTAT DS    C                   SESSION STATUS                  PDUM 57680017
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND         PDUM 57740017
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND         PDUM 57800017
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS               PDUM 57860017
         EJECT                                                     PDUM 57920017
         SPACE 2                                                   PDUM 57980017
*                             SECTION TWO                          PDUM 58040017
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHIPDUM 58100017
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAPDUM 58160017
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GEPDUM 58220017
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.         PDUM 58280017
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENTPDUM 58340017
*                                       FRAME                      PDUM 58400017
CCTCCR   DS    XL3                 CURRENT COMMAND KEY             PDUM 58460017
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF APDUM 58520017
*                                       MULTIPLE DISPLAY FRAME (ENTPDUM 58580017
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATIPDUM 58640017
CCTDISM  DS    C                   DISPLAY MASK                    PDUM 58700017
CCTCSM   DS    C                   COMMAND SELECT MASK             PDUM 58760017
CCTPSTAT DS    CL2                 GJP STATUS                      PDUM 58820017
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER         PDUM 58880017
CCTPWKA  DS    CL352               PROCESSOR WORK AREA             PDUM 58940017
         SPACE 2                                                   PDUM 59000017
*                             SECTION THREE                        PDUM 59060017
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIPDUM 59120017
*                   INTO SECTION ONE OR TWO                        PDUM 59180017
CCTDGMP  DS    F                  POINTER TO DGM                   PDUM 59240017
CCTDATAP DS    F                  POINTER TO DATA NUMBER           PDUM 59300017
CCTCSTP  DS    F                  POINTER TO CST                   PDUM 59360017
CCTCPSTP DS    F                  POINTER TO CURRENT PST           PDUM 59420017
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN       PDUM 59480017
CCTDORP  DS    F                  POINTER TO DOR MODULE            PDUM 59540017
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR         PDUM 59600017
CCTDIARP DS    F                  POINTER TO DIA                   PDUM 59660017
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE PDUM 59720017
CCTACTP  DS    F                  POINTER TO ACT                   PDUM 59780017
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORSPDUM 59840017
CCTIERRP DS    F                  POINTER TO IERR                  PDUM 59900017
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA         PDUM 59960017
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA          PDUM 60020017
CCTGEND  DS    F                  POINTER TO SYSGEN DATA           PDUM 60080017
CCTJDCBP DS    F                  POINTER TO JCL DS DCB            PDUM 60140017
CCTRDCBP DS    F                  POINTER TO DIA DS DCB            PDUM 60200017
CCTDDCBP DS    F                  POINTER TO 2250 DCB              PDUM 60260017
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB           PDUM 60320017
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB           PDUM 60380017
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB          PDUM 60440017
CCTTIME  DS    F                  POINTER TO TIMER RTN FOR GJP     PDUM 60500017
CCTPECB  DS    F                  PROCESSOR'S ECB                  PDUM 60560017
CCTWECB  DS    F                  WTOR ECB                         PDUM 60620017
CCTDIAWA DS    CL136               DIARY WORK AREA                 PDUM 60680017
CCTLPWRK DS    CL184               LPMANIP WORK AREA               PDUM 60740017
CCTCSAVE DS    CL72                CTL SAVE AREA                   PDUM 60800017
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA           PDUM 60860017
CCTASAVE DS    CL72                DAT SAVE AREA                   PDUM 60920017
*                                                                  PDUM 60980017
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.  PDUM 61040017
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW      PDUM 61100017
*                                                                  PDUM 61160017
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA        PDUM 61220017
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER          PDUM 61280017
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTEDPDUM 61340017
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE          PDUM 61400017
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE      PDUM 61460017
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES               PDUM 61520017
CCTIELST EQU   CCTLPWRK+68         AREA USED FOR GTNIT/GTEND PARAM PDUM 61580017
CCTRDLST EQU   CCTIELST+24         AREA USED FOR GTRED PARAMETER LIPDUM 61640017
CCTWRLST EQU   CCTRDLST+16         AREA USED FOR GTWRT PARAMETER LIPDUM 61700017
CCTTSLST EQU   CCTWRLST+20         AREA USED FOR GTCLT PARAMETER LIPDUM 61760017
CCTDSREF EQU   CCTTSLST+12         DATA SET REFERENCE NUMBER       PDUM 61820017
CCTSTCOD EQU   CCTDSREF+4          WORD TO CONTAIN RESULTS OF INIT,PDUM 61880017
CCTDATYP EQU   CCTSTCOD+4          WORD TO CONTAIN DATA TYPE CODE  PDUM 61940017
CCTCTLOP EQU   CCTDATYP+4          WORD CONTAINING CODE DENOTING DEPDUM 62000017
*                                  INATION OF DATA                 PDUM 62060017
CCTTSTCD EQU   CCTCTLOP+4          WORD TO CONTAIN CODE REPRESENTINPDUM 62120017
*                                  THE I/O OPERATION TO BE TESTED BPDUM 62180017
*                                  GTCLT                           PDUM 62240017
CCTIOECB EQU   CCTTSTCD+4         ECB USED IN WTOR ON I/O ERRORS   PDUM 62300017
CCTREPAR EQU   CCTIOECB+4         AREA USED FOR WTOR REPLY         PDUM 62360017
CCTERLST EQU   CCTREPAR+4          AREA FOR IERR MODEL PARAMETER LIPDUM 62420017
         EJECT                                                     PDUM 62480017
CVT      DSECT                                                     PDUM 62540017
         CVT   SYS=VMS                                             PDUM 62600017
         EJECT                                                     PDUM 62660017
*                                                                  PDUM 62720017
*  GFX LIST POINTED TO BY CVT                                      PDUM 62780017
*                                                                  PDUM 62840017
GRAPLIST DSECT                                                     PDUM 62900017
GOCT     DS    1F                      POINTER TO THE OCT          PDUM 62960017
GGAPR    DS    1F                      POINTER TO GAPR             PDUM 63020017
GCANC    DS    1F                      POINTER TO CANCEL RTN       PDUM 63080017
GFXOCTHD DSECT                                                     PDUM 63140017
GFXHDSTR EQU   *                       START OF HEADER RECORD      PDUM 63200017
OCTSYS   DS    CL1                     BASE SYSTEM                 PDUM 63260017
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS           PDUM 63320017
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS     PDUM 63380017
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD  PDUM 63440017
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD  PDUM 63500017
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS         PDUM 63560017
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS         PDUM 63620017
         DS    0H                                                  PDUM 63680017
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250        PDUM 63740017
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD  PDUM 63800017
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD  PDUM 63860017
         DS    0F                                                  PDUM 63920017
OCTFGREG DS    CL4                      REGION SIZE GJP            PDUM 63980017
OCTFUREG DS    CL4                      REGION SIZE USER FGD       PDUM 64040017
OCTBUREG DS    CL4                      REGION SIZE USER BGD       PDUM 64100017
OCTGTCB  DS    CL4                     TCB ADDRESS OF GFX          PDUM 64160017
OCTHRES  DS    CL4                     RESERVED                    PDUM 64220017
OCTNAME  DS    CL20                     PROGRAMMER NAME            PDUM 64280017
OCTACCT  DS    CL20                     ACCOUNT NUMBER             PDUM 64340017
GFXHDEND EQU   *                       END OF HEADER RECORD        PDUM 64400017
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD   PDUM 64460017
         EJECT                                                     PDUM 64520017
GFXOCTEN DSECT                                                     PDUM 64580017
         DS    0F                                                  PDUM 64640017
GFXENSTR EQU   *                       START OF ENTRY RECORD       PDUM 64700017
OCTECB   DS    CL4                      ECB                        PDUM 64760017
OCTUCB   DS    CL4                      UCB ADDRESS                PDUM 64820017
OCTUNIT  DS    CL4                      UNIT ADDRESS               PDUM 64880017
OCTCOUNT DS    CL4                      JOB COUNT                  PDUM 64940017
OCTNOTE  DS    CL4                      NOTE                       PDUM 65000017
OCTABEND DS    A                       ABEND CODE                  PDUM 65060017
OCTFPART DS    CL2                      PARTITION NUMBER (MFT ONLY)PDUM 65120017
OCTDNOTE DS    CL3                      NOTE FIELD FOR DIARY DATA SPDUM 65180017
OCTIERNO DS    CL3                      INTERNAL ERROR NUMBER      PDUM 65240017
*******************************************************************PDUM 65300017
****                          ATTRIBUTE 1                          PDUM 65360017
*******************************************************************PDUM 65420017
OCTATTR1 DS    CL2                      ATTRIBUTES                 PDUM 65480017
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE    PDUM 65540017
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PPDUM 65600017
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING    PDUM 65660017
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ  PDUM 65720017
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SPDUM 65780017
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER PDUM 65840017
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER PDUM 65900017
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250      PDUM 65960017
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB     PDUM 66020017
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECPDUM 66080017
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT      PDUM 66140017
OCTBERR1 EQU   X'10'          0-                  1-GJP INTERNAL ERPDUM 66200017
OCTBERR2 EQU   X'08'          0-                  1-GJP INTERNAL ERPDUM 66260017
*******************************************************************PDUM 66320017
****                          ATTRIBUTE 2                          PDUM 66380017
*******************************************************************PDUM 66440017
OCTATTR2 DS    CL2                      ATTRIBUTES                 PDUM 66500017
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERPDUM 66560017
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB PDUM 66620017
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF         PDUM 66680017
OCTBFAST EQU   X'10'          0-                  1-FAST STOP      PDUM 66740017
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP    PDUM 66800017
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP      PDUM 66860017
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND  PDUM 66920017
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250       PDUM 66980017
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INPDUM 67040017
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USPDUM 67100017
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST   PDUM 67160017
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST    PDUM 67220017
*******************************************************************PDUM 67280017
****                          ATTRIBUTE 3                          PDUM 67340017
*******************************************************************PDUM 67400017
OCTATTR3 DS    CL2                      ATTRIBUTES                 PDUM 67460017
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERPDUM 67520017
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB PDUM 67580017
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF         PDUM 67640017
OCTBFASM EQU   X'10'          0-                  1-FAST STOP      PDUM 67700017
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP    PDUM 67760017
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP      PDUM 67820017
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND  PDUM 67880017
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250       PDUM 67940017
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INPDUM 68000017
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USPDUM 68060017
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST   PDUM 68120017
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST    PDUM 68180017
*******************************************************************PDUM 68240017
****                          ATTRIBUTE 4                          PDUM 68300017
*******************************************************************PDUM 68360017
OCTATTR4 DS    CL2                      ATTRIBUTES                 PDUM 68420017
GFXENEND EQU   *                       END OF ENTRY RECORD         PDUM 68480017
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD        PDUM 68540017
         END                                                            73600016
