         TITLE 'IKAPCSR0 PROCESSOR FOR IKAGJP'                          00400016
*                                                                       00800016
         TITLE 'IKAPCSR0 PROCESSOR FOR IKAGJP'                          01200016
*                                                                       01600016
*                                                                       02000016
*                   COMMAND SELECT ROUTINE                              02400016
*                                                                       02800016
* ROUTINE NAME       IKAPSCR0                                           03200016
*                                                                       03600016
* CHART ID           PI,PJ                                              04000016
*                                                                       04400016
*  FUNCTION:        COMMAND SELECTION AND INITIALIZATION FOR COMMAND    04800016
*                   PROCESSORS                                          05200016
*                                                                       05600016
*  ATTRIBUTES:      TRANSIENT,REENTERABLE                               06000016
*                                                                       06400016
*ENTRY POINTS       IKAPCSR0                                            06800016
*                                                                       07200016
*  OPERATION:       SCAN EXTRACTION RECORD, DETERMINE IF SELECTION WAS  07600016
*                   MADE. IN NORMAL CONDITIONS, IT UPDATES CONSOLE      08000016
*                   CONTROL TABLE, SUCH AS CURRENT COMMAND KEY, THE     08400016
*                   ADDRESS OF CURRENT PARAMETER SELECT TABLE AND THEN  08800016
*                   GIVES CONTROL BACK TO CTL. IN CASE OF ERROR, IT     09200016
*                   PASSES PARAMETE TO MSG INFORMING THE USER THAT A    09600016
*                   MISTAKE WAS MADE                                    10000016
*                                                                       10400016
*  EXIT:            BRANCH TO MSG IF ERROR CONDITION                    10800016
*                                                                       10900016
*                   RETURN CODE IN REGISTER 15                          11000016
*                                                                       11100016
*                   CODE- 0  NORMAL COMPLETION                          11200016
*                                                                       11300016
* INPUT             REGISTER 1 POINTING TO CONSOLE CONTROL TABLE        11400016
*                                                                       11500016
*                   REGISTER 13 POINTING TO A REGISTER SAVE AREA        11600016
*                                                                       11700016
*                   REGISTER 14 RETURN ADDRESS                          11800016
*                                                                       11900016
*                   EXTRACTION RECORD IN PROCESSOR WORKAREA             12000016
*                                                                       12100016
*                                                                       12200016
* OUTPUT            UPDATED CONSOLE CONTROL TABLE                       12300016
*                                                                       12400016
*                                                                       12500016
* EXTERNAL REFERENCE IKACTL                                             12600016
*                    IKADGM                                             12700016
*                    IKADMSG                                            12800016
*                                                                       14800016
*  ERROR CONDITIONS: USER MADE NO SELECTION                             15200016
*                    USER MADE MULTIPLE SELECTION                       15600016
*                                                                       16000016
*  TABLE AND WORKAREA: CONSOLE CONTROL TABLE                            16400016
*                      PARAMETER SELECTION TABLE                        16800016
*                                                                       17200016
*  RESTRICTION:                                                         17600016
*                                                                       18000016
*                                                                       18400016
*                                                                       18800016
*                                                                       19200016
*                                                                       19600016
         EJECT                                                          20000016
*                                                                       20400016
*                                                                       20800016
* DEFINE GENERAL REGISTERS AND EQUATES                                  21200016
*                                                                       21600016
*                                                                       22000016
IKAPCSR0 CSECT                                                          22400016
*0172,552000                                                       PDUM 22600017
RPAR0    EQU   0                        PARAMETER                       22800016
RPAR1    EQU   1                        PARAMETER                       23200016
RCCT     EQU   2                        CCT REGISTER                    23600016
RCOUNTER EQU   3                        COUNTER                         24000016
RCST     EQU   4                        CST ADDRESS                     24400016
RPWKA    EQU   5                        PROCESSOR WORK AREA ADDRESS     24800016
RPOINTER EQU   6                        POINT TO SELECTED CST ENTRY     25200016
RMSG     EQU   7                        MESSAGE REGISTER                25600016
RRETURN  EQU   8                        MSG RETURN REGISTER             26000016
RPST     EQU   9                        POINT TO DELET LOAD PST ADDRESS 26400016
RBASE    EQU   10                       BASE REGISTER                   26800016
RWORK    EQU   11                       GENERAL PURPOSE                 27200016
RI2      EQU   12                                                       27600016
RSAVE    EQU   13                       SAVE REGISTER                   28000016
RRET     EQU   14                       RETURN REGISTER                 28400016
RBR      EQU   15                       BRANCH REGISTER                 28800016
LENGTH   EQU   344                                                      29200016
*                                                                       29600016
* SAVE REGISTERS UPDATE HISTORY SEQUENCE NUMBER, WAIT PROCESSOR'S ECB   30000016
*                                                                       30400016
*                                                                       30800016
         SAVE  (14,12)                  SAVE REGISTERS                  31200016
         BALR  RBASE,0                  SET BASE                        31600016
         USING *,RBASE                                                  32000016
         LR    RCCT,RPAR1               LOAD CCT ADDRESS                32400016
         USING CCT,RCCT                                                 32800016
         ST    RSAVE,CCTPSAVE+4         SAVE CALLING PROGRAM SAVE ADDR  33200016
         LA    RWORK,CCTPSAVE           LOAD OUR SAVE ADDRESS           33600016
         ST    RWORK,8(0,RSAVE)         GIVE TO CALLING PROGRAM         34000016
         LR    RSAVE,RWORK             POINT TO OUR SAVE ADDRESS        34400016
         TM    CCTPSTAT,X'01'          Q. CANCEL MODE                   34500016
         BO    SWAIT                   BRANCH IF YES                    34600016
         SR    RWORK,RWORK              CLEAR REGISTER                  34800016
         L     RWORK,CCTHSN             LOAD HISTORY SEQUENCE NUMBER    35200016
         LA    RWORK,1(RWORK)           ADD ONE AND                     35600016
         STH   RWORK,CCTHSN+2           STORE BACK                      36000016
