IKAJCL   START 0                                                        00100016
*                                                                       00200016
****              * *  JCL  GENERATOR  * *                              00300016
*                                                                       00400016
*  MODULE NAME =    IKAJCL                                              00500016
*                                                                       00600016
*  CHART ID.   =    FP,FQ                                               00700016
*                                                                       00800016
*  FUNCTION    =    GENERATE JCL ON DATA SET FROM COMMAND PROCESSING    00900016
*                   ROUTINES INPUT                                      01000016
*                                                                       01100016
*  ATTRIBUTES  =    RESIDENT,REENTERABLE                                01200016
*                                                                       01300016
*  ENTRY POINT =    ENTERED VIA BRANCH FROM COMMAND PROCESSING ROUTINES 01400016
*                                                                       01500016
*  OPERATION   =                                                        01600016
*                                                                       01700016
*  EXITS       =    RETURN TO CALLER                                    01800016
*                                                                       01900016
*  INPUT       =    COMMAND PROCESSING ROUTINES OUTPUT                  02000016
*                                                                       02100016
*  OUTPUT      =    JCL RECORDS ON JCL DATA SET                         02200016
*                                                                       02300016
*  EXTERNAL                                                             02400016
*   REFERENCES =                                                        02500016
*                                                                       02600016
*  ERROR                                                                02700016
*   CONDITIONS =                                                        02800016
*                                                                       02900016
*  TABLES AND                                                           03000016
*   WORKAREAS  =    IKACCT                                              03100016
*                   JCL WORKAREA                                        03200016
*                                                                       03300016
*  RESTRICTIONS=                                                        03400016
*                                                                       03500016
* * * * * * * * * * * *                                                 03600016
         EJECT                                                          03700016
         SPACE                                                          03740016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         03780016
         SPACE                                                          03820016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    03860016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     03900016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       03940016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             03980016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  04020016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  04060016
*                   SET.                                                04100016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      04140016
*                   SECOND.                                             04180016
         SPACE 2                                                        04220016
CCT      DSECT                                                          04260016
         SPACE 2                                                        04300016
*                             SECTION ONE                               04340016
         SPACE                                                          04380016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     04420016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    04460016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  04500016
         SPACE                                                          04540016
         DS    0F                                                       04580016
CCTUNAME DS    5F                  USER'S NAME                          04620016
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         04660016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     04700016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       04740016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    04780016
*                                       AT LAST BEGIN JOB               04820016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   04860016
*                                       LAST BEGIN JOB                  04900016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 04940016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    04980016
*                                       JOB                             05020016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    05060016
*                                       JOB                             05100016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     05140016
*                                       CESSOR                          05180016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         05220016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         05260016
CCTJCTR  DS    H                   JOB COUNTER                          05300016
CCTUBPRI DS    H                        USERS BACKGROUND PRIORITY  PJKA 05320017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                05340016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   05380016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  05420016
CCTSSTAT DS    C                   SESSION STATUS                       05460016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              05500016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              05540016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    05580016
         EJECT                                                          05620016
         SPACE 2                                                        05660016
*                             SECTION TWO                               05700016
         SPACE                                                          05740016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   05780016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  05820016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 05860016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              05900016
         SPACE                                                          05940016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     05980016
*                                       FRAME                           06020016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  06060016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     06100016
*                                       MULTIPLE DISPLAY FRAME (ENT)    06140016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   06180016
CCTDISM  DS    C                   DISPLAY MASK                         06220016
CCTCSM   DS    C                   COMMAND SELECT MASK                  06260016
CCTPSTAT DS    CL2                 GJP STATUS                           06300016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              06340016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  06380016
         SPACE 2                                                        06420016
*                             SECTION THREE                             06460016
         SPACE                                                          06500016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    06540016
*                   INTO SECTION ONE OR TWO                             06580016
         SPACE                                                          06620016
CCTDGMP  DS    F                  POINTER TO DGM                        06660016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                06700016
CCTCSTP  DS    F                  POINTER TO CST                        06740016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                06780016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            06820016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 06860016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              06900016
CCTDIARP DS    F                  POINTER TO DIA                        06940016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      06980016
CCTACTP  DS    F                  POINTER TO ACT                        07020016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     07060016
CCTIERRP DS    F                  POINTER TO IERR                       07100016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              07140016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               07180016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                07220016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 07260016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 07300016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   07340016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                07380016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                07420016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               07460016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              07500016
CCTPECB  DS    F                  PROCESSOR'S ECB                       07540016
CCTWECB  DS    F                  WTOR ECB                              07580016
CCTDIAWA DS    CL136               DIARY WORK AREA                      07620016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    07660016
CCTCSAVE DS    CL72                CTL SAVE AREA                        07700016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                07740016
CCTASAVE DS    CL72                DAT SAVE AREA                        07780016
*                                                                       07820016
IKACCT   EQU   CCT                                                      07860016
         EJECT                                                          08400016
***                 REGISTER  EQUATES                                   08500016
*                                                                       08600016
RPAR0    EQU   0                                                        08700016
RPAR1    EQU   1                                                        08800016
RCCT     EQU   2                       CCT POINTER                      08900016
RBASE    EQU   3                        BASE                            09000016
RMANIP   EQU   4                        POINTER TO GETMAIN-D WORKAREA   09100016
RFLDLENG EQU   5                        LENGTH OF FIELD TESTED          09200016
ROUTLENG EQU   6                        ABSOLUTE LENGTH COUNTER         09300016
RRECLENG EQU   7                        POINTER TO EXT.REC POS. TESTED  09400016
RCCTLENG EQU   8                        JCL OUTAREA LENGTH COUNTER      09500016
RWK      EQU   9                        WORK REGISTER                   09600016
RLENG    EQU   10                       RECORD LENGTH COUNTER           09700016
RFLD     EQU   11                       POINTER TO FIELD TESTED         09800016
RWK2     EQU   12                       SECOND WORK REGISTER            09900016
RSAVE    EQU   13                                                       10000016
RRET     EQU   14                                                       10100016
RBR      EQU   15                                                       10200016
RWORK    EQU   RWK                                                      10300016
* * * * * * * * * * *                                                   10400016
         EJECT                                                          10500016
WKAREA   DSECT                                                          10600016
MYSAVE   DS    72C                                                      10700016
         DS    0D                                                       10800016
