IKAPCAN  START 0                                                        00400016
**                                                                      00800016
* * *             * CANCEL JOB PROCESSOR *                              01200016
**                                                                      01600016
*  MODULE NAME=    IKAPCAN0                                        PJKL 02000017
*                                                                       02400017
*  CHART ID.  =    FJ                                              PJKL 02800017
*                                                                       03200016
*  FUNCTION   =    PROCESS CANCEL COMMAND IN COMMAND SPECIFICATION MODE 03600016
*                                                                       04000016
*  ATTRIBUTES =    TRANSIENT,REUSABLE                                   04400016
*                                                                       04800016
*  ENTRY POINT=    ENTERED VIA LINK FROM IKAPCTL                        05200016
*                                                                       05600016
*  OPERATION  =    THIS PROCESSOR PERFORMS THE FOLLOWING FUNCTIONS      06000016
*                                      *   *                            06400016
*                    * RESET START ADDRESS OF JCL DATA SET, THUS        06800016
*                        ELIMINATING THIS DATA SET                      07200016
*                                        *                              07600016
*                  * RESETS START ADDRESSES OF BOTH EXTRACT DATA SETS,  08100016
*                      THUS ELIMINATING THESE DATA SETS                 08600016
*                                        *                              09200016
*                    * TURNS ON BITS IN THE CCT (CCTPSTAT BIT 0+1),     09600016
*                        INDICATING THAT JOB- AND EXECUTE CARDS ARE     10000016
*                        REQUIRED                                       10400016
*                                        *                              10800016
*                    * RESETS DISPLAY MASK IN THE CCT (CCTDISM),THUS    11200016
*                        PERMITTING DISPLAY OF ALL INFORMATION ON THE   11600016
*                        PARAMETER FRAMES                               12000016
*                                        *                              12400016
*                    * RESETS BITS IN THE CCT (CCTPSTAT BIT 2+3),       12800016
*                        ELIMINATING PREVIOUS INDICATION OF JOBLIB      13200016
*                        AND BACKGROUND JOB.                            13600016
*                                      *   *                            14800016
*  EXITS      =    BRANCH TO IKADIA                                     15200016
*                  BRANCH TO IKADMSG                                    15600016
*                  RETURN TO IKAPCTL                                    16000016
*                                                                       16400016
*  INPUT      =                                                         16800016
*                                                                       17200016
*  OUTPUT     =                                                         17600016
*                                                                       18000016
*  EXTERNAL                                                             18400016
*   REFERENCES=                                                         18800016
*                                                                       19200016
*  ERROR                                                                19600016
*   CONDITIONS=                                                         20000016
*                                                                       20400016
*  TABLES AND                                                           20800016
*   WORKAREAS =    IKACCT                                               21200016
*                                                                       21600016
* RESTRICTIONS=                                                         22000016
*                                                                       22400016
* * * * * * * * * * * * *                                               22800016
         EJECT                                                          23200016
*                                                                       23600016
* * *                    REGISTER  EQUATES                              24000016
*                                                                       24400016
RPAR0    EQU   0                                                        24800016
RPAR1    EQU   1                                                        25200016
RPAR2    EQU   2                                                        25600016
RBASE    EQU   3                                                        26000016
RCCT     EQU   4                                                        26400016
RREC     EQU   5                                                        26800016
RWK      EQU   6                                                        27200016
RMES     EQU   7                                                        27600016
RMAIN    EQU   8                                                        28000016
RJCLIO   EQU   9                                                        28400016
RDCB     EQU   10                                                       28800016
R11      EQU   11                                                       29200016
R12      EQU   12                                                       29600016
RSAVE    EQU   13                                                       30000016
RRET     EQU   14                                                       30400016
RBR      EQU   15                                                       30800016
*                                                                       31200016
*                                                                       31600016
WKAREA   DSECT                                                          32000016
MSGPARAM DS    20F                                                      32400016
*                                                                       32800016
         EJECT                                                          33200016
         SPACE                                                          33300016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         33400016
         SPACE                                                          33500016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    33600016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     33700016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       33800016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             33900016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  34000016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  34100016
*                   SET.                                                34200016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      34300016
*                   SECOND.                                             34400016
         SPACE 2                                                        34500016
CCT      DSECT                                                          34600016
         SPACE 2                                                        34700016
*                             SECTION ONE                               34800016
         SPACE                                                          34900016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     35000016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    35100016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  35200016
         SPACE                                                          35300016
         DS    0F                                                       35400016
