         TITLE 'DESCRIBE DATA PROCESSOR FOR GJP'                        00050016
*                                                                       00100016
*   IKAPDES    DESCRIBE DATA ROUTINE                                    00150016
*                                                                       00200016
*                                                                       00208016
*     CHART ID - FG,FH,FI                                               00216016
*                                                                       00224016
*     ATTRIBUTES - TRANSIENT, REENTRENT                                 00232016
*                                                                       00240016
*     FUNCTION - SCAN THE FIELDS OF EXTRACTED INPUT RECORD TO INSURE    00250016
*                THAT THEY ARE IN OS/360 JOB CONTROL LANGUAGE FORMAT.   00300016
*                WHEN FIELD HAS BEEN VERIFIED MOVE KEYWORDS TO THE      00350016
*                EXTRACTED RECORD.                                      00400016
*                                                                       00450016
*     OPERATION- EACH FIELD IS FIRST SCANED IN REVERSE TO DETERMINE ITS 00500016
*                LENGTH AND IF THERE ARE ANY IMBEDDED BLANKS. IF THE    00550016
*                FIELD CONTAINS IMBEDDED BLANKS OR THE FIELD IS BLANK   00600016
*                ON A REQUIRED PARAMETER THE CONSOLE OPERATOR IS IN-    00650016
*                FORMED. ONLY ONE FIELD IS CHECKED AT A TIME AND MUST   00700016
*                BE CORRECTED BEFORE CONTINUING. WHEN THE FIELD HAS     00750016
*                BEEN VERIFIED AS BEING IN JCL FORMAT THE KEYWORD FOR   00800016
*                THAT PARAMETER IS INSERTED INTO THE RECORD. IF NO      00850016
*                INFORMATION WAS ENTERED FOR A GIVEN PARAMETER AND A    00900016
*                DEFAULT OPTION WAS TAKEN THE DEFAULT VALUE WILL BE     00950016
*                INSERTED INTO THE RECORD.                              01000016
*                                                                       01050016
*     OTHER FUNCTIONS - IF THE USER INDICATES A STATUS OTHER THAN       01100016
*                CATALOGED AN ADDITIONAL OVERLAY DISPLAY WILL BE        01150016
*                REQUESTED FROM THE KEY MANIP ROUTINE.                  01200016
*                                                                       01250016
*     REQUIREMENTS FOR USE - REGISTER ONE WILL CONTAIN THE ADDRESS OF   01300016
*                CCT. A POST CODE OF 4 FOR AN END FUNCTION OR A POST    01350016
*                CODE OF 8 FOR A CANCEL FUNCTION.                       01400016
*                A POST CODE OF 28 INDICATES AN INTERNAL ERROR     GJPF 01420017
*                                                                       01450016
*     RETURN CODES ISSUED -'00' NORMAL COMPLETION                       01500016
*                          '0C' CANCEL FRAME                            01550016
*                          '18' ERROR IN RECALL ACCEPT MODE             01570016
*                          '1C' INTERNAL ERROR                     GJPF 01580017
*                                                                       01600016
*     TABLES AND WORK AREA USED-                                        01650016
*                                                                       01700016
*                CONSOLE CONTROL TABLE (CCT)                            01750016
*                  EXTRACT RECORD (CCTPWKA)                             01800016
*                  DIARY WORK AREA (CCTDIAWA)                           01850016
*                  PROCESSOR ECB (CCTPECB)                              01900016
*                  GJP STATUS BYTE (IGNORBIT)                           01950016
*                                                                       02000016
*     EXTERNAL REFERENCES -                                             02050016
*                                                                       02100016
*                DMSG ROUTINE TO DISPLAY ERROR MESSAGES                 02150016
*                KYMANIP ROUTINE FOR OVERLAY DISPLAYS                   02200016
*                DIA ROUTINE TO RECORD OUTPUT                           02250016
*                JCL ROUTINE TO PROCESS OUTPUT                          02300016
         EJECT                                                          02320016
*                                                                       02350016
*  REGISTER EQUATES AND LABELS USED                                     02400016
*                                                                       02450016
         SPACE                                                          02500016
RPAR0    EQU   0                       PARAMETER REG.0                  02550016
RPAR1    EQU   1                       PARAMETER REG.1                  02600016
BASER    EQU   2                       BASE REGISTER                    02650016
CCTR     EQU   3                       POINTER TO CCT                   02700016
GETR     EQU   4                       POINTER TO GETMAIN AREA          02750016
FIELDR   EQU   5                       POINTER TO FIELD TO BE SCANED    02800016
EXTR     EQU   6                       POINTER TO EXTRACT RECORD        02850016
LENGTHR  EQU   7                       LENGTH OF FIELD TO BE SCANED     02900016
COUNTR   EQU   8                       COUNT REG.                       02950016
SCOUNTR  EQU   9                       SUBFIELD COUNT REG.              03000016
CHARR    EQU   10                      CHARACTER REG.                   03050016
DIAR     EQU   11                      POINTER TO DIARY WORK AREA       03100016
PARMR    EQU   12                                                       03150016
RSAVE    EQU   13                      POINTER TO REG. SAVE AREA        03200016
RRET     EQU   14                      RETURN ADDR REG.                 03250016
RBR      EQU   15                      BRANCH AND RETURN CODE REG.      03300016
PNTR     EQU   1                       POINTER TO END OF CONSTANT       03350016
LISTR    EQU   8                       POINTER TO PARAMETER LIST        03400016
MSGR     EQU   9                       POINTER TO MESSAGE TO DISPLAY    03450016
MOVER    EQU   10                      LENGTH OF MOVE                   03500016
STORR    EQU   11                      WORD TO BE STORED                03550016
         EJECT                                                          03600016
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         03620016
         SPACE                                                          03640016
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    03660016
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     03680016
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       03700016
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             03720016
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  03740016
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  03760016
*                   SET.                                                03780016
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      03800016
*                   SECOND.                                             03820016
         SPACE 2                                                        03840016
CCT      DSECT                                                          03860016
         USING *,CCTR                                                   03880016
         SPACE                                                          03900016
*                             SECTION ONE                               03920016
         SPACE                                                          03940016
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     03960016
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    03980016
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  04000016
         SPACE                                                          04020016
         DS    0F                                                       04040016
CCTUNAME DS    5F                  USER'S NAME                          04060016
CCTUACCT DS    5F                  USER'S ACCOUNT NUMBER                04080016
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     04100016
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       04120016
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    04140016
*                                       AT LAST BEGIN JOB               04160016
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   04180016
*                                       LAST BEGIN JOB                  04200016
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 04220016
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    04240016
*                                       JOB                             04260016
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    04280016
*                                       JOB                             04300016
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     04320016
*                                       CESSOR                          04340016
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         04360016
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         04380016
CCTJCTR  DS    H                   JOB COUNTER                          04400016
CCTHIST  DS    109F                HISTORY OF OPERATIONS                04420016
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   04440016
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  04460016
CCTSSTAT DS    C                   SESSION STATUS                       04480016
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              04500016
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              04520016
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    04540016
         EJECT                                                          04560016
         SPACE 2                                                        04580016
*                             SECTION TWO                               04600016
         SPACE                                                          04620016
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   04640016
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  04660016
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 04680016
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              04700016
         SPACE                                                          04720016
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     04740016
*                                       FRAME                           04760016
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  04780016
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     04800016
*                                       MULTIPLE DISPLAY FRAME (ENT)    04820016
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   04840016
CCTDISM  DS    C                   DISPLAY MASK                         04860016
CCTCSM   DS    C                   COMMAND SELECT MASK                  04880016
CCTPSTAT DS    CL2                 GJP STATUS                           04900016
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              04920016
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  04940016
         SPACE 2                                                        04960016
*                             SECTION THREE                             04980016
         SPACE                                                          05000016
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    05020016
*                   INTO SECTION ONE OR TWO                             05040016
         SPACE                                                          05060016
CCTDGMP  DS    F                  POINTER TO DGM                        05080016
CCTDATAP DS    F                  POINTER TO DATA NUMBER                05100016
CCTCSTP  DS    F                  POINTER TO CST                        05120016
CCTCPSTP DS    F                  POINTER TO CURRENT PST                05140016
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            05160016
CCTDORP  DS    F                  POINTER TO DOR MODULE                 05180016
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              05200016
CCTDIARP DS    F                  POINTER TO DIA                        05220016
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      05240016
CCTACTP  DS    F                  POINTER TO ACT                        05260016
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     05280016
CCTIERRP DS    F                  POINTER TO IERR                       05300016
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              05320016
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               05340016
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                05360016
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 05380016
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 05400016
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   05420016
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                05440016
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                05460016
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               05480016
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              05500016
CCTPECB  DS    F                  PROCESSOR'S ECB                       05520016
CCTWECB  DS    F                  WTOR ECB                              05540016
CCTDIAWA DS    CL136               DIARY WORK AREA                      05560016
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    05580016
CCTCSAVE DS    CL72                CTL SAVE AREA                        05600016
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                05620016
CCTASAVE DS    CL72                DAT SAVE AREA                        05640016
         EJECT                                                          06150016
*                                                                       06200016
*     DSECT LAYOUT FOR PROCESSOR WORK AREA (CCTPWKA) WITHIN CCT         06250016
*                                                                       06300016
         SPACE                                                          06350016
EXTREC   DSECT                                                          06400016
         USING *,EXTR                                                   06450016
EDES     DS    CL4                     CONSTANT DEF//                   06500016
EDDNM    DS    C                       DDNAME FIELD LESS ONE            06550016
EDDNAME  DS    CL18                    DATA LABEL                       06600016
EDD      DS    CL10                    CONSTANT DD DSNAME               06650016
EDSNM    DS    C                       DSNAME FIELD LESS ONE            06700016
EDSNAME  DS    CL44                    DATA NAME                        06750016
EDISP1   DS    CL7                     CONSTANT DISP=(                  06800016
EDISTAT  DS    CL3                     CONSTANT OF STATUS               06850016
EDISP2   DS    CL8                     CONSTANT ,XXXXXX)                06900016
EUNIT    DS    CL6                     CONSTANT  UNIT=                  06950016
EUNITNM  DS    CL8                     UNIT NAME OR NUMBER              07000016
EVOLUME  DS    CL11                    CONSTANT VOLUME=SER=             07050016
EVOLNUM  DS    C                       VOLUME SERIAL NUMBER LESS ONE    07100016
EVOLSER  DS    CL6                     VOLUME SERIAL NUMBER             07150016
ESPACE   DS    CL8                     CONSTANT SPACE=(                 07200016
ETYPE    DS    CL5                     TYPE SPACE TRK OR CYL            07250016
EVALUE   DS    CL9                     VALUE OF TRACKS OR CYLINDERS     07300016
EPARENS  DS    CL2                     CONSTANT ))                      07350016
ECOMMA   DS    C                       COMMA BEFORE OTHER DATA          07400016
EOTHER   DS    CL50                    OTHER INFORMATION                07450016
ESYSOUT  DS    CL8                     CONSTANT  SYSOUT=                07500016
ECLASS   DS    CL1                     SYSOUT CLASS                     07550016
EDELIM   DS    CL2                     FIELD DELIMITERS                 07600016
         DS    CL86                    UNUSED                           07650016
ECATED   DS    CL2                     CATALOGED STATUS                 07700016
EOLD     DS    CL2                     OLD STATUS                       07750016
EMOD     DS    CL2                     MODIFY STATUS                    07800016
ESHR     DS    CL2                     SHARE STATUS                     07850016
ENEW     DS    CL2                     NEW STATUS                       07900016
ESYSALL  DS    CL2                     SYSTEM ALLOCATE                  07950016
EDAPOOL  DS    CL2                     DIRECT ACCESS POOL               08000016
EKEEP    DS    CL2                     KEEP DISPOSITION                 08050016
EPASS    DS    CL2                     PASS DISPOSITION                 08100016
EDELETE  DS    CL2                     DELETE DISPOSITION               08150016
ECAT     DS    CL2                     CATALOGED DISPOSITION            08200016
EPRINT   DS    CL2                     PRINT OUTPUT                     08250016
EPUNCH   DS    C                       PUNCH OUTPUT                     08300016
EDISPLAY EQU   ECATED-2                 DISPLAY OUTPUT             IIXX 08320018
EUNITFLD DS    C                       UNIT INFORMATION LESS ONE        08350016
EUNINFO  DS    CL7                     UNIT INFORMATION                 08400016
ETRKFLD  DS    C                       TRACK FIELD LESS ONE             08450016
ETRACKS  DS    CL9                     TRACK INFORMATION                08500016
ECYLFLD  DS    C                       CYLINDED FIELD LESS ONE          08550016
ECYL     DS    CL8                     CYLINDER INFORMATION             08600016
EXTEND   EQU   *                                                        08650016
         EJECT                                                          08670016
         SPACE                                                          08700016
*                                                                       08750016
*  DSECT LAYOUT OF AREA GOTTEN BY GETMAIN                               08800016
*                                                                       08850016
         SPACE                                                          08900016
GETAREA  DSECT                                                          08950016
         USING *,GETR                                                   09000016
         DS    0F                                                       09050016
LENGTH   DS    1H                      LENGTH OF DATA WITHIN FIELD      09100016
SYSWTH   DS    C                       SYSOUT SWITCH                    09150016
LSWITCH  DS    C                       LEFT PAREN                       09200016
RSWITCH  DS    C                       RIGHT PAREN                      09250016
TRKSWT   DS    C                       TRACK SWITCH                     09300016
CYLSWT   DS    C                       CYLINDER SWITCH                  09350016
ASTSWT   DS    C                       ASTERISK SWITCH                  09400016
PERSWT   DS    C                       PERIOD SWITCH                    09450016
COMASWT  DS    C                       COMMA SWITCH                     09500016
DATASWT  DS    C                       DATA SWITCH                      09550016
PLUSGEN  DS    C                       NEW GENERATION                   09600016
LOCATSW  DS    C                       SWITCH FOR LOCATE MACRO          09620016
MSGPARM  DS    8F                      PARAMETER LIST OF MSG'S          09650016
MSGADDR  DS    30F                     MESSAGES TO BE DISPLAYED         09700016
PARMEND  EQU   *                       END OF PARAMETER LIST            09750016
WARNSWT  DS    C                       WARNING FOR UNIT OR VOLUME       09800016
WARNSWT2 DS    C                       WARNING FOR TRACKS OR CYLINDERS  09850016
WARNSWT3 DS    C                       WARNING SWITCH FOR NO SPACE      09870016
OVLYSWT  DS    C                       SWITCH FOR OVERLAY FRAME UP      09900016
OVLYSWT2 DS    C                       SWITCH FOR OVERLAY FRAME TWO     09950016
LOCLIST  DS    F                       PARAMETER LIST FOR LOCATE        09955016
LOCDATA  DS    F                       ADDR OF DSNAME                   09960016
         DS    F                       NOT USED                         09965016
LOCAREA  DS    F                       ADDR OF WORK AREA                09970016
GETEND1  EQU   *                       END OF AREA TO BE CLEARED        09975016
LOCNAME  DS    CL44                    DATA SET NAME                    09980016
LOCWORK  DS    0D                      WORK AREA USED                   09985016
         DS    265C                    BY LOCATE                        09990016
GETEND   EQU   *                                                        10000016
         SPACE                                                          10050016
*                                                                       10100016
*  DSECT LAYOUT OF RECORD WORK AREA (CCTRECWA) WITHIN CCT               10150016
*                                                                       10200016
         SPACE                                                          10250016
DIARY    DSECT                                                          10300016
         USING *,DIAR                                                   10350016
         DS    0F                                                       10400016
         DS    CL5                     UNUSED                           10450016