JCLOUTAR DS    80C                                                      10900016
APOWORK  DS    40C                                                      11000016
SIXTEEN  DS    4C                                                       11100016
CONVHSN  DS    3C                                                       11150016
PASSW    DS    XL1                                                      11200016
PTRSW    DS    XL1                                                      11300016
COMSW    DS    XL1                                                      11400016
DOUBLSW  DS    XL1                                                      11500016
SW26     DS    XL1                                                      11600016
NOCOMSW  DS    XL1                                                      11700016
         DS    0F                                                       11800016
DECB     DS    20C                                                      11900016
*                                                                       12000016
         EJECT                                                          12500016
IKAJCL   CSECT                                                          12600016
*0822,304400,326400,328000,352000,465000,493000                    PJKA 12650017
START    EQU   *                                                        12700016
         SAVE  (14,12)                                                  12800016
         BALR  RBASE,0                  SET UP BASE                     12900016
         USING *,RBASE                                                  13000016
         LR    RCCT,RPAR1               LOAD REG WITH ADDR. OF CCT      13100016
         USING IKACCT,RCCT                                              13200016
*                                                                       13300016
         GETMAIN R,LV=208+DCBLENG                                       13400016
         ST    RPAR1,8(0,RSAVE)        SAVE PREVIOUS SAVEAREA           13500016
         ST    RSAVE,4(RPAR1)                                           13600016
         LR    RSAVE,RPAR1                                              13700016
         LR    RMANIP,RPAR1                                             13800016
         USING WKAREA,RMANIP                                            13900016
         MVI   JCLOUTAR,X'40'           CLEAR JCL WORKAREA              14000016
         MVC   JCLOUTAR+1(79),JCLOUTAR                                  14100016
         LA    RCCTLENG,JCLOUTAR       ADDRESS OF JCL OUTPUTAREA        14200016
         LA    RCCTLENG,15(RCCTLENG)   INCREMENT BY 15                  14300016
         ST    RCCTLENG,SIXTEEN        STORE IN CONSTANT SIXTEEN        14400016
         LA    RCCTLENG,JCLOUTAR       RESTORE JCL OUTPUTAREA ADDRESS   14500016
         L     RWK,CCTHSN               LOAD HISTORY SEQU. NUMBER       14510016
         LA    RWK,0(RWK)               CLEAR HIGH ORDER BYTE           14520016
         MVI   APOWORK,X'40'            CLEAR WORKAREA                  14530016
         MVC   APOWORK+1(39),APOWORK                                    14540016
         CVD   RWK,APOWORK              CONVERT HISTORY SEQU. NUMBER    14550016
         UNPK  APOWORK+15(5),APOWORK+5(3)  UNPACK                       14560016
         OI    APOWORK+19,X'F0'         CHANGE SIGN TO ZONE             14570016
         MVC   CONVHSN(3),APOWORK+17    STORE HIST.SEQU.NUMBER          14580016
         SR    RFLDLENG,RFLDLENG        SET FLDLENG TO ZERO             14600016
         SR    ROUTLENG,ROUTLENG        SET OUTLENG TO ZERO             14700016
         LA    RRECLENG,CCTPWKA         SET RECLENG TO EXTRACT RECORD   14800016
         LA    RRECLENG,2(RRECLENG)     THIRD POSITION                  14900016
         NI    COMSW,X'7F'              SET COMSW OFF                   15000016
         NI    PASSW,X'7F'             SET PASSW OFF                    15100016
         NI    NOCOMSW,X'7F'           SET NOCOMSW OFF                  15200016
         OI    PTRSW,X'80'             SET PTRSW ON                     15300016
*                                                                       15400016
*                                                                       15500016
BEGIN    TM    CCTPSTAT,X'80'           Q. IS JOB CARD REQUIRED BIT ON  15600016
         BO    GENJOB                   A. YES                          15700016
         CLC   CCTPWKA(3),ECI           Q. IS EXTRACT RECORD ENTER DATA 15800016
         BNE   PROCEXT                  A. NO                           15900016
         LA    RWK,CCTPWKA              SET RWK TO ADDR OF EXTRACT REC  16000016
         LA    RWK,3(RWK)                                               16100016
MOVECI   MVC   JCLOUTAR(80),0(RWK)        MOVE CARD IMAGE TO JCL OUTAR  16200016
         MVC   DECB(DCBLENG),WRITBEG   MOVE ECB TO WORKAREA DECB        16300016
         L     RPAR1,CCTJDCBP          GET ADDRESS OF JCL DCB           16400016
         ST    RPAR1,DECB+DCBADDR      SET UP DECB                      16500016
         LA    RPAR1,JCLOUTAR                                           16600016
         ST    RPAR1,DECB+AREAADDR     PUT IN AREA ADDRESS              16700016
         WRITE  DECB,SF,MF=E           WRITE A RECORD                   16800016
         CHECK  DECB                                                    16900016
*                                                                       17000016
         A     RWK,EIGHTY               INCREMENT RWK TO NEXT RECORD    17100016
         CLI   0(RWK),X'37'             Q. IS IT LAST RECORD            17200016
         BNE   MOVECI                   A. NO - GO TO MOVE NEXT         17300016
         B     WRITEEXT                 A. YES - GO TO WRITE EXTRACT    17400016
*                                                DATA SET               17500016
*                                                                       17600016
*  FOLLOWING IS A SERIES OF ROUTINES TO GENERATE JOB CARD(S)            17700016
*                                                                       17800016
GENJOB   EQU   *                                                        17900016
         SR    RWK,RWK                  CLEAR WORK REGISTER             18000016
         LA    RCCTLENG,JCLOUTAR        ADDRESS OF JCL OUTPUT           18400016
         MVC   0(3,RCCTLENG),CSLASH     MOVE //J TO JCL OUTPUT          18500016
         LA    RCCTLENG,3(RCCTLENG)     INCREMENT COUNTER               18600016
         MVC   0(3,RCCTLENG),CCTUNIT    MOVE UNIT ADDRESS               18700016
         LA    RCCTLENG,3(RCCTLENG)                                     18800016
         MVI   APOWORK,X'40'            CLEAR WORKAREA                  18900016
         MVC   APOWORK+1(39),APOWORK                                    19000016
         LH    RWK,CCTJCTR              LOAD JOBCOUNT                   19020016
         LA    RWK,1(RWK)               BUMP COUNT                      19040016
         STH   RWK,CCTJCTR              LOAD BACK NEW JOBCOUNT          19060016
         CVD   RWK,APOWORK              CONVERT JOB COUNTER TO DECIMAL  19100016
         UNPK  APOWORK+15(5),APOWORK+5(3) UNPACK                        19200016
         OI    APOWORK+19,X'F0'         CHANGE SIGN TO ZONE             19300016
         MVC   0(4,RCCTLENG),APOWORK+16 MOVE JOB COUNT                  19400016
         LA    RCCTLENG,5(RCCTLENG)     INCREMENT OUTPUT AREA COUNT     19500016
         LA    ROUTLENG,11(ROUTLENG)    INCREMENT LENGTH COUNT          19600016
         MVC   0(3,RCCTLENG),CJOB       MOVE 'JOB' TO OUTAREA           19700016
         LA    RCCTLENG,4(RCCTLENG)     INCREMENT COUNTERS              19800016
         LA    ROUTLENG,4(ROUTLENG)                                     19900016
         CLC   CCTUOTHR(20),BLANKS      Q. IS PASSWORD GIVEN            20000016
         BE    TESTACNO                 A. NO                           20100016
         MVC   0(1,RCCTLENG),LFTPAR     MOVE LEFT PARENTH.              20200016
         LA    RCCTLENG,1(RCCTLENG)     INCREMENT COUNTERS              20300016
         LA    ROUTLENG,1(ROUTLENG)                                     20400016
         OI    PASSW,X'80'              SET PASSWITCH ON                20500016
