*                                                                       00200016
         START 0                                                        00400016
* MODULE NAME      -IKAPBEG                                             00600016
*                                                                       00800016
* CHART  ID        - FJ                                                 01000016
*                                                                       01200016
* FUNCTION         -PREPARE TO START USER'S JOB                         01400016
*                                                                       01600016
* ATTRIBUTES       -TRANSIENT,REENTERABLE                               01800016
*                                                                       02000016
* ENTRY POINTS     -IKAPBEG                                             02200016
*                  -ENTERED UPON LINK FROM CONTROL(CTL)                 02400016
*                                                                       02600016
* OPERATION        -PASS PARAMETER LIST TO IKAPROC0 IF BEGIN PROCEDURE  02640016
*                   OPTION IS TAKEN AND PERFORM JCL TO THE JCL          02680016
*                   GENERATOR                                           02720016
*                  -DISPLAY MESSAGE IF RETURN CODE FROM IKAPROC0 IS NOT 02760016
*                   NORMAL COMPLETION                                   02800016
*                  -PUT OUT 'JOB SCHEDULED AS JXXXYYYY' MESSAGE         02840016
*                   WHERE  XXX---2250 ADDRESS                           02880016
*                         YYYY--JOB COUNT                               02920016
*                                                                       02960016
*                  -GO TO DIARY ROUTINE                                 03000016
*                  -PASS /* CARD TO THE JCL GENERATOR                   03200016
*                  -WRITE PORTION OF CCT TO BE SAVED ON DIA DATA SET    03400016
*                  -PERFORM NOTE FUNCTION FOR EXTRACT AND DIA           03600016
*                  -CLOSE DCB'S FOR EXTRACT AND DIA                     03800016
*                                                                       04200016
* EXITS            -XCTL TO SCHEDULER INTERFACE MODULE                  04400016
*                                                                       04600016
* INPUT            -REGISTER 1 POINTING TO CONSOLE CONTROL TABLE        04850016
*                                                                       04900016
*                  -REGISTER 13 POINTING TO REGISTER SAVE AREA          04950016
*                                                                       05000016
* OUTPUT           -/* CARD IN CCT                                      05200016
*                  -//          EXEC   XXXXXXXX                         05220016
*                   WHERE XXXXXXXX---PROCEDURE NAME                     05240016
*                  -//PROCSTEP.DDNAME DD  UNIT=YYY                      05260016
*                   WHERE PROCSTEP IS THE STEP NAME IN THE PROCEDURE    05280016
*                   AND DDNAME IS THE DDNAME OF THE DD CARD             05300016
*                   YYY IS 2250 ADDRESS                                 05320016
*                  -/*                                                  05340016
*                                                                       05400016
* EXTERNAL REFERENCES  -JCL GENERATOR                                   05600016
*                      -DIARY RTN                                       05800016
*                      -MSG RTN                                         06000016
*                  -PROCEDURE ROUTINE                                   06060016
*                                                                       06120016
*                                                                       06200016
* ERROR CONDITIONS -NONE                                                06400016
*                                                                       06600016
* TABLES AND WORKAREAS  -CONSOLE CONTROL TABLE                          06800016
*                                                                       07000016
* RESTRICTIONS     -NONE                                                07200016
         EJECT                                                          07400016
         EJECT                                                          07480016
         SPACE                                                          07560016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         07640016
         SPACE                                                          07720016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    07800016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     07880016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       07960016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             08040016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  08120016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  08200016
*                   SET.                                                08280016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      08360016
*                   SECOND.                                             08440016
         SPACE 2                                                        08520016
CCT      DSECT                                                          08600016
         SPACE 2                                                        08680016
*                             SECTION ONE                               08760016
         SPACE                                                          08840016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     08920016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    09000016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  09080016
         SPACE                                                          09160016
         DS    0F                                                       09240016
CCTUNAME DS    5F                  USER'S NAME                          09320016
CCTVACCT DS    5F                  USER'S ACCOUNT NUMBER                09400016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     09480016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       09560016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    09640016
*                                       AT LAST BEGIN JOB               09720016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   09800016
*                                       LAST BEGIN JOB                  09880016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 09960016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    10040016
*                                       JOB                             10120016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    10200016
*                                       JOB                             10280016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     10360016
*                                       CESSOR                          10440016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         10520016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         10600016
CCTJCTR  DS    H                   JOB COUNTER                          10680016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                10760016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   10840016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  10920016
CCTSSTAT DS    C                   SESSION STATUS                       11000016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              11080016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              11160016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    11240016
         EJECT                                                          11320016
         SPACE 2                                                        11400016
*                             SECTION TWO                               11480016
         SPACE                                                          11560016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   11640016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  11720016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 11800016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              11880016
         SPACE                                                          11960016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     12040016
*                                       FRAME                           12120016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  12200016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     12280016
*                                       MULTIPLE DISPLAY FRAME (ENT)    12360016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   12440016
CCTDISM  DS    C                   DISPLAY MASK                         12520016
CCTCSM   DS    C                   COMMAND SELECT MASK                  12600016
CCTPSTAT DS    CL2                 GJP STATUS                           12680016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              12760016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  12840016
         SPACE 2                                                        12920016
*                             SECTION THREE                             13000016
         SPACE                                                          13080016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    13160016
*                   INTO SECTION ONE OR TWO                             13240016
         SPACE                                                          13320016
CCTDGMP  DS    F                  POINTER TO DGM                        13400016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                13480016
CCTCSTP  DS    F                  POINTER TO CST                        13560016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                13640016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            13720016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 13800016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              13880016
CCTDIARP DS    F                  POINTER TO DIA                        13960016
CCIDIRP  DS    F                  POINTER TO DISPLAY INPUT RTN          14040016
CCTACTP  DS    F                  POINTER TO ACT                        14120016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     14200016
CCTIERRP DS    F                  POINTER TO IERR                       14280016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              14360016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               14440016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                14520016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 14600016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 14680016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   14760016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                14840016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                14920016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               15000016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              15080016
CCTPECB  DS    F                  PROCESSOR'S ECB                       15160016
CCTWECB  DS    F                  WTOR ECB                              15240016
CCTDIAWA DS    CL136               DIARY WORK AREA                      15320016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    15400016
CCTCSAVE DS    CL72                CTL SAVE AREA                        15480016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                15560016
CCTASAVE DS    CL72                DAT SAVE AREA                        15640016
         EJECT                                                          16600016
IKAPBEG0 CSECT                                                          16800016
*1761,424000                                                       PDUM 16900017
*                                                                       17000016
PBEG     TITLE 'THE BEGIN JOB PROCESSING ROUTINE'                       17200016
*                                                                       17400016
RPAR0    EQU   0                                                        17600016
RPAR1    EQU   1                                                        17800016
RWORK3   EQU   2                                                        18000016
RWORK    EQU   3                                                        18200016
RINTRETN EQU   3                                                        18400016
RWORK1   EQU   4                                                        18600016
RWORK2   EQU   5                                                        18800016
RCOUNT   EQU   6                                                        19000016
RAREA    EQU   7                                                        19200016
RDCB     EQU   8                                                        19400016
RLIST    EQU   9                                                        19600016
RNOTE    EQU   10                                                       19800016
RBASE    EQU   11                       BASE REGISTER                   20000016
RCCT     EQU   12                       CCT DSECT BASE                  20200016
RSAVE    EQU   13                       SAVE REGISTER                   20400016
RRET     EQU   14                       RETURN REG                      20600016
RBR      EQU   15                       BRANCH AND RETURN CODE REG      20800016
BYTECON  EQU   X'C0'                                                    21000016
ONE      EQU   X'01'                                                    21200016
SIZE     EQU   356                                                      21400016
PROCADR1 EQU   21                          ADDRESS BEGIN PROCEDURE      21600016
PROCADR2 EQU    268                    ADDRESS OF BEGIN PROCEDURE       21800016
PRONAME1 EQU    280                    ADDRESS OF PROCEDURE NAME        22000016
PRONAME2 EQU   32                          ADDRESS PROCEDURE NAME       22200016
NAMEPTER EQU    276                    POINTER TO PROCEDURE NAME        22400016
         EJECT                                                          22600016
         SAVE  (14,12)                  SAVE REGISTERS                  22800016
         BALR  RBASE,0                  BASE REG                        23000016
         USING *,RBASE                                                  23200016
         USING CCT,RCCT                                                 23400016
         LR    RCCT,RPAR1               ADDRESS OF CCT                  23600016
         LA    RPAR1,CCTPSAVE           ADDRESS OF PROCESSOR SAVE AREA  23800016
         ST    RPAR1,8(RSAVE)           PNTR IN OLD TO NEW SAVE AREA    24000016
         ST    RSAVE,CCTPSAVE+4         PNTR IN NEW TO OLD SAVE AREA    24200016
         LR    RSAVE,RPAR1              POINT REG 13 TO NEW SAVE AREA   24400016
         CLC   CCTPWKA+PROCADR2(8),BLANKS   O. BEGIN PROCEDURE          24600016
         BNE   BEGPROC                        BRANCH BEGPROC IF YES     24800016
         BAL   14,MOVEJTR                                               24900016
         B     JCLEND                  BRANCH JCLEND IF BEGIN JOB       25000016
BEGMSG   LA    RWORK,CCTPWKA+20        A LOCATION OF WORK AREA          25200016
         N     RWORK,DOUBLE             A DOUBLE WORD BOUNDARY          25400016
         LH    RWORK1,CCTJCTR          JOB COUNTER                      25600016
         CVD   RWORK1,0(RWORK)          CONVERT TO DECIMAL              25800016
         UNPK  CCTPWKA(5),5(3,RWORK)   UNPACK IT                        26000016
         OI    CCTPWKA+4,X'F0'         CLEAR ZONE                       26200016
         MVC   CCTPWKA(4),CCTPWKA+1    PUT IT ON A FULL WORD            26400016
         L     RWORK,CCTPWKA                    MOVE COUNT TO REGISTER  26600016
         EJECT                                                          26800016
*                                                                       27000016
* PREPARE TO PUT OUT MESSAGE                                            27200016
*                                                                       27400016
         SR    RWORK1,RWORK1            CLEAR REGISTER                  27600016
         ST    RWORK1,CCTPWKA           CLEAR FIRST WORD OF WORK AREA   27800016
         L     RWORK1,PBEGM             ADDRESS OF MESSAGE MODULE       28000016
         L     RWORK1,0(RWORK1)         POINT MESSAGE                   28200016
         LA    RWORK2,CCTPWKA+4         LOAD ADDRESS                    28400016
         ST    RWORK2,CCTPWKA           PUT IN MESSAGE PARAMETER        28600016
         MVI   CCTPWKA,X'C0'            OPTION BYTE                     28800016
         MVC   CCTPWKA+4(26),0(RWORK1)  MOVE IN MESSAGE                 29000016
         MVC   CCTPWKA+UNITPOS+4(3),CCTUNIT  2250 ADDRESS               29200016
         ST    RWORK,CCTDIAWA           JOB COUNT                       29400016
         MVC   CCTPWKA+CNTPOS+4(4),CCTDIAWA  JOB COUNT TO MSG           29600016
         LA    RPAR0,CCTPWKA            PARAMETER LIST FOR DMSG         29800016
         LR    RPAR1,RCCT               CCT ADDRESS                     30000016
         L     RBR,CCTDMRP              ADDRESS OF MESSAGE ROUTINE      30200016
         OI    CCTSSTAT,16              INDICATE NO EXTRACT RECORD PDUM 30300017
         BALR  RRET,RBR                 GO TO MESSAGE MODULE            30400016
         CH    15,CODE1C               Q. INTERNAL ERROR HAPPENED  PDUM 30430017
         BE    RETURNIR                 BRANCH IF YES              PDUM 30460017
         B     NOTEEXT                  BRANCH                          30500016
         EJECT                                                          30600016
         EJECT                                                          32800016
* PREPARE FOR JCL GENERATOR                                             33000016
JCLEND   EQU   *                                                        33100016
         MVC   CCTPWKA(7),SLASHCON     MOVE JCL                         33700016
         B     GOJCL                                                    34400016
MOVEJCL  MVC   CCTPWKA(LRECORD),PROCJCL MOVE PROC JCL IN PROCESSOR WKA  34600016
         MVC   CCTPWKA+PROCADR1(8),CCTPWKA+PROCADR2   PACK PROCEDURE    34800016
         TM    CCTPSTAT,X'10'          Q. BACKGROUND PROCEDURE          34860016
         BO    BACKPROC                BRANCH IF YES                    34920016
         MVC   CCTPWKA+PRONAME2(18),CCTPWKA+PRONAME1  JCL RECORD        35000016
         MVC   CCTPWKA+59(3),CCTUNIT   MOVE UNIT ADDRESS IN WORKAREA    35100016
         LA    RWORK1,16               LOAD PROC CODE              9904 35110018
         CR    RBR,RWORK1          Q. CODE=PROC                    9904 35120018
         BNE   GOJCL               A.NO                            9904 35130018
         MVC   CCTPWKA+PROCJCL6(PROCJCL5),PROCJCL2  MOVE PROC JCL  9904 35140018
         MVC   CCTPWKA+PROCJCL7(3),CCTUNIT  MOVE IN UNIT ADDR      9904 35150018
GOJCL    LR    RPAR1,RCCT              LOAD CCT ADDRESS                 35200016
         L     RBR,CCTJCLGP            LOAD JCL GENERATOR ADDR          35400016
         BALR  RRET,RBR                TGO TO JCL GENERATOR             35600016
         CH    15,CODE1C               Q. INTERNAL ERROR HAPPENED  PDUM 35660017
         BE    RETURNIR                 BRANCH IF YES              PDUM 35720017
         B     BEGMSG                   BRANCH                          35800016
MOVEJTR  EQU   *                                                        35810016
         LA    RWORK,CCTPWKA+200       A ADDR                           35820016
         N     RWORK,DOUBLE            DOUBLE WORD BOUNDRY              35830016
         LH    RWORK1,CCTJCTR          JOB COUNTER                      35840016
         CVD   RWORK1,0(RWORK)         CONVERT TO DECIMAL               35850016
         UNPK  CCTPWKA+180(5),5(3,RWORK)   UNPACK                       35860016
         OI    CCTPWKA+184,X'F0'                                        35870016
         MVI   CCTPWKA+70,C'J'                                          35880016
         MVC   CCTPWKA+71(3),CCTUNIT   UNIT ADDR                        35890016
         MVC   CCTPWKA+74(4),CCTPWKA+181                                35900016
         BR    14                      BRANCH                           35910016
BACKPROC EQU   *                                                        35930016
         MVC   CCTPWKA+30(4),ENDJCL    MOVE /* AND 2637 IN WORKAREA     35950016
         B     GOJCL                   BRANCH TO JCL GENERATOR          35970016
         EJECT                                                          36000016
*                                                                       36200016
* SET PARAMETER AND LINK TO IKAPROC0                                    36400016
*                                                                       36600016
BEGPROC  LA    RWORK1,CCTPWKA+PRONAME1  POINT TO PROCEDURE NAME         36800016
         ST    RWORK1,CCTPWKA+NAMEPTER  SAVE IT                         37000016
         LA    RPAR0,CCTPWKA+PROCADR2   POINT TO PROCEDURE              37200016
         LR    RPAR1,RCCT               POINT TO CCT                    37400016
         TM    CCTPSTAT,X'10'          Q. BACKGROUND PROCEDURE          37440016
         BZ    FORPROC                 BRANCH IF NO                     37480016
         OI    CCTPWKA+NAMEPTER,X'80'  SET BACKGROUND WIITCH            37520016
FORPROC  EQU   *                                                        37560016
         LINK  EP=IKAPROC0              LINK PROCEDURE MODULE           37600016
         LA    RWORK1,0                 LOAD NORMAL RETURN CODE         37800016
         CR    RBR,RWORK1               NORMAL RETURN                   38000016
         BE    CODEOK              A. CODE OK                      9904 38050018
         LA    RWORK1,16           PROC CARD CODE                  9904 38100018
         CR    RBR,RWORK1          Q. CODE = PROC                  9904 38150018
         BNE   PROCMSG                  BRANCH TO PROCMSG IF NOT        38200016
CODEOK   EQU   *                                                   9904 38300018
         MVC   CCTDIAWA+23(8),PROCCON   MOVE PROC DATA IN DIAWKA        38400016
         LH    RWORK2,CCTJCTR          * UPDATE                         38420016
         LA    RWORK3,1(RWORK2)        *    JOBCOUNT FOR                38440016
         STH   RWORK3,CCTJCTR          *            RECALL              38460016
         BAL   14,MOVEJTR                                               38500016
         STH   RWORK2,CCTJCTR          RESTORE JOB COUNT                38550016
         B     MOVEJCL                  BRANCH                          38600016
         EJECT                                                          38800016
*                                                                       39000016
* SET ERROR MESSAGE TURN ON MESSAGE TO BE DISPLAY SWITCH IN CCT         39200016
*                                                                       39400016
PROCMSG  LA    RWORK1,4                 LOAD RETURN CODE 4              39600016
         CR    RBR,RWORK1               PROCEDURE NOT FIND              39800016
         BE    NOTFIND                  BRANCH NOTFIND IF YES           40000016
         LA    RWORK1,8                 SET A CODE = 8 IN REGISTER PDUM 40020017
         CR    RBR,RWORK1              Q. INPUT OUTPUT ERROR       PDUM 40040017
         BE    IOERROR                  BRANCH IF YES              PDUM 40060017
NOSTEP   BAL   RINTRETN,INTERMSG        STEP NAME NOT FOUND        PDUM 40080017
         DC    H'12'                    SET CODE FOR MESSAGE       PDUM 40100017
         B     SWITCHON                 BRANCH                     PDUM 40120017
IOERROR  BAL   RINTRETN,INTERMSG        BRANCH INTERMSGE IF IO ERROR    40200016
         DC    H'8'                     MESSAGE INDICATOR               40400016
         B     SWITCHON                 GO TO TURN ON MESSAGE SWITCH    40600016
NOTFIND  BAL   RINTRETN,INTERMSG        BRANCH TO INTERMSG              40800016
         DC    H'4'                     MESSAGE INDICATOR               41000016
         B     SWITCHON                 GO TO TURN ON MESSAGE SWITCH    41200016
INTERMSG MVI   CCTPWKA,C' '             CLEAR MESSAGE AREA              41400016
         MVC   CCTPWKA+1(200),CCTPWKA                                   41600016
         L     RWORK1,PBEGM             LOAD MESSAGE MODULE ADDRESS     41800016
         AH    RWORK1,0(RINTRETN)       POINT TO MESSAGE POINTER        42000016
         L     RWORK1,0(RWORK1)         LOAD MESSAGE PARAMETER LIST ADR 42200016
         MVC   CCTPWKA(16),0(RWORK1)    MOVE IT TO WORKAREA        PDUM 42400017
         LA    RWORK2,CCTPWKA+16        LOAD MESSAGE ADDR               42600016
         ST    RWORK2,CCTPWKA+4        SAVE IT IN PAR-LIST              42800016
         MVI   CCTPWKA+4,X'40'         SET OPTION BITS                  43000016
         L     RWORK2,4(RWORK1)         LOAD MESSAGE ADDRESS            43200016
         MVC   CCTPWKA+16(26),0(RWORK2) MOVE MESSAGE IN WORK AREA       43400016
         MVC   CCTPWKA+34(8),CCTPWKA+PROCADR2 MOVE IN PROCEDURE NAME    43600016
         B     2(RINTRETN)              BRANCH BACK                     43800016
SWITCHON OI    CCTPSTAT+1,X'40'         TURN MESSAGE TO BE DISPLAY SWCH 44000016
         LA    RBR,12                  SET RETURN CODE                  44200016
RETURNIR EQU   *                                                   PDUM 44300017
         L     RSAVE,CCTPSAVE+4         LOAD CALLING SAVE ADDRESS       44400016
         RETURN (14,12),RC=(15)         RETURN                          44600016
*                                                                       44800016
         EJECT                                                          45000016
* NOTE THE LOCATION OF EXTRACT                                          45200016
*                                                                       45400016
NOTEEXT  L     RPAR1,CCTEDCBP           ADDRESS OF EXTRACT DCB          45600016
         NOTE  (RPAR1)                  EXTRACT POSITION                45800016
         ST    RPAR1,CCTENOTE                                           46000016
         MVI   CCTENOTE+3,ONE          POSITION TO NEXT BLOCK           46200016
*                                                                       46327016
* PREPARE FOR DIARY ROUTINE AND NOTE THE LOCATION OF RECORD             46334016
*                                                                       46341016
         ST    RWORK,CCTDIAWA           JOB COUNT                       46348016
         MVC   CCTDIAWA+19(4),CCTDIAWA  JOB COUNT TO DIARY FORMAT       46355016
         MVC   CCTDIAWA+16(3),CCTUNIT   2250 ADDRESS TO KIARY FORMAT    46362016
         MVC   CCTDIAWA(16),RECCON      COMPLETE DIARY FORMAT           46369016
         LR    RPAR1,RCCT               CCT ADDRESS                     46376016
         L     RBR,CCTDIARP             ADDRESS OF DIARY ROUTINE        46383016
         BALR  RRET,RBR                 GO TO DIARY                     46390016
         CH    15,CODE1C               Q. INTERNAL ERROR HAPPENED  PDUM 46391017
         BE    RETURNIR                 BRANCH IF YES              PDUM 46392017
         TM    CCTSSTAT,X'80'          Q. RECORD OPTION                 46393016
         BC    8,WRITECCT                                               46396016
         MVC   CCTPWKA(LWRITE),FWRITE                                   46396216
         L     RDCB,CCTRDCBP           DIARY DCB ADDRESS                46396416
         LA    RAREA,BLANKRD           ADDR OF BLANK RECORDS            46396616
         SR    2,2                     CLEAR COUNTER                    46396816
WRITEBK  EQU   *                                                        46397016
         WRITE CCTPWKA,SF,(RDCB),(RAREA),MF=E                           46397216
         CHECK CCTPWKA                                                  46397416
         LA    2,1(2)                  UPDATE COUNTER                   46397616
         CH    2,TWO                   Q, WRITE TWO RECORD              46397816
         BE    NEXTWRT                 BRANCH IF YES                    46398016
         LA    RAREA,120(RAREA)        JUMP TO NEXT RECORD              46398216
         B     WRITEBK                 BRANCH                           46398416
NEXTWRT  EQU   *                                                        46398616
         L     RPAR1,CCTRDCBP           ADDRESS OF DIARY ECB            46400016
         NOTE  (RPAR1)                  NOTE THE POSITION               46600016
         LR    RNOTE,RPAR1              SAVE NOT POSITION               46800016
         ST    RNOTE,CCTRNOTE          SAVE IN CCT                      47000016
         MVI   CCTRNOTE+3,ONE          NEXT BLOCK                       47200016
*                                                                       47210016
* WRITE THE PORTION OF THE CCT THAT MUST BE SAVED ONTO THE EXTRACT      47220016
* DATA SET 356 BYTE RECORDS WILL BE USED                                47230016
*                                                                       47240016
WRITECCT L     RDCB,CCTEDCBP            DCB ADDRESS                     47250016
         L     RCOUNT,NOREC             NO OF RDCS TO BE WRITTEN        47260016
         LR    RAREA,RCCT               FIRST RCD                       47270016
         MVC   CCTPWKA(LLENGTH),WRITERCD  MOVE LIST TO CCT              47280016
READMORE WRITE CCTPWKA,SF,(RDCB),(RAREA),MF=E                           47290016
         LA    RPAR1,CCTPWKA            ADDRESS OF DECB                 47300016
         CHECK (1)                      CEHCK FOR COMPLETION            47310016
         LA    RAREA,SIZE(RAREA)        BUMP TO NEXT RECORD             47320016
         BCT   RCOUNT,READMORE                                          50320016
         EJECT                                                          54600016
* PREPARE TO LEAVE                                                      54800016
         LA    RPAR0,0                 SET CODE ZERO                    54900016
         LR    RPAR1,RCCT              CCT ADDRESS                      55000016
*                                                                       55200016
         L     RSAVE,CCTPSAVE+4              RESTORE 13                 55400016
         L     RRET,12(RSAVE)                RESTORE 14                 55600016
*                                                                       55800016
* GO TO THE SCHEDULER INTERFACE                                         56000016
*                                                                       56200016
         XCTL  (2,12),EP=IKASCH                                         56400016
         EJECT                                                          56600016
MOVEMSG  MVC   CCTPWKA+4(1),0(RWORK1)     MOVE MESSAGE                  56800016
WRITEST  EQU   *                                                        57000016
WRITERCD WRITE RCDECB,SF,,,,MF=L                                        57200016
WRITEND  EQU   *                                                        57400016
LLENGTH  EQU   WRITEND-WRITEST                                          57600016
FWRITE   WRITE DECBW,SF,,,120,MF=L     WRITE                            57640016
FWRITEE  EQU   *                                                        57680016
*                                                                       57720016
LWRITE   EQU   FWRITEE-FWRITE                                           57760016
CLOSESTR EQU   *                                                        57800016
         CLOSE (0,,0,),MF=L             CLOSE LIST                      58000016
CLOSEND  EQU   *                                                        58200016
CLOSESIZ EQU   CLOSEND-CLOSESTR         LENGTH OF CLOSE LIST            58400016
RECCON   DC    C'     BEGIN     J'                                      58600016
SLASHCON DC    C'BEG'                   *****************************   58800016
         DC    C'/*'                    * THIS IS THE /* RECORD     *   59000016
         DC    X'26'                    * FORMATE FOR JCL GENERATOR *   59200016
         DC    X'37'                    *****************************   59400016
*                                                                       59500016
UNITPOS  EQU   X'13'                                                    59600016
CNTPOS   EQU   X'16'                                                    59800016
TWO      DC    H'2'                    A NUMBER                         59830016
BLANKRD  DC    CL60' '                                                  59860016
         DC    CL60' '                                                  59890016
         DC    CL60' '                                                  59920016
         DC    CL60' '                                                  59950016
         DS    0F                                                       60000016
PBEGM    DC    V(IKAMBEG0)             MESSAGE MODULE                   60200016
DOUBLE   DC    X'FFFFFFF8'                                              60400016
NOREC    DC    X'00000002'             *RECORD NUMBER                   60600016
SVCPARM  EQU   *                      * SVC PARAMETER LIST              60800016
SVCCODE  DC    C'PBEG'                 *CODE FOR BEGIN JOB              61100016
SVCINFO  EQU   *                      * PASSED INFORMATION              61400016
SVC2250  DC    F'0'                   * 2250 ADDRESS                    61600016
SVCJBCNT DC    F'0'                                                     61800016
SVCNOTE  DC    F'0'                    *NOTE ADDRESS                    62000016
SVCBACK  DC    X'00'                  *BACKGROUND JOB INDICATOR         62200016
SVCEND   EQU   *                      *                                 62400016
PROCCON  DC    CL8'  PROC  '                                            62600016
BLANKS   DC    CL8' '                   8 BLANKS                        62800016
PROCJCL  DC    C'BEG'                   JOB                             63000016
         DC    CL10'//        '         CONTROL                         63200016
         DC    X'24'                    LANGUAGE                        63400016
         DC    C'EXEC'                  FORMAT                          63600016
         DC    X'24'                    OF                              63800016
         DC    CL10' '                  BEGIN                           64000016
PROCJCL1 EQU   *                                                   9904 64100018
         DC    X'26'                    PROCEDURE                       64200016
         DC    C'//'                                                    64400016
         DC    CL18' '                                                  64600016
         DC    X'24'                                                    64800016
         DC    C'DD'                                                    65000016
         DC    X'24'                                                    65200016
         DC    CL8'UNIT='                                               65400016
         DC    X'26'                                                    65600016
ENDJCL   DC    C'/*'                                                    66000016
         DC    X'2637'                                                  66400016
PROCJCLE EQU   *                                                        66600016
CODE1C   DC    H'28'                    INTERNAL ERROR CODE        PDUM 66700017
PROCJCL2 DC    X'25'                                               9904 66709018
         DC    C'UNIT='                                            9904 66718018
PROCJCL3 DC    C'   '                                              9904 66727018
         DC    X'26'                                               9904 66736018
         DC    C'/*'                                               9904 66745018
         DC    X'2637'                                             9904 66754018
PROCJCL4 EQU   *                                                   9904 66763018
PROCJCL5 EQU   PROCJCL4-PROCJCL2                                   9904 66772018
PROCJCL6 EQU   PROCJCL1-PROCJCL                                    9904 66781018
PROCJCL7 EQU   PROCJCL3-PROCJCL2+PROCJCL6                          9904 66790018
LRECORD  EQU   PROCJCLE-PROCJCL        PROCEDURE RECORD LENGTH          66800016
NOTESTRT EQU   SVCNOTE-SVCPARM                                          67000016
COUNTSTR EQU   SVCJBCNT-SVCPARM                                         67200016
UNITSTRT EQU   SVC2250-SVCPARM                                          67400016
LISTLNGT EQU   SVCEND-SVCPARM           LENGTH OF PARAMETER LIST        67600016
BACKSTRT EQU   SVCBACK-SVCPARM                                          67800016
         SPACE 2                                                        67820000
*********************************************************************** 67840000
*                                                                       67860000
*        MAINTENANCE AREA                                        A33564 67880000
*                                                                       67900000
*********************************************************************** 67920000
PATCH    DC    15F'0'                                            A33564 67940000
         SPACE 2                                                        67960000
         END                                                            68000016