LABELCON DS    CL10                    LABEL CONSTANT OF DATA SET       10500016
DLABEL   DS    CL19                    DATA LABEL                       10550016
DSN      DS    CL46                    DATA SET NAME                    10600016
DSTAT    DS    CL8                     STATUS                           10650016
DDEVICE  EQU   *                       DIRECT ACCESS POOL               10670016
DUNIT    DS    CL10                    UNIT                             10690016
DVOLUME  DS    CL8                     VOLUME                           10710016
DSPACE   DS    CL11                    SPACE                            10750016
DDISPO   DS    CL8                     DISPOSITION                      10800016
DOTHER   DS    CL50                    OTHER DATA                       10850016
         SPACE                                                          10900016
*                                                                       10950016
*  DSECT LAYOUT OF SYSGEN DATA MODULE                                   11000016
*                                                                       11050016
         SPACE                                                          11100016
SGDATA   DSECT                                                          11120016
         USING *,RPAR1                                                  11150016
         DS    0F                                                       11200016
SYSUNIT  DS    CL8                     SYSTEM DISPLAY UNIT              11250016
SYSDAP   DS    CL8                     SYSTEM DIRECT ACCESS DEVICE      11300016
SYSALOC  DS    CL10                    SYS SPACE ALLOCATION             11350016
         EJECT                                                          11400016
*                                                                       11450016
*  EQUATES USED                                                         11500016
*                                                                       11550016
         SPACE                                                          11600016
PRNTCLSS EQU   CCTSOUT+1                                                11650016
PUNCLSS  EQU   CCTSOUT+2                                                11700016
IGNORBIT EQU   CCTPSTAT+1                                               11750016
SAVE13   EQU   CCTPSAVE+4                                               11800016
POSTCODE EQU   CCTPECB+3                                                11850016
ZERO     EQU   0                                                        11900016
ONE      EQU   1                                                        11950016
TWO      EQU   2                                                        12000016
THREE    EQU   3                                                        12050016
FOUR     EQU   4                                                        12100016
FIVE     EQU   5                                                        12150016
SIX      EQU   6                                                        12200016
SEVEN    EQU   7                                                        12250016
EIGHT    EQU   8                                                        12300016
NINE     EQU   9                                                        12350016
TEN      EQU   10                                                       12400016
ELEVEN   EQU   11                                                       12450016
TWELVE   EQU   12                                                       12500016
ONE3     EQU   13                                                       12550016
ONE4     EQU   14                                                       12600016
ONE6     EQU   16                                                       12650016
ONE7     EQU   17                                                       12700016
FOUR7    EQU   47                                                       12750016
FIVE0    EQU   50                                                       12800016
THREE04  EQU   304                                                      12850016
THREE10  EQU   310                                                      12900016
RECXCEPT EQU   X'04'                                                    12920016
MASK8    EQU   X'08'                                                    12950016
HEX25    EQU   X'25'                                                    13000016
HEX30    EQU   X'30'                                                    13050016
HEX40    EQU   X'40'                                                    13100016
HEX4B    EQU   X'4B'                                                    13150016
HEX4D    EQU   X'4D'                                                    13200016
HEX4E    EQU   X'4E'                                                    13250016
HEX50    EQU   X'50'                                                    13300016
HEX5B    EQU   X'5B'                                                    13350016
HEX5C    EQU   X'5C'                                                    13400016
HEX5D    EQU   X'5D'                                                    13450016
HEX60    EQU   X'60'                                                    13500016
HEX6B    EQU   X'6B'                                                    13550016
HEX7B    EQU   X'7B'                                                    13600016
HEX7C    EQU   X'7C'                                                    13650016
HEXC0    EQU   X'C0'                                                    13700016
HEXF0    EQU   X'F0'                                                    13750016
HEXFF    EQU   X'FF'                                                    13800016
DSNMLGT  EQU   EDISP1-EDSNAME                                           13850016
DDNMLGT  EQU   EDD-EDDNAME                                              13900016
CYLLGT   EQU   EXTEND-ECYL                                              13950016
TRKLGT   EQU   ECYL-ETRACKS                                             14000016
CLRALL   EQU   GETEND1-LENGTH          LENGTH OF AREA TO BE CLEARED     14050016
CLRWKA   EQU   PARMEND-LENGTH                                           14100016
PNTR1    EQU   0                                                        14150016
PNTR2    EQU   PNTR1+4                                                  14200016
PNTR3    EQU   PNTR2+4                                                  14250016
PNTR4    EQU   PNTR3+4                                                  14300016
PNTR5    EQU   PNTR4+4                                                  14350016
PNTR6    EQU   PNTR5+4                                                  14400016
PNTR7    EQU   PNTR6+4                                                  14450016
PNTR8    EQU   PNTR7+4                                                  14500016
PNTR9    EQU   PNTR8+4                                                  14550016
PNTR10   EQU   PNTR9+4                                                  14600016
PNTR11   EQU   PNTR10+4                                                 14650016
PNTR12   EQU   PNTR11+4                                                 14700016
PNTR13   EQU   PNTR12+4                                                 14750016
PNTR14   EQU   PNTR13+4                                                 14800016
PNTR15   EQU   PNTR14+4                                                 14850016
PNTR16   EQU   PNTR15+4                                                 14900016
PNTR17   EQU   PNTR16+4                                                 14950016
PNTR18   EQU   PNTR17+4                                                 15000016
PNTR19   EQU   PNTR18+4                                                 15050016
PNTR20   EQU   PNTR19+4                                                 15100016
PNTR21   EQU   PNTR20+4                                                 15150016
PNTR22   EQU   PNTR21+4                                                 15200016
PNTR23   EQU   PNTR22+4                                                 15250016
PNTR24   EQU   PNTR23+4                                                 15300016
PNTR25   EQU   PNTR24+4                                                 15350016
PNTR26   EQU   PNTR25+4                                                 15400016
PNTR27   EQU   PNTR26+4                                                 15450016
PNTR28   EQU   PNTR27+4                                                 15500016
PNTR29   EQU   PNTR28+4                                                 15550016
PNTR30   EQU   PNTR29+4                                                 15600016
PNTR31   EQU   PNTR30+4                                                 15650016
PNTR32   EQU   PNTR31+4                                                 15700016
PNTR33   EQU   PNTR32+4                                                 15750016
PNTR34   EQU   PNTR33+4                                                 15800016
PNTR35   EQU   PNTR34+4                                                 15850016
PNTR36   EQU   PNTR35+4                                                 15900016
PNTR37   EQU   PNTR36+4                                                 15950016
PNTR38   EQU   PNTR37+4                                                 16000016
PNTR39   EQU   PNTR38+4                                                 16050016
PNTR40   EQU   PNTR39+4                                                 16100016
PNTR41   EQU   PNTR40+4                                                 16150016
PNTR42   EQU   PNTR41+4                                                 16200016
PNTR43   EQU   PNTR42+4                                                 16250016
PNTR44   EQU   PNTR43+4                                                 16300016
PNTR45   EQU   PNTR44+4                                                 16350016
PNTR46   EQU   PNTR45+4                                                 16400016
PNTR47   EQU   PNTR46+4                                                 16450016
PNTR48   EQU   PNTR47+4                                                 16500016
PNTR49   EQU   PNTR48+4                                                 16550016
PNTR50   EQU   PNTR49+4                                                 16570016
PNTR51   EQU   PNTR50+4                                                 16580016
PNTR52   EQU   PNTR51+4                 PRINT OR DISPLAY           IIXX 16586018
PNTR53   EQU   PNTR52+4                 PUNCH OR DISPLAY           IIXX 16592018
         EJECT                                                          16600016
IKAPDES0 CSECT                                                          16650016
*0822,192000,197500,354300-354400,713000,814610-814620             GJPF 16670017
*2512                                                              IIXX 16680018
         SPACE                                                          16700016
*                                                                       16750016
*  SAVE REGISTERS AND SET UP REG.3 AS BASE REGISTER  ESTABLISH LINKS    16800016
*  BETWEEN REGISTER SAVE AREAS                                          16850016
*                                                                       16900016
         SPACE                                                          16950016
         SAVE  (14,12),,*              SAVE ALL REGISTERS               17000016
         BALR  BASER,0                 SET UP REG.2 AS BASE             17050016
         USING *,BASER                                                  17100016
         LR    CCTR,RPAR1              LOAD ADDR OF CCT INTO REG.3      17150016
         LA    RPAR1,CCTPSAVE          LOAD ADDR OF PROCESSER REGISTER  17200016
*                                      SAVE AREA                        17250016
         ST    RPAR1,EIGHT(ZERO,RSAVE) STORE ADDR OF REG. SAVE IN       17300016
*                                      CALLERS SAVE AREA                17350016
         ST    RSAVE,SAVE13            STORE ADDR OF PREVIOUS SAVE AREA 17400016
         LA    RSAVE,CCTPSAVE          LOAD ADDR OF REG. SAVE AREA      17450016
         SPACE                                                          17500016
*                                                                       17550016
*  GET SPACE FOR WORK AREAS TO BE USED FOR PROCESSING                   17600016
*                                                                       17650016
         SPACE                                                          17700016
         GETMAIN  R,LV=GETEND-LENGTH                                    17750016
         SPACE                                                          17800016
         LR    GETR,RPAR1              LOAD ADDR OF GETMAIN ADDRESS     17850016
         LA    EXTR,CCTPWKA            LOAD ADDR OF PROC WORK AREA      17900016
         XC    ZERO(CLRALL,GETR),ZERO(GETR)   CLEAR ALL OF GETMAIN AREA 17950016
         SPACE                                                          18000016
*                                                                       18050016
*  WAIT FOR ECB TO BE POSTED BY DAT                                     18100016
*                                                                       18150016
         SPACE                                                          18200016
WAITECB  WAIT  ECB=CCTPECB                                              18250016
         SPACE                                                          18300016
*                                                                       18350016
*  TEST FOR CANCEL                                                      18400016
*                                                                       18450016
         SPACE                                                          18500016
         TM    POSTCODE,MASK8          TEST FOR CANCEL CODE             18550016
         BO    EXIT                    BRANCH IF CANCEL                 18600016
         SPACE                                                          18610017
         TM    POSTCODE,X'1C'          IS POST CODE INT ERR        GJPF 18620017
         BO    ERORTN                  YES GO TO ERROR RETURN      GJPF 18630017
         SPACE                                                          18650016
*                                                                       18700016
*  DETERMINE IF ADDITIONAL DISPLAY IS NEED FROM DGM                     18750016
*                                                                       18800016
         SPACE                                                          18850016
         LA    DIAR,CCTDIAWA           LOAD ADDR OF DIARY WORK AREA     18900016
         MVI   CCTDIAWA,C' '           MOVE A BLANK TO DIARY WORK AREA  18910016
         MVC   CCTDIAWA+1(175),CCTDIAWA   CLR DIA WORKAREA TO BLANKS    18920016
PTORPCH  CLC   EPRINT(TWO),BLANK       IS DISPOSITION PRINT             18950016
         BNE   MVSYOUT1                BRANCH IF YES                    19000016
         CLC   EPUNCH(TWO),BLANK       IS DISPOSITION PUNCH             19050016
         BNE   MVSYOUT2                BRANCH IF YES                    19100016
         TM    CCTPSTAT,X'10'           Q. BACKGROUND JOB          IIXX 19103018
         BO    NODISP                   YES, DISPLAY NOT ALLOWED   IIXX 19106018
         CLC   EDISPLAY(TWO),BLANK IS DISPOSITION DISPLAY          IIXX 19110018
         BNE   MVSYOUT3            BRANCH IF YES                   IIXX 19120018
NODISP   EQU   *                                                   IIXX 19130018
         CLC   ECATED(TWO),BLANK       IS STATUS CATALOGED              19150016
         BNE   SETLOCSW                YES GO TO SET LOCATE SWITCH GJPF 19200017
         CLC   EOLD(SIX),BLANK         IS STATUS OLD,MOD OR SHARE       19250016
         BNE   CKUNIT                  BRANCH IF YES                    19300016
         CLC   ENEW(TWO),BLANK         IS STATUS NEW                    19350016
         BNE   CKTRK                   BRANCH IF YES                    19400016
         SPACE                                                          19450016
*                                                                       19500016
*  NO STATUS WAS INDICATED TURN ON CATALOGED DEFAULT AND GO TO CKDSNAME 19550016
*                                                                       19600016
         SPACE                                                          19650016
         MVI   ECATED,HEXFF            TURN DEFAUT CATALOGED STATUS ON  19700016
         B     SETLOCSW                GO TO SET LOCATE SWITCH     GJPF 19750017
         SPACE                                                          19800016
*                                                                       19850016
*  CHECK IF UNIT  OR VOLUME  WERE SPECIFIED IF NOT GO TO DGM FOR        19900016
*  AN OVERLAY DISPLAY                                                   19950016
*                                                                       20000016
         SPACE                                                          20050016
CKUNIT   CLC   EUNINFO(SIX),BLANK      HAS UNIT BEEN SPECIFIED          20100016
         BNE   CKDSNAME                BRANCH IF YES                    20150016
         CLC   EVOLSER(SIX),BLANK      HAS VOLUME BEEN SPECIFIED        20200016
         BNE   CKDSNAME                BRANCH IF YES                    20250016
         CLC   EMOD(FOUR),BLANK        IS IT MOD OR SHARE DATA SET      20270016
         BNE   SETLOCSW                YES GO TO SET LOCATE SWITCH      20290016
         TM    OVLYSWT,HEXFF           IS OVERLAY SWITCH ON             20330016
         BO    CKDSNAME                YES GO TO CHECK DSNAME           20410016
         SPACE                                                          20500016
*                                                                       20550016
*  ADDITIONAL OVERLAY DISPLAY NEEDED GO TO KEY MANIP ROUTINE            20600016
*                                                                       20650016
         SPACE                                                          20700016
         MVI   OVLYSWT,HEXFF           TURN OVERLAY SWITCH ON           20850016
         LA    RPAR0,EOLD-EDES         LOAD INPUT MAP OF OLD            20900016
TSTXCEPT TM    CCTPSTAT,RECXCEPT        IS STATUS RECALL ACCEPT MODE    20920016
         BO    RECRET                  YES RETURN                       20940016
         TM    CCTSSTAT,32              Q. REMOTE GRAPHIC DEVICE   GJPF 20946017
         BO    CKDSNAME                 YES - DISPLAY IS UP        GJPF 20952017
         LR    RPAR1,CCTR              LOAD CCT ADDR                    20960016
         L     RBR,CCTPKYM             LOAD ADDR OF KEY MANIP           21000016
         BALR  RRET,RBR                BRANCH TO KEY MANIP              21050016
         SPACE                                                          21100016
         CH    RBR,FOUR4               IS OVERLAY UP                    21150016
         BE    CKDSNAME                YES GO TO CHECK DSNAME           21200016
CLEARECB NC    IGNORBIT(ONE),IGNOROFF  TURN OFF IGNORE ATTN BIT         21250016
         XC    CCTPECB(FOUR),CCTPECB   CLEAR PROCESSOR ECB              21300016
         XC    ZERO(CLRWKA,GETR),ZERO(GETR)  CLEAR WORK AREA            21350016
         B     WAITECB                 BRANCH TO WAIT                   21400016
         SPACE                                                          21450016
*                                                                       21500016
*  CHECK IF TRACKS OR CYLINDERS WERE SPECIFIED                          21550016
*                                                                       21600016
         SPACE                                                          21650016
CKTRK    CLC   ETRACKS(SIX),BLANK      HAVE TRACKS BEEN SPECIFIED       21700016
         BNE   CKDSNAME                BRANCH IF YES                    21750016
         CLC   ECYL(SIX),BLANK         HAVE CYLINDERS BEEN SPECIFIED    21800016
         BNE   CKDSNAME                BRANCH IF YES                    21850016
         CLC   ESYSALL(TWO),BLANK      WAS SYSTEM ALLOCATE CHECKED      21900016
         BNE   CKDSNAME                YES GO TO CHECK DSNAME           21950016
         TM    OVLYSWT2,HEXFF          IS OVERLAY TWO SWITCH ON         22100016
         BO    CKDSNAME                YES GO TO CHECK DSNAME           22150016
         MVI   OVLYSWT2,HEXFF          TURN OVERLAY SWITCH ON           22200016
         LA    RPAR0,ENEW-EDES         LOAD INPUT MAP OF NEW            22250016
         B     TSTXCEPT                 GO TO TEST ACCEPT MODE          22300016
         SPACE                                                          22350016