*                                                                       36400016
SWAIT    WAIT  ECB=CCTPECB              WAIT PROCESSOR ECB              36800016
         TM    CCTPECB+3,X'1C'         Q. IERR ENTERED             PDUM 36860017
         BO    IERRETR                  BRANCH IF YES              PDUM 36920017
         NI    CCTPSTAT,X'FE'          OFF SWITCH                       37000016
         TM    CCTPECB+3,X'08'          CANCEL?                         37200016
         BC    1,SNUC                   YES BRANCH TO NUC FOR REDISPLAY 37600016
         EJECT                                                          38000016
*                                                                       38400016
*                                                                       38800016
* SCAN CST AND EXTRACT RECORD FOR SELECTED COMMAND                      39200016
*                                                                       39600016
*                                                                       40000016
         SR    RCOUNTER,RCOUNTER        CLEAR COUNTER                   40400016
         SR    RPOINTER,RPOINTER        CLEAR SELECTED ENTRY POINTER    40800016
         L     RCST,CCTCSTP             LOAD CST ADDRESS                41200016
SCANBEG  LA    RPWKA,CCTPWKA            LOAD PROCESSOR WORKAREA ADDRESS 41600016
         CLI   0(RCST),X'00'            END OF SCAN                     42000016
         BE    SCANEND                  YES, BRANCH SCANEND             42400016
         LH    RWORK,10(RCST)           NO, LOAD INPUT MAPPING          42800016
         LTR   RWORK,RWORK             Q. IS ZERO                       42900016
         BZ    UPDATCST                BRANCH IF YES                    43000016
         AR    RPWKA,RWORK              GET COMPARE LOCATION            43200016
         SR    RWORK,RWORK              CLEAR REGISTER                  43600016
         IC    RWORK,7(RCST)            GET COMPARE LENGTH              44000016
         SH    RWORK,ONE                SUBTRACT ONE                    44400016
         EX    RWORK,COMPARE            TEST IF THIS COMMAND SELECTED   44800016
         BE    UPDATCST                 NO BRANCH TO UPDATCST           45200016
         LA    RCOUNTER,1(RCOUNTER)     UPDATE COUNTER BY ONE           45600016
         LR    RPOINTER,RCST            SAVE SELECTED ENTRY             46000016
UPDATCST SR    RWORK,RWORK              CLEAR REGISTER                  46400016
         IC    RWORK,0(RCST)            GET CST ENTRY LENGTH            46800016
         AR    RCST,RWORK               POINT TO NEW ENTRY              47200016
         B     SCANBEG                  BRANCH TO SCANBEG               47600016
SCANEND  CH    RCOUNTER,ONE             IS ONE COMMAND SELECTED         48000016
         BE    UPDTCCT                  YES UPDATE CCT                  48400016
         BH    SMSG                     MULTIPLE SELECTED               48800016
         BAL   RRETURN,SMSG0            NO SELECT                       49200016
         DC    H'0'                     SET MSG DISPLACEMENT            49600016
         B     SCLEAR1                  CLEAR PROCESSOR ECB AND WAIT    50000016