TESTACNO LA    RLENG,20                 MAX.LENGTH OF ACCOUNT NUMBER    20600016
         LA    RFLD,CCTUACCT+19         LOW POS. OF ACCOUNT NUMBER      20700016
SCAN1    CLI   0(RFLD),X'40'            SCAN ACCT.NUMBER TO GET LENGTH  20800016
         BNE   ENDSCAN1                 FIRST NON-BLANK - END OF SCAN   20900016
         S     RFLD,CONE                GO TO NEXT POSITION             21000016
         BCT   RLENG,SCAN1                                              21100016
ENDSCAN1 LA    RFLD,CCTUACCT            ADDRESS OF ACCOUNT NUMBER       21200016
         BAL   RRET,APOSTR              BRANCH TO APOSTR.SUBROUTINE     21300016
*                                                                       21400016
         LA    RWK2,APOWORK                                             21500016
         SR    RWK,RWK2                 GET LENGTH OF DATA IN WORKAREA  21600016
         S     RWK,CONE                DECREMENT BY 1                   21700016
         EX    RWK,MVWKA                EXECUTE MOVE OF DATA FROM WKAR. 21800016
         LA    RWK,1(RWK)               INCREMENT RWK                   21900016
         AR    RCCTLENG,RWK             INCREMENT COUNTERS              22000016
         AR    ROUTLENG,RWK                                             22100016
         MVC   0(1,RCCTLENG),COMMA      MOVE COMMA                      22200016
         OI    NOCOMSW,X'80'           SET NOCOMSW ON                   22300016
         LA    RCCTLENG,1(RCCTLENG)     INCREMENT COUNTERS              22400016
         LA    ROUTLENG,1(ROUTLENG)                                     22500016
         TM    PASSW,X'80'              Q. IS PASSWITCH ON              22600016
         BZ    COMPNAM                  A. NO                           22700016
         LA    RLENG,20                 MAX.LENGTH OF PASSWORD          22800016
         LA    RFLD,CCTUOTHR+19         LOW POS.OF PASSWORD             22900016
SCAN2    CLI   0(RFLD),X'40'            SCAN PASSWORD TO GET LENGTH     23000016
         BNE   ENDSCAN2                 FIRST NON-BLANK - END OF SCAN   23100016
         S     RFLD,CONE                                                23200016
         BCT   RLENG,SCAN2              GO TO NEXT POSITION             23300016
ENDSCAN2 LA    RFLD,CCTUOTHR            ADDRESS OF PASSWORD             23400016
         BAL   RRET,APOSTR              BRANCH TO APOSTR.SUBROUTINE     23500016
         LA    RWK2,APOWORK                                             23600016
         SR    RWK,RWK2                 GET LENGTH OF DATA IN WORKAREA  23700016
         LA    RWK,3(RWK)               INCREMENT BY 3                  23800016
         AR    ROUTLENG,RWK             ADD LENGTH OF DATA TO OUTLENGTH 23900016
         LR    RFLDLENG,RWK             SAVE LENGTH OF DATA             24000016
         S     RCCTLENG,CONE            DECREMENT BY 1(NEED FO TSTLEN)  24100016
         BAL   RRET,TESTLENG            BRANCH TO TEST LENGTH           24200016
         S     RWK,CFOUR                RESTORE DATA LENGTH FOR EXEC.   24300016
         EX    RWK,MVWKA                EXECUTE MOVE OF DATA FROM WKAR. 24400016
         LA    RWK,1(RWK)                                               24500016
         AR    RCCTLENG,RWK             INCREMENT COUNTER               24600016
         MVC   0(1,RCCTLENG),RTPAR      MOVE RIGHT PARENT.              24700016
         NI    PASSW,X'7F'              SET PASSW OFF                   24800016
         LA    RCCTLENG,1(RCCTLENG)     INCREMENT COUNTERS              24900016
         MVC   0(1,RCCTLENG),COMMA      MOVE COMMA                      25000016
         OI    NOCOMSW,X'80'           SET NOCOMSW ON                   25100016
         LA    RCCTLENG,1(RCCTLENG)     INCREMENT COUNTERS              25200016
         LA    ROUTLENG,1(ROUTLENG)                                     25300016
COMPNAM  LA    RLENG,20                 MAX.LENGTH OF NAME              25400016
         LA    RFLD,CCTUNAME+19         LOW POS. OF NAME                25500016
SCAN3    CLI   0(RFLD),X'40'            SCAN NAME TO GET LENGTH         25600016
         BNE   ENDSCAN3                 FIRST NON-BLANK - END OF SCAN   25700016
         S     RFLD,CONE                                                25800016
         BCT   RLENG,SCAN3              GO TO NEXT POSITION             25900016
ENDSCAN3 LA    RFLD,CCTUNAME            ADDRESS OF NAME                 26000016
         BAL   RRET,APOSTR              BRANCH TO APOSTR.SUBROUTINE     26100016