*                                                                       22400016
*  MOVE CONSTANT SYSOUT= AND SYSOUT CLASS                               22450016
*                                                                       22500016
         SPACE                                                          22550016
MVSYOUT1 MVC   ECLASS(ONE),PRNTCLSS    MOVE PRINT CLASS                 22600016
         MVC   DDISPO(FIVE),PRINT      MOVE CON PRINT TO DIA WORK AREA  22650016
         B     MVSYSOUT                TO MOVE CONSTANTS                22700016
MVSYOUT2 MVC   ECLASS(ONE),PUNCLSS     MOVE PUNCH CLASS                 22750016
         MVC   DDISPO(FIVE),PUNCH      MOVE CON PUNCH TO DIA WORK AREA  22800016
         B     MVSYSOUT            MOVE CONSTANTS                  IIXX 22810018
MVSYOUT3 MVC    ECLASS(ONE),CCTSOUT  MOVE DISPLAY CLASS            IIXX 22820018
         MVC   DDISPO(SEVEN),DISPLAY  MOVE CONS DISPLAY            IIXX 22830018
MVSYSOUT MVC   ESYSOUT(EIGHT),SYSOUT   MOVE CONSTANT SYSOUT=            22850016
         MVC   EDELIM(TWO),CLASS       MOVE DELEMITERS                  22900016
MVDD     MVC   EDD(FOUR),DD            MOVE CONSTANT DD                 22950016
         OI    SYSWTH,HEXFF            SET SYSOUT SWITCH ON             23000016
         B     SCANDDNM                TO SCAN DD NAME                  23050016
         SPACE                                                          23057016
*                                                                       23064016
*  STATUS OF DATA SET IS EITHER MOD OR SHARE SET SWITCH TO LOCATE IT    23071016
*                                                                       23078016
         SPACE                                                          23085016
SETLOCSW MVI   LOCATSW,HEXFF           SET LOCATE SWITCH ON             23092016
         SPACE                                                          23100016
*                                                                       23150016
*  SCAN DATA NAME FOR VALID CHARACTERS AND PUNCTUATION                  23200016
*                                                                       23250016
         SPACE                                                          23300016
CKDSNAME LA    FIELDR,EDSNM            LOAD ADDR OF DATA SET NAME FIELD 23350016
         LA    LENGTHR,DSNMLGT         LOAD LENGTH OF FIELD             23400016
         LA    COUNTR,BLANK            LOAD ADDRESS OF A BLANK          23450016
         BAL   RRET,SCAN1              GO TO SCAN ONE                   23500016
         SPACE                                                          23550016
         B     TABLE1(RBR)             TO BRANCH TABLE PLUS REG.15      23600016
TABLE1   B     ADD1                    TO ADD ONE TO FIELD REG.         23650016
         B     BLNKS                   FIELD HAS BLANKS                 23700016
         SPACE                                                          23750016
*                                                                       23800016
*  DATA NAME FIELD BLANK CHECK IF NEW WAS PICKED                        23850016
*                                                                       23900016
         CLC   EPRINT(TWO),BLANK       IS DISPOSITION PRINT             23908016
         BNE   SCANDDNM                YES,GO TO SCAN DDNAME            23916016
         CLC   EPUNCH(TWO),BLANK       IS DISPOSITION BLANK             23924016
         BNE    SCANDDNM               YES,GO TO SCAN DDNAME            23932016
         TM    CCTPSTAT,X'10'           Q. BACKGROUND JOB          IIXX 23932618
         BO    FLDBLNK                  YES, DISPLAY NOT ALLOWED   IIXX 23933218
         CLC   EDISPLAY(TWO),BLANK IS DISPOSITON DISPLAY           IIXX 23934018
         BNE   SCANDDNM            YES, GO SCAN DDNAME             IIXX 23936018
         B     FLDBLNK                 FIELD IS BLANK-ERROR             23940016
         SPACE                                                          23950016
         CLC   ENEW(TWO),BLANK         WAS NEW SELECTED                 24000016
         BNE   SCANDDNM                YES GO TO SCAN DDNAME            24050016
         B     FLDBLNK                 FIELD IS BLANK                   24100016
         SPACE                                                          24150016
*                                                                       24200016
*  ERROR DSNAME FIELD HAS IMBEDDED BLANKS                               24250016
*                                                                       24300016
         SPACE                                                          24350016
BLNKS    BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    24400016
         DC    AL2(PNTR1)              DISPLACEMENT OF POINTER NO 1     24450016
         SPACE                                                          24500016
*                                                                       24550016
*  ERROR DATA SET NAME FIELD BLANK                                      24600016
*                                                                       24650016
         SPACE                                                          24700016
FLDBLNK  BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    24750016
         DC    AL2(PNTR2)              DISPLACEMENT OF POINTER NO 2     24800016
         SPACE                                                          24850016
*                                                                       24900016
*  CHECK FIRST CHARACTER FOR AN ASTERISK OR AN AMPERSAND                24950016
*                                                                       25000016
         SPACE                                                          25050016
ADD1     LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         25100016
         CLI   ZERO(FIELDR),HEX50      COMPARE CHAR. TO AN AMPERSAND    25150016
         BE    LOADONE                 IF EQUAL GO TO LOAD ONE          25200016
         CLI   ZERO(FIELDR),HEX5C      COMPARE CHAR. TO AN ASTERISK     25250016
         BE    ADD3                    IF EQUAL GO TO ADD3              25300016
         SR    COUNTR,COUNTR           ZERO COUNT REG.                  25350016
         B     LDEIGHT                 TO LOAD EIGHT                    25400016
ADD3     LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         25450016
         CLC   ZERO(ZERO,FIELDR),BLANK COMPARE CHAR. TO A BLANK         25500016
         BE    SETAST                  GO TO SET ASTERISK SWITCH        25550016
         CLI   ZERO(FIELDR),HEX4B      COMPARE CHAR. TO A PERIOD        25600016
         BE    LOADTWO                 TO LOAD TWO                      25650016
         SPACE                                                          25700016
*                                                                       25750016
*  ERROR ASTERISK NOT FOLLOWED BY A PERIOD                              25800016
*                                                                       25850016
         SPACE                                                          25900016
         LA    SCOUNTR,ONE             LOAD SUBFIELD COUNT REG WITH ONE 25920016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    25950016
         DC    AL2(PNTR3)              DISPLACEMENT OF POINTER NO 3     26000016
         SPACE                                                          26050016
*                                                                       26100016
*  SET ASTERISK SWITCH ON AND MOVE DD CONSTANT                          26140016
*                                                                       26180016
         SPACE                                                          26220016
SETAST   MVI   ASTSWT,HEXFF            SET ASTERISK SWITCH ON           26260016
         MVC   EDD(FOUR),DD            MOVE CONSTANT DD                 26300016
         B     SCANDDNM                GO TO SCAN DDNAME                26340016
         SPACE                                                          26400016
*                                                                       26450016
*  LOAD COUNT AND LENGTH REGISTERS AND GO TO SCAN ROUTINE               26500016
*                                                                       26550016
         SPACE                                                          26600016
LOADONE  LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         26650016
         LA    COUNTR,ONE              LOAD COUNT REG WITH ONE          26700016
         B     LDEIGHT                 TO LOAD LENGTHR                  26750016
LOADTWO  LA    COUNTR,TWO              LOAD COUNT REG. WITH TWO         26800016
         LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO PIONTER               26850016
LDEIGHT  LA    LENGTHR,EIGHT           LOAD LENGTH REG. WITH EIGHT      26900016
         BAL   RRET,SCAN2              GO TO SCAN2                      26950016
         SPACE                                                          27000016
*                                                                       27050016
* DETERMINE IF SCAN WAS GOOD AND RETURN TO SCAN IF MORE THAT ONE        27100016
* SUBFIELD IS PRESENT                                                   27150016
*                                                                       27200016
         SPACE                                                          27250016
         AR    COUNTR,SCOUNTR          ADD SUBFIELD COUNT TO TOTAL      27300016
         B     TABLE2(RBR)             BRANCH TO TABLE PLUS REG.15      27350016
TABLE2   B     CTEQUAL                 TO COMPARE FOR EQUAL COUNTS      27400016
         B     CKPER                   TO CHECK FOR A PERIOD            27450016
         B     CKSIGN                  TO CHECK FOR A SIGN              27500016
         B     TESTZERO                TO TEST FIRST CHAR FOR ZERO      27550016
         SPACE                                                          27600016
CTEQUAL  CH    COUNTR,LENGTH           COMPARE COUNT TO LENGTH          27650016
         BE    MVDSNAME                BRANCH TO MOVE COSTANT DSNAME    27700016
         LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD REG.            27750016
         LA    COUNTR,ONE(ZERO,COUNTR) ADD ONE TO COUNT                 27800016
CKPER    CLI   ZERO(FIELDR),HEX4B      COMPARE TO A PERIOD              27850016
         BNE   LPAREN                  BRANCH NOT PERIOD                27900016
         TM    LSWITCH,HEXFF           IS LEFT PAREN SWITCH ON          27910016
         BO    MEMNMERR                YES GO TO MEMBER NAME ERROR      27920016
         SPACE                                                          27950016
ADD4     CH    COUNTR,LENGTH           COMPARE COUNT TO LENGTH          28000016
         BNL   ENDINGER                BRANCH IF COUNT NOT LOW          28050016
         LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         28100016
         B     LDEIGHT                 BRANCH TO LOAD EIGHT             28150016
         SPACE                                                          28200016
*                                                                       28250016
*  TEST FIRST CHARACTER FOR A ZERO IF GOOD TEST FOR RIGHT PAREN         28300016
*                                                                       28350016
         SPACE                                                          28400016
TESTZERO CLI   ZERO(FIELDR),HEXF0      IS CHAR A ZERO                   28450016
         BNE   FSTCHAR                 NO GO TO FIRST CHAR ERROR        28500016
         LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         28550016
         LA    COUNTR,ONE(ZERO,COUNTR) ADD ONE TO COUNT                 28600016
         TM    ZERO(FIELDR),HEX5D      IS CHAR A RIGHT PAREN            28650016
         BO    COMPCONT                YES GO TO COMPARE COUNT          28700016
         B     FSTCHAR                 NO GO TO FIRST CHAR ERROR        28750016
         SPACE                                                          28800016
*                                                                       28850016
*  ERROR  NAME ENDS WITH A PERIOD                                       28900016
*                                                                       28950016
         SPACE                                                          29000016
ENDINGER BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    29050016
         DC    AL2(PNTR4)              DISPLACEMENT OF POINTER NO 4     29100016
         SPACE                                                          29106016
*                                                                       29112016
*  ERROR PERIOD IN MEMBER NAME                                          29118016
*                                                                       29124016
         SPACE                                                          29130016
MEMNMERR BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    29136016
         DC    AL2(PNTR50)             DISPLACEMENT OF POINTER NO. 50   29142016
         SPACE                                                          29150016
LPAREN   CLI   ZERO(FIELDR),HEX4D      COMPARE FOR LEFT PAREN           29200016
         BE    LPARSWT                 BRANCH IF YES TO SET SWITCH      29250016
         CLI   ZERO(FIELDR),HEX5D      IS CHARACTER A RIGHT PAREN       29300016
         BNE   CKSIGN                  BRANCH IF NOT RIGHT PAREN        29350016
         MVI   RSWITCH,HEXFF           SET RIGHT PAREN SWITCH ON        29400016
         TM    LSWITCH,HEXFF           TEST LEFT PAREN SWITCH           29450016
         BO    CNTEQ                                                    29500016
         SPACE                                                          29550016
*                                                                       29600016
*  ERROR IN PUNCTUATION : ODD PARENS                                    29650016
*                                                                       29700016
         SPACE                                                          29750016
ODDPAR   BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    29800016
         DC    AL2(PNTR6)              DISPLACEMENT OF POINTER NO 6     29850016
         SPACE                                                          29900016
*                                                                       29950016
*  CHECK LEFT PAREN SWITCH IF ON GO TO LEFT PAREN ERROR IF NOT ON SET   30000016
*  IT ON                                                                30050016
*                                                                       30100016
         SPACE                                                          30150016
LPARSWT  TM    LSWITCH,HEXFF           TEST FOR LEFT PAREN SWITCH ON    30200016
         BO    ODDPAR                  IF ON BRANCH TO ERROR            30250016
         OI    LSWITCH,HEXFF           SET LEFT PAREN SWITCH ON         30300016
         B     ADD4                    GO TO ADD4                       30350016
         SPACE                                                          30400016
*                                                                       30450016
*  ERROR SPECIAL CHARACTER IN DATA NAME FIELD                           30500016
*                                                                       30550016
         SPACE                                                          30600016
SPECCHAR BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    30650016
         DC    AL2(PNTR8)              DISPLACEMENT OF POINTER NO 8     30700016
         SPACE                                                          30750016
CNTEQ    CH    COUNTR,LENGTH           COMPARE COUNT TO LENGTH          30800016
         BE    MVDSNAME                IF EQUAL GO TO MOVE DSNAME       30850016
         SPACE                                                          30900016
*                                                                       30950016
*  ERROR IN PUNCTUATION : DATA FOLLOWS A RIGHT PAREN                    31000016
*                                                                       31050016
         SPACE                                                          31100016
RPARERR  BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    31150016
         DC    AL2(PNTR7)              DISPLACEMENT OF POINTER NO 7     31200016
         SPACE                                                          31250016
*                                                                       31300016
*  CHECK FOR SIGN OR NON ALPHA CHARACTER                                31350016
*                                                                       31400016
         SPACE                                                          31450016
CKSIGN   CLI   ZERO(FIELDR),HEX4E      TEST FOR A PLUS SIGN             31500016
         BE    SETPLUS                 BRANCH IF YES                    31550016
         CLI   ZERO(FIELDR),HEX60      TEST FOR A MINUS SIGN            31600016
         BE    CKPARSWT                BRANCH IF YES                    31650016
         CH    SCOUNTR,ONE1            DOES SUBFIELD COUNT HAVE ONE     31700016
         BH    CKLENGT                 NO GO TO CHECK LENGTH            31750016
         SPACE                                                          31800016
*                                                                       31850016
*  ERROR FIRST CHARACTER IS NON-ALPHABETIC                              31900016
*                                                                       31950016
         SPACE                                                          32000016
FSTCHAR  BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    32050016
         DC    AL2(PNTR5)              DISPLACEMENT OF POINTER NO 5     32100016
         SPACE                                                          32150016
*                                                                       32200016
*  CHECK NAME FOR LENGTH VIOLATION                                      32250016
*                                                                       32300016
         SPACE                                                          32350016
CKLENGT  CR    SCOUNTR,LENGTHR         IS SUB COUNT EQUAL TO LENGTH     32400016
         BL    SPECCHAR                NO GO TO SPECIAL CHARACTER       32450016
         SPACE                                                          32500016
*                                                                       32550016
*  ERROR NAME IS MORE THAN EIGHT CHARACTERS GO TO DISPLAY MSG ROUTINE   32600016
*                                                                       32650016
         SPACE                                                          32700016
TOLONG   BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    32750016
         DC    AL2(PNTR9)              DISPLACEMENT OF POINTER NO 9     32800016
         SPACE                                                          32850016
*                                                                       32900016
*  CHECK GENERATION NUMBER                                              32950016
*                                                                       33000016
         SPACE                                                          33050016
SETPLUS  MVI   PLUSGEN,HEXFF           SET NEW GENERATION SWITCH ON     33100016
         SPACE                                                          33150016
CKPARSWT TM    LSWITCH,HEXFF           TEST LEFT PAREN SWITCH           33200016
         BO    ADD5                    IF ON GO TO ADD5                 33250016
         SPACE                                                          33300016