SMSG0    LH    RMSG,0(RRETURN)          LOAD MSG DISPLACEMENT           50400016
         A     RMSG,MSGMODA             POINT TO MESSAGE                50800016
         L     RPAR0,0(RMSG)            SET PARAMETER                   51200016
         LR    RPAR1,RCCT               LOAD CCT ADDRESS                51600016
         OI    CCTPSTAT+1,X'20'         IGNORE ATTENTION                52000016
         L     RBR,CCTDMRP              LOAD MESSAGE ROUTINE ADDRESS    52400016
         BALR  RRET,RBR                 DISPLAY MESSAGE                 52800016
         CH    15,CODE1C               Q. INTERNAL ERROR HAPPENED  PDUM 52900017
         BE    SRETURN                  BRANCH IF YES              PDUM 53000017
         NI    CCTPSTAT+1,X'DF'         ALLOW ATTENTION                 53200016
         B     2(RRETURN)               GO BACK AND CONTINUE PROCESS    53600016
SMSG     BAL   RRETURN,SMSG0            BRANCH TO INTERAL MSG RTN       54000016
         DC    H'4'                     SET MSG INDICATOR               54400016
         B     SCLEAR1                  CLEAR ECB                       54800016
UPDTCCT  CLC   LOGON(5),12(RPOINTER)   Q. LOGON SELECTED                55000016
         BNE   CKCOMD                  BRANCH IF NO                PDUM 55100017
         CLC   CCTCCR(3),LON           LOGON TABLE IN CORE         PDUM 55200017
         BE    SCLEAR                  BRANCH IF YES               PDUM 55300017
         MVC   CCTCCR(3),LON           SET KEYWORD FOR LOGON       PDUM 55400017
         LOAD  EP=IKATLON0             LOAD IN LOGON TABLE         PDUM 55500017
         ST    RPAR0,CCTCPSTP          SAVE ITS ADDRESS            PDUM 55600017
         B     SCLEAR                  BRANCH                      PDUM 55700017
         EJECT                                                          56000016
*                                                                       56400016
*                                                                       56800016
* CHECK NEW COMMAND HAS PST OR NOT, DELETE OLD PST AND LOAD NEW PST     57200016
* UPDATE CCTCCR AND CCTCPSTP                                            57600016
*                                                                       58000016
*                                                                       58400016
CKCOMD   EQU   *                                                   PDUM 58500017
         LA    RPST,CCTPWKA+LENGTH      *                               58700016
         MVC   0(8,RPST),PSTABLE        * DELET OLD PST IF IT EXISTS    59000016
         SR    RCOUNTER,RCOUNTER        ZERO REGISTER                   59300016
         C     RCOUNTER,CCTCPSTP       Q. DOES OLD COMMAND HAVE A PST   59600016
         BE    TESTPST                  NO  GO TO TEXT NEW COMMAND PST  59900016
         MVC   4(3,RPST),CCTCCR         *                               60200016
         DELETE EPLOC=(RPST)            *                               60500016
TESTPST  TM    4(RPOINTER),X'01'       Q.DOES NEW COMMAND HAVE A PST    60800016
         BZ    LOADPST                  YES GO TO LOAD IT IN CORE       61100016
         ST    RCOUNTER,CCTCPSTP        ZERO CURRENT PST POINTER IF NO  61400016
         B     UPDTKEY                  BRANCH                          61700016
LOADPST  MVC   4(3,RPST),12(RPOINTER)   MOVE NEW COMMAND KEY IN MODEL   62000016
         LOAD  EPLOC=(RPST)             LOAD NEW PST                    62800016
         ST    RPAR0,CCTCPSTP           STORE CURRENT PST IN CCT        63200016
UPDTKEY  MVC   CCTCCR(3),12(RPOINTER)   UPDATE COMMAND KEY              63600016
SCLEAR   MVI   CCTPECB,X'00'            CLEAR ECB                       64000016
         LA    RBR,0                    SET RETURN CODE                 64400016
SRETURN  L     RSAVE,CCTPSAVE+4        RESTORE SAVE ADDRESS             64800016
         RETURN (14,12),RC=(15)         RETURN TO CALLING               65200016
SNUC     TM    CCTPSTAT+1,X'02'         RECALL MODE                     65400016
         BC    1,CLEAR2                BRANCH IF YES                    65600016
         L     RBR,CCTDGMP              LOAD NUC RTN ADDRESS            65800016
         LR    RPAR1,RCCT               LOAD CCT ADDRESS                66000016
         NI    CCTPSTAT+1,X'DF'        ATTENTION SWITCH ON              66200016
         BALR  RRET,RBR                 BRANCH TO NUC                   66400016
         B     SCLEAR1                  CLEAR ECB                       66800016
         DC    X'C000'                  START GENERAT                   67200016
SCLEAR1  MVI   CCTPECB,X'00'            CLEAR ECB                       67600016
         CH    15,CODE1C               Q. INTERNAL ERROR HAPPENED  PDUM 67700017
         BE    SRETURN                  BRANCH IF YES              PDUM 67800017
         B     SWAIT                    GO TO WAIT                      68000016