*                                                                       26200016
         LA    RWK2,APOWORK                                             26300016
         SR    RWK,RWK2                 GET LENGTH OF DATA IN WORKAREA  26400016
         LA    RWK,1(RWK)               INCREMENT BY ONE                26500016
         AR    ROUTLENG,RWK             ADD LENGTH OF DATA TO OUTLENGTH 26600016
         LR    RFLDLENG,RWK             SAVE LENGTH OF DATA             26700016
         S     RCCTLENG,CONE            DECREMENT BY ONE                26800016
         BAL   RRET,TESTLENG            BRANCH TO TEST LENGTH           26900016
         S     RWK,CTWO                 RESTORE DATA LENGTH FOR EXEC.   27000016
         EX    RWK,MVWKA                EXECUTE MOVE OF DATA FROM WKAR. 27100016
*                                                                       27200016
         AR    RCCTLENG,RWK             INCREMENT COUNTER               27300016
         LA    ROUTLENG,11(ROUTLENG)    SET UP COUNTERS                 27400016
         LA    RFLDLENG,11                                              27500016
         BAL   RRET,TESTLENG            BRANCH TO TEST LENGTH           27600016
*                                                                       27700016
         C     RCCTLENG,SIXTEEN       Q. IS JCL OUTPUT LENGTH OVER 16   27800016
         BNH   CONT1                    A. NO                           27900016
         MVC   0(1,RCCTLENG),COMMA      A. YES - MOVE COMMA             28000016
         LA    RCCTLENG,1(RCCTLENG)                                     28100016
         A     ROUTLENG,CONE                                            28200016
*                                                                       28300016
CONT1    MVC   0(10,RCCTLENG),MESLEV    MOVE MESSAGE LEVEL              28400016
         LA    RCCTLENG,9(RCCTLENG)     INCREMENT COUNTER               28500016
         LA    ROUTLENG,10(ROUTLENG)    SET UP COUNTERS                 28600016
         LA    RFLDLENG,10                                              28700016
         BAL   RRET,TESTLENG            BRANCH TO TEST LENGTH           28800016
         C     RCCTLENG,SIXTEEN        Q. IS JCL OUTPUT LENGTH OVER 16  28900016
         BNH   CONT2                   A. NO                            29000016
         MVC   0(1,RCCTLENG),COMMA     MOVE COMMA                       29100016
         LA    RCCTLENG,1(RCCTLENG)    INCREMENT COUNTERS               29200016
         A     ROUTLENG,CONE                                            29300016
CONT2    MVC   0(10,RCCTLENG),MSGCLASS  MOVE MESSAGE CLASS CONSTANT     29400016
         LA    RCCTLENG,9(RCCTLENG)     INCREMENT COUNTER               29500016
         TM    CCTPSTAT,X'10'         Q. IS JOB BACKGROUND              29530016
         BO    BACLASS                 YES,BRANCH                       29560016
         MVC   0(1,RCCTLENG),CCTSOUT    MOVE SYSOUT CLASS               29600016
         B     TESTSYST                                                 29700016
BACLASS  MVC   0(1,RCCTLENG),CCTSOUT+3     MOVE BACKGROUND MSG CLASS    29800016
TESTSYST EQU   *                                                        29900016
*                                                                       30000016
         L     RPAR1,CCTGEND            POINTER TO SYSGEND DATA         30060016
         CLC   28(2,RPAR1),CONE+2       Q. IS IT MVT                    30120016
         BE MVT                         A. YES                          30180016
         CLC   28(2,RPAR1),CTWO+2       Q. IS IT MFT                    30240016
         BE    MFT                      A. YES                          30300016
         MVC   APOWORK(20),BLANKS       CLEAR WORKSPACE                 30310016
         MVC   APOWORK(3),IMSG38        MOVE MESSAGE NUMBER INTO LIST   30320016
         MVC   APOWORK+3(5),MODIDEN          MODULE IDENTIFIER          30330016
         MVC   APOWORK+8(4),CZERO            ZEROS TO ADDR. OF INSERT   30340016
         OI    APOWORK+8,X'80'          SET CONTROL BIT (RETURN TO ME)  30350016
         LR    RPAR1,RCCT               CCT POINTER                     30360016
         LA    RPAR0,APOWORK            PARAMETER LIST POINTER          30370016
         L     RBR,CCTIERRP             LOAD POINTER TO IERR.ROUTINE    30380016
         BALR  RRET,RBR                 BRANCH TO IT                    30390016
*                                                                       30400016
* MESSAGE READS: IKA038I - SGSYS INVAL,MVT ASSUMED                      30410016
*                                                                       30420016
         CL    RBR,CQUIT              Q. IS RETURN CODE QUIT       PJKA 30440017
         BE    QUIT                   A. YES                       PJKA 30460017
MVT      EQU   *                                                        30480016
         LA    ROUTLENG,14(ROUTLENG)    INCREMENT POINTERS              30570016
         LA    RFLDLENG,14                                              30660016
         BAL   RRET,TESTLENG            BRANCH TO TEST LENGTH           30760016
*                                                                       30800016
         C     RCCTLENG,SIXTEEN         Q. IS JCL OUTPUT LENGTH OVER 16 30840016
         BNH   NOCOMMA1                 A. NO                           30880016
         MVC   0(1,RCCTLENG),COMMA      MOVE COMMA                      30920016
         LA    RCCTLENG,1(RCCTLENG)     INCREMENT COUNTERS              30960016
         A     ROUTLENG,CONE                                            31000016
NOCOMMA1 MVC   0(13,RCCTLENG),CROLL     MOVE IN ROLL CONSTANT           31090016
         LA    RCCTLENG,12(RCCTLENG)    INCREMENT POINTER               31180016
         S     ROUTLENG,CONE                                            31280016
*                                                                       31640016
*                                                                       31680016
MFT      EQU   *                                                        31720016
         TM    CCTPSTAT,X'10'           Q. IS IT BACKGROUND             31760016
         BO    BACKPRI                  Q. YES                          31800016
         CLC   CCTFRPRI(2),BLANKS       Q. IS FOREGROUND PRIORITY GIVEN 31840016
         BE    TSTCLASS                 Q. NO                           31880016
MAINPRI  LA    ROUTLENG,8(ROUTLENG)     INCREMENT COUNTERS              31920016
         LA    RFLDLENG,8                                               31960016
         BAL   RRET,TESTLENG            BRANCH TO TEST LENGTH           32000016
*                                                                       32040016
         C     RCCTLENG,SIXTEEN         Q. IS JCL OUTPUTLENG OVER 16    32080016
         BNH   NOCOMMA2                 A. NO                           32120016
         MVC   0(1,RCCTLENG),COMMA      MOVE COMMA                      32160016
         LA    RCCTLENG,1(RCCTLENG)     INCREMENT COUNTERS              32200016
         A     ROUTLENG,CONE                                            32240016