*                                                                       33350016
*  ERROR NO LEFT PAREN BEFORE SIGN                                      33400016
*                                                                       33450016
         SPACE                                                          33500016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    33550016
         DC    AL2(PNTR10)             DISPLACEMENT OF POINTER NO 10    33600016
         SPACE                                                          33650016
ADD5     SR    SCOUNTR,SCOUNTR         ZERO SUBFIELD COUNT REG          33700016
NEXTNUM  LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         33750016
         LA    COUNTR,ONE(ZERO,COUNTR) ADD ONE TO COUNT                 33800016
         TM    ZERO(FIELDR),HEXF0      TEST FON NUMERIC CHAR.           33850016
         BO    COMPLENG                BRANCH IF NUMERIC                33900016
         BCT   SCOUNTR,GENERR          IF NOT ONE BRANCH TO GEN. ERROR  33950016
         CLI   ZERO(FIELDR),HEX5D      COMPARE CHAR.TO RIGHT PAREN      34000016
         BE    COMPCONT                IF EQUAL GO TO COMPARE COUNT     34050016
         SPACE                                                          34100016
*                                                                       34150016
*  ERROR SIGN NOT FOLLOWED BY NUMERIC VALUE GO TO DISPLAY MSG ROUTINE   34200016
*                                                                       34250016
         SPACE                                                          34300016
GENERR   LA    SCOUNTR,TWO             LOAD SUBFIELD COUNT REG WITH TWO 34330016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    34360016
         DC    AL2(PNTR12)             DISPLACEMENT OF POINTER NO 12    34400016
         SPACE                                                          34450016
COMPLENG CH    COUNTR,LENGTH           COMPARE COUNT TO LENGTH          34500016
         BE    ODDPAR                  IF EQUAL NO RIGHT PAREN          34550016
         LA    SCOUNTR,ONE             LOAD ONE INTO SUBFIELD COUNT REG 34600016
         B     NEXTNUM                 GO TO CHECK NEXT NUMBER          34650016
         SPACE                                                          34700016
COMPCONT MVI   RSWITCH,HEXFF           SET RIGHT PAREN SWITCH ON        34750016
         CH    COUNTR,LENGTH           COMPARE COUNT TO LENGTH          34800016
         BE    MVDSNAME                IF EQUAL GO TO MOVE DSNAME       34850016
         B     RPARERR                 GO TO RIGHT PAREN ERROR          34900016
         SPACE                                                          34950016
         SPACE                                                          35000016
*                                                                       35050016
*  CHECK FOR ODD PARENS IF NONE MOVE CONSTANT DSNAME                    35100016
*                                                                       35150016
         SPACE                                                          35200016
MVDSNAME TM    LSWITCH,HEXFF           IS LEFT PAREN SWITCH ON          35250016
         BZ    MOVEIT                  NO GO TO MOVE DSNAME             35300016
         TM    RSWITCH,HEXFF           IS RIGHT PAREN SWITCH ON         35350016
         BZ    ODDPAR                  YES GO TO ODD PAREN ERROR        35400016
MOVEIT   TM    LOCATSW,HEXFF           IS LOCATE SWITCH ON              35410016
         BO    TOLOCATE                YES GO TO LOCATE DATA SET        35420016
MOVDSNM  MVC   EDD(ELEVEN),DSNAME      MOVE CONSTANT DD DSNAME=         35450016
         MVI   DATASWT,HEXFF           SET DATA NAME SWITCH ON          35500016
         MVC   DSN(DSNMLGT),EDSNAME    MOVE DATA NAME TO DIA WORK AREA  35550016
         SPACE                                                          35600016
*                                                                       35650016
*  SCAN DATA LABEL VALID CHARACTERS AND PUNCTUATION                     35700016
*                                                                       35750016
         SPACE                                                          35800016
SCANDDNM LA    FIELDR,EDDNM            LOAD ADDR OF DATA NAME FIELD     35850016
         LA    LENGTHR,DDNMLGT         LOAD LENGH REG WITH DDNM LENGTH  35900016
         LA    COUNTR,BLANK            LOAD ADDR OF A BLANK             35950016
         BAL   RRET,SCAN1              GO TO SCAN1 ROUTINE              36000016
         SPACE                                                          36050016
*                                                                       36100016
*  DETERMINE IF SCAN WAS GOOD IF NO GO TO PROPER ERROR MSG              36150016
*                                                                       36200016
         SPACE                                                          36250016
         B     TABLE4(RBR)             GO TO TABLE PLUS RETURN CODE     36300016
TABLE4   B     ADDONEA                 SCAN GOOD GO TO ADD ONE          36350016
         B     IMBLANK                 GO TO IMBEDDED BLANK ERROR MSG   36400016
         SPACE                                                          36450016
*                                                                       36500016
*  ERROR FIELD IS BLANK GO TO DISPLAY MESSAGE ROUTINE                   36550016
*                                                                       36600016
         SPACE                                                          36650016
FLDBLANK BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    36700016
         DC    AL2(PNTR14)             DISPLACEMENT OF POINTER NO 14    36750016
         SPACE                                                          36800016
*                                                                       36850016
*  ERROR FIELD HAS IMBEDDED BLANKS GO TO DISPLAY MESSAGE ROUTINE        36900016
*                                                                       36950016
         SPACE                                                          37000016
IMBLANK  BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    37050016
         DC    AL2(PNTR13)             DISPLACEMENT OF POINTER NO 13    37100016
         SPACE                                                          37150016
*                                                                       37200016
*  SCAN WAS GOOD GO TO SCAN2 FOR VALID CHARACTERS                       37250016
*                                                                       37300016
         SPACE                                                          37350016
ADDONEA  LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         37400016
         LA    LENGTHR,EIGHT           LOAD EIGHT INTO LENGTH REG.      37450016
         SR    COUNTR,COUNTR           ZERO COUNT REG.                  37500016
TOSCAN2  BAL   RRET,SCAN2              BRANCH TO SCAN2 ROUTINE          37550016
         SPACE                                                          37600016
*                                                                       37650016
*  DETERMINE IF SCAN WAS GOOD RETURN TO SCAN IF MORE DATA IS IN FIELD   37700016
*                                                                       37750016
         SPACE                                                          37800016
         AR    COUNTR,SCOUNTR          ADD SUBFIELD COUNT TO TOTAL CONT 37850016
         B     TABLE5(RBR)             GO TO TABLE PLUS RETURN CODE     37900016
TABLE5   B     CMPCOUNT                TO COMPARE COUNT                 37950016
         B     CMPPERD                 TO COMPARE FOR PERIOD            38000016
         B     NONALPHA                TO NON-ALPHA ERROR               38050016
         SPACE                                                          38100016
*                                                                       38150016
* ERROR NAME STARTS WITH A NON-ALPHA CHAR. GO TO DISPLAY MSG ROUTINE    38200016
*                                                                       38250016
         SPACE                                                          38300016
NONALPHA BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    38350016
         DC    AL2(PNTR15)             DISPLACEMENT OF POINTER NO 15    38400016
         SPACE                                                          38450016
CMPCOUNT CH    COUNTR,LENGTH           COMPARE COUNT TO LENGTH          38500016
         BE    MVCONDES                IF EQUAL GO TO MOVE CONSTANT DES 38550016
         LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         38600016
         LA    COUNTR,ONE(ZERO,COUNTR) ADD ONE TO COUNT                 38650016
CMPPERD  CLI   ZERO(FIELDR),HEX4B      COMPARE CHAR TO A PERIOD         38700016
         BE    COUNTEQ                 IF EQUAL GO TO COMPARE COUNT     38750016
         SPACE                                                          38800016
*                                                                       38850016
*  CHECK SUBFIELD NAME LENGTH IN DDNAME                                 38900016
*                                                                       38950016
         SPACE                                                          39000016
         LA    LENGTHR,ONE              LOAD LENGTH REG WITH 1          39050016
         BAL   RRET,SCAN2               TO SCAN2 ROUTINE                39100016
         SPACE                                                          39150016
         B     TABLE6(RBR)              TO BRANCH TABLE PLUS REG 15     39200016
TABLE6   B     TOOLONG                  TO TO LONG                      39250016
         B     TOOLONG                  TO TO LONG                      39300016
         B     SPECHAR2                 TO SPECIAL CHARACTER IN NAME    39350016
         SPACE                                                          39400016
*                                                                       39450016
*  ERROR SUBFIELD NAME LENGTH MORE THAN EIGHT                           39500016
*                                                                       39550016
         SPACE                                                          39600016
TOOLONG  LA    LENGTHR,EIGHT           LOAD LENGTH REG WITH 8           39620016
         LA    SCOUNTR,EIGHT           LOAD SUBFIELD COUNT WITH EIGHT   39640016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    39660016
         DC    AL2(PNTR17)             DISPLACEMENT OF POINTER NO 17    39700016
         SPACE                                                          39750016
*                                                                       39800016
*  ERROR SPECIAL CHARACTER IN DDNAME                                    39850016
*                                                                       39900016
         SPACE                                                          39950016
SPECHAR2 BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    40000016
         DC    AL2(PNTR16)             DISPLACEMENT OF POINTER NO 16    40050016
         SPACE                                                          40100016
COUNTEQ  CH    COUNTR,LENGTH           IS COUNT EQUAL TO LENGTH         40150016
         BE    INVALCAR                YES FIELD END WITH INVALID CHAR  40200016
         TM    PERSWT,HEXFF            IS PERIOD SWITCH ON              40250016
         BO    PERERR                  YES GO TO PERIOD ERROR           40300016
         MVI   PERSWT,HEXFF            SET PERIOD SWITCH ON             40350016
         LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         40400016
         B     TOSCAN2                 BRANCH TO SCAN2                  40450016
         SPACE                                                          40500016
*                                                                       40550016
*  ERROR NAME ENDS WITH AN INVALID CHARACTER                            40600016
*                                                                       40650016
         SPACE                                                          40700016
INVALCAR BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    40750016
         DC    AL2(PNTR18)             DISPLACEMENT OF POINTER NO 18    40800016
         SPACE                                                          40850016
*                                                                       40900016
*  ERROR MORE THAN ONE PERIOD IN DDNAME                                 40950016
*                                                                       41000016
         SPACE                                                          41050016
PERERR   BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSG       41100016
         DC    AL2(PNTR41)             DISPLACEMENT OF POINTER NO 41    41150016
         SPACE                                                          41200016
*                                                                       41250016
*  MOVE CONSTANT DES// AND CHECK FOR SYSOUT SWITCH ON                   41300016
*                                                                       41350016
         SPACE                                                          41400016
MVCONDES MVC   EDES(FIVE),DES          MOVE CONSTANT DES// TO EXTRACT   41450016
         MVC   DLABEL(ONE7),EDDNAME    MOVE DATA LABEL TO DIA WORK AREA 41500016
         TM    SYSWTH,HEXFF            IS SYSOUT SWITCH ON              41550016
         BO    CHKDISPO                YES BRANCH TO CHECK DISPOSITION  41600016
         SPACE                                                          41650016
*                                                                       41700016
*  SCAN DISPOSITION AND STATUS TO INSURE ONLY ONE WAS PICKED            41750016
*                                                                       41800016
         SPACE                                                          41850016
         SR    COUNTR,COUNTR           ZERO COUNT REG                   41900016
         CLC   ECATED(TWO),BLANK       IS STATUS CATALOGED              41950016
         BE    CHKOLD                  NO GO TO CHECK OLD               42000016
         LA    COUNTR,ONE(ZERO,COUNTR) YES ADD ONE TO COUNT             42050016
CHKOLD   CLC   EOLD(TWO),BLANK         IS STATUS OLD                    42100016
         BE    CHKMOD                  NO GO TO CHECK MODIFY            42150016
         LA    COUNTR,ONE(ZERO,COUNTR) YES ADD ONE TO COUNT             42200016
CHKMOD   CLC   EMOD(TWO),BLANK         IS STATUS MODIFY                 42250016
         BE    CHKSHR                  NO GO TO CHECK SHARE             42300016
         LA    COUNTR,ONE(ZERO,COUNTR) YES ADD ONE TO COUNT             42350016
CHKSHR   CLC   ESHR(TWO),BLANK         IS STATUS SHARE                  42400016
         BE    CHKNEW                  NO GO TO CHECK NEW               42450016
         LA    COUNTR,ONE(ZERO,COUNTR) YES ADD ONE TO COUNT             42500016
CHKNEW   CLC   ENEW(TWO),BLANK         IS STATUS NEW                    42550016
         BE    CHKCOUNT                NO GO TO COMPARE COUNT           42600016
         LA    COUNTR,ONE(ZERO,COUNTR) YES ADD ONE TO COUNT             42650016
CHKCOUNT CH    COUNTR,ONE1             IS COUNT MORE THAN ONE           42700016
         BH    MORSTAT                 YES MORE THAN ONE STATUS GIVEN   42750016
         SPACE                                                          42800016
*                                                                       42850016
*  CHECK DISPOSITION                                                    42900016
*                                                                       42950016
         SPACE                                                          43000016
         SR    COUNTR,COUNTR           ZERO COUNT REG                   43050016
         CLC   EKEEP(TWO),BLANK        IS DISPOSITION KEEP              43100016
         BE    CHKPASS                 NO GO TO CHECK PASS              43150016
         LA    COUNTR,ONE(ZERO,COUNTR) ADD ONE TO COUNT                 43200016
CHKPASS  CLC   EPASS(TWO),BLANK        IS DISPOSITION PASS              43250016
         BE    CHKDEL                  NO GO TO CHECK DELETE            43300016
         LA    COUNTR,ONE(ZERO,COUNTR) ADD ONE TO COUNT                 43350016
CHKDEL   CLC   EDELETE(TWO),BLANK      IS DISPOSITION DELETE            43400016
         BE    CHKCATLG                NO GO TO COMPARE COUNT           43450016
         LA    COUNTR,ONE(ZERO,COUNTR) ADD ONE TO COUNT                 43500016
CHKCATLG CLC   ECAT(TWO),BLANK         IS DISPOSITION CATALOG           43550016
         BE    CKCOUNT                 NO GO TO CHECK COUNT             43600016
         LA    COUNTR,ONE(ZERO,COUNTR) ADD ONE TO COUNT                 43650016
         SPACE                                                          43700016
CKCOUNT  CH    COUNTR,ONE1             COMPARE COUNT TO ONE             43750016
         BH    MORDISP                 IF HIGH MORE THAN ONE DISP       43800016
         B     CEKCATLG                IF EQUAL GO TO CHECK CATALOGED   43850016
         SPACE                                                          43900016
*                                                                       43950016
*  ERROR MORE THAN ONE DISPOSITION GIVEN                                44000016
*                                                                       44050016
         SPACE                                                          44100016
MORDISP  BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    44150016
         DC    AL2(PNTR20)             DISPLACEMENT OF POINTER NO 20    44200016
         SPACE                                                          44250016
*                                                                       44300016
*  CHECK FOR CATALOGED STATUS IF CATALOGED MOVE CONSTANT                44350016
*                                                                       44400016
         SPACE                                                          44450016