CCTUNAME DS    5F                  USER'S NAME                          35500016
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         35600016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     35700016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       35800016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    35900016
*                                       AT LAST BEGIN JOB               36000016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   36100016
*                                       LAST BEGIN JOB                  36200016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 36300016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    36400016
*                                       JOB                             36500016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    36600016
*                                       JOB                             36700016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     36800016
*                                       CESSOR                          36900016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         37000016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         37100016
CCTJCTR  DS    H                   JOB COUNTER                          37200016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                37300016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   37400016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  37500016
CCTSSTAT DS    C                   SESSION STATUS                       37600016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              37700016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              37800016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    37900016
         EJECT                                                          38000016
         SPACE 2                                                        38100016
*                             SECTION TWO                               38200016
         SPACE                                                          38300016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   38400016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  38500016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 38600016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              38700016
         SPACE                                                          38800016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     38900016
*                                       FRAME                           39000016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  39100016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     39200016
*                                       MULTIPLE DISPLAY FRAME (ENT)    39300016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   39400016
CCTDISM  DS    C                   DISPLAY MASK                         39500016
CCTCSM   DS    C                   COMMAND SELECT MASK                  39600016
CCTPSTAT DS    CL2                 GJP STATUS                           39700016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              39800016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  39900016
         SPACE 2                                                        40000016
*                             SECTION THREE                             40100016
         SPACE                                                          40200016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    40300016
*                   INTO SECTION ONE OR TWO                             40400016
         SPACE                                                          40500016
CCTDGMP  DS    F                  POINTER TO DGM                        40600016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                40700016
CCTCSTP  DS    F                  POINTER TO CST                        40800016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                40900016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            41000016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 41100016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              41200016
CCTDIARP DS    F                  POINTER TO DIA                        41300016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      41400016
CCTACTP  DS    F                  POINTER TO ACT                        41500016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     41600016
CCTIERRP DS    F                  POINTER TO IERR                       41700016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              41800016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               41900016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                42000016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 42100016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 42200016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   42300016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                42400016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                42500016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               42600016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              42700016
CCTPECB  DS    F                  PROCESSOR'S ECB                       42800016
CCTWECB  DS    F                  WTOR ECB                              42900016
CCTDIAWA DS    CL136               DIARY WORK AREA                      43000016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    43100016
CCTCSAVE DS    CL72                CTL SAVE AREA                        43200016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                43300016
CCTASAVE DS    CL72                DAT SAVE AREA                        43400016
*                                                                       43500016
IKACCT   EQU   CCT                                                      43600016
         EJECT                                                          51600016
IKAPCAN0 CSECT                                                          52000016
*3472,020000-028000,700000,752000-756000                           PJKL 52200017
*                                                                       52400016
START    EQU   *                                                        52800016
         SAVE  (14,12)                                                  53200016
         BALR  RBASE,0                  SET UP BASE                     53600016
         USING *,RBASE                                                  54000016
*                                                                       54400016
         LR    RCCT,RPAR1               LOAD REGISTER WITH ADDR. OF CCT 54800016
         USING IKACCT,RCCT                                              55200016
         L     RREC,CCTDIARP            LOAD POINTER TO RECORD ROUTINE  55600016
         LA    RWK,CCTPSAVE             SET UP SAVE AREA                56000016
         ST    RWK,8(0,RSAVE)                                           56400016
         ST    RSAVE,4(RWK)                                             56800016
         LR    RSAVE,RWK                                                57200016
         B     STRTPNT                                                  57240016
* * *    THE FOLLOWING ROUTINE, THAT PUTS OUT A MESSAGE SAYING          57280016
* * *    'PROCESSING INPUT' IS BYPASSED BECAUSE PROCESSING TAKES SO     57320016
* * *    LITTLE TIME, THE MESSAGE CAN HARDLY BE SEEN                    57360016
**                                                                      57400016
* * *    IF WE WANT TO SAVE CORE, WE CAN ELIMINATE THIS SECTION AND     57440016
* * *    WILL GAIN APPROXIMATELY 70 BYTES + THE GETMAIN'D AREA          57480016
***                                                                     57520016
*                                                                       57600016
         GETMAIN R,LV=80                                                58000016
         LR    RMAIN,RPAR1                                              58400016
         USING WKAREA,RMAIN                                             58800016