NOCOMMA2 MVC   0(5,RCCTLENG),PRITY      MOVE PRIORITY CONSTANT          32280016
         LA    RCCTLENG,5(RCCTLENG)     INCREMENT                       32320016
         TM    CCTPSTAT,X'10'           Q. IS IT BACKGROUND             32360016
         BO    MOVEBPRI                 A. YES                          32400016
         MVC   0(2,RCCTLENG),CCTFRPRI   MOVE FOREGROUND PRIORITY DATA   32440016
CONTPRI  LA    RCCTLENG,1(RCCTLENG)     INCREMENT COUNTERS              32480016
         S     ROUTLENG,CONE                                            32520016
         B     TSTCLASS                                                 32560016
*                                                                       32600016
BACKPRI  EQU   *                                                        32620017
         CLC   CCTUBPRI(2),BLANKS     Q. IS BACKGROUND PRI. ENTEREDPJKA 32640017
         BE    TSTCLASS                 A. NO                           32680016
         B     MAINPRI                                                  32720016
*                                                                       32760016
MOVEBPRI EQU   *                                                        32780017
         MVC   0(2,RCCTLENG),CCTUBPRI   MOVE BACKGR. PRI. DATA     PJKA 32800017
         B     CONTPRI                                                  32840016
*                                                                       32880016
*                                                                       32920016
TSTCLASS EQU   *                                                        32960016
         TM    CCTPSTAT,X'10'           Q. IS IT BACKGROUND             33120016
         BO    BACKJCLS                 A. YES                          33160016
         CLC   CCTFJCLS(1),BLANKS       Q. IS FOREGROUND JOBCLASS GIVEN 33200016
         BE    TYPRN                    A. NO                           33240016
MAINJCLS LA    ROUTLENG,8(ROUTLENG)     INCREMENT POINTERS              33280016
         LA    RFLDLENG,8                                               33320016
         BAL   RRET,TESTLENG            BRANCH TO TEST LENGTH           33360016
*                                                                       33400016
         C     RCCTLENG,SIXTEEN         Q. IS JCL OUTPUT LENGTH OVER 16 33440016
         BNH   NOCOMMA3                                                 33480016
         MVC   0(1,RCCTLENG),COMMA      MOVE COMMA                      33520016
         LA    RCCTLENG,1(RCCTLENG)     INCREMENT COUNTERS              33560016
         A     ROUTLENG,CONE                                            33600016
NOCOMMA3 MVC   0(6,RCCTLENG),CLASS      MOVE JOBCLASS CONSTANT          33640016
         LA    RCCTLENG,6(RCCTLENG)     INCREMENT COUNTER               33680016
         TM    CCTPSTAT,X'10'           Q. IS IT BACKGROUND             33720016
         BO    MVBJCLS                  A. YES                          33760016
         MVC   0(1,RCCTLENG),CCTFJCLS   MOVE FOREGROUND JOBCLASS        33800016
CONTJCLS S     ROUTLENG,CONE                                            33840016
         B     TYPRN                                                    33880016
*                                                                       33920016
BACKJCLS CLC   CCTBJCLS(1),BLANKS       Q. IS BACKGROUND JOBCLASS GIVEN 33960016
         BE    TYPRN                    A. NO                           34000016
         B     MAINJCLS                                                 34040016
*                                                                       34080016
MVBJCLS  MVC   0(1,RCCTLENG),CCTBJCLS   MOVE BACKGROUND JOBCLASS        34120016
         B     CONTJCLS                                                 34160016
*                                                                       34200016
*                                                                       34240016
TYPRN    TM    CCTPSTAT,X'10'           Q. IS IT BACKGROUND             34280016
         BO    MVGJP                                                    34320016
         LA    ROUTLENG,12(ROUTLENG)    INCREMENT POINTERS              34360016
         LA    RFLDLENG,12                                              34400016
         BAL   RRET,TESTLENG            BRANCH TO TEST LENGTH           34440016
*                                                                       34480016
         C     RCCTLENG,SIXTEEN         Q. IS JCL OUTPUT LENGTH OVER 16 34520016
         BNH   CONTTYPR                 A. NO                           34560016
         MVC   0(1,RCCTLENG),COMMA      MOVE COMMA                      34600016
         LA    RCCTLENG,1(RCCTLENG)     INCREMENT COUNTERS              34640016
CONTTYPR MVC   0(11,RCCTLENG),CTYPERUN  MOVE TYPERUN CONSTANT           34680016
*                                                                       34720016
MVGJP    LA    RCCTLENG,JCLOUTAR                                        35100016
         LA    RCCTLENG,73(,RCCTLENG)   SET COUNTER                PJKA 35130017
         TM    CCTSSTAT,32              Q. REMOTE GRAPHIC DEVICE   PJKA 35160017
         BZ    SGJP1                    NO                         PJKA 35190017
         MVI   0(RCCTLENG),C'S'         PRINTED RECORD IS FOR SGJP PJKA 35220017
SGJP1    LA    RCCTLENG,1(,RCCTLENG)    INCREMENT FOR CHARACTER    PJKA 35250017
         MVC   0(3,RCCTLENG),CGJP       MOVE GJP CONSTANT               35300016
         LA    RCCTLENG,3(RCCTLENG)                                     35400016
         MVC   0(3,RCCTLENG),CONVHSN    MOVE HIST.SEQU.NUMBER           35900016
         MVC   DECB(DCBLENG),WRITBEG   MOVE ECB TO WORKAREA DECB        36400016
         L     RPAR1,CCTJDCBP          GET ADDRESS OF JCL DCB           36500016
         ST    RPAR1,DECB+DCBADDR      SET UP DECB                      36600016
         LA    RPAR1,JCLOUTAR                                           36700016
         ST    RPAR1,DECB+AREAADDR     PUT IN AREA ADDRESS              36800016
         WRITE  DECB,SF,MF=E           WRITE A RECORD                   36900016
         CHECK  DECB                                                    37000016
*                                                                       37100016
         MVI   JCLOUTAR,X'40'           CLEAR JCL WORKAREA              37200016
         MVC   JCLOUTAR+1(79),JCLOUTAR                                  37300016
         OI    PTRSW,X'80'              SET PTRSWITCH ON                37400016
         SR    RFLDLENG,RFLDLENG        RESET FLDLENGTH                 37500016
         SR    ROUTLENG,ROUTLENG              OUTLENGTH                 37600016
         LA    RCCTLENG,JCLOUTAR              CCTLENGTH                 37700016
         NI    CCTPSTAT,X'7F'           SET JOB CARD REQUIRED BIT OFF   37750016
         B     BEGIN                                                    37800016