CEKCATLG CLC   ECATED(TWO),BLANK       IS DATA SET CATALOGED            44500016
         BE    CHEKNEW                 NO GO TO CHECK NEW               44550016
         TM    PLUSGEN,HEXFF           IS NEW GENERATION SWITCH ON      44600016
         BO    GENERROR                YES GO TO GENERATION ERROR       44650016
         TM    ASTSWT,HEXFF           Q.IS ASTERISK  SWITCH ON     IIXX 44660018
         BO    TODIA                   YES GO TO DIARY ROUTINE     IIXX 44670018
         MVC   EDISP1(SEVEN),DISP      MOVE CONSTANT DISP(=             44700016
         MVC   EDISTAT(THREE),OLD      MOVE CONSTANT OLD                44750016
         MVC   DSTAT(THREE),OLD        MOVE OLD STATUS TO DIA WORK AREA 44800016
         B     MOVECONS                GO TO MOVE DISPOSITION           44850016
         SPACE                                                          44900016
*                                                                       44950016
*  ERROR MORE THAN ONE STATUS INDICATED                                 45000016
*                                                                       45050016
         SPACE                                                          45100016
MORSTAT  BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    45150016
         DC    AL2(PNTR19)             DISPLACEMENT OF POINTER NO 19    45200016
         SPACE                                                          45250016
*                                                                       45300016
*  ERROR NEW GENERATION INDICATED BUT NEW STATUS WAS NOT                45350016
*                                                                       45400016
         SPACE                                                          45450016
GENERROR BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    45500016
         DC    AL2(PNTR48)             DISPLACEMENT OF POINTER NO 48    45550016
         SPACE                                                          45600016
*                                                                       45650016
*  CHECK DISPOSITON OF NEW IF NEW CHECK FOR VOLUME AND UNIT             45700016
*                                                                       45750016
         SPACE                                                          45800016
CHEKNEW  CLC   ENEW(TWO),BLANK         IS STATUS NEW                    45850016
         BE    CHEKVOL                 NO GO TO CHECK IF VOLUME SPEC.   45900016
         CLC   EDAPOOL(TWO),BLANK      DIRECT ACCESS POOL SPECIFIED     45950016
         BE    MVCONNEW                NO GO TO MOVE CONSTANT NEW       46000016
         CLC   EVOLSER(SIX),BLANK      WAS VOLUME SERIAL NO. SPECIFIED  46050016
         BNE   VOLERR                  YES GO TO VOLUME AND UNIT ERROR  46100016
         CLC   EUNINFO(SIX),BLANK      WAS UNIT SPECIFIED               46150016
         BE    MOVEDAP                 NO GO TO MOVE DAP VALUE          46200016
         SPACE                                                          46250016
*                                                                       46300016
*  ERROR VOLUME OR UNIT SPECIFIED WITH DIRECT ACCESS POOL               46350016
*                                                                       46400016
         SPACE                                                          46450016
VOLERR   BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    46500016
         DC    AL2(PNTR21)             DISPLACEMENT OF POINTER NO 21    46550016
         SPACE                                                          46600016
*                                                                       46650016
*  MOVE SYSTEM DIRECT ACESS DEVICE TO EXTRACT RECORD. ALSO MOVE         46700016
*  CONSTANTS FOR NEW AND DEVICE TO DIARY WORK AREA AND EXTRACT REC.     46750016
*                                                                       46800016
         SPACE                                                          46850016
MOVEDAP  L     RPAR1,CCTGEND           LOAD ADDR OF SYSGEN DATA         46900016
         MVC   EDISP1(SEVEN),DISP      MOVE CONSTANT DISP=(             46950016
         MVC   EDISTAT(THREE),NEW      MOVE CONSTANT NEW                47000016
         MVC   DSTAT(THREE),NEW        MOVE NEW STATUS TO VIA WORK AREA 47050016
         MVC   EUNIT(SIX),UNIT         MOVE CONSTANT UNIT=              47100016
         MVC   DDEVICE(EIGHT),DAP      MOVE CONSTANT D A POOL TO DIARY  47150016
         MVC   EUNITNM(EIGHT),SYSDAP   MOVE SYSGEN DIRECT ACCESS DEVICE 47200016
         B     CKSYSALL                GO TO CHECK TRACK AND CYLINDERS  47250016
         SPACE                                                          47300016
*                                                                       47350016
*  MOVE CONSTANT NEW AND GO TO CHECK VOLUME AND UNIT                    47400016
*                                                                       47450016
         SPACE                                                          47500016
MVCONNEW MVC   EDISP1(SEVEN),DISP      MOVE CONSTANT DISP=(             47550016
         MVC   EDISTAT(THREE),NEW      MOVE CONSTANT NEW                47600016
         MVC   DSTAT(THREE),NEW        MOVE NEW STATUS TO DIA WORK AREA 47650016
         SPACE                                                          47700016
CHEKVOL  CLC   EVOLSER(SIX),BLANK      WAS VOLUME SERIAL NO. SPECIFIED  47750016
         BNE   SCANVOL                 YES GO TO SCAN VOLUME SERIAL NO. 47800016
         CLC   EUNINFO(SIX),BLANK      WAS UNIT SPECIFIED               47850016
         BNE   CHEKUNIT                YES GO TO CHECK UNIT INFO        47900016
         CLC   EOTHER(SIX),BLANK       DOES OTHER FIELD CONTAIN DATA    47950016
         BE    UNITERR                 NO GO TO UNIT VOLUME ERROR       48000016
         TM    WARNSWT,HEXFF           IS WARNING SWITCH ON             48050016
         BO    NEWSPEC                 YES GO TO CHECK NEW SPECIFIED    48100016
         MVI   WARNSWT,HEXFF           TURN ON WARNING SWITCH           48150016
         SPACE                                                          48200016
*                                                                       48250016
*  ERROR UNIT OR VOLUME NOT SPECIFIED BY OTHER FIELD CONTAINS DATA      48300016
*                                                                       48350016
         SPACE                                                          48400016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    48450016
         DC    AL2(PNTR22)             DISPLACEMENT OF POINTER NO 22    48500016
         SPACE                                                          48550016
*                                                                       48600016
*  ERROR UNIT OR VOLUME WAS NOT SPECIFIED                               48650016
*                                                                       48700016
         SPACE                                                          48750016
UNITERR  CLI   LOCATSW,X'F0'           WAS A LOCATE SUCESSFUL           48770016
         BE    NEWSPEC                 YES GO TO CHECK NEW              48790016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    48810016
         DC    AL2(PNTR23)             DISPLACEMENT OF POINTER NO 23    48850016
         SPACE                                                          48900016
*                                                                       48950016
*  SCAN VOLUME SERIAL NUMBER FOR VALID CHARACTERS                       49000016
*                                                                       49050016
         SPACE                                                          49100016
SCANVOL  LA    FIELDR,EVOLNUM          LOAD ADDR OF VOLUME SER NO.      49150016
         LA    LENGTHR,SIX             LOAD LENGTH OF SIX               49200016
         LA    COUNTR,BLANK            LOAD ADDR OF BLANKS              49250016
         BAL   RRET,SCAN1              BRANCH TO SCAN ROUTINE           49300016
         SPACE                                                          49350016
         CH    RBR,FOUR4               WAS SCAN GOOD                    49400016
         BE    IMBEDBKS                NO IMBEDDED BLANKS GO TO ERR MSG 49450016
         LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         49500016
         LA    LENGTHR,SEVEN           LOAD LENGTH OF SEVEN             49550016
         LA    SCOUNTR,TWO             LOAD COUNT OF TWO                49600016
         BAL   RRET,SCAN3              BRANCH TO SCAN ROUTINE           49650016
         SPACE                                                          49700016
         CH    RBR,FOUR4               WAS SCAN GOOD                    49750016
         BE    SPECHAR                 NO SPECIAL CHAR. GO TO ERR MSG   49800016
         MVC   EVOLUME(TWELVE),VOLUM   MOVE CONSTANT VOLUME=SER=        49850016
         MVC   DVOLUME(SIX),EVOLSER    MOVE VOL SER NO TO DIA WORK AREA 49900016
         CLC   EUNINFO(TWO),BLANK      WAS UNIT SPECIFIED               49950016
         BE    NEWSPEC                 NO GO TO CHECK IF NEW SPECIFIED  50000016
         B     CHEKUNIT                YES GO TO CHECK UNIT INFO        50050016
         SPACE                                                          50100016
*                                                                       50150016
*  ERROR NAME HAS IMBEDDED BLANKS                                       50200016
*                                                                       50250016
         SPACE                                                          50300016
IMBEDBKS BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    50350016
         DC    AL2(PNTR24)             DISPLACEMENT OF POINTER NO 24    50400016
         SPACE                                                          50450016
*                                                                       50500016
*  ERROR SPECIAL CHARACTERS IN NAME                                     50550016
*                                                                       50600016
         SPACE                                                          50650016
SPECHAR  BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    50700016
         DC    AL2(PNTR25)             DISPLACEMENT OF POINTER NO 25    50750016
         SPACE                                                          50800016
*                                                                       50850016
*  SCAN UNIT INFORMATION FOR LENGTH AND VALID CHARACTERS                50900016
*                                                                       50950016
         SPACE                                                          51000016
CHEKUNIT LA    FIELDR,EUNITFLD         LOAD ADDR OF UNIT INFO FIELD     51050016
         LA    LENGTHR,EIGHT           LOAD LENGTH REG WITH EIGHT       51100016
         LA    COUNTR,BLANK            LOAD ADDR OF A BLANK             51150016
         BAL   RRET,SCAN1              BRANCH TO SCAN1                  51200016
         SPACE                                                          51250016
         CH    RBR,FOUR4               WAS SCAN GOOD                    51300016
         BE    IMBLANKS                NO IMBEDDED BLANKS               51350016
         SPACE                                                          51400016
         LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         51450016
         LA    LENGTHR,NINE            LOAD LENGTH REG WITH NINE        51500016
         LA    SCOUNTR,TWO             LOAD SUBFIELD COUNT REG WITH TWO 51550016
         BAL   RRET,SCAN3              BRANCH TO SCAN3                  51600016
         SPACE                                                          51650016
         CH    RBR,FOUR4               WAS SCAN GOOD                    51700016
         BE    CKDASH                  NO GO TO CHECK IF DASH           51750016
         SPACE                                                          51800016
MVUNIT   MVC   EUNIT(SIX),UNIT          MOVE CONSTANT UNIT=             51850016
         MVC   DUNIT(EIGHT),EUNINFO    MOVE UNIT INFO TO DIA WORK AREA  51900016
         MVC   EUNITNM(EIGHT),EUNINFO  MOVE UNIT INFORMATION            51950016
NEWSPEC  CLC   ENEW(TWO),BLANK         WAS NEW SPECIFIED                52000016
         BE    CHEKSTAT                NO GO TO CHECK OTHER STATUS      52050016
         SPACE                                                          52100016
*                                                                       52150016
*  CHECK TRACKS AND CYLINDERS FOR VALID DATA                            52200016
*                                                                       52250016
         SPACE                                                          52300016
CKSYSALL CLC   ESYSALL(TWO),BLANK      HAS SYSTEM ALLOCATE BEEN SPEC.   52350016
         BE    CKTRKS                  NO GO TO CHECK TRACKS            52400016
         CLC   ETRACKS(SIX),BLANK      HAVE TRACKS BEEN SPECIFIED       52450016
         BNE   TRKCYLER                YES GO TO TRACK CYLINDER ERROR   52500016
         CLC   ECYL(SIX),BLANK         HAVE CYLINDERS BEEN SPECIFIED    52550016
         BNE   TRKCYLER                YES GO TO TRACK CYLINDER ERROR   52600016
         SPACE                                                          52650016
         MVC   ESPACE(ONE3),SPACE      MOVE CONSTANT SPACE=(TRK,(       52700016
         L     RPAR1,CCTGEND           LOAD ADDR OF SYSGEN DATA         52750016
         MVC   EVALUE(NINE),SYSALOC    MOVE SYSGEN SYSALLOCATE          52800016
         MVC   EPARENS(TWO),PARENS     MOVE CLOSING PARENS              52850016
         MVC   DSPACE(NINE),ALLOCAT    MOVE CON SYS ALLOC TO DIA WK AR  52900016
         B     MOVECONS                GO TO MOVE CONSTANTS             52950016
         SPACE                                                          53000016
*                                                                       53050016
*  ERROR IMBEDDED BLANKS IN UNIT NAME                                   53100016
*                                                                       53150016
         SPACE                                                          53200016
IMBLANKS BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    53250016
         DC    AL2(PNTR27)             DISPLACEMENT OF POINTER NO 27    53300016
         SPACE                                                          53350016
*                                                                       53400016
*  ERROR SPECIAL CHARACTER IN UNIT NAME                                 53450016
*                                                                       53500016
         SPACE                                                          53550016
*                                                                       53600016
*  CHECK IF CHARACTER IN UNIT NAME IS A DASH                            53650016
*                                                                       53700016
         SPACE                                                          53750016
CKDASH   CLI   ZERO(FIELDR),HEX60      IS CHAR A DASH                   53800016
         BNE   SPECAR                  NO GO TO SPECIAL CHAR            53850016
         TM    ONE(FIELDR),HEXF0       IS CHAR NUMERIC                  53900016
         BO    MVUNIT                  YES GO TO MOVE UNIT CONSTANT     53950016
         SPACE                                                          54000016
SPECAR   BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    54050016
         DC    AL2(PNTR26)             DISPLACEMENT OF POINTER NO 26    54100016
         SPACE                                                          54150016
*                                                                       54200016
*  ERROR TRACKS AND/OR CYLINDERS SPECIFIED WITH SYSTEM ALLOCATE         54250016
*                                                                       54300016
         SPACE                                                          54350016
TRKCYLER BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    54400016
         DC    AL2(PNTR28)             DISPLACEMENT OF POINTER NO 28    54450016
         SPACE                                                          54500016
*                                                                       54550016
*  DETERMINE STATUS AND MOVE KEYWORDS AND CONSTANTS                     54600016
*                                                                       54650016
         SPACE                                                          54700016
CHEKSTAT CLC   EOLD(TWO),BLANK         IS DISPOSITION OLD               54750016
         BNE   MVOLD                   YES GO TO MOVE OLD               54800016
         CLC   EMOD(TWO),BLANK         IS DISPOSITION MOD               54850016
         BNE   MVMOD                   YES GO TO MOVE MOD               54900016
         CLC   ESHR(TWO),BLANK         IS DISPOSITION SHR               54950016
         BE    MOVECONS                NO GO TO MOVE CONSTANTS          55000016
         MVC   EDISP1(SEVEN),DISP      MOVE CONSTANT DISP=(             55050016
         MVC   EDISTAT(THREE),SHR      MOVE CONSTANT SHR                55100016
         MVC   DSTAT(THREE),SHR        MOVE CON SHR TO DIA WORK AREA    55150016
         B     MOVECONS                BRANCH TO MOVE CONSTANTS         55200016
MVOLD    MVC   EDISP1(SEVEN),DISP      MOVE CONSTANT DISP=(             55250016
         MVC   EDISTAT(THREE),OLD      MOVE CONSTANT OLD                55300016
         MVC   DSTAT(THREE),OLD        MOVE CON OLD TO DIA WORK AREA    55350016
         B     MOVECONS                BRANCH TO MOVE CONSTANTS         55400016
MVMOD    MVC   EDISP1(SEVEN),DISP      MOVE CONSTANT DISP=(             55450016
         MVC   EDISTAT(THREE),MOD      MOVE CONSTANT MOD                55500016
         MVC   DSTAT(THREE),MOD        MOVE CON MOD TO DIA WORK AREA    55550016
         B     MOVECONS                BRANCH TO MOVE CONSTANTS         55600016
         SPACE                                                          55650016
*                                                                       55700016
*  CHECK IF TRACKS AND CYLINDERS WERE SPECIFIED                         55750016
*                                                                       55800016
         SPACE                                                          55850016
CKTRKS   CLC   ETRACKS(SIX),BLANK      HAVE TRACKS BEEN SPECIFIED       55900016
         BE    CKCYLS                  NO GO TO CHECK CYLINDERS         55950016
         CLC   ECYL(SIX),BLANK         HAVE CYLINDERS BEEN SPECIFIED    56000016
         BNE   TRKERR                  YES GO TO ERROR                  56050016
         SPACE                                                          56100016
*                                                                       56150016
*  SCAN TRACKS FOR IMBEDDED BLANKS                                      56200016
*                                                                       56250016
         SPACE                                                          56300016
         LA    FIELDR,ETRKFLD          LOAD ADDR OF TRACK FIELD         56350016
         LA    LENGTHR,TRKLGT          LOAD LENGTH REG WITH TRK LENGTH  56400016
         LA    COUNTR,BLANK            LOAD ADDR OF A BLANK             56450016
         BAL   RRET,SCAN1              BRANCH TO SCAN ROUTINE ONE       56500016
         SPACE                                                          56550016
         CH    RBR,FOUR4               WAS SCAN GOOD                    56600016
         BE    IMBBLKS                 NO GO TO IMBEDDED BLANKS         56650016
         SPACE                                                          56700016
*                                                                       56750016
*  SCAN WAS GOOD NOW SCAN FOR VALID DATA                                56800016
*                                                                       56850016
         SPACE                                                          56900016
         SR    SCOUNTR,SCOUNTR         ZERO SUBFIELD COUNT              56950016
         SR    LENGTHR,LENGTHR         ZERO LENGTH REG.                 57000016
         LA    CHARR,FOUR              LOAD FOUR INTO CHAR REG.         57050016
         OI    TRKSWT,HEXFF            TURN ON TRACK SWITCH             57100016
ADD1FLD  LA    FIELDR,ONE(ZERO,FIELDR)  ADD ONE TO FIELD POINTER        57150016
         LA    LENGTHR,ONE(ZERO,LENGTHR) ADD ONE TO LENGTH REG          57200016
         TM    ZERO(FIELDR),HEXF0      IS CHARACTER NUMERIC             57250016
         BO    ADDTOCNT                YES GO TO ADD ONE TO COUNT       57300016
         CLI   ZERO(FIELDR),HEX6B      IS CHARACTER A COMMA             57350016
         BE    ZEROCNT                 YES GO TO ZERO COUNT             57400016
TRKORCYL TM    CYLSWT,HEXFF            IS CYLINDER SWITCH ON            57450016
         BO    CYLERR                  YES GO TO CYLINDER ERROR         57500016
         SPACE                                                          57550016
*                                                                       57600016
*  ERROR SPECIAL CHARACTER OR ALPHA CHARACTER IN TRACK FIELD            57650016
*                                                                       57700016
         SPACE                                                          57750016
         TM    ZERO(FIELDR),HEXC0      IS CHAR ALPHA                    57800016
         BO    TRKALPHA                YES GO TO TRACKS ALPHA CHAR      57850016
         SPACE                                                          57900016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    57950016
         DC    AL2(PNTR29)             DISPLACEMENT OF POINTER NO 29    58000016
         SPACE                                                          58050016
TRKALPHA BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    58100016
         DC    AL2(PNTR45)             DISPLACEMENT OF POINTER NO 45    58150016
         SPACE                                                          58200016
*                                                                       58250016
*  ERROR SPECIAL OR ALPHA CHARACTER IN CYLINDER FIELD                   58300016
*                                                                       58350016
         SPACE                                                          58400016
CYLERR   TM    ZERO(FIELDR),HEXC0      IS CHAR ALPHA                    58450016
         BO    CYLALPHA                YES GO TO CYLINDER ALPHA         58500016
         SPACE                                                          58550016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    58600016
         DC    AL2(PNTR38)             DISPLACEMENT OF POINTER NO 38    58650016
         SPACE                                                          58700016
CYLALPHA BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    58750016
         DC    AL2(PNTR46)             DISPLACEMENT OF POINTER NO 46    58800016
         SPACE                                                          58850016
*                                                                       58900016
*  ERROR TRACK AND CYLINDERS BOTH SPECIFIED                             58950016
*                                                                       59000016
         SPACE                                                          59050016
TRKERR   BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    59100016
         DC    AL2(PNTR30)             DISPLACEMENT OF POINTER NO 30    59150016
         SPACE                                                          59200016
*                                                                       59250016
*  ERROR TRACK FIELD HAS IMBEDDED BLANKS                                59300016
*                                                                       59350016
         SPACE                                                          59400016
IMBBLKS  BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    59450016
         DC    AL2(PNTR31)             DISPLACEMENT OF POINTER NO 31    59500016
         SPACE                                                          59550016
ZEROCNT  SR    SCOUNTR,SCOUNTR         ZERO SUBFIELD COUNT              59600016
         TM    COMASWT,HEXFF           IS COMMA SWITCH ON               59650016
         BO    TSTYPE                  YES GO TO CHECK TYPE             59700016
         MVI   COMASWT,HEXFF           SET COMMA SWITCH ON              59750016
         B     ADD1FLD                 GO TO ADD ONE TO FIELD POINTER   59800016
         SPACE                                                          59850016
TSTYPE   TM    TRKSWT,HEXFF            TRACKS BEING TESTED              59900016
         BO    TRKCOMAS                YES GO TO TRACK COMMA ERROR      59950016
         SPACE                                                          60000016
*                                                                       60050016
*  ERROR MORE THAN ONE COMMA IN CYLINDER FIELD                          60100016
*                                                                       60150016
         SPACE                                                          60200016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSG       60250016
         DC    AL2(PNTR42)             DISPLACEMENT OF POINTER NO 42    60300016
         SPACE                                                          60350016
*                                                                       60400016
*  ERROR MORE THAN ONE COMMA IN TRACK FIELD                             60450016
*                                                                       60500016
         SPACE                                                          60550016
TRKCOMAS BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSG       60600016
         DC    AL2(PNTR43)             DISPLACEMENT OF POINTER NO 43    60650016
         SPACE                                                          60700016
ADDTOCNT LA    SCOUNTR,ONE(ZERO,SCOUNTR) ADD ONE TO SUBFIELD COUNT      60750016
         CR    SCOUNTR,CHARR           SUBFIELD COUNT EQUAL TO CONSTANT 60800016
         BE    LENGTEQ                 YES GO TO CHECK TOTAL LENGTH     60850016
         CH    LENGTHR,LENGTH          IS LENGTH REG EQUAL TO LENGTH    60900016
         BNE   ADD1FLD                 NO GO TO ADD ONE TO FIELD REG    60950016
         SPACE                                                          61000016
TSTTRKCY TM    TRKSWT,HEXFF            IS TRACK SWITCH ON               61050016
         BO    MVTRKS                  YES GO TO MOVE TRACK CONSTANTS   61100016
         MVC   ESPACE(EIGHT),SPACE     MOVE CONSTANT SPACE=(            61150016
         MVC   ETYPE(FIVE),CYL         MOVE CONSTANT CYL,(              61200016
         B     MVNUMIC                 GO TO MOVE NUMERIC VALUE         61250016
         SPACE                                                          61300016
MVTRKS   MVC   ESPACE(ONE3),SPACE      MOVE CONSTANT SPACE=(TRK,(       61350016
         MVC   EVALUE(NINE),ETRACKS    MOVE NUMERIC VALUE FOR TRACKS    61400016
         MVC   DSPACE(NINE),ETRACKS    MOVE TRACK ALLOCATE TO DIA WK AR 61450016
         LA    RPAR1,EVALUE(LENGTHR)   LOAD ADDR FOR CONSTANT ))        61500016
         MVC   ZERO(TWO,RPAR1),PARENS  MOVE CONSTANT ))                 61550016
         B     MOVECONS                GO TO MOVE CONSTANTS             61600016
         SPACE                                                          61650016
MVNUMIC  MVC   EVALUE(SEVEN),ECYL      MOVE NUMERIC VALUE FOR CYLINDERS 61700016
         MVC   DSPACE(SEVEN),ECYL      MOVE CYL ALLOCATE TO DIA WK AREA 61750016
         LA    RPAR1,EVALUE(LENGTHR)   LOAD ADDR FOR CONSTANT ))        61800016
         MVC   ZERO(TWO,RPAR1),PARENS  MOVE CONSTANT ))                 61850016
         B     MOVECONS                GO TO MOVE CONSTANTS             61900016
         SPACE                                                          61950016
*                                                                       62000016
*  WAS CYLINDER OR OTHER SPECIFIED                                      62050016
*                                                                       62100016
         SPACE                                                          62150016
CKCYLS   CLC   ECYL(SIX),BLANK         WAS CYLINDERS SPECIFIED          62200016
         BNE   LDCYLFLD                YES GO TO LOAD CYLINDER FIELD    62250016
         CLC   EOTHER(SIX),BLANK       DOES OTHER FIELD CONTAIN DATA    62300016
         BNE   CKWARSWT                YES GO TO CHECK WARNING SWITCH   62350016
         SPACE                                                          62400016
*                                                                       62450016
*  ERROR NO SPACE HAS BEEN ALLOCATED                                    62500016
*                                                                       62550016
         SPACE                                                          62600016
         TM    WARNSWT3,HEXFF          IS NO SPACE WARNING SWITCH ON    62610016
         BO    MOVECONS                YES GO TO MOVE CONSTANTS         62620016
         OI    WARNSWT3,HEXFF          SET NO SPACE SWITCH ON           62630016
         SPACE                                                          62640016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    62650016
         DC    AL2(PNTR32)             DISPLACEMENT OF POINTER NO 32    62700016
         SPACE                                                          62750016
*                                                                       62800016
*  LOAD ADDRESS OF CYLINDER FIELD AND SCAN FOR VALID CHARACTERS         62850016
*                                                                       62900016
         SPACE                                                          62950016
LDCYLFLD LA    FIELDR,ECYLFLD          LOAD ADDR OF CYLINDER FIELD      63000016
         LA    LENGTHR,CYLLGT          LOAD LENGTH REG WITH CYL  ENGTH  63050016
         LA    COUNTR,BLANK            LOAD ADDR OF A BLANK             63100016
         BAL   RRET,SCAN1              BRANCH TO SCAN1 ROUTINE          63150016
         SPACE                                                          63200016
         CH    RBR,FOUR4               WAS SCAN GOOD                    63250016
         BE    IMBLNKS                 NO IMBEDDED BLANKS               63300016
         SR    SCOUNTR,SCOUNTR         ZERO SUBFIELD COUNT REG          63350016
         SR    LENGTHR,LENGTHR         ZERO LENGTH REG                  63400016
         LA    CHARR,THREE             LOAD CHARACTER REG WITH 3        63450016
         OI    CYLSWT,HEXFF            SET CYLINDER SWITCH ON           63500016
         B     ADD1FLD                                                  63550016
         SPACE                                                          63600016
*                                                                       63650016
*  CHECK WARNING SWITCH IF ON GO TO MOVE CONSTANTS. IF NOT ON DISPLAY   63700016
*   WARNING MESSAGE                                                     63750016
*                                                                       63800016
         SPACE                                                          63850016
CKWARSWT TM    WARNSWT2,HEXFF          IS WARNING SWITCH ON             63900016
         BO    MOVECONS                YES GO TO MOVE CONSTANTS         63950016
         OI    WARNSWT2,HEXFF          SET WARNING SWITCH ON            64000016
         SPACE                                                          64050016
*                                                                       64100016
*  WARING MESSAGE TRACKS AND CYLINDERS NOT SPECIFIED                    64150016
*                                                                       64200016
         SPACE                                                          64250016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    64300016
         DC    AL2(PNTR33)             DISPLACEMENT OF POINTER NO 33    64350016
         SPACE                                                          64400016
LENGTEQ  CH    LENGTHR,LENGTH          IS LENGTH REG EQUAL TO LENGTH    64450016
         BE    TSTTRKCY                YES GO TO TEST TRACKS AND CYL'S  64500016
         SPACE                                                          64550016
ADTOFLD  LA    FIELDR,ONE(ZERO,FIELDR) ADD ONE TO FIELD POINTER         64600016
         LA    LENGTHR,ONE(ZERO,LENGTHR)  ADD ONE TO COUNT              64650016
         CLI   ZERO(FIELDR),HEX6B      IS CHARACTER A COMMA             64700016
         BE    COMPLGT                                                  64750016
         TM    ZERO(FIELDR),HEXF0      IS CHAR NUMERIC                  64760016
         BM    TRKORCYL                NO GO TO SPECIAL OR ALPHA CHAR   64780016
         TM    CYLSWT,HEXFF            IS CYLINDER SWITCH ON            64800016
         BO    CYLTOLON                YES GO TO CYLINDER TO LONG       64850016
         SPACE                                                          64900016
*                                                                       64950016
*  ERROR SUBFIELD WITHIN TRACK FIELD TO LONG                            65000016
*                                                                       65050016
         SPACE                                                          65100016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    65150016
         DC    AL2(PNTR34)             DISPLACEMENT OF POINTER NO 34    65200016
         SPACE                                                          65250016
*                                                                       65300016
*  ERROR CYLINDER SUBFIELD TO LONG                                      65350016
*                                                                       65400016
         SPACE                                                          65450016
CYLTOLON BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    65500016
         DC    AL2(PNTR39)             DISPLACEMENT OF POINTER NO 39    65550016
         SPACE                                                          65600016
COMPLGT  CH    LENGTHR,LENGTH                                           65650016
         BE    ILLCHAR                                                  65700016
         SR    SCOUNTR,SCOUNTR                                          65750016
         MVI   COMASWT,HEXFF           SET COMMA SWITCH ON              65770016
         B     ADD1FLD                                                  65800016
ILLCHAR  TM    CYLSWT,HEXFF            IS CYLINDER SWITCH ON            65850016
         BO    CYLINVAL                YES GO TO CYLINDER LAST CHAR INV 65900016
         SPACE                                                          65950016
*                                                                       66000016
*  ERROR FIELD END WITH AN INVALID CHARACTER                            66050016
*                                                                       66100016
         SPACE                                                          66150016
         BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    66200016
         DC    AL2(PNTR35)             DISPLACEMENT OF POINTER NO 35    66250016
         SPACE                                                          66300016
*                                                                       66350016
*  ERROR CYLINDER FIELD HAS IMBEDDED BLANKS                             66400016
*                                                                       66450016
         SPACE                                                          66500016
IMBLNKS  BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    66550016
         DC    AL2(PNTR36)             DISPLACEMENT OF POINTER NO 36    66600016
         SPACE                                                          66650016
*                                                                       66700016
*  ERROR LAST CHARACTER IN CYLINDER INVALID                             66750016
*                                                                       66800016
         SPACE                                                          66850016
CYLINVAL BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSG       66900016
         DC    AL2(PNTR40)             DISPLACEMENT OF POINTER NO 40    66950016
         SPACE                                                          67000016
*                                                                       67050016
*  MOVE REMAINING CONSTANTS TO EXTRACT RECORD AND GO TO DIARY ROUTINE   67100016
*                                                                       67150016
         SPACE                                                          67200016
MOVECONS CLI   PLUSGEN,HEXFF           IS NEW GENERATION SWITCH ON      67250016
         BNE   DISPASS                 NO TO TO CHECK PASS              67300016
         CLC   ECAT(TWO),BLANK         IS DISPOSITION CATALOG           67350016
         BNE   MVCATLG                 YES GO TO MOVE CATALOG           67400016
         B     CATERR                                                   67450016
         SPACE                                                          67500016
DISPASS  CLC   EPASS(TWO),BLANK        IS DISPOSITION PASS              67550016
         BE    DISDELET                NO GO TO CHECK DELETE            67600016
         MVC   EDISP2(SIX),PASS        MOVE CONSTANT ,PASS)             67650016
         MVC   DDISPO(FOUR),PASS+ONE   MOVE CON PASS TO DIA WORK  AREA  67700016
         B     TODIA                   GO TO DIARY ROUTINE              67750016
         SPACE                                                          67800016
DISDELET CLC   EDELETE(TWO),BLANK      IS DISPOSITION DELETE            67850016
         BE    DISCATLG                NO GO TO CHECK CATALOG           67900016
         MVC   EDISP2(EIGHT),DELETE    MOVE CONSTANT ,DELETE)           67950016
         MVC   DDISPO(SIX),DELETE+ONE  MOVE CON DELETE TO DIA WK AREA   68000016
         B     TODIA                   GO TO DIARY ROUTINE              68050016
         SPACE                                                          68100016
DISCATLG CLC   ECAT(TWO),BLANK         IS DISPOSITION CATALOG           68150016
         BE    DISKEEP                 NO GO TO CHECK KEEP              68200016
MVCATLG  MVC   EDISP2(SEVEN),CATLG     MOVE CONSTANT ,CATLG)            68250016
         MVC   DDISPO(FIVE),CATLG+ONE  MOVE CON CATLG TO DIA WORK AREA  68300016
         B     TODIA                   GO TO DIARY ROUTINE              68350016
         SPACE                                                          68400016
DISKEEP  CLC   EKEEP(TWO),BLANK        IS DISPOSITION KEEP              68450016
         BE    MOVPAREN                NO GO TO MOVE PAREN              68500016
         MVC   EDISP2(SIX),KEEP        MOVE CONSTANT ,KEEP)             68550016
         MVC   DDISPO(FOUR),KEEP+ONE   MOVE CONSTANT KEEP TO DIARY      68600016
         B     TODIA                   GO TO DIARY ROUTINE              68650016
         SPACE                                                          68700016
