         TITLE 'IKAINIT INITIALIZATION ROUTINE FOR IKAGJP'              00100016
*                                                                       00200016
IKAINIT  CSECT                                                          00300016
*2402,502450-502460                                                LCLF 00330017
*2567,107400                                                       9317 00360017
*1074,096200-096300                                                3052 00365018
*1074,158200-158800,165600,182300,192800,198000,272400,273000,     IIXX 00368018
*     273600-273800,458910-458950,502200,502310,505440,502443-     IIXX 00371018
*     502440,502680,502788,502866,502908-502938,749790             IIXX 00375018
*1074,222000,223000                                                3054 00380018
* 546000-547000                                                  A36205 00385020
*                                                                       00390020
*********************************************************************** 00395020
*                                                                       00400016
* MODULE NAME       -IKAGJP                                             00470016
*                                                                       00540016
* CSECT  NAME       -IKAINIT                                            00610016
* ENTRY POINT       -IKAINIT                                            00680016
* OTHER  CSECTS IN MODULE     -IKAMINIT                                 00750016
*                                                                       00820016
* CHART ID          -EA                                                 00890016
*                                                                       00960016
* FUNCTION          - INITIALIZE  GJP                                   01030016
*                   - REINITIALIZE GJP BETWEEN JOBS                     01100016
*                   - CHECK FOR SYSTEM ERRORS                           01170016
* ATTRIBUTES        - NON-RESIDENT                                      01240016
*                   - REENTRANT                                         01310016
* OPERATION         - PART 1 -INITIALIZATION ************************** 01380016
*                            -GETMAIN FOR CONSOLE CONTROL TABLE (CCT),  01450016
*                                         DCBS, GRAPHIC MACROS, AND     01520016
*                                         WORK SPACE.                   01590016
*                            -FIND OVERALL CONTROL TABLE (OCT) ENTRY    01660016
*                                         VIA COMMAND INPUT BUFFER (CIB 01730016
*                            -FOR DESIGNATED 2250 , OPEN FOLLOWING DCBS 01800016
*                                         -JCL                          01870016
*                                         -GRAPHIC                      01940016
*                                         -EXTRACT                      02010016
*                                         -EXTRACT (RECALL MODE)        02080016
*                            -ISSUE GRAPHIC MACROS                      02150016
*                                         -CREATE GRAPHIC ATTENSION     02220016
*                                          CONTROL BLOCK (GACB)         02290016
*                                         -ISSUE SPECIFY ATTENSION      02360016
*                                          ROUTINE (SPAR)               02430016
*                                         -ASSIGN BUFFER                02500016
*                            -GETMAIN FOR GRAPHICS WORK AREA            02570016
*                            -LOAD FOLLING MODULES                      02640016
*                                         -IKATCST0 (CONSOLE SUPPORT    02710016
*                                          TABLE)                       02780016
*                                         -IKANUC (CONSOLE SUPPORT MOD- 02850016
*                                          ULES)                        02920016
*                                         -IKAIERR (ERROR MSG ROUTINE)  02990016
*                            -DETERMINE IF REINITIALIZATION IS REQUIRED 03060016
*                                         -ANY SYSTEM MSG BLOCK (SMB)   03130016
*                                          OR ANY INDICATION OF SYSTEM  03200016
*                                          ERROR, OR ANY VARY OFFGFX    03270016
*                                          COMMAND WILL FORCE REINITIAL 03340016
*                                          IZATION                      03410016
* OPERATION         -PART 2  -REINITIALIZATION ************************ 03480016
*                            -READ EXTRACT DATA SET INTO CCT (HI BYTE   03550016
*                             IN OCTNOTE WILL BE 'F0'IF RECALL MODE     03620016
*                             DATA SET IS TO BE READ IN PLACE OF NORMAL 03690016
*                             EXTRACT DATA SET)                         03760016
*                            -POINT TO PLACE IN EXTRACT DATA SET TO BE  03830016
*                             USED FOR NEXT RECORD                      03900016
*                            -SET UP ANY ERROR MSGS (SMBS)IN CCTWKA FOR 03970016
*                             SMB PROCESSOR                             04040016
*OPERATION         -PART 3   -COMPLETE INITIALIZATION AND EXIT          04110016
*                            -MOVE PROCESSING INFORMATION (PRIORITY,    04180016
*                             REGION,SYSOUT CLASSES, 2250 UNIT ADDR,    04250016
*                             JOB COUNT INTO CCT                        04320016
*                  -PART 3A  -IF SIMPLE INITIALIZATION HAS BEEN DONE    04390016
*                             LOAD IKATLON0, FREEMAIN WORKAREA NOT      04460016
*                             REQUIRED, XCTL TO IKACTL                  04530016
*                  -PART 3B  -IF REINITIALIZATION HAS BEEN DONE         04600016
*                             OPEN DATA SET FOR DIARY IF A PRINTED REC- 04670016
*                             ORD HAS BEEN REQUESTED                    04740016
*                             SET COMMAND SELECT MASK                   04810016
*                             SET DISPLAY MASK                          04880016
*                             FREEMAIN WORK AREA NO LONGER REQUIRED     04950016
*                             XCTL TO SMB PROCESSOR                     05020016
*                                                                       05090016
*                                                                       05300016
* INPUT           -REGISTER ONE POINTS TO PARMLIST                      05400016
*                    WORD ONE                                           05500016
*                    WORD TWO                                           05600016
*                    WORD THREE    ADDR COMMAND INPUT BUFFER (CIB)      05700016
*                 - OCT HEADER (ADDR IN CVT)                            05800016
*                 - OCT ENTRY (ADDR IN CIB)                             05900016
*                                                                       06000016
* OUTPUT           -REGISTER 1 CONTAINS CCT ADDRESS                     06100016
*                  -SET SYSTEM MESSAGE IN CCTPWKA                       06200016
*                                                                       06300016
* EXTERNAL REFERENCES -NONE                                             06400016
*                                                                       06500016
* ERROR CONDITIONS -NONE                                                06600016
*                                                                       06700016
*                                                                       06800016
* DEFINE GENERAL REGISTERS                                              06900016
*                                                                       07000016
RPAR0    EQU   0                        PARAMETER REGISTER              07100016
RPAR1    EQU   1                        PARAMETER REGISTER              07200016
RCCT     EQU   2                        BASE FOR CCT DCB ETC            07300016
RGRAPHIC EQU   3                        BASE GRAPHIC AREA               07400016
RWORK    EQU   4                        GENERAL PURPOSE                 07500016
ROPEN    EQU   5                        REGISTER FOR OPEN MACRO         07600016
RNUC     EQU   6                                                        07700016
RLENGTH  EQU   7                                                        07800016
RINCR    EQU   8                       INCREAMENT REGISTER              07900016
REND     EQU    9                      ADDRESS OS END OF GETMAIN        08000016
RBEGIN   EQU   10                       ADDRESS OF GETMAIN              08100016
RBASE    EQU   11                       BASE REGISTER                   08200016
RSAVE    EQU   13                                                       08300016
RRET     EQU   14                       RETURN REGISTER                 08400016
RBR      EQU   15                       BRANCH REGISTER                 08500016
THREE    EQU   3                                                   RMIF 08530018
NINE     EQU   9                                                   RMIF 08560018
EXTNOTE  EQU   2                        POINTER TO NOTE OF EXT DCB      08600016
UNITADDR EQU   6                        POINTER TO GRAPHIC 255 ADDRESS  08700016
*                                       PASSED BY GFX                   08800016
SYSOUTCL EQU   9                        POINTER TO SYSOUT CLASS         08900016
FGRPRI   EQU   13                       POINTER TO GROUP (MFT-II) OR    09000016
*                                       PRIORITY (MVT) FOR GJP AND PROG 09100016
BGRPRI   EQU   15                       POINTER TO GROUP OR PRIORITY    09200016
*                                       FOR GJP OR USER PROG BACKGROUND 09300016
JOBCTR   EQU   17                       JOB COUNTER                     09400016
EODADDR  EQU   33                       EOD ADDRESS IN DCB              09500016
LRECORD  EQU   356                      LENGTH OF PER EXTRACT RECORD    09600016
GOODOPEN EQU   X'10'                                                    09610016
SYNAD    EQU   X'39'                                               3052 09620018
EODAD    EQU   X'21'                                               3052 09630018
VIII     EQU   8                        EQUATE                     IIXX 09640018
A        EQU   *                                                        09650016
         TITLE 'IKAINIT PART 1  INITIALIZATION  ***********************X09700016
               ********************'                                    09750016
*                                                                       09800016
* SAVE GENERAL REGISTERS, SET BASE, GET NECESSARY CORE FOR GJP WORKAREA 09900016
*                                                                       10000016
         SAVE  (14,12)                  SAVE GENERAL REGISTERS          10100016
         BALR  RBASE,0                  SET UP BASE                     10200016
         USING *,RBASE                                                  10300016
RCVT     EQU   3                                                        10400016
ROCT     EQU   12                                                       10500016
         USING INITWKA,RCCT        DSECT FOR CCT                        10600016
         USING DCVT,RCVT           DSECT FOR CVT                        10700016
         L     RCVT,CVTPTR        SET BASE FOR CVT                      10710016
         L     RWORK,CVTTCBP      RWORK HAC ADDR OF                     10720016
         L     RWORK,4(RWORK)     RWORK HAS ADDR CU                     10730016
         OI    20(RWORK),X'20'         SET BIT IN TCB              9317 10740017
*                                 FOR ABEND RTN FOR                     10750016
         LR    RWORK,RPAR1         SAVE ADDR PARM LIST                  10800016
         GETMAIN R,LV=INITWKAE-INITWKA  GETMAIN FOR CCT                 10900016
         LR    RCCT,RPAR1              LOAD GETMAIN ADDRESS             11000016
         L     RLENGTH,LWKA             LOAD GETMAIN LENGTH             11100016
         LR    RBEGIN,RPAR1             LOAD START ADDRESS              11200016
         LA    REND,0(RBEGIN,RLENGTH)   LOAD THE END ADDRESS            11300016
         LA    RINCR,8                  SET INCREMENT                   11400016
         SR    REND,RINCR              SUBTRACT 8                       11500016
CLEAR    XC    0(8,RBEGIN),0(RBEGIN)    CLEAR GETMAIN AREA              11600016
         BXLE  RBEGIN,RINCR,CLEAR       CHECK IF FINISH CLEAR JOB       11700016
         ST    RLENGTH,LSAVE1           SAVE GETMAIN LENGTH AT THE      11800016
*                                       FIRST WORD OF GETMAIN AREA      11900016
         ST    RSAVE,ISAVE+4            SAVE CALLING SAVE ADDRESS       12000016
         LA    RSAVE,SAVE2        ADDR SAVE AREA FOR INIT               12050016
MINUSONE EQU   X'FFF0'            TO LOWER PRIORITY                     12060016
         CHAP  MINUSONE           LOWER PRIORITY FR                     12070016
*                                                                       12100016
* GET ADDR OF OCT HEADER AND ENTRY RECORD AND SAVE THEM IN CCTWKA       12200016
*                                                                       12300016
         ST    RWORK,ADPARM        SAVE ADDR PARAMETER LIST             12400016
         LA    RWORK,ANSWAREA           ANSWER AREA DDRESS         EXTR 12410019
         LA    RPAR1,EXTRCT             LIST FORM ADDRESS          EXTR 12420019
         EXTRACT (RWORK),FIELDS=COMM,MF=(E,(1))                    EXTR 12430019
         L     RWORK,ANSWAREA           POINTER TO COMM.PARM.LIST  EXTR 12440019
         ST    RWORK,CCTTIME            SAVE IT IN CCT             EXTR 12450019
         L     RWORK,4(RWORK)           GET CIB ADDRESS            EXTR 12460019
       LR    RINCR,RWORK          ADDR CIB                              12530016
         LA    RINCR,127(RINCR)   ADDR END OF CIB                       12560016
SCANCIB  CLC   0(9,RWORK),ENTRYEQU SCAN CIB FOR ADDR OF OCT HEADER      12600016
         BE    FOUNDADR            FOUND 'OCTENTRYE' IN CIB             12700016
         LA    RWORK,1(RWORK)      NOT FOUND, INCREMENT                 12800016
         CR    RINCR,RWORK        Q. END OF CIB                         12830016
         BE    NOTINCIB                                                 12860016
         B     SCANCIB                                                  12890016
NOTINCIB EQU   *                                                        12920016
         MVC   ERRORMSG(EL),CIBMSG      MOVE IN BAD CIB MSG             12940016
         B     ERRORRTN                 ISSUE MSG                       12960016
FOUNDADR L     RCVT,CVTPTR        SET BASE FOR CVT                      12980016
         L     ROCT,CVTQOCR       ADDR LIST OF POINTERS                 13010016
         LTR   ROCT,ROCT                Q. GFX RUNNING             IIXX 13020018
         BZ    NOFREEGR                 EXIT IF NOT                IIXX 13030018
         L     ROCT,0(ROCT)       ADDR OCT HEADER                       13040016
         ST    ROCT,ADOCTHD       SAVE ADDR OCT HEADER IN GETMAIN       13070016
         USING  GFXOCTHD,ROCT                                      PDUM 13074016
         TM    OCTSYS,X'2'                                         PDUM 13078016
         BC    8,MVT              SKIP IF MVT SYSTEM               PDUM 13082016
         DROP   ROCT                                               PDUM 13086016
         OI    CCTDISM,X'10'                                       PDUM 13090016
MVT      EQU   *                                                   PDUM 13094016
         LA    RINCR,15           SETRINCR TO MAX NUMB OF 2250'S        13100016
         USING GFXOCTHD,ROCT                                            13130016
         LA    ROCT,GFXHDSZE(ROCT)  SET BASE FORFIRST OCT ENTRY         13160016
         USING GFXOCTEN,ROCT                                            13190016
         MVC   CCTUNIT(THREE),NINE(RWORK)  UNIT ADDR FROM CIB      RMIF 13200018
SCANENT  CLC   9(3,RWORK),OCTUNIT+1  Q. IS THIS THE CORRECT ENTRY       13220016
         BE    FOUNDENT                                                 13250016
         LA    ROCT,GFXENSZE(ROCT)  A. NO    SET BASE FOR NEXT ENTRY    13280016
         BCT   RINCR,SCANENT                                            13310016
         B     NOTINCIB                                                 13340016
FOUNDENT ST    ROCT,ADOCTEN                                             13370016
*                                                                       13400016
         MVC   CCTUNIT(3),OCTUNIT+1                                PDUM 13450016
* INITIALIZE CONSOLE CONTROL TABLE                                      13500016
*                                                                       13600016
         MVI   CCTDIAWA,C' '            BLANK DIA WORK AREA             13700016
         MVC   CCTDIAWA+1(135),CCTDIAWA IN CCT                          13800016
*                                                              CCTDIAWA 13900016
         LOAD  EP=IKATCST0         LOAD COMMAND SELECT TABLE       3054 13930018
         ST    RPAR0,CCTCSTP       SAVE ADDR                       3054 13960018
         EJECT                                                          14000016
*                                                                       14100016
* CREATE JCL GRAPHIC EXTRACT DCB'S                                      14200016
*                                                                       14300016
         MVC   DJCLDCB(LJCLDCB),JCLDCB  MAKE JCLDCB REENTERABLE         14400016
         MVC   DGRADCB(LGRADCB),GRADCB MAKE GRADCB REENTERABLE          14800016
         MVC   DEXTDCB(LEXTDCB),EXTDCB  MAKE EXTDCB REENTERABLE         15200016
         MVC   DEXTDCB1(LEXTDCB1),EXTDCB1 MAKE EXT DCB1 REENTERABLE     15600016
*                                                                       15900016
* OPEN JCL GRAPHIC EXTRACT DCB'S                                        16000016
*                                                                       16100016
         MVC   DOPENDCB(LOPEN),OPENDCB  MAKE OPEN MACRO REENTERABLE     16200016
         LA    RPAR1,DOPENDCB           LOAD ITS ADDRESS                16300016
         OPEN  (DJCLDCB,(INOUT),DGRADCB,(INOUT),DEXTDCB,(INOUT),       X16400016
               DEXTDCB1,(INOUT)),MF=(E,(1))                             16500016
         EJECT                                                          16503016
         USING IHADCB,RWORK             USING RWORK AS BASE TO CHECK    16506016
*                                       ON 'OPEN'                       16509016
CHECK1   LA    RWORK,DJCLDCB            *                               16512016
         TM    DCBOFLGS,GOODOPEN        * CHECK JCLDCB                  16515016
         BO    CHECK2                   JCLDCB OPENED OK.               16518016
         MVC   ERRORMSG(EL),DCBMSG                                      16521016
         MVC   ERRORDCB(EE),DCBMSG2     'OPEN OF JCL DCB' MSG PARM SET  16524016
         B     ERRORRTN                 IKAIERR                         16527016
CHECK2   ST    RWORK,CCTJDCBP      PUT PTR TO OPEN JCL DCB IN CCT  PDUM 16529016
         LA    RWORK,DGRADCB       SET BASE FOR GRAPHIC DCB        PDUM 16531016
         TM    DCBOFLGS,GOODOPEN        * CHECK GRAPHIC DCB             16533016
         BO    CHECK3                   GRAPHIC DCB OPENED OK           16536016
         MVC   ERRORMSG(EL),DCBMSG                                      16539016
         MVC   ERRORDCB(EE),DCBMSG3     'OPEN OF GRA DCB' MSG PARM SET  16542016
         B     ERRORRTN                 GO TO ERROR ROUTINE             16545016
CHECK3   ST    RWORK,CCTDDCBP      PUT PTR TO OPEN GRA DCB IN CCT  PDUM 16547016
         LA    RWORK,DEXTDCB       SET BASE FOR EXT DCB            PDUM 16549016
         TM    DCBOFLGS,GOODOPEN        * CHECK ON EXTDCB               16551016
         BO    CHECK4                   EXTRACT DATA SET NOW OPEN       16554016
         MVC   ERRORMSG(EL),DCBMSG                                      16557016
         MVC   ERRORDCB(EE),DCBMSG1     MOVE IN ERROR MSG          IIXX 16560018
         B     ERRORRTN                 ISSUE ERROR MSG                 16563016
CHECK4   ST    RWORK,CCTEDCBP      PUT PTR TO GOOD EXT DCB IN CCT  PDUM 16565016
         LA    RWORK,DEXTDCB1      SET BASE FOR EXT1 DCB           PDUM 16567016
         TM    DCBOFLGS,GOODOPEN        * CHECK RECALL MODE EXTRACT DS  16569016
         BO    CHECKEND                 * EXTDCB OK                     16572016
         MVC   ERRORMSG(EL),DCBMSG                                      16575016
         MVC   ERRORDCB(EE),DCBMSG4     MOVE IN ERROR MSG               16578016
         B     ERRORRTN                 ISSUE ERROR MSG                 16581016
CHECKEND EQU   *                                                        16584016
         ST    RWORK,CCTEDCB1      PUT PTR TO GOOD EXT1 DCB IN CCT PDUM 16585016
         DROP  RWORK                                                    16587016
         MVC   EODADDR+DEXTDCB1(3),EODRTN    PUT ADDR OF'END OF DATA'   16590016
         MVC      SYNAD+DEXTDCB1(3),IORTN    PUT ADDR OF 'SYNCH' ERROR  16593016
         EJECT                                                          16600016
*                                                                       16700016
* CREATE GRAPHIC ATTENTION CONTROL BLOCK AND COMMUNITE AREA             16800016
*                                                                       16900016
         MVC   GACBDGM(LGACB),GACB      MOVE GACB IN GETMAIN AREA       17000016
         LA    RWORK,COMUTAR            LOAD COMMUNICATE AREA ADDRES    17100016
         ST    RWORK,GACBDGM            STORE IT IN GACB                17200016
         LA    RWORK,DGRADCB            LOAD GRAPHIC DCB ADDRESS        17300016
         ST    RWORK,GACBDGM+4         STORE IT IN GACBDGM              17400016
         LA    RWORK,8(RCCT)           GET CCT ADDRESS                  17500016
         ST    RWORK,COMUTAR+16         STORE IT IN COMMUNICATE AREA    17600016
         LA    RWORK,GACBDGM                                            17630016
         ST    RWORK,CCTGACBP     SAVE ADDR OF GRAPHIC ACCESS CONTROL   17660016
*                                                                       17700016
* SPECIFY ATTENTION ROUTINE                                             17800016
*                                                                       17900016
         MVI   CCTPSTAT+1,X'20'     SET IGNORE ATTENSION BIT            17950016
         MVC   DSPAR(LSPAR),SPAR        MAKE SPAR REENTERABLE           18000016
         LA    RPAR1,DSPAR              GET ITS ADDRESS AND             18100016
         SPAR  (GACBDGM),MF=(E,(1))     ISSUE SPAR MACRO                18200016
         LTR   RBR,RBR                                                  18210016
         BZ    SPAROK                   SPAR OK                         18220016
S3       MVC   ERRORMSG(EL),SPARMSG     *                               18240016
         STC   15,ERROR15               PUT RETURN CODE IN IERR PARM    18245016
         B     ERRORRTN                 *                               18250016
SPAROK   EQU   *                                                        18260016
         OI    CCTGACBP,X'80'           SET HI BIT TO SHOW SPAR OK PDUM 18280016
*                                                                       18300016
* ASSIGN BUFFER FOR GRAPHIC ROUTINE E FORM                              18400016
*                                                                       18500016
         L     ROCT,ADOCTHD        LOAD ADDR OCT HEADER                 18600016
         USING GFXOCTHD,ROCT       DSECT FO                             18700016
         CLI   OCTSYS,X'F3'        TEST IF SYSTEM IS ITSS               18800016
         BE    SKIP                                                     18900016
         MVC   GBUFFER(LASNLIST),ASNLIST  ASSIGN BUFFER REENTRABLE      19000016
         L     RWORK,CCTDDCBP                                           19100016
         ASGNBFR 0(RWORK),MF=(E,GBUFFER)                                19200016
         LTR   RBR,RBR                  TEST RETURN CODE                19220016
         BZ    SKIP                     BRANCH IF OK                    19240016
ASGNIMP  MVC   ERRORMSG(EL),AS1        MSG FOR IERR                     19275016
         STC   RBR,ERROR15              PUT RETURN CODE INTO LIST  IIXX 19280018
         B     ERRORRTN                                                 19285016
SKIP     EQU   *                                                        19300016
         OI    CCTDDCBP,X'80'           SET HI BIT TO SHOW ASGNBF- PDUM 19350016
         EJECT                                                          19400016
*                                                                       19500016
* GETMAIN FOR GRAPHIC ROUTINES WORK AREA                                19600016
*                                                                       19700016
         L     RPAR0,LGRAPHIC           LOAD GETMAIN LENGTH        IIXX 19760018
         GETMAIN R,LV=(0)                                          IIXX 19820018
         LR    RGRAPHIC,RPAR1           SET GETMAIN BASE                19900016
         USING GRAPHIC,RGRAPHIC                                         20000016
         L     RLENGTH,LGRAPHIC         LOAD GETMAIN LENGTH             20100016
         LR    RBEGIN,RPAR1             LOAD START ADDRESS              20200016
         LA    REND,0(RBEGIN,RLENGTH)   LOAD THE END ADDRESS            20300016
         LA    RINCR,8                  SET INCREMENT                   20400016
         SR    REND,RINCR              SUBTRACT 8                       20500016
CLEAR1   XC    0(8,RBEGIN),0(RBEGIN)    CLEAR GETMAIN AREA              20600016
         BXLE  RBEGIN,RINCR,CLEAR1      BRANCH INDEX EQUAL OR LOW       20700016
         ST    RLENGTH,LSAVE2           SAVE GETMAIN LENGTH AT THE      20800016
*                                       FIRST WORD OF GETMAIN AREA      20900016
         LA    RWORK,DGMWKA1            LOAD DGMWKA1 ADDRESS            21000016
         ST    RWORK,CCTGWRKP           SAVE IT IN CCT                  21100016
*                                                              CCTGWRKP 21200016
         LA    RWORK,ACTWKA             LOAD ATTENTION RTN WORKAREA     21300016
         ST    RWORK,CCTACTP            AND SAVE IT IN CCT              21400016
*                                                              CCTACTP  21500016
         LA    RWORK,DGMWKA2            LOAD DGMWKA2 ADDRESS            21600016
         ST    RWORK,DGMWKA1+44         AND SAVE ITS ADDRESS            21700016
         EJECT                                                          21800016
*                                                                       21900016
* LOAD IN MODULES AND TABLES                                            22000016
*                                                                       22100016
*                                                              CCTCSTP  22400016
         LOAD  EP=IKANUC                LOAD IKANUC MODULE IN CORE      22500016
*                                       THIS MODULE IS LINK EDITED WITH 22600016
*                                       DGM DAT DMSG JCL DIA LYMANIP    22700016
*                                       SYSGEN DOR MODULES              22800016
         LR    RNUC,RPAR0               LOAD IKANUC ADDRESS             22900016
         MVC   CCTDGMP(4),0(RNUC)       STORE DGM ADDRESS IN CCT        23000016
*                                                              CCTDGMP  23100016
         MVC   GACBDGM+16(4),4(RNUC)    STORE DAT ADDRESS IN GACB       23200016
         MVC   CCTDMRP(4),8(RNUC)       STORE DMSG ADDRESS IN CCT       23300016
*                                                              CCTDMRP  23400016
         MVC   CCTJCLGP(4),12(RNUC)     MOVE JCL GENERATOR ADDRESS      23500016
*                                                              CCTJCLGP 23600016
         MVC   CCTDIARP(4),16(RNUC)     MOVE DIA ADDRESS IN CCT         23700016
*                                                              CCTDIARP 23800016
         MVC   CCTPKYM(4),20(RNUC)      MOVE KYMANIP ADDRESS IN CCT     23900016
*                                                              CCTDIARP 24000016
         MVC   CCTGEND(4),24(RNUC)      MOVE SYSGEND ADDRESS IN CCT     24100016
*                                                           CCTCORP     24200016
         MVC   CCTDORP(4),28(RNUC)      MOVE IKADOR ADDRESS IN CCT      24300016
*                                                              CCTGEND  24400016
         MVC   CCTDIRP(4),32(RNUC)      MOVE DIR MODULE ADDRESS IN CCT  24500016
*                                                              CCTDIRP  24600016
         LOAD  EP=IKAIERR               LOAD IERR IN CORE               24700016
         ST    RPAR0,CCTIERRP                                           24850016
         BAL   R10,MIP             GO READ MANUAL INPUT TO CLEAR   IIXX 25150018
*                                  ANY ATTENSIONS                       25450018
         EJECT                                                          25900016
*                                                                       26000016
* FILL UP CCT WITH INFORMATION PASSED BY GFX                            26100016
*                                                                       26200016
RRECNO   EQU   7                        CONTAIN THE NUMBER OF RECORDS   26300016
*                                       TO BE READ                      26400016
RDCBBASE EQU   7                        BASE FOR DIA DCB DSECT          26500016
RAREA    EQU   8                        POINTER TO READ IN AREA         26600016
RLINK    EQU   9                        INTERAL LINK REGISTER           26700016
RJOBCTR  EQU   10                       CONTAIN JOB COUNTER (BINARY)    26800016
RDECB    EQU   10                       POINTER TO READ DECB            26900016
         L     ROCT,ADOCTEN        LOAD ADDR OCT ENTRY                  27000016
         USING GFXOCTEN,ROCT       DSECT FOR OCT ENTRY RECORD           27100016
         TM    OCTATTR1+1,OCTERR1  TEST ERROR BIT                  PDUM 27120016
         BC    1,FILLCCT           IF ERROR SIMULATE LOGON         PDUM 27140016
         TM    OCTATTR2,OCTABND    TEST ABEND BIT                  PDUM 27160016
         BC    1,FILLCCT           IF ABEND SIMULATE LOGON         PDUM 27180016
         TM    OCTATTR1+1,OCTBSMBB     TEST SMB BIT                     27200016
         BO    REX                     BRABCH IF YES                    27220016
         TM    OCTATTR1,OCTBIODQ+OCTBIOGS+OCTBIOGD+OCTBIOUS        IIXX 27240018
*                                 Q. ANY I/O ERROR BIT SET IN OCT       27260016
         BC    5,REX              A. YES READ EXT RECORD INTO CCT       27280016
         TM    OCTATTR2,OCTBFAST+OCTBMED+OCTBSLOW                  IIXX 27300018
*                                 Q. ANY STOP BITS SET IN OCT           27320016
         BC    5,REX              A. YES READ EXT RECORD INTO CCT       27340016
         CLC   OCTATTR1(VIII),ZEROS8    Q. OCT ENTRY VALID         IIXX 27350018
         BE    NOGDCB                   NO - TERMINATE             IIXX 27360018
         B     FILLCCT                  GO TO LOG ON               IIXX 27370018
         SPACE                                                          27404016
         SPACE                                                          27408016
         SPACE                                                          27412016
         SPACE                                                          27416016
         SPACE                                                          27420016
         SPACE                                                          27424016
         SPACE                                                          27428016
         SPACE                                                          27432016
*********************************************************************** 27436016
*********************************************************************** 27440016
*********************************************************************** 27444016
         SPACE                                                          27448016
         SPACE                                                          27452016
*                     IKAINIT END OF PART 1  (INITIALIZATION)           27456016
         SPACE                                                          27460016
         SPACE                                                          27464016
         SPACE                                                          27468016
*********************************************************************** 27472016
*********************************************************************** 27476016
*********************************************************************** 27480016
         TITLE  'IKAINIT PART 2  REINITIALIZATION)(ONLY IF SMB, ERROR, X27490016
               OR VARY BITS ON IN OCT)'                                 27500016
REX      EQU   *                                                        27510016
         MVC      EODAD+DEXTDCB(3),EODRTN    SET UP END OF DATA ROUTINE 27520016
         MVC      EODAD+DEXTDCB1(3),EODRTN   IN EXT & EXT1 DCBS         27530016
         MVC      SYNAD+DEXTDCB(3),IORTN     PUT SYNCHRONOUS ADDR IN    27540016
         MVC      SYNAD+DEXTDCB1(3),IORTN    DCBS.                      27550016
*                                                                       27600016
* READ FROM EXTRACT DCB TO CONSOLE CONTROL TABLE (CCT)                  27700016
*                                                                       27800016
         TM    OCTNOTE+3,X'F0'                                          27804016
         BC    1,RECALD                                                 27808016
         B     NORC                                                     27812016
RECALD   EQU   *                                                        27816016
         LA    RWORK,IPOINT                                             27820016
         ST    RWORK,CCTPWKA                                            27824016
         NI    OCTNOTE+3,X'01'                                          27828016
       MVC   WKAREAD(LREAD),READ1                                       27840016
       MVC   CCTPWKA(4),OCTNOTE                                         27844016
         LA    RPAR0,CCTPWKA                                            27848016
         L     RPAR1,CCTEDCB1                                           27852016
         LA   RRECNO,2                                                  27856016
         LA    RAREA,CCT                                                27860016
         POINT (1),(0)                                                  27864016
         LA    RDECB,WKAREAD                                            27868016
READCCT1 READ  (RDECB),SF,DEXTDCB1,(RAREA),,,MF=E                       27872016
         CHECK (RDECB)                                                  27876016
         LA    RAREA,LRECORD(RAREA)                                     27880016
         BCT   RRECNO,READCCT1                                          27884016
    B   IPOINT                                                          27888016
EODERR   MVC   ERRORMSG(EL),EODMSG1          MOVE IN END OF DATA MSG    27888816
         B     ERRORRTN                                                 27889616
SYNCHER  MVC ERRORMSG(EL),SYNCHM1       MOVE IN SYNCHRONOUS ERROR MSG   27890416
         B     ERRORRTN                                                 27891216
NORC     EQU   *                                                        27892016
         LA    RWORK,IPOINT             * SET END OF DATA SET HANDLING  27900016
         ST    RWORK,CCTPWKA            * ROUTINE ADDRESS IN EXTRACT    28000016
         LA    RWORK,DEXTDCB            * DCB                           28100016
         MVC   EODADDR+DEXTDCB(3),CCTPWKA+1                             28200016
*                                  PUT END OF DATA SET ADDR IN CCT      28300016
         MVC   WKAREAD(LREAD),READ      MOVE READ IN WORKAREA           28400016
         MVC   CCTPWKA(4),OCTNOTE   MOVE NOTE INTO  CCT                 28500016
         LA    RPAR0,CCTPWKA            POINTING TO NOTE NUMBER         28600016
         L     RPAR1,CCTEDCBP           EXTRACT DCB ADDRESS             28700016
         LA    RRECNO,2                 LOAD NUMBER OF RECORDS FOR READ 28800016
         LA    RAREA,CCT                LOAD AREA ADDRESS FOR READ      28900016
         POINT (1),(0)                  POINT TO WHERE TO START TO READ 29000016
         LA    RDECB,WKAREAD            LOAD DECB ADDRESS               29100016
READCCT  READ  (RDECB),SF,DEXTDCB,(RAREA),,,MF=E                        29200016
         CHECK (RDECB)                  CHECK FOR READ COMPLETE         29300016
         LA    RAREA,LRECORD(RAREA)     UPDATE AREA ENTRY               29400016
         BCT   RRECNO,READCCT           READ MORE IF NOT FINISH         29500016
IPOINT   TM    CCTSSTAT,X'40'          Q.IS CCTSEXT SWITCH ON           29600016
         MVI   CCTPSTAT+1,X'20'    SET ERROR CODE TO ZERO               29630016
*                                  SET IGNORE ATTENSION BIT             29660016
         BC    1,PTDCB1                 BRANCH IF YES                   29700016
         LA   RPAR0,ONE           SET TO POINT TO FIRST EXT RECORD      29800016
         L     RPAR1,CCTEDCBP           DCB ADDRESS                     29900016
         B     POINT                    BRANCH                          30000016
PTDCB1   LA   RPAR0,ONE           SET TO POINT TO FIRST EXT RECORD      30100016
         L     RPAR1,CCTEDCB1           DCB ADDRESS                     30200016
         MVC   CCTEDCB1(4),CCTEDCBP     SWITCH POINTERS                 30300016
         ST    RPAR1,CCTEDCBP                       BACK TO NORMAL      30400016
POINT    POINT (1),(0)                  POINT TO LOCATION FOR READ OR   30500016
         MVC   DEXTDCB+33(3),DEXTDCB1+33  RESET EODAD ADDRESS           30600016
         MVC   CCTCCR(3),BEGKEY              SET KEY WORD IN CCTCCR     31800016
         EJECT                                                          31900016
*                                                                       32000016
         TM    OCTATTR1,OCTBIODQ                                        32200016
         BZ    TESTSMB                                                  32300016
         TM    OCTATTR2,OCTBSLOW  Q. HAS OPERATOR REQUESTED SLOW STOP   32400016
         BO    DEQSMSG                                                  32500016
         B     DEQMSG                                                   32600016
TESTSMB  TM    OCTATTR1,OCTBIOUS  Q. WAS THERE AN ERROR IN USER'S SMB   32700016
         BZ    TESTDSB                                                  32800016
         TM    OCTATTR2,OCTBSLOW  Q. HAS OPERATOR REQUESTED SLOW STOP   32900016
         BO    DSBSMSG                A.YES BRANCH DSBSMSG              33000016
         B     DSBMSG                 N.NO  BRANCH DSBMSG               33100016
TESTDSB  TM    OCTATTR1,OCTBIOGD  Q. WAS THERE AN ERROR IN DSB          33200016
         BZ    TESTMED                                                  33300016
         TM    OCTATTR2,OCTBSLOW  Q. HAS OPERATOR REQUESTED SLOW STOP   33400016
         BO    SMBSMSG                                                  33500016
         B     SMBMSG                                                   33600016
TESTMED  TM    OCTATTR2,OCTBMED                                         33700016
         BZ    TESTSLOW                                                 33800016
         NI     OCTATTR1+1,255-OCTBSMBB URN OFF O SMB BIT BEC      PDUM 33820016
*                                 SMB SHOULD NOT BE DISPLAYED WITH PDUM 33840016
*                                 MEDIUM STOP                      PDUM 33860016
         B     MSTOPMSG                                                 33900016
TESTSLOW TM    OCTATTR2,OCTBSLOW  Q. HAS OPERATOR REQUESTED SLOW STOP   34000016
         BO    STOPSMB                                                  34100016
         B     FILLCCT                                                  34200016
         EJECT                                                          34500016
*                                                                       34600016
* PRAPARE NECESSARY INFORMATION FOR MESSAGE HANDLING                    34700016
*                                                                       34800016
DEQMSG   EQU   *                                                        34900016
         BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 35000016
         DC    H'4'                     MESSAGE POINTER DISPLACEMENT    35100016
         B     MSGMODE                  BRANCH                          35200016
DEQSMSG  EQU   *                                                        35300016
         BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 35400016
         DC    H'8'                     MESSAGE POINTER DISPLACEMENT    35500016
         B     MSGMODE                  BRANCH                          35600016
DSBMSG   EQU   *                                                        35700016
         BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 35800016
         DC    H'12'                    MESSAGE POINTER DISPLACEMENT    35900016
         B     MSGMODE                  BRANCH                          36000016
DSBSMSG  BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 36100016
         DC    H'16'                    MESSAGE POINTER DISPLACEMENT    36200016
         B     MSGMODE                  BRANCH                          36300016
SMBMSG   BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 36400016
         DC    H'20'                    MESSAGE POINTER DISPLACEMENT    36500016
         B     MSGMODE                  BRANCH                          36600016
SMBSMSG  BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 36700016
         DC    H'24'                    MESSAGE POINTER DISPLACEMENT    36800016
         B     MSGMODE                  BRANCH                          36900016
MSTOPMSG EQU   *                                                        37000016
         BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 37100016
         DC    H'28'                    MESSAGE POINTER DISPLACEMENT    37200016
         B     MSGMODE                  BRANCH                          37300016
STOPSMB  EQU   *                                                        37400016
         BAL   RLINK,INITMSG           BRANCH TO MESSAGE HANDLING RTN   37500016
         DC    H'0'                                                     37600016
MSGMODE  OI    CCTPSTAT+1,X'40'         TURN ON MESSAGE DISPLAY SWITCH  38000016
         MVI   CCTCSM,X'08'             SET SELECT MASK (LOGOFF ONLY)   38100016
         TITLE 'IKAINIT PART 3  COMPLETE INITIALIZATION **************' 38150016
FILLCCT  EQU   *                   FILL IN CCT FROM OCT                 38200016
* MOVE OCT HEADER INTO CCT                                              38300016
*                                                                       38400016
         USING GFXOCTHD,ROCT       DSECT FOR OCT HEADER                 38600016
         L     ROCT,ADOCTHD        LOAD ADDR OCT HEADER                 38700016
         MVC   OCTHDSV(GFXHDSZE),GFXOCTHD                               38800016
*                                  MOVE OCT HEADER INTO SAVE AREA       38900016
         LA    ROCT,OCTHDSV        LOAD ADDR OCT SAVE AREA              39000016
         MVC   CCTSOUT(1),OCTGSMB                                       39100016
*                                  GJP SYSOUT CLASS                     39200016
         MVC   CCTFJCLS(1),OCTFTYPE                                     39300016
*                                  JOBCLASS USER'S FOREGROUND JOB       39400016
         MVC   CCTBJCLS(1),OCTBTYPE                                     39500016
*                                  JOBCLASS USER'S BACKGROUND JOB       39600016
         MVC   CCTSOUT+1(1),OCTPRINT                                    39700016
*                                  PRINT SYSOUT CLASS                   39800016
         MVC   CCTSOUT+2(1),OCTPUNCH                                    39900016
*                                  PUNCH SYSOUT CLASS                   40000016
         MVC   CCTSOUT+3(1),OCTBSMB                                     40100016
*                                  BATCH SMB SYSOUT CLASS               40200016
         MVC   CCTFRPRI(2),OCTFPRI                                      40300016
*                                  PRIORITY OF FOREGROUND JOB           40400016
         MVC   CCTBRPRI(2),OCTBPRI                                      40500016
*                                  PRIORITY OF BACKGROUND JOB           40600016
         MVC   CCTGRGN(4),OCTFGREG                                      40700016
         MVC  CCTUFRGN(4),OCTFUREG                                      40800016
*                                  FOREGROUND REGION SIZE               40900016
         MVC  CCTUBRGN(4),OCTBUREG                                      41000016
*                                  BACKGROUND REGION SIZE               41100016
* MOVE OCT ENTRY INTO CCT                                               41200016
         L     ROCT,ADOCTEN       LOAD ADDR OCT ENTRY                   41300016
         USING GFXOCTEN,ROCT       DSECT FOR OCT ENTRY RECORD           41400016
         MVC   CCTUNIT(3),OCTUNIT+1                                     41600016
*                                                                       41610016
* PACK JOB COUNT NUMBER, CONVERT IT TO BINARY, AND PUT IN CCT           41620016
*                                                                       41630016
         LA    RWORK,CCTPWKA+100       AN ADDR IN CCT WORK AREA         41640016
         N     RWORK,DOUBLE             INSURE ADDR IS OF DOUBLE WORD   41650016
         SR    RJOBCTR,RJOBCTR         CLEAR REG                        41660016
         ST    RJOBCTR,0(RWORK)        ZERO OUT FIRST WORD OF DOUBLE    41670016
         PACK  4(4,RWORK),OCTCOUNT(4)  PACK JOB COUNT INTO WORKAREA     41680016
*                                      SECOND WORD OF DOUBLE            41690016
         CVB   RJOBCTR,0(RWORK)        CONVERT EBCDIC TO BINARY         41700016
         STH   RJOBCTR,CCTJCTR         STORE BINARY NUMB IN CCT         41710016
         TM    OCTATTR1+1,OCTERR1  TEST ERROR BIT                  PDUM 41712016
         BC    1,LON               IF ERROR SIMULATE LOGON         PDUM 41714016
         TM    OCTATTR2,OCTABND    TEST ABEND BIT                  PDUM 41716016
         BC    1,LON               IF ABEND SIMULATE LOGON         PDUM 41718016
         TM    OCTATTR1,OCTBIODQ+OCTBIOGS+OCTBIOGD+OCTBIOUS+OCTBSTOP    41720016
*                                 Q. ANY I/O ERROR BIT SET IN OCT       41730016
         BC    5,DSELECT2              A. BRANCH IF YES                 41740016
         TM    OCTATTR2,OCTBLOFF+OCTBFAST+OCTBMED+OCTBSLOW+OCTABND      41750016
*                                 Q. ANY STOP BITS SET IN OCT           41760016
         BC    5,DSELECT2              A. BRANCH IF YES                 41770016
         TM    OCTATTR1+1,OCTBSMBB Q. BEGIN JOB TIME                    41800016
         BO    DSELECT                                                  41900016
         TITLE  'IKAINIT PART 3A(EXIT TO LOGON) **********************' 42000016
*                                                                       42100016
* LOAD LOGON PARAMETER TABLE SET KEY WORD IN CCTCCR SET COMMAND SELECT  42200016
* MASK TURN ON JOB AND EXEC CARD RECORD                                 42300016
*                                                                       42400016
LON      LOAD  EP=IKATLON0              LOAD LOGON PARAMETER TABLE      42500016
         ST    RPAR0,CCTCPSTP           SAVE ITS ADDRESS IN CCT         42600016
         MVC   CCTCCR(3),LONKEY         PUT LOGON KEYWORD IN CCTCCR     42700016
         MVI   CCTCSM,X'01'             SET COMMAND SELECT MASK         42800016
         OI    CCTPSTAT,X'C0'           TURN ON JOB AND EXEC CARD RECRD 42900016
         NI    OCTATTR1+1,255-OCTERR1   TURN OF ERROR 2IT          PDUM 42901016
         NI    OCTATTR2,255-OCTABND-OCTBIRRE  TURN OFF ABEND, ERRO-PDUM 42902016
         NI    OCTATTR3,255-OCTABND-OCTBIRRE  TURN OFF ABEND, E--O-PDUM 42903016
R10      EQU   10                                                  PDUM 42904016
         SR    R10,R10             CLEAR REG IF LOGON TIME         PDUM 42905016
MIP      EQU   *                   USED BY LON OR BY ERROR ROUTINE PDUM 42906016
* FREE KEYBOARD VIA READ MANUAL INPUT                                   42910016
         L     RWORK,CCTDDCBP           ADDR GRAPHICS DCB               42920016
         LA    Q,CCTPWKA+10       ADDR OF 3 BYTE AREA FOR RETURN   PDUM 42926016
         LA    RPAR1,DGREADR      ADDROF GREAD L FORM              PDUM 42932016
         GREADR (RPAR1),MIP,(RWORK),(Q),MF=E                       PDUM 42938016
         LTR   R10,R10                                             PDUM 42944016
         BCR   7,R10               YES, RETURN TO ERROR ROUTINE    PDUM 42950016
         LA    1,FREEABL               ADDR OF BEGINNING OF FREEMAIN    42960016
*                                 FREEMAIN WORK AREA NOT NEEDED AFTER   42970016
*                                 INIT                                  42980016
         FREEMAIN   R,LV=LFREEABL,A=(1),SP=0                            42990016
         L     0,LSAVE1                                            PDUM 42992016
         LA    1,LFREEABL                                          PDUM 42994016
         SR    0,1                                                 PDUM 42996016
         ST    0,LSAVE1                                            PDUM 42998016
XCTLCTL  LA    RPAR1,CCT               LOAD CCT ADDRESS                 43000016
         L     RSAVE,ISAVE+4            LOAD CALLING SAVE ADDRESS       43100016
         XCTL  (2,12),EP=IKACTL         TRANSFER CONTROL TO IKACTL      43200016
         TITLE 'IKAINIT PART 3B (EXIT TO SMB PROCESSOR) **************' 43250016
*                                                                       43300016
* SET PARAMETER TO DISPLAY SELECT FRAM AND TRANSFER CONTROL TO IKAMSG   43400016
*                                                                       43500016
*                                                                       43600016
* GETMAIN FOR DIARY DCB AND OPEN DIARY DCB IF RECORD OPTION IS TAKEN    43700016
DSELECT  MVI   CCTCSM,X'21'       SET SELECT MASK TO NORMAL             43780016
DSELECT2 EQU   *                                                   PDUM 43870016
         NI    CCTDISM,X'10'                                       PDUM 43910016
         TM    CCTSSTAT,X'80'     Q. PRINTED RECORD DESIRED        PDUM 43950016
         BZ    DSELECT1                 BRANCH IF NO                    44000016
         GETMAIN R,LV=DSCTEND-DCBDSECT                                  44100016
         LR    RDCBBASE,RPAR1          GETMAIN ADDRESS                  44200016
         USING DCBDSECT,RDCBBASE                                        44300016
         L     RWORK,LENGTH             GETMAIN LENGTH                  44400016
         SH    RWORK,TWO                *                               44500016
         LA    RWORK1,DCBDSECT          * CLEAR GETMAIN AREA            44600016
         MVI   0(RWORK1),X'00'          *                               44700016
         EX    RWORK,MOVE              *                                44800016
         AH    RWORK,TWO                RESET GETMAIN LENGTH            44900016
         ST    RWORK,DCBDSECT           SAVE IT AT FIRST WORK           45000016
         LA    RWORK1,DIADCB            DIARY DCB ADDRESS               45100016
         ST    RWORK1,CCTRDCBP          SAVE DIARY DCB ADDRESS          45200016
         MVC   DIADCB(LDCB),DCBDIA      *                               45300016
         MVC   DOPEN(4),DIAOPEN         * OPEN DIARY DCB                45400016
         MVC   DOPEN+1(3),CCTRDCBP+1    *                               45500016
         LA    RPAR1,DOPEN              *                               45600016
         OPEN  ,MF=(E,(1))              *                               45700016
         LA    RWORK,DIADCB                                             45701016
         USING IHADCB,RWORK            ADRESSABILITY FOR DCB            45702016
         TM    DCBOFLGS,GOODOPEN                                        45703016
         BO    DIAOK                                                    45704016
         MVC   ERRORMSG(EL),DCBMSG                                      45706016
         MVC   ERRORDCB(EE),DCBMSG5    SET UP PARM FOR IKAIERR     PDUM 45706516
         B     ERRORRTN                                                 45707016
DIAOK    EQU   *                                                        45708016
         DROP  RWORK                                                    45709016
         LA    RPAR0,CCTRNOTE     ADDR OF PROPER RECORD IN DIARY        45710016
         L     RPAR1,CCTRDCBP     ADDR DIARY DCB                        45720016
         POINT (1),(0)            POINT TO PRPER RECORD                 45730016
DSELECT1 EQU    *                                                       45750016
         MVI   CCTPSTAT,X'C0'     TURN ON SW FOR EXEC AND JOB CARDS     45780016
         USING GFXOCTEN,ROCT                                       PDUM 45790016
         L     ROCT,ADOCTEN       ADRESSABILITY FOR OCT ENTRY      PDUM 45800016
         LA    1,FREEABL               ADDR OF BEGINNING OF FREEMAIN    45820016
*                                 FREEMAIN WORK AREA NOT NEEDED AFTER   45840016
*                                 INIT                                  45860016
         FREEMAIN   R,LV=LFREEABL,A=(1),SP=0                            45880016
         L     0,LSAVE1                                            PDUM 45881016
         LA    1,LFREEABL                                          PDUM 45882016
         SR    0,1                                                 PDUM 45883016
         ST    0,LSAVE1                                            PDUM 45884016
         TM    OCTATTR1+1,OCTBSMBB  IF NO SMB SKIP SMB PROCESSOR   PDUM 45887016
         BZ    XCTLCTL            A. NO, SKIP SMB PROCESSOR AND GO      45890016
         TM    OCTATTR1,OCTBIODQ+OCTBIOGS+OCTBIOGD+OCTBIOUS        LCLF 45890317
         BC    5,XCTLCTL                                           LCLF 45890617
XCTLSMB  L     RSAVE,ISAVE+4            RELOAD CALLING SAVE ADDRESS     45900016
         LA    RPAR1,CCT               LOAD CCT ADDRESS                 46000016
         XCTL  (2,12),EP=IKAPSMB0       XCTL TO SMB                     46100016
         EJECT                                                          46200016
*                                                                       46300016
* THIS IS MESSAGE HANDLING ROUTINE                                      46400016
*                                                                       46500016
RPARLIST EQU   3                        POINT TO MESSAGE PARAMETER LIST 46600016
RMSGADDR EQU   4                        POINT TO MESSAGE AREA           46700016
RMINIT   EQU   5                        POINT TO IKAMINIT               46800016
RMSGLTH  EQU   6                        MESSAGE LENGTH                  46900016
ROPTBYTE EQU   7                        MESSAGE OPTION BYTE             47000016
RWORK1   EQU   8                                                        47100016
RWORK2   EQU   12                                                       47200016
*                                                                       47300016
INITMSG  EQU   *                                                        47400016
         LA    RPARLIST,CCTPWKA         POINT TO MESSAGE PAR-LIST ADDR  47500016
         MVI   0(RPARLIST),X'00'           CLEAR WORKAREA FOR MESSAGE   47600016
         MVC   1(100,RPARLIST),0(RPARLIST)                              47700016
         LA    RMSGADDR,CCTPWKA+12      POINT TO MESSAGE FIELD          47800016
         L     RMINIT,VMINIT            LOAD IKAMINIT ADDRESS           47900016
         AH    RMINIT,0(RLINK)         POINTER TO ADDRESS OF PAR-LIST   48000016
         L     RWORK1,0(RMINIT)         POINT TO PAR-LIST               48100016
CONTINUE SR    ROPTBYTE,ROPTBYTE       CLEAR REGISTER                   48200016
         IC    ROPTBYTE,0(RWORK1)       SAVE OPTION BYTG                48300016
         SR    RMSGLTH,RMSGLTH          ZERO REGISTER                   48400016
         STC   RMSGLTH,0(RWORK1)        ZERO OPTION BYTE                48500016
         L     RWORK2,0(RWORK1)         GET MESSAGE ADDRESS             48600016
         IC    RMSGLTH,0(RWORK2)        GET MESSAGE LENGTH              48700016
         EX    RMSGLTH,MOVEMSG          MOVE MESSAGE IN CCTPWKA         48800016
         ST    RMSGADDR,0(RPARLIST)     SET MESSAGE PARAMETER IN CCT    48900016
         STC   ROPTBYTE,0(RPARLIST)     SET OPTION BYTE                 49000016
         CH    ROPTBYTE,ENTRYEND       Q.NO MORE MESSAGE                49100016
         BE    2(RLINK)                 BRANCH IF YES                   49200016
         LA    RPARLIST,4(RPARLIST)     UPDATE PAR-LIST POINTER         49300016
         AR    RMSGADDR,RMSGLTH         UPDATE MSG-FIELD POINTER        49400016
         LA    RMSGADDR,1(RMSGADDR)                                     49500016
         LA    RWORK1,4(RWORK1)         UPDATE PAR-LIST POINTER         49600016
         B     CONTINUE                                                 49700016
         L     RSAVE,ISAVE+4                                            49900016
         RETURN (14,12)                                                 50000016
MOVE     MVC   1(0,RWORK1),0(RWORK1)                                    50100016
         EJECT                                                          50200016
         DS    0F                                                       50201016
HIBIT    DC    X'80000000'                                              50202016
EE       EQU   3                                                        50203016
         EJECT                                                          50204016
*                                                                       50205016
* INTERNAL ERROR MSGS SET UP FOR IKAIERR                                50206016
*                                                                       50207016
*                                                                       50208016
DCBMSG1  DC    AL3(MSGEXT)                                         IIXX 50208518
DCBMSG2  DC    AL3(MSGJCL)                                              50209016
DCBMSG3  DC    AL3(MSGGRA)                                              50210016
DCBMSG4  DC    AL3(MSGEXT1)                                             50211016
DCBMSG5  DC    AL3(MSGDIA)                                              50212016
DCBMSG   DC    C'056'                                                   50213016
         DC    C'INIT '                                                 50214016
         DC    X'40'                                                    50215016
         DC    C'   '                                                   50216016
DCBMSGE  EQU   *                                                        50217016
EL       EQU   DCBMSGE-DCBMSG                                           50218016
AS1      DC    C'058'                                                   50219016
         DC    C'INIT '                 MODULE NAME                IIXX 50220018
         DC    X'40D90000'                                              50221016
SPARMSG  DC    C'055'                                                   50222016
         DC    C'INIT '                                                 50223016
         DC    X'40D90000'                                              50224016
CIBMSG   DC    C'059'                                                   50225016
         DC    C'INIT '                                                 50226016
         DC    X'00000000'                                              50227016
         DC    C'   '                                                   50228016
         DS    0F                                                       50229016
SYNCHM1  EQU   *                                                        50230016
         DC    C'062'                   MESSAGE NO.                IIXX 50231018
         DC    C'INIT '                                                 50232016
         DC    X'40'                                                    50233016
         DC    AL3(DEX)                                                 50234016
EODMSG1  DC    C'061'                                                   50235016
         DC    C'INIT '                MODULE NAME                      50236016
         DC    X'40'                                                    50237016
         DC    AL3(DEX)                                                 50238016
DEX      DC    X'0008'                                                  50239016
         DC    C'EXT'                                                   50240016
         DC    C'XXX'                                                   50241016
ADINS    DC    AL3(PINS)                                                50242016
PINS     DC    X'D9000000'                                              50243016
MSGJCL   DC    X'0005'                                             PDUM 50244117
         DC    C'JCL'                                              PDUM 50244217
MSGGRA   DC    X'0006'                                             IIXX 50244318
         DC    C'2250'                                             IIXX 50244418
MSGEXT1  DC    X'0006'                                             PDUM 50244517
         DC    C'EXT1'                                             PDUM 50244617
MSGDIA   DC    X'0005'                                             PDUM 50244717
         DC    C'DIA'                                              PDUM 50244817
MSGEXT   DC    X'0005'                                             IIXX 50245518
         DC    C'EXT '                                             IIXX 50246218
ERRORRTN LR    RPAR1,RCCT               ADDR CCT FOR IERR               50247016
         LA    RPAR1,8(RPAR1)                                           50248016
         LA    RPAR0,ERRORMSG           ADDR MSG FORM FOR IERR          50249016
         O     RPAR0,HIBIT                                         PDUM 50258016
         LINK  EP=IKAIERR                                          PDUM 50259016
         L     R10,CCTDDCBP        ADDR GRAPH DCB                  RMIF 50259118
         LTR   R10,R10             TEST                            RMIF 50259218
         BZ    NOGDCB              NO MIP IF NOT OPEN              RMIF 50259318
         BAL   R10,MIP             GO -EAD MANUAL &NPUT TO ALLOW ATPDUM 50259616
*                                  TO GET THROUGH TO GFX.          PDUM 50260216
         B     TSPAR                    TO ISSUE DAR & RLSEBER     IIXX 50260518
Q        EQU   5                                                   PDUM 50260816
NOGDCB   EQU   *                                                   RMIF 50261118
         USING IHADCB,RWORK        RWORK WILL BE USED WITH DCBDSECTPDUM 50261416
         LA    1,CCTJDCBP          ADDR OF PTR TO JCLDCB           PDUM 50262016
         BAL   Q,CLEAN             BAL TO RTN TO CLOSE JCLDCB      PDUM 50262616
         LA    1,CCTDDCBP          ADDR OF PTR TO GRAPHIC DCB      PDUM 50263216
         BAL   Q,CLEAN             BAL TO RTN TO CLOSE GRAPHIC DCB PDUM 50263816
         LA    1,CCTEDCBP          ADDR OF PTR TO EXTRACT DCB      PDUM 50264416
         BAL   Q,CLEAN             BAL TO RTN TO CLOSE EXTRACT DCB PDUM 50265016
         LA    1,CCTEDCB1          ADDR OF PTR TO RECALL DCB       PDUM 50265616
         BAL   Q,CLEAN             BAL TO RTN TO CLOSE RECALL DCB  PDUM 50266216
         LA    1,CCTRDCBP          ADDR OF PTR TO DIARY DCB        PDUM 50266816
         BAL   Q,CLEAN             BAL TO RTN TO CLOSE DIARY DCB   PDUM 50267416
         B     NORLBUF                  CONTINUE                   IIXX 50268018
CLEAN    CLC   0(4,1),ZEROS8       Q. IS THERE ANY DCB AT ALL.     PDUM 50268616
         BCR   8,Q                 A. NO RETURN                    PDUM 50269216
         L     RWORK,0(1)          A. YES, PICK UP PTR TO DCB      PDUM 50269816
         TM    DCBOFLGS,GOODOPEN   Q. IS DCB OPEN                  PDUM 50270416
         BCR   8,Q                 A. NO, RETURN                   PDUM 50271016
         MVI   0(1),X'80'         SET OPTION BYTE FOR CLOSE        PDUM 50271616
         CLOSE MF=(E,(1))          A. YES, CLOSE                   PDUM 50272216
         MVC   0(4,1),ZEROS8       ZERO OUT PTR TO DCB             PDUM 50272816
         BR    Q                   RETURN                          PDUM 50273416
TSPAR    TM    CCTGACBP,X'80'      Q. HAS SPAR BEEN ISSUED OK      PDUM 50274016
         DROP  RWORK                                               PDUM 50274616
         BC    8,NODAR             A. NO SKIP DAR                  PDUM 50275216
         LA    6,CCTPWKA                                           PDUM 50275816
         MVC    CCTPWKA(8),DARLIST                                 PDUM 50276416
         L     4,CCTGACBP                                          PDUM 50277016
         DAR   ((4)),MF=(E,(6))                                    PDUM 50277616
NODAR    TM    CCTDDCBP,X'80'      Q. HAS ASS&GN BUFFE- BEEN &SSUEDPDUM 50278216
         BZ    NOGDCB                   NO BUFFER ASSIGNED         IIXX 50278818
         LA    6,CCTPWKA                                           PDUM 50279416
         MVC    CCTPWKA(8),RBUFLIST                                PDUM 50280016
         L     4,CCTDDCBP                                          PDUM 50280616
         RLSEBFR  ((4)),MF=(E,(6))                                 PDUM 50281216
         B     NOGDCB                   TO CLOSE DCB'S             IIXX 50281518
NORLBUF  EQU   *                                                   PDUM 50281816
RHOLD    EQU   RCCT                                                PDUM 50282416
         L     RGRAPHIC,CCTGWRKP  ADDR GRAPHIC AREA                PDUM 50283016
         LTR   RGRAPHIC,RGRAPHIC                                   PDUM 50283616
         BC    8,NOFREEGR         &F THE-E &S NO G-APH&C A-EA DO NOPDUM 50284216
*                                 FREEMAIN ANYTHING                PDUM 50284816
         S     RGRAPHIC,EIGHT     ADDR OF LENGTH OF AREA           PDUM 50285416
         LR    1,RGRAPHIC         ADDR OF AREA TO FREEMAIN IN R1   PDUM 50286016
         L     RPAR0,LGRAPHIC           GET LENGTH OF AREA         IIXX 50286418
         FREEMAIN R,LV=(0),A=(1)                                   IIXX 50286818
NOFREEGR EQU   *                                                   PDUM 50287216
*                                  FREEMAIN CCT                    PDUM 50287816
         LR    1,RHOLD             ADDR CCT                        PDUM 50288416
         L     0,0(1)              IN R0                           PDUM 50289016
         L     7,ISAVE+4                                           PDUM 50289616
         FREEMAIN  R,LV=(0),A=(1)       FREE CCT                   PDUM 50290216
         LR    RSAVE,7                                             PDUM 50294416
         LM    14,12,12(13)       RESTORE SYSTEM REGISTERS         PDUM 50295016
         SR    15,15                                               PDUM 50295616
         BR    14                 RETURN TO SYSTEM                 PDUM 50296216
*                                                                       50300016
* DEFINE CONSTANTS AREA AND EQUATES                                     50400016
*                                                                       50500016
MOVEMSG  MVC   0(0,RMSGADDR),0(RWORK2) MOVE MESSAGE IN WROKAREA         50600016
VMINIT   DC    V(IKAMINIT)              POINT TO IKAMINIT MODULE        50700016
ENTRYEQU DC    CL9'OCTENTRY='                                           50800016
         DS    0F                                                       50900016
ZEROS    DC    X'0000'                                                  51000016
ZEROS8   DC    X'0000000000000000'                                      51050016
*                                  MODEL OCTENTRY USED TO -ESTA-T GPDUM 51060016
         DS    0F                                                  PDUM 51070016
EIGHT    DC    XL4'8'                                              PDUM 51080016
         DS    0F                                                       51100016
ONE      DC    XL4'01'                                                  51200016
BUFLEN   DC    X'1000'                  DEFINE BUFFER LENGTH            51300016
TWO      DC    H'2'                    CONSTANT TWO                     51400016
EODRTN   DC    AL3(EODERR)                                              51430016
IORTN    DC    AL3(SYNCHER)                                             51460016
         DS    0F                                                       51500016
DOUBLE   DC    X'FFFFFFF8'                                              51600016
LONKEY   DC    C'LON'                                                   51700016
BEGKEY   DC    C'BEG'                                                   51800016
ENTRYEND DC    X'00C0'                  OPTION BYTE FOR END OF ENTRY    51900016
LGRAPHIC DC    A(GRAPHICE-GRAPHIC)                                      52000016
LWKA     DC    A(INITWKAE-INITWKA)      LENGTH OF DSECT                 52100016
LENGTH   DC    A(DSCTEND-DCBDSECT)                                      52200016
DATADDR  EQU   *                                                        52300016
COMADDR  EQU   *                                                        52400016
         EJECT                                                          52500016
*                                                                       52600016
* SPAR AND OPEN MACRO IN MF=L                                           52700016
*                                                                       52800016
SPAR     SPAR  (GACB),MF=L                                              52900016
SPARE    EQU   *                                                        53000016
OPENDCB  OPEN  (JCLDCB,(INOUT),GRADCB,(INOUT),EXTDCB,(INOUT),          X53100016
               EXTDCB1,(INOUT)),MF=L                                    53200016
OPENDCBE EQU   *                                                        53300016
DIAOPEN  OPEN  (DCBDIA,(INOUT)),MF=L                                    53400016
DIAOPENE EQU   *                                                        53500016
*                                                                       53600016
* ASSIGN BUFFER FOR GRAPHIC F FORM                              (OS)    53700016
*                                                                       53800016
ASNLIST  EQU   *                                                        53900016
         ASGNBFR ,BUFLEN,MF=L                                           54000016
ASNLISTE EQU   *                                                (OS)    54100016
         EJECT                                                          54200016
*                                                                       54300016
* GACB MACRO IN MF=L                                                    54400016
*                                                                       54500016
GACB     SAEC  EP=0,DCB=GRADCB,COMAREA=COMADDR,                        *54600020
               ATTNTYP=(R,LP,CANCEL,END),RESTART=YES             A36205 54700020
GACBE    EQU   *                                                        54800016
         EJECT                                                          54900016
*                                                                       55000016
* JCLDCB                                                                55100016
*                                                                       55200016
JCLDCB   DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=GJPJCL,DEVD=DA,RECFM=FBS, X55300016
               LRECL=80,BLKSIZE=80,SYNAD=DUMMY                          55400016
JCLDCBE  EQU   *                                                        55500016
         EJECT                                                          55600016
*                                                                       55700016
** GRADCB                                                               55800016
*                                                                       55900016
GRADCB   DCB   DSORG=GS,MACRF=(RC,WC),GTYPE=BASIC,DDNAME=GJP2250        56800016
GRADCBE  EQU   *                                                        57700016
         EJECT                                                          57800016
*                                                                       57900016
* DIARY DCB                                                             58000016
*                                                                       58100016
DCBDIA   DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=GJPDIA,DEVD=DA,RECFM=FBS, X58200016
               LRECL=120,BLKSIZE=120,SYNAD=DUMMY                        58300016
DCBDIAE  EQU   *                                                        58400016
         EJECT                                                          58500016
*                                                                       58600016
* EXTDCB                                                                58700016
*                                                                       58800016
EXTDCB   DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=GJPEXT,DEVD=DA,RECFM=FBS, X58900016
               LRECL=372,BLKSIZE=372,SYNAD=DUMMY,EODAD=DUMMY            59000016
EXTDCBE  EQU   *                                                        59100016
         EJECT                                                          59200016
*                                                                       59300016
* EXT DCB1                                                              59400016
*                                                                       59500016
EXTDCB1  DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=GJPEXT1,DEVD=DA,RECFM=FBS,X59600016
               LRECL=372,BLKSIZE=372,SYNAD=DUMMY,EODAD=DUMMY            59700016
EXTDCB1E EQU   *                                                        59800016
*                                                                       59900016
* READ IN MF=L                                                          60000016
*                                                                       60100016
READ     READ  EXTDECB,SF,,,,,MF=L                                      60200016
READ1    READ  EXTDECB1,SF,,,,,MF=L                                     60250016
READEND  EQU   *                                                        60300016
*                                 READ MANUAL INPUT L FORM              60320016
GREADR   GREADR MIP1,MIP,,,MF=L                                         60340016
GREADRE  EQU   *                                                        60360016
DARLIST  DAR   (DARLIST),MF=L                                      PDUM 60363016
RBUFLIST RLSEBFR ,ALL,MF=L                                         PDUM 60366016
W        EQU   (*-A)                                               PDUM 60371016
TOT      EQU   X'E00'                                              PDUM 60376016
LMINIT   EQU   X'170'                                              PDUM 60381016
LINIT    EQU   TOT-LMINIT                                          PDUM 60386016
PADDING  DC    XL(LINIT-W)'0'                                      PDUM 60391016
         EJECT                                                          60400016
LJCLDCB  EQU   JCLDCBE-JCLDCB                                           60500016
LEXTDCB  EQU   EXTDCBE-EXTDCB                                           60600016
LEXTDCB1 EQU   EXTDCB1E-EXTDCB1                                         60700016
LGRADCB  EQU   GRADCBE-GRADCB           LENGTH OF GRAPHIC DCB           60800016
LOPEN    EQU   OPENDCBE-OPENDCB                                         60900016
LGACB    EQU   GACBE-GACB                                               61000016
LSPAR    EQU   SPARE-SPAR                                               61100016
LASNLIST EQU   ASNLISTE-ASNLIST         LENGTH OF ASSIGN BUFFER (OS)    61200016
LREAD    EQU   READEND-READ             READ LENGTH                     61300016
LDCB     EQU   DCBDIAE-DCBDIA           DIARY DCB LENGTH                61400016
LGREADR  EQU   GREADRE-GREADR      LENGTH OF GREADR L FORM              61450016
DUMMY    EQU   *                                                        61500016
         SPACE 2                                                        61510020
*********************************************************************** 61520020
*                                                                       61530020
*        MAINTENANCE AREA                                        A33564 61540020
*                                                                       61550020
*********************************************************************** 61560020
PATCH    DC    40F'0'                                            A33564 61570020
         SPACE 2                                                        61580020
         EJECT                                                          61600016
* DSECT FOR CCT DCB'S GACB SPAR OPEN                                    61700016
*                                                                       61800016
INITWKA  DSECT                                                          61900016
LSAVE1   DS    XL8                                                      62000016
         EJECT                                                          62100016
         SPACE                                                          62200016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         62300016
         SPACE                                                          62400016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    62500016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     62600016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       62700016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             62800016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  62900016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  63000016
*                   SET.                                                63100016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      63200016
*                   SECOND.                                             63300016
         SPACE 2                                                        63400016
CCT      EQU   *                                                        63500016
         SPACE 2                                                        63600016
*                             SECTION ONE                               63700016
         SPACE                                                          63800016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     63900016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    64000016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  64100016
         SPACE                                                          64200016
         DS    0F                                                       64300016
CCTUNAME DS    5F                  USER'S NAME                          64400016
CCTVACCT DS    5F                  USER'S ACCOUNT NUMBER                64500016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     64600016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       64700016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    64800016
*                                       AT LAST BEGIN JOB               64900016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   65000016
*                                       LAST BEGIN JOB                  65100016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 65200016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    65300016
*                                       JOB                             65400016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    65500016
*                                       JOB                             65600016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     65700016
*                                       CESSOR                          65800016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         65900016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         66000016
CCTJCTR  DS    H                   JOB COUNTER                          66100016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                66200016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   66300016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  66400016
CCTSSTAT DS    C                   SESSION STATUS                       66500016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              66600016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              66700016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    66800016
         EJECT                                                          66900016
         SPACE 2                                                        67000016
*                             SECTION TWO                               67100016
         SPACE                                                          67200016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   67300016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  67400016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 67500016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              67600016
         SPACE                                                          67700016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     67800016
*                                       FRAME                           67900016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  68000016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     68100016
*                                       MULTIPLE DISPLAY FRAME (ENT)    68200016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   68300016
CCTDISM  DS    C                   DISPLAY MASK                         68400016
CCTCSM   DS    C                   COMMAND SELECT MASK                  68500016
CCTPSTAT DS    CL2                 GJP STATUS                           68600016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              68700016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  68800016
         SPACE 2                                                        68900016
*                             SECTION THREE                             69000016
         SPACE                                                          69100016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    69200016
*                   INTO SECTION ONE OR TWO                             69300016
         SPACE                                                          69400016
CCTDGMP  DS    F                  POINTER TO DGM                        69500016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                69600016
CCTCSTP  DS    F                  POINTER TO CST                        69700016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                69800016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            69900016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 70000016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              70100016
CCTDIARP DS    F                  POINTER TO DIA                        70200016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT RTN          70300016
CCTACTP  DS    F                  POINTER TO ACT                        70400016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     70500016
CCTIERRP DS    F                  POINTER TO IERR                       70600016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              70700016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               70800016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                70900016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 71000016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 71100016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   71200016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                71300016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                71400016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               71500016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              71600016
CCTPECB  DS    F                  PROCESSOR'S ECB                       71700016
CCTWECB  DS    F                  WTOR ECB                              71800016
CCTDIAWA DS    CL136               DIARY WORK AREA                      71900016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    72000016
CCTCSAVE DS    CL72                CTL SAVE AREA                        72100016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                72200016
CCTASAVE DS    CL72                DAT SAVE AREA                        72300016
         EJECT                                                          72800016
*                                                                       72900016
* DCB'S GACB SPAR OPEN                                                  73000016
*                                                                       73100016
         DS    0F                                                       73200016
DJCLDCB  DS    XL(JCLDCBE-JCLDCB)       SPACE FOR JCLDCB                73300016
         DS    0F                                                       73400016
DGRADCB  DS    XL(GRADCBE-GRADCB)       SPACE FOR GRADCB                73500016
         DS    0F                                                       73600016
DEXTDCB  DS    XL(EXTDCBE-EXTDCB)       SPACE FOR EXTRACTE DCB          73700016
         DS    0F                                                       73800016
DEXTDCB1 DS    XL(EXTDCB1E-EXTDCB1)     SPACE FOR EXTRACT DCB           73900016
         DS    0F                                                       74000016
GACBDGM  DS    XL(GACBE-GACB)           SPACE FOR GACB                  74300016
         DS    0F                                                       74400016
DSPAR    DS    XL(SPARE-SPAR)           SPACE FOR SPAR MACRO            74500016
         DS    0F                                                       74600016
GBUFFER  EQU   *                                                        74700016
         DS    XL(ASNLISTE-ASNLIST)     SPACE FOR ASSIGN BUFFER         74800016
         DS    0F                                                       74900016
COMUTAR  DS    14F                 COMMUNICATION AREA FOR GRAPHICS      74909016
ISAVE    DS    2F                  SAVE ADDR SYSTEM SAVE AREA           74918016
         DS    0F                                                  EXTR 74920019
EXTRCT   EXTRACT ANSWAREA,FIELDS=COMM,MF=L                         EXTR 74922019
ANSWAREA DS    1F                                                  EXTR 74924019
         DS    0D                                                       74927016
FREEABL  EQU   *                   BEGINING OF AREA IN GETMAIN NOT NEED 74936016
*                                  ED AFTER INIT                        74945016
DOPENDCB DS    XL(OPENDCBE-OPENDCB)     SPACE FOR OPEN MACRO            74954016
         DS    0F                                                       74963016
DGREADR  DS    XL(GREADRE-GREADR)  SPACE FOR READ MANUAL INPUT          74972016
ERRORMSG DS    12F                                                      74975016
ERRORDCB EQU   ERRORMSG+9                                               74978016
ERROR15  EQU   ERRORMSG+11              EQUATE FOR RETURN CODE     IIXX 74979018
SAVER13  DS    F                                                        74981016
SAVE2    DS    18F                                                      74990016
WKAREAD  DS    XL(READEND-READ)                                         75000016
ADPARM   DS    1F                                                       75220016
ADOCTHD  DS    1F                                                       75240016
ADOCTEN  DS    1F                                                       75260016
OCTHDSV  DS    XL76                                                     75280016
INITWKAE EQU   *                        END OF THIS DSECT               75300016
LFREEABL EQU   INITWKAE-FREEABL    S                                    75350016
         EJECT                                                          75400016
*                                                                       75500016
* DSECT FOR GRAPHIC WORKARE                                             75600016
*                                                                       75700016
GRAPHIC  DSECT                          SPACE                           75800016
LSAVE2   DS    XL8                           FOR                        75900016
DGMWKA1  DS    XL2000                           GRAPHIC                 76000016
ACTWKA   DS    XL1000                             WORK                  76100016
DGMWKA2  DS    XL1000                                       AREA        76200016
GRAPHICE EQU   *                        END IF THIS DSECT               76300016
DCVT     DSECT                                                          76400016
         CVT                                                            76500016
GFXOCTHD DSECT                                                          76600016
GFXHDSTR EQU   *                       START OF HEADER RECORD           76700016
OCTSYS   DS    CL1                     BASE SYSTEM                      76800016
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                76900016
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          77000016
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       77100016
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       77200016
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              77300016
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              77400016
OCTCTYPE DS    CL1                 JOBCLASS FOR FGD JOB-INTERNAL FOPDUM 77450016
         DS    0H                                                       77500016
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             77600016
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       77700016
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       77800016
OCTITYPE DS    CL1                 JOBCLASS FOR SGJP - EXTERNAL    PDUM 77860016
OCTITYPI DS    CL1                 JOBCLASS FOR SGJP - INTERNAL    PDUM 77920016
OCTFGREG DS    CL4                      REGION SIZE GJP                 78000016
OCTFUREG DS    CL4                      REGION SIZE USER FGD            78100016
OCTBUREG DS    CL4                      REGION SIZE USER BGD            78200016
OCTHRES  DS    CL8                      RESERVED                        78300016
OCTNAME  DS    CL20                     PROGRAMMER NAME                 78400016
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  78500016
GFXHDEND EQU   *                       END OF HEADER RECORD             78600016
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        78700016
         EJECT                                                          78800016
GFXOCTEN DSECT                                                          78900016
         DS    0F                                                       79000016
GFXENSTR EQU   *                       START OF ENTRY RECORD            79100016
OCTECB   DS    CL4                      ECB                             79200016
OCTUCB   DS    CL4                      UCB ADDRESS                     79300016
OCTUNIT  DS    CL4                      UNIT ADDRESS                    79400016
OCTCOUNT DS    CL4                      JOB COUNT                       79500016
OCTNOTE  DS    CL4                      NOTE                            79600016
OCTABEND DS    A                       ABEND CODE                       79700016
OCTFPART DS    CL2                 PARTITION NUMBER (MFT ONLY)     PDUM 79760016
OCTRESD  DS    CL6                 RESERVED                        PDUM 79820016
**********************************************************************  79900016
****                          ATTRIBUTE 1                          **** 80000016
**********************************************************************  80100016
OCTATTR1 DS    CL2                      ATTRIBUTES                      80200016
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         80300016
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   80400016
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         80500016
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       80600016
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   80700016
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  80800016
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  80900016
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           81000016
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          81100016
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   81200016
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           81300016
OCTERR1  EQU   X'10'               0-             1-GJP INTERNAL ERPDUM 81330016
OCTERR2  EQU   X'08'               0-             1-GJP INTERNAL ERPDUM 81360016
**********************************************************************  81400016
****                          ATTRIBUTE 2                          **** 81500016
**********************************************************************  81600016
OCTATTR2 DS    CL2                      ATTRIBUTES                      81700016
OCTBIRRE EQU   X'80'               0-             1-GJP INTERNAL ERPDUM 81800016
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      81900016
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              82000016
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           82100016
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         82200016
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           82300016
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       82400016
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            82500016
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  82600016
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  82700016
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        82800016
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         82900016
**********************************************************************  83000016
****                          ATTRIBUTE 3                          **** 83100016
**********************************************************************  83200016
OCTATTR3 DS    CL2                      ATTRIBUTES                      83300016
OCTBCANM EQU   X'80'          0-                  1-                    83400016
OCTBIERR EQU   X'80'               0-             1-GJP INTERNAL ERPDUM 83500016
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              83600016
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           83700016
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         83800016
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           83900016
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       84000016
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            84100016
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  84200016
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  84300016
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        84400016
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         84500016
**********************************************************************  84600016
****                          ATTRIBUTE 4                          **** 84700016
**********************************************************************  84800016
OCTATTR4 DS    CL2                      ATTRIBUTES                      84900016
OCTBSGJP EQU   X'80'               0-USER/GJP JOB      1-INITIAL PRPDUM 84950016
GFXENEND EQU   *                       END OF ENTRY RECORD              85000016
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             85100016
         EJECT                                                          85200016
         DCBD  DSORG=PS,DEVD=DA         DSECT FOR DCBS                  85250016
*                                                                       85300016
* DSECT FOR DIARY DCB                                                   85400016
*                                                                       85500016
DCBDSECT DSECT                                                          85600016
         DS    D                                                        85700016
DIADCB   DS    XL(DCBDIAE-DCBDIA)                                       85800016
DIADCBE  EQU   *                                                        85900016
DOPEN    DS    F                                                        86000016
DSCTEND  EQU   *                                                        86100016
         END                                                            86200016