* * * * * *                                                             37900016
PROCEXT  LA    RRECLENG,1(RRECLENG)     INCREMENT POINTER TO EXTRACT    38000016
*                                       RECORD POSITION TESTED NEXT     38100016
         CLI   0(RRECLENG),X'40'        Q. IS THIS POSITION BLANK       38200016
         BNE   ISIT37                 A. NO                             38260016
         LTR   RFLDLENG,RFLDLENG      Q. LEADING BLANKS                 38320016
         BZ    PROCEXT                A. YES - DO NOT COUNT             38380016
ISIT37   CLI   0(RRECLENG),X'37'      Q. IS THIS A HEX 37 DELIMETER     38440016
         BE    WRITEEXT                 A. YES                          38500016
         CLI   0(RRECLENG),X'26'        Q. IS THIS A HEX 26 DELIMETER   38600016
         BE    HEX26                    A. YES                          38700016
         TM    COMSW,X'80'              Q. IS COMSWITCH ON              38800016
         BO    COMON                    A. YES                          38900016
TSTPTR   TM    PTRSW,X'80'              Q. IS PTRSWITCH ON              39000016
         BO    PTROF                    A. YES                          39100016
ISIT24   CLI   0(RRECLENG),X'24'        Q. IS THIS A HEX 24 DELIMETER   39200016
         BE    HEX24                    A. YES                          39300016
         CLI   0(RRECLENG),X'25'        Q. IS THIS A HEX 25 DELIMETER   39400016
         BE    HEX25                    A. YES                          39500016
         LA    RFLDLENG,1(RFLDLENG)     INCREMENT FLDLENGTH             39600016
         B     PROCEXT                                                  39700016
*                                                                       39800016
COMON    NI    COMSW,X'7F'              SET COMSWITCH OFF               39900016
         C     RFLDLENG,CONE            Q. IS FLDLENGTH ZERO            40000016
         BL    NOFLDL                   A. YES                          40100016
         MVC   0(1,RCCTLENG),COMMA      MOVE COMMA                      40200016
         LA    RCCTLENG,1(RCCTLENG)     INCREMENT COUNTERS              40300016
         LA    ROUTLENG,1(ROUTLENG)                                     40400016
         SR    RFLDLENG,RFLDLENG        RESET FLDLENGTH                 40500016
         B     TSTPTR                                                   40600016
*                                                                       40700016
NOFLDL   C     RFLDLENG,CZERO          Q. IS FIELDLENGTH NEGATIVE       40800016
         BL    WRONGINP                A. YES                           40900016
         S     RFLDLENG,CONE            DECREMENT FLDLENGTH TO BALANCE  41000016
* *                                     THE INCREMENT AT END OF PROCEXT 41100016
*                                                                       41200016
PTROF    NI    PTRSW,X'7F'              SET PTRSWITCH OFF               41300016
         LR    RWK,RRECLENG             SAVE RRECLENGTH                 41400016
         B     ISIT24                                                   41500016
*                                                                       41600016
HEX24    EQU   *                                                        41700016
         S     RCCTLENG,CONE                                            41800016
         C     RFLDLENG,CONE          Q. IS FLDLENGTH ZERO              41810016
         BL    UPDAT                  A. YES                            41820016
         OI    NOCOMSW,X'80'            SET NOCOMMA SWITCH ON           41850016
         BAL   RRET,TESTLENG            BRANCH TO TEST LENGTH           41900016
         S     RFLDLENG,CONE           DECREMENT BY 1 FOR EXEC.         42000016
         EX    RFLDLENG,MVEXTR          EXECUTE MOVE OF DATA TO JCLOUT. 42100016
*                                                                       42200016
UPDAT    EQU   *                                                        42250016
         AR    RCCTLENG,RFLDLENG        UPDATE POINTER TO JCLOUTAREA    42300016
         LA    RCCTLENG,2(RCCTLENG)    AND REPOSITION TO NEXT FIELD     42400016
         LA    ROUTLENG,1(ROUTLENG)    INCREMENT OUTLENG                42500016
         SR    RFLDLENG,RFLDLENG        RESET FLDLENGTH                 42600016
PTRON    OI    PTRSW,X'80'              SET PTRSWITCH ON                42700016
         B     PROCEXT                                                  42800016
*                                                                       42900016
HEX25    NI    SW26,X'7F'               SET SW26 OFF                    43000016
TSTFLDL  C     RFLDLENG,CONE            Q. IS FLDLENGTH ZERO            43100016
         BL    NOFLDL                   A. YES                          43200016
FLDLNZER EQU   *                                                        43300016
         S     RCCTLENG,CONE                                            43400016
         OI    NOCOMSW,X'80'            SET NOCOMMA SWITCH ON           43450016
         BAL   RRET,TESTLENG            BRANCH TO TEST LENGTH           43500016
         S     RFLDLENG,CONE           DECREMENT BY 1 FOR EXEC.         43600016
         EX    RFLDLENG,MVEXTR          EXECUTE MOVE OF DATA TO JCLOUT. 43700016
*                                                                       43800016
         AR    RCCTLENG,RFLDLENG        UPDATE POINTER TO JCLOUTAREA    43900016
         LA    RCCTLENG,1(RCCTLENG)    AND REPOSITION TO NEXT FIELD     44000016
*                                                                       44100016
SWCH26   TM    SW26,X'80'               Q. IS SW26 ON                   44200016
         BO    SW26OF                   A. YES                          44300016
         OI    COMSW,X'80'              SET COMSWITCH ON                44400016
         B     PTRON                                                    44500016
*                                                                       44600016
SW26OF   NI    SW26,X'7F'               SET SW26 OFF                    44700016
         B     MVGJP                                                    44800016
*                                                                       44900016
HEX26    OI    SW26,X'80'              SET SW26 ON                      45000016
         C     RFLDLENG,CONE           Q. IS FIELD LENGTH ZERO          45100016
         BL    SW26OF                  A. YES                           45200016
         B     FLDLNZER                A. NO                            45300016