MOVPAREN MVC   EDISP2(ONE),PARENS      MOVE CLOSING PAREN               68750016
         B     TODIA                   GO TO DIARY ROUTINE              68770016
         SPACE                                                          68800016
*                                                                       68850016
*  ERROR NEW GENERATION WAS INDICATED WITHOUT CATALOG DISPOSITION       68900016
*                                                                       68950016
         SPACE                                                          69000016
CATERR   BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    69050016
         DC    AL2(PNTR49)             DISPLACEMENT OF POINTER NO 49    69100016
         SPACE                                                          69150016
*                                                                       69200016
*  MOVE CONSTANT DES AND 117 BYTES OF DATA TO RECORD WORK AREA          69250016
*                                                                       69300016
         SPACE                                                          69350016
TODIA    MVC   LABELCON(EIGHT),DSCON   MOVE CONSTANT TO DIARY ROUTINE   69400016
         MVC   DOTHER(FIVE0),EOTHER    MOVE 1O BYTES OF OTHER           69450016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT                 69500016
         L     RBR,CCTDIARP            LOAD ADDR OF DIARY ROUTINE       69550016
         O     RPAR1,HIGH4             OR A HIGH ORDER FOUR INTO RPAR1  69570016
         BALR  RRET,RBR                BRANCH TO DIARY ROUTINE          69600016
         SPACE                                                          69610017
         CH    RBR,INTERR              IS RETURN CODE 1C           GJPF 69620017
         BE    ERORTN                  YES GO TO ERROR RETURN      GJPF 69630017
         SPACE                                                          69650016