*                                                                       59200016
         LA    RMES,MSGPARAM            SET UP MESSAGE PARAMETER TABLE  59600016
         LA    RWK,PROCINP              ADDRESS OF MESSAGE              60000016
         ST    RWK,0(RMES)              STORE IN PARAMETER TABLE        60400016
         MVI   0(RMES),X'40'            DISPLAY WITH BASIC CHARACTERS   60800016
         OI    0(RMES),X'80'            END OF PARAMETER TABLE          61200016
         LR    RPAR1,RCCT               LOAD POINTER TO CCT             61600016
         LA    RPAR0,MSGPARAM           LOAD POINTER TO MSG.PARAMETERS  62000016
         L     RBR,CCTDMRP              LOAD POINTER TO MSG.ROUTINE     62400016
         BALR  RRET,RBR                 BRANCH TO MSG.ROUTINE           62800016
*                                                                       63200016
         LR    RPAR1,RMAIN              LOAD ADDRESS OF GETMAINED AREA  63600016
         FREEMAIN R,LV=80,A=(1)                                         64000016
*                                                                       64400016
STRTPNT  EQU   *                                                        64600016
         L     RPAR1,CCTEDCBP           ADDR. OF EXTRACT DS. DCB        64800016
         LA    RPAR0,FIRST              INDICATE BEGINNING OF DS        65000016
         POINT (1),(0)                  POSITION DS. TO BEGINNING       65200016
*                                                                       65400016
         L     RPAR1,CCTEDCB1           ADDR. OF SECOND EXTRACT DS. DCB 65600016
         LA    RPAR0,FIRST              INDICATE BEGINNING OF DS        65800016
         POINT (1),(0)                  POSITION DS. TO BEGINNING       66000016
*                                                                       66200016
         L     RPAR1,CCTJDCBP           ADDR. OF JCL DS. DCB            66400016
         LA    RPAR0,FIRST              INDICATE BEGINNING OF DS        66600016
         POINT (1),(0)                  POSITION DS. TO BEGINNING       66800016
* * *                                      *                            67000016
* *                           CLOSE AND OPEN MACROS WHERE USED ON EARLY 67200016
* *                           VERSION OF IKAPCAN0 - BUT PROVED TO TAKE  67400016
* *                           TOO MUCH OF PROCESSING TIME               67600016
* * *                                      *                            67800016
         OI    CCTPSTAT,X'80'           TURN JOB CARD REQUIRED BIT ON   68400016
         OI    CCTPSTAT,X'40'           TURN EXEC.CARD REQUIRED BIT ON  68800016
         NI    CCTPSTAT,X'DF'           TURN JOBLIB CARD BIT OFF        69200016
         NI    CCTPSTAT,X'EF'           TURN BACKGROUND-JOB BIT OFF     69600016
         NI    CCTDISM,X'10'            RESET DISPLAY MASK         PJKL 70600017
*                                                                       72000016
         MVI   CCTDIAWA,X'40'           SET DIARY AND RECORD AREA       72400016
         MVC   CCTDIAWA+1(133),CCTDIAWA TO BLANKS                       72800016
         MVC   CCTDIAWA+5(14),CANCJOB   MOVE CANCEL JOB CONSTANT        73200016
         LR    RPAR1,RCCT               LOAD POINTER TO CCT             73600016
         LR    RBR,RREC                 LOAD POINTER TO RECORD ROUTINE  74000016
         BALR  RRET,RBR                 BRANCH TO RECORD ROUTINE        74400016
*                                                                       74800016
         CL    RBR,QUIT               Q. IS CODE QUIT              PJKL 75000017
         BE    LEAVE                  A. YES - DO NOT TOUCH RET.CD PJKL 75200017
         SR    RBR,RBR                  SET NORMAL RETURN CODE     PJKL 75400017
LEAVE    NI    CCTPSTAT+1,X'DF'         SET IGNORE ATTENTION OFF   PJKL 75600017
         LR    RPAR1,RCCT               LOAD POINTER TO CCT             76000016
         L     RSAVE,4(RSAVE)                                           76400016
         RETURN (14,12),RC=(15)         RETURN TO CTL                   76800016
*                                                                       77200016
*                                                                       77600016
* * *                   *  CONSTANT  *                                  78000016
FIRST    DC    F'1'                                                     78200016
QUIT     DC    X'0000001C'                                         PJKL 78300017
*                                                                       78400016
PROCINP  DC    XL1'10'                                                  78800016
         DC    C'PROCESSING INPUT'                                      79200016
*                                                                       79600016
CANCJOB  DC    C'CANCEL        '                                        80400016
***                                                                     95800016
         SPACE 2                                                        95900000
*********************************************************************** 96000000
*                                                                       96100000
*        MAINTENANCE AREA                                        A33564 96200000
*                                                                       96300000
*********************************************************************** 96400000
PATCH    DC    3F'0'                                            A33564  96500000
         SPACE     2                                                    96600000
         END                                                            96800016