*                                                                       45400016
*              *  WRITE EXTRACT RECORD ON EXTRACT DATASET  *            45410016
*                                                                       45420016
WRITEEXT EQU   *                                                        45450016
         MVC   DECB(DCBLENG),WRITBEG   MOVE ECB TO WORKAREA DECB        45500016
         L     RPAR1,CCTEDCBP          GET ADDRESS OF EXTRACT DCB       45600016
         ST    RPAR1,DECB+DCBADDR      SET UP DECB                      45700016
         LA    RPAR1,CCTOVRLY           BEGINNING OF EXTRACT RECORD     45800016
         ST    RPAR1,DECB+AREAADDR     PUT IN AREA ADDRESS              45900016
         WRITE  DECB,SF,MF=E           WRITE A RECORD                   46000016
         CHECK  DECB                                                    46100016
         SR    RBR,RBR                  NORMAL RETURN CODE         PJKA 46130017
QUIT     EQU   *                                                   PJKA 46160017
         L     RSAVE,4(RSAVE)                                           46200016
         LR    RPAR1,RMANIP            LOAD ADDR OF MAIN STORAGE WKA    46300016
         FREEMAIN  R,LV=208+DCBLENG,A=(1)                               46400016
         RETURN (14,12),RC=(15)         RETURN TO PROCESSOR        PJKA 46500017
*                                                                       46600016
WRONGINP EQU   *                                                        46620016
         MVC   APOWORK(20),BLANKS       CLEAR WORKSPACE                 46640016
         MVC   APOWORK(3),IMSG39        MOVE MESSAGE NUMBER INTO LIST   46660016
         MVC   APOWORK+3(5),MODIDEN          MODULE IDENTIFIER          46680016
         MVC   APOWORK+8(4),CZERO            ZEROS TO ADDR. OF INSERT   46700016
         OI    APOWORK+8,X'80'          SET CONTROL BIT (RETURN TO ME)  46720016
         LR    RPAR1,RCCT               CCT POINTER                     46740016
         LA    RPAR0,APOWORK            PARAMETER LIST POINTER          46760016
         L     RBR,CCTIERRP             LOAD POINTER TO IERR.ROUTINE    46780016
         BALR  RRET,RBR                 BRANCH TO IT                    46800016
*                                                                       46820016
* MESSAGE READS: IKA039I - PROCESSOR INPUT ERR                          46840016
*                                                                       46860016
         CL    RBR,CQUIT              Q. IS RETURN CODE QUIT       PJKA 46870017
         BE    QUIT                   A. YES                       PJKA 46880017
         SR    RFLDLENG,RFLDLENG       RESET FIELDLENGTH                46900016
         B     PROCEXT                 SKIP THIS DELIMETER AND CONTIN.  47000016
*                                                                       47188016
* * * * * * * * * * * * * * * * * * * *                                 47200016
         EJECT                                                          47300016
*                                                                       47400016
* * *               * *  TESTLENG SUBROUTINE  * *                       47500016
*                                                                       47600016
*                 SCAN BACKWARDS EACH FIELD AND SUBTRACT THE AMOUNT     47620016
*                 OF TRAILING BLANKS FROM FIELDLENGTH TO GET THE ACTUAL 47640016
*                 LENGTH OF THE FIELD                                   47660016
*                 TESTS THE LENGTH OF A FIELD TO BE MOVED TO THE        47700016
*                 JCL OUTPUT AREA AND IF THE FIELD WILL NOT FIT         47800016
*                 INTO THE AVAILABLE SPACE,WILL WRITE OUT AN 80         47900016
*                 CHARACTER JCL-RECORD AND THAN MOVE THE FIELD TO       48000016
*                 THE BEGINNING (POS.16) OF THE NEXT JCL OUTPUT.        48100016
*                                                                       48200016
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 48300016
*                                                                       48400016
TESTLENG EQU   *                                                        48410016
         TM    CCTPSTAT,X'80'         Q. IS JOB CARD REQUIRED BIT ON    48420016
         BO    NOSCAN                 A. YES                            48430016
         LR    RPAR1,RRECLENG           POINTER TO DELIMETER            48440016
SCANBACK S     RPAR1,CONE               DECREMENT POINTER TO FLD.TESTED 48450016
         CLI   0(RPAR1),X'40'           TEST FOR BLANK                  48460016
         BNE   CONTESTL                 NONBLANK - END OF SCAN          48470016
         BCT   RFLDLENG,SCANBACK        DECREMENT FIELDLENGTH-CONTINUE  48480016
CONTESTL AR    ROUTLENG,RFLDLENG        ESTABLISH OUTLENG               48490016
NOSCAN   C     ROUTLENG,CSEVTY        Q. IS OUTLENG OVER 70             48500016
         BNH   INCCTL                   A. NO                           48600016
         TM    NOCOMSW,X'80'           Q. IS NOCOMSW ON                 48700016
         BO    NOCOMMA                 A. YES                           48800016
         MVC   1(1,RCCTLENG),COMMA      MOVE COMMA                      48900016
NOCOMMA  LA    RCCTLENG,JCLOUTAR       SET COUNTER TO CONTINUATION COL. 49000016
         LA    RCCTLENG,71(RCCTLENG)                                    49100016
         MVI   0(RCCTLENG),X'E7'        SET X IN CONTINUATION COLUMN    49200016
         LA    RCCTLENG,2(,RCCTLENG)                               PJKA 49230017
         TM    CCTSSTAT,32              Q. REMOTE GRAPHIC DEVICE   PJKA 49260017
         BZ    SGJP2                    NO                         PJKA 49290017
         MVI   0(RCCTLENG),C'S'         PRINTED RECORD IS FOR SGJP PJKA 49320017
SGJP2    LA    RCCTLENG,1(,RCCTLENG)    INCREMENT FOR CHARACTER    PJKA 49350017
         MVC   0(3,RCCTLENG),CGJP       MOVE GJP CONSTANT               49400016
         LA    RCCTLENG,3(RCCTLENG)                                     49500016
         MVC   0(3,RCCTLENG),CONVHSN    MOVE HIST.SEQU.NUMBER           49900016
         LR    ROUTLENG,RRET            SAVE RETURN ADDR. TO CALLER     50200016
*                                                                       50500016
         MVC   DECB(DCBLENG),WRITBEG   MOVE ECB TO WORKAREA DECB        50600016
         L     RPAR1,CCTJDCBP          GET ADDRESS OF JCL DCB           50700016
         ST    RPAR1,DECB+DCBADDR      SET UP DECB                      50800016
         LA    RPAR1,JCLOUTAR                                           50900016
         ST    RPAR1,DECB+AREAADDR     PUT IN AREA ADDRESS              51000016
         WRITE  DECB,SF,MF=E           WRITE A RECORD                   51100016
         CHECK  DECB                                                    51200016