*                                                                       69700016
*  SET UP AND BRANCH TO JCL GENERATOR WITH OUTPUT                       69750016
*                                                                       69800016
         SPACE                                                          69850016
         TM    DATASWT,HEXFF           IS DATA SWITCH ON                69900016
         BO    TSTOTHR                 YES GO TO TEST OTHER FIELD       69950016
         CLI   EDISP1,HEX40            IS THERE A DISPOSITION           70000016
         BNE   BLKCOMMA                YES GO TO BLANK COMMA            70050016
         CLC   EOTHER(EIGHT),BLANK     DOES OTHER FIELD CONTAIN DATA    70100016
         BNE   MVDELIM                 YES GO TO MOVE DELIMETERS        70150016
         CLI   ESYSOUT,HEX40           DOES SYSOUT CONTAIN DATA         70200016
         BNE   SYSCOMMA                YES GO TO BLANK COMMA            70250016
         B     MVDELIM                 GO TO MOVE DELIMETERS            70300016
         SPACE                                                          70350016
BLKCOMMA MVI   EDISP1,HEX40            MOVE A BLANK                     70400016
         B     TSTOTHR                 GO TO TEST OTHER                 70450016
         SPACE                                                          70500016
SYSCOMMA MVI   ESYSOUT,HEX40           MOVE A BLANK                     70550016
         B     TOJCL                   GO TO JCL GENERATOR              70600016
         SPACE                                                          70650016
TSTOTHR  CLC   EOTHER(EIGHT),BLANK     DOES OTHER CONTAIN INFO          70700016
         BE    MVDELIM                 NO GO TO MOVE DELIMETER          70750016
         MVI   ECOMMA,HEX25                                             70800016
MVDELIM  MVC   EDELIM(TWO),CLASS       MOVE CLOSING DELIMETERS          70850016
         SPACE                                                          70900016
TOJCL    LR    RPAR1,CCTR              LOAD ADDR OF CCT                 70950016
         L     RBR,CCTJCLGP            LOAD ADDR OF JCL GENERATOR       71000016
         BALR  RRET,RBR                BRANCH TO JCL GENERATOR          71050016
         SPACE                                                          71100016
         CH    RBR,INTERR              IS RETURN CODE 1C           GJPF 71200017
         BE    ERORTN                  YES GO TO ERROR RETURN      GJPF 71300017
         B     NORMRET                 BRANCH TO NORMAL RETURN     GJPF 71400017
         SPACE                                                          71650016
*                                                                       71700016
*  SYSOUT SWITCH WAS ON CHECK OTHER FIELD TO INSURE NO DATA WAS ENTERED 71750016
*                                                                       71800016
         SPACE                                                          71850016
CHKDISPO CLC   ECATED(TEN),BLANK       WAS ANY STATUS PICKED            71900016
         BNE   SYSOUTER                YES GO TO SYSOUT ERROR           71950016
         CLC   ESYSALL(FOUR),BLANK     WAS DAP OR SA PICKED             72000016
         BNE   SYSOUTER                YES GO TO SYSOUT ERROR           72050016
         CLC   EDSNAME(SIX),BLANK      IS DSNAME FIELD BLANK            72100016
         BNE   BASTERIC                NO GO TO CHECK ASTERICK SWITCH   72150016
BVOL     CLC   EVOLSER(SIX),BLANK      IS VOLUME SERIAL NUMBER BLANK    72200016
         BNE   SYSOUTER                NO GO TO SYSOUT ERROR            72250016
         CLC   EUNINFO(SIX),BLANK      IS UNIT BLANK                    72300016
         BNE   SYSOUTER                NO GO TO SYSOUT ERROR            72350016
         CLC   ETRACKS(SIX),BLANK      IS TRACKS BLANK                  72400016
         BNE   SYSOUTER                NO GO TO SYSOUT ERROR            72450016
         CLC   ECYL(SIX),BLANK         IS CYLINDER BLANK                72500016
         BNE   SYSOUTER                NO GO TO SYSOUT ERROR            72550016
         SPACE                                                          72600016
         TM    ASTSWT,HEXFF            IS ASTERISK SWITCH ON            72650016
         BO    TSTOTHER                YES GO TO CHECK OTHER            72700016
         CLC   EKEEP(EIGHT),BLANK      IS KEEP,PASS,DELETE,CATLG BLANK  72750016
         BNE   MORDISP                 NO GO TO MORE THAN ONE DISPOST   72800016
         CLC   EPRINT(TWO),BLANK       IS PRINT BLANK                   72850016
         BNE   CKPUNCH                 NO GO TO CHECK PUNCH             72900016
         CLC   EPUNCH(TWO),BLANK        Q. PUNCH BLANK             IIXX 72907018
         BE    TODIA                    YES, TO DIARY ROUTINE      IIXX 72914018
         TM    CCTPSTAT,X'10'           Q. BACKGROUND JOB          IIXX 72921018
         BO    TODIA                    YES, NO MORE TESTS         IIXX 72928018
         CLC   EDISPLAY(TWO),BLANK      Q. DISPLAY BLANK           IIXX 72935018
         BNE   PUNDSPER                 NO, PUNCH OF DISPLAY ERROR IIXX 72942018
         B     TODIA                   GO TO DIARY ROUTINE              72950016
         SPACE                                                          73000016
CKPUNCH  CLC   EPUNCH(TWO),BLANK       IS PUNCH BLANK                   73050016
         BNE   PRTPUNER                NO GO TO PRINT PUNCH ERROR       73100016
         TM    CCTPSTAT,X'10'           Q. BACKGROUND JOB          IIXX 73110018
         BO    TODIA                    YES, NO MORE TESTS         IIXX 73120018
         CLC   EDISPLAY(TWO),BLANK      Q. DISPLAY BLANK           IIXX 73130018
         BNE   PRTDSPER                 NO, PRINT OR DISPLAY ERROR IIXX 73140018
         B     TODIA                   GO TO DIARY ROUTINE              73150016
BASTERIC TM    ASTSWT,HEXFF            IS ASTERICK SWITCH ON            73200016
         BO    BVOL                    YES GO TO CHECK VOLUME           73250016
         SPACE                                                          73300016
*                                                                       73350016
*  ERROR FIELDS OTHER THAN DATA LABEL CONTAIN DATA                      73400016
*                                                                       73450016
         SPACE                                                          73500016
SYSOUTER BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    73550016
         DC    AL2(PNTR37)             DISPLACEMENT OF POINTER NO 37    73600016
         SPACE                                                          73650016
*                                                                       73700016
*  ERROR PRINT AND PUNCH BOTH SPECIFIED                                 73750016
*                                                                       73800016
         SPACE                                                          73850016
PRTPUNER BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSOB    73900016
         DC    AL2(PNTR44)             DISPLACEMENT OF POINTER NO 44    73950016
         SPACE                                                          74000016
*                                                                       74050016
*  ASTERISK SWITCH ON CHECK OTHER FIELD AND DISPOSITION                 74100016
*                                                                       74150016
         SPACE                                                          74200016
TSTOTHER CLC   EOTHER(ONE6),BLANK                                       74250016
         BNE   ASTERR                                                   74300016
         CLC   EKEEP(ONE4),BLANK       WAS ANY DISPOSITION PICKED       74350016
         BNE   ASTERR                  YES GO TO ASTERISK ERROR         74400016
         B     TODIA                                                    74450016
         SPACE                                                          74500016
*                                                                       74550016
*  ERROR FIELDS OTHER THAN DATA REFERENCE CONTAIN DATA                  74600016
*                                                                       74650016
         SPACE                                                          74700016
ASTERR   BAL   PARMR,MSGSUB            LOAD REG AND BRANCH TO MSGSUB    74750016
         DC    AL2(PNTR47)             DISPLACEMENT OF POINTER NO 47    74800016
         SPACE 1                                                   IIXX 74803018
*                                                                  IIXX 74806018
*  ERROR PRINT AND DISPLAY BOTH SPECIFIED                          IIXX 74809018
*                                                                  IIXX 74812018
         SPACE 1                                                   IIXX 74815018
PRTDSPER BAL   PARMR,MSGSUB             GO TO MSGSUB WITH PNTR     IIXX 74818018
         DC    AL2(PNTR52)              PRINT OR DISPLAY           IIXX 74821018
         SPACE 1                                                   IIXX 74824018
*                                                                  IIXX 74827018
*  ERROR PUNCH AND DISPLAY BOTH SPECIFIED                          IIXX 74830018
*                                                                  IIXX 74833018
         SPACE 1                                                   IIXX 74836018
PUNDSPER BAL   PARMR,MSGSUB             GO TO MSGSUB WITH PNTR     IIXX 74839018
         DC    AL2(PNTR53)              PUNCH OR DISPLAY           IIXX 74842018
         EJECT                                                          74850016
*                                                                       74900016
*  EXIT ROUTINE FREE AQUIRED STORAGE LOAD RETURN CODE AND RETURN        74950016
*                                                                       75000016
         SPACE                                                          75050016
EXIT     LH    RBR,CANCODE              LOAD CANCEL RETURN CODE         75060016
         B     RETURN                   BRANCH TO RETURN                75070016
ERORTN   LH    RBR,INTERR              LOAD ERROR RETURN CODE      GJPF 75073017
         B     RETURN                  BRANCH TO RETURN            GJPF 75076017
RECRET   LH    RBR,ERRCODE              LOAD ERROR RETURN CODE          75080016
         B     RETURN                   BRANCH TO RETURN                75090016
NORMRET  LH    RBR,NORMCODE             LOAD NORMAL RETURN CODE         75100016
RETURN   LR    DIAR,RBR                 SAVE RETURN CODE                75110016
         XC    CCTPECB(FOUR),CCTPECB   CLEAR PROCESSOR ECB              75120016
         NC    IGNORBIT(ONE),IGNOROFF  TURN OF IGNORE ATTN BIT          75150016
         FREEMAIN R,LV=GETEND-LENGTH,A=(4)                              75200016
         LR    RBR,DIAR                 LOAD SAVED RETURN CODE          75250016
         L     RSAVE,SAVE13            LOAD ADDR OF SAVE AREA           75300016
         RETURN (14,12),RC=(15)                                         75350016
         EJECT                                                          75400016
*                                                                       75450016
*  SCAN ONE SUBROUTINE                                                  75500016
*                                                                       75550016
         SPACE                                                          75600016
SCAN1    LA    CHARR,ZERO(LENGTHR,FIELDR) TOTAL DISPLACEMENT            75650016
         CLC   ZERO(ONE,CHARR),BLANK      IS CHAR A BLANK               75700016
         BNE   STLENGTH                   NO GO TO STORE LENGTH         75750016
         BCT   LENGTHR,SCAN1              SUBTRACT ONE FROM LENGTH AND  75800016
         LA    RBR,EIGHT                  LENGTH IS ZERO LOAD RETURN    75850016
*                                      CODE OF EIGHT                    75900016
         BR    RRET                       RETURN VIA REG 14             75950016
         SPACE                                                          76000016
STLENGTH STH   LENGTHR,LENGTH             STORE LENGTH OF DATA          76050016
TOTDISPL LA    CHARR,ZERO(LENGTHR,FIELDR)  TOTAL DISPLACEMENT           76100016
         CLC   ZERO(ONE,CHARR),BLANK      IS CHAR A BLANK               76150016
         BE    BLNKERR                    YES GO TO IMBEDDED BLANK RET  76200016
         BCT   LENGTHR,TOTDISPL           SUBTRACT ONE FROM LENGTH AND  76250016
         LA    RBR,ZERO                GOOD SCAN LOAD RETURN CODE OF 0  76300016
         BR    RRET                       RETURN VIA REG 14             76350016
BLNKERR  LA    RBR,FOUR                   LOAD RETURN CODE OF 04        76400016
         BR    RRET                    RETURN VIA REG 14                76450016
         EJECT                                                          76500016
*                                                                       76550016
*  SCAN TWO AND SCAN THREE SUBROUTINE                                   76600016
*                                                                       76650016
         SPACE                                                          76700016
SCAN2    LA    SCOUNTR,ONE             LOAD SUBFIELD COUNT REG WITH ONE 76750016
SCAN3    TM    ZERO(FIELDR),HEXC0      DOES CHAR HAVE 2 HIGH ORDER BITS 76800016
         BO    TSTNUM                  YES GO TO CHECK NEXT TWO         76850016
         CLI   ZERO(FIELDR),HEX5B      IS CHAR A $ SIGN                 76900016
         BE    FRSTCHAR                YES GO TO CHECK IF FIRST CHAR    76950016
         CLI   ZERO(FIELDR),HEX7B      IS CHAR A # SIGN                 77000016
         BE    FRSTCHAR                YES GO TO CHECK IF FIRST CHAR    77050016
         CLI   ZERO(FIELDR),HEX7C      IS CHAR A @ SIGN                 77100016
         BE    FRSTCHAR                YES GO TO CHECK IF FIRST CHAR    77150016
         CLC   ZERO(ONE,FIELDR),BLANK  IS CHARACTER A BLANK             77200016
         BNE   COMPONE                 NO GO TO COMPARE TO ONE          77250016
         BCT   SCOUNTR,GOODSCAN        SUBTRACT ONE FROM SUB COUNT      77300016
COMPONE  CH    SCOUNTR,ONE1            IS BUBFIELD COUNT MORE THAN ONE  77350016
         BH    MORTHAN1                YES BRANCH TO MORE THAN ONE      77400016
         LA    RBR,EIGHT               LOAD RETURN CODE OF 08           77450016
         BR    RRET                    RETURN VIA REG 14                77500016
MORTHAN1 LA    RBR,FOUR                LOAD RETURN CODE OF 04           77550016
         BR    RRET                    RETURN VIA REG 14                77600016