CLEAR2   LA    RBR,8                   RETURN CODE                      68100016
         MVI   CCTPECB,X'00'           CLEAR ECB                        68200016
         B     SRETURN                  BRANCH                          68300016
IERRETR  EQU   *                                                   PDUM 68320017
         LR    1,RCCT                   CCT ADDRESS                PDUM 68340017
         LA    15,28                    SET IERR ENTERED CODE      PDUM 68360017
         B     SRETURN                  BRANCH                     PDUM 68380017
*                                                                       68400016
*                                                                       68800016
* DEFINE CONSTANTS AREA                                                 69200016
*                                                                       69600016
*                                                                       70000016
ONE      DC    H'1'                                                     70400016
COMPARE  CLC   0(0,RPWKA),BLANKS                                        70800016
         DS    0F                                                       71200016
BLANKS   DC    CL8' '                                                   71600016
PSTABLE  DC    C'IKAT   0'                                              72000016
LOGON    DC    C'LOGON'                                                 72200016
LON      DC    CL3'LON'                LOGON KEYWORD               PDUM 72260017
CODE1C   DC    H'28'                    CODE FOR INTERNAL ERROR    PDUM 72320017
         DS    0F                                                       72400016
MSGMODA  DC    V(IKAMCSR0)                                              72800016
         SPACE 2                                                        72850020
*********************************************************************** 72900020
*                                                                       72950020
*        MAINTENANCE AREA                                        A33564 73000020
*                                                                       73050020
*********************************************************************** 73100020
PATCH    DC    5F'0'                                             A33564 73150020
         EJECT                                                          73200016
         EJECT                                                          73300016
         SPACE                                                          73400016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         73500016
         SPACE                                                          73600016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    73700016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     73800016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       73900016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             74000016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  74100016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  74200016
*                   SET.                                                74300016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      74400016
*                   SECOND.                                             74500016
         SPACE 2                                                        74600016
CCT      DSECT                                                          74700016
         SPACE 2                                                        74800016
*                             SECTION ONE                               74900016
         SPACE                                                          75000016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     75100016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    75200016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  75300016
         SPACE                                                          75400016
         DS    0F                                                       75500016
CCTUNAME DS    5F                  USER'S NAME                          75600016
CCTVACCT DS    5F                  USER'S ACCOUNT NUMBER                75700016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     75800016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       75900016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    76000016
*                                       AT LAST BEGIN JOB               76100016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   76200016
*                                       LAST BEGIN JOB                  76300016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 76400016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    76500016
*                                       JOB                             76600016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    76700016
*                                       JOB                             76800016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     76900016
*                                       CESSOR                          77000016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         77100016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         77200016
CCTJCTR  DS    H                   JOB COUNTER                          77300016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                77400016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   77500016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  77600016
CCTSSTAT DS    C                   SESSION STATUS                       77700016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              77800016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              77900016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    78000016
         EJECT                                                          78100016
         SPACE 2                                                        78200016
*                             SECTION TWO                               78300016
         SPACE                                                          78400016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   78500016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  78600016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 78700016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              78800016
         SPACE                                                          78900016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     79000016
*                                       FRAME                           79100016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  79200016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     79300016
*                                       MULTIPLE DISPLAY FRAME (ENT)    79400016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   79500016
CCTDISM  DS    C                   DISPLAY MASK                         79600016
CCTCSM   DS    C                   COMMAND SELECT MASK                  79700016
CCTPSTAT DS    CL2                 GJP STATUS                           79800016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              79900016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  80000016
         SPACE 2                                                        80100016
*                             SECTION THREE                             80200016
         SPACE                                                          80300016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    80400016
*                   INTO SECTION ONE OR TWO                             80500016
         SPACE                                                          80600016
CCTDGMP  DS    F                  POINTER TO DGM                        80700016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                80800016
CCTCSTP  DS    F                  POINTER TO CST                        80900016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                81000016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            81100016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 81200016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              81300016
CCTDIARP DS    F                  POINTER TO DIA                        81400016
CCIDIRP  DS    F                  POINTER TO DISPLAY INPUT RTN          81500016
CCTACTP  DS    F                  POINTER TO ACT                        81600016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     81700016
CCTIERRP DS    F                  POINTER TO IERR                       81800016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              81900016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               82000016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                82100016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 82200016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 82300016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   82400016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                82500016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                82600016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               82700016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              82800016
CCTPECB  DS    F                  PROCESSOR'S ECB                       82900016
CCTWECB  DS    F                  WTOR ECB                              83000016
CCTDIAWA DS    CL136               DIARY WORK AREA                      83100016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    83200016
CCTCSAVE DS    CL72                CTL SAVE AREA                        83300016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                83400016
CCTASAVE DS    CL72                DAT SAVE AREA                        83500016
         END                                                            93200016