*                                                                       51300016
         MVI   JCLOUTAR,X'40'           CLEAR JCL WORKAREA              51400016
         MVC   JCLOUTAR+1(79),JCLOUTAR                                  51500016
         LR    RRET,ROUTLENG            RESTORE RETURN ADDR.            51550016
         LA    RCCTLENG,JCLOUTAR        RESET COUNTER                   51600016
         MVC   0(2,RCCTLENG),CSLASH     MOVE// CONSTANT                 51700016
         LA    RCCTLENG,14(RCCTLENG)    INCREMENT COUNTERS              51800016
         L     ROUTLENG,CSIXTN                                          51900016
         AR    ROUTLENG,RFLDLENG                                        52000016
*                                                                       52300016
INCCTL   LA    RCCTLENG,1(RCCTLENG)     SET POINTER TO CORRECT OUTPUT   52400016
*                                       POSITION                        52500016
         NI    NOCOMSW,X'7F'           SET NOCOMSW OFF                  52600016
         BR    RRET                     BRANCH BACK TO CALLER           52700016
* * * * * * * *                                                         52800016
         EJECT                                                          52900016
* * *               * *  APOSTR SUBROUTINE  * *                         53000016
*           WILL DOUBLE SINGLE APOSTROPHIES OF USER'S INPUT             53100016
*           DATA (WHERE LEGITIMATE) TO MAKE FIELD USABLE FOR JCL        53200016
*                                                                       53300016
APOSTR   LA    RLENG,1(RLENG)          SET COUNTER                      53400016
         LA    RWORK,APOWORK            LOAD ADDRESS OF WORKAREA        53500016
         MVC   APOWORK(20),BLANKS       BLANK OUT WORKAREA              53600016
         MVC   APOWORK+20(20),BLANKS                                    53700016
         NI    DOUBLSW,X'7F'            SET DOUBLSWITCH OFF             53800016
         MVI   0(RWORK),X'7D'           MOVE IN LEADING APOSTROPHE      53900016
         A     RWORK,CONE               INCREMENT COUNTER               54000016
BEGAPO   CLI   0(RFLD),X'7D'            Q. IS THIS AN APOSTROPHE        54100016
         BE    TESTDBL                  A. YES                          54200016
         TM    DOUBLSW,X'80'            A. NO - TEST DOUBLESWITCH       54300016
         BZ    ENDOFLD                  A. DOUBLSWITCH OFF              54400016
         MVI   0(RWORK),X'7D'           MOVE APOSTROPHE TO WORKAREA     54500016
         A     RWORK,CONE               INCREMENT COUNTER               54600016
DBLOFF   NI    DOUBLSW,X'7F'            SET DOUBLSWITCH OFF             54700016
ENDOFLD  BCT   RLENG,MVDIGIT            Q. IS IT END OF FIELD TESTED    54800016
         MVI   0(RWORK),X'7D'           A. YES - MOVE IN TRAILING APOS. 54900016
         A     RWORK,CONE               INCREMENT COUNTER               55000016
         B     ENDAPO                   END OF ROUTINE                  55100016
MVDIGIT  MVC   0(1,RWORK),0(RFLD)       MOVE DIGIT TO WORKAREA          55200016
         A     RWORK,CONE               INCREMENT COUNTERS              55300016
         A     RFLD,CONE                                                55400016
         B     BEGAPO                   TEST NEXT POSITION              55500016
TESTDBL  TM    DOUBLSW,X'80'            R. IS DOUBLSWITCH ON            55600016
         BO    DBLOFF                   A. YES                          55700016
         OI    DOUBLSW,X'80'            SET DOUBLSWITCH ON              55800016
         B     ENDOFLD                                                  55900016
ENDAPO   BR    RRET                                                     56000016
*                                                                       56100016
         EJECT                                                          56200016
* * *            * *  CONSTANTS  * *                                    56300016
*                                                                       56400016
CZERO    DC    F'0'                                                     56500016
CONE     DC    F'1'                                                     56600016
CTWO     DC    F'2'                                                     56700016
CTRI     DC    F'3'                                                     56800016
CFOUR    DC    F'4'                                                     56900016
CSIXTN   DC    F'16'                                                    57000016
CSEVTY   DC    F'70'                                                    57100016
EIGHTY   DC    F'81'                                                    57200016
CQUIT    DC    X'0000001C'                                         PJKA 57250017
ECI      DC    C'ENT'                                                   57300016
CSLASH   DC    C'//'                                                    57400016
CJOB     DC    C'JOB'                                                   57500016
BLANKS   DC    20CL1' '                                                 57600016
LFTPAR   DC    C'('                                                     57700016
CAPO     DC    X'7D'                                                    57800016
RTPAR    DC    C')'                                                     57900016
COMMA    DC    C','                                                     58000016
MESLEV   DC    C'MSGLEVEL=1'                                            58100016
MSGCLASS DC    C'MSGCLASS='                                             58200016
PRITY    DC    C'PRTY='                                                 58280016
REG      DC    C'REGION=000K'                                           58360016
CTYPERUN DC    C'TYPRUN=HOLD'                                           58430016
CLASS    DC    C'CLASS='                                                58500016
CROLL    DC    C'ROLL=(NO,YES)'                                         58550016
CGJP     DC    C'GJP'                                                   58600016
MODIDEN  DC    C'JCL  '                                                 58620016
IMSG38   DC    C'038'                                                   58640016
IMSG39   DC    C'039'                                                   58660016
*                                                                       58700016
MVWKA    MVC   0(0,RCCTLENG),APOWORK    INSTRUCTION TO MOVE WKAREA TO   58800016
*                                       JCL OUTPUT AREA                 58900016
*                                                                       59000016
MVEXTR   MVC   0(0,RCCTLENG),0(RWK)     INSTRUCTION TO MOVE DATA FROM   59100016
* * *                                   EXTRACT RECORD TO JCL OUTAREA   59200016
         SPACE 2                                                        59210000
*********************************************************************** 59220000
*                                                                       59230000
*        MAINTENANCE AREA                                        A33564 59240000
*                                                                       59250000
*********************************************************************** 59260000
PATCH    DC    26F'0'                                            A33564 59270000
         SPACE 2                                                        59280000
* * *                                                                   59300016
         WRITE  WRITBEG,SF,,,,MF=L                                      59400016
WRITEND  EQU   *                                                        59500016
DCBLENG  EQU   WRITEND-WRITBEG                                          59600016
DCBADDR  EQU   8                                                        59700016
AREAADDR EQU   12                                                       59800016
         END                                                            59900016