TSTNUM   TM    ZERO(FIELDR),HEX30      DOES CHAR HAVE THIRD AND         77650016
*                                      FOURTH HIGH ORDER BITS ON        77700016
         BO    FRSTCHAR                YES GO TO CHECK FIRST CHAR       77750016
MAXLENGT CR    LENGTHR,SCOUNTR         LENGTR REG EQUAL TO SUBFIELD REG 77800016
         BE    GOODSCAN                YES GO TO GOOD SCAN              77850016
         LA    FIELDR,ONE(ZERO,FIELDR)    ADD ONE TO FIELD POINTER      77900016
         LA    SCOUNTR,ONE(ZERO,SCOUNTR)  ADD ONE TO SUBFIELD COUNT     77950016
         B     SCAN3                                                    78000016
FRSTCHAR CH    SCOUNTR,ONE1            DOES SUBFIELD COUNT REG HAVE ONE 78050016
         BH    MAXLENGT                NO GO TO CHECK MAXIMUM LENGTH    78100016
         LA    RBR,TWELVE              LOAD RETURN CODE OF 12           78150016
         BR    RRET                    RETURN TO MAIN ROUTINE           78200016
         SPACE                                                          78250016
GOODSCAN LA    RBR,ZERO                LOAD RETURN CODE OF ZERO         78300016
         BR    RRET                    RETURN TO MAIN ROUTINE           78350016
         EJECT                                                          78400016
*                                                                       78450016
*  MESSAGE SUBROUTINE TO PASS PARAMETERS TO MSG ROUTINE                 78500016
*                                                                       78550016
         SPACE                                                          78600016
MSGSUB   TM    CCTPSTAT,RECXCEPT        IS STATUS RECALL ACCEPT MODE    78620016
         BO    RECRET                   YES RETURN                      78640016
         LH    PARMR,ZERO(PARMR)        LOAD DISPLACEMENT               78660016
         A     PARMR,LISTPNTR          A BEGINNING OF LIST              78700016
         L     PARMR,ZERO(PARMR)       LOAD ADDR OF PARAMETER LIST      78750016
         LA    LENGTHR,ONE(ZERO,LENGTHR)  ADD ONE TO LENGTH OF MOVE     78800016
         SR    FIELDR,SCOUNTR          SUBTRACT NO OF CHARS FROM PNTR   78850016
         LA    MSGR,MSGADDR            LOAD ADDR OF AREA TO MOVE MSG TO 78900016
         LA    LISTR,MSGPARM           LOAD ADDR OF AREA TO MOVE PARMS  78950016
         SPACE                                                          79000016
TESTFF   CLI   ZERO(PARMR),HEXFF       IS FIRST BYTE F'S                79050016
         BNE   STRPARM                 NO GO TO STORE PARAMETER         79100016
         L     STORR,FOUR(PARMR)       LOAD NEXT WORD                   79150016
         SR    MOVER,MOVER             ZERO MOVE REGISTER               79200016
         IC    MOVER,ZERO(STORR)       INSERT LENGTH OF MOVE            79250016
         BCT   MOVER,EX1               SUBTRACT ONE FROM LENGTH OF MOVE 79300016
EX1      EX    MOVER,MOVE1             EXECUTE MOVE INSTRUCTION         79350016
         LA    PNTR,FOUR(MOVER,MSGR)   LOAD ADDR OF END OF MOVE + THREE 79400016
         CLI   ONE(PARMR),HEXFF                                         79450016
         BE    MVBADFLD                                                 79500016
         SPACE                                                          79550016
         LH    STORR,TWO(PARMR)        LOAD EXTRACT DISPLACEMENT        79600016
         LA    STORR,CCTPWKA(STORR)    LOAD ADDR OF DATA TO BE MOVED    79650016
         SR    MOVER,MOVER             ZERO MOVE REGISTER               79700016
         IC    MOVER,ONE(PARMR)        INSERT LENGTH OF DATA TO BE MVD  79750016
         BCT   MOVER,EX2               SUBTRACT ONE FROM LENGTH OF MOVE 79800016
EX2      EX    MOVER,MOVE2             EXECUTE MOVE INSTRUCTION         79850016
MVLENGTH MVC   MSGADDR(ONE),LENGTCON   MOVE LENGTH OF LINE              79900016
         ST    MSGR,ZERO(LISTR)        STORE MESSAGE ADDR               79950016
         MVC   ZERO(ONE,LISTR),FOUR(PARMR)  MOVE CODE FOR MESSAGE       80000016
         LA    PARMR,EIGHT(PARMR)      MOVE POINTER TO NEXT PARAMETER   80050016
         L     STORR,ZERO(LISTR)       LOAD PARAMETER INTO STORE REG    80100016
         B     TESTLAST                BRANCH TO TEST FOR LAST PARM     80150016
         SPACE                                                          80200016
MVBADFLD EX    LENGTHR,MOVE3                                            80250016
         B     MVLENGTH                                                 80300016
         SPACE                                                          80350016
STRPARM  L     STORR,ZERO(PARMR)       LOAD PARAMETER INTO STORE REG    80400016
         LA    PARMR,FOUR(PARMR)       MOVE POINTER                     80450016
TESTLAST LTR   STORR,STORR             IS THIS LAST PARAMETER           80500016
         ST    STORR,ZERO(LISTR)       STORE PARAMETER                  80550016
         BC    TEN,MOVEPT              NOT LAST PARAMETER               80600016
         SPACE                                                          80650016
         LA    RPAR0,MSGPARM            LOAD ADDR OF PARAMETER LIST     80700016
         LR    RPAR1,CCTR              LOAD ADDR OF CCT INTO REG.1      80750016
         L     RBR,CCTDMRP             LOAD ADDR OF DMSG INTO REG.15    80800016
         SPACE                                                          80900016
         XC    CCTPECB(FOUR),CCTPECB   CLEAR PROCESSOR ECB              80950016
         BALR  RRET,RBR                 BRANCH TO DISPLAY MSG ROUTINE S 80970016
         CH    RBR,INTERR              IS RETURN CODE 1C           GJPF 80980017
         BE    ERORTN                  YES GO TO ERROR RETURN      GJPF 80990017
         NC    IGNORBIT(ONE),IGNOROFF  TURN OFF IGNORE ATTN BIT         81000016
         XC    ZERO(CLRWKA,GETR),ZERO(GETR)  CLEAR WORK AREA            81050016
         B     WAITECB                 BRANCH TO WAIT                   81100016
         SPACE                                                          81150016
MOVEPT   LA    LISTR,FOUR(LISTR)       MOVE POINTER TO PARAMETER LIST   81200016
         B     TESTFF                                                   81250016
         SPACE                                                          81300016
MOVE1    MVC   ZERO(ZERO,MSGR),ZERO(STORR)  MOVE FOR EXECUTE INST       81350016
MOVE2    MVC   ZERO(ZERO,PNTR),ZERO(STORR)  MOVE FOR EXECUTE INST       81400016
MOVE3    MVC   ZERO(ZERO,PNTR),ZERO(FIELDR)  MOVE FOR MVBADFLD EX INST  81450016
         EJECT                                                          81451016
*                                                                       81452016
*  BUILD LIST FOR LOCATE MACRO                                          81453016
*                                                                       81454016
         SPACE                                                          81455016
TOLOCATE MVC   LOCLIST(FOUR),LOCFLGS   MOVE INDICATOR FLAGS TO PARM LST 81456016
         LA    COUNTR,LOCNAME          LOAD ADDR OF NAME                81457016
         ST    COUNTR,LOCDATA          STORE ADDR IN PARM LIST          81458016
         LA    COUNTR,LOCWORK          LOAD ADDR OF WORK AREA           81459016
         ST    COUNTR,LOCAREA          STORE ADDR IN PARM LIST          81460016
         LA    COUNTR,EDSNAME          LOAD ADDR OD DSNAME         GJPF 81460117
         SR    PARMR,PARMR             ZERO COUNT REG              GJPF 81460217
         LA    CHARR,DSNMLGT           LOAD LENGTH OF FIELD        GJPF 81460317
         MVI   LOCNAME,C' '            MOVE A BLANK TO NAME AREA   GJPF 81460417
         MVC   LOCNAME+ONE(43),LOCNAME CLEAR AREA TO BLANKS        GJPF 81460517
COMPREN  CLI   ZERO(COUNTR),C'('       COMPARE CHAR TO RIGHT PAREN GJPF 81460617
         BE    TSTNXT                  IF EQUAL GO TEST NEXT CHAR  GJPF 81460717
         LA    COUNTR,ONE(COUNTR)      ADD ONE TO POINTER          GJPF 81460817
         LA    PARMR,ONE(PARMR)        ADD ONE TO COUNT            GJPF 81460917
         CR    PARMR,CHARR             IS COUNT EQUAL TO LENGTH    GJPF 81461017
         BL    COMPREN                 LOW GO TO COMPARE NEXT CHAR GJPF 81461117
         SPACE                                                          81461217
TSTNXT   CLI   ONE(COUNTR),C'-'        IS CHAR A MINUS             GJPF 81461317
         BE    LDLGT                   YES GO TO LOAD FULL LENGTH  GJPF 81461417
         CLI   ONE(COUNTR),C'+'        IS CHAR A PLUS              GJPF 81461517
         BE    LDLGT                   YES GO TO LOAD FULL LENGTH  GJPF 81461617
         CLI   ONE(COUNTR),C'0'        IS CHAR A ZERO              GJPF 81461717
         BNE   EXMVC                   NO GO TO EXECUTE MOVE       GJPF 81461817
         SPACE                                                          81461917
LDLGT    LR    PARMR,CHARR             LOAD LENGTH OF FIELD        GJPF 81462017
EXMVC    BCTR  PARMR,ZERO              SUBTRACT ONE FROM COUNT     GJPF 81462117
         EX    PARMR,MVCDSNM           EXECUTE MOVE INSTRUCTION    GJPF 81462217
         SPACE                                                          81462317
         LOCATE  LOCLIST               ISSUE LOCATE MACRO               81463016
         SPACE                                                          81464016
         CH    RBR,NORMCODE            WAS DATA SET FOUND               81465016
         BE    RESETSW                 YES GO TO RESET LOCATE SWITCH    81466016
         SPACE                                                          81467016
         CLC   ECATED(TWO),BLANK       WAS CATALOGED INDICATED          81468016
         BNE   CTLGERR                 YES GO TO CATALOG ERROR          81469016
         TM    OVLYSWT,HEXFF           IS OVERLAY UP                    81470016
         BO    CTLGERR                 YES GO TO CATALOG ERROR          81471016
         TM    CCTPSTAT,RECXCEPT       IS STATUS RECALL EXCEPT MODE     81472016
         BO    RECRET                  YES GO TO RECALL RETURN          81473016
         MVI   OVLYSWT,HEXFF           TURN ON OVERLAY SWITCH           81474016
         TM    CCTSSTAT,32             Q. REMOTE GRAPHIC DEVICE    GJPF 81474317
         BO    CTLGERR                 YES - DISPLAY IS UP         GJPF 81474617
         LA    RPAR0,EOLD-EDES         LOAD INPUT MAP OF OLD            81475016
         LR    RPAR1,CCTR              LOAD CCT ADDR                    81476016
         L     RBR,CCTPKYM             LOAD ADDR OF KEYMANIP            81477016
         BALR  RRET,RBR                BRANCH TO KEY MANIP              81478016
         SPACE                                                          81479016
*                                                                       81480016
*  ERROR  DATA SET WAS INDICATED TO BE CATALOGED BUT COULD NOT BE FOUND 81481016
*                                                                       81482016
         SPACE                                                          81483016
CTLGERR  BAL   PARMR,MSGSUB            LOAD REG ANB BRANCH TO MSGSUB    81484016
         DC    AL2(PNTR51)             DISPLACEMENT OF POINTER NO 51    81485016
         SPACE                                                          81486016
RESETSW  MVI   LOCATSW,X'F0'           RESET LOCATE SWITCH              81487016
         B     MOVDSNM                 GO TO MOVE DATA SET NAME         81488016
         SPACE                                                          81492017
MVCDSNM  MVC   LOCNAME(ZERO),EDSNAME   MOVE DS NAME TO LOCATE LIST GJPF 81496017
         EJECT                                                          81500016
*                                                                       81550016
*  CONSTANTS AND EQUATES USED                                           81600016
*                                                                       81650016
         SPACE                                                          81700016
LISTPNTR DC    V(IKAMDES0)             ADDR CONSTANT FOR MESSAGE MOD    81750016
HIGH4    DC    X'40000000'             CONSTANT FOR ORING REG'S         81770016
LOCFLGS  DC    X'44000000'             INDICATOR FLAGS FOR LOCATE       81780016
ONE1     DC    AL2(1)                                                   81800016
THREE3   DC    AL2(3)                                                   81850016
FOUR4    DC    AL2(4)                                                   81900016
EIGHT8   DC    AL2(8)                                                   81950016
NORMCODE DC    X'0000'                                                  82000016
CANCODE  DC    X'000C'                                                  82050016
ERRCODE  DC    X'0018'                RETURN CODE FOR ERROR IN REC MODE 82070016
INTERR   DC    X'001C'                 INTERNAL ERROR CODE         GJPF 82080017
LENGTCON DC    AL1(72)                 LENGTH CON OF 72                 82100016
BLANK    DC    CL16' '                 16 BYTES OF BLANKS               82150016
IGNOROFF DC    X'DF'                   MASK OF 11011111                 82200016
DD       DC    X'24'                                                    82250016
         DC    C'DD'                                                    82300016
         DC    X'24'                                                    82350016
SYSOUT   DC    X'25'                   HEX 25 CON                       82400016
         DC    C'SYSOUT='              KEYWORD CONSTANT                 82450016
CLASS    DC    X'2637'                                                  82500016
DES      DC    C'DES//'                                                 82550016
DSNAME   DC    X'24'                                                    82600016
         DC    C'DD'                                                    82650016
         DC    X'24'                                                    82700016
         DC    C'DSNAME='                                               82750016
DISP     DC    X'25'                                                    82800016
         DC    C'DISP=('                                                82850016
NEW      DC    C'NEW'                                                   82900016
OLD      DC    C'OLD'                                                   82950016
MOD      DC    C'MOD'                                                   83000016
SHR      DC    C'SHR'                                                   83050016
UNIT     DC    X'25'                                                    83100016
         DC    C'UNIT='                                                 83150016
VOLUM    DC    X'25'                                                    83200016
         DC    C'VOLUME=SER='                                           83250016
SPACE    DC    X'25'                                                    83300016
         DC    C'SPACE=('                                               83350016
TRK      DC    C'TRK,('                CONSTANT FOR TRACKS              83400016
CYL      DC    C'CYL,('                CONSTANT FOR CYLINDERS           83450016
PARENS   DC    C'))'                                                    83500016
PASS     DC    C',PASS)'               CONSTANT FOR PASS                83550016
DELETE   DC    C',DELETE)'                                              83600016
CATLG    DC    C',CATLG)'                                               83650016
KEEP     DC    C',KEEP)'                                                83700016
DSCON    DC    C'DESCRIBE'             CONSTANT FOR DIARY AND HST       83750016
DAP      DC    C'D A POOL'             CONSTANT FOR DIARY AND HST       83800016
ALLOCAT  DC    C'SYS ALLOC'            CONSTANT FOR DIARY AND HST       83850016
PRINT    DC    C'PRINT'                CONSTANT FOR DIARY AND HST       83900016
PUNCH    DC    C'PUNCH'                CONSTANT FOR DIARY AND HST       83950016
DISPLAY  DC    C'DISPLAY'          CONSTANT FOR DIARY AND HIST     IIXX 83970018
         SPACE 2                                                        83973000
*********************************************************************** 83976000
*                                                                       83979000
*        MAINTENANCE AREA                                        A33564 83982000
*                                                                       83985000
*********************************************************************** 83988000
PATCH    DC    40F'0'                                            A33564 83991000
         SPACE 2                                                        83994000
         END                                                            84000016
